Rules for integrands of the form(((a+b (x^n)))^p)

0:  ∫(((b (x^n)))^p)dx

Derivation: Piecewise constant extraction

Basis: (∂_x)((((b (x^n)))^p)/(x^(n p)))==0

Basis: ((((b (x^n)))^p)/(x^(n p)))==(((b^(IntPart[p])) (((b (x^n)))^(FracPart[p])))/(x^(n FracPart[p])))

Rule 1.1.3.1.0:

∫(((b (x^n)))^p)dx  ⟶  (((b^(IntPart[p])) (((b (x^n)))^(FracPart[p])))/(x^(n FracPart[p])))∫(x^(n p))dx

Program code:

Int[(b_.*x_^n_)^p_,x_Symbol] :=
  b^IntPart[p]*(b*x^n)^FracPart[p]/x^(n*FracPart[p])*Int[x^(n*p),x] /;
FreeQ[{b,n,p},x]

1:  ∫(((a+b (x^n)))^p)dx  when n∈𝔽 ∧ (1/n)∈ℤ

Derivation: Integration by substitution

Basis: If (1/n)∈ℤ, then F[(x^n)]==(1/n) Subst[(x^((1/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Rule 1.1.3.1.1: If n∈𝔽 ∧ (1/n)∈ℤ, then

∫(((a+b (x^n)))^p)dx  ⟶  (1/n) Subst[∫(x^((1/n)-1))(((a+b x))^p)dx,x,(x^n)]

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  1/n*Subst[Int[x^(1/n-1)*(a+b*x)^p,x],x,x^n] /;
FreeQ[{a,b,p},x] && FractionQ[n] && IntegerQ[1/n]

2.  ∫(((a+b (x^n)))^p)dx  when  (1/n)+p∈(SuperMinus[ℤ])∧ p≠-1

1:  ∫(((a+b (x^n)))^p)dx  when  (1/n)+p+1==0

Reference: G&R 2.110.2, CRC 88d with n (p+1)+1==0

Derivation: Binomial recurrence 3b with m==0 and (1/n)+p+1==0

Rule 1.1.3.1.2.1: If  (1/n)+p+1==0, then

∫(((a+b (x^n)))^p)dx  ⟶  ((x (((a+b (x^n)))^(p+1)))/a)

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  x*(a+b*x^n)^(p+1)/a /;
FreeQ[{a,b,n,p},x] && EqQ[1/n+p+1,0]

2:  ∫(((a+b (x^n)))^p)dx  when  (1/n)+p+1∈(SuperMinus[ℤ])∧ p≠-1

Reference: G&R 2.110.2, CRC 88d

Derivation: Binomial recurrence 2b

Derivation: Integration by parts

Basis: (x^m) (((a+b (x^n)))^p)==(x^(m+n p+n+1))((((a+b (x^n)))^p)/(x^(n (p+1)+1)))

Basis: ∫((((a+b (x^n)))^p)/(x^(n (p+1)+1)))dx==-((((a+b (x^n)))^(p+1))/((x^(n (p+1)))a n (p+1)))

Rule 1.1.3.1.2.2: If  (1/n)+p+1∈(SuperMinus[ℤ])∧ p≠-1, then

∫(((a+b (x^n)))^p)dx  ⟶  -((x (((a+b (x^n)))^(p+1)))/(a n (p+1)))+((n(p+1)+1)/(a n (p+1)))∫(((a+b (x^n)))^(p+1))dx

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  -x*(a+b*x^n)^(p+1)/(a*n*(p+1)) +
  (n*(p+1)+1)/(a*n*(p+1))*Int[(a+b*x^n)^(p+1),x] /;
FreeQ[{a,b,n,p},x] && ILtQ[Simplify[1/n+p+1],0] && NeQ[p,-1]

3:  ∫(((a+b (x^n)))^p)dx  when  n<0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis:  If  p∈ℤ, then(((a+b (x^n)))^p)==(x^(n p))(((b+a (x^(-n))))^p)

Rule 1.1.3.1.3: If  n<0 ∧ p∈ℤ, then

∫(((a+b (x^n)))^p)dx  ⟶  ∫(x^(n p)) (((b+a (x^(-n))))^p)dx

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  Int[x^(n*p)*(b+a*x^(-n))^p,x] /;
FreeQ[{a,b},x] && LtQ[n,0] && IntegerQ[p]

4.  ∫(((a+b (x^n)))^p)dx  when  n∈ℤ

1.  ∫(((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])

1.  ∫(((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ p>0

1:  ∫(((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.1.3.1.4.1.1.1: If  n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ]), then

∫(((a+b (x^n)))^p)dx  ⟶  ∫ExpandIntegrand[(((a+b (x^n)))^p),x]dx

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*x^n)^p,x],x] /;
FreeQ[{a,b},x] && IGtQ[n,0] && IGtQ[p,0]

2:  ∫(((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ p>0

Reference: G&R 2.110.1, CRC 88b

Derivation: Binomial recurrence 1b

Derivation: Inverted integration by parts

Note: If  n∈(SuperPlus[ℤ])∧ p>0, then n p+1≠0.

Rule 1.1.3.1.4.1.1.2: If  n∈(SuperPlus[ℤ])∧ p>0, then

∫(((a+b (x^n)))^p)dx  ⟶  ((x (((a+b (x^n)))^p))/(n p+1))+((a n p)/(n p+1))∫(((a+b (x^n)))^(p-1))dx

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  x*(a+b*x^n)^p/(n*p+1) +
  a*n*p/(n*p+1)*Int[(a+b*x^n)^(p-1),x] /;
FreeQ[{a,b},x] && IGtQ[n,0] && GtQ[p,0] && 
  (IntegerQ[2*p] || EqQ[n,2] && IntegerQ[4*p] || EqQ[n,2] && IntegerQ[3*p] || LtQ[Denominator[p+1/n],Denominator[p]])

2.  ∫(((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ p<-1

1.  ∫(1/(((a+b (x^2)))^(5/4)))dx  when  a≮0 ∧ (b/a)>0

1:  ∫(1/(((a+b (x^2)))^(5/4)))dx  when  a>0 ∧ (b/a)>0

Contributed by Martin Welz on 7 August 2016

Rule 1.1.3.1.4.1.2.1.1: If  a>0 ∧ (b/a)>0, then

∫(1/(((a+b (x^2)))^(5/4)))dx  ⟶ (2/((a^(5/4)) (Sqrt[(b/a)]))) EllipticE[(1/2) ArcTan[(Sqrt[(b/a)]) x],2]

Program code:

Int[1/(a_+b_.*x_^2)^(5/4),x_Symbol] :=
  2/(a^(5/4)*Rt[b/a,2])*EllipticE[1/2*ArcTan[Rt[b/a,2]*x],2] /;
FreeQ[{a,b},x] && GtQ[a,0] && PosQ[b/a]

2:  ∫(1/(((a+b (x^2)))^(5/4)))dx  when  a≮0 ∧ (b/a)>0

Derivation: Piecewise constant extraction

Basis: (∂_x)((((1+((b (x^2))/a)))^(1/4))/(((a+b (x^2)))^(1/4)))==0

Rule 1.1.3.1.4.1.2.1.2: If  a≮0 ∧ (b/a)>0, then

∫(1/(((a+b (x^2)))^(5/4)))dx  ⟶  ((((1+((b (x^2))/a)))^(1/4))/(a (((a+b (x^2)))^(1/4))))∫(1/(((1+((b (x^2))/a)))^(5/4)))dx

Program code:

Int[1/(a_+b_.*x_^2)^(5/4),x_Symbol] :=
  (1+b*x^2/a)^(1/4)/(a*(a+b*x^2)^(1/4))*Int[1/(1+b*x^2/a)^(5/4),x] /;
FreeQ[{a,b},x] && PosQ[a] && PosQ[b/a]

2:  ∫(1/(((a+b (x^2)))^(7/6)))dx

Derivation: Piecewise constant extraction and integration by substitution

Basis:  (∂_x)(1/((((a+b (x^2)))^(2/3)) ((((a/(a+b (x^2)))))^(2/3))))==0

Basis: (((((a/(a+b (x^2)))))^(2/3))/(Sqrt[a+b (x^2)]))==Subst[(1/(((1-b (x^2)))^(1/3))),x,(x/(Sqrt[a+b (x^2)]))] (∂_x)(x/(Sqrt[a+b (x^2)]))

Rule 1.1.3.1.4.1.2.2:

∫(1/(((a+b (x^2)))^(7/6)))dx  ⟶  (1/((((a+b (x^2)))^(2/3)) ((((a/(a+b (x^2)))))^(2/3))))∫(((((a/(a+b (x^2)))))^(2/3))/(Sqrt[a+b (x^2)]))dx
  ⟶  (1/((((a+b (x^2)))^(2/3)) ((((a/(a+b (x^2)))))^(2/3))))Subst[∫(1/(((1-b (x^2)))^(1/3)))dx,x,(x/(Sqrt[a+b (x^2)]))]

Program code:

Int[1/(a_+b_.*x_^2)^(7/6),x_Symbol] :=
  1/((a +b*x^2)^(2/3)*(a/(a+b*x^2))^(2/3))*Subst[Int[1/(1-b*x^2)^(1/3),x],x,x/Sqrt[a+b*x^2]] /;
FreeQ[{a,b},x]

3:  ∫(((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ p<-1

Reference: G&R 2.110.2, CRC 88d

Derivation: Binomial recurrence 2b

Derivation: Integration by parts

Basis: (((a+b (x^n)))^p)==(x^(n (p+1)+1))((((a+b (x^n)))^p)/(x^(n (p+1)+1)))

Basis: ∫((((a+b (x^n)))^p)/(x^(n (p+1)+1)))dx==-((((a+b (x^n)))^(p+1))/((x^(n (p+1)))a n (p+1)))

Rule 1.1.3.1.4.1.2.3: If  n∈(SuperPlus[ℤ])∧ p<-1, then

∫(((a+b (x^n)))^p)dx  ⟶  -((x (((a+b (x^n)))^(p+1)))/(a n (p+1)))+((n(p+1)+1)/(a n (p+1)))∫(((a+b (x^n)))^(p+1))dx

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  -x*(a+b*x^n)^(p+1)/(a*n*(p+1)) +
  (n*(p+1)+1)/(a*n*(p+1))*Int[(a+b*x^n)^(p+1),x] /;
FreeQ[{a,b},x] && IGtQ[n,0] && LtQ[p,-1] && 
  (IntegerQ[2*p] || n==2 && IntegerQ[4*p] || n==2 && IntegerQ[3*p] || Denominator[p+1/n]<Denominator[p])

3.  ∫(1/(a+b (x^n)))dx  when  n∈(SuperPlus[ℤ])

1.  ∫(1/(a+b (x^n)))dx  when ((n-1)/2)∈(SuperPlus[ℤ])

1:  ∫(1/(a+b (x^3)))dx

Reference: G&R 2.126.1.2, CRC 74

Derivation: Algebraic expansion

Basis: (1/(a+b (x^3)))==(1/(3 (a^(2/3)) ((a^(1/3))+(b^(1/3)) x)))+((2 (a^(1/3))-(b^(1/3)) x)/(3 (a^(2/3)) ((a^(2/3))-(a^(1/3)) (b^(1/3)) x+(b^(2/3)) (x^2))))

Rule 1.1.3.1.4.1.3.1.1:

∫(1/(a+b (x^3)))dx  ⟶  (1/(3 (a^(2/3))))∫(1/((a^(1/3))+(b^(1/3)) x))dx+(1/(3 (a^(2/3))))∫((2 (a^(1/3))-(b^(1/3)) x)/((a^(2/3))-(a^(1/3)) (b^(1/3)) x+(b^(2/3)) (x^2)))dx

Program code:

Int[1/(a_+b_.*x_^3),x_Symbol] :=
  1/(3*Rt[a,3]^2)*Int[1/(Rt[a,3]+Rt[b,3]*x),x] + 
  1/(3*Rt[a,3]^2)*Int[(2*Rt[a,3]-Rt[b,3]*x)/(Rt[a,3]^2-Rt[a,3]*Rt[b,3]*x+Rt[b,3]^2*x^2),x] /;
FreeQ[{a,b},x]

x.  ∫(1/(a+b (x^5)))dx

1:  ∫(1/(a+b (x^5)))dx  when (a/b)>0

Derivation: Algebraic expansion

Basis: If  (r/s)=((((a/b)))^(1/5)), then (1/(a+b (x^5)))==(r/(5 a (r+s x)))+((2 r(r-(1/4) (1-(Sqrt[5])) s x))/(5 a ((r^2)-(1/2) (1-(Sqrt[5]))r s x+(s^2)(x^2))))+((2r (r-(1/4) (1+(Sqrt[5])) s x))/(5 a ((r^2)-(1/2) (1+(Sqrt[5]))r s x+(s^2)(x^2))))

Note: This rule not necessary for host systems that automatically simplify Cos[((k π)/5)] to radicals when k is an integer.

Rule 1.1.3.1.4.1.3.1.2.1: If  (a/b)>0, let (r/s)=((((a/b)))^(1/5)), then

∫(1/(a+b (x^5)))dx  ⟶  (r/(5 a))∫(1/(r+s x))dx+((2 r)/(5 a))∫((r-(1/4) (1-(Sqrt[5])) s x)/((r^2)-(1/2) (1-(Sqrt[5]))r s x+(s^2)(x^2)))dx+((2 r)/(5 a))∫((r-(1/4) (1+(Sqrt[5])) s x)/((r^2)-(1/2) (1+(Sqrt[5]))r s x+(s^2)(x^2)))dx

Program code:

(* Int[1/(a_+b_.*x_^5),x_Symbol] :=
  With[{r=Numerator[Rt[a/b,5]], s=Denominator[Rt[a/b,5]]},
  r/(5*a)*Int[1/(r+s*x),x] + 
  2*r/(5*a)*Int[(r-1/4*(1-Sqrt[5])*s*x)/(r^2-1/2*(1-Sqrt[5])*r*s*x+s^2*x^2),x] + 
  2*r/(5*a)*Int[(r-1/4*(1+Sqrt[5])*s*x)/(r^2-1/2*(1+Sqrt[5])*r*s*x+s^2*x^2),x]] /;
FreeQ[{a,b},x] && PosQ[a/b] *)

2:  ∫(1/(a+b (x^5)))dx  when (a/b)≯0

Derivation: Algebraic expansion

Basis: If  (r/s)=(((-(a/b)))^(1/5)), then (1/(a+b (x^5)))==(r/(5 a (r-s x)))+((2 r(r+(1/4) (1-(Sqrt[5])) s x))/(5 a ((r^2)+(1/2) (1-(Sqrt[5]))r s x+(s^2)(x^2))))+((2r (r+(1/4) (1+(Sqrt[5])) s x))/(5 a ((r^2)+(1/2) (1+(Sqrt[5]))r s x+(s^2)(x^2))))

Note: This rule not necessary for host systems that automatically simplify Cos[((k π)/5)] to radicals when k is an integer.

Rule 1.1.3.1.4.1.3.1.2.2: If  (a/b)≯0, let (r/s)=(((-(a/b)))^(1/5)), then

∫(1/(a+b (x^5)))dx  ⟶  (r/(5 a))∫(1/(r-s x))dx+((2 r)/(5 a))∫((r+(1/4) (1-(Sqrt[5])) s x)/((r^2)+(1/2) (1-(Sqrt[5]))r s x+(s^2)(x^2)))dx+((2 r)/(5 a))∫((r+(1/4) (1+(Sqrt[5])) s x)/((r^2)+(1/2) (1+(Sqrt[5]))r s x+(s^2)(x^2)))dx

Program code:

(* Int[1/(a_+b_.*x_^5),x_Symbol] :=
  With[{r=Numerator[Rt[-a/b,5]], s=Denominator[Rt[-a/b,5]]},
  r/(5*a)*Int[1/(r-s*x),x] + 
  2*r/(5*a)*Int[(r+1/4*(1-Sqrt[5])*s*x)/(r^2+1/2*(1-Sqrt[5])*r*s*x+s^2*x^2),x] + 
  2*r/(5*a)*Int[(r+1/4*(1+Sqrt[5])*s*x)/(r^2+1/2*(1+Sqrt[5])*r*s*x+s^2*x^2),x]] /;
FreeQ[{a,b},x] && NegQ[a/b] *)

3.  ∫(1/(a+b (x^n)))dx  when ((n-3)/2)∈(SuperPlus[ℤ])

1:  ∫(1/(a+b (x^n)))dx  when ((n-3)/2)∈(SuperPlus[ℤ])∧ (a/b)>0

Derivation: Algebraic expansion

Basis: If ((n-1)/2)∈ℤ and (r/s)=((((a/b)))^(1/n)), then (1/(a+b (z^n)))==(r/(a n(r+s z)))+((2r)/(a n))(∑_(k=1)^((n-1)/2))((r-s Cos[(((2 k-1) π)/n)] z)/((r^2)-2 r s Cos[(((2 k-1) π)/n)] z+(s^2) (z^2)))

Rule 1.1.3.1.4.1.3.1.3.1: If ((n-3)/2)∈(SuperPlus[ℤ])∧ (a/b)>0, let (r/s)=((((a/b)))^(1/n)), then

∫(1/(a+b (x^n)))dx  ⟶  (r/(a n)) ∫(1/(r+s x))dx+((2 r)/(a n))(∑_(k=1)^((n-1)/2))∫((r-s Cos[(((2 k-1) π)/n)] x)/((r^2)-2 r s Cos[(((2 k-1) π)/n)] x+(s^2) (x^2)))dx

Program code:

Int[1/(a_+b_.*x_^n_),x_Symbol] :=
  Module[{r=Numerator[Rt[a/b,n]], s=Denominator[Rt[a/b,n]], k, u},
  u=Int[(r-s*Cos[(2*k-1)*Pi/n]*x)/(r^2-2*r*s*Cos[(2*k-1)*Pi/n]*x+s^2*x^2),x];
  r/(a*n)*Int[1/(r+s*x),x] + Dist[2*r/(a*n),Sum[u,{k,1,(n-1)/2}],x]] /;
FreeQ[{a,b},x] && IGtQ[(n-3)/2,0] && PosQ[a/b]

2:  ∫(1/(a+b (x^n)))dx  when ((n-3)/2)∈(SuperPlus[ℤ])∧ (a/b)≯0

Derivation: Algebraic expansion

Basis: If ((n-1)/2)∈ℤ and (r/s)=(((-(a/b)))^(1/n)), then (1/(a+b (z^n)))==(r/(a n(r-s z)))+((2r)/(a n))(∑_(k=1)^((n-1)/2))((r+s Cos[(((2 k-1) π)/n)] z)/((r^2)+2 r s Cos[(((2 k-1) π)/n)] z+(s^2) (z^2)))

Rule 1.1.3.1.4.1.3.1.3.2: If ((n-3)/2)∈(SuperPlus[ℤ])∧ (a/b)≯0, let (r/s)=(((-(a/b)))^(1/n)), then

∫(1/(a+b (x^n)))dx  ⟶  (r/(a n)) ∫(1/(r-s x))dx+((2 r)/(a n))(∑_(k=1)^((n-1)/2))∫((r+s Cos[(((2 k-1) π)/n)] x)/((r^2)+2 r s Cos[(((2 k-1) π)/n)] x+(s^2) (x^2)))dx

Program code:

Int[1/(a_+b_.*x_^n_),x_Symbol] :=
  Module[{r=Numerator[Rt[-a/b,n]], s=Denominator[Rt[-a/b,n]], k, u},
  u=Int[(r+s*Cos[(2*k-1)*Pi/n]*x)/(r^2+2*r*s*Cos[(2*k-1)*Pi/n]*x+s^2*x^2),x];
  r/(a*n)*Int[1/(r-s*x),x] + Dist[2*r/(a*n),Sum[u,{k,1,(n-1)/2}],x]] /;
FreeQ[{a,b},x] && IGtQ[(n-3)/2,0] && NegQ[a/b]

2.  ∫(1/(a+b (x^n)))dx  when (n/2)∈(SuperPlus[ℤ])

1.  ∫(1/(a+b (x^n)))dx  when ((n+2)/4)∈(SuperPlus[ℤ])

1.  ∫(1/(a+b (x^2)))dx

1:  ∫(1/(a+b (x^2)))dx  when (a/b)>0

Reference: G&R 2.124.1a, CRC 60, A&S 3.3.21

Derivation: Primitive rule

Basis: ArcTan'[z]==(1/(1+(z^2)))

Rule 1.1.3.1.4.1.3.2.1.1.1: If  (a/b)>0, then

∫(1/(a+b (x^2)))dx  ⟶  ((Sqrt[(a/b)])/a)ArcTan[(x/(Sqrt[(a/b)]))]

Program code:

Int[1/(a_+b_.*x_^2),x_Symbol] :=
  1/(Rt[a,2]*Rt[b,2])*ArcTan[Rt[b,2]*x/Rt[a,2]] /;
FreeQ[{a,b},x] && PosQ[a/b] && (GtQ[a,0] || GtQ[b,0])

Int[1/(a_+b_.*x_^2),x_Symbol] :=
  -1/(Rt[-a,2]*Rt[-b,2])*ArcTan[Rt[-b,2]*x/Rt[-a,2]] /;
FreeQ[{a,b},x] && PosQ[a/b] && (LtQ[a,0] || LtQ[b,0])

Int[1/(a_+b_.*x_^2),x_Symbol] :=
(*Rt[b/a,2]/b*ArcTan[Rt[b/a,2]*x] /; *)
  Rt[a/b,2]/a*ArcTan[x/Rt[a/b,2]] /;
FreeQ[{a,b},x] && PosQ[a/b]

2:  ∫(1/(a+b (x^2)))dx  when (a/b)≯0

Reference: G&R 2.124.1b', CRC 61b, A&S 3.3.23

Derivation: Primitive rule

Basis: ArcTanh'[z]==(1/(1-(z^2)))

Rule 1.1.3.1.4.1.3.2.1.1.2: If  (a/b)≯0, then

∫(1/(a+b (x^2)))dx  ⟶  ((Sqrt[-(a/b)])/a)ArcTanh[(x/(Sqrt[-(a/b)]))]

Program code:

Int[1/(a_+b_.*x_^2),x_Symbol] :=
  1/(Rt[a,2]*Rt[-b,2])*ArcTanh[Rt[-b,2]*x/Rt[a,2]] /;
FreeQ[{a,b},x] && NegQ[a/b] && (GtQ[a,0] || LtQ[b,0])

Int[1/(a_+b_.*x_^2),x_Symbol] :=
  -1/(Rt[-a,2]*Rt[b,2])*ArcTanh[Rt[b,2]*x/Rt[-a,2]] /;
FreeQ[{a,b},x] && NegQ[a/b] && (LtQ[a,0] || GtQ[b,0])

Int[1/(a_+b_.*x_^2),x_Symbol] :=
(*-Rt[-b/a,2]/b*ArcTanh[Rt[-b/a,2]*x] /; *)
  Rt[-a/b,2]/a*ArcTanh[x/Rt[-a/b,2]] /;
FreeQ[{a,b},x] && NegQ[a/b]

2.  ∫(1/(a+b (x^n)))dx  when ((n-2)/4)∈(SuperPlus[ℤ])

1:  ∫(1/(a+b (x^n)))dx  when ((n-2)/4)∈(SuperPlus[ℤ])∧ (a/b)>0

Derivation: Algebraic expansion

Basis: If ((n-2)/4)∈ℤ and (r/s)=((((a/b)))^(1/n)), then (1/(a+b (z^n)))==((2(r^2))/(a n((r^2)+(s^2) (z^2))))+((4(r^2))/(a n))(∑_(k=1)^((n-2)/4))(((r^2)-(s^2) Cos[((2 (2 k-1) π)/n)] (z^2))/((r^4)-2 (r^2) (s^2) Cos[((2 (2 k-1) π)/n)] (z^2)+(s^4) (z^4)))

Basis: (((r^2)-(s^2) Cos[2 θ] (z^2))/((r^4)-2 (r^2) (s^2) Cos[2 θ]  (z^2)+(s^4) (z^4)))==(1/(2 r))(((r-s Cos[θ] z)/((r^2)-2r s Cos[θ] z+(s^2) (z^2))) +((r+s Cos[θ] z)/((r^2)+2r s Cos[θ] z+(s^2) (z^2))))

Rule 1.1.3.1.4.1.3.2.1.2.1: If ((n-2)/4)∈(SuperPlus[ℤ])∧ (a/b)>0, let (r/s)=((((a/b)))^(1/n)), then

∫(1/(a+b (x^n)))dx  ⟶  ((2 (r^2))/(a n))∫(1/((r^2)+(s^2) (x^2)))dx+((4 (r^2))/(a n))(∑_(k=1)^((n-2)/4))∫(((r^2)-(s^2) Cos[((2 (2 k-1) π)/n)] (x^2))/((r^4)-2 (r^2) (s^2) Cos[((2 (2 k-1) π)/n)] (x^2)+(s^4) (x^4)))dx

  ⟶  ((2 (r^2))/(a n))∫(1/((r^2)+(s^2) (x^2)))dx+((2 r)/(a n))(∑_(k=1)^((n-2)/4))(∫((r-s Cos[(((2 k-1) π)/n)] x)/((r^2)-2r s Cos[(((2 k-1) π)/n)] x+(s^2) (x^2)))dx+∫((r+s Cos[(((2 k-1) π)/n)] x)/((r^2)+2r s Cos[(((2 k-1) π)/n)] x+(s^2) (x^2)))dx)

Program code:

Int[1/(a_+b_.*x_^n_),x_Symbol] :=
  Module[{r=Numerator[Rt[a/b,n]], s=Denominator[Rt[a/b,n]], k, u, v},
  u=Int[(r-s*Cos[(2*k-1)*Pi/n]*x)/(r^2-2*r*s*Cos[(2*k-1)*Pi/n]*x+s^2*x^2),x] + 
    Int[(r+s*Cos[(2*k-1)*Pi/n]*x)/(r^2+2*r*s*Cos[(2*k-1)*Pi/n]*x+s^2*x^2),x];
  2*r^2/(a*n)*Int[1/(r^2+s^2*x^2),x] + Dist[2*r/(a*n),Sum[u,{k,1,(n-2)/4}],x]] /;
FreeQ[{a,b},x] && IGtQ[(n-2)/4,0] && PosQ[a/b]

2:  ∫(1/(a+b (x^n)))dx  when ((n-2)/4)∈(SuperPlus[ℤ])∧ (a/b)≯0

Derivation: Algebraic expansion

Basis: If ((n-2)/4)∈ℤ and (r/s)=(((-(a/b)))^(1/n)), then (1/(a+b (z^n)))==((2(r^2))/(a n((r^2)-(s^2) (z^2))))+((4(r^2))/(a n))(∑_(k=1)^((n-2)/4))(((r^2)-(s^2) Cos[((4 k π)/n)] (z^2))/((r^4)-2 (r^2) (s^2) Cos[((4 k π)/n)] (z^2)+(s^4) (z^4)))

Basis: (((r^2)-(s^2) Cos[2 θ] (z^2))/((r^4)-2 (r^2) (s^2) Cos[2 θ]  (z^2)+(s^4) (z^4)))==(1/(2 r))(((r-s Cos[θ] z)/((r^2)-2r s Cos[θ] z+(s^2) (z^2))) +((r+s Cos[θ] z)/((r^2)+2r s Cos[θ] z+(s^2) (z^2))))

Rule 1.1.3.1.4.1.3.2.1.2.2: If ((n-2)/4)∈(SuperPlus[ℤ])∧ (a/b)≯0, let (r/s)=(((-(a/b)))^(1/n)), then

∫(1/(a+b (x^n)))dx  ⟶  ((2 (r^2))/(a n))∫(1/((r^2)-(s^2) (x^2)))dx+((4 (r^2))/(a n))(∑_(k=1)^((n-2)/4))∫(((r^2)-(s^2) Cos[((4 k π)/n)] (x^2))/((r^4)-2 (r^2) (s^2) Cos[((4 k π)/n)] (x^2)+(s^4) (x^4)))dx

  ⟶  ((2 (r^2))/(a n))∫(1/((r^2)-(s^2) (x^2)))dx+((2 r)/(a n))(∑_(k=1)^((n-2)/4))(∫((r-s Cos[((2 k π)/n)] x)/((r^2)-2r s Cos[((2 k π)/n)] x+(s^2) (x^2)))dx+∫((r+s Cos[((2 k π)/n)] x)/((r^2)+2r s Cos[((2 k π)/n)] x+(s^2) (x^2)))dx)

Program code:

Int[1/(a_+b_.*x_^n_),x_Symbol] :=
  Module[{r=Numerator[Rt[-a/b,n]], s=Denominator[Rt[-a/b,n]], k, u},
  u=Int[(r-s*Cos[(2*k*Pi)/n]*x)/(r^2-2*r*s*Cos[(2*k*Pi)/n]*x+s^2*x^2),x] + 
    Int[(r+s*Cos[(2*k*Pi)/n]*x)/(r^2+2*r*s*Cos[(2*k*Pi)/n]*x+s^2*x^2),x];
  2*r^2/(a*n)*Int[1/(r^2-s^2*x^2),x] + Dist[2*r/(a*n),Sum[u,{k,1,(n-2)/4}],x]] /;
FreeQ[{a,b},x] && IGtQ[(n-2)/4,0] && NegQ[a/b]

2.  ∫(1/(a+b (x^n)))dx  when (n/4)∈(SuperPlus[ℤ])

1.  ∫(1/(a+b (x^4)))dx

1:  ∫(1/(a+b (x^4)))dx  when  (a/b)>0

Derivation: Algebraic expansion

Basis: If (r/s)=(Sqrt[(a/b)]), then (1/(a+b (x^4)))==((r-s (x^2))/(2 r (a+b (x^4))))+((r+s (x^2))/(2 r (a+b (x^4))))

Note: Resulting integrands are of the form ((d+e (x^2))/(a+c (x^4))) where c (d^2)-a (e^2)==0 as required by the algebraic trinomial rules.

Rule 1.1.3.1.4.1.3.2.2.1.1: If (a/b)>0, let (r/s)=(Sqrt[(a/b)]), then

∫(1/(a+b (x^4)))dx  ⟶  (1/(2r))∫((r-s (x^2))/(a+b (x^4)))dx+(1/(2r))∫((r+s (x^2))/(a+b (x^4)))dx

Program code:

Int[1/(a_+b_.*x_^4),x_Symbol] :=
  With[{r=Numerator[Rt[a/b,2]], s=Denominator[Rt[a/b,2]]},
  1/(2*r)*Int[(r-s*x^2)/(a+b*x^4),x] + 1/(2*r)*Int[(r+s*x^2)/(a+b*x^4),x]] /;
FreeQ[{a,b},x] && (GtQ[a/b,0] || PosQ[a/b] && AtomQ[SplitProduct[SumBaseQ,a]] && AtomQ[SplitProduct[SumBaseQ,b]])

2:  ∫(1/(a+b (x^4)))dx  when (a/b)≯0

Reference: G&R 2.132.1.2', CRC 78'

Derivation: Algebraic expansion

Basis: Let (r/s)=(Sqrt[-(a/b)]), then (1/(a+b (z^2)))==(r/(2a(r-s z)))+(r/(2a(r+s z)))

Rule 1.1.3.1.4.1.3.2.2.1.2: If (a/b)≯0, let (r/s)=(Sqrt[-(a/b)]), then

∫(1/(a+b (x^4)))dx  ⟶  (r/(2 a))∫(1/(r-s (x^2)))dx+(r/(2 a))∫(1/(r+s (x^2)))dx

Program code:

Int[1/(a_+b_.*x_^4),x_Symbol] :=
  With[{r=Numerator[Rt[-a/b,2]], s=Denominator[Rt[-a/b,2]]},
  r/(2*a)*Int[1/(r-s*x^2),x] + r/(2*a)*Int[1/(r+s*x^2),x]] /;
FreeQ[{a,b},x] && Not[GtQ[a/b,0]]

2.  ∫(1/(a+b (x^n)))dx  when (n/4)-1∈(SuperPlus[ℤ])

1:  ∫(1/(a+b (x^n)))dx  when (n/4)-1∈(SuperPlus[ℤ])∧ (a/b)>0

Reference: G&R 2.132.1.1', CRC 77'

Derivation: Algebraic expansion

Basis: If (r/s)=((((a/b)))^(1/4)), then (1/(a+b (z^4)))==((r ((Sqrt[2]) r-s z))/(2(Sqrt[2])a((r^2)-(Sqrt[2]) r s z+(s^2) (z^2))))+((r ((Sqrt[2]) r+s z))/(2(Sqrt[2])a((r^2)+(Sqrt[2]) r s z+(s^2) (z^2))))

Rule 1.1.3.1.4.1.3.2.2.2.1: If (n/4)∈(SuperPlus[ℤ])∧ n>4 ∧ (a/b)>0, let (r/s)=((((a/b)))^(1/4)), then

∫(1/(a+b (x^n)))dx  ⟶  (r/(2 (Sqrt[2]) a))∫(((Sqrt[2]) r-s (x^(n/4)))/((r^2)-(Sqrt[2]) r s (x^(n/4))+(s^2) (x^(n/2))))dx+(r/(2 (Sqrt[2]) a))∫(((Sqrt[2]) r+s (x^(n/4)))/((r^2)+(Sqrt[2]) r s (x^(n/4))+(s^2) (x^(n/2))))dx

Program code:

Int[1/(a_+b_.*x_^n_),x_Symbol] :=
  With[{r=Numerator[Rt[a/b,4]], s=Denominator[Rt[a/b,4]]},
  r/(2*Sqrt[2]*a)*Int[(Sqrt[2]*r-s*x^(n/4))/(r^2-Sqrt[2]*r*s*x^(n/4)+s^2*x^(n/2)),x] + 
  r/(2*Sqrt[2]*a)*Int[(Sqrt[2]*r+s*x^(n/4))/(r^2+Sqrt[2]*r*s*x^(n/4)+s^2*x^(n/2)),x]] /;
FreeQ[{a,b},x] && IGtQ[n/4,1] && GtQ[a/b,0]

2:  ∫(1/(a+b (x^n)))dx  when (n/4)-1∈(SuperPlus[ℤ])∧ (a/b)≯0

Reference: G&R 2.132.1.2', CRC 78'

Derivation: Algebraic expansion

Basis: Let (r/s)=(Sqrt[-(a/b)]), then (1/(a+b (z^2)))==(r/(2a(r-s z)))+(r/(2a(r+s z)))

Rule 1.1.3.1.4.1.3.2.2.2.2: If (n/4)∈(SuperPlus[ℤ])∧ (a/b)≯0, let (r/s)=(Sqrt[-(a/b)]), then

∫(1/(a+b (x^n)))dx  ⟶  (r/(2 a))∫(1/(r-s (x^(n/2))))dx+(r/(2 a))∫(1/(r+s (x^(n/2))))dx

Program code:

Int[1/(a_+b_.*x_^n_),x_Symbol] :=
  With[{r=Numerator[Rt[-a/b,2]], s=Denominator[Rt[-a/b,2]]},
  r/(2*a)*Int[1/(r-s*x^(n/2)),x] + r/(2*a)*Int[1/(r+s*x^(n/2)),x]] /;
FreeQ[{a,b},x] && IGtQ[n/4,1] && Not[GtQ[a/b,0]]

4.  ∫(1/(Sqrt[a+b (x^n)]))dx  when  n∈(SuperPlus[ℤ])

1.  ∫(1/(Sqrt[a+b (x^2)]))dx

1.  ∫(1/(Sqrt[a+b (x^2)]))dx  when  a>0

1:  ∫(1/(Sqrt[a+b (x^2)]))dx  when  a>0 ∧ b>0

Reference: CRC 278

Derivation: Primitive rule

Basis: ArcSinh'[z]==(1/(Sqrt[1+(z^2)]))

Rule 1.1.3.1.4.1.4.1.1.1: If  a>0 ∧ b>0, then

∫(1/(Sqrt[a+b (x^2)]))dx  ⟶   (1/(Sqrt[b])) ArcSinh[(((Sqrt[b]) x)/(Sqrt[a]))]

Program code:

Int[1/Sqrt[a_+b_.*x_^2],x_Symbol] :=
  ArcSinh[Rt[b,2]*x/Sqrt[a]]/Rt[b,2] /;
FreeQ[{a,b},x] && GtQ[a,0] && PosQ[b]

2:  ∫(1/(Sqrt[a+b (x^2)]))dx  when  a>0 ∧ b≯0

Reference: G&R 2.271.4b, CRC 279, A&S 3.3.44

Derivation: Primitive rule

Basis: ArcSin'[z]==(1/(Sqrt[1-(z^2)]))

Rule 1.1.3.1.4.1.4.1.1.2: If  a>0 ∧ b≯0, then

∫(1/(Sqrt[a+b (x^2)]))dx  ⟶  (1/(Sqrt[-b])) ArcSin[(((Sqrt[-b]) x)/(Sqrt[a]))]

Program code:

Int[1/Sqrt[a_+b_.*x_^2],x_Symbol] :=
  ArcSin[Rt[-b,2]*x/Sqrt[a]]/Rt[-b,2] /;
FreeQ[{a,b},x] && GtQ[a,0] && NegQ[b]

2:  ∫(1/(Sqrt[a+b (x^2)]))dx  when  a≯0

Reference: CRC 278'

Reference: CRC 279'

Derivation: Integration by substitution

Basis: (1/(Sqrt[a+b (x^2)]))==Subst[(1/(1-b (x^2))),x,(x/(Sqrt[a+b (x^2)]))] (∂_x)(x/(Sqrt[a+b (x^2)]))

Rule 1.1.3.1.4.1.4.1.2: If  a≯0, then

∫(1/(Sqrt[a+b (x^2)]))dx  ⟶  Subst[∫(1/(1-b (x^2)))dx,x,(x/(Sqrt[a+b (x^2)]))]

Program code:

Int[1/Sqrt[a_+b_.*x_^2],x_Symbol] :=
  Subst[Int[1/(1-b*x^2),x],x,x/Sqrt[a+b*x^2]] /;
FreeQ[{a,b},x] && Not[GtQ[a,0]]

2.  ∫(1/(Sqrt[a+b (x^3)]))dx

x:  ∫(1/(Sqrt[a+b (x^3)]))dx  when  a>0

Reference: G&R 3.139

Derivation: Piecewise constant extraction and integration by the Möbius substitution

Basis: Let q->((((b/a)))^(1/3)), then (∂_x)(((((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))]))/(Sqrt[a+b (x^3)]))==0

Basis: (1/((((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))])))==-(((Sqrt[2]) (1+(Sqrt[3])))/((3^(1/4)) q))Subst[(1/((Sqrt[1-(x^2)]) (Sqrt[1+(7+4 (Sqrt[3])) (x^2)]))),x,((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))] (∂_x)((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))

Note: If  a>0 ∧ b>0, then ArcSin[((-1+(Sqrt[3])-((((b/a)))^(1/3)) x)/(1+(Sqrt[3])+((((b/a)))^(1/3)) x))] is real when (Sqrt[a+b (x^3)]) is real.

Note: Although simpler than the following rule, Mathematica is unable to validate the result by differentiation.

Rule 1.1.3.1.4.1.4.2.1.1: If  a>0, let q->((((b/a)))^(1/3)), then

∫(1/(Sqrt[a+b (x^3)]))dx  ⟶  (((((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))]))/(Sqrt[a+b (x^3)])) ∫(1/((((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))])))dx
  ⟶  -(((Sqrt[2]) (1+(Sqrt[3])) (((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))]))/((3^(1/4)) q (Sqrt[a+b (x^3)]))) Subst[∫(1/((Sqrt[1-(x^2)]) (Sqrt[1+(7+4 (Sqrt[3])) (x^2)])))dx,x,((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))]
  ⟶  -(((Sqrt[2]) (1+(Sqrt[3])) (((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))]))/((3^(1/4)) q (Sqrt[a+b (x^3)]))) EllipticF[ArcSin[((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))],-7-4 (Sqrt[3])]

Program code:

(* Int[1/Sqrt[a_+b_.*x_^3],x_Symbol] :=
  With[{q=Rt[b/a,3]},
  -Sqrt[2]*(1+Sqrt[3])*(1+Sqrt[3]+q*x)^2*Sqrt[(1+q^3*x^3)/(1+Sqrt[3]+q*x)^4]/(3^(1/4)*q*Sqrt[a+b*x^3])*
    EllipticF[ArcSin[(-1+Sqrt[3]-q*x)/(1+Sqrt[3]+q*x)],-7-4*Sqrt[3]]] /;
FreeQ[{a,b},x] && PosQ[a] *)

1:  ∫(1/(Sqrt[a+b (x^3)]))dx  when  a>0

Reference: G&R 3.139

Derivation: Piecewise constant extraction, integration by the Möbius substitution, and piecewise constant extraction

Basis: Let q->((((b/a)))^(1/3)), then (∂_x)(((((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))]))/(Sqrt[a+b (x^3)]))==0

Basis: (1/((((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))])))==-((2 (Sqrt[2-(Sqrt[3])]))/((3^(1/4)) q))Subst[(1/(Sqrt[(1-(x^2)) (7-4 (Sqrt[3])+(x^2))])),x,((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))] (∂_x)((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))

Basis: (∂_x)(((Sqrt[1-(x^2)]) (Sqrt[7-4 (Sqrt[3])+(x^2)]))/( (Sqrt[(1-(x^2)) (7-4 (Sqrt[3])+(x^2))])))==0

Note: If  a>0 ∧ b>0, then ArcSin[((-1+(Sqrt[3])-((((b/a)))^(1/3)) x)/(1+(Sqrt[3])+((((b/a)))^(1/3)) x))] is real when (Sqrt[a+b (x^3)]) is real.

Note: -7-4 (Sqrt[3])==-(((2+(Sqrt[3])))^2)

Warning: The result is discontinuous on the real line when x==-((1+(Sqrt[3]))/q) where q->((((b/a)))^(1/3)).

Rule 1.1.3.1.4.1.4.2.1.1: If  a>0, let q->(r/s)->((((b/a)))^(1/3)), then

∫(1/(Sqrt[a+b (x^3)]))dx  ⟶  (((((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))]))/(Sqrt[a+b (x^3)])) ∫(1/((((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))])))dx
  ⟶  -((2 (Sqrt[2-(Sqrt[3])]) (((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))]))/((3^(1/4)) q (Sqrt[a+b (x^3)]))) Subst[∫(1/( (Sqrt[(1-(x^2)) (7-4 (Sqrt[3])+(x^2))])))dx,x,((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))]
  ⟶  -((2 (Sqrt[2-(Sqrt[3])]) (1+q x) (Sqrt[((1-q x+(q^2) (x^2))/(((1+(Sqrt[3])+q x))^2))]))/((3^(1/4)) q (Sqrt[a+b (x^3)]) (Sqrt[((1+q x)/(((1+(Sqrt[3])+q x))^2))]))) Subst[∫(1/( (Sqrt[1-(x^2)]) (Sqrt[7-4 (Sqrt[3])+(x^2)])))dx,x,((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))]
  ⟶  -((2 (Sqrt[2+(Sqrt[3])]) (1+q x) (Sqrt[((1-q x+(q^2) (x^2))/(((1+(Sqrt[3])+q x))^2))]))/((3^(1/4)) q (Sqrt[a+b (x^3)]) (Sqrt[((1+q x)/(((1+(Sqrt[3])+q x))^2))]))) EllipticF[ArcSin[((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))],-7-4 (Sqrt[3])]
  ⟶  ((2 (Sqrt[2+(Sqrt[3])]) (s+r x) (Sqrt[(((s^2)-r s x+(r^2) (x^2))/((((1+(Sqrt[3])) s+r x))^2))]))/((3^(1/4)) r (Sqrt[a+b (x^3)]) (Sqrt[((s (s+r x))/((((1+(Sqrt[3])) s+r x))^2))]))) EllipticF[ArcSin[(((1-(Sqrt[3])) s+r x)/((1+(Sqrt[3])) s+r x))],-7-4 (Sqrt[3])]

Program code:

(* Int[1/Sqrt[a_+b_.*x_^3],x_Symbol] :=
  With[{q=Rt[a/b,3]},
  2*Sqrt[2+Sqrt[3]]*(q+x)*Sqrt[(q^2-q*x+x^2)/((1+Sqrt[3])*q+x)^2]/
    (3^(1/4)*Sqrt[a+b*x^3]*Sqrt[q*(q+x)/((1+Sqrt[3])*q+x)^2])*
    EllipticF[ArcSin[((1-Sqrt[3])*q+x)/((1+Sqrt[3])*q+x)],-7-4*Sqrt[3]]] /;
FreeQ[{a,b},x] && PosQ[a] && EqQ[b^2,1] *)

(* Int[1/Sqrt[a_+b_.*x_^3],x_Symbol] :=
  With[{q=Rt[b/a,3]},
  -2*Sqrt[2+Sqrt[3]]*(1+q*x)*Sqrt[(1-q*x+q^2*x^2)/(1+Sqrt[3]+q*x)^2]/
    (3^(1/4)*q*Sqrt[a+b*x^3]*Sqrt[(1+q*x)/(1+Sqrt[3]+q*x)^2])*
    EllipticF[ArcSin[(-1+Sqrt[3]-q*x)/(1+Sqrt[3]+q*x)],-7-4*Sqrt[3]]] /;
FreeQ[{a,b},x] && PosQ[a] *)

Int[1/Sqrt[a_+b_.*x_^3],x_Symbol] :=
  With[{r=Numer[Rt[b/a,3]], s=Denom[Rt[b/a,3]]},
  2*Sqrt[2+Sqrt[3]]*(s+r*x)*Sqrt[(s^2-r*s*x+r^2*x^2)/((1+Sqrt[3])*s+r*x)^2]/
    (3^(1/4)*r*Sqrt[a+b*x^3]*Sqrt[s*(s+r*x)/((1+Sqrt[3])*s+r*x)^2])*
    EllipticF[ArcSin[((1-Sqrt[3])*s+r*x)/((1+Sqrt[3])*s+r*x)],-7-4*Sqrt[3]]] /;
FreeQ[{a,b},x] && PosQ[a]

2:  ∫(1/(Sqrt[a+b (x^3)]))dx  when  a≯0

Reference: G&R 3.139

Derivation: Piecewise constant extraction, integration by the Möbius substitution, and piecewise constant extraction

Basis: Let q->((((b/a)))^(1/3)), then (∂_x)(((((1-(Sqrt[3])+q x))^2) (Sqrt[-((1+(q^3) (x^3))/(((1-(Sqrt[3])+q x))^4))]))/(Sqrt[a+b (x^3)]))==0

Basis: (1/((((1-(Sqrt[3])+q x))^2) (Sqrt[-((1+(q^3) (x^3))/(((1-(Sqrt[3])+q x))^4))])))==((2 (Sqrt[2-(Sqrt[3])]))/((3^(1/4)) q))Subst[(1/( (Sqrt[(1-(x^2))(1+(7-4 (Sqrt[3])) (x^2))]))),x,((1+(Sqrt[3])+q x)/(-1+(Sqrt[3])-q x))] (∂_x)((1+(Sqrt[3])+q x)/(-1+(Sqrt[3])-q x))

Basis: (∂_x)(((Sqrt[1-(x^2)]) (Sqrt[1+(7-4 (Sqrt[3])) (x^2)]))/( (Sqrt[(1-(x^2))(1+(7-4 (Sqrt[3])) (x^2))])))==0

Note: If  a<0 ∧ b<0, then ArcSin[((1+(Sqrt[3])+((((b/a)))^(1/3)) x)/(-1+(Sqrt[3])-((((b/a)))^(1/3)) x))] is real when (Sqrt[a+b (x^3)]) is real.

Warning: The result is discontinuous on the real line when x==-((1-(Sqrt[3]))/q) where q->((((b/a)))^(1/3)).

Rule 1.1.3.1.4.1.4.2.1: If a≯0, let q->(r/s)->((((b/a)))^(1/3)), then

∫(1/(Sqrt[a+b (x^3)]))dx  ⟶  (((((1-(Sqrt[3])+q x))^2) (Sqrt[-((1+(q^3) (x^3))/(((1-(Sqrt[3])+q x))^4))]))/(Sqrt[a+b (x^3)])) ∫(1/((((1-(Sqrt[3])+q x))^2) (Sqrt[-((1+(q^3) (x^3))/(((1-(Sqrt[3])+q x))^4))])))dx
  ⟶  ((2 (Sqrt[2-(Sqrt[3])]) (((1-(Sqrt[3])+q x))^2) (Sqrt[-((1+(q^3) (x^3))/(((1-(Sqrt[3])+q x))^4))]))/((3^(1/4)) q (Sqrt[a+b (x^3)]))) Subst[∫(1/( (Sqrt[(1-(x^2))(1+(7-4 (Sqrt[3])) (x^2))])))dx,x,((1+(Sqrt[3])+q x)/(-1+(Sqrt[3])-q x))]
  ⟶  -((2 (Sqrt[2-(Sqrt[3])]) (1+q x) (Sqrt[((1-q x+(q^2) (x^2))/(((1-(Sqrt[3])+q x))^2))]))/((3^(1/4)) q (Sqrt[a+b (x^3)]) (Sqrt[-((1+q x)/(((1-(Sqrt[3])+q x))^2))])))Subst[∫(1/((Sqrt[1-(x^2)]) (Sqrt[1+(7-4 (Sqrt[3])) (x^2)])))dx,x,((1+(Sqrt[3])+q x)/(-1+(Sqrt[3])-q x))]
  ⟶  -((2 (Sqrt[2-(Sqrt[3])]) (1+q x) (Sqrt[((1-q x+(q^2) (x^2))/(((1-(Sqrt[3])+q x))^2))]))/((3^(1/4)) q (Sqrt[a+b (x^3)]) (Sqrt[-((1+q x)/(((1-(Sqrt[3])+q x))^2))])))EllipticF[ArcSin[((1+(Sqrt[3])+q x)/(-1+(Sqrt[3])-q x))],-7+4 (Sqrt[3])]
  ⟶  ((2 (Sqrt[2-(Sqrt[3])]) (s+r x) (Sqrt[(((s^2)-r s x+(r^2) (x^2))/((((1-(Sqrt[3])) s+r x))^2))]))/((3^(1/4)) r (Sqrt[a+b (x^3)]) (Sqrt[-((s (s+r x))/((((1-(Sqrt[3])) s+r x))^2))]))) EllipticF[ArcSin[(((1+(Sqrt[3])) s+r x)/((1-(Sqrt[3])) s+r x))],-7+4 (Sqrt[3])]

Program code:

(* Int[1/Sqrt[a_+b_.*x_^3],x_Symbol] :=
  With[{q=Rt[a/b,3]},
  2*Sqrt[2-Sqrt[3]]*(q+x)*Sqrt[(q^2-q*x+x^2)/((1-Sqrt[3])*q+x)^2]/
    (3^(1/4)*Sqrt[a+b*x^3]*Sqrt[-q*(q+x)/((1-Sqrt[3])*q+x)^2])*
    EllipticF[ArcSin[((1+Sqrt[3])*q+x)/((1-Sqrt[3])*q+x)],-7+4*Sqrt[3]]] /;
FreeQ[{a,b},x] && NegQ[a] && EqQ[b^2,1] *)

(* Int[1/Sqrt[a_+b_.*x_^3],x_Symbol] :=
  With[{q=Rt[b/a,3]},
  -2*Sqrt[2-Sqrt[3]]*(1+q*x)*Sqrt[(1-q*x+q^2*x^2)/(1-Sqrt[3]+q*x)^2]/
    (3^(1/4)*q*Sqrt[a+b*x^3]*Sqrt[-(1+q*x)/(1-Sqrt[3]+q*x)^2])*
    EllipticF[ArcSin[(1+Sqrt[3]+q*x)/(-1+Sqrt[3]-q*x)],-7+4*Sqrt[3]]] /;
FreeQ[{a,b},x] && NegQ[a] *)

Int[1/Sqrt[a_+b_.*x_^3],x_Symbol] :=
  With[{r=Numer[Rt[b/a,3]], s=Denom[Rt[b/a,3]]},
  2*Sqrt[2-Sqrt[3]]*(s+r*x)*Sqrt[(s^2-r*s*x+r^2*x^2)/((1-Sqrt[3])*s+r*x)^2]/
    (3^(1/4)*r*Sqrt[a+b*x^3]*Sqrt[-s*(s+r*x)/((1-Sqrt[3])*s+r*x)^2])*
    EllipticF[ArcSin[((1+Sqrt[3])*s+r*x)/((1-Sqrt[3])*s+r*x)],-7+4*Sqrt[3]]] /;
FreeQ[{a,b},x] && NegQ[a]

3.  ∫(1/(Sqrt[a+b (x^4)]))dx

1:  ∫(1/(Sqrt[a+b (x^4)]))dx  when  (b/a)>0

Reference: G&R 3.166.1

Derivation: Piecewise constant extraction

Basis: (∂_x)(((1+(q^2) (x^2)) (Sqrt[((a+b (x^4))/(a (((1+(q^2) (x^2)))^2)))]))/(Sqrt[a+b (x^4)]))==0

Contributed by Martin Welz on 12 August 2016

Rule 1.1.3.1.4.1.4.3.1: If  (b/a)>0, let q->((((b/a)))^(1/4)), then

∫(1/(Sqrt[a+b (x^4)]))dx  ⟶  (((1+(q^2) (x^2)) (Sqrt[((a+b (x^4))/(a (((1+(q^2) (x^2)))^2)))]))/(Sqrt[a+b (x^4)])) ∫(1/((1+(q^2) (x^2)) (Sqrt[((a+b (x^4))/(a (((1+(q^2) (x^2)))^2)))])))dx
  ⟶  (((1+(q^2) (x^2)) (Sqrt[((a+b (x^4))/(a (((1+(q^2) (x^2)))^2)))]))/(2 q (Sqrt[a+b (x^4)]))) EllipticF[2 ArcTan[q x],(1/2)]

Program code:

Int[1/Sqrt[a_+b_.*x_^4],x_Symbol] :=
  With[{q=Rt[b/a,4]},
  (1+q^2*x^2)*Sqrt[(a+b*x^4)/(a*(1+q^2*x^2)^2)]/(2*q*Sqrt[a+b*x^4])*EllipticF[2*ArcTan[q*x],1/2]] /;
FreeQ[{a,b},x] && PosQ[b/a]

2.  ∫(1/(Sqrt[a+b (x^4)]))dx  when (b/a)≯0

1:  ∫(1/(Sqrt[a+b (x^4)]))dx  when  (b/a)≯0 ∧ a>0

Rule 1.1.3.1.4.1.4.3.2.1: If  (b/a)≯0 ∧ a>0, then

∫(1/(Sqrt[a+b (x^4)]))dx  ⟶  (1/((a^(1/4)) (((-b))^(1/4)))) EllipticF[ArcSin[(((((-b))^(1/4)) x)/(a^(1/4)))],-1]

Program code:

Int[1/Sqrt[a_+b_.*x_^4],x_Symbol] :=
  EllipticF[ArcSin[Rt[-b,4]*x/Rt[a,4]],-1]/(Rt[a,4]*Rt[-b,4]) /;
FreeQ[{a,b},x] && NegQ[b/a] && GtQ[a,0]

2:  ∫(1/(Sqrt[a+b (x^4)]))dx  when a<0 ∧ b>0

Reference: G&R 3.152.3+

Note: Not sure if the shorter rule is valid for all q.

Rule 1.1.3.1.4.1.4.3.2.2: If  a<0 ∧ b>0, let q->(Sqrt[-a b]), then

∫(1/(Sqrt[a+b (x^4)]))dx  ⟶  (((Sqrt[((a-q (x^2))/(a+q (x^2)))]) (Sqrt[((a+q (x^2))/q)]))/((Sqrt[2]) (Sqrt[a+b (x^4)]) (Sqrt[(a/(a+q (x^2)))]))) EllipticF[ArcSin[(x/(Sqrt[((a+q (x^2))/(2 q))]))],(1/2)]

∫(1/(Sqrt[a+b (x^4)]))dx  ⟶  (((Sqrt[-a+q (x^2)]) (Sqrt[((a+q (x^2))/q)]))/((Sqrt[2]) (Sqrt[-a]) (Sqrt[a+b (x^4)]))) EllipticF[ArcSin[(x/(Sqrt[((a+q (x^2))/(2 q))]))],(1/2)]

Program code:

Int[1/Sqrt[a_+b_.*x_^4],x_Symbol] :=
  With[{q=Rt[-a*b,2]},
  Sqrt[-a+q*x^2]*Sqrt[(a+q*x^2)/q]/(Sqrt[2]*Sqrt[-a]*Sqrt[a+b*x^4])*
    EllipticF[ArcSin[x/Sqrt[(a+q*x^2)/(2*q)]],1/2] /;
  IntegerQ[q]] /;
FreeQ[{a,b},x] && LtQ[a,0] && GtQ[b,0]

Int[1/Sqrt[a_+b_.*x_^4],x_Symbol] :=
  With[{q=Rt[-a*b,2]},
  Sqrt[(a-q*x^2)/(a+q*x^2)]*Sqrt[(a+q*x^2)/q]/(Sqrt[2]*Sqrt[a+b*x^4]*Sqrt[a/(a+q*x^2)])*
    EllipticF[ArcSin[x/Sqrt[(a+q*x^2)/(2*q)]],1/2]] /;
FreeQ[{a,b},x] && LtQ[a,0] && GtQ[b,0]

3:  ∫(1/(Sqrt[a+b (x^4)]))dx  when  (b/a)≯0 ∧ a≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[1+((b (x^4))/a)])/(Sqrt[a+b (x^4)]))==0

Rule 1.1.3.1.4.1.4.3.2.3: If  (b/a)≯0 ∧ a≯0, then

∫(1/(Sqrt[a+b (x^4)]))dx  ⟶  ((Sqrt[1+((b (x^4))/a)])/(Sqrt[a+b (x^4)]))∫(1/(Sqrt[1+((b (x^4))/a)]))dx

Program code:

Int[1/Sqrt[a_+b_.*x_^4],x_Symbol] :=
  Sqrt[1+b*x^4/a]/Sqrt[a+b*x^4]*Int[1/Sqrt[1+b*x^4/a],x] /;
FreeQ[{a,b},x] && NegQ[b/a] && Not[GtQ[a,0]]

4:  ∫(1/(Sqrt[a+b (x^6)]))dx

Derivation: Piecewise constant extraction and integration by the substitution

Basis: Let q->((((b/a)))^(1/3)), then (∂_x)((x (1+q (x^2)) (Sqrt[((1-q (x^2)+(q^2) (x^4))/(((1+(1+(Sqrt[3])) q (x^2)))^2))]))/((Sqrt[a+b (x^6)]) (Sqrt[((q (x^2) (1+q (x^2)))/(((1+(1+(Sqrt[3])) q (x^2)))^2))])))==0

Basis: ((Sqrt[((q (x^2) (1+q (x^2)))/(((1+(1+(Sqrt[3])) q (x^2)))^2))])/(x (1+q (x^2)) (Sqrt[((1-q (x^2)+(q^2) (x^4))/(((1+(1+(Sqrt[3])) q (x^2)))^2))])))==-(1/(3^(1/4))) Subst[(1/((Sqrt[1-(x^2)]) (Sqrt[2-(Sqrt[3])+(2+(Sqrt[3])) (x^2)]))),x,((1+(1-(Sqrt[3])) q (x^2))/(1+(1+(Sqrt[3])) q (x^2)))] (∂_x)((1+(1-(Sqrt[3])) q (x^2))/(1+(1+(Sqrt[3])) q (x^2)))

Rule 1.1.3.1.4.1.4.4: Let q->(r/s)->((((b/a)))^(1/3)), then

∫(1/(Sqrt[a+b (x^6)]))dx  ⟶  ((x (1+q (x^2)) (Sqrt[((1-q (x^2)+(q^2) (x^4))/(((1+(1+(Sqrt[3])) q (x^2)))^2))]))/((Sqrt[a+b (x^6)]) (Sqrt[((q (x^2) (1+q (x^2)))/(((1+(1+(Sqrt[3])) q (x^2)))^2))]))) ∫((Sqrt[((q (x^2) (1+q (x^2)))/(((1+(1+(Sqrt[3])) q (x^2)))^2))])/(x (1+q (x^2)) (Sqrt[((1-q (x^2)+(q^2) (x^4))/(((1+(1+(Sqrt[3])) q (x^2)))^2))])))dx
  ⟶  -((x (1+q (x^2)) (Sqrt[((1-q (x^2)+(q^2) (x^4))/(((1+(1+(Sqrt[3])) q (x^2)))^2))]))/((3^(1/4)) (Sqrt[a+b (x^6)]) (Sqrt[((q (x^2) (1+q (x^2)))/(((1+(1+(Sqrt[3])) q (x^2)))^2))]))) Subst[∫(1/((Sqrt[1-(x^2)]) (Sqrt[2-(Sqrt[3])+(2+(Sqrt[3])) (x^2)])))dx,x,((1+(1-(Sqrt[3])) q (x^2))/(1+(1+(Sqrt[3])) q (x^2)))]
  ⟶  ((x (1+q (x^2)) (Sqrt[((1-q (x^2)+(q^2) (x^4))/(((1+(1+(Sqrt[3])) q (x^2)))^2))]))/(2 (3^(1/4)) (Sqrt[a+b (x^6)]) (Sqrt[((q (x^2) (1+q (x^2)))/(((1+(1+(Sqrt[3])) q (x^2)))^2))]))) EllipticF[ArcCos[((1+(1-(Sqrt[3])) q (x^2))/(1+(1+(Sqrt[3])) q (x^2)))],((2+(Sqrt[3]))/4)]
  ⟶  ((x (s+r (x^2)) (Sqrt[(((s^2)-r s (x^2)+(r^2) (x^4))/(((s+(1+(Sqrt[3])) r (x^2)))^2))]))/(2 (3^(1/4)) s (Sqrt[a+b (x^6)]) (Sqrt[((r (x^2) (s+r (x^2)))/(((s+(1+(Sqrt[3])) r (x^2)))^2))]))) EllipticF[ArcCos[((s+(1-(Sqrt[3])) r (x^2))/(s+(1+(Sqrt[3])) r (x^2)))],((2+(Sqrt[3]))/4)]

Program code:

Int[1/Sqrt[a_+b_.*x_^6],x_Symbol] :=
  With[{r=Numer[Rt[b/a,3]], s=Denom[Rt[b/a,3]]},
  x*(s+r*x^2)*Sqrt[(s^2-r*s*x^2+r^2*x^4)/(s+(1+Sqrt[3])*r*x^2)^2]/
    (2*3^(1/4)*s*Sqrt[a+b*x^6]*Sqrt[r*x^2*(s+r*x^2)/(s+(1+Sqrt[3])*r*x^2)^2])*
    EllipticF[ArcCos[(s+(1-Sqrt[3])*r*x^2)/(s+(1+Sqrt[3])*r*x^2)],(2+Sqrt[3])/4]] /;
FreeQ[{a,b},x]

5:  ∫(1/(Sqrt[a+b (x^8)]))dx

Derivation: Algebraic expansion

Basis: (1/(Sqrt[a+b (x^8)]))==((1-((((b/a)))^(1/4)) (x^2))/(2 (Sqrt[a+b (x^8)])))+((1+((((b/a)))^(1/4)) (x^2))/(2 (Sqrt[a+b (x^8)])))

Note: Integrands are of the form ((c+d (x^2))/(Sqrt[a+b (x^8)])) where b (c^4)-a (d^4)==0 for which there is a terminal rule.

Rule 1.1.3.1.4.1.4.5:

∫(1/(Sqrt[a+b (x^8)]))dx  ⟶  (1/2) ∫((1-((((b/a)))^(1/4)) (x^2))/(Sqrt[a+b (x^8)]))dx+(1/2) ∫((1+((((b/a)))^(1/4)) (x^2))/(Sqrt[a+b (x^8)]))dx

Program code:

Int[1/Sqrt[a_+b_.*x_^8],x_Symbol] :=
  1/2*Int[(1-Rt[b/a,4]*x^2)/Sqrt[a+b*x^8],x] + 
  1/2*Int[(1+Rt[b/a,4]*x^2)/Sqrt[a+b*x^8],x] /;
FreeQ[{a,b},x]

5.  ∫(1/(((a+b (x^2)))^(1/4)))dx

1.  ∫(1/(((a+b (x^2)))^(1/4)))dx  when  a≮0

1.  ∫(1/(((a+b (x^2)))^(1/4)))dx  when  a>0

1:  ∫(1/(((a+b (x^2)))^(1/4)))dx  when  a>0 ∧ (b/a)>0

Reference: G&R 2.110.1, CRC 88b

Derivation: Binomial recurrence 1b

Rule 1.1.3.1.4.1.5.1.1.1: If a>0 ∧ (b/a)>0, then

∫(1/(((a+b (x^2)))^(1/4)))dx  ⟶  ((2 x)/(((a+b (x^2)))^(1/4)))-a ∫(1/(((a+b (x^2)))^(5/4)))dx

Program code:

Int[1/(a_+b_.*x_^2)^(1/4),x_Symbol] :=
  2*x/(a+b*x^2)^(1/4) - a*Int[1/(a+b*x^2)^(5/4),x] /;
FreeQ[{a,b},x] && GtQ[a,0] && PosQ[b/a]

2:  ∫(1/(((a+b (x^2)))^(1/4)))dx  when  a>0 ∧ (b/a)≯0

Rule 1.1.3.1.4.1.5.1.1.2: If  a>0 ∧ (b/a)≯0, then

∫(1/(((a+b (x^2)))^(1/4)))dx  ⟶  (2/((a^(1/4)) (Sqrt[-(b/a)]))) EllipticE[(1/2) ArcSin[(Sqrt[-(b/a)]) x],2]

Program code:

Int[1/(a_+b_.*x_^2)^(1/4),x_Symbol] :=
  2/(a^(1/4)*Rt[-b/a,2])*EllipticE[1/2*ArcSin[Rt[-b/a,2]*x],2] /;
FreeQ[{a,b},x] && GtQ[a,0] && NegQ[b/a]

2:  ∫(1/(((a+b (x^2)))^(1/4)))dx  when  a≮0

Derivation: Piecewise constant extraction

Basis: (∂_x)((((1+((b (x^2))/a)))^(1/4))/(((a+b (x^2)))^(1/4)))==0

Rule 1.1.3.1.4.1.5.1.2: If  a≮0, then

∫(1/(((a+b (x^2)))^(1/4)))dx  ⟶  ((((1+((b (x^2))/a)))^(1/4))/(((a+b (x^2)))^(1/4)))∫(1/(((1+((b (x^2))/a)))^(1/4)))dx

Program code:

Int[1/(a_+b_.*x_^2)^(1/4),x_Symbol] :=
  (1+b*x^2/a)^(1/4)/(a+b*x^2)^(1/4)*Int[1/(1+b*x^2/a)^(1/4),x] /;
FreeQ[{a,b},x] && PosQ[a]

2:  ∫(1/(((a+b (x^2)))^(1/4)))dx  when a≯0

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[-((b (x^2))/a)])/x)==0

