Rules for integrands of the form(((c x))^m) (((a+b (x^n)))^p)

D:  ∫(((c x))^m) ((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧(p∈ℤ ∨ ((Subscript[a, 1])>0 ∧ (Subscript[a, 2])>0))

Derivation: Algebraic simplification

Basis: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧(p∈ℤ ∨ ((Subscript[a, 1])>0 ∧ (Subscript[a, 2])>0)), then ((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)==((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^(2 n))))^p)

Rule: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧(p∈ℤ ∨ ((Subscript[a, 1])>0 ∧ (Subscript[a, 2])>0)), then

∫(((c x))^m) ((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  ⟶   ∫(((c x))^m) ((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^(2 n))))^p)dx

Program code:

Int[(c_.*x_)^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  Int[(c*x)^m*(a1*a2+b1*b2*x^(2*n))^p,x] /;
FreeQ[{a1,b1,a2,b2,c,m,n,p},x] && EqQ[a2*b1+a1*b2,0] && (IntegerQ[p] || GtQ[a1,0] && GtQ[a2,0])

1.  ∫(x^m) (((a+b (x^n)))^p)dx  when  m==n-1

1:  ∫((x^m)/(a+b (x^n)))dx  when  m==n-1

Derivation: Integration by substitution and reciprocal rule for integration

Basis: If  m==n-1, then (x^m)F[(x^n)]==(1/n)F[(x^n)](∂_x)(x^n)

Rule 1.1.3.2.1.1: If  m==n-1, then

∫((x^m)/(a+b (x^n)))dx  ⟶  (1/n) Subst[∫(1/(a+b x))dx,x,(x^n)]  ⟶  ((Log[a+b (x^n)])/(b n))

Program code:

Int[x_^m_./(a_+b_.*x_^n_),x_Symbol] :=
  Log[RemoveContent[a+b*x^n,x]]/(b*n) /;
FreeQ[{a,b,m,n},x] && EqQ[m,n-1]

2:  ∫(x^m) (((a+b (x^n)))^p)dx  when  m==n-1 ∧ p≠-1

Reference: G&R 2.110.4, CRC 88a with m=n-1

Derivation: Binomial recurrence 2a with m=n-1

Derivation: Integration by substitution and power rule for integration

Basis: If  m==n-1, then (x^m)F[(x^n)]==(1/n)F[(x^n)](∂_x)(x^n)

Rule 1.1.3.2.1.2: If  m==n-1 ∧ p≠-1, then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  (1/n) Subst[∫(((a+b x))^p)dx,x,(x^n)]  ⟶  ((((a+b (x^n)))^(p+1))/(b n (p+1)))

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  (a+b*x^n)^(p+1)/(b*n*(p+1)) /;
FreeQ[{a,b,m,n,p},x] && EqQ[m,n-1] && NeQ[p,-1]

Int[x_^m_.*(a1_+b1_.*x_^n_.)^p_*(a2_+b2_.*x_^n_.)^p_,x_Symbol] :=
  (a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(2*b1*b2*n*(p+1)) /;
FreeQ[{a1,b1,a2,b2,m,n,p},x] && EqQ[a2*b1+a1*b2,0] && EqQ[m,2*n-1] && NeQ[p,-1]

2:  ∫(x^m) (((a+b (x^n)))^p)dx  when  p∈ℤ ∧ n<0

Derivation: Algebraic expansion

Basis: If  p∈ℤ, then (((a+b (x^n)))^p)==(x^(n p))(((b+a (x^(-n))))^p)

Rule 1.1.3.2.2: If  p∈ℤ ∧ n<0, then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  ∫(x^(m+n p)) (((b+a (x^(-n))))^p)dx

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  Int[x^(m+n*p)*(b+a*x^(-n))^p,x] /;
FreeQ[{a,b,m,n},x] && IntegerQ[p] && NegQ[n]

3:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p+1==0 ∧ m≠-1

Reference: G&R 2.110.6, CRC 88c with m+n p+n+1==0

Derivation: Binomial recurrence 3b with m+n p+n+1==0

Rule 1.1.3.2.3: If ((m+1)/n)+p+1==0 ∧ m≠-1, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((((c x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a c(m+1)))

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a+b*x^n)^(p+1)/(a*c*(m+1)) /;
FreeQ[{a,b,c,m,n,p},x] && EqQ[(m+1)/n+p+1,0] && NeQ[m,-1]

Int[(c_.*x_)^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(a1*a2*c*(m+1)) /;
FreeQ[{a1,b1,a2,b2,c,m,n,p},x] && EqQ[a2*b1+a1*b2,0] && EqQ[(m+1)/(2*n)+p+1,0] && NeQ[m,-1]

4.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)∈ℤ

1:  ∫(x^m) (((a+b (x^n)))^p)dx  when ((m+1)/n)∈ℤ

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m)F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Note: If  n∈ℤ ∧ ((m+1)/n)∈ℤ, then m∈ℤ, and (((c x))^m) automatically evaluates to (c^m)(x^m).

Rule 1.1.3.2.4.1: If ((m+1)/n)∈ℤ, then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1))(((a+b x))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a+b*x)^p,x],x,x^n] /;
FreeQ[{a,b,m,n,p},x] && IntegerQ[Simplify[(m+1)/n]]

Int[x_^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a1+b1*x)^p*(a2+b2*x)^p,x],x,x^n] /;
FreeQ[{a1,b1,a2,b2,m,n,p},x] && EqQ[a2*b1+a1*b2,0] && IntegerQ[Simplify[(m+1)/(2*n)]]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((c x))^m)/(x^m))==0

Rule 1.1.3.2.4.2: If ((m+1)/n)∈ℤ, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((c^(IntPart[m]))(((c x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)))^p)dx

Program code:

Int[(c_*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,m,n,p},x] && IntegerQ[Simplify[(m+1)/n]]

Int[(c_*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a1+b1*x^n)^p*(a2+b2*x^n)^p,x] /;
FreeQ[{a1,b1,a2,b2,c,m,n,p},x] && EqQ[a2*b1+a1*b2,0] && IntegerQ[Simplify[(m+1)/(2*n)]]

5:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.1.3.2.5: If  p∈(SuperPlus[ℤ]), then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  ∫ExpandIntegrand[(((c x))^m) (((a+b (x^n)))^p),x]dx

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(c*x)^m*(a+b*x^n)^p,x],x] /;
FreeQ[{a,b,c,m,n},x] && IGtQ[p,0]

6.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p+1∈(SuperMinus[ℤ])

