Rules for integrands of the form(((e x))^m) (((a+b (x^n)))^p)(((c+d (x^n)))^q)

0.  ∫(((e x))^m) (((b (x^n)))^p) (((c+d (x^n)))^q)dx

1.  ∫(((e x))^m) (((b (x^n)))^p) (((c+d (x^n)))^q)dx  when m∈ℤ ∨ e>0

1:  ∫(((e x))^m) (((b (x^n)))^p) (((c+d (x^n)))^q) dx  when (m∈ℤ ∨ e>0) ∧ ((m+1)/n)∈ℤ

Derivation: Algebraic expansion and integration by substitution

Basis: If  ((m+1)/n)∈ℤ, then (x^m) (((b (x^n)))^p)==(1/(b^(((m+1)/n)-1))) (x^(n-1)) (((b (x^n)))^(p+((m+1)/n)-1))

Basis: (x^(n-1))F[(x^n)]==(1/n) Subst[F[x],x,(x^n)] (∂_x)(x^n)

Rule 1.1.3.4.0.1.1: If  (m∈ℤ ∨ e>0) ∧ ((m+1)/n)∈ℤ, then

∫(((e x))^m) (((b (x^n)))^p) (((c+d (x^n)))^q) dx  ⟶  ((e^m)/(n (b^(((m+1)/n)-1)))) Subst[∫(((b x))^(p+((m+1)/n)-1)) (((c+d x))^q)dx,x,(x^n)]

Program code:

Int[(e_.*x_)^m_.*(b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  e^m/(n*b^(Simplify[(m+1)/n]-1))*Subst[Int[(b*x)^(p+Simplify[(m+1)/n]-1)*(c+d*x)^q,x],x,x^n] /;
FreeQ[{b,c,d,e,m,n,p,q},x] && (IntegerQ[m] || GtQ[e,0]) && IntegerQ[Simplify[(m+1)/n]]

2:  ∫(((e x))^m) (((b (x^n)))^p) (((c+d (x^n)))^q)dx  when (m∈ℤ ∨ e>0) ∧ ((m+1)/n)∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((b (x^n)))^p)/(x^(n p)))==0

Rule 1.1.3.4.0.1.2: If (m∈ℤ ∨ e>0) ∧ ((m+1)/n)∉ℤ, then

∫(((e x))^m) (((b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((e^m) (b^(IntPart[p])) (((b (x^n)))^(FracPart[p])))/(x^(n FracPart[p])))∫(x^(m+n p)) (((c+d (x^n)))^q)dx

Program code:

Int[(e_.*x_)^m_.*(b_.*x_^n_.)^p_*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  e^m*b^IntPart[p]*(b*x^n)^FracPart[p]/x^(n*FracPart[p])*Int[x^(m+n*p)*(c+d*x^n)^q,x] /;
FreeQ[{b,c,d,e,m,n,p,q},x] && (IntegerQ[m] || GtQ[e,0]) && Not[IntegerQ[Simplify[(m+1)/n]]]

2:  ∫(((e x))^m) (((b (x^n)))^p) (((c+d (x^n)))^q)dx  when m∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e x))^m)/(x^m))==0

Rule 1.1.3.4.0.2: If  m∉ℤ, then