Basis: (x/((Sqrt[-((b (x^2))/a)]) (((a+b (x^2)))^(1/4))))==(2/b) Subst[((x^2)/(Sqrt[1-((x^4)/a)])),x,(((a+b (x^2)))^(1/4))] (∂_x)(((a+b (x^2)))^(1/4))

Rule 1.1.3.1.4.1.5.2: If  a≯0, then

∫(1/(((a+b (x^2)))^(1/4)))dx  ⟶  ((Sqrt[-((b (x^2))/a)])/x) ∫(x/((Sqrt[-((b (x^2))/a)]) (((a+b (x^2)))^(1/4))))dx  ⟶  ((2 (Sqrt[-((b (x^2))/a)]))/(b x)) Subst[∫((x^2)/(Sqrt[1-((x^4)/a)]))dx,x,(((a+b (x^2)))^(1/4))]

Program code:

Int[1/(a_+b_.*x_^2)^(1/4),x_Symbol] :=
  2*Sqrt[-b*x^2/a]/(b*x)*Subst[Int[x^2/Sqrt[1-x^4/a],x],x,(a+b*x^2)^(1/4)] /;
FreeQ[{a,b},x] && NegQ[a]

6.  ∫(1/(((a+b (x^2)))^(3/4)))dx

1.  ∫(1/(((a+b (x^2)))^(3/4)))dx  when  a≮0