1:  ∫(x^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p+1∈(SuperMinus[ℤ])∧ m≠-1

Reference: G&R 2.110.6, CRC 88c

Derivation: Binomial recurrence 3b

Note: This rule drives ((m+1)/n)+p+1 to 0 by incrementing m by n.

Rule 1.1.3.2.6.1: If  ((m+1)/n)+p+1∈(SuperMinus[ℤ])∧ m≠-1, then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  (((x^(m+1)) (((a+b (x^n)))^(p+1)))/(a (m+1)))-((b (m+n (p+1)+1))/(a (m+1)))∫(x^(m+n)) (((a+b (x^n)))^p)dx

Program code:

Int[x_^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  x^(m+1)*(a+b*x^n)^(p+1)/(a*(m+1)) - 
  b*(m+n*(p+1)+1)/(a*(m+1))*Int[x^(m+n)*(a+b*x^n)^p,x] /;
FreeQ[{a,b,m,n,p},x] && ILtQ[Simplify[(m+1)/n+p+1],0] && NeQ[m,-1]

Int[x_^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  x^(m+1)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(a1*a2*(m+1)) - 
  b1*b2*(m+2*n*(p+1)+1)/(a1*a2*(m+1))*Int[x^(m+2*n)*(a1+b1*x^n)^p*(a2+b2*x^n)^p,x] /;
FreeQ[{a1,b1,a2,b2,m,n,p},x] && EqQ[a2*b1+a1*b2,0] && ILtQ[Simplify[(m+1)/(2*n)+p+1],0] && NeQ[m,-1]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p+1∈(SuperMinus[ℤ])∧ p≠-1

Reference: G&R 2.110.2, CRC 88d

Derivation: Binomial recurrence 2b

Derivation: Integration by parts

Basis: (x^m) (((a+b (x^n)))^p)==(x^(m+n p+n+1))((((a+b (x^n)))^p)/(x^(n (p+1)+1)))

Basis: ∫((((a+b (x^n)))^p)/(x^(n (p+1)+1)))dx==-((((a+b (x^n)))^(p+1))/((x^(n (p+1)))a n (p+1)))

Note: This rule drives ((m+1)/n)+p+1 to 0 by incrementing p by 1.

Rule 1.1.3.2.6.2: If ((m+1)/n)+p+1∈(SuperMinus[ℤ])∧ p≠-1, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  -(((((c x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a c n (p+1)))+((m+n (p+1)+1)/(a n (p+1)))∫(((c x))^m) (((a+b (x^n)))^(p+1))dx

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  -(c*x)^(m+1)*(a+b*x^n)^(p+1)/(a*c*n*(p+1)) +
  (m+n*(p+1)+1)/(a*n*(p+1))*Int[(c*x)^m*(a+b*x^n)^(p+1),x] /;
FreeQ[{a,b,c,m,n,p},x] && ILtQ[Simplify[(m+1)/n+p+1],0] && NeQ[p,-1]

Int[(c_.*x_)^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  -(c*x)^(m+1)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(2*a1*a2*c*n*(p+1)) +
  (m+2*n*(p+1)+1)/(2*a1*a2*n*(p+1))*Int[(c*x)^m*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1),x] /;
FreeQ[{a1,b1,a2,b2,c,m,n,p},x] && EqQ[a2*b1+a1*b2,0] && ILtQ[Simplify[(m+1)/(2*n)+p+1],0] && NeQ[p,-1]

7.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈ℤ

1.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])

1:  ∫(x^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ m∈ℤ ∧ GCD[m+1,n]≠1

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ m∈ℤ, let k=GCD[m+1,n], then (x^m) F[(x^n)]==(1/k)Subst[(x^(((m+1)/k)-1)) F[(x^(n/k))],x,(x^k)] (∂_x)(x^k)

Rule 1.1.3.2.7.1.1: If  n∈(SuperPlus[ℤ])∧ m∈ℤ, let k=GCD[m+1,n], if  k≠1, then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  (1/k) Subst[∫(x^(((m+1)/k)-1)) (((a+b (x^(n/k))))^p)dx,x,(x^k)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  With[{k=GCD[m+1,n]},
  1/k*Subst[Int[x^((m+1)/k-1)*(a+b*x^(n/k))^p,x],x,x^k] /;
 k≠1] /;
FreeQ[{a,b,p},x] && IGtQ[n,0] && IntegerQ[m]

Int[x_^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  With[{k=GCD[m+1,2*n]},
  1/k*Subst[Int[x^((m+1)/k-1)*(a1+b1*x^(n/k))^p*(a2+b2*x^(n/k))^p,x],x,x^k] /;
 k≠1] /;
FreeQ[{a1,b1,a2,b2,p},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && IntegerQ[m]

2.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when n∈(SuperPlus[ℤ])∧ p>0

1:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ p>0 ∧ m<-1

Reference: G&R 2.110.3

Derivation: Binomial recurrence 1a

Derivation: Integration by parts

Rule 1.1.3.2.7.1.2.1: If  n∈(SuperPlus[ℤ])∧ p>0 ∧ m<-1, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((((c x))^(m+1)) (((a+b (x^n)))^p))/(c(m+1)))-((b n p)/((c^n)(m+1)))∫(((c x))^(m+n)) (((a+b (x^n)))^(p-1))dx

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a+b*x^n)^p/(c*(m+1)) - 
  b*n*p/(c^n*(m+1))*Int[(c*x)^(m+n)*(a+b*x^n)^(p-1),x] /;
FreeQ[{a,b,c},x] && IGtQ[n,0] && GtQ[p,0] && LtQ[m,-1] && Not[ILtQ[(m+n*p+n+1)/n,0]] && 
  IntBinomialQ[a,b,c,n,m,p,x]

Int[(c_.*x_)^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a1+b1*x^n)^p*(a2+b2*x^n)^p/(c*(m+1)) - 
  2*b1*b2*n*p/(c^(2*n)*(m+1))*Int[(c*x)^(m+2*n)*(a1+b1*x^n)^(p-1)*(a2+b2*x^n)^(p-1),x] /;
FreeQ[{a1,b1,a2,b2,c,m},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && GtQ[p,0] && LtQ[m,-1] && NeQ[m+2*n*p+1,0] && 
  IntBinomialQ[a1*a2,b1*b2,c,2*n,m,p,x]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ p>0 ∧ m+n p+1≠0

Reference: G&R 2.110.1, CRC 88b

Derivation: Binomial recurrence 1b

Derivation: Inverted integration by parts

Rule 1.1.3.2.7.1.2.2: If  n∈(SuperPlus[ℤ])∧ p>0 ∧ m+n p+1≠0, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((((c x))^(m+1)) (((a+b (x^n)))^p))/(c(m+n p+1)))+((a n p)/(m+n p+1))∫(((c x))^m) (((a+b (x^n)))^(p-1))dx

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a+b*x^n)^p/(c*(m+n*p+1)) +
  a*n*p/(m+n*p+1)*Int[(c*x)^m*(a+b*x^n)^(p-1),x] /;
FreeQ[{a,b,c,m},x] && IGtQ[n,0] && GtQ[p,0] && NeQ[m+n*p+1,0] && IntBinomialQ[a,b,c,n,m,p,x]

Int[(c_.*x_)^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a1+b1*x^n)^p*(a2+b2*x^n)^p/(c*(m+2*n*p+1)) + 
  2*a1*a2*n*p/(m+2*n*p+1)*Int[(c*x)^m*(a1+b1*x^n)^(p-1)*(a2+b2*x^n)^(p-1),x] /;
FreeQ[{a1,b1,a2,b2,c,m},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && GtQ[p,0] && NeQ[m+2*n*p+1,0] && IntBinomialQ[a1*a2,b1*b2,c,2*n,m,p,x]

3.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when n∈(SuperPlus[ℤ])∧ p<-1

1.  ∫((x^m)/(((a+b (x^4)))^(5/4)))dx  when  (b/a)>0 ∧ ((m-2)/4)∈ℤ

1:  ∫((x^2)/(((a+b (x^4)))^(5/4)))dx  when  (b/a)>0

Derivation: Piecewise constant extraction

Basis: (∂_x)((x (((1+(a/(b (x^4)))))^(1/4)))/(((a+b (x^4)))^(1/4)))==0

Rule 1.1.3.2.7.1.3.1.1: If (b/a)>0, then

∫((x^2)/(((a+b (x^4)))^(5/4)))dx  ⟶  ((x (((1+(a/(b (x^4)))))^(1/4)))/(b (((a+b (x^4)))^(1/4))))∫(1/((x^3) (((1+(a/(b (x^4)))))^(5/4))))dx

Program code:

Int[x_^2/(a_+b_.*x_^4)^(5/4),x_Symbol] :=
  x*(1+a/(b*x^4))^(1/4)/(b*(a+b*x^4)^(1/4))*Int[1/(x^3*(1+a/(b*x^4))^(5/4)),x] /;
FreeQ[{a,b},x] && PosQ[b/a]

2:  ∫((x^m)/(((a+b (x^4)))^(5/4)))dx  when  (b/a)>0 ∧ ((m-2)/4)∈(SuperPlus[ℤ])

Reference: G&R 2.110.5, CRC 88a

Derivation: Binomial recurrence 3a

Derivation: Inverted integration by parts

Rule 1.1.3.2.7.1.3.1.2: If (b/a)>0 ∧ ((m-2)/4)∈(SuperPlus[ℤ]), then

∫((x^m)/(((a+b (x^4)))^(5/4)))dx  ⟶  ((x^(m-3))/(b (m-4) (((a+b (x^4)))^(1/4))))-((a (m-3))/(b (m-4)))∫((x^(m-4))/(((a+b (x^4)))^(5/4)))dx

Program code:

Int[x_^m_/(a_+b_.*x_^4)^(5/4),x_Symbol] :=
  x^(m-3)/(b*(m-4)*(a+b*x^4)^(1/4)) - a*(m-3)/(b*(m-4))*Int[x^(m-4)/(a+b*x^4)^(5/4),x] /;
FreeQ[{a,b},x] && PosQ[b/a] && IGtQ[(m-2)/4,0]

3:  ∫((x^m)/(((a+b (x^4)))^(5/4)))dx  when  (b/a)>0 ∧ ((m-2)/4)∈(SuperMinus[ℤ])

Reference: G&R 2.110.6, CRC 88c

Derivation: Binomial recurrence 3b

Derivation: Integration by parts

Rule 1.1.3.2.7.1.3.1.3: If  (b/a)>0 ∧ ((m-2)/4)∈(SuperMinus[ℤ]), then

∫((x^m)/(((a+b (x^4)))^(5/4)))dx  ⟶  ((x^(m+1))/(a (m+1) (((a+b (x^4)))^(1/4))))-((b m)/(a (m+1)))∫((x^(m+4))/(((a+b (x^4)))^(5/4)))dx

Program code:

Int[x_^m_/(a_+b_.*x_^4)^(5/4),x_Symbol] :=
  x^(m+1)/(a*(m+1)*(a+b*x^4)^(1/4)) - b*m/(a*(m+1))*Int[x^(m+4)/(a+b*x^4)^(5/4),x] /;
FreeQ[{a,b},x] && PosQ[b/a] && ILtQ[(m-2)/4,0]

2.  ∫((((c x))^m)/(((a+b (x^2)))^(5/4)))dx  when (b/a)>0 ∧ 2 m∈ℤ

1:  ∫((Sqrt[c x])/(((a+b (x^2)))^(5/4)))dx  when  (b/a)>0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sqrt[c x]) (((1+(a/(b (x^2)))))^(1/4)))/(((a+b (x^2)))^(1/4)))==0

Rule 1.1.3.2.7.1.3.2.1: If (b/a)>0, then

∫((Sqrt[c x])/(((a+b (x^2)))^(5/4)))dx  ⟶  (((Sqrt[c x]) (((1+(a/(b (x^2)))))^(1/4)))/(b (((a+b (x^2)))^(1/4))))∫(1/((x^2) (((1+(a/(b (x^2)))))^(5/4))))dx

Program code:

Int[Sqrt[c_.*x_]/(a_+b_.*x_^2)^(5/4),x_Symbol] :=
  Sqrt[c*x]*(1+a/(b*x^2))^(1/4)/(b*(a+b*x^2)^(1/4))*Int[1/(x^2*(1+a/(b*x^2))^(5/4)),x] /;
FreeQ[{a,b,c},x] && PosQ[b/a]

2:  ∫((((c x))^m)/(((a+b (x^2)))^(5/4)))dx  when  (b/a)>0 ∧ 2 m∈ℤ ∧ m>(3/2)

Reference: G&R 2.110.5, CRC 88a

Derivation: Binomial recurrence 3a

Derivation: Inverted integration by parts

Rule 1.1.3.2.7.1.3.2.2: If (b/a)>0 ∧ 2 m∈ℤ ∧ m>(3/2), then

∫((((c x))^m)/(((a+b (x^2)))^(5/4)))dx  ⟶  ((2 c (((c x))^(m-1)))/(b (2 m-3) (((a+b (x^2)))^(1/4))))-((2 a (c^2) (m-1))/(b (2 m-3)))∫((((c x))^(m-2))/(((a+b (x^2)))^(5/4)))dx

Program code:

Int[(c_.*x_)^m_/(a_+b_.*x_^2)^(5/4),x_Symbol] :=
  2*c*(c*x)^(m-1)/(b*(2*m-3)*(a+b*x^2)^(1/4)) - 2*a*c^2*(m-1)/(b*(2*m-3))*Int[(c*x)^(m-2)/(a+b*x^2)^(5/4),x] /;
FreeQ[{a,b,c},x] && PosQ[b/a] && IntegerQ[2*m] && GtQ[m,3/2]

3:  ∫((((c x))^m)/(((a+b (x^2)))^(5/4)))dx  when  (b/a)>0 ∧ 2 m∈ℤ ∧ m<-1

Reference: G&R 2.110.6, CRC 88c

Derivation: Binomial recurrence 3b

Derivation: Integration by parts

Rule 1.1.3.2.7.1.3.2.3: If (b/a)>0 ∧ 2 m∈ℤ ∧ m<-1, then

∫((((c x))^m)/(((a+b (x^2)))^(5/4)))dx  ⟶  ((((c x))^(m+1))/(a c (m+1) (((a+b (x^2)))^(1/4))))-((b (2 m+1))/(2 a (c^2) (m+1)))∫((((c x))^(m+2))/(((a+b (x^2)))^(5/4)))dx

Program code:

Int[(c_.*x_)^m_/(a_+b_.*x_^2)^(5/4),x_Symbol] :=
  (c*x)^(m+1)/(a*c*(m+1)*(a+b*x^2)^(1/4)) - b*(2*m+1)/(2*a*c^2*(m+1))*Int[(c*x)^(m+2)/(a+b*x^2)^(5/4),x] /;
FreeQ[{a,b,c},x] && PosQ[b/a] && IntegerQ[2*m] && LtQ[m,-1]

3:  ∫((x^2)/(((a+b (x^4)))^(5/4)))dx  when  (b/a)≯0

Reference: G&R 2.110.4

Derivation: Binomial recurrence 2a

Derivation: Integration by parts

Rule 1.1.3.2.7.1.3.3: If (b/a)≯0, then

∫((x^2)/(((a+b (x^4)))^(5/4)))dx  ⟶  -(1/(b x (((a+b (x^4)))^(1/4))))-(1/b) ∫(1/((x^2) (((a+b (x^4)))^(1/4))))dx

Program code:

Int[x_^2/(a_+b_.*x_^4)^(5/4),x_Symbol] :=
  -1/(b*x*(a+b*x^4)^(1/4)) - 1/b*Int[1/(x^2*(a+b*x^4)^(1/4)),x] /;
FreeQ[{a,b},x] && NegQ[b/a]

4:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ p<-1 ∧ m+1>n

Reference: G&R 2.110.4

Derivation: Binomial recurrence 2a

Derivation: Integration by parts

Basis: (x^m) (((a+b (x^n)))^p)==(x^(m-n+1))(((a+b (x^n)))^p) (x^(n-1))

Basis: ∫(((a+b (x^n)))^p) (x^(n-1))dx==((((a+b (x^n)))^(p+1))/(b n (p+1)))

Rule 1.1.3.2.7.1.3.4: If  n∈(SuperPlus[ℤ])∧ p<-1 ∧ m+1>n, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((c^(n-1))(((c x))^(m-n+1)) (((a+b (x^n)))^(p+1)))/(b n (p+1)))-(((c^n)(m-n+1))/(b n (p+1)))∫(((c x))^(m-n)) (((a+b (x^n)))^(p+1))dx

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  c^(n-1)*(c*x)^(m-n+1)*(a+b*x^n)^(p+1)/(b*n*(p+1)) -
  c^n*(m-n+1)/(b*n*(p+1))*Int[(c*x)^(m-n)*(a+b*x^n)^(p+1),x] /;
FreeQ[{a,b,c},x] && IGtQ[n,0] && LtQ[p,-1] && GtQ[m+1,n] && Not[ILtQ[(m+n*(p+1)+1)/n,0]] && IntBinomialQ[a,b,c,n,m,p,x]

(* Int[(c_.*x_)^m_.*u_^p_*v_^p_,x_Symbol] :=
  With[{a=BinomialParts[u,x][[1]],b=BinomialParts[u,x][[2]],n=BinomialParts[u,x][[3]]},
  c^(n-1)*(c*x)^(m-n+1)*u^(p+1)*v^(p+1)/(b*n*(p+1)) -
  c^n*(m-n+1)/(b*n*(p+1))*Int[(c*x)^(m-n)*u^(p+1)*v^(p+1),x] /;
 IGtQ[n,0] && m+1>n && Not[ILtQ[(m+n*(p+1)+1)/n,0]] && 
   IntBinomialQ[a,b,c,n,m,p,x]] /;
FreeQ[c,x] && BinomialQ[u*v,x] && LtQ[p,-1] *)

Int[(c_.*x_)^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  c^(2*n-1)*(c*x)^(m-2*n+1)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(2*b1*b2*n*(p+1)) - 
  c^(2*n)*(m-2*n+1)/(2*b1*b2*n*(p+1))*Int[(c*x)^(m-2*n)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1),x] /;
FreeQ[{a1,b1,a2,b2,c},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && LtQ[p,-1] && m+1>2*n && 
  Not[ILtQ[(m+2*n*(p+1)+1)/(2*n),0]] && IntBinomialQ[a1*a2,b1*b2,c,2*n,m,p,x]

5:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ p<-1

Reference: G&R 2.110.2, CRC 88d

Derivation: Binomial recurrence 2b

Derivation: Integration by parts

Basis: (x^m) (((a+b (x^n)))^p)==(x^(m+n p+n+1))((((a+b (x^n)))^p)/(x^(n (p+1)+1)))

Basis: ∫((((a+b (x^n)))^p)/(x^(n (p+1)+1)))dx==-((((a+b (x^n)))^(p+1))/((x^(n (p+1)))a n (p+1)))

Rule 1.1.3.2.7.1.3.5: If  n∈(SuperPlus[ℤ])∧ p<-1, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  -(((((c x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a c n (p+1)))+((m+n (p+1)+1)/(a n (p+1)))∫(((c x))^m) (((a+b (x^n)))^(p+1))dx

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  -(c*x)^(m+1)*(a+b*x^n)^(p+1)/(a*c*n*(p+1)) +
  (m+n*(p+1)+1)/(a*n*(p+1))*Int[(c*x)^m*(a+b*x^n)^(p+1),x] /;
FreeQ[{a,b,c,m},x] && IGtQ[n,0] && LtQ[p,-1] && IntBinomialQ[a,b,c,n,m,p,x]

Int[(c_.*x_)^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  -(c*x)^(m+1)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(2*a1*a2*c*n*(p+1)) + 
  (m+2*n*(p+1)+1)/(2*a1*a2*n*(p+1))*Int[(c*x)^m*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1),x] /;
FreeQ[{a1,b1,a2,b2,c,m},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && LtQ[p,-1] && IntBinomialQ[a1*a2,b1*b2,c,2*n,m,p,x]

4.  ∫((x^m)/(a+b (x^n)))dx  when  n∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])

1.  ∫((x^m)/(a+b (x^n)))dx  when  n∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1

1.  ∫((x^m)/(a+b (x^n)))dx  when  ((n-1)/2)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1

1:  ∫(x/(a+b (x^3)))dx

Reference: G&R 2.126.2, CRC 75

Derivation: Algebraic expansion

Basis: (x/(a+b (x^3)))==-(1/(3 (a^(1/3)) (b^(1/3)) ((a^(1/3))+(b^(1/3)) x)))+(((a^(1/3))+(b^(1/3)) x)/(3 (a^(1/3)) (b^(1/3)) ((a^(2/3))-(a^(1/3)) (b^(1/3)) x+(b^(2/3)) (x^2))))

Rule 1.1.3.2.7.1.4.1.1.1:

∫(x/(a+b (x^3)))dx  ⟶  -(1/(3 (a^(1/3)) (b^(1/3))))∫(1/((a^(1/3))+(b^(1/3)) x))dx+(1/(3 (a^(1/3)) (b^(1/3))))∫(((a^(1/3))+(b^(1/3)) x)/((a^(2/3))-(a^(1/3)) (b^(1/3)) x+(b^(2/3)) (x^2)))dx

Program code:

Int[x_/(a_+b_.*x_^3),x_Symbol] :=
  -1/(3*Rt[a,3]*Rt[b,3])*Int[1/(Rt[a,3]+Rt[b,3]*x),x] + 
  1/(3*Rt[a,3]*Rt[b,3])*Int[(Rt[a,3]+Rt[b,3]*x)/(Rt[a,3]^2-Rt[a,3]*Rt[b,3]*x+Rt[b,3]^2*x^2),x] /;
FreeQ[{a,b},x]

2.  ∫((x^m)/(a+b (x^5)))dx  when  m∈(SuperPlus[ℤ])∧ m<4

1:  ∫((x^m)/(a+b (x^5)))dx  when m∈(SuperPlus[ℤ])∧ m<4 ∧ (a/b)>0

Derivation: Algebraic expansion

Basis: If  m∈ℤ ∧ 0≤m<5,  let (r/s)=((((a/b)))^(1/5)), then ((x^m)/(a+b (x^5)))==(((((-1))^m)(r^(m+1)))/(5 a (s^m) (r+s x)))+((2 (r^(m+1)) )/(5 a (s^m)))((r Cos[((m π)/5)]-s Cos[(((m+1) π)/5)] x)/((r^2)-(1/2) (1+(Sqrt[5])) r s x+(s^2) (x^2)))+((2 (r^(m+1)) )/(5 a (s^m)))((r Cos[((3 m π)/5)]-s Cos[((3 (m+1) π)/5)] x)/((r^2)-(1/2) (1-(Sqrt[5])) r s x+(s^2) (x^2)))

Note: This rule not necessary for host systems that automatically simplify Cos[((k π)/5)] to radicals when k is an integer.

Rule 1.1.3.2.7.1.4.1.1.2.1: If  m∈(SuperPlus[ℤ])∧ m<4 ∧ (a/b)>0, let (r/s)=((((a/b)))^(1/5)), then

∫((x^m)/(a+b (x^5)))dx  ⟶  (((((-1))^m)(r^(m+1)))/(5 a (s^m))) ∫(1/(r+s x))dx+((2 (r^(m+1)) )/(5 a (s^m))) ∫((r Cos[((m π)/5)]-s Cos[(((m+1) π)/5)] x)/((r^2)-(1/2) (1+(Sqrt[5])) r s x+(s^2) (x^2)))dx+((2 (r^(m+1)) )/(5 a (s^m))) ∫((r Cos[((3 m π)/5)]-s Cos[((3 (m+1) π)/5)] x)/((r^2)-(1/2) (1-(Sqrt[5])) r s x+(s^2) (x^2)))dx

Program code:

(* Int[x_^m_./(a_+b_.*x_^5),x_Symbol] :=
  With[{r=Numerator[Rt[a/b,5]], s=Denominator[Rt[a/b,5]]},
  (-1)^m*r^(m+1)/(5*a*s^m)*Int[1/(r+s*x),x] + 
  2*r^(m+1)/(5*a*s^m)*Int[(r*Cos[m*Pi/5]-s*Cos[(m+1)*Pi/5]*x)/(r^2-1/2*(1+Sqrt[5])*r*s*x+s^2*x^2),x] + 
  2*r^(m+1)/(5*a*s^m)*Int[(r*Cos[3*m*Pi/5]-s*Cos[3*(m+1)*Pi/5]*x)/(r^2-1/2*(1-Sqrt[5])*r*s*x+s^2*x^2),x]] /;
FreeQ[{a,b},x] && IGtQ[m,0] && LtQ[m,4] && PosQ[a/b] *)

2:  ∫((x^m)/(a+b (x^5)))dx  when m∈(SuperPlus[ℤ])∧ m<4 ∧ (a/b)≯0

Derivation: Algebraic expansion

Basis: If  m∈ℤ ∧ 0≤m<5,  let (r/s)=(((-(a/b)))^(1/5)), then ((x^m)/(a+b (x^5)))==((r^(m+1))/(5 a (s^m) (r-s x)))+((2 (((-1))^m) (r^(m+1)))/(5 a (s^m)))((r Cos[((m π)/5)]+s Cos[(((m+1) π)/5)] x)/((r^2)+(1/2) (1+(Sqrt[5])) r s x+(s^2) (x^2)))+((2 (((-1))^m) (r^(m+1)))/(5 a (s^m)))((r Cos[((3 m π)/5)]+s Cos[((3 (m+1) π)/5)] x)/((r^2)+(1/2) (1-(Sqrt[5])) r s x+(s^2) (x^2)))

Note: This rule not necessary for host systems that automatically simplify Cos[((k π)/5)] to radicals when k is an integer.

Rule 1.1.3.2.7.1.4.1.1.2.1: If  m∈(SuperPlus[ℤ])∧ m<4 ∧ (a/b)≯0, let (r/s)=(((-(a/b)))^(1/5)), then

∫((x^m)/(a+b (x^5)))dx  ⟶  ((r^(m+1))/(5 a (s^m))) ∫(1/(r-s x))dx+((2 (((-1))^m) (r^(m+1)))/(5 a (s^m))) ∫((r Cos[((m π)/5)]+s Cos[(((m+1) π)/5)] x)/((r^2)+(1/2) (1+(Sqrt[5])) r s x+(s^2) (x^2)))dx+((2 (((-1))^m) (r^(m+1)))/(5 a (s^m))) ∫((r Cos[((3 m π)/5)]+s Cos[((3 (m+1) π)/5)] x)/((r^2)+(1/2) (1-(Sqrt[5])) r s x+(s^2) (x^2)))dx

Program code:

(* Int[x_^m_./(a_+b_.*x_^5),x_Symbol] :=
  With[{r=Numerator[Rt[-a/b,5]], s=Denominator[Rt[-a/b,5]]},
  (r^(m+1)/(5*a*s^m))*Int[1/(r-s*x),x] + 
  2*(-1)^m*r^(m+1)/(5*a*s^m)*Int[(r*Cos[m*Pi/5]+s*Cos[(m+1)*Pi/5]*x)/(r^2+1/2*(1+Sqrt[5])*r*s*x+s^2*x^2),x] + 
  2*(-1)^m*r^(m+1)/(5*a*s^m)*Int[(r*Cos[3*m*Pi/5]+s*Cos[3*(m+1)*Pi/5]*x)/(r^2+1/2*(1-Sqrt[5])*r*s*x+s^2*x^2),x]] /;
FreeQ[{a,b},x] && IGtQ[m,0] && LtQ[m,4] && NegQ[a/b] *)

3.  ∫((x^m)/(a+b (x^n)))dx  when  ((n-1)/2)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1 ∧ n>3

1:  ∫((x^m)/(a+b (x^n)))dx  when  ((n-1)/2)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ (a/b)>0

Derivation: Algebraic expansion

Basis: If  ((n-1)/2)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1,  let (r/s)=((((a/b)))^(1/n)), then ((z^m)/(a+b (z^n)))==-((((-r))^(m+1))/(a n (s^m) (r+s z)))+((2 (r^(m+1)) )/(a n (s^m)))(∑_(k=1)^((n-1)/2))((r Cos[(((2 k-1) m π)/n)]-s Cos[(((2 k-1) (m+1) π)/n)] z)/((r^2)-2 r s Cos[(((2 k-1) π)/n)] z+(s^2) (z^2)))

Rule 1.1.3.2.7.1.4.1.1.3.1: If  ((n-1)/2)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ (a/b)>0, let (r/s)=((((a/b)))^(1/n)), then

∫((x^m)/(a+b (x^n)))dx  ⟶  -((((-r))^(m+1))/(a n (s^m)))∫(1/(r+s x))dx+((2 (r^(m+1)) )/(a n (s^m)))(∑_(k=1)^((n-1)/2))∫((r Cos[(((2 k-1) m π)/n)]-s Cos[(((2 k-1) (m+1) π)/n)] x)/((r^2)-2 r s Cos[(((2 k-1) π)/n)] x+(s^2) (x^2)))dx

Program code:

Int[x_^m_./(a_+b_.*x_^n_),x_Symbol] :=
  Module[{r=Numerator[Rt[a/b,n]], s=Denominator[Rt[a/b,n]], k, u},
  u=Int[(r*Cos[(2*k-1)*m*Pi/n]-s*Cos[(2*k-1)*(m+1)*Pi/n]*x)/(r^2-2*r*s*Cos[(2*k-1)*Pi/n]*x+s^2*x^2),x];
  -(-r)^(m+1)/(a*n*s^m)*Int[1/(r+s*x),x] + Dist[2*r^(m+1)/(a*n*s^m),Sum[u,{k,1,(n-1)/2}],x]] /;
FreeQ[{a,b},x] && IGtQ[(n-1)/2,0] && IGtQ[m,0] && LtQ[m,n-1] && PosQ[a/b]

2:  ∫((x^m)/(a+b (x^n)))dx  when  ((n-1)/2)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ (a/b)≯0

Derivation: Algebraic expansion

Basis: If  ((n-1)/2)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1, let (r/s)=(((-(a/b)))^(1/n)), then ((z^m)/(a+b (z^n)))==((r^(m+1))/(a n (s^m) (r-s z)))-((2 (((-r))^(m+1)))/(a n (s^m)))(∑_(k=1)^((n-1)/2))((r Cos[(((2 k-1) m π)/n)]+s Cos[(((2 k-1) (m+1) π)/n)] z)/((r^2)+2 r s Cos[(((2 k-1) π)/n)] z+(s^2) (z^2)))

Rule 1.1.3.2.7.1.4.1.1.3.2: If  ((n-1)/2)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1 ∧ (a/b)≯0, let (r/s)=(((-(a/b)))^(1/n)), then

∫((x^m)/(a+b (x^n)))dx  ⟶  ((r^(m+1))/(a n (s^m)))∫(1/(r-s x))dx-((2 (((-r))^(m+1)))/(a n (s^m)))(∑_(k=1)^((n-1)/2))∫(( r Cos[(((2 k-1) m π)/n)]+s Cos[(((2 k-1) (m+1) π)/n)] x)/((r^2)+2 r s Cos[(((2 k-1) π)/n)] x+(s^2) (x^2)))dx

Program code:

Int[x_^m_./(a_+b_.*x_^n_),x_Symbol] :=
  Module[{r=Numerator[Rt[-a/b,n]], s=Denominator[Rt[-a/b,n]], k, u},
  u=Int[(r*Cos[(2*k-1)*m*Pi/n]+s*Cos[(2*k-1)*(m+1)*Pi/n]*x)/(r^2+2*r*s*Cos[(2*k-1)*Pi/n]*x+s^2*x^2),x];
  r^(m+1)/(a*n*s^m)*Int[1/(r-s*x),x] - Dist[2*(-r)^(m+1)/(a*n*s^m),Sum[u,{k,1,(n-1)/2}],x]] /;
FreeQ[{a,b},x] && IGtQ[(n-1)/2,0] && IGtQ[m,0] && LtQ[m,n-1] && NegQ[a/b]

2.  ∫((x^m)/(a+b (x^n)))dx  when  (n/2)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1

1.  ∫((x^m)/(a+b (x^n)))dx  when  ((n-2)/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1

1:  ∫((x^m)/(a+b (x^n)))dx  when  ((n-2)/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ (a/b)>0

Derivation: Algebraic expansion

Basis: If  ((n-2)/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1, let (r/s)=((((a/b)))^(1/n)), then ((z^m)/(a+b (z^n)))==((2 (((-1))^(m/2))(r^(m+2)))/(a n (s^m)((r^2)+(s^2) (z^2))))+((4 (r^(m+2)))/(a n (s^m)))(∑_(k=1)^((n-2)/4))(((r^2) Cos[(((2 k-1) m π)/n)]-(s^2) Cos[(((2 k-1) (m+2) π)/n)] (z^2))/((r^4)-2 (r^2) (s^2) Cos[((2 (2 k-1) π)/n)] (z^2)+(s^4) (z^4)))

Basis: (((r^2) Cos[ρ]-(s^2) Cos[ρ+2 θ] (z^2))/((r^4)-2 (r^2) (s^2) Cos[2 θ] (z^2)+(s^4) (z^4)))==(1/(2 r))(((r Cos[ρ]-s Cos[ρ+θ] z)/((r^2)-2r s Cos[θ] z+(s^2) (z^2))) +((r Cos[ρ]+s Cos[ρ+θ] z)/((r^2)+2r s Cos[θ] z+(s^2) (z^2))))

Rule 1.1.3.2.7.1.4.1.2.1.1: If ((n-2)/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ (a/b)>0, let (r/s)=((((a/b)))^(1/n)), then

∫((x^m)/(a+b (x^n)))dx  ⟶  ((2 (((-1))^(m/2)) (r^(m+2)))/(a n (s^m)))∫(1/((r^2)+(s^2) (x^2)))dx+((4 (r^(m+2)))/(a n (s^m)))(∑_(k=1)^((n-2)/4))∫(((r^2) Cos[(((2 k-1) m π)/n)]-(s^2) Cos[(((2 k-1) (m+2) π)/n)] (x^2))/((r^4)-2 (r^2) (s^2) Cos[((2 (2 k-1) π)/n)] (x^2)+(s^4) (x^4)))dx

  ⟶  ((2 (((-1))^(m/2)) (r^(m+2)))/(a n (s^m)))∫(1/((r^2)+(s^2) (x^2)))dx+((2 (r^(m+1)))/(a n (s^m)))(∑_(k=1)^((n-2)/4))(∫((r Cos[(((2 k-1) m π)/n)]-s Cos[(((2 k-1) (m+1) π)/n)] x)/((r^2)-2r s Cos[(((2 k-1) π)/n)] x+(s^2) (x^2)))dx+∫((r Cos[(((2 k-1) m π)/n)]+s Cos[(((2 k-1) (m+1) π)/n)] x)/((r^2)+2r s Cos[(((2 k-1) π)/n)] x+(s^2) (x^2)))dx)

Program code:

Int[x_^m_./(a_+b_.*x_^n_),x_Symbol] :=
  Module[{r=Numerator[Rt[a/b,n]], s=Denominator[Rt[a/b,n]], k, u},
  u=Int[(r*Cos[(2*k-1)*m*Pi/n]-s*Cos[(2*k-1)*(m+1)*Pi/n]*x)/(r^2-2*r*s*Cos[(2*k-1)*Pi/n]*x+s^2*x^2),x] + 
    Int[(r*Cos[(2*k-1)*m*Pi/n]+s*Cos[(2*k-1)*(m+1)*Pi/n]*x)/(r^2+2*r*s*Cos[(2*k-1)*Pi/n]*x+s^2*x^2),x];
  2*(-1)^(m/2)*r^(m+2)/(a*n*s^m)*Int[1/(r^2+s^2*x^2),x] + Dist[2*r^(m+1)/(a*n*s^m),Sum[u,{k,1,(n-2)/4}],x]] /;
 FreeQ[{a,b},x] && IGtQ[(n-2)/4,0] && IGtQ[m,0] && LtQ[m,n-1] && PosQ[a/b]

2:  ∫((x^m)/(a+b (x^n)))dx  when  ((n-2)/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ (a/b)≯0

Derivation: Algebraic expansion

Basis: If  ((n-2)/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1, let (r/s)=(((-(a/b)))^(1/n)), then ((z^m)/(a+b (z^n)))==((2 (r^(m+2)))/(a n (s^m)((r^2)-(s^2) (z^2))))+((4 (r^(m+2)))/(a n (s^m)))(∑_(k=1)^((n-2)/4))(((r^2) Cos[((2 k m π)/n)]-(s^2) Cos[((2 k (m+2) π)/n)] (z^2))/((r^4)-2 (r^2) (s^2) Cos[((4 k π)/n)] (z^2)+(s^4) (z^4)))

Basis: (((r^2) Cos[ρ]-(s^2) Cos[ρ+2 θ] (z^2))/((r^4)-2 (r^2) (s^2) Cos[2 θ] (z^2)+(s^4) (z^4)))==(1/(2 r))(((r Cos[ρ]-s Cos[ρ+θ] z)/((r^2)-2r s Cos[θ] z+(s^2) (z^2))) +((r Cos[ρ]+s Cos[ρ+θ] z)/((r^2)+2r s Cos[θ] z+(s^2) (z^2))))

Rule 1.1.3.2.7.1.4.1.2.1.2: If ((n-2)/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ (a/b)≯0, let (r/s)=(((-(a/b)))^(1/n)), then

∫((x^m)/(a+b (x^n)))dx  ⟶  ((2 (r^(m+2)))/(a n (s^m)))∫(1/((r^2)-(s^2) (x^2)))dx+((4 (r^(m+2)))/(a n (s^m)))(∑_(k=1)^((n-2)/4))∫(((r^2) Cos[((2 k m π)/n)]-(s^2) Cos[((2 k (m+2) π)/n)] (x^2))/((r^4)-2 (r^2) (s^2) Cos[((4 k π)/n)] (x^2)+(s^4) (x^4)))dx

  ⟶  ((2 (r^(m+2)))/(a n (s^m)))∫(1/((r^2)-(s^2) (x^2)))dx+((2 (r^(m+1)))/(a n (s^m)))(∑_(k=1)^((n-2)/4))(∫((r Cos[((2 k m π)/n)]-s Cos[((2 k (m+1) π)/n)] x)/((r^2)-2r s Cos[((2 k π)/n)] x+(s^2) (x^2)))dx+∫((r Cos[((2 k m π)/n)]+s Cos[((2 k (m+1) π)/n)] x)/((r^2)+2r s Cos[((2 k π)/n)] x+(s^2) (x^2)))dx)

Program code:

Int[x_^m_./(a_+b_.*x_^n_),x_Symbol] :=
  Module[{r=Numerator[Rt[-a/b,n]], s=Denominator[Rt[-a/b,n]], k, u},
  u=Int[(r*Cos[2*k*m*Pi/n]-s*Cos[2*k*(m+1)*Pi/n]*x)/(r^2-2*r*s*Cos[2*k*Pi/n]*x+s^2*x^2),x] + 
    Int[(r*Cos[2*k*m*Pi/n]+s*Cos[2*k*(m+1)*Pi/n]*x)/(r^2+2*r*s*Cos[2*k*Pi/n]*x+s^2*x^2),x];
  2*r^(m+2)/(a*n*s^m)*Int[1/(r^2-s^2*x^2),x] + Dist[2*r^(m+1)/(a*n*s^m),Sum[u,{k,1,(n-2)/4}],x]] /;
 FreeQ[{a,b},x] && IGtQ[(n-2)/4,0] && IGtQ[m,0] && LtQ[m,n-1] && NegQ[a/b]

2.  ∫((x^m)/(a+b (x^n)))dx  when  (n/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1

1.  ∫((x^2)/(a+b (x^4)))dx

1:  ∫((x^2)/(a+b (x^4)))dx  when  (a/b)>0

Derivation: Algebraic expansion

Basis: If (r/s)=(Sqrt[(a/b)]), then ((x^2)/(a+b (x^4)))==((r+s (x^2))/(2 s (a+b (x^4))))-((r-s (x^2))/(2 s (a+b (x^4))))

Note: Resulting integrands are of the form ((d+e (x^2))/(a+c (x^4))) where c (d^2)-a (e^2)==0 as required by the algebraic trinomial rules.

Rule 1.1.3.2.7.1.4.1.2.2.1.1: If (a/b)>0, let (r/s)=(Sqrt[(a/b)]), then

∫((x^2)/(a+b (x^4)))dx  ⟶  (1/(2s))∫((r+s (x^2))/(a+b (x^4)))dx-(1/(2s))∫((r-s (x^2))/(a+b (x^4)))dx

Program code:

Int[x_^2/(a_+b_.*x_^4),x_Symbol] :=
  With[{r=Numerator[Rt[a/b,2]], s=Denominator[Rt[a/b,2]]},
  1/(2*s)*Int[(r+s*x^2)/(a+b*x^4),x] - 
  1/(2*s)*Int[(r-s*x^2)/(a+b*x^4),x]] /;
FreeQ[{a,b},x] && (GtQ[a/b,0] || PosQ[a/b] && AtomQ[SplitProduct[SumBaseQ,a]] && AtomQ[SplitProduct[SumBaseQ,b]])

2:  ∫((x^2)/(a+b (x^4)))dx  when  (a/b)≯0

Reference: G&R 2.132.3.2', CRC 82'

Derivation: Algebraic expansion

Basis: If  (r/s)=(Sqrt[-(a/b)]), then (z/(a+b (z^2)))==(s/(2b(r+s z)))-(s/(2b(r-s z)))

Rule 1.1.3.2.7.1.4.1.2.2.1.2: If  (a/b)≯0, let (r/s)=(Sqrt[-(a/b)]), then

∫((x^2)/(a+b (x^4)))dx  ⟶  (s/(2 b))∫(1/(r+s (x^2)))dx-(s/(2 b))∫(1/(r-s (x^2)))dx

Program code:

Int[x_^2/(a_+b_.*x_^4),x_Symbol] :=
  With[{r=Numerator[Rt[-a/b,2]], s=Denominator[Rt[-a/b,2]]},
  s/(2*b)*Int[1/(r+s*x^2),x] -
  s/(2*b)*Int[1/(r-s*x^2),x]] /;
FreeQ[{a,b},x] && Not[GtQ[a/b,0]]

2.  ∫((x^m)/(a+b (x^n)))dx  when  (n/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ n>4

1:  ∫((x^m)/(a+b (x^n)))dx  when  (n/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ (a/b)>0

Reference: G&R 2.132.3.1', CRC 81'

Derivation: Algebraic expansion

Basis: If  (r/s)=((((a/b)))^(1/4)), then (z/(a+b (z^4)))==((s^3)/(2(Sqrt[2])b r((r^2)-(Sqrt[2]) r s z+(s^2) (z^2))))-((s^3)/(2(Sqrt[2])b r((r^2)+(Sqrt[2]) r s z+(s^2) (z^2))))

Rule 1.1.3.2.7.1.4.1.2.2.2.1: If  (n/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ (a/b)>0, let (r/s)=((((a/b)))^(1/4)), then

∫((x^m)/(a+b (x^n)))dx  ⟶  ((s^3)/(2 (Sqrt[2]) b r))∫((x^(m-n/4))/((r^2)-(Sqrt[2]) r s (x^(n/4))+(s^2) (x^(n/2))))dx-((s^3)/(2 (Sqrt[2]) b r))∫((x^(m-n/4))/((r^2)+(Sqrt[2]) r s (x^(n/4))+(s^2) (x^(n/2))))dx

Program code:

Int[x_^m_./(a_+b_.*x_^n_),x_Symbol] :=
  With[{r=Numerator[Rt[a/b,4]], s=Denominator[Rt[a/b,4]]},
  s^3/(2*Sqrt[2]*b*r)*Int[x^(m-n/4)/(r^2-Sqrt[2]*r*s*x^(n/4)+s^2*x^(n/2)),x] -
  s^3/(2*Sqrt[2]*b*r)*Int[x^(m-n/4)/(r^2+Sqrt[2]*r*s*x^(n/4)+s^2*x^(n/2)),x]] /;
FreeQ[{a,b},x] && IGtQ[n/4,0] && IGtQ[m,0] && LtQ[m,n-1] && GtQ[a/b,0]

2.  ∫((x^m)/(a+b (x^n)))dx  when  (n/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<n-1∧ (a/b)≯0

1:  ∫((x^m)/(a+b (x^n)))dx  when  (n/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<(n/2) ∧ (a/b)≯0

Reference: G&R 2.132.1.2', CRC 78'

Derivation: Algebraic expansion

Basis: If  (r/s)=(Sqrt[-(a/b)]), then (1/(a+b (z^2)))==(r/(2a(r+s z)))+(r/(2a(r-s z)))

Rule 1.1.3.2.7.1.4.1.2.2.2.2.1: If  (n/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m<(n/2) ∧ (a/b)≯0, let (r/s)=(Sqrt[-(a/b)]), then

∫((x^m)/(a+b (x^n)))dx  ⟶  (r/(2 a))∫((x^m)/(r+s (x^(n/2))))dx+(r/(2 a))∫((x^m)/(r-s (x^(n/2))))dx

Program code:

Int[x_^m_/(a_+b_.*x_^n_),x_Symbol] :=
  With[{r=Numerator[Rt[-a/b,2]], s=Denominator[Rt[-a/b,2]]},
  r/(2*a)*Int[x^m/(r+s*x^(n/2)),x] +
  r/(2*a)*Int[x^m/(r-s*x^(n/2)),x]] /;
FreeQ[{a,b},x] && IGtQ[n/4,0] && IGtQ[m,0] && LtQ[m,n/2] && Not[GtQ[a/b,0]]

2:  ∫((x^m)/(a+b (x^n)))dx  when  (n/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ (n/2)≤m<n ∧ (a/b)≯0

Reference: G&R 2.132.3.2', CRC 82'

Derivation: Algebraic expansion

Basis: If  (r/s)=(Sqrt[-(a/b)]), then (z/(a+b (z^2)))==(s/(2b(r+s z)))-(s/(2b(r-s z)))

Rule 1.1.3.2.7.1.4.1.2.2.2.2.2: If  (n/4)∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ (n/2)≤m<n ∧ (a/b)≯0, let (r/s)=(Sqrt[-(a/b)]), then

∫((x^m)/(a+b (x^n)))dx  ⟶  (s/(2 b))∫((x^(m-n/2))/(r+s (x^(n/2))))dx-(s/(2 b))∫((x^(m-n/2))/(r-s (x^(n/2))))dx

Program code:

Int[x_^m_/(a_+b_.*x_^n_),x_Symbol] :=
  With[{r=Numerator[Rt[-a/b,2]], s=Denominator[Rt[-a/b,2]]},
  s/(2*b)*Int[x^(m-n/2)/(r+s*x^(n/2)),x] -
  s/(2*b)*Int[x^(m-n/2)/(r-s*x^(n/2)),x]] /;
FreeQ[{a,b},x] && IGtQ[n/4,0] && IGtQ[m,0] && LeQ[n/2,m] && LtQ[m,n] && Not[GtQ[a/b,0]]

2:  ∫((x^m)/(a+b (x^n)))dx  when n∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m>2 n-1

Derivation: Algebraic expansion

Rule 1.1.3.2.7.1.4.2: If  n∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m>2 n-1, then

∫((x^m)/(a+b (x^n)))dx  ⟶  ∫PolynomialDivide[(x^m),a+b (x^n),x]dx

Program code:

Int[x_^m_/(a_+b_.*x_^n_),x_Symbol] :=
  Int[PolynomialDivide[x^m,(a+b*x^n),x],x] /;
FreeQ[{a,b},x] && IGtQ[m,0] && IGtQ[n,0] && GtQ[m,2*n-1]

5.  ∫((x^m)/(Sqrt[a+b (x^n)]))dx  when  n∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])

1.  ∫(x/(Sqrt[a+b (x^3)]))dx

1:  ∫(x/(Sqrt[a+b (x^3)]))dx  when  a>0

Derivation: Algebraic expansion

Note: ((Sqrt[2])/(Sqrt[2+(Sqrt[3])]))==-1+(Sqrt[3])

Rule: If  a>0, let (r/s)->((((b/a)))^(1/3)), then

∫(x/(Sqrt[a+b (x^3)]))dx  ⟶  (((Sqrt[2]) s)/((Sqrt[2+(Sqrt[3])]) r)) ∫(1/(Sqrt[a+b (x^3)]))dx+(1/r) ∫(((1-(Sqrt[3])) s+r x)/(Sqrt[a+b (x^3)]))dx

Program code:

Int[x_/Sqrt[a_+b_.*x_^3],x_Symbol] :=
  With[{r=Numer[Rt[b/a,3]], s=Denom[Rt[b/a,3]]},
  -(1-Sqrt[3])*s/r*Int[1/Sqrt[a+b*x^3],x] + 1/r*Int[((1-Sqrt[3])*s+r*x)/Sqrt[a+b*x^3],x]] /;
FreeQ[{a,b},x] && PosQ[a]

2:  ∫(x/(Sqrt[a+b (x^3)]))dx  when  a≯0

Derivation: Algebraic expansion

Note: ((Sqrt[2])/(Sqrt[2-(Sqrt[3])]))==1+(Sqrt[3])

Rule: If  a≯0, let (r/s)->((((b/a)))^(1/3)), then

∫(x/(Sqrt[a+b (x^3)]))dx  ⟶  -(((Sqrt[2]) s)/((Sqrt[2-(Sqrt[3])]) r)) ∫(1/(Sqrt[a+b (x^3)]))dx+(1/r) ∫(((1+(Sqrt[3])) s+r x)/(Sqrt[a+b (x^3)]))dx

Program code:

Int[x_/Sqrt[a_+b_.*x_^3],x_Symbol] :=
  With[{r=Numer[Rt[b/a,3]], s=Denom[Rt[b/a,3]]},
  -(1+Sqrt[3])*s/r*Int[1/Sqrt[a+b*x^3],x] + 1/r*Int[((1+Sqrt[3])*s+r*x)/Sqrt[a+b*x^3],x]] /;
FreeQ[{a,b},x] && NegQ[a]

2.  ∫((x^2)/(Sqrt[a+b (x^4)]))dx

1:  ∫((x^2)/(Sqrt[a+b (x^4)]))dx  when (b/a)>0

Derivation: Algebraic expansion

Rule 1.1.3.2.7.1.5.2.1: If  (b/a)>0, let q->(Sqrt[(b/a)]), then

∫((x^2)/(Sqrt[a+b (x^4)]))dx  ⟶  (1/q) ∫(1/(Sqrt[a+b (x^4)]))dx-(1/q) ∫((1-q (x^2))/(Sqrt[a+b (x^4)]))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^4],x_Symbol] :=
  With[{q=Rt[b/a,2]},
  1/q*Int[1/Sqrt[a+b*x^4],x] - 1/q*Int[(1-q*x^2)/Sqrt[a+b*x^4],x]] /;
FreeQ[{a,b},x] && PosQ[b/a]

2.  ∫((x^2)/(Sqrt[a+b (x^4)]))dx  when  (b/a)≯0

1:  ∫((x^2)/(Sqrt[a+b (x^4)]))dx  when a<0 ∧ b>0

Derivation: Algebraic expansion

Rule 1.1.3.2.7.1.5.2.2.1: If  (b/a)≯0 ∧ a<0, let q->(Sqrt[-(b/a)]), then

∫((x^2)/(Sqrt[a+b (x^4)]))dx  ⟶  (1/q) ∫(1/(Sqrt[a+b (x^4)]))dx-(1/q) ∫((1-q (x^2))/(Sqrt[a+b (x^4)]))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^4],x_Symbol] :=
  With[{q=Rt[-b/a,2]},
  1/q*Int[1/Sqrt[a+b*x^4],x] - 1/q*Int[(1-q*x^2)/Sqrt[a+b*x^4],x]] /;
FreeQ[{a,b},x] && LtQ[a,0] && GtQ[b,0]

2:  ∫((x^2)/(Sqrt[a+b (x^4)]))dx  when (b/a)≯0 ∧ a≮0

Derivation: Algebraic expansion

Rule 1.1.3.2.7.1.5.2.2.2: If  (b/a)≯0 ∧ a≮0, let q->(Sqrt[-(b/a)]), then

∫((x^2)/(Sqrt[a+b (x^4)]))dx  ⟶  -(1/q) ∫(1/(Sqrt[a+b (x^4)]))dx+(1/q) ∫((1+q (x^2))/(Sqrt[a+b (x^4)]))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^4],x_Symbol] :=
  With[{q=Rt[-b/a,2]},
  -1/q*Int[1/Sqrt[a+b*x^4],x] + 1/q*Int[(1+q*x^2)/Sqrt[a+b*x^4],x]] /;
FreeQ[{a,b},x] && NegQ[b/a]

3:  ∫((x^4)/(Sqrt[a+b (x^6)]))dx

Derivation: Algebraic expansion

Rule 1.1.3.2.7.1.5.3: Let (r/s)->((((b/a)))^(1/3)), then

∫((x^4)/(Sqrt[a+b (x^6)]))dx  ⟶  ((((Sqrt[3])-1) (s^2))/(2 (r^2)))∫(1/(Sqrt[a+b (x^6)]))dx-(1/(2 (r^2)))∫((((Sqrt[3])-1) (s^2)-2 (r^2) (x^4))/(Sqrt[a+b (x^6)]))dx

  ⟶  (((1+(Sqrt[3])) r x (Sqrt[a+b (x^6)]))/(2 b (s+(1+(Sqrt[3])) r (x^2))))-(((3^(1/4)) s x (s+r (x^2)) (Sqrt[(((s^2)-r s (x^2)+(r^2) (x^4))/(((s+(1+(Sqrt[3])) r (x^2)))^2))]))/(2 (r^2) (Sqrt[a+b (x^6)]) (Sqrt[((r (x^2) (s+r (x^2)))/(((s+(1+(Sqrt[3])) r (x^2)))^2))]))) EllipticE[ArcCos[((s+(1-(Sqrt[3])) r (x^2))/(s+(1+(Sqrt[3])) r (x^2)))],((2+(Sqrt[3]))/4)]-
(((1-(Sqrt[3])) s x (s+r (x^2)) (Sqrt[(((s^2)-r s (x^2)+(r^2) (x^4))/(((s+(1+(Sqrt[3])) r (x^2)))^2))]))/(4 (3^(1/4)) (r^2) (Sqrt[a+b (x^6)]) (Sqrt[((r (x^2) (s+r (x^2)))/(((s+(1+(Sqrt[3])) r (x^2)))^2))]))) EllipticF[ArcCos[((s+(1-(Sqrt[3])) r (x^2))/(s+(1+(Sqrt[3])) r (x^2)))],((2+(Sqrt[3]))/4)]

Program code:

Int[x_^4/Sqrt[a_+b_.*x_^6],x_Symbol] :=
  With[{r=Numer[Rt[b/a,3]], s=Denom[Rt[b/a,3]]},
  (Sqrt[3]-1)*s^2/(2*r^2)*Int[1/Sqrt[a+b*x^6],x] - 1/(2*r^2)*Int[((Sqrt[3]-1)*s^2-2*r^2*x^4)/Sqrt[a+b*x^6],x]] /;
FreeQ[{a,b},x]

(* Int[x_^4/Sqrt[a_+b_.*x_^6],x_Symbol] :=
  With[{r=Numer[Rt[b/a,3]], s=Denom[Rt[b/a,3]]},
  (1+Sqrt[3])*r*x*Sqrt[a+b*x^6]/(2*b*(s+(1+Sqrt[3])*r*x^2)) - 
  3^(1/4)*s*x*(s+r*x^2)*Sqrt[(s^2-r*s*x^2+r^2*x^4)/(s+(1+Sqrt[3])*r*x^2)^2]/
    (2*r^2*Sqrt[a+b*x^6]*Sqrt[r*x^2*(s+r*x^2)/(s+(1+Sqrt[3])*r*x^2)^2])*
    EllipticE[ArcCos[(s+(1-Sqrt[3])*r*x^2)/(s+(1+Sqrt[3])*r*x^2)],(2+Sqrt[3])/4] - 
  (1-Sqrt[3])*s*x*(s+r*x^2)*Sqrt[(s^2-r*s*x^2+r^2*x^4)/(s+(1+Sqrt[3])*r*x^2)^2]/
    (4*3^(1/4)*r^2*Sqrt[a+b*x^6]*Sqrt[r*x^2*(s+r*x^2)/(s+(1+Sqrt[3])*r*x^2)^2])*
    EllipticF[ArcCos[(s+(1-Sqrt[3])*r*x^2)/(s+(1+Sqrt[3])*r*x^2)],(2+Sqrt[3])/4]] /;
FreeQ[{a,b},x] *)

4:  ∫((x^2)/(Sqrt[a+b (x^8)]))dx

Derivation: Algebraic expansion

Basis: ((x^2)/(Sqrt[a+b (x^8)]))==((1+((((b/a)))^(1/4)) (x^2))/(2 ((((b/a)))^(1/4)) (Sqrt[a+b (x^8)])))-((1-((((b/a)))^(1/4)) (x^2))/(2 ((((b/a)))^(1/4)) (Sqrt[a+b (x^8)])))

Note: Integrands are of the form ((c+d (x^2))/(Sqrt[a+b (x^8)])) where b (c^4)-a (d^4)==0 for which there is a terminal rule.

Rule 1.1.3.2.7.1.5.4:

∫((x^2)/(Sqrt[a+b (x^8)]))dx  ⟶  (( 1)/(2 ((((b/a)))^(1/4))))∫((1+((((b/a)))^(1/4)) (x^2))/(Sqrt[a+b (x^8)]))dx-(1/(2 ((((b/a)))^(1/4))))∫((1-((((b/a)))^(1/4)) (x^2))/(Sqrt[a+b (x^8)]))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^8],x_Symbol] :=
  1/(2*Rt[b/a,4])*Int[(1+Rt[b/a,4]*x^2)/Sqrt[a+b*x^8],x] - 
  1/(2*Rt[b/a,4])*Int[(1-Rt[b/a,4]*x^2)/Sqrt[a+b*x^8],x] /;
FreeQ[{a,b},x]

6.  ∫((x^m)/(((a+b (x^n)))^(1/4)))dx  when  n∈(SuperPlus[ℤ])∧ 2 m∈(SuperPlus[ℤ])

1.  ∫((x^2)/(((a+b (x^4)))^(1/4)))dx

1:  ∫((x^2)/(((a+b (x^4)))^(1/4)))dx  when  (b/a)>0

Reference: G&R 2.110.1, CRC 88b

Derivation: Binomial recurrence 1b

Rule 1.1.3.2.7.1.6.1.1: If (b/a)>0, then

∫((x^2)/(((a+b (x^4)))^(1/4)))dx  ⟶  ((x^3)/(2 (((a+b (x^4)))^(1/4))))-(a/2) ∫((x^2)/(((a+b (x^4)))^(5/4)))dx

Program code:

Int[x_^2/(a_+b_.*x_^4)^(1/4),x_Symbol] :=
  x^3/(2*(a+b*x^4)^(1/4)) - a/2*Int[x^2/(a+b*x^4)^(5/4),x] /;
FreeQ[{a,b},x] && PosQ[b/a]

2:  ∫((x^2)/(((a+b (x^4)))^(1/4)))dx  when  (b/a)≯0

Reference: G&R 2.110.5, CRC 88a

Derivation: Binomial recurrence 3a

Rule 1.1.3.2.7.1.6.1.2: If (b/a)≯0, then

∫((x^2)/(((a+b (x^4)))^(1/4)))dx  ⟶  ((((a+b (x^4)))^(3/4))/(2 b x))+(a/(2 b)) ∫(1/((x^2) (((a+b (x^4)))^(1/4))))dx

Program code:

Int[x_^2/(a_+b_.*x_^4)^(1/4),x_Symbol] :=
  (a+b*x^4)^(3/4)/(2*b*x) + a/(2*b)*Int[1/(x^2*(a+b*x^4)^(1/4)),x] /;
FreeQ[{a,b},x] && NegQ[b/a]

2.  ∫(1/((x^2) (((a+b (x^4)))^(1/4))))dx

1:  ∫(1/((x^2) (((a+b (x^4)))^(1/4))))dx  when  (b/a)>0

Reference: G&R 2.110.3

Derivation: Binomial recurrence 1a

Derivation: Integration by parts

Rule 1.1.3.2.7.1.6.2.1: If (b/a)>0, then

∫(1/((x^2) (((a+b (x^4)))^(1/4))))dx  ⟶  -(1/(x (((a+b (x^4)))^(1/4))))-b ∫((x^2)/(((a+b (x^4)))^(5/4)))dx

Program code:

Int[1/(x_^2*(a_+b_.*x_^4)^(1/4)),x_Symbol] :=
  -1/(x*(a+b*x^4)^(1/4)) - b*Int[x^2/(a+b*x^4)^(5/4),x] /;
FreeQ[{a,b},x] && PosQ[b/a]

2:  ∫(1/((x^2) (((a+b (x^4)))^(1/4))))dx  when  (b/a)≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((x (((1+(a/(b (x^4)))))^(1/4)))/(((a+b (x^4)))^(1/4)))==0

Rule 1.1.3.2.7.1.6.2.2: If (b/a)≯0, then

∫(1/((x^2) (((a+b (x^4)))^(1/4))))dx  ⟶  ((x (((1+(a/(b (x^4)))))^(1/4)))/(((a+b (x^4)))^(1/4))) ∫(1/((x^3) (((1+(a/(b (x^4)))))^(1/4))))dx

Program code:

Int[1/(x_^2*(a_+b_.*x_^4)^(1/4)),x_Symbol] :=
  x*(1+a/(b*x^4))^(1/4)/(a+b*x^4)^(1/4)*Int[1/(x^3*(1+a/(b*x^4))^(1/4)),x] /;
FreeQ[{a,b},x] && NegQ[b/a]

3.  ∫((Sqrt[c x])/(((a+b (x^2)))^(1/4)))dx

1:  ∫((Sqrt[c x])/(((a+b (x^2)))^(1/4)))dx  when  (b/a)>0

Reference: G&R 2.110.1, CRC 88b

Derivation: Binomial recurrence 1b

Rule 1.1.3.2.7.1.6.3.2: If (b/a)>0, then

∫((Sqrt[c x])/(((a+b (x^2)))^(1/4)))dx  ⟶  ((x (Sqrt[c x]))/(((a+b (x^2)))^(1/4)))-(a/2)∫((Sqrt[c x])/(((a+b (x^2)))^(5/4)))dx

Program code:

Int[Sqrt[c_*x_]/(a_+b_.*x_^2)^(1/4),x_Symbol] :=
  x*Sqrt[c*x]/(a+b*x^2)^(1/4) - a/2*Int[Sqrt[c*x]/(a+b*x^2)^(5/4),x] /;
FreeQ[{a,b,c},x] && PosQ[b/a]

2:  ∫((Sqrt[c x])/(((a+b (x^2)))^(1/4)))dx  when  (b/a)≯0

Reference: G&R 2.110.5, CRC 88a

Derivation: Binomial recurrence 3a

Rule 1.1.3.2.7.1.6.3.2: If (b/a)≯0, then

∫((Sqrt[c x])/(((a+b (x^2)))^(1/4)))dx  ⟶  ((c (((a+b (x^2)))^(3/4)))/(b (Sqrt[c x])))+((a (c^2))/(2 b))∫(1/((((c x))^(3/2)) (((a+b (x^2)))^(1/4))))dx

Program code:

Int[Sqrt[c_*x_]/(a_+b_.*x_^2)^(1/4),x_Symbol] :=
  c*(a+b*x^2)^(3/4)/(b*Sqrt[c*x]) + a*c^2/(2*b)*Int[1/((c*x)^(3/2)*(a+b*x^2)^(1/4)),x] /;
FreeQ[{a,b,c},x] && NegQ[b/a]

4.  ∫(1/((((c x))^(3/2)) (((a+b (x^2)))^(1/4))))dx

1:  ∫(1/((((c x))^(3/2)) (((a+b (x^2)))^(1/4))))dx  when  (b/a)>0

Reference: G&R 2.110.3

Derivation: Binomial recurrence 1a

Derivation: Integration by parts

Rule 1.1.3.2.7.1.6.4.1: If (b/a)>0, then

∫(1/((((c x))^(3/2)) (((a+b (x^2)))^(1/4))))dx  ⟶  -(2/(c (Sqrt[c x]) (((a+b (x^2)))^(1/4))))-(b/(c^2))∫((Sqrt[c x])/(((a+b (x^2)))^(5/4)))dx

Program code:

Int[1/((c_.*x_)^(3/2)*(a_+b_.*x_^2)^(1/4)),x_Symbol] :=
  -2/(c*Sqrt[c*x]*(a+b*x^2)^(1/4)) - b/c^2*Int[Sqrt[c*x]/(a+b*x^2)^(5/4),x] /;
FreeQ[{a,b,c},x] && PosQ[b/a]

2:  ∫(1/((((c x))^(3/2)) (((a+b (x^2)))^(1/4))))dx  when  (b/a)≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sqrt[c x]) (((1+(a/(b (x^2)))))^(1/4)))/(((a+b (x^2)))^(1/4)))==0

Rule 1.1.3.2.7.1.6.4.2: If (b/a)≯0, then

∫(1/((((c x))^(3/2)) (((a+b (x^2)))^(1/4))))dx  ⟶  (((Sqrt[c x]) (((1+(a/(b (x^2)))))^(1/4)))/((c^2) (((a+b (x^2)))^(1/4)))) ∫(1/((x^2) (((1+(a/(b (x^2)))))^(1/4))))dx

Program code:

Int[1/((c_.*x_)^(3/2)*(a_+b_.*x_^2)^(1/4)),x_Symbol] :=
  Sqrt[c*x]*(1+a/(b*x^2))^(1/4)/(c^2*(a+b*x^2)^(1/4))*Int[1/(x^2*(1+a/(b*x^2))^(1/4)),x] /;
FreeQ[{a,b,c},x] && NegQ[b/a]

7.  ∫((Sqrt[c x])/(Sqrt[a+b (x^2)]))dx  when  -(b/a)>0

1.  ∫((Sqrt[x])/(Sqrt[a+b (x^2)]))dx  when  -(b/a)>0

1:  ∫((Sqrt[x])/(Sqrt[a+b (x^2)]))dx  when -(b/a)>0 ∧ a>0

Derivation: Integration by substitution

Basis: If  -(b/a)>0 ∧ a>0, then ((Sqrt[x])/(Sqrt[a+b (x^2)]))==-(2/((Sqrt[a])(((-(b/a)))^(3/4)))) Subst[((Sqrt[1-2 (x^2)])/(Sqrt[1-(x^2)])),x,((Sqrt[1-(Sqrt[-(b/a)]) x])/(Sqrt[2]))](∂_x)((Sqrt[1-(Sqrt[-(b/a)]) x])/(Sqrt[2]))

Rule 1.1.3.2.7.1.7.1.1: If  -(b/a)>0 ∧ a>0, then

∫((Sqrt[x])/(Sqrt[a+b (x^2)]))dx  ⟶  -(2/((Sqrt[a])(((-(b/a)))^(3/4))))Subst[∫((Sqrt[1-2 (x^2)])/(Sqrt[1-(x^2)]))dx,x,((Sqrt[1-(Sqrt[-(b/a)]) x])/(Sqrt[2]))]

Program code:

Int[Sqrt[x_]/Sqrt[a_+b_.*x_^2],x_Symbol] :=
  -2/(Sqrt[a]*(-b/a)^(3/4))*Subst[Int[Sqrt[1-2*x^2]/Sqrt[1-x^2],x],x,Sqrt[1-Sqrt[-b/a]*x]/Sqrt[2]] /;
FreeQ[{a,b},x] && GtQ[-b/a,0] && GtQ[a,0]

2:  ∫((Sqrt[x])/(Sqrt[a+b (x^2)]))dx  when -(b/a)>0 ∧ a≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[1+((b (x^2))/a)])/(Sqrt[a+b (x^2)]))==0

Rule 1.1.3.2.7.1.7.1.2: If  -(b/a)>0 ∧ a≯0, then

∫((Sqrt[x])/(Sqrt[a+b (x^2)]))dx  ⟶  ((Sqrt[1+((b (x^2))/a)])/(Sqrt[a+b (x^2)]))∫((Sqrt[x])/(Sqrt[1+((b (x^2))/a)]))dx

Program code:

Int[Sqrt[x_]/Sqrt[a_+b_.*x_^2],x_Symbol] :=
  Sqrt[1+b*x^2/a]/Sqrt[a+b*x^2]*Int[Sqrt[x]/Sqrt[1+b*x^2/a],x] /;
FreeQ[{a,b},x] && GtQ[-b/a,0] && Not[GtQ[a,0]]

2:  ∫((Sqrt[c x])/(Sqrt[a+b (x^2)]))dx  when -(b/a)>0

Derivation: Piecewise constant extraction

Rule 1.1.3.2.7.1.7.2: If  -(b/a)>0, then

∫((Sqrt[c x])/(Sqrt[a+b (x^2)]))dx  ⟶  ((Sqrt[c x])/(Sqrt[x])) ∫((Sqrt[x])/(Sqrt[a+b (x^2)]))dx

Program code:

Int[Sqrt[c_*x_]/Sqrt[a_+b_.*x_^2],x_Symbol] :=
  Sqrt[c*x]/Sqrt[x]*Int[Sqrt[x]/Sqrt[a+b*x^2],x] /;
FreeQ[{a,b,c},x] && GtQ[-b/a,0]

8:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ m>n-1 ∧ m+n p+1≠0

Reference: G&R 2.110.5, CRC 88a

Derivation: Binomial recurrence 3a

Derivation: Inverted integration by parts

Rule 1.1.3.2.7.1.8: If  n∈(SuperPlus[ℤ])∧ m>n-1 ∧ m+n p+1≠0, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((c^(n-1))(((c x))^(m-n+1)) (((a+b (x^n)))^(p+1)))/(b (m+n p+1)))-((a (c^n)(m-n+1))/(b (m+n p+1)))∫(((c x))^(m-n)) (((a+b (x^n)))^p)dx

Program code:

Int[(c_.*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  c^(n-1)*(c*x)^(m-n+1)*(a+b*x^n)^(p+1)/(b*(m+n*p+1)) -
  a*c^n*(m-n+1)/(b*(m+n*p+1))*Int[(c*x)^(m-n)*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,p},x] && IGtQ[n,0] && GtQ[m,n-1] && NeQ[m+n*p+1,0] && IntBinomialQ[a,b,c,n,m,p,x]

Int[(c_.*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  c^(n-1)*(c*x)^(m-n+1)*(a+b*x^n)^(p+1)/(b*(m+n*p+1)) -
  a*c^n*(m-n+1)/(b*(m+n*p+1))*Int[(c*x)^(m-n)*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,m,p},x] && IGtQ[n,0] && SumSimplerQ[m,-n] && NeQ[m+n*p+1,0] && ILtQ[Simplify[(m+1)/n+p],0]

Int[(c_.*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  c^(2*n-1)*(c*x)^(m-2*n+1)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(b1*b2*(m+2*n*p+1)) - 
  a1*a2*c^(2*n)*(m-2*n+1)/(b1*b2*(m+2*n*p+1))*Int[(c*x)^(m-2*n)*(a1+b1*x^n)^p*(a2+b2*x^n)^p,x] /;
FreeQ[{a1,b1,a2,b2,c,p},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && GtQ[m,2*n-1] && NeQ[m+2*n*p+1,0] && 
  IntBinomialQ[a1*a2,b1*b2,c,2*n,m,p,x]

Int[(c_.*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  c^(2*n-1)*(c*x)^(m-2*n+1)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(b1*b2*(m+2*n*p+1)) - 
  a1*a2*c^(2*n)*(m-2*n+1)/(b1*b2*(m+2*n*p+1))*Int[(c*x)^(m-2*n)*(a1+b1*x^n)^p*(a2+b2*x^n)^p,x] /;
FreeQ[{a1,b1,a2,b2,c,m,p},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && SumSimplerQ[m,-2*n] && NeQ[m+2*n*p+1,0] && 
  ILtQ[Simplify[(m+1)/(2*n)+p],0]

9:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ m<-1

Reference: G&R 2.110.6, CRC 88c

Derivation: Binomial recurrence 3b

Derivation: Integration by parts

Basis: (x^m) (((a+b (x^n)))^p)==((x^m)/(((a+b (x^n)))^((m+n+1)/n)))(((a+b (x^n)))^(((m+1)/n)+p+1))

Basis: ∫((x^m)/(((a+b (x^n)))^((m+n+1)/n)))dx==((x^(m+1))/((((a+b (x^n)))^((m+1)/n)) (a (m+1))))

Note: Requirement that m+1<n ensures new term is a proper fraction.

Rule 1.1.3.2.7.1.9: If  n∈(SuperPlus[ℤ])∧ m<-1, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((((c x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a c(m+1)))-((b (m+n (p+1)+1))/(a (c^n)(m+1)))∫(((c x))^(m+n)) (((a+b (x^n)))^p)dx

Program code:

Int[(c_.*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a+b*x^n)^(p+1)/(a*c*(m+1)) -
  b*(m+n*(p+1)+1)/(a*c^n*(m+1))*Int[(c*x)^(m+n)*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,p},x] && IGtQ[n,0] && LtQ[m,-1] && IntBinomialQ[a,b,c,n,m,p,x]

Int[(c_.*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a+b*x^n)^(p+1)/(a*c*(m+1)) -
  b*(m+n*(p+1)+1)/(a*c^n*(m+1))*Int[(c*x)^(m+n)*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,m,p},x] && IGtQ[n,0] && SumSimplerQ[m,n] && ILtQ[Simplify[(m+1)/n+p],0]

Int[(c_.*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(a1*a2*c*(m+1)) - 
  b1*b2*(m+2*n*(p+1)+1)/(a1*a2*c^(2*n)*(m+1))*Int[(c*x)^(m+2*n)*(a1+b1*x^n)^p*(a2+b2*x^n)^p,x] /;
FreeQ[{a1,b1,a2,b2,c,p},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && LtQ[m,-1] && IntBinomialQ[a1*a2,b1*b2,c,2*n,m,p,x]

Int[(c_.*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(a1*a2*c*(m+1)) - 
  b1*b2*(m+2*n*(p+1)+1)/(a1*a2*c^(2*n)*(m+1))*Int[(c*x)^(m+2*n)*(a1+b1*x^n)^p*(a2+b2*x^n)^p,x] /;
FreeQ[{a1,b1,a2,b2,c,m,p},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && SumSimplerQ[m,2*n] && ILtQ[Simplify[(m+1)/(2*n)+p],0]

10:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (((c x))^m) F[x]==(k/c) Subst[(x^(k (m+1)-1))F[((x^k)/c)],x,(((c x))^(1/k))] (∂_x)(((c x))^(1/k))

Rule 1.1.3.2.7.1.10: If  n∈(SuperPlus[ℤ])∧ m∈𝔽, let k=Denominator[m], then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (k/c) Subst[∫(x^(k (m+1)-1)) (((a+((b (x^(k n)))/(c^n))))^p) dx,x,(((c x))^(1/k))]

Program code:

Int[(c_.*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  k/c*Subst[Int[x^(k*(m+1)-1)*(a+b*x^(k*n)/c^n)^p,x],x,(c*x)^(1/k)]] /;
FreeQ[{a,b,c,p},x] && IGtQ[n,0] && FractionQ[m] && IntBinomialQ[a,b,c,n,m,p,x]

Int[(c_.*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  k/c*Subst[Int[x^(k*(m+1)-1)*(a1+b1*x^(k*n)/c^n)^p*(a2+b2*x^(k*n)/c^n)^p,x],x,(c*x)^(1/k)]] /;
FreeQ[{a1,b1,a2,b2,c,p},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && FractionQ[m] && IntBinomialQ[a1*a2,b1*b2,c,2*n,m,p,x]

11.  ∫(x^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ m∈ℤ ∧ Denominator[p+((m+1)/n)]<Denominator[p]

1.  ∫(x^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ m∈ℤ ∧ p+((m+1)/n)∈ℤ

1:  ∫(x/(((a+b (x^3)))^(2/3)))dx

Rule 1.1.3.2.7.1.11.1.1: Let q->(b^(1/3)), then

∫(x/(((a+b (x^3)))^(2/3)))dx  ⟶  -((ArcTan[((1+((2 q x)/(((a+b (x^3)))^(1/3))))/(Sqrt[3]))])/((Sqrt[3]) (q^2)))-((Log[q x-(((a+b (x^3)))^(1/3))])/(2 (q^2)))

Program code:

Int[x_/(a_+b_.*x_^3)^(2/3),x_Symbol] :=
  With[{q=Rt[b,3]},
  -ArcTan[(1+2*q*x/(a+b*x^3)^(1/3))/Sqrt[3]]/(Sqrt[3]*q^2) - Log[q*x-(a+b*x^3)^(1/3)]/(2*q^2)] /;
FreeQ[{a,b},x]

2:  ∫(x^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ m∈ℤ ∧ p+((m+1)/n)∈ℤ

Derivation: Integration by substitution

Basis:  If  n∈ℤ ∧ m∈ℤ ∧ p+((m+1)/n)∈ℤ, then (x^m) (((a+b (x^n)))^p)==(a^(p+((m+1)/n))) Subst[((x^m)/(((1-b (x^n)))^(p+((m+1)/n)+1))),x,(x/(((a+b (x^n)))^(1/n)))] (∂_x)(x/(((a+b (x^n)))^(1/n)))

Rule 1.1.3.2.7.1.11.1.2: If  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ m∈ℤ ∧ p+((m+1)/n)∈ℤ, then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  (a^(p+((m+1)/n)))Subst[∫((x^m)/(((1-b (x^n)))^(p+((m+1)/n)+1)))dx,x,(x/(((a+b (x^n)))^(1/n)))]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  a^(p+(m+1)/n)*Subst[Int[x^m/(1-b*x^n)^(p+(m+1)/n+1),x],x,x/(a+b*x^n)^(1/n)] /;
FreeQ[{a,b},x] && IGtQ[n,0] && LtQ[-1,p,0] && NeQ[p,-1/2] && IntegersQ[m,p+(m+1)/n]

Int[x_^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  (a1*a2)^(p+(m+1)/(2*n))*
    Subst[Int[x^m/((1-b1*x^n)^(p+(m+1)/(2*n)+1)*(1-b2*x^n)^(p+(m+1)/(2*n)+1)),x],x,
      x/((a1+b1*x^n)^(1/(2*n))*(a2+b2*x^n)^(1/(2*n)))] /;
FreeQ[{a1,b1,a2,b2},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && LtQ[-1,p,0] && NeQ[p,-1/2] && IntegersQ[m,p+(m+1)/(2*n)]

2:  ∫(x^m) (((a+b (x^n)))^p)dx  when  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ m∈ℤ ∧ Denominator[p+((m+1)/n)]<Denominator[p]

Derivation: Piecewise constant extraction and integration by substitution

Basis:  (∂_x)(((((a/(a+b (x^n)))))^(p+((m+1)/n))) (((a+b (x^n)))^(p+((m+1)/n))))==0

Basis:  If  n∈ℤ, then ((x^m)/(((((a/(a+b (x^n)))))^(p+((m+1)/n))) (((a+b (x^n)))^((m+1)/n))))==Subst[((x^m)/(((1-b (x^n)))^(p+((m+1)/n)+1))),x,(x/(((a+b (x^n)))^(1/n)))] (∂_x)(x/(((a+b (x^n)))^(1/n)))

Rule 1.1.3.2.7.1.11.2: If  n∈(SuperPlus[ℤ])∧ -1<p<0 ∧ p≠-(1/2) ∧ m∈ℤ ∧ Denominator[p+((m+1)/n)]<Denominator[p], then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  ((((a/(a+b (x^n)))))^(p+((m+1)/n))) (((a+b (x^n)))^(p+((m+1)/n)))∫((x^m)/(((((a/(a+b (x^n)))))^(p+((m+1)/n))) (((a+b (x^n)))^((m+1)/n))))dx
  ⟶  ((((a/(a+b (x^n)))))^(p+((m+1)/n))) (((a+b (x^n)))^(p+((m+1)/n)))Subst[∫((x^m)/(((1-b (x^n)))^(p+((m+1)/n)+1)))dx,x,(x/(((a+b (x^n)))^(1/n)))]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  (a/(a+b*x^n))^(p+(m+1)/n)*(a+b*x^n)^(p+(m+1)/n)*Subst[Int[x^m/(1-b*x^n)^(p+(m+1)/n+1),x],x,x/(a+b*x^n)^(1/n)] /;
FreeQ[{a,b},x] && IGtQ[n,0] && LtQ[-1,p,0] && NeQ[p,-1/2] && IntegerQ[m] && LtQ[Denominator[p+(m+1)/n],Denominator[p]]

Int[x_^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  (a1/(a1+b1*x^n))^(p+(m+1)/(2*n))*(a1+b1*x^n)^(p+(m+1)/(2*n))*(a2/(a2+b2*x^n))^(p+(m+1)/(2*n))*(a2+b2*x^n)^(p+(m+1)/(2*n))*
    Subst[Int[x^m/((1-b1*x^n)^(p+(m+1)/(2*n)+1)*(1-b2*x^n)^(p+(m+1)/(2*n)+1)),x],x,
      x/((a1+b1*x^n)^(1/(2*n))*(a2+b2*x^n)^(1/(2*n)))] /;
FreeQ[{a1,b1,a2,b2},x] && EqQ[a2*b1+a1*b2,0] && IGtQ[2*n,0] && LtQ[-1,p,0] && NeQ[p,-1/2] && 
  IntegerQ[m] && LtQ[Denominator[p+(m+1)/(2*n)],Denominator[p]]

2.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperMinus[ℤ])

1.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperMinus[ℤ])∧ m∈ℚ

1:  ∫(x^m) (((a+b (x^n)))^p)dx  when  n∈(SuperMinus[ℤ])∧ m∈ℤ

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ m∈ℤ, then (x^m) F[(x^n)]==-Subst[((F[(x^(-n))])/(x^(m+2))),x,(1/x)] (∂_x)(1/x)

Rule 1.1.3.2.7.2.1.1: If  n∈(SuperMinus[ℤ])∧ m∈ℤ, then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  -Subst[∫((((a+b (x^(-n))))^p)/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  -Subst[Int[(a+b*x^(-n))^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,p},x] && ILtQ[n,0] && IntegerQ[m]

Int[x_^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  -Subst[Int[(a1+b1*x^(-n))^p*(a2+b2*x^(-n))^p/x^(m+2),x],x,1/x] /;
FreeQ[{a1,b1,a2,b2,p},x] && EqQ[a2*b1+a1*b2,0] && ILtQ[2*n,0] && IntegerQ[m]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperMinus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ k>1, then (((c x))^m) F[(x^n)]==-(k/c)Subst[ ((F[(c^(-n)) (x^(-k n))])/(x^(k (m+1)+1))),x,(1/(((c x))^(1/k)))] (∂_x)(1/(((c x))^(1/k)))

Rule 1.1.3.2.7.2.1.2: If  n∈(SuperMinus[ℤ])∧ m∈𝔽, let k=Denominator[m], then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  -(k/c) Subst[∫((((a+b (c^(-n)) (x^(-k n))))^p)/(x^(k (m+1)+1)))dx,x,(1/(((c x))^(1/k)))]

Program code:

Int[(c_.*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  -k/c*Subst[Int[(a+b*c^(-n)*x^(-k*n))^p/x^(k*(m+1)+1),x],x,1/(c*x)^(1/k)]] /;
FreeQ[{a,b,c,p},x] && ILtQ[n,0] && FractionQ[m]

Int[(c_.*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  -k/c*Subst[Int[(a1+b1*c^(-n)*x^(-k*n))^p*(a2+b2*c^(-n)*x^(-k*n))^p/x^(k*(m+1)+1),x],x,1/(c*x)^(1/k)]] /;
FreeQ[{a1,b1,a2,b2,c,p},x] && EqQ[a2*b1+a1*b2,0] && ILtQ[2*n,0] && FractionQ[m]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈(SuperMinus[ℤ])∧ m∉ℚ

Derivation:  Piecewise constant extraction and integration by substitution

Basis: (∂_x)((((c x))^m) ((((x^(-1))))^m))==0

Basis: F[x]==-Subst[((F[(x^(-1))] )/(x^2)),x,(1/x)](∂_x)(1/x)

Rule 1.1.3.2.7.2.2: If  n∈(SuperMinus[ℤ])∧ m∉ℚ, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((c x))^m) ((((1/x)))^m)∫((((a+b (x^n)))^p)/((((1/x)))^m))dx  ⟶  -(1/c) (((c x))^(m+1)) ((((1/x)))^(m+1)) Subst[∫((((a+b (x^(-n))))^p)/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[(c_.*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  -1/c*(c*x)^(m+1)*(1/x)^(m+1)*Subst[Int[(a+b*x^(-n))^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,m,p},x] && ILtQ[n,0] && Not[RationalQ[m]]

Int[(c_.*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  -1/c*(c*x)^(m+1)*(1/x)^(m+1)*Subst[Int[(a1+b1*x^(-n))^p*(a2+b2*x^(-n))^p/x^(m+2),x],x,1/x] /;
FreeQ[{a1,b1,a2,b2,c,m,p},x] && EqQ[a2*b1+a1*b2,0] && ILtQ[2*n,0] && Not[RationalQ[m]]

8.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈𝔽

1:  ∫(x^m) (((a+b (x^n)))^p)dx  when  n∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (x^m)F[(x^n)]==k Subst[(x^(k(m+1)-1))F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule 1.1.3.2.8.1: If  n∈𝔽, let k=Denominator[n], then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  k Subst[∫(x^(k(m+1)-1)) (((a+b (x^(k n))))^p)dx,x,(x^(1/k))]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k*(m+1)-1)*(a+b*x^(k*n))^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,m,p},x] && FractionQ[n]

Int[x_^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  With[{k=Denominator[2*n]},
  k*Subst[Int[x^(k*(m+1)-1)*(a1+b1*x^(k*n))^p*(a2+b2*x^(k*n))^p,x],x,x^(1/k)]] /;
FreeQ[{a1,b1,a2,b2,m,p},x] && EqQ[a2*b1+a1*b2,0] && FractionQ[2*n]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  n∈𝔽

Derivation: Piecewise constant extraction

Basis: (∂_x)((((c x))^m)/(x^m))==0

Rule 1.1.3.2.8.2: If  n∈𝔽, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((c^(IntPart[m]))(((c x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)))^p)dx

Program code:

Int[(c_*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,m,p},x] && FractionQ[n]

Int[(c_*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a1+b1*x^n)^p*(a2+b2*x^n)^p,x] /;
FreeQ[{a1,b1,a2,b2,c,m,p},x] && EqQ[a2*b1+a1*b2,0] && FractionQ[2*n]

9.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  (n/(m+1))∈ℤ

1:  ∫(x^m) (((a+b (x^n)))^p)dx  when  (n/(m+1))∈ℤ

Derivation: Integration by substitution

Basis: If (n/(m+1))∈ℤ, then (x^m)F[(x^n)]==(1/(m+1))Subst[F[(x^(n/(m+1)))],x,(x^(m+1))](∂_x)(x^(m+1))

Rule 1.1.3.2.9.1: If (n/(m+1))∈ℤ, then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  (1/(m+1))Subst[∫(((a+b (x^(n/(m+1)))))^p)dx,x,(x^(m+1))]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  1/(m+1)*Subst[Int[(a+b*x^Simplify[n/(m+1)])^p,x],x,x^(m+1)] /;
FreeQ[{a,b,m,n,p},x] && IntegerQ[Simplify[n/(m+1)]] && Not[IntegerQ[n]]

Int[x_^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  1/(m+1)*Subst[Int[(a1+b1*x^Simplify[n/(m+1)])^p*(a2+b2*x^Simplify[n/(m+1)])^p,x],x,x^(m+1)] /;
FreeQ[{a1,b1,a2,b2,m,n,p},x] && EqQ[a2*b1+a1*b2,0] && IntegerQ[Simplify[2*n/(m+1)]] && Not[IntegerQ[2*n]]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  (n/(m+1))∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((c x))^m)/(x^m))==0

Rule 1.1.3.2.9.2: If (n/(m+1))∈ℤ, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((c^(IntPart[m]))(((c x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)))^p)dx

Program code:

Int[(c_*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,m,n,p},x] && IntegerQ[Simplify[n/(m+1)]] && Not[IntegerQ[n]]

Int[(c_*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a1+b1*x^n)^p*(a2+b2*x^n)^p,x] /;
FreeQ[{a1,b1,a2,b2,c,m,n,p},x] && EqQ[a2*b1+a1*b2,0] && IntegerQ[Simplify[2*n/(m+1)]] && Not[IntegerQ[2*n]]

10.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p∈ℤ

1.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p∈ℤ ∧ p>0

1.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p==0 ∧ p>0

1:  ∫(x^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p==0 ∧ p>0

Reference: G&R 2.110.3

Derivation: Binomial recurrence 1a

Derivation: Integration by parts

Rule 1.1.3.2.10.1.1.1: If ((m+1)/n)+p==0 ∧ p>0, then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  (((x^(m+1)) (((a+b (x^n)))^p))/(m+1))-((b n p)/(m+1))∫(x^(m+n)) (((a+b (x^n)))^(p-1))dx

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  x^(m+1)*(a+b*x^n)^p/(m+1) - 
  b*n*p/(m+1)*Int[x^(m+n)*(a+b*x^n)^(p-1),x] /;
FreeQ[{a,b,m,n},x] && EqQ[(m+1)/n+p,0] && GtQ[p,0]

Int[x_^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  x^(m+1)*(a1+b1*x^n)^p*(a2+b2*x^n)^p/(m+1) - 
  2*b1*b2*n*p/(m+1)*Int[x^(m+2*n)*(a1+b1*x^n)^(p-1)*(a2+b2*x^n)^(p-1),x] /;
FreeQ[{a1,b1,a2,b2,m,n},x] && EqQ[a2*b1+a1*b2,0] && EqQ[(m+1)/(2*n)+p,0] && GtQ[p,0]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p==0 ∧ p>0

Derivation: Piecewise constant extraction

Basis: (∂_x)((((c x))^m)/(x^m))==0

Rule 1.1.3.2.10.1.1.2: If ((m+1)/n)+p==0 ∧ p>0, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((c^(IntPart[m]))(((c x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)))^p)dx

Program code:

Int[(c_*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,m,n},x] && EqQ[(m+1)/n+p,0] && GtQ[p,0]

Int[(c_*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a1+b1*x^n)^p*(a2+b2*x^n)^p,x] /;
FreeQ[{a1,b1,a2,b2,c,m,n},x] && EqQ[a2*b1+a1*b2,0] && EqQ[(m+1)/(2*n)+p,0] && GtQ[p,0]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p∈ℤ ∧ p>0 ∧ m+n p+1≠0

Reference: G&R 2.110.1, CRC 88b

Derivation: Binomial recurrence 1b

Derivation: Inverted integration by parts

Rule 1.1.3.2.10.1.2: If ((m+1)/n)+p∈ℤ ∧ p>0 ∧ m+n p+1≠0, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((((c x))^(m+1)) (((a+b (x^n)))^p))/(c(m+n p+1)))+((a n p)/(m+n p+1))∫(((c x))^m) (((a+b (x^n)))^(p-1))dx

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a+b*x^n)^p/(c*(m+n*p+1)) +
  a*n*p/(m+n*p+1)*Int[(c*x)^m*(a+b*x^n)^(p-1),x] /;
FreeQ[{a,b,c,m,n},x] && IntegerQ[p+Simplify[(m+1)/n]] && GtQ[p,0] && NeQ[m+n*p+1,0]

Int[(c_.*x_)^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a1+b1*x^n)^p*(a2+b2*x^n)^p/(c*(m+2*n*p+1)) +
  2*a1*a2*n*p/(m+2*n*p+1)*Int[(c*x)^m*(a1+b1*x^n)^(p-1)*(a2+b2*x^n)^(p-1),x] /;
FreeQ[{a1,b1,a2,b2,c,m,n},x] && EqQ[a2*b1+a1*b2,0] && IntegerQ[p+Simplify[(m+1)/(2*n)]] && GtQ[p,0] && NeQ[m+2*n*p+1,0]

2.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p∈ℤ ∧ p<0

1.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p∈ℤ ∧ -1<p<0

1:  ∫(x^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p∈ℤ ∧ -1<p<0

Derivation: Integration by substitution

Basis:  If ((m+1)/n)+p∈ℤ, let k=Denominator[p], then (x^m) (((a+b (x^n)))^p)==((k (a^(p+((m+1)/n))))/n) Subst[((x^(((k (m+1))/n)-1))/(((1-b (x^k)))^(p+((m+1)/n)+1))),x,((x^(n/k))/(((a+b (x^n)))^(1/k)))] (∂_x)((x^(n/k))/(((a+b (x^n)))^(1/k)))

Basis:  If a2 b1+a1 b2==0 ∧ ((m+1)/(2 n))+p∈ℤ, let k=Denominator[p], then (x^m) (((a1+b1 (x^n)))^p) (((a2+b2 (x^n)))^p)==((k (((a1 a2))^(p+((m+1)/(2 n)))))/(2 n)) Subst[((x^(((k (m+1))/(2 n))-1))/(((1-b1 b2 (x^k)))^(p+((m+1)/(2 n))+1))),x,((x^(2 n/k))/((((a1+b1 (x^n)))^(1/k)) (((a2+b2 (x^n)))^(1/k))))] (∂_x)((x^(2 n/k))/((((a1+b1 (x^n)))^(1/k)) (((a2+b2 (x^n)))^(1/k))))

Note: The exponents in the resulting integrand are integers.

Rule 1.1.3.2.10.2.1.1: If ((m+1)/n)+p∈ℤ ∧ -1<p<0, let k=Denominator[p], then

∫(x^m) (((a+b (x^n)))^p)dx  ⟶  ((k (a^(p+((m+1)/n))))/n) Subst[∫((x^(((k (m+1))/n)-1))/(((1-b (x^k)))^(p+((m+1)/n)+1)))dx,x,((x^(n/k))/(((a+b (x^n)))^(1/k)))]

∫(x^m) (((a1+b1 (x^n)))^p) (((a2+b2 (x^n)))^p)dx  ⟶  ((k (((a1 a2))^(p+((m+1)/(2 n)))))/(2 n)) Subst[∫((x^(((k (m+1))/(2 n))-1))/(((1-b1 b2 (x^k)))^(p+((m+1)/(2 n))+1)))dx,x,((x^(2 n/k))/((((a1+b1 (x^n)))^(1/k)) (((a2+b2 (x^n)))^(1/k))))]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  With[{k=Denominator[p]},
  k*a^(p+Simplify[(m+1)/n])/n*
	Subst[Int[x^(k*Simplify[(m+1)/n]-1)/(1-b*x^k)^(p+Simplify[(m+1)/n]+1),x],x,x^(n/k)/(a+b*x^n)^(1/k)]] /;
FreeQ[{a,b,m,n},x] && IntegerQ[p+Simplify[(m+1)/n]] && LtQ[-1,p,0]

Int[x_^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  With[{k=Denominator[p]},
  k*(a1*a2)^(p+Simplify[(m+1)/(2*n)])/(2*n)*
	Subst[Int[x^(k*Simplify[(m+1)/(2*n)]-1)/(1-b1*b2*x^k)^(p+Simplify[(m+1)/(2*n)]+1),x],x,x^(2*n/k)/((a1+b1*x^n)^(1/k)*(a2+b2*x^n)^(1/k))]] /;
FreeQ[{a1,b1,a2,b2,m,n},x] && EqQ[a2*b1+a1*b2,0] && IntegerQ[p+Simplify[(m+1)/(2*n)]] && LtQ[-1,p,0]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p∈ℤ ∧ -1<p<0

Derivation: Piecewise constant extraction

Basis: (∂_x)((((c x))^m)/(x^m))==0

Rule 1.1.3.2.10.2.1.2: If ((m+1)/n)+p∈ℤ ∧ -1<p<0, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((c^(IntPart[m]))(((c x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)))^p)dx

Program code:

Int[(c_*x_)^m_*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,m,n},x] && IntegerQ[p+Simplify[(m+1)/n]] && LtQ[-1,p,0]

Int[(c_*x_)^m_*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a1+b1*x^n)^p*(a2+b2*x^n)^p,x] /;
FreeQ[{a1,b1,a2,b2,c,m,n},x] && EqQ[a2*b1+a1*b2,0] && IntegerQ[p+Simplify[(m+1)/(2*n)]] && LtQ[-1,p,0]

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  ((m+1)/n)+p∈ℤ ∧ p<-1

Reference: G&R 2.110.2, CRC 88d

Derivation: Binomial recurrence 2b

Derivation: Integration by parts

Basis: (x^m) (((a+b (x^n)))^p)==(x^(m+n p+n+1))((((a+b (x^n)))^p)/(x^(n (p+1)+1)))

Basis: ∫((((a+b (x^n)))^p)/(x^(n (p+1)+1)))dx==-((((a+b (x^n)))^(p+1))/((x^(n (p+1)))a n (p+1)))

Rule 1.1.3.2.10.2.2: If ((m+1)/n)+p∈ℤ ∧ p<-1, then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  -(((((c x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a c n (p+1)))+((m+n (p+1)+1)/(a n (p+1)))∫(((c x))^m) (((a+b (x^n)))^(p+1))dx

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  -(c*x)^(m+1)*(a+b*x^n)^(p+1)/(a*c*n*(p+1)) +
  (m+n*(p+1)+1)/(a*n*(p+1))*Int[(c*x)^m*(a+b*x^n)^(p+1),x] /;
FreeQ[{a,b,c,m,n},x] && IntegerQ[p+Simplify[(m+1)/n]] && LtQ[p,-1]

Int[(c_.*x_)^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  -(c*x)^(m+1)*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1)/(2*a1*a2*c*n*(p+1)) +
  (m+2*n*(p+1)+1)/(2*a1*a2*n*(p+1))*Int[(c*x)^m*(a1+b1*x^n)^(p+1)*(a2+b2*x^n)^(p+1),x] /;
FreeQ[{a1,b1,a2,b2,c,m,n},x] && EqQ[a2*b1+a1*b2,0] && IntegerQ[p+Simplify[(m+1)/(2*n)]] && LtQ[p,-1]

11.  ∫((((c x))^m)/(a+b (x^n)))dx  when  ((m+1)/n)∈𝔽

1.  ∫((x^m)/(a+b (x^n)))dx  when  ((m+1)/n)∈𝔽

1:  ∫((x^m)/(a+b (x^n)))dx  when  ((m+1)/n)∈𝔽 ∧ m-n⪡m

Reference: CRC 86

Derivation: Binomial recurrence 3a with p=-1

Rule 1.1.3.2.11.1.1: If  ((m+1)/n)∈𝔽 ∧ m-n⪡m, then

∫((x^m)/(a+b (x^n)))dx  ⟶  ((x^(m-n+1))/(b (m-n+1)))-(a/b)∫((x^(m-n))/(a+b (x^n)))dx

Program code:

Int[x_^m_./(a_+b_.*x_^n_),x_Symbol] :=
  With[{mn=Simplify[m-n]},
  x^(mn+1)/(b*(mn+1)) -
  a/b*Int[x^mn/(a+b*x^n),x]] /;
FreeQ[{a,b,m,n},x] && FractionQ[Simplify[(m+1)/n]] && SumSimplerQ[m,-n]

2:  ∫((x^m)/(a+b (x^n)))dx  when  ((m+1)/n)∈𝔽 ∧ m+n⪡m

Reference: CRC 87

Derivation: Binomial recurrence 3b with p=-1

Rule 1.1.3.2.11.1.2: If  ((m+1)/n)∈𝔽 ∧ m+n⪡m, then

∫((x^m)/(a+b (x^n)))dx  ⟶  ((x^(m+1))/(a (m+1)))-(b/a)∫((x^(m+n))/(a+b (x^n)))dx

Program code:

Int[x_^m_/(a_+b_.*x_^n_),x_Symbol] :=
  x^(m+1)/(a*(m+1)) -
  b/a*Int[x^Simplify[m+n]/(a+b*x^n),x] /;
FreeQ[{a,b,m,n},x] && FractionQ[Simplify[(m+1)/n]] && SumSimplerQ[m,n]

2:  ∫((((c x))^m)/(a+b (x^n)))dx  when  ((m+1)/n)∈𝔽

Derivation: Piecewise constant extraction

Basis: (∂_x)((((c x))^m)/(x^m))==0

Rule 1.1.3.2.11.2: If ((m+1)/n)∈𝔽, then

∫((((c x))^m)/(a+b (x^n)))dx  ⟶  (((c^(IntPart[m]))(((c x))^(FracPart[m])))/(x^(FracPart[m])))∫((x^m)/(a+b (x^n)))dx

Program code:

Int[(c_*x_)^m_/(a_+b_.*x_^n_),x_Symbol] :=
  c^IntPart[m]*(c*x)^FracPart[m]/x^FracPart[m]*Int[x^m/(a+b*x^n),x] /;
FreeQ[{a,b,c,m,n},x] && FractionQ[Simplify[(m+1)/n]] && (SumSimplerQ[m,n] || SumSimplerQ[m,-n])

12.  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  p∉(SuperPlus[ℤ])

1:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  p∉(SuperPlus[ℤ])∧ (p∈(SuperMinus[ℤ]) ∨ a>0)

Note: If  t==r+1 ∧ r∈ℤ, then Hypergeometric2F1[r,s,t,z]==Hypergeometric2F1[s,r,t,z] are elementary or undefined.

Rule 1.1.3.2.12.1: If  p∉(SuperPlus[ℤ])∧ (p∈(SuperMinus[ℤ]) ∨ a>0), then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((a^p)(((c x))^(m+1)))/(c(m+1)))Hypergeometric2F1[-p,((m+1)/n),((m+1)/n)+1,-((b (x^n))/a)]

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  a^p*(c*x)^(m+1)/(c*(m+1))*Hypergeometric2F1[-p,(m+1)/n,(m+1)/n+1,-b*x^n/a] /;
FreeQ[{a,b,c,m,n,p},x] && Not[IGtQ[p,0]] && (ILtQ[p,0] || GtQ[a,0])

x:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  p∉(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ]) ∨ a>0)

Note: If  r==1 ∧(s∈ℤ ∨ t∈ℤ), then Hypergeometric2F1[r,s,t,z]==Hypergeometric2F1[s,r,t,z] are undefined or can be expressed in elementary form.

Note: Mathematica has a hard time simplifying the derivative of the following antiderivative to the integrand, so the following, more complicated, but easily differentiated, rule is used instead.

Rule 1.1.3.2.12.x: If  p∉(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ]) ∨ a>0), then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((((c x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a c(m+1)))Hypergeometric2F1[1,((m+1)/n)+p+1,((m+1)/n)+1,-((b (x^n))/a)]

Program code:

(* Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  (c*x)^(m+1)*(a+b*x^n)^(p+1)/(a*c*(m+1))*Hypergeometric2F1[1,(m+1)/n+p+1,(m+1)/n+1,-b*x^n/a] /;
FreeQ[{a,b,c,m,n,p},x] && Not[IGtQ[p,0]] && Not[ILtQ[p,0] || GtQ[a,0]] *)

2:  ∫(((c x))^m) (((a+b (x^n)))^p)dx  when  p∉(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ]) ∨ a>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((a+b (x^n)))^p)/(((1+((b (x^n))/a)))^p))==0

Rule 1.1.3.2.12.2: If  p∉(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ]) ∨ a>0), then

∫(((c x))^m) (((a+b (x^n)))^p)dx  ⟶  (((a^(IntPart[p])) (((a+b (x^n)))^(FracPart[p])))/(((1+((b (x^n))/a)))^(FracPart[p]))) ∫(((c x))^m) (((1+((b (x^n))/a)))^p)dx

Program code:

Int[(c_.*x_)^m_.*(a_+b_.*x_^n_)^p_,x_Symbol] :=
  a^IntPart[p]*(a+b*x^n)^FracPart[p]/(1+b*x^n/a)^FracPart[p]*Int[(c*x)^m*(1+b*x^n/a)^p,x] /;
FreeQ[{a,b,c,m,n,p},x] && Not[IGtQ[p,0]] && Not[ILtQ[p,0] || GtQ[a,0]]

D:  ∫(((c x))^m) ((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0, then (∂_x)((((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p))/((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^(2 n))))^p))==0

Rule: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ p∉ℤ, then

∫(((c x))^m) ((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^n)))^p)dx  ⟶  ((((((Subscript[a, 1])+(Subscript[b, 1]) (x^n)))^(FracPart[p])) ((((Subscript[a, 2])+(Subscript[b, 2]) x))^(FracPart[p])))/((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^2)))^(FracPart[p])))∫(((c x))^m) ((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^(2 n))))^p)dx

Program code:

Int[(c_.*x_)^m_.*(a1_+b1_.*x_^n_)^p_*(a2_+b2_.*x_^n_)^p_,x_Symbol] :=
  (a1+b1*x^n)^FracPart[p]*(a2+b2*x^n)^FracPart[p]/(a1*a2+b1*b2*x^(2*n))^FracPart[p]*Int[(c*x)^m*(a1*a2+b1*b2*x^(2*n))^p,x] /;
FreeQ[{a1,b1,a2,b2,c,m,n,p},x] && EqQ[a2*b1+a1*b2,0] && Not[IntegerQ[p]]

(* IntBinomialQ[a,b,c,n,m,p,x] returns True iff (c*x)^m*(a+b*x^n)^p is integrable wrt x in terms of non-hypergeometric functions. *)
IntBinomialQ[a_,b_,c_,n_,m_,p_,x_] :=
  IGtQ[p,0] || RationalQ[m] && IntegersQ[n,2*p] || IntegerQ[(m+1)/n+p] || 
  (EqQ[n,2] || EqQ[n,4]) && IntegersQ[2*m,4*p] || 
  EqQ[n,2] && IntegerQ[6*p] && (IntegerQ[m] || IntegerQ[m-p])

Rules for integrands of the form(((d x))^m) (((a+b (((c (x^q)))^n)))^p)

1:  ∫(((d x))^m) (((a+b (((c x))^n)))^p)dx

Derivation: Integration by substitution

Rule:

∫(((d x))^m) (((a+b (((c x))^n)))^p)dx  ⟶  (1/c)Subst[∫(((((d x)/c)))^m)(((a+b (x^n)))^p)dx,x,c x]

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*(c_*x_)^n_)^p_.,x_Symbol] :=
  1/c*Subst[Int[(d*x/c)^m*(a+b*x^n)^p,x],x,c*x] /;
FreeQ[{a,b,c,d,m,n,p},x]

2:  ∫(((d x))^m) (((a+b (((c (x^q)))^n)))^p)dx  when  n q∈ℤ

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((((d x))^(m+1))/((((((c (x^q)))^(1/q))))^(m+1)))==0

Basis: ((F[(((c (x^q)))^(1/q))])/x)==Subst[((F[x])/x),x,(((c (x^q)))^(1/q))] (∂_x)(((c (x^q)))^(1/q))

Rule: If  n q∈ℤ, then

∫(((d x))^m) (((a+b (((c (x^q)))^n)))^p)dx  ⟶  ((((d x))^(m+1))/(d ((((((c (x^q)))^(1/q))))^(m+1)))) ∫((((((((c (x^q)))^(1/q))))^(m+1)) (((a+b ((((((c (x^q)))^(1/q))))^(n q))))^p))/x)dx
  ⟶  ((((d x))^(m+1))/(d ((((((c (x^q)))^(1/q))))^(m+1)))) Subst[∫(x^m) (((a+b (x^(n q))))^p)dx,x,(((c (x^q)))^(1/q))]

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*(c_.*x_^q_)^n_)^p_.,x_Symbol] :=
  (d*x)^(m+1)/(d*((c*x^q)^(1/q))^(m+1))*Subst[Int[x^m*(a+b*x^(n*q))^p,x],x,(c*x^q)^(1/q)] /;
FreeQ[{a,b,c,d,m,n,p,q},x] && IntegerQ[n*q] && NeQ[x,(c*x^q)^(1/q)]

3:  ∫(((d x))^m) (((a+b (((c (x^q)))^n)))^p)dx  when  n∈𝔽

Derivation: Integration by substitution

Rule: If  n∈𝔽, then

∫(((d x))^m) (((a+b (((c (x^q)))^n)))^p)dx  ⟶  Subst[∫(((d x))^m) (((a+b (c^n) (x^(n q))))^p)dx,(x^(1/k)),((((c (x^q)))^(1/k))/((c^(1/k)) ((((x^(1/k))))^(q-1))))]

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*(c_.*x_^q_)^n_)^p_.,x_Symbol] :=
  With[{k=Denominator[n]},
  Subst[Int[(d*x)^m*(a+b*c^n*x^(n*q))^p,x],x^(1/k),(c*x^q)^(1/k)/(c^(1/k)*(x^(1/k))^(q-1))]] /;
FreeQ[{a,b,c,d,m,p,q},x] && FractionQ[n]

4:  ∫(((d x))^m) (((a+b (((c (x^q)))^n)))^p)dx  when  n∉ℝ

Derivation: Integration by substitution

Basis: F[(((c (x^q)))^n)]==Subst[F[(c^n) (x^(n q))],(x^(n q)),((((c (x^q)))^n)/(c^n))]

Rule: If  n∉ℝ, then

∫(((d x))^m) (((a+b (((c (x^q)))^n)))^p)dx  ⟶  Subst[∫(((d x))^m) (((a+b (c^n) (x^(n q))))^p)dx,(x^(n q)),((((c (x^q)))^n)/(c^n))]

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*(c_.*x_^q_)^n_)^p_.,x_Symbol] :=
  Subst[Int[(d*x)^m*(a+b*c^n*x^(n*q))^p,x],x^(n*q),(c*x^q)^n/c^n] /;
FreeQ[{a,b,c,d,m,n,p,q},x] && Not[RationalQ[n]]

S.  ∫(u^m) (((a+b (v^n)))^p)dx

1:  ∫(x^m)(((a+b (v^n)))^p)dx  when  v==c+d x ∧ m∈ℤ

Derivation: Integration by substitution

Basis: If  m∈ℤ, then (x^m)F[c+d x]==(1/(d^(m+1)))Subst[(((x-c))^m) F[x],x,c+d x](∂_x)(c+d x)

Rule 1.1.3.2.S.2: If  v==c+d x ∧ m∈ℤ, then

∫(x^m)(((a+b (v^n)))^p)dx  ⟶  (1/(d^(m+1)))Subst[∫(((x-c))^m)(((a+b (x^n)))^p)dx,x,v]

Program code:

Int[x_^m_.*(a_+b_.*v_^n_)^p_.,x_Symbol] :=
  With[{c=Coefficient[v,x,0],d=Coefficient[v,x,1]},
  1/d^(m+1)*Subst[Int[SimplifyIntegrand[(x-c)^m*(a+b*x^n)^p,x],x],x,v] /;
 NeQ[c,0]] /;
FreeQ[{a,b,n,p},x] && LinearQ[v,x] && IntegerQ[m]

2:  ∫(u^m)(((a+b (v^n)))^p)dx  when  v==c+d x ∧ u==e v

Derivation: Integration by substitution and piecewise constant extraction

Basis: If  u==e v, then (∂_x)((u^m)/(v^m))==0

Rule 1.1.3.2.S.3: If  v==c+d x ∧ u==e v, then

∫(u^m)(((a+b (v^n)))^p)dx  ⟶  ((u^m)/(d (v^m)))Subst[∫(x^m) (((a+b (x^n)))^p)dx,x,v]

Program code:

Int[u_^m_.*(a_+b_.*v_^n_)^p_.,x_Symbol] :=
  u^m/(Coefficient[v,x,1]*v^m)*Subst[Int[x^m*(a+b*x^n)^p,x],x,v] /;
FreeQ[{a,b,m,n,p},x] && LinearPairQ[u,v,x]