∫(((e x))^m) (((b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((e^(IntPart[m]))(((e x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((b (x^n)))^p) (((c+d (x^n)))^q)dx

Program code:

Int[(e_*x_)^m_*(b_.*x_^n_.)^p_*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(b*x^n)^p*(c+d*x^n)^q,x] /;
FreeQ[{b,c,d,e,m,n,p,q},x] && Not[IntegerQ[m]]

E1.  ∫((x^m)/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  when b c-2 a d==0 ∧ m∈ℤ ∧ (a>0 ∨ (m/2)∈ℤ)

1:  ∫(x/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  when b c-2 a d==0 ∧ a>0

Note: The result is real and continuous when the integrand is, and substitution u->(x^2) results in 2 inverse trig and 2 log terms.

Rule 1.1.3.4.E1.1: If  b c-2 a d==0 ∧ a>0, then

∫(x/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  ⟶  -(1/((Sqrt[2]) (a^(1/4)) d)) ArcTan[(((Sqrt[a])-(Sqrt[a+b (x^2)]))/((Sqrt[2]) (a^(1/4)) (((a+b (x^2)))^(1/4))))]-(1/((Sqrt[2]) (a^(1/4)) d)) ArcTanh[(((Sqrt[a])+(Sqrt[a+b (x^2)]))/((Sqrt[2]) (a^(1/4)) (((a+b (x^2)))^(1/4))))]

Program code:

Int[x_/((a_+b_.*x_^2)^(1/4)*(c_+d_.*x_^2)),x_Symbol] :=
  -1/(Sqrt[2]*Rt[a,4]*d)*ArcTan[(Rt[a,4]^2-Sqrt[a+b*x^2])/(Sqrt[2]*Rt[a,4]*(a+b*x^2)^(1/4))] - 
  1/(Sqrt[2]*Rt[a,4]*d)*ArcTanh[(Rt[a,4]^2+Sqrt[a+b*x^2])/(Sqrt[2]*Rt[a,4]*(a+b*x^2)^(1/4))] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-2*a*d,0] && PosQ[a]

2:  ∫((x^m)/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  when b c-2 a d==0 ∧ m∈ℤ ∧ (a>0 ∨ (m/2)∈ℤ)

Rule 1.1.3.4.E1.2: If  b c-2 a d==0 ∧ m∈ℤ ∧ (a>0 ∨ (m/2)∈ℤ), then

∫((x^m)/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  ⟶  ∫ExpandIntegrand[((x^m)/((((a+b (x^2)))^(1/4)) (c+d (x^2)))),x]dx

Program code:

Int[x_^m_/((a_+b_.*x_^2)^(1/4)*(c_+d_.*x_^2)),x_Symbol] :=
  Int[ExpandIntegrand[x^m/((a+b*x^2)^(1/4)*(c+d*x^2)),x],x] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-2*a*d,0] && IntegerQ[m] && (PosQ[a] || IntegerQ[m/2])

E2.  ∫((x^m)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  when b c-2 a d==0 ∧ m∈ℤ ∧ (a>0 ∨ (m/2)∈ℤ)

1.  ∫((x^2)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  when b c-2 a d==0

1:  ∫((x^2)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  when b c-2 a d==0 ∧ ((b^2)/a)>0

Reference: Eneström index number E688 in The Euler Archive

Rule 1.1.3.4.E2.1.1: If  b c-2 a d==0 ∧ ((b^2)/a)>0, then

∫((x^2)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  ⟶  -(b/(a d (((((b^2)/a)))^(3/4)))) ArcTan[((b+(Sqrt[((b^2)/a)]) (Sqrt[a+b (x^2)]))/((((((b^2)/a)))^(3/4)) x (((a+b (x^2)))^(1/4))))]+(b/(a d (((((b^2)/a)))^(3/4)))) ArcTanh[((b-(Sqrt[((b^2)/a)]) (Sqrt[a+b (x^2)]))/((((((b^2)/a)))^(3/4)) x (((a+b (x^2)))^(1/4))))]

Program code:

Int[x_^2/((a_+b_.*x_^2)^(3/4)*(c_+d_.*x_^2)),x_Symbol] :=
  -b/(a*d*Rt[b^2/a,4]^3)*ArcTan[(b+Rt[b^2/a,4]^2*Sqrt[a+b*x^2])/(Rt[b^2/a,4]^3*x*(a+b*x^2)^(1/4))] + 
  b/(a*d*Rt[b^2/a,4]^3)*ArcTanh[(b-Rt[b^2/a,4]^2*Sqrt[a+b*x^2])/(Rt[b^2/a,4]^3*x*(a+b*x^2)^(1/4))] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-2*a*d,0] && PosQ[b^2/a]

2:  ∫((x^2)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  when b c-2 a d==0 ∧ ((b^2)/a)≯0

Reference: Eneström index number E688 in The Euler Archive

Derivation: Integration by substitution

Basis: If  b c-2 a d==0, then ((x^2)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))==((2 b)/d) Subst[((x^2)/(4 a+(b^2) (x^4))),x,(x/(((a+b (x^2)))^(1/4)))] (∂_x)(x/(((a+b (x^2)))^(1/4)))

Rule 1.1.3.4.E2.1.2: If  b c-2 a d==0 ∧ ((b^2)/a)≯0, then

∫((x^2)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  ⟶  ((2 b)/d) Subst[∫((x^2)/(4 a+(b^2) (x^4)))dx,x,(x/(((a+b (x^2)))^(1/4)))]

  ⟶  -(b/((Sqrt[2]) a d (((-((b^2)/a)))^(3/4)))) ArcTan[(((((-((b^2)/a)))^(1/4)) x)/((Sqrt[2]) (((a+b (x^2)))^(1/4))))]+(b/((Sqrt[2]) a d (((-((b^2)/a)))^(3/4)))) ArcTanh[(((((-((b^2)/a)))^(1/4)) x)/((Sqrt[2]) (((a+b (x^2)))^(1/4))))]

Program code:

Int[x_^2/((a_+b_.*x_^2)^(3/4)*(c_+d_.*x_^2)),x_Symbol] :=
  -b/(Sqrt[2]*a*d*Rt[-b^2/a,4]^3)*ArcTan[(Rt[-b^2/a,4]*x)/(Sqrt[2]*(a+b*x^2)^(1/4))] + 
  b/(Sqrt[2]*a*d*Rt[-b^2/a,4]^3)*ArcTanh[(Rt[-b^2/a,4]*x)/(Sqrt[2]*(a+b*x^2)^(1/4))] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-2*a*d,0] && NegQ[b^2/a]

2:  ∫((x^m)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  when b c-2 a d==0 ∧ m∈ℤ ∧ (a>0 ∨ (m/2)∈ℤ)

Rule 1.1.3.4.E2.2: If  b c-2 a d==0 ∧ m∈ℤ, then

∫((x^m)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  ⟶  ∫ExpandIntegrand[((x^m)/((((a+b (x^2)))^(3/4)) (c+d (x^2)))),x]dx

Program code:

Int[x_^m_/((a_+b_.*x_^2)^(3/4)*(c_+d_.*x_^2)),x_Symbol] :=
  Int[ExpandIntegrand[x^m/((a+b*x^2)^(3/4)*(c+d*x^2)),x],x] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-2*a*d,0] && IntegerQ[m] && (PosQ[a] || IntegerQ[m/2])

1:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ m-n+1==0

Derivation: Integration by substitution

Basis: (x^(n-1))F[(x^n)]==(1/n) Subst[F[x],x,(x^n)] (∂_x)(x^n)

Rule 1.1.3.4.1: If  b c-a d≠0 ∧ m-n+1==0, then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (1/n) Subst[∫(((a+b x))^p) (((c+d x))^q)dx,x,(x^n)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  1/n*Subst[Int[(a+b*x)^p*(c+d*x)^q,x],x,x^n] /;
FreeQ[{a,b,c,d,m,n,p,q},x] && NeQ[b*c-a*d,0] && EqQ[m-n+1,0]

2:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ (p|q)∈ℤ ∧ n<0

Derivation: Algebraic expansion

Basis: If  p∈ℤ, then (((a+b (x^n)))^p)==(x^(n p))(((b+a (x^(-n))))^p)

Rule 1.1.3.4.2: If  b c-a d≠0 ∧ (p|q)∈ℤ ∧ n<0, then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ∫(x^(m+n (p+q))) (((b+a (x^(-n))))^p) (((d+c (x^(-n))))^q)dx

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  Int[x^(m+n*(p+q))*(b+a*x^(-n))^p*(d+c*x^(-n))^q,x] /;
FreeQ[{a,b,c,d,m,n},x] && NeQ[b*c-a*d,0] && IntegersQ[p,q] && NegQ[n]

3.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ ((m+1)/n)∈ℤ

1:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ ((m+1)/n)∈ℤ

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m)F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Note: If  n∈ℤ ∧ ((m+1)/n)∈ℤ, then m∈ℤ, and (((e x))^m) automatically evaluates to (e^m)(x^m).

Rule 1.1.3.4.3.1: If  b c-a d≠0 ∧ ((m+1)/n)∈ℤ, then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((a+b x))^p) (((c+d x))^q)dx,x,(x^n)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a+b*x)^p*(c+d*x)^q,x],x,x^n] /;
FreeQ[{a,b,c,d,m,n,p,q},x] && NeQ[b*c-a*d,0] && IntegerQ[Simplify[(m+1)/n]]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ ((m+1)/n)∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e x))^m)/(x^m))==0

Basis: ((((e x))^m)/(x^m))==(((e^(IntPart[m]))(((e x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.1.3.4.3.2: If  b c-a d≠0 ∧ ((m+1)/n)∈ℤ, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((e^(IntPart[m]))(((e x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx

Program code:

Int[(e_*x_)^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n)^p*(c+d*x^n)^q,x] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && NeQ[b*c-a*d,0] && IntegerQ[Simplify[(m+1)/n]]

4:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ (p|q)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.1.3.4.4: If  b c-a d≠0 ∧ (p|q)∈(SuperPlus[ℤ]), then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ∫ExpandIntegrand[(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q),x]dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  Int[ExpandIntegrand[(e*x)^m*(a+b*x^n)^p*(c+d*x^n)^q,x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[b*c-a*d,0] && IGtQ[p,0] && IGtQ[q,0]

5.  ∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  when b c-a d≠0

1:  ∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  when b c-a d≠0 ∧ a d (m+1)-b c(m+n (p+1)+1)==0 ∧ m≠-1

Derivation: Trinomial recurrence 2b with c=0 and  a d (m+1)-b c (m+n (p+1)+1)==0

Rule 1.1.3.4.5.1: If  b c-a d≠0 ∧ a d (m+1)-b c(m+n (p+1)+1)==0 ∧ m≠-1, then

∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  ⟶  ((c (((e x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a e (m+1)))

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  c*(e*x)^(m+1)*(a+b*x^n)^(p+1)/(a*e*(m+1)) /;
FreeQ[{a,b,c,d,e,m,n,p},x] && NeQ[b*c-a*d,0] && EqQ[a*d*(m+1)-b*c*(m+n*(p+1)+1),0] && NeQ[m,-1]

Int[(e_.*x_)^m_.*(a1_+b1_.*x_^non2_.)^p_.*(a2_+b2_.*x_^non2_.)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  c*(e*x)^(m+1)*(a1+b1*x^(n/2))^(p+1)*(a2+b2*x^(n/2))^(p+1)/(a1*a2*e*(m+1)) /;
FreeQ[{a1,b1,a2,b2,c,d,e,m,n,p},x] && EqQ[non2,n/2] && EqQ[a2*b1+a1*b2,0] && EqQ[a1*a2*d*(m+1)-b1*b2*c*(m+n*(p+1)+1),0] && NeQ[m,-1]

2.  ∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  when  b c-a d≠0 ∧ m+n (p+1)+1==0

1:  ∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  when b c-a d≠0 ∧ m+n (p+1)+1==0 ∧ (n∈ℤ ∨ e>0) ∧ (n>0 ∧ m<-1  ∨ n<0 ∧ m+n>-1)

Derivation: Trinomial recurrence 3b with c=0

Rule 1.1.3.4.5.2.1: If  b c-a d≠0 ∧ (n∈ℤ ∨ e>0) ∧ (n>0 ∧ m<-1  ∨ n<0 ∧ m+n>-1), then

∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  ⟶  ((c (((e x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a e (m+1)))+(d/(e^n)) ∫(((e x))^(m+n)) (((a+b (x^n)))^p)dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  c*(e*x)^(m+1)*(a+b*x^n)^(p+1)/(a*e*(m+1)) + d/e^n*Int[(e*x)^(m+n)*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && NeQ[b*c-a*d,0] && EqQ[m+n*(p+1)+1,0] && (IntegerQ[n] || GtQ[e,0]) && 
  (GtQ[n,0] && LtQ[m,-1] || LtQ[n,0] && GtQ[m+n,-1])

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  when b c-a d≠0 ∧ m+n (p+1)+1==0 ∧ m≠-1

Derivation: Trinomial recurrence 2b with c=0

Rule 1.1.3.4.5.2.2: If  b c-a d≠0 ∧ m+n (p+1)+1==0 ∧ m≠-1, then

∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  ⟶  (((b c-a d)(((e x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a b e(m+1)))+(d/b) ∫(((e x))^m) (((a+b (x^n)))^(p+1))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  (b*c-a*d)*(e*x)^(m+1)*(a+b*x^n)^(p+1)/(a*b*e*(m+1)) + d/b*Int[(e*x)^m*(a+b*x^n)^(p+1),x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && NeQ[b*c-a*d,0] && EqQ[m+n*(p+1)+1,0] && NeQ[m,-1]

3:  ∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  when b c-a d≠0 ∧ (n∈ℤ ∨ e>0) ∧ (n>0 ∧ m<-1  ∨ n<0 ∧ m+n>-1)

Derivation: Trinomial recurrence 3b with c=0

Rule 1.1.3.4.5.3: If  b c-a d≠0 ∧ (n∈ℤ ∨ e>0) ∧ (n>0 ∧ m<-1  ∨ n<0 ∧ m+n>-1), then

∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  ⟶  ((c (((e x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a e (m+1)))+((a d (m+1)-b c(m+n (p+1)+1))/(a (e^n) (m+1))) ∫(((e x))^(m+n)) (((a+b (x^n)))^p)dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  c*(e*x)^(m+1)*(a+b*x^n)^(p+1)/(a*e*(m+1)) + 
  (a*d*(m+1)-b*c*(m+n*(p+1)+1))/(a*e^n*(m+1))*Int[(e*x)^(m+n)*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b*c-a*d,0] && (IntegerQ[n] || GtQ[e,0]) && 
  (GtQ[n,0] && LtQ[m,-1] || LtQ[n,0] && GtQ[m+n,-1]) && Not[ILtQ[p,-1]]

Int[(e_.*x_)^m_.*(a1_+b1_.*x_^non2_.)^p_.*(a2_+b2_.*x_^non2_.)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  c*(e*x)^(m+1)*(a1+b1*x^(n/2))^(p+1)*(a2+b2*x^(n/2))^(p+1)/(a1*a2*e*(m+1)) + 
  (a1*a2*d*(m+1)-b1*b2*c*(m+n*(p+1)+1))/(a1*a2*e^n*(m+1))*Int[(e*x)^(m+n)*(a1+b1*x^(n/2))^p*(a2+b2*x^(n/2))^p,x] /;
FreeQ[{a1,b1,a2,b2,c,d,e,p},x] && EqQ[non2,n/2] && EqQ[a2*b1+a1*b2,0] && (IntegerQ[n] || GtQ[e,0]) && 
  (GtQ[n,0] && LtQ[m,-1] || LtQ[n,0] && GtQ[m+n,-1]) && Not[ILtQ[p,-1]]

4.  ∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  when  b c-a d≠0 ∧ p<-1

1.  ∫(x^m) (((a+b (x^2)))^p) (c+d (x^2))dx  when  b c-a d≠0 ∧ p<-1 ∧ (m/2)∈ℤ ∧ (p∈ℤ ∨ m+2p+1==0)

1:  ∫(x^m) (((a+b (x^2)))^p) (c+d (x^2))dx  when b c-a d≠0 ∧ p<-1 ∧ (m/2)∈(SuperPlus[ℤ])∧ (p∈ℤ ∨ m+2p+1==0)

Derivation: ???

Note: If (m/2)∈(SuperPlus[ℤ]), (b^(m/2)) (x^(m-2)) (c+d (x^2))-(((-a))^(m/2-1)) (b c-a d) is divisible by a+b (x^2).

Note: The degree of the polynomial in the resulting integrand is m .

Note: This rule should be generalized for integrands of the form (x^m) (((a+b (x^n)))^p) (c+d (x^n)).

Rule 1.1.3.4.5.4.1.1: If  b c-a d≠0 ∧ p<-1 ∧ (m/2)∈(SuperPlus[ℤ])∧ (p∈ℤ ∨ m+2p+1==0), then

∫(x^m) (((a+b (x^2)))^p) (c+d (x^2))dx  ⟶  
(((((-a))^(m/2-1))(b c-a d) x (((a+b (x^2)))^(p+1)))/(2 (b^(m/2+1)) (p+1)))+
(1/(2 (b^(m/2+1)) (p+1)))∫(((a+b (x^2)))^(p+1))(((2 b(p+1) (x^2) ((b^(m/2)) (x^(m-2)) (c+d (x^2))-(((-a))^(m/2-1)) (b c-a d)))/(a+b (x^2)))-(((-a))^(m/2-1)) (b c-a d))dx

Program code:

Int[x_^m_*(a_+b_.*x_^2)^p_*(c_+d_.*x_^2),x_Symbol] :=
  (-a)^(m/2-1)*(b*c-a*d)*x*(a+b*x^2)^(p+1)/(2*b^(m/2+1)*(p+1)) + 
  1/(2*b^(m/2+1)*(p+1))*Int[(a+b*x^2)^(p+1)*
    ExpandToSum[2*b*(p+1)*x^2*Together[(b^(m/2)*x^(m-2)*(c+d*x^2)-(-a)^(m/2-1)*(b*c-a*d))/(a+b*x^2)]-(-a)^(m/2-1)*(b*c-a*d),x],x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && LtQ[p,-1] && IGtQ[m/2,0] && (IntegerQ[p] || EqQ[m+2*p+1,0])

2:  ∫(x^m) (((a+b (x^2)))^p) (c+d (x^2))dx  when b c-a d≠0 ∧ p<-1 ∧ (m/2)∈(SuperMinus[ℤ])∧ (p∈ℤ ∨ m+2p+1==0)

Derivation: ???

Note: If (m/2)∈(SuperMinus[ℤ]), (b^(m/2)) (c+d (x^2))-(((-a))^(m/2-1)) (b c-a d)(x^(-m+2)) is divisible by a+b (x^2).

Note: The degree of the polynomial in the resulting integrand is -m .

Note: This rule should be generalized for integrands of the form (x^m) (((a+b (x^n)))^p) (c+d (x^n)).

Rule 1.1.3.4.5.4.1.2: If  b c-a d≠0 ∧ p<-1 ∧ (m/2)∈(SuperMinus[ℤ])∧ (p∈ℤ ∨ m+2p+1==0), then

∫(x^m) (((a+b (x^2)))^p) (c+d (x^2))dx  ⟶  
(((((-a))^(m/2-1))(b c-a d) x (((a+b (x^2)))^(p+1)))/(2 (b^(m/2+1)) (p+1)))+
(1/(2 (b^(m/2+1)) (p+1)))∫(x^m) (((a+b (x^2)))^(p+1))(((2 b(p+1) ((b^(m/2)) (c+d (x^2))-(((-a))^(m/2-1)) (b c-a d)(x^(-m+2))))/(a+b (x^2)))-(((-a))^(m/2-1)) (b c-a d) (x^(-m)))dx

Program code:

Int[x_^m_*(a_+b_.*x_^2)^p_*(c_+d_.*x_^2),x_Symbol] :=
  (-a)^(m/2-1)*(b*c-a*d)*x*(a+b*x^2)^(p+1)/(2*b^(m/2+1)*(p+1)) + 
  1/(2*b^(m/2+1)*(p+1))*Int[x^m*(a+b*x^2)^(p+1)*
    ExpandToSum[2*b*(p+1)*Together[(b^(m/2)*(c+d*x^2)-(-a)^(m/2-1)*(b*c-a*d)*x^(-m+2))/(a+b*x^2)]-
      (-a)^(m/2-1)*(b*c-a*d)*x^(-m),x],x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && LtQ[p,-1] && ILtQ[m/2,0] && (IntegerQ[p] || EqQ[m+2*p+1,0])

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  when b c-a d≠0 ∧ p<-1

Derivation: Trinomial recurrence 2b with c=0

Rule 1.1.3.4.5.4.2: If  b c-a d≠0 ∧ p<-1, then

∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  ⟶  -(((b c-a d)(((e x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a b e n (p+1)))-((a d (m+1)-b c(m+n (p+1)+1))/(a b n (p+1))) ∫(((e x))^m) (((a+b (x^n)))^(p+1))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  -(b*c-a*d)*(e*x)^(m+1)*(a+b*x^n)^(p+1)/(a*b*e*n*(p+1)) - 
  (a*d*(m+1)-b*c*(m+n*(p+1)+1))/(a*b*n*(p+1))*Int[(e*x)^m*(a+b*x^n)^(p+1),x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[b*c-a*d,0] && LtQ[p,-1] && 
  (Not[IntegerQ[p+1/2]] && NeQ[p,-5/4] || Not[RationalQ[m]] || IGtQ[n,0] && ILtQ[p+1/2,0] && LeQ[-1,m,-n*(p+1)])

Int[(e_.*x_)^m_.*(a1_+b1_.*x_^non2_.)^p_.*(a2_+b2_.*x_^non2_.)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  -(b1*b2*c-a1*a2*d)*(e*x)^(m+1)*(a1+b1*x^(n/2))^(p+1)*(a2+b2*x^(n/2))^(p+1)/(a1*a2*b1*b2*e*n*(p+1)) - 
  (a1*a2*d*(m+1)-b1*b2*c*(m+n*(p+1)+1))/(a1*a2*b1*b2*n*(p+1))*Int[(e*x)^m*(a1+b1*x^(n/2))^(p+1)*(a2+b2*x^(n/2))^(p+1),x] /;
FreeQ[{a1,b1,a2,b2,c,d,e,m,n},x] && EqQ[non2,n/2] && EqQ[a2*b1+a1*b2,0] && LtQ[p,-1] && 
  (Not[IntegerQ[p+1/2]] && NeQ[p,-5/4] || Not[RationalQ[m]] || IGtQ[n,0] && ILtQ[p+1/2,0] && LeQ[-1,m,-n*(p+1)])

5:  ∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  when b c-a d≠0 ∧ m+n (p+1)+1≠0

Derivation: Trinomial recurrence 2b with c=0 composed with binomial recurrence 1b

Rule 1.1.3.4.5.5: If  b c-a d≠0 ∧ m+n (p+1)+1≠0, then

∫(((e x))^m) (((a+b (x^n)))^p) (c+d (x^n))dx  ⟶  ((d (((e x))^(m+1)) (((a+b (x^n)))^(p+1)))/(b e (m+n (p+1)+1)))-((a d (m+1)-b c(m+n (p+1)+1))/(b (m+n (p+1)+1)))∫(((e x))^m) (((a+b (x^n)))^p)dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  d*(e*x)^(m+1)*(a+b*x^n)^(p+1)/(b*e*(m+n*(p+1)+1)) - 
  (a*d*(m+1)-b*c*(m+n*(p+1)+1))/(b*(m+n*(p+1)+1))*Int[(e*x)^m*(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && NeQ[b*c-a*d,0] && NeQ[m+n*(p+1)+1,0]

Int[(e_.*x_)^m_.*(a1_+b1_.*x_^non2_.)^p_.*(a2_+b2_.*x_^non2_.)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  d*(e*x)^(m+1)*(a1+b1*x^(n/2))^(p+1)*(a2+b2*x^(n/2))^(p+1)/(b1*b2*e*(m+n*(p+1)+1)) - 
  (a1*a2*d*(m+1)-b1*b2*c*(m+n*(p+1)+1))/(b1*b2*(m+n*(p+1)+1))*Int[(e*x)^m*(a1+b1*x^(n/2))^p*(a2+b2*x^(n/2))^p,x] /;
FreeQ[{a1,b1,a2,b2,c,d,e,m,n,p},x] && EqQ[non2,n/2] && EqQ[a2*b1+a1*b2,0] && NeQ[m+n*(p+1)+1,0]

6.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈ℤ

1.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])

0:  ∫(((((e x))^m) (((a+b (x^n)))^p))/(c+d (x^n)))dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.1.3.4.6.1.0: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ]), then

∫(((((e x))^m) (((a+b (x^n)))^p))/(c+d (x^n)))dx  ⟶  ∫ExpandIntegrand[(((((e x))^m) (((a+b (x^n)))^p))/(c+d (x^n))),x]dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_/(c_+d_.*x_^n_),x_Symbol] :=
  Int[ExpandIntegrand[(e*x)^m*(a+b*x^n)^p/(c+d*x^n),x],x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && IGtQ[p,0] && (IntegerQ[m] || IGtQ[2*(m+1),0] || Not[RationalQ[m]])

1.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^2)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])

1:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^2)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m<-1 ∧ n>0

Derivation: ?

Rule 1.1.3.4.6.1.1.1: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m<-1 ∧ n>0, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^2)dx  ⟶  
(((c^2)(((e x))^(m+1)) (((a+b (x^n)))^(p+1)))/(a e (m+1)))-(1/(a (e^n) (m+1)))∫(((e x))^(m+n)) (((a+b (x^n)))^p) (b (c^2) n (p+1)+c (b c-2 a d) (m+1)-a (m+1)(d^2) (x^n)) dx

Program code:

Int[(e_.*x_)^m_*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^2,x_Symbol] :=
  c^2*(e*x)^(m+1)*(a+b*x^n)^(p+1)/(a*e*(m+1)) - 
  1/(a*e^n*(m+1))*Int[(e*x)^(m+n)*(a+b*x^n)^p*Simp[b*c^2*n*(p+1)+c*(b*c-2*a*d)*(m+1)-a*(m+1)*d^2*x^n,x],x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[m,-1] && GtQ[n,0]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^2)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1

Derivation: ?

Rule 1.1.3.4.6.1.1.2: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^2)dx  ⟶  
-(((((b c-a d))^2) (((e x))^(m+1))(((a+b (x^n)))^(p+1)))/(a (b^2) e n (p+1)))+(1/(a (b^2) n (p+1)))∫(((e x))^m) (((a+b (x^n)))^(p+1)) ((((b c-a d))^2) (m+1)+(b^2) (c^2) n (p+1)+a b (d^2) n (p+1)(x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^2,x_Symbol] :=
  -(b*c-a*d)^2*(e*x)^(m+1)*(a+b*x^n)^(p+1)/(a*b^2*e*n*(p+1)) + 
  1/(a*b^2*n*(p+1))*Int[(e*x)^m*(a+b*x^n)^(p+1)*Simp[(b*c-a*d)^2*(m+1)+b^2*c^2*n*(p+1)+a*b*d^2*n*(p+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[p,-1]

3:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^2)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m+n (p+2)+1≠0

Derivation: ?

Rule 1.1.3.4.6.1.1.3: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m+n (p+2)+1≠0, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^2)dx  ⟶  
(((d^2)(((e x))^(m+n+1))(((a+b (x^n)))^(p+1)))/(b (e^(n+1))(m+n (p+2)+1)))+
(1/(b (m+n (p+2)+1)))∫(((e x))^m) (((a+b (x^n)))^p) (b (c^2)(m+n (p+2)+1)+d ((2 b c-a d) (m+n+1)+2 b c n (p+1)) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^2,x_Symbol] :=
  d^2*(e*x)^(m+n+1)*(a+b*x^n)^(p+1)/(b*e^(n+1)*(m+n*(p+2)+1)) + 
  1/(b*(m+n*(p+2)+1))*Int[(e*x)^m*(a+b*x^n)^p*Simp[b*c^2*(m+n*(p+2)+1)+d*((2*b*c-a*d)*(m+n+1)+2*b*c*n*(p+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && NeQ[m+n*(p+2)+1,0]

2:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈ℤ ∧ GCD[m+1,n]≠1

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ m∈ℤ, let k=GCD[m+1,n], then (x^m) F[(x^n)]==(1/k)Subst[(x^(((m+1)/k)-1)) F[(x^(n/k))],x,(x^k)] (∂_x)(x^k)

Rule 1.1.3.4.6.1.2: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈ℤ, let k=GCD[m+1,n], if  k≠1, then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (1/k) Subst[∫(x^(((m+1)/k)-1)) (((a+b (x^(n/k))))^p) (((c+d (x^(n/k))))^q)dx,x,(x^k)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  With[{k=GCD[m+1,n]},
  1/k*Subst[Int[x^((m+1)/k-1)*(a+b*x^(n/k))^p*(c+d*x^(n/k))^q,x],x,x^k] /;
 k≠1] /;
FreeQ[{a,b,c,d,p,q},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && IntegerQ[m]

3:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (((e x))^m) F[x]==(k/e) Subst[(x^(k (m+1)-1))F[((x^k)/e)],x,(((e x))^(1/k))] (∂_x)(((e x))^(1/k))

Rule 1.1.3.4.6.1.3: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈𝔽, let k=Denominator[m], then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (k/e) Subst[∫(x^(k (m+1)-1)) (((a+((b (x^(k n)))/(e^n))))^p) (((c+((d (x^(k n)))/(e^n))))^q) dx,x,(((e x))^(1/k))]

Program code:

Int[(e_.*x_)^m_*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  With[{k=Denominator[m]},
  k/e*Subst[Int[x^(k*(m+1)-1)*(a+b*x^(k*n)/e^n)^p*(c+d*x^(k*n)/e^n)^q,x],x,(e*x)^(1/k)]] /;
FreeQ[{a,b,c,d,e,p,q},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && FractionQ[m] && IntegerQ[p]

4.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1

1.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ q>0

1:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ q>0 ∧ m-n+1>0

Derivation: Binomial product recurrence 1 with A=0, B=1 and m=m-n

Derivation: Binomial product recurrence 3a with A=c, B=d and q=q-1

Rule 1.1.3.4.6.1.4.1.1: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ q>0 ∧ m-n+1>0, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
(((e^(n-1)) (((e x))^(m-n+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^q))/(b n (p+1)))-((e^n)/(b n (p+1)))∫(((e x))^(m-n)) (((a+b (x^n)))^(p+1)) (((c+d (x^n)))^(q-1)) (c(m-n+1)+d(m+n (q-1)+1) (x^n)) dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  e^(n-1)*(e*x)^(m-n+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^q/(b*n*(p+1)) - 
  e^n/(b*n*(p+1))*Int[(e*x)^(m-n)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)*Simp[c*(m-n+1)+d*(m+n*(q-1)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[p,-1] && GtQ[q,0] && GtQ[m-n+1,0] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ q>1

Derivation: Binomial product recurrence 1 with A=c, B=d and q=q-1

Rule 1.1.3.4.6.1.4.1.2: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ q>1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
((-(c b-a d) (((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q-1)))/(a b e n (p+1)))+(1/(a b n (p+1)))·
∫(((e x))^m) (((a+b (x^n)))^(p+1)) (((c+d (x^n)))^(q-2))(c (c b n (p+1)+(c b-a d) (m+1))+d (c b n (p+1)+(c b-a d) (m+n (q-1)+1)) (x^n))dx

Programcode:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -(c*b-a*d)*(e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)/(a*b*e*n*(p+1)) + 
  1/(a*b*n*(p+1))*Int[(e*x)^m*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-2)*
    Simp[c*(c*b*n*(p+1)+(c*b-a*d)*(m+1))+d*(c*b*n*(p+1)+(c*b-a*d)*(m+n*(q-1)+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[p,-1] && GtQ[q,1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

3:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ 0<q<1

Derivation: Binomial product recurrence 1 with A=1 and B=0

Derivation: Binomial product recurrence 3b with A=c, B=d and q=q-1

Rule 1.1.3.4.6.1.4.1.3: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ 0<q<1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
-(((((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^q))/(a e n (p+1)))+
(1/(a n (p+1)))∫(((e x))^m) (((a+b (x^n)))^(p+1)) (((c+d (x^n)))^(q-1)) (c (m+n (p+1)+1)+d (m+n (p+q+1)+1) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -(e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^q/(a*e*n*(p+1)) + 
  1/(a*n*(p+1))*Int[(e*x)^m*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)*Simp[c*(m+n*(p+1)+1)+d*(m+n*(p+q+1)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[p,-1] && LtQ[0,q,1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

2.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ m-n+1>0

1:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ m-n+1>n

Derivation: Binomial product recurrence 3a with A=0, B=1 and m=m-n

Rule 1.1.3.4.6.1.4.2.1: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ m-n+1>n, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
-((a (e^(2 n-1)) (((e x))^(m-2n+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q+1)))/(b n(b c-a d)(p+1)))+
((e^(2 n))/(b n(b c-a d)(p+1)))∫(((e x))^(m-2n)) (((a+b (x^n)))^(p+1)) (((c+d (x^n)))^q) (a c(m-2n+1)+(a d(m-n+n q+1)+b c n (p+1)) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -a*e^(2*n-1)*(e*x)^(m-2*n+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q+1)/(b*n*(b*c-a*d)*(p+1)) + 
  e^(2*n)/(b*n*(b*c-a*d)*(p+1))*Int[(e*x)^(m-2*n)*(a+b*x^n)^(p+1)*(c+d*x^n)^q*
    Simp[a*c*(m-2*n+1)+(a*d*(m-n+n*q+1)+b*c*n*(p+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[p,-1] && GtQ[m-n+1,n] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ n≥m-n+1>0

Derivation: Binomial product recurrence 3a with A=1 and B=0

Derivation: Binomial product recurrence 3b with A=0, B=1 and m=m-n

Rule 1.1.3.4.6.1.4.2.2: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ n≥m-n+1>0, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
(((e^(n-1)) (((e x))^(m-n+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q+1)))/(n(b c-a d)(p+1)))-
((e^n)/(n(b c-a d)(p+1)))∫(((e x))^(m-n)) (((a+b (x^n)))^(p+1)) (((c+d (x^n)))^q) (c(m-n+1)+d(m+n (p+q+1)+1) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  e^(n-1)*(e*x)^(m-n+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q+1)/(n*(b*c-a*d)*(p+1)) - 
  e^n/(n*(b*c-a*d)*(p+1))*Int[(e*x)^(m-n)*(a+b*x^n)^(p+1)*(c+d*x^n)^q*Simp[c*(m-n+1)+d*(m+n*(p+q+1)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[p,-1] && GeQ[n,m-n+1] && GtQ[m-n+1,0] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

3:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1

Derivation: Binomial product recurrence 3b with A=1 and B=0

Rule 1.1.3.4.6.1.4.3: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
-((b (((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q+1)))/(a e n(b c-a d)(p+1)))+
(1/(a n(b c-a d)(p+1)))∫(((e x))^m) (((a+b (x^n)))^(p+1)) (((c+d (x^n)))^q) (c b(m+1)+n (b c-a d)(p+1)+d b (m+n (p+q+2)+1) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -b*(e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q+1)/(a*e*n*(b*c-a*d)*(p+1)) + 
  1/(a*n*(b*c-a*d)*(p+1))*
    Int[(e*x)^m*(a+b*x^n)^(p+1)*(c+d*x^n)^q*Simp[c*b*(m+1)+n*(b*c-a*d)*(p+1)+d*b*(m+n*(p+q+2)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m,q},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[p,-1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

5.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>0

1.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>0 ∧ m<-1

1:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>0 ∧ m<-1 ∧ p>0

Derivation: Binomial product recurrence 2a with A=a, B=b and p=p-1

Rule 1.1.3.4.6.1.5.1.1: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>0 ∧ m<-1 ∧ p>0, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
(((((e x))^(m+1)) (((a+b (x^n)))^p) (((c+d (x^n)))^q))/(e (m+1)))-(n/((e^n) (m+1)))∫(((e x))^(m+n)) (((a+b (x^n)))^(p-1)) (((c+d (x^n)))^(q-1)) (b c p+a d q+b d (p+q) (x^n))dx

Program code:

Int[(e_.*x_)^m_*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  (e*x)^(m+1)*(a+b*x^n)^p*(c+d*x^n)^q/(e*(m+1)) - 
  n/(e^n*(m+1))*Int[(e*x)^(m+n)*(a+b*x^n)^(p-1)*(c+d*x^n)^(q-1)*Simp[b*c*p+a*d*q+b*d*(p+q)*x^n,x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && GtQ[q,0] && LtQ[m,-1] && GtQ[p,0] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>1 ∧ m<-1

Derivation: Binomial product recurrence 2a with A=c, B=d and q=q-1

Rule 1.1.3.4.6.1.5.1.2: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>1 ∧ m<-1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
((c (((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q-1)))/(a e (m+1)))-(1/(a (e^n) (m+1)))·
∫(((e x))^(m+n)) (((a+b (x^n)))^p) (((c+d (x^n)))^(q-2))(c(c b-a d)(m+1)+c n (b c (p+1)+a d (q-1))+d ((c b-a d) (m+1)+c b n (p+q)) (x^n))dx

Program code:

Int[(e_.*x_)^m_*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  c*(e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)/(a*e*(m+1)) - 
  1/(a*e^n*(m+1))*Int[(e*x)^(m+n)*(a+b*x^n)^p*(c+d*x^n)^(q-2)*
    Simp[c*(c*b-a*d)*(m+1)+c*n*(b*c*(p+1)+a*d*(q-1))+d*((c*b-a*d)*(m+1)+c*b*n*(p+q))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && GtQ[q,1] && LtQ[m,-1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

3:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ 0<q<1 ∧ m<-1

Derivation: Binomial product recurrence 2a with A=1 and B=0

Derivation: Binomial product recurrence 4b with A=c, B=d and q=q-1

Rule 1.1.3.4.6.1.5.1.3: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ 0<q<1 ∧ m<-1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
(((((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^q))/(a e (m+1)))-
(1/(a (e^n) (m+1)))∫(((e x))^(m+n)) (((a+b (x^n)))^p) (((c+d (x^n)))^(q-1)) (c b(m+1)+n (b c (p+1)+a d q)+d (b (m+1)+b n (p+q+1)) (x^n))dx

Program code:

Int[(e_.*x_)^m_*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  (e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^q/(a*e*(m+1)) - 
  1/(a*e^n*(m+1))*Int[(e*x)^(m+n)*(a+b*x^n)^p*(c+d*x^n)^(q-1)*
    Simp[c*b*(m+1)+n*(b*c*(p+1)+a*d*q)+d*(b*(m+1)+b*n*(p+q+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[0,q,1] && LtQ[m,-1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>0 ∧ p>0

Derivation: Binomial product recurrence 2b with A=a, B=b and p=p-1

Rule 1.1.3.4.6.1.5.2: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>0 ∧ p>0, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
(((((e x))^(m+1)) (((a+b (x^n)))^p) (((c+d (x^n)))^q))/(e(m+n (p+q)+1)))+
(n/(m+n (p+q)+1))∫(((e x))^m) (((a+b (x^n)))^(p-1)) (((c+d (x^n)))^(q-1)) (a c(p+q)+(q(b c-a d)+a d(p+q)) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  (e*x)^(m+1)*(a+b*x^n)^p*(c+d*x^n)^q/(e*(m+n*(p+q)+1)) + 
  n/(m+n*(p+q)+1)*Int[(e*x)^m*(a+b*x^n)^(p-1)*(c+d*x^n)^(q-1)*Simp[a*c*(p+q)+(q*(b*c-a*d)+a*d*(p+q))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && GtQ[q,0] && GtQ[p,0] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

3:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>1

Derivation: Binomial product recurrence 2b with A=c, B=d and q=q-1

Rule 1.1.3.4.6.1.5.3: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
((d (((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q-1)))/(b e (m+n (p+q)+1)))+(1/(b (m+n (p+q)+1)))∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^(q-2))·
(c ((c b-a d) (m+1)+c b n (p+q))+(d(c b-a d) (m+1)+d n (q-1)(b c-a d)+c b d n (p+q)) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  d*(e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)/(b*e*(m+n*(p+q)+1)) + 
  1/(b*(m+n*(p+q)+1))*Int[(e*x)^m*(a+b*x^n)^p*(c+d*x^n)^(q-2)*
    Simp[c*((c*b-a*d)*(m+1)+c*b*n*(p+q))+(d*(c*b-a*d)*(m+1)+d*n*(q-1)*(b*c-a*d)+c*b*d*n*(p+q))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && GtQ[q,1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

4:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>0 ∧ m-n+1>0

Derivation: Binomial product recurrence 2b with A=0, B=1 and m=m-n

Derivation: Binomial product recurrence 4a with A=c, B=d and q=q-1

Rule 1.1.3.4.6.1.5.4: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ q>0 ∧ m-n+1>0, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
(((e^(n-1))(((e x))^(m-n+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^q))/(b (m+n (p+q)+1)))-
((e^n)/(b (m+n (p+q)+1)))∫(((e x))^(m-n)) (((a+b (x^n)))^p) (((c+d (x^n)))^(q-1)) (a c (m-n+1)+(a d(m-n+1)-n q(b c-a d)) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  e^(n-1)*(e*x)^(m-n+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^q/(b*(m+n*(p+q)+1)) - 
  e^n/(b*(m+n*(p+q)+1))*
    Int[(e*x)^(m-n)*(a+b*x^n)^p*(c+d*x^n)^(q-1)*Simp[a*c*(m-n+1)+(a*d*(m-n+1)-n*q*(b*c-a*d))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && GtQ[q,0] && GtQ[m-n+1,0] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

6:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m-n+1>n

Derivation: Binomial product recurrence 4a with A=0, B=1 and m=m-n

Rule 1.1.3.4.6.1.6: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m-n+1>n, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
(((e^(2 n-1)) (((e x))^(m-2n+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q+1)))/(b d (m+n (p+q)+1)))-((e^(2 n))/(b d (m+n (p+q)+1)))·
∫(((e x))^(m-2n)) (((a+b (x^n)))^p) (((c+d (x^n)))^q)(a c (m-2n+1)+(a d (m+n(q-1)+1)+b c (m+n(p-1)+1)) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  e^(2*n-1)*(e*x)^(m-2*n+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q+1)/(b*d*(m+n*(p+q)+1)) - 
  e^(2*n)/(b*d*(m+n*(p+q)+1))*
    Int[(e*x)^(m-2*n)*(a+b*x^n)^p*(c+d*x^n)^q*Simp[a*c*(m-2*n+1)+(a*d*(m+n*(q-1)+1)+b*c*(m+n*(p-1)+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,p,q},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && GtQ[m-n+1,n] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

7:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m<-1

Derivation: Binomial product recurrence 4b with A=1 and B=0

Rule 1.1.3.4.6.1.7: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ m<-1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
(((((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q+1)))/(a c e(m+1)))-
(1/(a c (e^n) (m+1)))∫(((e x))^(m+n)) (((a+b (x^n)))^p) (((c+d (x^n)))^q) ((b c+a d) (m+n+1)+n (b c p+a d q)+b d (m+n (p+q+2)+1) (x^n))dx

Program code:

Int[(e_.*x_)^m_*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  (e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q+1)/(a*c*e*(m+1)) - 
  1/(a*c*e^n*(m+1))*
    Int[(e*x)^(m+n)*(a+b*x^n)^p*(c+d*x^n)^q*Simp[(b*c+a*d)*(m+n+1)+n*(b*c*p+a*d*q)+b*d*(m+n*(p+q+2)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,p,q},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[m,-1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

8.  ∫(((((e x))^m) (((c+d (x^n)))^q))/(a+b (x^n)))dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])

1.  ∫((((e x))^m)/((a+b (x^n)) (c+d (x^n))))dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])

1:  ∫((((e x))^m)/((a+b (x^n)) (c+d (x^n))))dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ n≤m≤2n-1

Derivation: Algebraic expansion

Basis: If  n∈ℤ, then ((((e x))^m)/((a+b (x^n)) (c+d (x^n))))==-((a (e^n) (((e x))^(m-n)))/((b c-a d) (a+b (x^n))))+((c (e^n) (((e x))^(m-n)))/((b c-a d) (c+d (x^n))))

Rule 1.1.3.4.6.1.8.1.1: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ n≤m≤2n-1, then

∫((((e x))^m)/((a+b (x^n)) (c+d (x^n))))dx  ⟶  -((a (e^n))/(b c-a d))∫((((e x))^(m-n))/(a+b (x^n)))dx+((c (e^n))/(b c-a d))∫((((e x))^(m-n))/(c+d (x^n)))dx

Program code:

Int[(e_.*x_)^m_./((a_+b_.*x_^n_)*(c_+d_.*x_^n_)),x_Symbol] :=
  -a*e^n/(b*c-a*d)*Int[(e*x)^(m-n)/(a+b*x^n),x] + c*e^n/(b*c-a*d)*Int[(e*x)^(m-n)/(c+d*x^n),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LeQ[n,m,2*n-1]

2:  ∫((((e x))^m)/((a+b (x^n)) (c+d (x^n))))dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (1/((a+b z) (c+d z)))==(b/((b c-a d) (a+b z)))-(d/((b c-a d) (c+d z)))

Rule 1.1.3.4.6.1.8.1.2: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ]), then

∫((((e x))^m)/((a+b (x^n)) (c+d (x^n))))dx  ⟶  (b/(b c-a d))∫((((e x))^m)/(a+b (x^n)))dx-(d/(b c-a d))∫((((e x))^m)/(c+d (x^n)))dx

Program code:

Int[(e_.*x_)^m_./((a_+b_.*x_^n_)*(c_+d_.*x_^n_)),x_Symbol] :=
  b/(b*c-a*d)*Int[(e*x)^m/(a+b*x^n),x] - d/(b*c-a*d)*Int[(e*x)^m/(c+d*x^n),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b*c-a*d,0] && IGtQ[n,0]

2:  ∫(((((e x))^m) (((c+d (x^n)))^q))/(a+b (x^n)))dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ n≤m≤2 n-1

Derivation: Algebraic expansion

Basis: If  n∈ℤ, then (1/(a+b (x^n)))==(((e^n) (((e x))^(-n)))/b)-((a (e^n) (((e x))^(-n)))/(b (a+b (x^n))))

Rule 1.1.3.4.6.1.8.2: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ n≤m≤2 n-1, then

∫(((((e x))^m) (((c+d (x^n)))^q))/(a+b (x^n)))dx  ⟶  ((e^n)/b)∫(((e x))^(m-n))(((c+d (x^n)))^q)dx-((a (e^n))/b)∫(((((e x))^(m-n)) (((c+d (x^n)))^q))/(a+b (x^n)))dx

Program code:

Int[(e_.*x_)^m_*(c_+d_.*x_^n_)^q_./(a_+b_.*x_^n_),x_Symbol] :=
  e^n/b*Int[(e*x)^(m-n)*(c+d*x^n)^q,x] - a*e^n/b*Int[(e*x)^(m-n)*(c+d*x^n)^q/(a+b*x^n),x] /;
FreeQ[{a,b,c,d,e,m,q},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LeQ[n,m,2*n-1] && IntBinomialQ[a,b,c,d,e,m,n,-1,q,x]

3.  ∫((x (((a+b (x^n)))^p))/(c+d (x^n)))dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])

1:  ∫((x (((a+b (x^n)))^p))/(c+d (x^n)))dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0

Derivation: Algebraic expansion

Basis: ((((a+b z))^p)/(c+d z))==((b (((a+b z))^(p-1)))/d)-(((b c-a d) (((a+b z))^(p-1)))/(d (c+d z)))

Rule 1.1.3.4.6.1.8.3.1: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0, then

∫((x (((a+b (x^n)))^p))/(c+d (x^n)))dx  ⟶  (b/d) ∫x (((a+b (x^n)))^(p-1))dx-((b c-a d)/d) ∫((x (((a+b (x^n)))^(p-1)))/(c+d (x^n)))dx

Program code:

Int[x_*(a_+b_.*x_^n_)^p_/(c_+d_.*x_^n_),x_Symbol] :=
  b/d*Int[x*(a+b*x^n)^(p-1),x] - (b*c-a*d)/d*Int[x*(a+b*x^n)^(p-1)/(c+d*x^n),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && GtQ[p,0] && IntBinomialQ[a,b,c,d,1,1,n,p,-1,x]

2:  ∫((x (((a+b (x^n)))^p))/(c+d (x^n)))dx  when b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1

Derivation: Algebraic expansion

Basis: ((((a+b z))^p)/(c+d z))==((b (((a+b z))^p))/(b c-a d))-((d (((a+b z))^(p+1)))/((b c-a d) (c+d z)))

Rule 1.1.3.4.6.1.8.3.2: If  b c-a d≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1, then

∫((x (((a+b (x^n)))^p))/(c+d (x^n)))dx  ⟶  (b/(b c-a d)) ∫x (((a+b (x^n)))^p)dx-(d/(b c-a d)) ∫((x (((a+b (x^n)))^(p+1)))/(c+d (x^n)))dx

Program code:

Int[x_*(a_+b_.*x_^n_)^p_/(c_+d_.*x_^n_),x_Symbol] :=
  b/(b*c-a*d)*Int[x*(a+b*x^n)^(p-1),x] - d/(b*c-a*d)*Int[x*(a+b*x^n)^(p+1)/(c+d*x^n),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && LtQ[p,-1] && IntBinomialQ[a,b,c,d,1,1,n,p,-1,x]

3.  ∫(x/((Sqrt[a+b (x^3)]) (c+d (x^3))))dx  when  b c-a d≠0 ∧ (b c-4 a d==0 ∨ b c+8 a d==0 ∨ (b^2) (c^2)-20 a b c d-8 (a^2) (d^2)==0)

1.  ∫(x/((a+b (x^3)) (Sqrt[c+d (x^3)])))dx  when  b c-a d≠0 ∧ 4 b c-a d==0

1:  ∫(x/((a+b (x^3)) (Sqrt[c+d (x^3)])))dx  when b c-a d≠0 ∧ 4 b c-a d==0 ∧ c>0

Reference: Goursat pseudo-elliptic integral

Attribution: Martin Welz on 24 January 2018 via sci.math.symbolic

Derivation: Algebraic expansion

Basis: If  4 b c-a d==0 ∧ c>0, let q->((((d/c)))^(1/3)), then (x/((a+b (x^3)) (Sqrt[c+d (x^3)])))==-(q/(6 (2^(2/3)) b x (Sqrt[c+d (x^3)])))+((d q (x^2))/((2^(5/3)) b (4 c+d (x^3)) (Sqrt[c+d (x^3)])))-(((q^2) ((2^(2/3))-2 q x))/(12 b (2+(2^(1/3)) q x) (Sqrt[c+d (x^3)])))+((q ((2^(4/3))+3 (q^2) (x^2)-(2^(1/3)) (q^3) (x^3)))/(6 (2^(2/3)) b x ((2^(4/3))-(2^(2/3)) q x+(q^2) (x^2)) (Sqrt[c+d (x^3)])))

Rule 1.1.3.4.6.1.8.3.3.1.1: If  b c-a d≠0 ∧ 4 b c-a d==0 ∧ c>0, let q->((((d/c)))^(1/3)), then

∫(x/((a+b (x^3)) (Sqrt[c+d (x^3)])))dx  ⟶  

-∫(q/(6 (2^(2/3)) b x (Sqrt[c+d (x^3)])))dx+∫((d q (x^2))/((2^(5/3)) b (4 c+d (x^3)) (Sqrt[c+d (x^3)])))dx-∫(((q^2) ((2^(2/3))-2 q x))/(12 b (2+(2^(1/3)) q x) (Sqrt[c+d (x^3)])))dx+∫((q ((2^(4/3))+3 (q^2) (x^2)-(2^(1/3)) (q^3) (x^3)))/(6 (2^(2/3)) b x ((2^(4/3))-(2^(2/3)) q x+(q^2) (x^2)) (Sqrt[c+d (x^3)])))dx  ⟶  

((q ArcTanh[((Sqrt[c+d (x^3)])/(Sqrt[c]))])/(9 (2^(2/3)) b (Sqrt[c])))+((q ArcTan[((Sqrt[c+d (x^3)])/((Sqrt[3]) (Sqrt[c])))])/(3 (2^(2/3)) (Sqrt[3]) b (Sqrt[c])))-((q ArcTan[(((Sqrt[3]) (Sqrt[c]) (1+(2^(1/3)) q x))/(Sqrt[c+d (x^3)]))])/(3 (2^(2/3)) (Sqrt[3]) b (Sqrt[c])))-((q ArcTanh[(((Sqrt[c]) (1-(2^(1/3)) q x))/(Sqrt[c+d (x^3)]))])/(3 (2^(2/3)) b (Sqrt[c])))

Program code:

Int[x_/((a_+b_.*x_^3)*Sqrt[c_+d_.*x_^3]),x_Symbol] :=
  With[{q=Rt[d/c,3]},
  q*ArcTanh[Sqrt[c+d*x^3]/Rt[c,2]]/(9*2^(2/3)*b*Rt[c,2]) + 
  q*ArcTan[Sqrt[c+d*x^3]/(Sqrt[3]*Rt[c,2])]/(3*2^(2/3)*Sqrt[3]*b*Rt[c,2]) - 
  q*ArcTan[Sqrt[3]*Rt[c,2]*(1+2^(1/3)*q*x)/Sqrt[c+d*x^3]]/(3*2^(2/3)*Sqrt[3]*b*Rt[c,2]) - 
  q*ArcTanh[Rt[c,2]*(1-2^(1/3)*q*x)/Sqrt[c+d*x^3]]/(3*2^(2/3)*b*Rt[c,2])] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[4*b*c-a*d,0] && PosQ[c]

2:  ∫(x/((a+b (x^3)) (Sqrt[c+d (x^3)])))dx  when b c-a d≠0 ∧ 4 b c-a d==0 ∧ c≯0

Reference: Goursat pseudo-elliptic integral

Derivation: Algebraic expansion

Basis: If  4 b c-a d==0 ∧ c>0, let q->((((d/c)))^(1/3)), then (x/((a+b (x^3)) (Sqrt[c+d (x^3)])))==-(q/(6 (2^(2/3)) b x (Sqrt[c+d (x^3)])))+((d q (x^2))/((2^(5/3)) b (4 c+d (x^3)) (Sqrt[c+d (x^3)])))-(((q^2) ((2^(2/3))-2 q x))/(12 b (2+(2^(1/3)) q x) (Sqrt[c+d (x^3)])))+((q ((2^(4/3))+3 (q^2) (x^2)-(2^(1/3)) (q^3) (x^3)))/(6 (2^(2/3)) b x ((2^(4/3))-(2^(2/3)) q x+(q^2) (x^2)) (Sqrt[c+d (x^3)])))

Rule 1.1.3.4.6.1.8.3.3.1.2: If  b c-a d≠0 ∧ 4 b c-a d==0 ∧ c≯0, let q->((((d/c)))^(1/3)), then

∫(x/((a+b (x^3)) (Sqrt[c+d (x^3)])))dx  ⟶  

-∫(q/(6 (2^(2/3)) b x (Sqrt[c+d (x^3)])))dx+∫((d q (x^2))/((2^(5/3)) b (4 c+d (x^3)) (Sqrt[c+d (x^3)])))dx-∫(((q^2) ((2^(2/3))-2 q x))/(12 b (2+(2^(1/3)) q x) (Sqrt[c+d (x^3)])))dx+∫((q ((2^(4/3))+3 (q^2) (x^2)-(2^(1/3)) (q^3) (x^3)))/(6 (2^(2/3)) b x ((2^(4/3))-(2^(2/3)) q x+(q^2) (x^2)) (Sqrt[c+d (x^3)])))dx

  ⟶  -((q ArcTan[((Sqrt[c+d (x^3)])/(Sqrt[-c]))])/(9 (2^(2/3)) b (Sqrt[-c])))-((q ArcTanh[((Sqrt[c+d (x^3)])/((Sqrt[3]) (Sqrt[-c])))])/(3 (2^(2/3)) (Sqrt[3]) b (Sqrt[-c])))-((q ArcTanh[(((Sqrt[3]) (Sqrt[-c]) (1+(2^(1/3)) q x))/(Sqrt[c+d (x^3)]))])/(3 (2^(2/3)) (Sqrt[3]) b (Sqrt[-c])))-((q ArcTan[(((Sqrt[-c]) (1-(2^(1/3)) q x))/(Sqrt[c+d (x^3)]))])/(3 (2^(2/3)) b (Sqrt[-c])))

Program code:

Int[x_/((a_+b_.*x_^3)*Sqrt[c_+d_.*x_^3]),x_Symbol] :=
  With[{q=Rt[d/c,3]},
  -q*ArcTan[Sqrt[c+d*x^3]/Rt[-c,2]]/(9*2^(2/3)*b*Rt[-c,2]) - 
  q*ArcTanh[Sqrt[c+d*x^3]/(Sqrt[3]*Rt[-c,2])]/(3*2^(2/3)*Sqrt[3]*b*Rt[-c,2]) - 
  q*ArcTanh[Sqrt[3]*Rt[-c,2]*(1+2^(1/3)*q*x)/Sqrt[c+d*x^3]]/(3*2^(2/3)*Sqrt[3]*b*Rt[-c,2]) - 
  q*ArcTan[Rt[-c,2]*(1-2^(1/3)*q*x)/Sqrt[c+d*x^3]]/(3*2^(2/3)*b*Rt[-c,2])] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[4*b*c-a*d,0] && NegQ[c]

2:  ∫(x/((a+b (x^3)) (Sqrt[c+d (x^3)])))dx  when b c-a d≠0 ∧ 8 b c+a d==0

Reference: Goursat pseudo-elliptic integral

Attribution: Martin Welz on 22 January 2018 via sci.math.symbolic

Derivation: Algebraic expansion

Basis:  If  8 b c+a d==0, let q->((((d/c)))^(1/3)), then (x/(a+b (x^3)))==((d q (x^2))/(4 b (8 c-d (x^3))))-(((q^2) (1+q x))/(12 b (2-q x)))+((2 c (q^2)-2 d x-d q (x^2))/(12 b c (4+2 q x+(q^2) (x^2))))

Rule 1.1.3.4.6.1.8.3.3.2: If  b c-a d≠0 ∧ 8 b c+a d==0, let q->((((d/c)))^(1/3)), then

∫(x/((a+b (x^3)) (Sqrt[c+d (x^3)])))dx  ⟶  ((d q)/(4 b)) ∫((x^2)/((8 c-d (x^3)) (Sqrt[c+d (x^3)])))dx-((q^2)/(12 b)) ∫((1+q x)/((2-q x) (Sqrt[c+d (x^3)])))dx+(1/(12 b c)) ∫((2 c (q^2)-2 d x-d q (x^2))/((4+2 q x+(q^2) (x^2)) (Sqrt[c+d (x^3)])))dx

Program code:

Int[x_/((a_+b_.*x_^3)*Sqrt[c_+d_.*x_^3]),x_Symbol] :=
  With[{q=Rt[d/c,3]},
  d*q/(4*b)*Int[x^2/((8*c-d*x^3)*Sqrt[c+d*x^3]),x] - 
  q^2/(12*b)*Int[(1+q*x)/((2-q*x)*Sqrt[c+d*x^3]),x] + 
  1/(12*b*c)*Int[(2*c*q^2-2*d*x-d*q*x^2)/((4+2*q*x+q^2*x^2)*Sqrt[c+d*x^3]),x]] /; 
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[8*b*c+a*d,0]

3.  ∫(x/((Sqrt[a+b (x^3)]) (c+d (x^3))))dx  when  b c-a d≠0 ∧ (b^2) (c^2)-20 a b c d-8 (a^2) (d^2)==0

1:  ∫(x/((Sqrt[a+b (x^3)]) (c+d (x^3))))dx  when b c-a d≠0 ∧ (b^2) (c^2)-20 a b c d-8 (a^2) (d^2)==0 ∧ a>0

Reference: Goursat pseudo-elliptic integral

Note: If (b^2) (c^2)-20 a b c d-8 (a^2) (d^2)==(b c-10 a d+6 (Sqrt[3]) a d) (b c-10 a d-6 (Sqrt[3]) a d)==0, then ((b c-10 a d)/(6 a d)) should simplify to (Sqrt[3]) or -(Sqrt[3]).

Rule 1.1.3.4.6.1.8.3.3.3.1: If  b c-a d≠0 ∧ (b^2) (c^2)-20 a b c d-8 (a^2) (d^2)==0 ∧ a>0, let q->((((b/a)))^(1/3)) and r->((b c-10 a d)/(6 a d)), then

∫(x/((Sqrt[a+b (x^3)]) (c+d (x^3))))dx  ⟶  
-((q (2-r) ArcTan[(((1-r) (Sqrt[a+b (x^3)]))/((Sqrt[2]) (Sqrt[a]) (r^(3/2))))])/(3 (Sqrt[2]) (Sqrt[a]) d (r^(3/2))))-((q (2-r) ArcTan[(((Sqrt[a]) (Sqrt[r]) (1+r) (1+q x))/((Sqrt[2]) (Sqrt[a+b (x^3)])))])/(2 (Sqrt[2]) (Sqrt[a]) d (r^(3/2))))-((q (2-r) ArcTanh[(((Sqrt[a]) (1-r) (Sqrt[r]) (1+q x))/((Sqrt[2]) (Sqrt[a+b (x^3)])))])/(6 (Sqrt[2]) (Sqrt[a]) d (Sqrt[r])))-((q (2-r) ArcTanh[(((Sqrt[a]) (Sqrt[r]) (1+r-2 q x))/((Sqrt[2]) (Sqrt[a+b (x^3)])))])/(3 (Sqrt[2]) (Sqrt[a]) d (Sqrt[r])))

Program code:

Int[x_/((c_+d_.*x_^3)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  With[{q=Rt[b/a,3],r=Simplify[(b*c-10*a*d)/(6*a*d)]},
  -q*(2-r)*ArcTan[(1-r)*Sqrt[a+b*x^3]/(Sqrt[2]*Rt[a,2]*r^(3/2))]/(3*Sqrt[2]*Rt[a,2]*d*r^(3/2)) - 
  q*(2-r)*ArcTan[Rt[a,2]*Sqrt[r]*(1+r)*(1+q*x)/(Sqrt[2]*Sqrt[a+b*x^3])]/(2*Sqrt[2]*Rt[a,2]*d*r^(3/2)) - 
  q*(2-r)*ArcTanh[Rt[a,2]*(1-r)*Sqrt[r]*(1+q*x)/(Sqrt[2]*Sqrt[a+b*x^3])]/(6*Sqrt[2]*Rt[a,2]*d*Sqrt[r]) - 
  q*(2-r)*ArcTanh[Rt[a,2]*Sqrt[r]*(1+r-2*q*x)/(Sqrt[2]*Sqrt[a+b*x^3])]/(3*Sqrt[2]*Rt[a,2]*d*Sqrt[r])] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[b^2*c^2-20*a*b*c*d-8*a^2*d^2,0] && PosQ[a]

2:  ∫(x/((Sqrt[a+b (x^3)]) (c+d (x^3))))dx  when b c-a d≠0 ∧ (b^2) (c^2)-20 a b c d-8 (a^2) (d^2)==0 ∧ a≯0

Reference: Goursat pseudo-elliptic integral

Note: If (b^2) (c^2)-20 a b c d-8 (a^2) (d^2)==(b c-10 a d+6 (Sqrt[3]) a d) (b c-10 a d-6 (Sqrt[3]) a d)==0, then ((b c-10 a d)/(6 a d)) should simplify to (Sqrt[3]) or -(Sqrt[3]).

Rule 1.1.3.4.6.1.8.3.3.3.2: If  b c-a d≠0 ∧ (b^2) (c^2)-20 a b c d-8 (a^2) (d^2)==0 ∧ a≯0, let q->((((b/a)))^(1/3)), and r->((b c-10 a d)/(6 a d)), then

∫(x/((Sqrt[a+b (x^3)]) (c+d (x^3))))dx  ⟶  
((q (2-r) ArcTanh[(((1-r) (Sqrt[a+b (x^3)]))/((Sqrt[2]) (Sqrt[-a]) (r^(3/2))))])/(3 (Sqrt[2]) (Sqrt[-a]) d (r^(3/2))))-((q (2-r) ArcTanh[(((Sqrt[-a]) (Sqrt[r]) (1+r) (1+q x))/((Sqrt[2]) (Sqrt[a+b (x^3)])))])/(2 (Sqrt[2]) (Sqrt[-a]) d (r^(3/2))))-((q (2-r) ArcTan[(((Sqrt[-a]) (1-r) (Sqrt[r]) (1+q x))/((Sqrt[2]) (Sqrt[a+b (x^3)])))])/(6 (Sqrt[2]) (Sqrt[-a]) d (Sqrt[r])))-((q (2-r) ArcTan[(((Sqrt[-a]) (Sqrt[r]) (1+r-2 q x))/((Sqrt[2]) (Sqrt[a+b (x^3)])))])/(3 (Sqrt[2]) (Sqrt[-a]) d (Sqrt[r])))

Program code:

Int[x_/((c_+d_.*x_^3)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  With[{q=Rt[b/a,3],r=Simplify[(b*c-10*a*d)/(6*a*d)]},
  q*(2-r)*ArcTanh[(1-r)*Sqrt[a+b*x^3]/(Sqrt[2]*Rt[-a,2]*r^(3/2))]/(3*Sqrt[2]*Rt[-a,2]*d*r^(3/2)) - 
  q*(2-r)*ArcTanh[Rt[-a,2]*Sqrt[r]*(1+r)*(1+q*x)/(Sqrt[2]*Sqrt[a+b*x^3])]/(2*Sqrt[2]*Rt[-a,2]*d*r^(3/2)) - 
  q*(2-r)*ArcTan[Rt[-a,2]*(1-r)*Sqrt[r]*(1+q*x)/(Sqrt[2]*Sqrt[a+b*x^3])]/(6*Sqrt[2]*Rt[-a,2]*d*Sqrt[r]) - 
  q*(2-r)*ArcTan[Rt[-a,2]*Sqrt[r]*(1+r-2*q*x)/(Sqrt[2]*Sqrt[a+b*x^3])]/(3*Sqrt[2]*Rt[-a,2]*d*Sqrt[r])] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[b^2*c^2-20*a*b*c*d-8*a^2*d^2,0] && NegQ[a]

4:  ∫(x/((((a+b (x^3)))^(1/3)) (c+d (x^3))))dx  when b c-a d≠0 ∧ b c+a d==0

Derivation: Algebraic expansion and integration by substitution

Basis: If  b c+a d==0 and q==((((b/a)))^(1/3)), then (x/((((a+b (x^3)))^(1/3)) (c+d (x^3))))==-((q^2)/(3 d (1-q x) (((a+b (x^3)))^(1/3))))+((a (q^2) (((1-q x))^2))/(3 d (a-b (x^3)) (((a+b (x^3)))^(1/3))))

Basis: If  q==((((b/a)))^(1/3)), then ((((1-q x))^2)/((a-b (x^3)) (((a+b (x^3)))^(1/3))))==((3 (q^2))/b)Subst[(1/(1+2 a (x^3))),x,((1+q x)/(((a+b (x^3)))^(1/3)))] (∂_x)((1+q x)/(((a+b (x^3)))^(1/3)))

Rule 1.1.3.4.6.1.8.3.4: If  b c-a d≠0 ∧ b c+a d==0, let q->((((b/a)))^(1/3)), then

∫(x/((((a+b (x^3)))^(1/3)) (c+d (x^3))))dx  ⟶  

-((q^2)/(3 d)) ∫(1/((1-q x) (((a+b (x^3)))^(1/3))))dx+((a (q^2))/(3 d)) ∫((((1-q x))^2)/((a-b (x^3)) (((a+b (x^3)))^(1/3))))dx  ⟶  

-((q^2)/(3 d)) ∫(1/((1-q x) (((a+b (x^3)))^(1/3))))dx+(q/d)Subst[∫(1/(1+2 a (x^3)))dx,x,((1+q x)/(((a+b (x^3)))^(1/3)))]

Program code:

Int[x_/((a_+b_.*x_^3)^(1/3)*(c_+d_.*x_^3)),x_Symbol] :=
  With[{q=Rt[b/a,3]},
  -q^2/(3*d)*Int[1/((1-q*x)*(a+b*x^3)^(1/3)),x] + 
  q/d*Subst[Int[1/(1+2*a*x^3),x],x,(1+q*x)/(a+b*x^3)^(1/3)]] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[b*c+a*d,0]

5:  ∫(x/((((a+b (x^3)))^(2/3)) (c+d (x^3))))dx  when b c-a d≠0

Rule 1.1.3.4.6.1.8.3.5: If  b c-a d≠0, let q->(((((b c-a d)/c)))^(1/3)), then

∫(x/((((a+b (x^3)))^(2/3)) (c+d (x^3))))dx  ⟶  -((ArcTan[((1+((2 q x)/(((a+b (x^3)))^(1/3))))/(Sqrt[3]))])/((Sqrt[3]) c (q^2)))+((Log[c+d (x^3)])/(6 c (q^2)))-((Log[q x-(((a+b (x^3)))^(1/3))])/(2 c (q^2)))

Program code:

Int[x_/((a_+b_.*x_^3)^(2/3)*(c_+d_.*x_^3)),x_Symbol] :=
  With[{q=Rt[(b*c-a*d)/c,3]},
  -ArcTan[(1+(2*q*x)/(a+b*x^3)^(1/3))/Sqrt[3]]/(Sqrt[3]*c*q^2) + Log[c+d*x^3]/(6*c*q^2) - Log[q*x-(a+b*x^3)^(1/3)]/(2*c*q^2)] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

4.  ∫(((x^2) (((c+d (x^4)))^q))/(a+b (x^4)))dx  when  b c-a d≠0 ∧ (q^2)==(1/4)

1:  ∫((x^2)/((a+b (x^4)) (Sqrt[c+d (x^4)])))dx  when  b c-a d≠0

Derivation: Algebraic expansion

Basis: If  (r/s)=(((-(a/b)))^(1/2)), then ((x^2)/(a+b (x^4)))==(s/(2b(r+s (x^2))))-(s/(2b(r-s (x^2))))

Rule 1.1.3.4.6.1.8.5.1: If  b c-a d≠0, let (r/s)=(((-(a/b)))^(1/2)), then

∫((x^2)/((a+b (x^4)) (Sqrt[c+d (x^4)])))dx  ⟶  (s/(2 b))∫(1/((r+s (x^2))(Sqrt[c+d (x^4)])))dx-(s/(2 b))∫(1/((r-s (x^2))(Sqrt[c+d (x^4)])))dx

Program code:

Int[x_^2/((a_+b_.*x_^4)*Sqrt[c_+d_.*x_^4]),x_Symbol] :=
  With[{r=Numerator[Rt[-a/b,2]], s=Denominator[Rt[-a/b,2]]},
  s/(2*b)*Int[1/((r+s*x^2)*Sqrt[c+d*x^4]),x] - s/(2*b)*Int[1/((r-s*x^2)*Sqrt[c+d*x^4]),x]] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

2:  ∫(((x^2) (Sqrt[c+d (x^4)]))/(a+b (x^4)))dx  when b c-a d≠0

Derivation: Algebraic expansion

Basis: ((Sqrt[c+d z])/(a+b z))==(d/(b (Sqrt[c+d z])))+((b c-a d)/(b (a+b z) (Sqrt[c+d z])))

Rule 1.1.3.4.6.1.8.5.2: If  b c-a d≠0, then

∫(((x^2) (Sqrt[c+d (x^4)]))/(a+b (x^4)))dx  ⟶  (d/b)∫((x^2)/(Sqrt[c+d (x^4)]))dx+((b c-a d)/b)∫((x^2)/((a+b (x^4)) (Sqrt[c+d (x^4)])))dx

Program code:

Int[x_^2*Sqrt[c_+d_.*x_^4]/(a_+b_.*x_^4),x_Symbol] :=
  d/b*Int[x^2/Sqrt[c+d*x^4],x] + (b*c-a*d)/b*Int[x^2/((a+b*x^4)*Sqrt[c+d*x^4]),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

9.  ∫((x^m)/((Sqrt[a+b (x^n)]) (Sqrt[c+d (x^n)])))dx  when  b c-a d≠0 ∧ (m|n)∈ℤ ∧ 0<m-n+1<n

1:  ∫((x^2)/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  when b c-a d≠0 ∧ (b/a)>0 ∧ (d/c)>0

Rule 1.1.3.4.6.1.9.1: If  b c-a d≠0 ∧ (b/a)>0 ∧ (d/c)>0, then

∫((x^2)/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  ⟶  ((x (Sqrt[a+b (x^2)]))/(b (Sqrt[c+d (x^2)])))-(c/b) ∫((Sqrt[a+b (x^2)])/(((c+d (x^2)))^(3/2)))dx

Program code:

Int[x_^2/(Sqrt[a_+b_.*x_^2]*Sqrt[c_+d_.*x_^2]),x_Symbol] :=
  x*Sqrt[a+b*x^2]/(b*Sqrt[c+d*x^2]) - c/b*Int[Sqrt[a+b*x^2]/(c+d*x^2)^(3/2),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && PosQ[b/a] && PosQ[d/c] && Not[SimplerSqrtQ[b/a,d/c]]

2:  ∫((x^n)/((Sqrt[a+b (x^n)]) (Sqrt[c+d (x^n)])))dx  when b c-a d≠0 ∧ (n==2 ∨ n==4)

Derivation: Algebraic expansion

Basis: (z/(Sqrt[a+b z]))==((Sqrt[a+b z])/b)-(a/(b (Sqrt[a+b z])))

Rule 1.1.3.4.6.1.9.2: If  b c-a d≠0 ∧ (n==2 ∨ n==4), then

∫((x^n)/((Sqrt[a+b (x^n)]) (Sqrt[c+d (x^n)])))dx  ⟶  (1/b)∫((Sqrt[a+b (x^n)])/(Sqrt[c+d (x^n)]))dx-(a/b)∫(1/((Sqrt[a+b (x^n)])(Sqrt[c+d (x^n)])))dx

Program code:

Int[x_^n_/(Sqrt[a_+b_.*x_^n_]*Sqrt[c_+d_.*x_^n_]),x_Symbol] :=
  1/b*Int[Sqrt[a+b*x^n]/Sqrt[c+d*x^n],x] - a/b*Int[1/(Sqrt[a+b*x^n]*Sqrt[c+d*x^n]),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && (EqQ[n,2] || EqQ[n,4]) && Not[EqQ[n,2] && SimplerSqrtQ[-b/a,-d/c]]

10:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  n∈(SuperPlus[ℤ])∧ (p+((m+1)/n)|q)∈ℤ ∧ -1<p<0

Derivation: Integration by substitution

Basis:  If  p+((m+1)/n)∈ℤ, let k=Denominator[p], then (x^m) (((a+b (x^n)))^p) F[(x^n)]==((k (a^(p+((m+1)/n))))/n) Subst[((x^(((k (m+1))/n)-1))/(((1-b (x^k)))^(p+((m+1)/n)+1)))F[((a (x^k))/(1-b (x^k)))],x,((x^(n/k))/(((a+b (x^n)))^(1/k)))] (∂_x)((x^(n/k))/(((a+b (x^n)))^(1/k)))

Basis:  If  (p+((m+1)/n)|q)∈ℤ, let k=Denominator[p], then (x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)==((k (a^(p+((m+1)/n))))/n) Subst[(((x^(((k (m+1))/n)-1)) (((c-(b c-a d) (x^k)))^q))/(((1-b (x^k)))^(p+q+((m+1)/n)+1))),x,((x^(n/k))/(((a+b (x^n)))^(1/k)))] (∂_x)((x^(n/k))/(((a+b (x^n)))^(1/k)))

Note: The exponents in the resulting integrand are integers.

Rule 1.1.3.4.6.1.10: If  n∈(SuperPlus[ℤ])∧ (p+((m+1)/n)|q)∈ℤ ∧ -1<p<0, let k=Denominator[p], then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ((k (a^(p+((m+1)/n))))/n) Subst[∫(((x^(((k (m+1))/n)-1)) (((c-(b c-a d) (x^k)))^q))/(((1-b (x^k)))^(p+q+((m+1)/n)+1)))dx,x,((x^(n/k))/(((a+b (x^n)))^(1/k)))]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  With[{k=Denominator[p]},
  k*a^(p+(m+1)/n)/n*
	Subst[Int[x^(k*(m+1)/n-1)*(c-(b*c-a*d)*x^k)^q/(1-b*x^k)^(p+q+(m+1)/n+1),x],x,x^(n/k)/(a+b*x^n)^(1/k)]] /;
FreeQ[{a,b,c,d},x] && IGtQ[n,0] && RationalQ[m,p] && IntegersQ[p+(m+1)/n,q] && LtQ[-1,p,0]

2.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈(SuperMinus[ℤ])

1.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈ℚ

1:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈ℤ

Derivation: Integration by substitution

Basis: F[x]==-Subst[((F[(x^(-1))] )/(x^2)),x,(1/x)](∂_x)(1/x)

Rule 1.1.3.4.6.2.1.1: If  b c-a d≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈ℤ, then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  -Subst[∫(((((a+b (x^(-n))))^p) (((c+d (x^(-n))))^q))/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -Subst[Int[(a+b*x^(-n))^p*(c+d*x^(-n))^q/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,d,p,q},x] && NeQ[b*c-a*d,0] && ILtQ[n,0] && IntegerQ[m]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ g>1, then (((e x))^m) F[(x^n)]==-(g/e)Subst[ ((F[(e^(-n)) (x^(-g n))])/(x^(g (m+1)+1))),x,(1/(((e x))^(1/g)))] (∂_x)(1/(((e x))^(1/g)))

Rule 1.1.3.4.6.2.1.2: If  b c-a d≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈𝔽, let g=Denominator[m], then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  -(g/e) Subst[∫(((((a+b (e^(-n)) (x^(-g n))))^p) (((c+d (e^(-n)) (x^(-g n))))^q))/(x^(g (m+1)+1)))dx,x,(1/(((e x))^(1/g)))]

Program code:

Int[(e_.*x_)^m_*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  With[{g=Denominator[m]},
  -g/e*Subst[Int[(a+b*e^(-n)*x^(-g*n))^p*(c+d*e^(-n)*x^(-g*n))^q/x^(g*(m+1)+1),x],x,1/(e*x)^(1/g)]] /;
FreeQ[{a,b,c,d,e,p,q},x] && ILtQ[n,0] && FractionQ[m]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈(SuperMinus[ℤ])∧ m∉ℚ

Derivation:  Piecewise constant extraction and integration by substitution

Basis: (∂_x)((((e x))^m) ((((x^(-1))))^m))==0

Basis: F[x]==-Subst[((F[(x^(-1))] )/(x^2)),x,(1/x)](∂_x)(1/x)

Rule 1.1.3.4.6.2.2: If  b c-a d≠0 ∧ n∈(SuperMinus[ℤ])∧ m∉ℚ, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((e x))^m) ((((x^(-1))))^m)∫(((((a+b (x^n)))^p) (((c+d (x^n)))^q))/((((x^(-1))))^m))dx
  ⟶  -(((e x))^m) ((((x^(-1))))^m) Subst[∫(((((a+b (x^(-n))))^p) (((c+d (x^(-n))))^q))/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[(e_.*x_)^m_*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -(e*x)^m*(x^(-1))^m*Subst[Int[(a+b*x^(-n))^p*(c+d*x^(-n))^q/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,d,e,m,p,q},x] && NeQ[b*c-a*d,0] && ILtQ[n,0] && Not[RationalQ[m]]

7.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈𝔽

1:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈𝔽

Derivation: Integration by substitution

Basis: If  g∈(SuperPlus[ℤ]), then (x^m)F[(x^n)]==g Subst[(x^(g(m+1)-1))F[(x^(g n))],x,(x^(1/g))] (∂_x)(x^(1/g))

Rule 1.1.3.4.7.1: If  b c-a d≠0 ∧ n∈𝔽, let g=Denominator[n], then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  g Subst[∫(x^(g(m+1)-1)) (((a+b (x^(g n))))^p) (((c+d (x^(g n))))^q)dx,x,(x^(1/g))]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  With[{g=Denominator[n]},
  g*Subst[Int[x^(g*(m+1)-1)*(a+b*x^(g*n))^p*(c+d*x^(g*n))^q,x],x,x^(1/g)]] /;
FreeQ[{a,b,c,d,m,p,q},x] && NeQ[b*c-a*d,0] && FractionQ[n]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈𝔽

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e x))^m)/(x^m))==0

Basis: ((((e x))^m)/(x^m))==(((e^(IntPart[m]))(((e x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.1.3.4.7.2: If  b c-a d≠0 ∧ n∈𝔽, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((e^(IntPart[m]))(((e x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx

Program code:

Int[(e_*x_)^m_*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n)^p*(c+d*x^n)^q,x] /;
FreeQ[{a,b,c,d,e,m,p,q},x] && NeQ[b*c-a*d,0] && FractionQ[n]

8.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ (n/(m+1))∈ℤ

x:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ (n/(m+1))∈(SuperMinus[ℤ])∧ m≠-1 ∧ -1≤p<0 ∧ -1≤q<0

Derivation: Integration by substitution

Basis: If (n/(m+1))∈ℤ, then (x^m)F[(x^n)]==-(1/(m+1))((F[((((x^(-(m+1)))))^(-(n/(m+1))))])/((((x^(-(m+1)))))^2))(∂_x)(x^(-(m+1)))

Rule 1.1.3.4.8.x: If  b c-a d≠0 ∧ m≠-1 ∧ (n/(m+1))∈(SuperMinus[ℤ])∧ -1≤p<0 ∧ -1≤q<0, then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  -(1/(m+1))Subst[∫(((((a+b (x^(-(n/(m+1))))))^p)(((c+d (x^(-(n/(m+1))))))^q))/(x^2))dx,x,(x^(-(m+1)))]

Program code:

(* Int[x_^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -1/(m+1)*Subst[Int[(a+b*x^Simplify[-n/(m+1)])^p*(c+d*x^Simplify[-n/(m+1)])^q/x^2,x],x,x^(-(m+1))] /;
FreeQ[{a,b,c,d,m,n},x] && NeQ[b*c-a*d,0] && NeQ[m,-1] && ILtQ[Simplify[n/(m+1)+1],0] && 
  GeQ[p,-1] && LtQ[p,0] && GeQ[q,-1] && LtQ[q,0] && Not[IntegerQ[n]] *)

1:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ (n/(m+1))∈ℤ

Derivation: Integration by substitution

Basis: If (n/(m+1))∈ℤ, then (x^m)F[(x^n)]==(1/(m+1))Subst[F[(x^(n/(m+1)))],x,(x^(m+1))](∂_x)(x^(m+1))

Rule 1.1.3.4.8.1: If  b c-a d≠0 ∧ (n/(m+1))∈ℤ, then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (1/(m+1))Subst[∫(((a+b (x^(n/(m+1)))))^p)(((c+d (x^(n/(m+1)))))^q)dx,x,(x^(m+1))]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  1/(m+1)*Subst[Int[(a+b*x^Simplify[n/(m+1)])^p*(c+d*x^Simplify[n/(m+1)])^q,x],x,x^(m+1)] /;
FreeQ[{a,b,c,d,m,n,p,q},x] && NeQ[b*c-a*d,0] && IntegerQ[Simplify[n/(m+1)]] && Not[IntegerQ[n]]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ (n/(m+1))∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e x))^m)/(x^m))==0

Basis: ((((e x))^m)/(x^m))==(((e^(IntPart[m]))(((e x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.1.3.4.8.2: If b c-a d≠0 ∧ (n/(m+1))∈ℤ, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((e^(IntPart[m]))(((e x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx

Program code:

Int[(e_*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n)^p*(c+d*x^n)^q,x] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && NeQ[b*c-a*d,0] && IntegerQ[Simplify[n/(m+1)]] && Not[IntegerQ[n]]

9.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ p<-1

1.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ p<-1 ∧ q>0

1:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ p<-1 ∧ q>1

Derivation: Binomial product recurrence 1 with A=c, B=d and q=q-1

Rule 1.1.3.4.9.1.1: If  b c-a d≠0 ∧ p<-1 ∧ q>1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
((-(c b-a d) (((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q-1)))/(a b e n (p+1)))+(1/(a b n (p+1)))·
∫(((e x))^m) (((a+b (x^n)))^(p+1)) (((c+d (x^n)))^(q-2))(c (c b n (p+1)+(c b-a d) (m+1))+d (c b n (p+1)+(c b-a d) (m+n (q-1)+1)) (x^n))dx

Programcode:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -(c*b-a*d)*(e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)/(a*b*e*n*(p+1)) + 
  1/(a*b*n*(p+1))*Int[(e*x)^m*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-2)*
    Simp[c*(c*b*n*(p+1)+(c*b-a*d)*(m+1))+d*(c*b*n*(p+1)+(c*b-a*d)*(m+n*(q-1)+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[b*c-a*d,0] && LtQ[p,-1] && GtQ[q,1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ p<-1 ∧ 0<q<1

Derivation: Binomial product recurrence 1 with A=1 and B=0

Derivation: Binomial product recurrence 3b with A=c, B=d and q=q-1

Rule 1.1.3.4.9.1.2: If  b c-a d≠0 ∧ p<-1 ∧ 0<q<1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
-(((((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^q))/(a e n (p+1)))+
(1/(a n (p+1)))∫(((e x))^m) (((a+b (x^n)))^(p+1)) (((c+d (x^n)))^(q-1)) (c (m+n (p+1)+1)+d (m+n (p+q+1)+1) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -(e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^q/(a*e*n*(p+1)) + 
  1/(a*n*(p+1))*Int[(e*x)^m*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)*Simp[c*(m+n*(p+1)+1)+d*(m+n*(p+q+1)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[b*c-a*d,0] && LtQ[p,-1] && LtQ[0,q,1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ p<-1

Derivation: Binomial product recurrence 3b with A=1 and B=0

Rule 1.1.3.4.9.2: If  b c-a d≠0 ∧ p<-1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
-((b (((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q+1)))/(a e n(b c-a d)(p+1)))+
(1/(a n(b c-a d)(p+1)))∫(((e x))^m) (((a+b (x^n)))^(p+1)) (((c+d (x^n)))^q) (c b(m+1)+n (b c-a d)(p+1)+d b (m+n (p+q+2)+1) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -b*(e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q+1)/(a*e*n*(b*c-a*d)*(p+1)) + 
  1/(a*n*(b*c-a*d)*(p+1))*
    Int[(e*x)^m*(a+b*x^n)^(p+1)*(c+d*x^n)^q*Simp[c*b*(m+1)+n*(b*c-a*d)*(p+1)+d*b*(m+n*(p+q+2)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m,n,q},x] && NeQ[b*c-a*d,0] && LtQ[p,-1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

10.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ q>0

1:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ q>0 ∧ p>0

Derivation: Binomial product recurrence 2b with A=a, B=b and p=p-1

Rule 1.1.3.4.10.1: If  b c-a d≠0 ∧ q>0 ∧ p>0, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
(((((e x))^(m+1)) (((a+b (x^n)))^p) (((c+d (x^n)))^q))/(e(m+n (p+q)+1)))+
(n/(m+n (p+q)+1))∫(((e x))^m) (((a+b (x^n)))^(p-1)) (((c+d (x^n)))^(q-1)) (a c(p+q)+(q(b c-a d)+a d(p+q)) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  (e*x)^(m+1)*(a+b*x^n)^p*(c+d*x^n)^q/(e*(m+n*(p+q)+1)) + 
  n/(m+n*(p+q)+1)*Int[(e*x)^m*(a+b*x^n)^(p-1)*(c+d*x^n)^(q-1)*Simp[a*c*(p+q)+(q*(b*c-a*d)+a*d*(p+q))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[b*c-a*d,0] && GtQ[q,0] && GtQ[p,0] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ q>1

Derivation: Binomial product recurrence 2b with A=c, B=d and q=q-1

Rule 1.1.3.4.10.2: If  b c-a d≠0 ∧ q>1, then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
((d (((e x))^(m+1)) (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q-1)))/(b e (m+n (p+q)+1)))+(1/(b (m+n (p+q)+1)))∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^(q-2))·
(c ((c b-a d) (m+1)+c b n (p+q))+(d(c b-a d) (m+1)+d n (q-1)(b c-a d)+c b d n (p+q)) (x^n))dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  d*(e*x)^(m+1)*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)/(b*e*(m+n*(p+q)+1)) + 
  1/(b*(m+n*(p+q)+1))*Int[(e*x)^m*(a+b*x^n)^p*(c+d*x^n)^(q-2)*
    Simp[c*((c*b-a*d)*(m+1)+c*b*n*(p+q))+(d*(c*b-a*d)*(m+1)+d*n*(q-1)*(b*c-a*d)+c*b*d*n*(p+q))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && NeQ[b*c-a*d,0] && GtQ[q,1] && IntBinomialQ[a,b,c,d,e,m,n,p,q,x]

11.  ∫((((e x))^m)/((a+b (x^n)) (c+d (x^n))))dx  when b c-a d≠0

1:  ∫((x^m)/((a+b (x^n)) (c+d (x^n))))dx  when b c-a d≠0 ∧(m==n ∨ m==2n-1)

Derivation: Algebraic expansion

Basis: ((x^m)/((a+b (x^n)) (c+d (x^n))))==-((a (x^(m-n)))/((b c-a d) (a+b (x^n))))+((c (x^(m-n)))/((b c-a d) (c+d (x^n))))

Rule 1.1.3.4.11.1: If  b c-a d≠0 ∧(m==n ∨ m==2n-1), then

∫((x^m)/((a+b (x^n)) (c+d (x^n))))dx  ⟶  -(a/(b c-a d))∫((x^(m-n))/(a+b (x^n)))dx+(c/(b c-a d))∫((x^(m-n))/(c+d (x^n)))dx

Program code:

Int[x_^m_/((a_+b_.*x_^n_)*(c_+d_.*x_^n_)),x_Symbol] :=
  -a/(b*c-a*d)*Int[x^(m-n)/(a+b*x^n),x] + c/(b*c-a*d)*Int[x^(m-n)/(c+d*x^n),x] /;
FreeQ[{a,b,c,d,m,n},x] && NeQ[b*c-a*d,0] && (EqQ[m,n] || EqQ[m,2*n-1])

2:  ∫((((e x))^m)/((a+b (x^n)) (c+d (x^n))))dx  when b c-a d≠0

Derivation: Algebraic expansion

Basis: (1/((a+b z) (c+d z)))==(b/((b c-a d) (a+b z)))-(d/((b c-a d) (c+d z)))

Rule 1.1.3.4.11.2: If  b c-a d≠0, then

∫((((e x))^m)/((a+b (x^n)) (c+d (x^n))))dx  ⟶  (b/(b c-a d))∫((((e x))^m)/(a+b (x^n)))dx-(d/(b c-a d))∫((((e x))^m)/(c+d (x^n)))dx

Program code:

Int[(e_.*x_)^m_./((a_+b_.*x_^n_)*(c_+d_.*x_^n_)),x_Symbol] :=
  b/(b*c-a*d)*Int[(e*x)^m/(a+b*x^n),x] - d/(b*c-a*d)*Int[(e*x)^m/(c+d*x^n),x] /;
FreeQ[{a,b,c,d,e,n,m},x] && NeQ[b*c-a*d,0]

12:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ p+2∈(SuperPlus[ℤ])∧ q+2∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.1.3.4.12: If  b c-a d≠0 ∧ p+2∈(SuperPlus[ℤ])∧ q+2∈(SuperPlus[ℤ]), then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ∫ExpandIntegrand[(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q),x]dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  Int[ExpandIntegrand[(e*x)^m*(a+b*x^n)^p*(c+d*x^n)^q,x],x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b*c-a*d,0] && IGtQ[p,-2] && (IGtQ[q,-2] || EqQ[q,-3] && IntegerQ[(m-1)/2])

A.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ m≠-1 ∧ m≠n-1

1:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ m≠-1 ∧ m≠n-1 ∧ (p∈ℤ ∨ a>0) ∧ (q∈ℤ ∨ c>0)

Rule 1.1.3.4.A.1: If  b c-a d≠0 ∧ m≠-1 ∧ m≠n-1 ∧ (p∈ℤ ∨ a>0) ∧ (q∈ℤ ∨ c>0), then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((a^p) (c^q) (((e x))^(m+1)))/(e (m+1))) AppellF1[((m+1)/n),-p,-q,1+((m+1)/n),-((b (x^n))/a),-((d (x^n))/c)]

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  a^p*c^q*(e*x)^(m+1)/(e*(m+1))*AppellF1[(m+1)/n,-p,-q,1+(m+1)/n,-b*x^n/a,-d*x^n/c] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && NeQ[b*c-a*d,0] && NeQ[m,-1] && NeQ[m,n-1] && 
  (IntegerQ[p] || GtQ[a,0]) && (IntegerQ[q] || GtQ[c,0])

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ m≠-1 ∧ m≠n-1 ∧ ¬(p∈ℤ ∨ a>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((a+b (x^n)))^p)/(((1+((b (x^n))/a)))^p))==0

Rule 1.1.3.4.A.2: If  b c-a d≠0 ∧ m≠-1 ∧ m≠n-1 ∧ ¬(p∈ℤ ∨ a>0), then

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((a^(IntPart[p])) (((a+b (x^n)))^(FracPart[p])))/( (((1+((b (x^n))/a)))^(FracPart[p])))) ∫(((e x))^m) (((1+((b (x^n))/a)))^p) (((c+d (x^n)))^q)dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  a^IntPart[p]*(a+b*x^n)^FracPart[p]/(1+b*x^n/a)^FracPart[p]*Int[(e*x)^m*(1+b*x^n/a)^p*(c+d*x^n)^q,x] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && NeQ[b*c-a*d,0] && NeQ[m,-1] && NeQ[m,n-1] && Not[IntegerQ[p] || GtQ[a,0]]

S.  ∫(u^m) (((a+b (v^n)))^p) (((c+d (v^n)))^q)dx  when  v==e+f x ∧ u==g v

1:  ∫(x^m)(((a+b (v^n)))^p) (((c+d (v^n)))^q)dx  when  v==e+f x ∧ m∈ℤ

Derivation: Integration by substitution

Basis: If  m∈ℤ, then (x^m)F[e+f x]==(1/(f^(m+1)))Subst[(((x-e))^m) F[x],x,e+f x](∂_x)(e+f x)

Rule 1.1.3.4.S.1: If  v==e+f x ∧ m∈ℤ, then

∫(x^m)(((a+b (v^n)))^p) (((c+d (v^n)))^q)dx  ⟶  (1/(f^(m+1)))Subst[∫(((x-e))^m)(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx,x,v]

Program code:

Int[x_^m_.*(a_.+b_.*v_^n_)^p_.*(c_.+d_.*v_^n_)^q_.,x_Symbol] :=
  1/Coefficient[v,x,1]^(m+1)*Subst[Int[SimplifyIntegrand[(x-Coefficient[v,x,0])^m*(a+b*x^n)^p*(c+d*x^n)^q,x],x],x,v] /;
FreeQ[{a,b,c,d,n,p,q},x] && LinearQ[v,x] && IntegerQ[m] && NeQ[v,x]

2:  ∫(u^m)(((a+b (v^n)))^p) (((c+d (v^n)))^q)dx  when  v==e+f x ∧ u==g v

Derivation: Integration by substitution and piecewise constant extraction

Basis: If  u==g v, then (∂_x)((u^m)/(v^m))==0

Rule 1.1.3.4.S.2: If  v==e+f x ∧ u==g v, then

∫(u^m)(((a+b (v^n)))^p) (((c+d (v^n)))^q)dx  ⟶  ((u^m)/(f (v^m)))Subst[∫(x^m) (((a+b (x^n)))^p) (((c+d (x^n)))^q)dx,x,v]

Program code:

Int[u_^m_.*(a_.+b_.*v_^n_)^p_.*(c_.+d_.*v_^n_)^q_.,x_Symbol] :=
  u^m/(Coefficient[v,x,1]*v^m)*Subst[Int[x^m*(a+b*x^n)^p*(c+d*x^n)^q,x],x,v] /;
FreeQ[{a,b,c,d,m,n,p,q},x] && LinearPairQ[u,v,x]

N.  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx

1.  ∫(x^m) (((a+b (x^n)))^p)(((c+d (x^(-n))))^q)dx

1:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx  when  q∈ℤ

Derivation: Algebraic normalization

Basis: If  q∈ℤ, then (((c+d (x^(-n))))^q)==(x^(-n q))(((d+c (x^n)))^q)

Rule 1.1.3.4.N.1.1: If  q∈ℤ, then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx  ⟶  ∫(x^(m-n q))(((a+b (x^n)))^p) (((d+c (x^n)))^q)dx

Program code:

Int[x_^m_.*(a_+b_.*x_^n_.)^p_.*(c_+d_.*x_^mn_.)^q_.,x_Symbol] :=
  Int[x^(m-n*q)*(a+b*x^n)^p*(d+c*x^n)^q,x] /;
FreeQ[{a,b,c,d,m,n,p},x] && EqQ[mn,-n] && IntegerQ[q] && (PosQ[n] || Not[IntegerQ[p]])

2:  ∫(x^m) (((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx  when  q∉ℤ ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(n q)) (((c+d (x^(-n))))^q))/(((d+c (x^n)))^q))==0

Basis: (((x^(n q)) (((c+d (x^(-n))))^q))/(((d+c (x^n)))^q))==(((x^(n FracPart[q])) (((c+d (x^(-n))))^(FracPart[q])))/(((d+c (x^n)))^(FracPart[q])))

Rule 1.1.3.4.N.1.2: If  q∉ℤ ∧ p∉ℤ, then

∫(x^m) (((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx  ⟶  (((x^(n FracPart[q])) (((c+d (x^(-n))))^(FracPart[q])))/(((d+c (x^n)))^(FracPart[q])))∫(x^(m-n q))(((a+b (x^n)))^p) (((d+c (x^n)))^q)dx

Program code:

Int[x_^m_.*(a_+b_.*x_^n_.)^p_.*(c_+d_.*x_^mn_.)^q_,x_Symbol] :=
  x^(n*FracPart[q])*(c+d*x^(-n))^FracPart[q]/(d+c*x^n)^FracPart[q]*Int[x^(m-n*q)*(a+b*x^n)^p*(d+c*x^n)^q,x] /;
FreeQ[{a,b,c,d,m,n,p,q},x] && EqQ[mn,-n] && Not[IntegerQ[q]] && Not[IntegerQ[p]]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e x))^m)/(x^m))==0

Basis: ((((e x))^m)/(x^m))==(((e^(IntPart[m]))(((e x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.1.3.4.N.2:

∫(((e x))^m) (((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx  ⟶  (((e^(IntPart[m]))(((e x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)))^p)(((c+d (x^(-n))))^q)dx

Program code:

Int[(e_*x_)^m_*(a_.+b_.*x_^n_.)^p_.*(c_+d_.*x_^mn_.)^q_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n)^p*(c+d*x^(-n))^q,x] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && EqQ[mn,-n]

(* IntBinomialQ[a,b,c,d,e,m,n,p,q,x] returns True iff (e*x)^m*(a+b*x^n)^p*(c+d*x^n)^q is integrable wrt x in terms of non-Appell functions. *)
IntBinomialQ[a_,b_,c_,d_,e_,m_,n_,p_,q_,x_Symbol] :=
  IntegersQ[p,q] || IGtQ[p,0] || IGtQ[q,0] || 
  EqQ[n,2] && (IntegersQ[m,2*p,2*q] || IntegersQ[2*m,p,2*q] || IntegersQ[2*m,2*p,q]) || 
  EqQ[n,4] && (IntegersQ[m,p,2*q] || IntegersQ[m,2*p,q]) || 
  EqQ[n,2] && IntegersQ[m/2,p+1/3,q] && (EqQ[b*c+3*a*d,0] || EqQ[b*c-9*a*d,0]) || 
  EqQ[n,2] && IntegersQ[m/2,q+1/3,p] && (EqQ[a*d+3*b*c,0] || EqQ[a*d-9*b*c,0]) || 
  EqQ[n,3] && IntegersQ[(m-1)/3,q,p-1/2] && (EqQ[b*c-4*a*d,0] || EqQ[b*c+8*a*d,0] || EqQ[b^2*c^2-20*a*b*c*d-8*a^2*d^2,0]) || 
  EqQ[n,3] && IntegersQ[(m-1)/3,p,q-1/2] && (EqQ[4*b*c-a*d,0] || EqQ[8*b*c+a*d,0] || EqQ[8*b^2*c^2+20*a*b*c*d-a^2*d^2,0]) || 
  EqQ[n,3] && (IntegersQ[m,q,3*p] || IntegersQ[m,p,3*q]) && EqQ[b*c+a*d,0] || 
  EqQ[n,3] && (IntegersQ[(m+2)/3,p+2/3,q] || IntegersQ[(m+2)/3,q+2/3,p]) || 
  EqQ[n,3] && (IntegersQ[m/3,p+1/3,q] || IntegersQ[m/3,q+1/3,p])

Rules for integrands of the form u((((Subscript[a, 1])+(Subscript[b, 1]) (x^(n/2))))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^(n/2))))^p) F[(x^n)]

1:  ∫u ((((Subscript[a, 1])+(Subscript[b, 1]) (x^(n/2))))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^(n/2))))^p) F[(x^n)]dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ (p∈ℤ ∨ ((Subscript[a, 1])>0∧(Subscript[a, 2])>0))

Derivation: Algebraic simplification

Basis: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ (p∈ℤ ∨ ((Subscript[a, 1])>0∧(Subscript[a, 2])>0)), then ((((Subscript[a, 1])+(Subscript[b, 1]) (x^(n/2))))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^(n/2))))^p)==((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^n)))^p)

Rule: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ (p∈ℤ ∨ ((Subscript[a, 1])>0∧(Subscript[a, 2])>0)), then

∫u ((((Subscript[a, 1])+(Subscript[b, 1]) (x^(n/2))))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^(n/2))))^p) F[(x^n)]dx  ⟶  ∫u ((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^n)))^p) F[(x^n)]dx

Program code:

Int[u_.*(a1_+b1_.*x_^non2_.)^p_.*(a2_+b2_.*x_^non2_.)^p_.*(c_+d_.*x_^n_.)^q_.,x_Symbol] :=
  Int[u*(a1*a2+b1*b2*x^n)^p*(c+d*x^n)^q,x] /;
FreeQ[{a1,b1,a2,b2,c,d,n,p,q},x] && EqQ[non2,n/2] && EqQ[a2*b1+a1*b2,0] && (IntegerQ[p] || GtQ[a1,0] && GtQ[a2,0])

Int[u_.*(a1_+b1_.*x_^non2_.)^p_.*(a2_+b2_.*x_^non2_.)^p_.*(c_+d_.*x_^n_.+e_.*x_^n2_.)^q_.,x_Symbol] :=
  Int[u*(a1*a2+b1*b2*x^n)^p*(c+d*x^n+e*x^(2*n))^q,x] /;
FreeQ[{a1,b1,a2,b2,c,d,e,n,p,q},x] && EqQ[non2,n/2] && EqQ[n2,2*n] && EqQ[a2*b1+a1*b2,0] && (IntegerQ[p] || GtQ[a1,0] && GtQ[a2,0])

2:  ∫u ((((Subscript[a, 1])+(Subscript[b, 1]) (x^(n/2))))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^(n/2))))^p) F[(x^n)]dx  when  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0 ∧ ¬(p∈ℤ ∨ ((Subscript[a, 1])>0∧(Subscript[a, 2])>0))

Derivation: Piecewise constant extraction

Basis: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0, then (∂_x)((((((Subscript[a, 1])+(Subscript[b, 1]) (x^(n/2))))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^(n/2))))^p))/((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^n)))^p))==0

Rule: If  (Subscript[a, 2]) (Subscript[b, 1])+(Subscript[a, 1]) (Subscript[b, 2])==0, then

∫u ((((Subscript[a, 1])+(Subscript[b, 1]) (x^(n/2))))^p) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^(n/2))))^p) F[(x^n)]dx  ⟶  ((((((Subscript[a, 1])+(Subscript[b, 1]) (x^(n/2))))^(FracPart[p])) ((((Subscript[a, 2])+(Subscript[b, 2]) (x^(n/2))))^(FracPart[p])))/((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^n)))^(FracPart[p])))∫u ((((Subscript[a, 1]) (Subscript[a, 2])+(Subscript[b, 1]) (Subscript[b, 2]) (x^n)))^p) F[(x^n)]dx

Program code:

Int[u_.*(a1_+b1_.*x_^non2_.)^p_*(a2_+b2_.*x_^non2_.)^p_*(c_+d_.*x_^n_.)^q_.,x_Symbol] :=
  (a1+b1*x^(n/2))^FracPart[p]*(a2+b2*x^(n/2))^FracPart[p]/(a1*a2+b1*b2*x^n)^FracPart[p]*
    Int[u*(a1*a2+b1*b2*x^n)^p*(c+d*x^n)^q,x] /;
FreeQ[{a1,b1,a2,b2,c,d,n,p,q},x] && EqQ[non2,n/2] && EqQ[a2*b1+a1*b2,0] && Not[EqQ[n,2] && IGtQ[q,0]]

Int[u_.*(a1_+b1_.*x_^non2_.)^p_.*(a2_+b2_.*x_^non2_.)^p_.*(c_+d_.*x_^n_.+e_.*x_^n2_.)^q_.,x_Symbol] :=
  (a1+b1*x^(n/2))^FracPart[p]*(a2+b2*x^(n/2))^FracPart[p]/(a1*a2+b1*b2*x^n)^FracPart[p]*
    Int[u*(a1*a2+b1*b2*x^n)^p*(c+d*x^n+e*x^(2*n))^q,x] /;
FreeQ[{a1,b1,a2,b2,c,d,e,n,p,q},x] && EqQ[non2,n/2] && EqQ[n2,2*n] && EqQ[a2*b1+a1*b2,0]