1.  ∫(1/(((a+b (x^2)))^(3/4)))dx  when  a>0

1:  ∫(1/(((a+b (x^2)))^(3/4)))dx  when  a>0 ∧ (b/a)>0

Contributed by Martin Welz on 7 August 2016

Rule 1.1.3.1.4.1.6.1.1.1: If  a>0 ∧ (b/a)>0, then

∫(1/(((a+b (x^2)))^(3/4)))dx  ⟶  (2/((a^(3/4)) (Sqrt[(b/a)]))) EllipticF[(1/2) ArcTan[(Sqrt[(b/a)]) x],2]

Program code:

Int[1/(a_+b_.*x_^2)^(3/4),x_Symbol] :=
  2/(a^(3/4)*Rt[b/a,2])*EllipticF[1/2*ArcTan[Rt[b/a,2]*x],2] /;
FreeQ[{a,b},x] && GtQ[a,0] && PosQ[b/a]

2:  ∫(1/(((a+b (x^2)))^(3/4)))dx  when  a>0 ∧ (b/a)≯0

∫(1/(((a+b (x^2)))^(3/4)))dx  ⟶  (2/((a^(3/4)) (Sqrt[-(b/a)]))) EllipticF[(1/2) ArcSin[(Sqrt[-(b/a)]) x],2]

Rule 1.1.3.1.4.1.6.1.1.2: If  a>0 ∧ (b/a)≯0, then

Program code:

Int[1/(a_+b_.*x_^2)^(3/4),x_Symbol] :=
  2/(a^(3/4)*Rt[-b/a,2])*EllipticF[1/2*ArcSin[Rt[-b/a,2]*x],2] /;
FreeQ[{a,b},x] && GtQ[a,0] && NegQ[b/a]

2:  ∫(1/(((a+b (x^2)))^(3/4)))dx  when  a≮0

Derivation: Piecewise constant extraction

Basis: (∂_x)((((1+((b (x^2))/a)))^(3/4))/(((a+b (x^2)))^(3/4)))==0

Rule 1.1.3.1.4.1.6.1.2: If  a≮0, then

∫(1/(((a+b (x^2)))^(3/4)))dx  ⟶  ((((1+((b (x^2))/a)))^(3/4))/(((a+b (x^2)))^(3/4)))∫(1/(((1+((b (x^2))/a)))^(3/4)))dx

Program code:

Int[1/(a_+b_.*x_^2)^(3/4),x_Symbol] :=
  (1+b*x^2/a)^(3/4)/(a+b*x^2)^(3/4)*Int[1/(1+b*x^2/a)^(3/4),x] /;
FreeQ[{a,b},x] && PosQ[a]

2:  ∫(1/(((a+b (x^2)))^(3/4)))dx  when a<0

Derivation: Piecewise constant extranction and integration by substitution

Basis: (∂_x)((Sqrt[-((b (x^2))/a)])/x)==0

Basis: (x/((Sqrt[-((b (x^2))/a)]) (((a+b (x^2)))^(3/4))))==(2/b) Subst[(1/(Sqrt[1-((x^4)/a)])),x,(((a+b (x^2)))^(1/4))] (∂_x)(((a+b (x^2)))^(1/4))

Rule 1.1.3.1.4.1.6.2: If  a<0, then

∫(1/(((a+b (x^2)))^(3/4)))dx  ⟶  ((Sqrt[-((b (x^2))/a)])/x) ∫(x/((Sqrt[-((b (x^2))/a)]) (((a+b (x^2)))^(3/4))))dx  ⟶  ((2 (Sqrt[-((b (x^2))/a)]))/(b x)) Subst[∫(1/(Sqrt[1-((x^4)/a)]))dx,x,(((a+b (x^2)))^(1/4))]

Program code:

Int[1/(a_+b_.*x_^2)^(3/4),x_Symbol] :=
  2*Sqrt[-b*x^2/a]/(b*x)*Subst[Int[1/Sqrt[1-x^4/a],x],x,(a+b*x^2)^(1/4)] /;
FreeQ[{a,b},x] && NegQ[a]

7:  ∫(1/(((a+b (x^2)))^(1/3)))dx

Derivation: Integration by substitution and piecewise constant extraction

Basis: (1/(((a+b (x^2)))^(1/3)))==((3 (Sqrt[b (x^2)]))/(2 b x)) Subst[(x/(Sqrt[-a+(x^3)])),x,(((a+b (x^2)))^(1/3))] (∂_x)(((a+b (x^2)))^(1/3))

Basis: (∂_x)((Sqrt[b (x^2)])/x)==0

Rule 1.1.3.1.4.1.7:

∫(1/(((a+b (x^2)))^(1/3)))dx  ⟶  ((3 (Sqrt[b (x^2)]))/(2 b x)) Subst[∫(x/(Sqrt[-a+(x^3)]))dx,x,(((a+b (x^2)))^(1/3))]

Program code:

Int[1/(a_+b_.*x_^2)^(1/3),x_Symbol] :=
  3*Sqrt[b*x^2]/(2*b*x)*Subst[Int[x/Sqrt[-a+x^3],x],x,(a+b*x^2)^(1/3)] /;
FreeQ[{a,b},x]

8:  ∫(1/(((a+b (x^2)))^(2/3)))dx

Derivation: Integration by substitution and piecewise constant extraction

Basis: (1/(((a+b (x^2)))^(2/3)))==((3 (Sqrt[b (x^2)]))/(2 b x)) Subst[(1/(Sqrt[-a+(x^3)])),x,(((a+b (x^2)))^(1/3))] (∂_x)(((a+b (x^2)))^(1/3))

Basis: (∂_x)((Sqrt[b (x^2)])/x)==0

Rule 1.1.3.1.4.1.8:

∫(1/(((a+b (x^2)))^(2/3)))dx  ⟶  ((3 (Sqrt[b (x^2)]))/(2 b x)) Subst[∫(1/(Sqrt[-a+(x^3)]))dx,x,(((a+b (x^2)))^(1/3))]

Program code:

Int[1/(a_+b_.*x_^2)^(2/3),x_Symbol] :=
  3*Sqrt[b*x^2]/(2*b*x)*Subst[Int[1/Sqrt[-a+x^3],x],x,(a+b*x^2)^(1/3)] /;
FreeQ[{a,b},x]

9:  ∫(1/(((a+b (x^4)))^(3/4)))dx

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^3) (((1+(a/(b (x^4)))))^(3/4)))/(((a+b (x^4)))^(3/4)))==0

Rule 1.1.3.1.4.1.9:

∫(1/(((a+b (x^4)))^(3/4)))dx  ⟶  (((x^3) (((1+(a/(b (x^4)))))^(3/4)))/(((a+b (x^4)))^(3/4))) ∫(1/((x^3) (((1+(a/(b (x^4)))))^(3/4))))dx

Program code:

Int[1/(a_+b_.*x_^4)^(3/4),x_Symbol] :=
  x^3*(1+a/(b*x^4))^(3/4)/(a+b*x^4)^(3/4)*Int[1/(x^3*(1+a/(b*x^4))^(3/4)),x] /;
FreeQ[{a,b},x]

10:  ∫(1/(((a+b (x^2)))^(1/6)))dx

Derivation: Binomial recurrence 2b

Rule 1.1.3.1.4.1.10:

∫(1/(((a+b (x^2)))^(1/6)))dx  ⟶  ((3 x)/(2 (((a+b (x^2)))^(1/6))))-(a/2)∫(1/(((a+b (x^2)))^(7/6)))dx

Program code:

Int[1/(a_+b_.*x_^2)^(1/6),x_Symbol] :=
  3*x/(2*(a+b*x^2)^(1/6)) - a/2*Int[1/(a+b*x^2)^(7/6),x] /;
FreeQ[{a,b},x]

11:  ∫(1/(((a+b (x^3)))^(1/3)))dx

Rule 1.1.3.1.4.1.11:

∫(1/(((a+b (x^3)))^(1/3)))dx  ⟶  ((ArcTan[((1+((2 (b^(1/3)) x)/(((a+b (x^3)))^(1/3))))/(Sqrt[3]))])/((Sqrt[3]) (b^(1/3))))-((Log[(((a+b (x^3)))^(1/3))-(b^(1/3)) x])/(2 (b^(1/3))))

Program code:

Int[1/(a_+b_.*x_^3)^(1/3),x_Symbol] :=
  ArcTan[(1+2*Rt[b,3]*x/(a+b*x^3)^(1/3))/Sqrt[3]]/(Sqrt[3]*Rt[b,3]) - Log[(a+b*x^3)^(1/3)-Rt[b,3]*x]/(2*Rt[b,3]) /;
FreeQ[{a,b},x]

12.  ∫(((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ Denominator[p+(1/n)]<Denominator[p]

1:  ∫(((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ p+(1/n)∈ℤ

Derivation: Integration by substitution

Basis:  If  n∈(SuperPlus[ℤ])∧ p+(1/n)∈ℤ, then (((a+b (x^n)))^p)==(a^(p+(1/n))) Subst[(1/(((1-b (x^n)))^(p+(1/n)+1))),x,(x/(((a+b (x^n)))^(1/n)))] (∂_x)(x/(((a+b (x^n)))^(1/n)))

Rule 1.1.3.1.4.1.12.1: If  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ p+(1/n)∈ℤ, then

∫(((a+b (x^n)))^p)dx  ⟶  (a^(p+(1/n)))Subst[∫(1/(((1-b (x^n)))^(p+(1/n)+1)))dx,x,(x/(((a+b (x^n)))^(1/n)))]

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  a^(p+1/n)*Subst[Int[1/(1-b*x^n)^(p+1/n+1),x],x,x/(a+b*x^n)^(1/n)] /;
FreeQ[{a,b},x] && IGtQ[n,0] && LtQ[-1,p,0] && NeQ[p,-1/2] && IntegerQ[p+1/n]

2:  ∫(((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ Denominator[p+(1/n)]<Denominator[p]

Derivation: Piecewise constant extraction and integration by substitution

Basis:  (∂_x)(((((a/(a+b (x^n)))))^(p+(1/n))) (((a+b (x^n)))^(p+(1/n))))==0

Basis:  If  n∈ℤ, then (1/(((((a/(a+b (x^n)))))^(p+(1/n))) (((a+b (x^n)))^(1/n))))==Subst[(1/(((1-b (x^n)))^(p+(1/n)+1))),x,(x/(((a+b (x^n)))^(1/n)))] (∂_x)(x/(((a+b (x^n)))^(1/n)))

Rule 1.1.3.1.4.1.12.2: If  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ Denominator[p+(1/n)]<Denominator[p], then

∫(((a+b (x^n)))^p)dx  ⟶  ((((a/(a+b (x^n)))))^(p+(1/n))) (((a+b (x^n)))^(p+(1/n)))∫(1/(((((a/(a+b (x^n)))))^(p+(1/n))) (((a+b (x^n)))^(1/n))))dx
  ⟶  ((((a/(a+b (x^n)))))^(p+(1/n))) (((a+b (x^n)))^(p+(1/n)))Subst[∫(1/(((1-b (x^n)))^(p+(1/n)+1)))dx,x,(x/(((a+b (x^n)))^(1/n)))]

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  (a/(a+b*x^n))^(p+1/n)*(a+b*x^n)^(p+1/n)*Subst[Int[1/(1-b*x^n)^(p+1/n+1),x],x,x/(a+b*x^n)^(1/n)] /;
FreeQ[{a,b},x] && IGtQ[n,0] && LtQ[-1,p,0] && NeQ[p,-1/2] && LtQ[Denominator[p+1/n],Denominator[p]]

2:  ∫(((a+b (x^n)))^p)dx  when  n∈(SuperMinus[ℤ])

Derivation: Integration by substitution

Basis: If  n∈ℤ, then F[(x^n)]==-Subst[((F[(x^(-n))])/(x^2)),x,(1/x)] (∂_x)(1/x)

Rule 1.1.3.1.4.2: If  n∈(SuperMinus[ℤ]), then

∫(((a+b (x^n)))^p)dx  ⟶  -Subst[∫((((a+b (x^(-n))))^p)/(x^2))dx,x,(1/x)]

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  -Subst[Int[(a+b*x^(-n))^p/x^2,x],x,1/x] /;
FreeQ[{a,b,p},x] && ILtQ[n,0]

5:  ∫(((a+b (x^n)))^p)dx  when  n∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then F[(x^n)]==k Subst[(x^(k-1))F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule 1.1.3.1.5: If  n∈𝔽, let k->Denominator[n], then

∫(((a+b (x^n)))^p)dx  ⟶  k Subst[∫(x^(k-1))(((a+b (x^(k n))))^p)dx,x,(x^(1/k))]

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*x^(k*n))^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,p},x] && FractionQ[n]

6:  ∫(((a+b (x^n)))^p)dx  when  p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.1.3.1.6: If  p∈(SuperPlus[ℤ]), then

∫(((a+b (x^n)))^p)dx  ⟶  ∫ExpandIntegrand[(((a+b (x^n)))^p),x]dx

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*x^n)^p,x],x] /;
FreeQ[{a,b,n},x] && IGtQ[p,0]

H.  ∫(((a+b (x^n)))^p)dx  when p∉(SuperPlus[ℤ])∧ (1/n)∉ℤ ∧ (1/n)+p∉(SuperMinus[ℤ])

1:  ∫(((a+b (x^n)))^p)dx  when  p∉(SuperPlus[ℤ])∧ (1/n)∉ℤ ∧ (1/n)+p∉(SuperMinus[ℤ])∧ (p∈(SuperMinus[ℤ]) ∨ a>0)

Note: If  t==r+1 ∧ r∈ℤ, then Hypergeometric2F1[r,s,t,z]==Hypergeometric2F1[s,r,t,z] are elementary or undefined.

Rule 1.1.3.1.7.1: If  p∉(SuperPlus[ℤ])∧ (1/n)∉ℤ ∧ (1/n)+p∉(SuperMinus[ℤ])∧ (p∈(SuperMinus[ℤ]) ∨ a>0), then

∫(((a+b (x^n)))^p)dx  ⟶  (a^p)x Hypergeometric2F1[-p,(1/n),(1/n)+1,-((b (x^n))/a)]

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  a^p*x*Hypergeometric2F1[-p,1/n,1/n+1,-b*x^n/a] /;
FreeQ[{a,b,n,p},x] && Not[IGtQ[p,0]] && Not[IntegerQ[1/n]] && Not[ILtQ[Simplify[1/n+p],0]] && 
  (IntegerQ[p] || GtQ[a,0])

x:  ∫(((a+b (x^n)))^p)dx  when  p∉(SuperPlus[ℤ])∧ (1/n)∉ℤ ∧ (1/n)+p∉(SuperMinus[ℤ])∧ ¬(p∈(SuperMinus[ℤ]) ∨ a>0)

Note: If  r==1 ∧(s∈ℤ ∨ t∈ℤ), then Hypergeometric2F1[r,s,t,z]==Hypergeometric2F1[s,r,t,z] are undefined or can be expressed in elementary form.

Note: Mathematica has a hard time simplifying the derivative of the following antiderivative to the integrand, so the following, more complicated, but easily differentiated, rule is used instead.

Rule 1.1.3.1.7.x: If  p∉(SuperPlus[ℤ])∧ (1/n)∉ℤ ∧ (1/n)+p∉(SuperMinus[ℤ])∧ ¬(p∈(SuperMinus[ℤ]) ∨ a>0), then

∫(((a+b (x^n)))^p)dx  ⟶  ((x (((a+b (x^n)))^(p+1)))/a)Hypergeometric2F1[1,(1/n)+p+1,(1/n)+1,-((b (x^n))/a)]

Program code:

(* Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  x*(a+b*x^n)^(p+1)/a*Hypergeometric2F1[1,1/n+p+1,1/n+1,-b*x^n/a] /;
FreeQ[{a,b,n,p},x] && Not[IGtQ[p,0]] && Not[IntegerQ[1/n]] && Not[ILtQ[Simplify[1/n+p],0]] && 
  Not[IntegerQ[p] || GtQ[a,0]] *)

2:  ∫(((a+b (x^n)))^p)dx  when  p∉(SuperPlus[ℤ])∧ (1/n)∉ℤ ∧ (1/n)+p∉(SuperMinus[ℤ])∧ ¬(p∈(SuperMinus[ℤ]) ∨ a>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((a+b (x^n)))^p)/(((1+((b (x^n))/a)))^p))==0

Rule 1.1.3.1.7.2: If  p∉(SuperPlus[ℤ])∧ (1/n)∉ℤ ∧ (1/n)+p∉(SuperMinus[ℤ])∧ ¬(p∈(SuperMinus[ℤ]) ∨ a>0), then

∫(((a+b (x^n)))^p)dx  ⟶  (((a^(IntPart[p])) (((a+b (x^n)))^(FracPart[p])))/(((1+((b (x^n))/a)))^(FracPart[p])))∫(((1+((b (x^n))/a)))^p)dx

Program code:

Int[(a_+b_.*x_^n_)^p_,x_Symbol] :=
  a^IntPart[p]*(a+b*x^n)^FracPart[p]/(1+b*x^n/a)^FracPart[p]*Int[(1+b*x^n/a)^p,x] /;
FreeQ[{a,b,n,p},x] && Not[IGtQ[p,0]] && Not[IntegerQ[1/n]] && 
  Not[ILtQ[Simplify[1/n+p],0]] && Not[IntegerQ[p] || GtQ[a,0]]

S:  ∫(((a+b (v^n)))^p)dx  when  v==c+d x

Derivation: Integration by substitution

Rule 1.1.3.1.S: If  v==c+d x, then

∫(((a+b (v^n)))^p)dx  ⟶  (1/d)Subst[∫(((a+b (x^n)))^p)dx,x,v]

Program code:

Int[(a_.+b_.*v_^n_)^p_,x_Symbol] :=
  1/Coefficient[v,x,1]*Subst[Int[(a+b*x^n)^p,x],x,v] /;
FreeQ[{a,b,n,p},x] && LinearQ[v,x] && NeQ[v,x]

Rules for integrands of the form((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)

1:  ∫((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧(p∈ℤ ∨ ((Subscript[a, 1])>0 ∧ (Subscript[a, 2])>0))

Derivation: Algebraic simplification

Basis: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧(p∈ℤ ∨ ((Subscript[a, 1])>0 ∧ (Subscript[a, 2])>0)), then ((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)==((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^(2 n))))^p)

Rule: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧(p∈ℤ ∨ ((Subscript[a, 1])>0 ∧ (Subscript[a, 2])>0)), then

∫((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  ⟶   ∫((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^(2 n))))^p)dx

Program code:

Int[(a1_.+b1_.*x_^n_)^p_.*(a2_.+b2_.*x_^n_)^p_.,x_Symbol] :=
  Int[(a1*a2+b1*b2*x^(2*n))^p,x] /;
FreeQ[{a1,b1,a2,b2,n,p},x] && EqQ[a2*b1+a1*b2,0] && (IntegerQ[p] || GtQ[a1,0] && GtQ[a2,0])

2.  ∫((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ p∉ℤ

1:  ∫((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ p∉ℤ ∧ n∈(SuperPlus[ℤ])∧ p>0

Reference: G&R 2.110.1, CRC 88b

Derivation: Binomial recurrence 1b

Derivation: Inverted integration by parts

Note: If  n∈(SuperPlus[ℤ])∧ p>0, then n p+1≠0.

Rule 1.1.3.1.4.1.1.2: If  n∈(SuperPlus[ℤ])∧ p>0, then

∫(((a+b (x^n)))^p)dx  ⟶  ((x (((a+b (x^n)))^p))/(n p+1))+((a n p)/(n p+1))∫(((a+b (x^n)))^(p-1))dx

Program code:

Int[(a1_+b1_.*x_^n_.)^p_.*(a2_+b2_.*x_^n_.)^p_.,x_Symbol] :=
  x*(a1+b1*x^n)^p*(a2+b2*x^n)^p/(2*n*p+1) + 
  2*a1*a2*n*p/(2*n*p+1)*Int[(a1+b1*x^n)^(p-1)*(a2+b2*x^n)^(p-1),x] /;
FreeQ[{a1,b1,a2,b2},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && GtQ[p,0] && (IntegerQ[2*p] || Denominator[p+1/n]<Denominator[p])

2:  ∫((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ p∉ℤ ∧ n∈(SuperPlus[ℤ])∧ p<-1

Reference: G&R 2.110.2, CRC 88d

Derivation: Binomial recurrence 2b

Derivation: Integration by parts

Basis: (((a+b (x^n)))^p)==(x^(n (p+1)+1))((((a+b (x^n)))^p)/(x^(n (p+1)+1)))

Basis: ∫((((a+b (x^n)))^p)/(x^(n (p+1)+1)))dx==-((((a+b (x^n)))^(p+1))/((x^(n (p+1)))a n (p+1)))

Rule 1.1.3.1.4.1.2: If  n∈(SuperPlus[ℤ])∧ p<-1, then

∫(((a+b (x^n)))^p)dx  ⟶  -((x (((a+b (x^n)))^(p+1)))/(a n (p+1)))+((n(p+1)+1)/(a n (p+1)))∫(((a+b (x^n)))^(p+1))dx

Program code:

Int[(a1_+b1_.*x_^n_.)^p_*(a2_+b2_.*x_^n_.)^p_,x_Symbol] :=
  -x*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(2*a1*a2*n*(p+1)) + 
  (2*n*(p+1)+1)/(2*a1*a2*n*(p+1))*Int[(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1),x] /;
FreeQ[{a1,b1,a2,b2},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && LtQ[p,-1] && (IntegerQ[2*p] || Denominator[p+1/n]<Denominator[p])

3:  ∫((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ p∉ℤ ∧ n∈(SuperMinus[ℤ])

Derivation: Integration by substitution

Basis: If  n∈ℤ, then F[(x^n)]==-Subst[((F[(x^(-n))])/(x^2)),x,(1/x)] (∂_x)(1/x)

Rule 1.1.3.1.4.2: If  n∈(SuperMinus[ℤ]), then

∫(((a+b (x^n)))^p)dx  ⟶  -Subst[∫((((a+b (x^(-n))))^p)/(x^2))dx,x,(1/x)]

Program code:

Int[(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  -Subst[Int[(a1+b1*x^(-n))^p*(a2+b2*x^(-n))^p/x^2,x],x,1/x] /;
FreeQ[{a1,b1,a2,b2,p},x] && EqQ[a2*b1+a1*b2,0] && ILtQ[2*n,0]

4:  ∫((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ p∉ℤ ∧ n∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then F[(x^n)]==k Subst[(x^(k-1))F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule 1.1.3.1.5: If  n∉ℤ ∧ n∈𝔽, let k=Denominator[n], then

∫(((a+b (x^n)))^p)dx  ⟶  k Subst[∫(x^(k-1))(((a+b (x^(k n))))^p)dx,x,(x^(1/k))]

Program code:

Int[(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  With[{k=Denominator[2*n]},
  k*Subst[Int[x^(k-1)*(a1+b1*x^(k*n))^p*(a2+b2*x^(k*n))^p,x],x,x^(1/k)]] /;
FreeQ[{a1,b1,a2,b2,p},x] && EqQ[a2*b1+a1*b2,0] && FractionQ[2*n]

5:  ∫((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0, then (∂_x)((((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p))/((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^(2 n))))^p))==0

Rule: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ p∉ℤ, then

∫((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  ⟶  ((((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^(FracPart[p])) ((((Subscript[a, 2])+(Subscript[b, 2]) x))^(FracPart[p])))/((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^2)))^(FracPart[p])))∫((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^(2 n))))^p)dx

Program code:

Int[(a1_.+b1_.*x_^n_)^p_*(a2_.+b2_.*x_^n_)^p_,x_Symbol] :=
  (a1+b1*x^n)^FracPart[p]*(a2+b2*x^n)^FracPart[p]/(a1*a2+b1*b2*x^(2*n))^FracPart[p]*Int[(a1*a2+b1*b2*x^(2*n))^p,x] /;
FreeQ[{a1,b1,a2,b2,n,p},x] && EqQ[a2*b1+a1*b2,0] && Not[IntegerQ[p]]

Rules for integrands of the form(((a+b (((c (x^q)))^n)))^p)

1:  ∫(((a+b (((c (x^q)))^n)))^p)dx  when  n q∈ℤ

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((((d x))^(m+1))/((((((c (x^q)))^(1/q))))^(m+1)))==0

Basis: ((F[(((c (x^q)))^(1/q))])/x)==Subst[((F[x])/x),x,(((c (x^q)))^(1/q))] (∂_x)(((c (x^q)))^(1/q))

Rule: If  n q∈ℤ, then

∫(((a+b (((c (x^q)))^n)))^p)dx  ⟶  (x/(((c (x^q)))^(1/q))) ∫(((((c (x^q)))^(1/q)) (((a+b ((((((c (x^q)))^(1/q))))^(n q))))^p))/x)dx
  ⟶  (x/(((c (x^q)))^(1/q))) Subst[∫(((a+b (x^(n q))))^p)dx,x,(((c (x^q)))^(1/q))]

Program code:

Int[(a_+b_.*(c_.*x_^q_.)^n_)^p_.,x_Symbol] :=
  x/(c*x^q)^(1/q)*Subst[Int[(a+b*x^(n*q))^p,x],x,(c*x^q)^(1/q)] /;
FreeQ[{a,b,c,n,p,q},x] && IntegerQ[n*q] && NeQ[x,(c*x^q)^(1/q)]

2:  ∫(((a+b (((c (x^q)))^n)))^p)dx  when  n∈𝔽

Derivation: Integration by substitution

Rule 1.1.3.2.S.4.3: If  n∈𝔽, then

∫(((a+b (((c (x^q)))^n)))^p)dx  ⟶  Subst[∫(((a+b (c^n) (x^(n q))))^p)dx,(x^(1/k)),((((c (x^q)))^(1/k))/((c^(1/k)) ((((x^(1/k))))^(q-1))))]

Program code:

Int[(a_+b_.*(c_.*x_^q_.)^n_)^p_.,x_Symbol] :=
  With[{k=Denominator[n]},
  Subst[Int[(a+b*c^n*x^(n*q))^p,x],x^(1/k),(c*x^q)^(1/k)/(c^(1/k)*(x^(1/k))^(q-1))]] /;
FreeQ[{a,b,c,p,q},x] && FractionQ[n]

3:  ∫(((a+b (((c (x^q)))^n)))^p)dx  when  n∉ℝ

Derivation: Integration by substitution

Basis: F[(((c (x^q)))^n)]==Subst[F[(c^n) (x^(n q))],(x^(n q)),((((c (x^q)))^n)/(c^n))]

Rule: If  n∉ℝ, then

∫(((a+b (((c (x^q)))^n)))^p)dx  ⟶  Subst[∫(((a+b (c^n) (x^(n q))))^p)dx,(x^(n q)),((((c (x^q)))^n)/(c^n))]

Program code:

Int[(a_+b_.*(c_.*x_^q_.)^n_)^p_.,x_Symbol] :=
  Subst[Int[(a+b*c^n*x^(n*q))^p,x],x^(n*q),(c*x^q)^n/c^n] /;
FreeQ[{a,b,c,n,p,q},x] && Not[RationalQ[n]]

?:  ∫(((a+b (v^n)))^p)dx  when  v==d (x^q) ∧ q∈(SuperMinus[ℤ])

Derivation: Integration by substitution

Basis: If  q∈ℤ, then  F[(x^q)]==-Subst[((F[(x^(-q))])/(x^2)),x,(1/x)] (∂_x)(1/x)

Rule 1.1.3.1.S.2.2: If  v==d (x^q) ∧ q∈(SuperMinus[ℤ]), then

∫(((a+b (v^n)))^p)dx  ⟶   -Subst[∫((((a+b (((d (x^(-q))))^n)))^p)/(x^2))dx,x,(1/x)]

Program code:

Int[(a_+b_.*(d_.*x_^q_.)^n_)^p_.,x_Symbol] :=
  -Subst[Int[(a+b*(d*x^(-q))^n)^p/x^2,x],x,1/x] /;
FreeQ[{a,b,d,n,p},x] && ILtQ[q,0]

2:  ∫(((a+b (v^n)))^p)dx  when  v==d (x^q) ∧ q∈𝔽

Derivation: Integration by substitution

Basis: If  s∈(SuperPlus[ℤ]), then  F[(x^(1/s))]==s Subst[(x^(s-1))F[x],x,(x^(1/s))] (∂_x)(x^(1/s))

Rule 1.1.3.1.S.2.2: If  v==d (x^q) ∧ q∈𝔽, let s->Denominator[q], then

∫(((a+b (v^n)))^p)dx  ⟶   ∫(((a+b (v^n)))^p)dx  ⟶  ∫(((a+b (((d ((((x^(1/s))))^(q s))))^n)))^p)dx  ⟶  s Subst[∫(x^(s-1)) (((a+b (((d (x^(q s))))^n)))^p)dx,x,(x^(1/s))]

Program code:

Int[(a_+b_.*(d_.*x_^q_.)^n_)^p_.,x_Symbol] :=
  With[{s=Denominator[q]},
  s*Subst[Int[x^(s-1)*(a+b*(d*x^(q*s))^n)^p,x],x,x^(1/s)]] /;
FreeQ[{a,b,d,n,p},x] && FractionQ[q]

x:  ∫(((a+b (v^n)))^p)dx  when  v==d (x^q) ∧ n q∉ℤ

Derivation: Integration by substitution

Rule 1.1.3.1.S.2.3: If  v==d (x^q) ∧ n q∉ℤ, then

∫(((a+b (v^n)))^p)dx  ⟶  Subst[∫(((a+b (x^(n q))))^p)dx,(x^(n q)),(v^n)]

Program code:

(* Int[(a_+b_.*(d_.*x_^q_.)^n_)^p_.,x_Symbol] :=
  Subst[Int[(a+b*x^(n*q))^p,x],x^(n*q),(d*x^q)^n] /;
FreeQ[{a,b,d,n,p,q},x] && Not[IntegerQ[n*q]] && NeQ[x^(n*q),(d*x^q)^n] *)