Rules for integrands of the form(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)

0:  ∫(x^m) (((f+g x))^n) (b x+c (x^2))dx

Rule 1.2.1.4.0: If  c f (m+2)-b g (m+n+3)==0, then

∫(x^m) (((f+g x))^n) (b x+c (x^2))dx  ⟶  ((c (x^(m+2)) (((f+g x))^(n+1)))/(g (m+n+3)))

Program code:

Int[x_^m_.*(f_+g_.*x_)^n_.*(b_.*x_+c_.*x_^2),x_Symbol] :=
  c*x^(m+2)*(f+g*x)^(n+1)/(g*(m+n+3)) /;
FreeQ[{b,c,f,g,m,n},x] && EqQ[c*f*(m+2)-b*g*(m+n+3),0] && NeQ[m+n+3,0]

1:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b x+c (x^2)))^p)/((((b/2)+c x))^(2 p)))==0

Rule 1.2.1.4.1: If  e f-d g≠0 ∧ (b^2)-4 a c==0 ∧ p∉ℤ, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  ((((a+b x+c (x^2)))^(FracPart[p]))/((c^(IntPart[p])) ((((b/2)+c x))^(2 FracPart[p]))))∫(((d+e x))^m) (((f+g x))^n) ((((b/2)+c x))^(2 p))dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (a+b*x+c*x^2)^FracPart[p]/(c^IntPart[p]*(b/2+c*x)^(2*FracPart[p]))*Int[(d+e*x)^m*(f+g*x)^n*(b/2+c*x)^(2*p),x] /;
FreeQ[{a,b,c,d,e,f,g,m,n},x] && NeQ[e*f-d*g,0] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]]

2.  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0

1:  ∫(((d+e x))^m)(((f+g x))^n)(((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then a+b x+c (x^2)==(d+e x) ((a/d)+((c x)/e))

Rule 1.2.1.4.2.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ, then

∫(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)dx  ⟶  ∫(((d+e x))^(m+p)) (((f+g x))^n)((((a/d)+((c x)/e)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[(d+e*x)^(m+p)*(f+g*x)^n*(a/d+c/e*x)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[p] && Not[IGtQ[n,0]]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[(d+e*x)^(m+p)*(f+g*x)^n*(a/d+c/e*x)^p,x] /;
FreeQ[{a,c,d,e,f,g,m,n},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && (IntegerQ[p] || GtQ[a,0] && GtQ[d,0] && EqQ[m+p,0])

2.  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ

1:  ∫(((x^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((a+b x+c (x^2))/(d+e x))==(a/d)+((c x)/e)

Rule 1.2.1.4.2.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ p>0, then

∫(((x^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  ⟶  ∫(x^n) ((a/d)+((c x)/e)) (((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[x_^n_.*(a_.+b_.*x_+c_.*x_^2)^p_/(d_+e_.*x_),x_Symbol] :=
  Int[x^n*(a/d+c*x/e)*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e,n,p},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && 
  (Not[IntegerQ[n]] || Not[IntegerQ[2*p]] || IGtQ[n,2] || GtQ[p,0] && NeQ[n,2])

Int[x_^n_.*(a_+c_.*x_^2)^p_/(d_+e_.*x_),x_Symbol] :=
  Int[x^n*(a/d+c*x/e)*(a+c*x^2)^(p-1),x] /;
FreeQ[{a,c,d,e,n,p},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && 
  (Not[IntegerQ[n]] || Not[IntegerQ[2*p]] || IGtQ[n,2] || GtQ[p,0] && NeQ[n,2])

2:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then d+e x==((a+b x+c (x^2))/((a/d)+((c x)/e)))

Basis: If  c (d^2)+a (e^2)==0, then d+e x==(((d^2)(a+c (x^2)))/(a(d-e x)))

Note: Since ((((a/d)+((c x)/e)))^(-m)) is a polynomial, this rule transforms integrand into an expression of the form (((d+e x))^m) (Subscript[P, q])[x] (((a+b x+c (x^2)))^p) for which there are rules.

Rule 1.2.1.4.2.2.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m∈(SuperMinus[ℤ]), then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  ∫((((a/d)+((c x)/e)))^(-m)) (((f+g x))^n) (((a+b x+c (x^2)))^(m+p))dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  Int[(a/d+c*x/e)^(-m)*(f+g*x)^n*(a+b*x+c*x^2)^(m+p),x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && ILtQ[m,0] && IntegerQ[n] && 
  (LtQ[n,0] || GtQ[p,0])

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  d^(2*m)/a^m*Int[(f+g*x)^n*(a+c*x^2)^(m+p)/(d-e*x)^m,x] /;
FreeQ[{a,c,d,e,f,g,n,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && EqQ[f,0] && ILtQ[m,-1] && 
  Not[IGtQ[n,0] && ILtQ[m+n,0] && Not[GtQ[p,1]]]

Int[(d_+e_.*x_)^m_*(f_+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  d^(2*m)/a^m*Int[(f+g*x)^n*(a+c*x^2)^(m+p)/(d-e*x)^m,x] /;
FreeQ[{a,c,d,e,f,g,n,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && ILtQ[m,0] && IntegerQ[n]

3.  ∫(((((f+g x))^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ n∈ℤ ∧ n+2 p∈(SuperMinus[ℤ])

1:  ∫(((((f+g x))^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ n∈(SuperPlus[ℤ])∧ n+2 p∈(SuperMinus[ℤ])

Derivation: Algebraic simplification and quadratic recurrence 2a

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((a+b x+c (x^2))/(d+e x))==((a e+c d x)/(d e))

Rule 1.2.1.4.2.2.3.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ n∈(SuperPlus[ℤ])∧ n+2 p∈(SuperMinus[ℤ]), then

∫(((((f+g x))^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  ⟶  (1/(d e))∫(a e+c d x)(((f+g x))^n) (((a+b x+c (x^2)))^(p-1))dx  ⟶  

-(((2 c d-b e) (((f+g x))^n) (((a+b x+c (x^2)))^(p+1)))/(e p ((b^2)-4 a c) (d+e x)))-
(1/(d e p((b^2)-4 a c)))∫(((f+g x))^(n-1)) (((a+b x+c (x^2)))^p)(b (a e g n-c d f (2 p+1))-2 a c (d g n-e f(2 p+1))-c g (b d-2 a e) (n+2 p+1) x)dx

Program code:

Int[(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_/(d_+e_.*x_),x_Symbol] :=
  -(2*c*d-b*e)*(f+g*x)^n*(a+b*x+c*x^2)^(p+1)/(e*p*(b^2-4*a*c)*(d+e*x)) - 
  1/(d*e*p*(b^2-4*a*c))*Int[(f+g*x)^(n-1)*(a+b*x+c*x^2)^p*
    Simp[b*(a*e*g*n-c*d*f*(2*p+1))-2*a*c*(d*g*n-e*f*(2*p+1))-c*g*(b*d-2*a*e)*(n+2*p+1)*x,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && IGtQ[n,0] && ILtQ[n+2*p,0]

Int[(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_/(d_+e_.*x_),x_Symbol] :=
  d*(f+g*x)^n*(a+c*x^2)^(p+1)/(2*a*e*p*(d+e*x)) - 
  1/(2*d*e*p)*Int[(f+g*x)^(n-1)*(a+c*x^2)^p*Simp[d*g*n-e*f*(2*p+1)-e*g*(n+2*p+1)*x,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && IGtQ[n,0] && ILtQ[n+2*p,0]

2:  ∫(((((f+g x))^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ n∈(SuperMinus[ℤ])∧ n+2 p∈(SuperMinus[ℤ])

Derivation: Algebraic simplification and quadratic recurrence 2b

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((a+b x+c (x^2))/(d+e x))==((a e+c d x)/(d e))

Rule 1.2.1.4.2.2.3.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ n∈(SuperMinus[ℤ])∧ n+2 p∈(SuperMinus[ℤ]), then

∫(((((f+g x))^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  ⟶  (1/(d e))∫(a e+c d x)(((f+g x))^n) (((a+b x+c (x^2)))^(p-1))dx  ⟶  

(((((f+g x))^(n+1)) (((a+b x+c (x^2)))^p) (c d-b e-c e x))/(p (2 c d-b e) (e f-d g)))+
(1/(p (2 c d-b e) (e f-d g)))∫(((f+g x))^n) (((a+b x+c (x^2)))^p)(b e g (n+p+1)+c e f (2 p+1)-c d g (n+2 p+1)+c e g (n+2 p+2) x)dx

Program code:

Int[(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_/(d_+e_.*x_),x_Symbol] :=
  (f+g*x)^(n+1)*(a+b*x+c*x^2)^p*(c*d-b*e-c*e*x)/(p*(2*c*d-b*e)*(e*f-d*g)) + 
  1/(p*(2*c*d-b*e)*(e*f-d*g))*Int[(f+g*x)^n*(a+b*x+c*x^2)^p*(b*e*g*(n+p+1)+c*e*f*(2*p+1)-c*d*g*(n+2*p+1)+c*e*g*(n+2*p+2)*x),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && 
  ILtQ[n,0] && ILtQ[n+2*p,0] && Not[IGtQ[n,0]]

Int[(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_/(d_+e_.*x_),x_Symbol] :=
  d*(f+g*x)^(n+1)*(a+c*x^2)^(p+1)/(2*a*p*(e*f-d*g)*(d+e*x)) + 
  1/(p*(2*c*d)*(e*f-d*g))*Int[(f+g*x)^n*(a+c*x^2)^p*(c*e*f*(2*p+1)-c*d*g*(n+2*p+1)+c*e*g*(n+2*p+2)*x),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && 
  ILtQ[n,0] && ILtQ[n+2*p,0] && Not[IGtQ[n,0]]

4.  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0

1:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ c e f+c d g-b e g==0 ∧ m-n-1≠0

Rule 1.2.1.4.2.2.4.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ c e f+c d g-b e g==0 ∧ m-n-1≠0, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  -((e (((d+e x))^(m-1)) (((f+g x))^n) (((a+b x+c (x^2)))^(p+1)))/(c (m-n-1)))

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  -e*(d+e*x)^(m-1)*(f+g*x)^n*(a+b*x+c*x^2)^(p+1)/(c*(m-n-1)) /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && EqQ[c*e*f+c*d*g-b*e*g,0] && NeQ[m-n-1,0]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -e*(d+e*x)^(m-1)*(f+g*x)^n*(a+c*x^2)^(p+1)/(c*(m-n-1)) /;
FreeQ[{a,c,d,e,f,g,m,n,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && EqQ[e*f+d*g,0] && NeQ[m-n-1,0]

2:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ m-n-2==0

Rule 1.2.1.4.2.2.4.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ m-n-2==0, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  -(((e^2) (((d+e x))^(m-1)) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^(p+1)))/((n+1) (c e f+c d g-b e g)))

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  -e^2*(d+e*x)^(m-1)*(f+g*x)^(n+1)*(a+b*x+c*x^2)^(p+1)/((n+1)*(c*e*f+c*d*g-b*e*g)) /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && EqQ[m+p,0] && EqQ[m-n-2,0]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -e^2*(d+e*x)^(m-1)*(f+g*x)^(n+1)*(a+c*x^2)^(p+1)/(c*(n+1)*(e*f+d*g)) /;
FreeQ[{a,c,d,e,f,g,m,n,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && EqQ[m+p,0] && EqQ[m-n-2,0]

3.  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ p>0

1:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ p>0 ∧ n<-1

Rule 1.2.1.4.2.2.4.3.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ p>0 ∧ n<-1, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  
(((((d+e x))^m) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^p))/(g (n+1)))+((c m)/(e g (n+1)))∫(((d+e x))^(m+1)) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^m*(f+g*x)^(n+1)*(a+b*x+c*x^2)^p/(g*(n+1)) + 
  c*m/(e*g*(n+1))*Int[(d+e*x)^(m+1)*(f+g*x)^(n+1)*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && GtQ[p,0] && LtQ[n,-1] && Not[IntegerQ[n+p] && LeQ[n+p+2,0]]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^m*(f+g*x)^(n+1)*(a+c*x^2)^p/(g*(n+1)) + 
  c*m/(e*g*(n+1))*Int[(d+e*x)^(m+1)*(f+g*x)^(n+1)*(a+c*x^2)^(p-1),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && GtQ[p,0] && LtQ[n,-1] && Not[IntegerQ[n+p] && LeQ[n+p+2,0]]

2:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ p>0 ∧ m-n-1≠0

Rule 1.2.1.4.2.2.4.3.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ p>0 ∧ m-n-1≠0, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  
-(((((d+e x))^m) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^p))/(g (m-n-1)))-((m(c e f+c d g-b e g))/((e^2) g (m-n-1)))∫(((d+e x))^(m+1)) (((f+g x))^n) (((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  -(d+e*x)^m*(f+g*x)^(n+1)*(a+b*x+c*x^2)^p/(g*(m-n-1)) - 
  m*(c*e*f+c*d*g-b*e*g)/(e^2*g*(m-n-1))*Int[(d+e*x)^(m+1)*(f+g*x)^n*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && GtQ[p,0] && NeQ[m-n-1,0] && Not[IGtQ[n,0]] && Not[IntegerQ[n+p] && LtQ[n+p+2,0]] && RationalQ[n]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -(d+e*x)^m*(f+g*x)^(n+1)*(a+c*x^2)^p/(g*(m-n-1)) - 
  c*m*(e*f+d*g)/(e^2*g*(m-n-1))*Int[(d+e*x)^(m+1)*(f+g*x)^n*(a+c*x^2)^(p-1),x] /;
FreeQ[{a,c,d,e,f,g,n},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && GtQ[p,0] && NeQ[m-n-1,0] && Not[IGtQ[n,0]] && Not[IntegerQ[n+p] && LtQ[n+p+2,0]] && RationalQ[n]

4.  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ p<-1

1:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ p<-1 ∧ n>0

Rule 1.2.1.4.2.2.4.4.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ p<-1 ∧ n>0, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  
((e (((d+e x))^(m-1)) (((f+g x))^n) (((a+b x+c (x^2)))^(p+1)))/(c (p+1)))-((e g n)/(c (p+1)))∫(((d+e x))^(m-1)) (((f+g x))^(n-1)) (((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(f+g*x)^n*(a+b*x+c*x^2)^(p+1)/(c*(p+1)) - 
  e*g*n/(c*(p+1))*Int[(d+e*x)^(m-1)*(f+g*x)^(n-1)*(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && LtQ[p,-1] && GtQ[n,0]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(f+g*x)^n*(a+c*x^2)^(p+1)/(c*(p+1)) - 
  e*g*n/(c*(p+1))*Int[(d+e*x)^(m-1)*(f+g*x)^(n-1)*(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && LtQ[p,-1] && GtQ[n,0]

2:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ p<-1

Rule 1.2.1.4.2.2.4.4.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ p<-1, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  
(((e^2) (((d+e x))^(m-1)) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^(p+1)))/((p+1) (c e f+c d g-b e g)))+(((e^2) g (m-n-2))/((p+1) (c e f+c d g-b e g)))∫(((d+e x))^(m-1)) (((f+g x))^n) (((a+b x+c (x^2)))^(p+1)) dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e^2*(d+e*x)^(m-1)*(f+g*x)^(n+1)*(a+b*x+c*x^2)^(p+1)/((p+1)*(c*e*f+c*d*g-b*e*g)) + 
  e^2*g*(m-n-2)/((p+1)*(c*e*f+c*d*g-b*e*g))*Int[(d+e*x)^(m-1)*(f+g*x)^n*(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && EqQ[m+p,0] && 
  LtQ[p,-1] && RationalQ[n]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e^2*(d+e*x)^(m-1)*(f+g*x)^(n+1)*(a+c*x^2)^(p+1)/(c*(p+1)*(e*f+d*g)) + 
  e^2*g*(m-n-2)/(c*(p+1)*(e*f+d*g))*Int[(d+e*x)^(m-1)*(f+g*x)^n*(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e,f,g,n},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && EqQ[m+p,0] && LtQ[p,-1] && RationalQ[n]

5:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ n>0 ∧ m-n-1≠0

Rule 1.2.1.4.2.2.4.5: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ n>0 ∧ m-n-1≠0, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  
-((e (((d+e x))^(m-1)) (((f+g x))^n) (((a+b x+c (x^2)))^(p+1)))/(c (m-n-1)))-((n(c e f+c d g-b e g))/(c e (m-n-1)))∫(((d+e x))^m) (((f+g x))^(n-1)) (((a+b x+c (x^2)))^p) dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  -e*(d+e*x)^(m-1)*(f+g*x)^n*(a+b*x+c*x^2)^(p+1)/(c*(m-n-1)) - 
  n*(c*e*f+c*d*g-b*e*g)/(c*e*(m-n-1))*Int[(d+e*x)^m*(f+g*x)^(n-1)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,p},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && GtQ[n,0] && NeQ[m-n-1,0] && (IntegerQ[2*p] || IntegerQ[n])

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -e*(d+e*x)^(m-1)*(f+g*x)^n*(a+c*x^2)^(p+1)/(c*(m-n-1)) - 
  n*(e*f+d*g)/(e*(m-n-1))*Int[(d+e*x)^m*(f+g*x)^(n-1)*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,f,g,m,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && GtQ[n,0] && NeQ[m-n-1,0] && (IntegerQ[2*p] || IntegerQ[n])

6:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ n<-1

Rule 1.2.1.4.2.2.4.6: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0 ∧ n<-1, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  
-(((e^2) (((d+e x))^(m-1)) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^(p+1)))/((n+1) (c e f+c d g-b e g)))-((c e (m-n-2))/((n+1) (c e f+c d g-b e g)))∫(((d+e x))^m) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  -e^2*(d+e*x)^(m-1)*(f+g*x)^(n+1)*(a+b*x+c*x^2)^(p+1)/((n+1)*(c*e*f+c*d*g-b*e*g)) - 
  c*e*(m-n-2)/((n+1)*(c*e*f+c*d*g-b*e*g))*Int[(d+e*x)^m*(f+g*x)^(n+1)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,p},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && LtQ[n,-1] && IntegerQ[2*p]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -e^2*(d+e*x)^(m-1)*(f+g*x)^(n+1)*(a+c*x^2)^(p+1)/((n+1)*(c*e*f+c*d*g)) - 
  e*(m-n-2)/((n+1)*(e*f+d*g))*Int[(d+e*x)^m*(f+g*x)^(n+1)*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,f,g,m,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p,0] && LtQ[n,-1] && IntegerQ[2*p]

7:  ∫((Sqrt[d+e x])/((f+g x) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0

Derivation: Integration by substitution

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((Sqrt[d+e x])/(x (Sqrt[a+b x+c (x^2)])))==-2 d Subst[(1/(a-d (x^2))),x,((Sqrt[a+b x+c (x^2)])/(Sqrt[d+e x]))](∂_x)((Sqrt[a+b x+c (x^2)])/(Sqrt[d+e x]))

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((Sqrt[d+e x])/((f+g x) (Sqrt[a+b x+c (x^2)])))==2 (e^2) Subst[(1/(c (e f+d g)-b e g+(e^2) g (x^2))),x,((Sqrt[a+b x+c (x^2)])/(Sqrt[d+e x]))](∂_x)((Sqrt[a+b x+c (x^2)])/(Sqrt[d+e x]))

Rule 1.2.1.4.2.2.4.7: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0, then

∫((Sqrt[d+e x])/((f+g x) (Sqrt[a+b x+c (x^2)])))dx  ⟶  2 (e^2) Subst[∫(1/(c (e f+d g)-b e g+(e^2) g (x^2)))dx,x,((Sqrt[a+b x+c (x^2)])/(Sqrt[d+e x]))]

Program code:

Int[Sqrt[d_+e_.*x_]/((f_.+g_.*x_)*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  2*e^2*Subst[Int[1/(c*(e*f+d*g)-b*e*g+e^2*g*x^2),x],x,Sqrt[a+b*x+c*x^2]/Sqrt[d+e*x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0]

Int[Sqrt[d_+e_.*x_]/((f_.+g_.*x_)*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  2*e^2*Subst[Int[1/(c*(e*f+d*g)+e^2*g*x^2),x],x,Sqrt[a+c*x^2]/Sqrt[d+e*x]] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0]

5.  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p-1==0

1:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when 
					e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p-1==0 ∧ b e g (n+1)+c e f (p+1)-c d g (2 n+p+3)==0 ∧ n+p+2≠0

Rule 1.2.1.4.2.2.5.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p-1==0 ∧ b e g (n+1)+c e f (p+1)-c d g (2 n+p+3)==0 ∧ n+p+2≠0, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  (((e^2) (((d+e x))^(m-2)) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^(p+1)))/(c g (n+p+2)))

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e^2*(d+e*x)^(m-2)*(f+g*x)^(n+1)*(a+b*x+c*x^2)^(p+1)/(c*g*(n+p+2)) /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p-1,0] && EqQ[b*e*g*(n+1)+c*e*f*(p+1)-c*d*g*(2*n+p+3),0] && NeQ[n+p+2,0]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e^2*(d+e*x)^(m-2)*(f+g*x)^(n+1)*(a+c*x^2)^(p+1)/(c*g*(n+p+2)) /;
FreeQ[{a,c,d,e,f,g,m,n,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p-1,0] && EqQ[e*f*(p+1)-d*g*(2*n+p+3),0] && NeQ[n+p+2,0]

2:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p-1==0 ∧ n<-1

Rule 1.2.1.4.2.2.5.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p-1==0 ∧ n<-1, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  
(((e^2) (e f-d g) (((d+e x))^(m-2)) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^(p+1)))/(g (n+1) (c e f+c d g-b e g)))-((e (b e g (n+1)+c e f (p+1)-c d g (2 n+p+3)))/(g (n+1) (c e f+c d g-b e g))) ∫(((d+e x))^(m-1)) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e^2*(e*f-d*g)*(d+e*x)^(m-2)*(f+g*x)^(n+1)*(a+b*x+c*x^2)^(p+1)/(g*(n+1)*(c*e*f+c*d*g-b*e*g)) - 
  e*(b*e*g*(n+1)+c*e*f*(p+1)-c*d*g*(2*n+p+3))/(g*(n+1)*(c*e*f+c*d*g-b*e*g))*
    Int[(d+e*x)^(m-1)*(f+g*x)^(n+1)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,p},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p-1,0] && LtQ[n,-1] && IntegerQ[2*p]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e^2*(e*f-d*g)*(d+e*x)^(m-2)*(f+g*x)^(n+1)*(a+c*x^2)^(p+1)/(c*g*(n+1)*(e*f+d*g)) - 
  e*(e*f*(p+1)-d*g*(2*n+p+3))/(g*(n+1)*(e*f+d*g))*Int[(d+e*x)^(m-1)*(f+g*x)^(n+1)*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,f,g,m,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p-1,0] && LtQ[n,-1] && IntegerQ[2*p]

3:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p-1==0 ∧ n≮-1

Rule 1.2.1.4.2.2.5.3: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p-1==0 ∧ n<-1, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  
(((e^2) (((d+e x))^(m-2)) (((f+g x))^(n+1)) (((a+b x+c (x^2)))^(p+1)))/(c g (n+p+2)))-((b e g (n+1)+c e f (p+1)-c d g (2 n+p+3))/(c g (n+p+2))) ∫(((d+e x))^(m-1)) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e^2*(d+e*x)^(m-2)*(f+g*x)^(n+1)*(a+b*x+c*x^2)^(p+1)/(c*g*(n+p+2)) - 
  (b*e*g*(n+1)+c*e*f*(p+1)-c*d*g*(2*n+p+3))/(c*g*(n+p+2))*Int[(d+e*x)^(m-1)*(f+g*x)^n*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p-1,0] && Not[LtQ[n,-1]] && IntegerQ[2*p]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e^2*(d+e*x)^(m-2)*(f+g*x)^(n+1)*(a+c*x^2)^(p+1)/(c*g*(n+p+2)) - 
  (e*f*(p+1)-d*g*(2*n+p+3))/(g*(n+p+2))*Int[(d+e*x)^(m-1)*(f+g*x)^n*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,f,g,m,n,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[p]] && EqQ[m+p-1,0] && Not[LtQ[n,-1]] && IntegerQ[2*p]

6:  ∫(((d+e x))^m)(((f+g x))^n)(((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ (m∈(SuperPlus[ℤ])∨ (m|n)∈ℤ)

Derivation: Algebraic expansion

Rule 1.2.1.4.2.2.6: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ (m∈(SuperPlus[ℤ])∨ (m|n)∈ℤ), then

∫(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)dx  ⟶  ∫ExpandIntegrand[(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p),x]dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^n*(a+b*x+c*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[p]] && ILtQ[m,0] && (ILtQ[n,0] || IGtQ[n,0] && ILtQ[p+1/2,0]) && Not[IGtQ[n,0]]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  Int[ExpandIntegrand[1/Sqrt[a+c*x^2],(d+e*x)^m*(f+g*x)^n*(a+c*x^2)^(p+1/2),x],x] /;
FreeQ[{a,c,d,e,f,g,n,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && IntegerQ[p-1/2] && ILtQ[m,0] && ILtQ[n,0] && Not[IGtQ[n,0]]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^n*(a+c*x^2)^p,x],x] /;
FreeQ[{a,c,d,e,f,g,n,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && ILtQ[m,0] && (ILtQ[n,0] || IGtQ[n,0] && ILtQ[p+1/2,0]) && Not[IGtQ[n,0]]

7:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p+(1/2)∈(SuperMinus[ℤ])∧ m∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion and special quadratic recurrence 2b

Basis: If  c (d^2)-b d e+a (e^2)==0, then (d+e x) (a e+c d x)==d e (a+b x+c (x^2))

Rule 1.2.1.4.2.2.7: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p+(1/2)∈(SuperMinus[ℤ])∧ m∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ]), 
    let (Subscript[Q, n-1])[x]->PolynomialQuotient[(((f+g x))^n),a e+c d x,x] and h->PolynomialRemainder[(((f+g x))^n),a e+c d x,x], then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  

h ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx+d e ∫(((d+e x))^(m-1)) (Subscript[Q, n-1])[x] (((a+b x+c (x^2)))^(p+1))dx  ⟶  

((h (2 c d-b e) (((d+e x))^m) (((a+b x+c (x^2)))^(p+1)))/(e(p+1)((b^2)-4 a c) ))+
(1/((p+1) ((b^2)-4 a c))) ∫(((d+e x))^(m-1)) (((a+b x+c (x^2)))^(p+1))(d e (p+1) ((b^2)-4 a c) (Subscript[Q, n-1])[x]-h (2 c d-b e) (m+2 p+2)) dx

Program code:

Int[(d_.+e_.*x_)^m_.*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  With[{Q=PolynomialQuotient[(f+g*x)^n,a*e+c*d*x,x], h=PolynomialRemainder[(f+g*x)^n,a*e+c*d*x,x]},
  h*(2*c*d-b*e)*(d+e*x)^m*(a+b*x+c*x^2)^(p+1)/(e*(p+1)*(b^2-4*a*c)) + 
  1/((p+1)*(b^2-4*a*c))*Int[(d+e*x)^(m-1)*(a+b*x+c*x^2)^(p+1)*
    ExpandToSum[d*e*(p+1)*(b^2-4*a*c)*Q-h*(2*c*d-b*e)*(m+2*p+2),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && ILtQ[p+1/2,0] && IGtQ[m,0] && IGtQ[n,0] && Not[IGtQ[n,0]]

Int[(d_.+e_.*x_)^m_.*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  With[{Q=PolynomialQuotient[(f+g*x)^n,a*e+c*d*x,x], h=PolynomialRemainder[(f+g*x)^n,a*e+c*d*x,x]},
  -d*h*(d+e*x)^m*(a+c*x^2)^(p+1)/(2*a*e*(p+1)) + 
  d/(2*a*(p+1))*Int[(d+e*x)^(m-1)*(a+c*x^2)^(p+1)*ExpandToSum[2*a*e*(p+1)*Q+h*(m+2*p+2),x],x]] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && ILtQ[p+1/2,0] && IGtQ[m,0] && IGtQ[n,0] && Not[IGtQ[n,0]]

8:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+n+2 p+1==0 ∧ m∈(SuperMinus[ℤ])∧ n∈(SuperMinus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.1.4.2.2.8: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+n+2 p+1==0 ∧ n∈ℤ ∧ m∈(SuperMinus[ℤ]), then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  ∫(((a+b x+c (x^2)))^p) ExpandIntegrand[(((d+e x))^m) (((f+g x))^n),x]dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*x+c*x^2)^p,(d+e*x)^m*(f+g*x)^n,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && 
  EqQ[m+n+2*p+1,0] && ILtQ[m,0] && ILtQ[n,0]

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+c*x^2)^p,(d+e*x)^m*(f+g*x)^n,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && EqQ[m+n+2*p+1,0] && ILtQ[m,0] && ILtQ[n,0]

x:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+n+2 p+1≠0 ∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion and quadratic recurrence 3a with A=d, B=e and m=m-1

Rule 1.2.1.4.2.2.x: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+n+2 p+1≠0 ∧ n∈(SuperPlus[ℤ]), then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  

∫(((d+e x))^m) ((((f+g x))^n)-((g^n)/(e^n)) (((d+e x))^n)) (((a+b x+c (x^2)))^p)dx+((g^n)/(e^n)) ∫(((d+e x))^(m+n)) (((a+b x+c (x^2)))^p)dx  ⟶  

(((g^n) (((d+e x))^(m+n-1)) (((a+b x+c (x^2)))^(p+1)))/(c (e^(n-1)) (m+n+2 p+1)))+(1/(c (e^n) (m+n+2 p+1))) ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)·
(c (e^n) (m+n+2 p+1) (((f+g x))^n)-c (g^n) (m+n+2 p+1) (((d+e x))^n)+e (g^n) (m+p+n) (((d+e x))^(n-2)) (b d-2 a e+(2 c d-b e) x))dx

Program code:

(* Int[(d_.+e_.*x_)^m_.*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  g^n*(d+e*x)^(m+n-1)*(a+b*x+c*x^2)^(p+1)/(c*e^(n-1)*(m+n+2*p+1)) + 
  1/(c*e^n*(m+n+2*p+1))*Int[(d+e*x)^m*(a+b*x+c*x^2)^p*
    ExpandToSum[c*e^n*(m+n+2*p+1)*(f+g*x)^n-c*g^n*(m+n+2*p+1)*(d+e*x)^n+e*g^n*(m+p+n)*(d+e*x)^(n-2)*(b*d-2*a*e+(2*c*d-b*e)*x),x],x] /;
FreeQ[{a,b,c,d,e,f,g,m,p},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && 
  NeQ[m+n+2*p+1,0] && IGtQ[n,0] *)

(* Int[(d_.+e_.*x_)^m_.*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  g^n*(d+e*x)^(m+n-1)*(a+c*x^2)^(p+1)/(c*e^(n-1)*(m+n+2*p+1)) + 
  1/(c*e^n*(m+n+2*p+1))*Int[(d+e*x)^m*(a+c*x^2)^p*
    ExpandToSum[c*e^n*(m+n+2*p+1)*(f+g*x)^n-c*g^n*(m+n+2*p+1)*(d+e*x)^n-2*e*g^n*(m+p+n)*(d+e*x)^(n-2)*(a*e-c*d*x),x],x] /;
FreeQ[{a,c,d,e,f,g,m,p},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && NeQ[m+n+2*p+1,0] && IGtQ[n,0] *)

9:  ∫(((e x))^m)(((f+g x))^n)(((b x+c (x^2)))^p)dx  when p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((((e x))^m)(((b x+c (x^2)))^p))/((x^(m+p)) (((b+c x))^p)))==0

Rule 1.2.1.4.2.2.9: If  p∉ℤ, then

∫(((e x))^m)(((f+g x))^n)(((b x+c (x^2)))^p)dx  ⟶  (((((e x))^m)(((b x+c (x^2)))^p))/((x^(m+p)) (((b+c x))^p)))∫(x^(m+p))(((f+g x))^n)(((b+c x))^p)dx

Program code:

Int[(e_.*x_)^m_*(f_.+g_.*x_)^n_*(b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (e*x)^m*(b*x+c*x^2)^p/(x^(m+p)*(b+c*x)^p)*Int[x^(m+p)*(f+g*x)^n*(b+c*x)^p,x] /;
FreeQ[{b,c,e,f,g,m,n},x] && Not[IntegerQ[p]] && Not[IGtQ[n,0]]

10:  ∫(((d+e x))^m)(((f+g x))^n)(((a+c (x^2)))^p)dx  when e f-d g≠0 ∧ c (d^2)+a (e^2)==0 ∧ p∉ℤ ∧ a>0 ∧ d>0

Derivation: Algebraic simplification

Basis: If  c (d^2)+a (e^2)==0 ∧ a>0 ∧ d>0, then (((a+c (x^2)))^p)==(((a-((a (e^2) (x^2))/(d^2))))^p)==(((d+e x))^p) ((((a/d)+((c x)/e)))^p)

Rule 1.2.1.4.2.2.10: If  e f-d g≠0 ∧ c (d^2)+a (e^2)==0 ∧ p∉ℤ ∧ a>0 ∧ d>0, then

∫(((d+e x))^m) (((f+g x))^n)(((a+c (x^2)))^p)dx  ⟶  ∫(((d+e x))^(m+p)) (((f+g x))^n)((((a/d)+((c x)/e)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  Int[(d+e*x)^(m+p)*(f+g*x)^n*(a/d+c/e*x)^p,x] /;
FreeQ[{a,c,d,e,f,g,m,n},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && GtQ[a,0] && GtQ[d,0] && Not[IGtQ[m,0]] && Not[IGtQ[n,0]]

11:  ∫(((d+e x))^m)(((f+g x))^n)(((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  c (d^2)-b d e+a (e^2)==0, then (∂_x)((((a+b x+c (x^2)))^p)/((((d+e x))^p) ((((a/d)+((c x)/e)))^p)))==0

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((((a+b x+c (x^2)))^p)/((((d+e x))^p) ((((a/d)+((c x)/e)))^p)))==((((a+b x+c (x^2)))^(FracPart[p]))/((((d+e x))^(FracPart[p])) ((((a/d)+((c x)/e)))^(FracPart[p]))))

Note: This could replace the above rules in this section, but would result in slightly more complicated antiderivatives.

Rule 1.2.1.4.2.2.11: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ, then

∫(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)dx  ⟶  ((((a+b x+c (x^2)))^(FracPart[p]))/((((d+e x))^(FracPart[p])) ((((a/d)+((c x)/e)))^(FracPart[p]))))∫(((d+e x))^(m+p)) (((f+g x))^n)((((a/d)+((c x)/e)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
(*(a+b*x+c*x^2)^p/((d+e*x)^p*(a*e+c*d*x)^p)*Int[(d+e*x)^(m+p)*(f+g*x)^n*(a*e+c*d*x)^p,x] /; *)
  (a+b*x+c*x^2)^FracPart[p]/((d+e*x)^FracPart[p]*(a/d+(c*x)/e)^FracPart[p])*Int[(d+e*x)^(m+p)*(f+g*x)^n*(a/d+c/e*x)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && Not[IGtQ[m,0]] && Not[IGtQ[n,0]]

Int[(d_+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (a+c*x^2)^FracPart[p]/((d+e*x)^FracPart[p]*(a/d+(c*x)/e)^FracPart[p])*Int[(d+e*x)^(m+p)*(f+g*x)^n*(a/d+c/e*x)^p,x] /;
FreeQ[{a,c,d,e,f,g,m,n},x] && NeQ[e*f-d*g,0] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && Not[IGtQ[m,0]] && Not[IGtQ[n,0]]

3:  ∫(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (m|n|p)∈ℤ

Derivation: Algebraic expansion

Rule 1.2.1.4.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (m|n|p)∈ℤ, then

∫(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)dx  ⟶  ∫ExpandIntegrand[(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p),x]dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^n*(a+b*x+c*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[p] && 
  (EqQ[p,1] && IntegersQ[m,n] || ILtQ[m,0] && ILtQ[n,0])

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^n*(a+c*x^2)^p,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegerQ[p] && 
  (EqQ[p,1] && IntegersQ[m,n] || ILtQ[m,0] && ILtQ[n,0])

4:  ∫((((a+b x+c (x^2)))^p)/((d+e x)(f+g x)))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∉ℤ ∧ p>0

Reference: Algebraic expansion

Basis: ((a+b x+c (x^2))/(d+e x))==(((c (d^2)-b d e+a (e^2))(f+g x))/(e (e f-d g) (d+e x)))-((c d f-b e f+a e g-c (e f-d g) x)/(e (e f-d g)))

Rule 1.2.1.4.4: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∉ℤ ∧ p>0, then

∫((((a+b x+c (x^2)))^p)/((d+e x)(f+g x)))dx  ⟶  
((c (d^2)-b d e+a (e^2))/(e (e f-d g)))∫((((a+b x+c (x^2)))^(p-1))/(d+e x))dx-(1/(e (e f-d g)))∫(((c d f-b e f+a e g-c (e f-d g) x) (((a+b x+c (x^2)))^(p-1)))/(f+g x))dx

Program code:

Int[(a_.+b_.*x_+c_.*x_^2)^p_/((d_.+e_.*x_)*(f_.+g_.*x_)),x_Symbol] :=
  (c*d^2-b*d*e+a*e^2)/(e*(e*f-d*g))*Int[(a+b*x+c*x^2)^(p-1)/(d+e*x),x] - 
  1/(e*(e*f-d*g))*Int[Simp[c*d*f-b*e*f+a*e*g-c*(e*f-d*g)*x,x]*(a+b*x+c*x^2)^(p-1)/(f+g*x),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && FractionQ[p] && GtQ[p,0]

Int[(a_+c_.*x_^2)^p_/((d_.+e_.*x_)*(f_.+g_.*x_)),x_Symbol] :=
  (c*d^2+a*e^2)/(e*(e*f-d*g))*Int[(a+c*x^2)^(p-1)/(d+e*x),x] - 
  1/(e*(e*f-d*g))*Int[Simp[c*d*f+a*e*g-c*(e*f-d*g)*x,x]*(a+c*x^2)^(p-1)/(f+g*x),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && FractionQ[p] && GtQ[p,0]

5:  ∫(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (n|p)∈ℤ ∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  q∈(SuperPlus[ℤ]), then (((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)==(q/e) Subst[(x^(q (m+1)-1)) (((((e f-d g)/e)+((g (x^q))/e)))^n) (((((c (d^2)-b d e+a (e^2))/(e^2))-(((2 c d-b e) (x^q))/(e^2))+((c (x^(2q)))/(e^2))))^p),x,(((d+e x))^(1/q))](∂_x)(((d+e x))^(1/q))

Rule 1.2.1.4.5: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (n|p)∈ℤ ∧ m∈𝔽, let q=Denominator[m], then

∫(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)dx  ⟶  (q/e) Subst[∫(x^(q (m+1)-1)) (((((e f-d g)/e)+((g (x^q))/e)))^n) (((((c (d^2)-b d e+a (e^2))/(e^2))-(((2 c d-b e) (x^q))/(e^2))+((c (x^(2q)))/(e^2))))^p)dx,x,(((d+e x))^(1/q))]

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  With[{q=Denominator[m]},
  q/e*Subst[Int[x^(q*(m+1)-1)*((e*f-d*g)/e+g*x^q/e)^n*
    ((c*d^2-b*d*e+a*e^2)/e^2-(2*c*d-b*e)*x^q/e^2+c*x^(2*q)/e^2)^p,x],x,(d+e*x)^(1/q)]] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegersQ[n,p] && FractionQ[m]

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_.,x_Symbol] :=
  With[{q=Denominator[m]},
  q/e*Subst[Int[x^(q*(m+1)-1)*((e*f-d*g)/e+g*x^q/e)^n*((c*d^2+a*e^2)/e^2-2*c*d*x^q/e^2+c*x^(2*q)/e^2)^p,x],x,(d+e*x)^(1/q)]] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegersQ[n,p] && FractionQ[m]

6.  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m-n==0 ∧ e f+d g==0

1:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when  m-n==0 ∧ e f+d g==0 ∧ (m∈ℤ ∨ d>0 ∧ f>0)

Derivation: Algebraic simplification

Basis: If  e f+d g==0 ∧ d>0 ∧ f>0, then (((d+e x))^m) (((f+g x))^m)==(((d f+e g (x^2)))^m)

Rule 1.2.1.4.6.1: If  m-n==0 ∧ e f+d g==0 ∧ (m∈ℤ ∨ d>0 ∧ f>0), then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  ∫(((d f+e g (x^2)))^m) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(f_+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[(d*f+e*g*x^2)^m*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && EqQ[m-n,0] && EqQ[e*f+d*g,0] && (IntegerQ[m] || GtQ[d,0] && GtQ[f,0])

Int[(d_+e_.*x_)^m_*(f_+g_.*x_)^n_*(a_.+c_.*x_^2)^p_.,x_Symbol] :=
  Int[(d*f+e*g*x^2)^m*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,f,g,m,n,p},x] && EqQ[m-n,0] && EqQ[e*f+d*g,0] && (IntegerQ[m] || GtQ[d,0] && GtQ[f,0])

2:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when  m-n==0 ∧ e f+d g==0

Derivation: Piecewise constant extraction

Basis: If  e f+d g==0, then (∂_x)(((((d+e x))^m) (((f+g x))^m))/(((d f+e g (x^2)))^m))==0

Rule 1.2.1.4.6.2: If  m-n==0 ∧ e f+d g==0, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  (((((d+e x))^(FracPart[m])) (((f+g x))^(FracPart[m])))/(((d f+e g (x^2)))^(FracPart[m])))∫(((d f+e g (x^2)))^m) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(f_+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  (d+e*x)^FracPart[m]*(f+g*x)^FracPart[m]/(d*f+e*g*x^2)^FracPart[m]*Int[(d*f+e*g*x^2)^m*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && EqQ[m-n,0] && EqQ[e*f+d*g,0]

Int[(d_+e_.*x_)^m_*(f_+g_.*x_)^n_*(a_.+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^FracPart[m]*(f+g*x)^FracPart[m]/(d*f+e*g*x^2)^FracPart[m]*Int[(d*f+e*g*x^2)^m*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,f,g,m,n,p},x] && EqQ[m-n,0] && EqQ[e*f+d*g,0]

7.  ∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  when  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ

1.  ∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ ∧ m>0

1.  ∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ ∧ m>0 ∧ n>0

1:  ∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ ∧ m>0 ∧ n>1

Reference: Algebraic expansion

Basis: (((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))==((g (2 c e f+c d g-b e g+c e g x)(((d+e x))^(m-1)) (((f+g x))^(n-2)))/(c^2))+((((c^2) d (f^2)-2 a c e f g-a c d (g^2)+a b e (g^2)+((c^2) e (f^2)+2 (c^2) d f g-2 b c e f g-b c d (g^2)+(b^2) e (g^2)-a c e (g^2)) x)(((d+e x))^(m-1)) (((f+g x))^(n-2)))/((c^2) (a+b x+c (x^2))))

Rule 1.2.1.4.7.1.1.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ ∧ m>0 ∧ n>1, then

∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  ⟶  
(g/(c^2))∫(2 c e f+c d g-b e g+c e g x)(((d+e x))^(m-1)) (((f+g x))^(n-2))dx+
(1/(c^2))∫((((c^2) d (f^2)-2 a c e f g-a c d (g^2)+a b e (g^2)+((c^2) e (f^2)+2 (c^2) d f g-2 b c e f g-b c d (g^2)+(b^2) e (g^2)-a c e (g^2)) x)(((d+e x))^(m-1)) (((f+g x))^(n-2)))/(a+b x+c (x^2)))dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  g/c^2*Int[Simp[2*c*e*f+c*d*g-b*e*g+c*e*g*x,x]*(d+e*x)^(m-1)*(f+g*x)^(n-2),x] + 
  1/c^2*Int[Simp[c^2*d*f^2-2*a*c*e*f*g-a*c*d*g^2+a*b*e*g^2+(c^2*e*f^2+2*c^2*d*f*g-2*b*c*e*f*g-b*c*d*g^2+b^2*e*g^2-a*c*e*g^2)*x,x]*
    (d+e*x)^(m-1)*(f+g*x)^(n-2)/(a+b*x+c*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[m]] && Not[IntegerQ[n]] && GtQ[m,0] && GtQ[n,1]

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_/(a_+c_.*x_^2),x_Symbol] :=
  g/c*Int[Simp[2*e*f+d*g+e*g*x,x]*(d+e*x)^(m-1)*(f+g*x)^(n-2),x] + 
  1/c*Int[Simp[c*d*f^2-2*a*e*f*g-a*d*g^2+(c*e*f^2+2*c*d*f*g-a*e*g^2)*x,x]*(d+e*x)^(m-1)*(f+g*x)^(n-2)/(a+c*x^2),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[m]] && Not[IntegerQ[n]] && GtQ[m,0] && GtQ[n,1]

2:  ∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ ∧ m>0 ∧ n>0

Reference: Algebraic expansion

Basis: (((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))==((e g (((d+e x))^(m-1)) (((f+g x))^(n-1)))/c)+(((c d f-a e g+(c e f+c d g-b e g) x)(((d+e x))^(m-1)) (((f+g x))^(n-1)))/(c (a+b x+c (x^2))))

Rule 1.2.1.4.7.1.1.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ ∧ m>0 ∧ n>0, then

∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  ⟶  
((e g)/c)∫(((d+e x))^(m-1)) (((f+g x))^(n-1))dx+(1/c)∫(((c d f-a e g+(c e f+c d g-b e g) x)(((d+e x))^(m-1)) (((f+g x))^(n-1)))/(a+b x+c (x^2)))dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  e*g/c*Int[(d+e*x)^(m-1)*(f+g*x)^(n-1),x] + 
  1/c*Int[Simp[c*d*f-a*e*g+(c*e*f+c*d*g-b*e*g)*x,x]*(d+e*x)^(m-1)*(f+g*x)^(n-1)/(a+b*x+c*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[m]] && Not[IntegerQ[n]] && GtQ[m,0] && GtQ[n,0]

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_/(a_+c_.*x_^2),x_Symbol] :=
  e*g/c*Int[(d+e*x)^(m-1)*(f+g*x)^(n-1),x] + 
  1/c*Int[Simp[c*d*f-a*e*g+(c*e*f+c*d*g)*x,x]*(d+e*x)^(m-1)*(f+g*x)^(n-1)/(a+c*x^2),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[m]] && Not[IntegerQ[n]] && GtQ[m,0] && GtQ[n,0]

2:  ∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ ∧ m>0 ∧ n<-1

Reference: Algebraic expansion

Basis: (((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))==-((g (e f-d g) (((d+e x))^(m-1)) (((f+g x))^n))/(c (f^2)-b f g+a (g^2)))+(((c d f-b d g+a e g+c (e f-d g) x) (((d+e x))^(m-1)) (((f+g x))^(n+1)))/((c (f^2)-b f g+a (g^2)) (a+b x+c (x^2))))

Rule 1.2.1.4.7.1.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ ∧ m>0 ∧ n<-1, then

∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  ⟶  
-((g (e f-d g))/(c (f^2)-b f g+a (g^2)))∫(((d+e x))^(m-1)) (((f+g x))^n)dx+(1/(c (f^2)-b f g+a (g^2)))∫(((c d f-b d g+a e g+c (e f-d g) x) (((d+e x))^(m-1)) (((f+g x))^(n+1)))/(a+b x+c (x^2)))dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  -g*(e*f-d*g)/(c*f^2-b*f*g+a*g^2)*Int[(d+e*x)^(m-1)*(f+g*x)^n,x] + 
  1/(c*f^2-b*f*g+a*g^2)*
    Int[Simp[c*d*f-b*d*g+a*e*g+c*(e*f-d*g)*x,x]*(d+e*x)^(m-1)*(f+g*x)^(n+1)/(a+b*x+c*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[m]] && Not[IntegerQ[n]] && GtQ[m,0] && LtQ[n,-1]

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_/(a_+c_.*x_^2),x_Symbol] :=
  -g*(e*f-d*g)/(c*f^2+a*g^2)*Int[(d+e*x)^(m-1)*(f+g*x)^n,x] + 
  1/(c*f^2+a*g^2)*
    Int[Simp[c*d*f+a*e*g+c*(e*f-d*g)*x,x]*(d+e*x)^(m-1)*(f+g*x)^(n+1)/(a+c*x^2),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[m]] && Not[IntegerQ[n]] && GtQ[m,0] && LtQ[n,-1]

2.  ∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ

1:  ∫((((d+e x))^m)/((Sqrt[f+g x]) (a+b x+c (x^2))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m+(1/2)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: If  q->(Sqrt[(b^2)-4a c]), then ((d+e x)/(a+b x+c (x^2)))==((2 c d-e (b-q))/(q (b-q+2 c x)))-((2 c d-e (b+q))/(q (b+q+2 c x)))

Rule 1.2.1.4.7.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m+(1/2)∈(SuperPlus[ℤ]), then

∫((((d+e x))^m)/((Sqrt[f+g x]) (a+b x+c (x^2))))dx  ⟶  ∫(1/((Sqrt[d+e x]) (Sqrt[f+g x])))ExpandIntegrand[((((d+e x))^(m+(1/2)))/(a+b x+c (x^2))),x]dx

Program code:

Int[(d_.+e_.*x_)^m_/(Sqrt[f_.+g_.*x_]*(a_.+b_.*x_+c_.*x_^2)),x_Symbol] :=
  Int[ExpandIntegrand[1/(Sqrt[d+e*x]*Sqrt[f+g*x]),(d+e*x)^(m+1/2)/(a+b*x+c*x^2),x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[m+1/2,0]

Int[(d_.+e_.*x_)^m_/(Sqrt[f_.+g_.*x_]*(a_.+c_.*x_^2)),x_Symbol] :=
  Int[ExpandIntegrand[1/(Sqrt[d+e*x]*Sqrt[f+g*x]),(d+e*x)^(m+1/2)/(a+c*x^2),x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[c*d^2+a*e^2,0] && IGtQ[m+1/2,0]

2:  ∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ

Derivation: Algebraic expansion

Basis: If  q->(Sqrt[(b^2)-4a c]), then (1/(a+b z+c (z^2)))==((2c)/(q(b-q+2 c z)))-((2c)/(q(b+q+2 c z)))

Rule 1.2.1.4.7.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m∉ℤ ∧ n∉ℤ, then

∫(((((d+e x))^m) (((f+g x))^n))/(a+b x+c (x^2)))dx  ⟶  ∫(((d+e x))^m) (((f+g x))^n) ExpandIntegrand[(1/(a+b x+c (x^2))),x]dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^n,1/(a+b*x+c*x^2),x],x] /;
FreeQ[{a,b,c,d,e,f,g,m,n},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[m]] && Not[IntegerQ[n]]

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_/(a_+c_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^n,1/(a+c*x^2),x],x] /;
FreeQ[{a,c,d,e,f,g,m,n},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[m]] && Not[IntegerQ[n]]

8:  ∫(x^2) (((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when  b e (m+p+2)+2 c d (p+1)==0 ∧ b d (p+1)+a e (m+1)==0 ∧ m+2 p+3≠0

Derivation: Special case of one step of the Ostrogradskiy-Hermite integration method

Rule 1.2.1.4.8: If  b e (m+p+2)+2 c d (p+1)==0 ∧ b d (p+1)+a e (m+1)==0 ∧ m+2 p+3≠0, then

∫(x^2) (((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  (((((d+e x))^(m+1)) (((a+b x+c (x^2)))^(p+1)))/(c e (m+2 p+3)))

Program code:

Int[x_^2*(d_.+e_.*x_)^m_.*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*x+c*x^2)^(p+1)/(c*e*(m+2*p+3)) /;
FreeQ[{a,b,c,d,e,m,p},x] && EqQ[b*e*(m+p+2)+2*c*d*(p+1),0] && EqQ[b*d*(p+1)+a*e*(m+1),0] && NeQ[m+2*p+3,0]

Int[x_^2*(d_.+e_.*x_)^m_.*(a_.+c_.*x_^2)^p_.,x_Symbol] :=
  (d+e*x)^(m+1)*(a+c*x^2)^(p+1)/(c*e*(m+2*p+3)) /;
FreeQ[{a,c,d,e,m,p},x] && EqQ[d*(p+1),0] && EqQ[a*(m+1),0] && NeQ[m+2*p+3,0]

9:  ∫(((g x))^n) (((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ m-p==0 ∧ b d+a e==0 ∧ c d+b e==0

Derivation: Piecewise constant extraction

Basis: If  b d+a e==0 ∧ c d+b e==0, then (∂_x)(((((d+e x))^p) (((a+b x+c (x^2)))^p))/(((a d+c e (x^3)))^p))==0

Rule 1.2.1.4.9: If  m-p==0 ∧ b d+a e==0 ∧ c d+b e==0, then

∫(((g x))^n) (((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  (((((d+e x))^(FracPart[p])) (((a+b x+c (x^2)))^(FracPart[p])))/(((a d+c e (x^3)))^(FracPart[p])))∫(((g x))^n) (((a d+c e (x^3)))^p)dx

Program code:

Int[(g_.*x_)^n_*(d_.+e_.*x_)^m_*(a_+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^FracPart[p]*(a+b*x+c*x^2)^FracPart[p]/(a*d+c*e*x^3)^FracPart[p]*Int[(g*x)^n*(a*d+c*e*x^3)^p,x] /;
FreeQ[{a,b,c,d,e,g,m,n,p},x] && EqQ[m-p,0] && EqQ[b*d+a*e,0] && EqQ[c*d+b*e,0]

10.  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ (n^2)==(1/4) ∧ (p^2)==(1/4)

1.  ∫(((d+e x))^m) (((f+g x))^n) (Sqrt[a+b x+c (x^2)])dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ (n^2)==(1/4)

1.  ∫(((d+e x))^m) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ

1:  ∫(((d+e x))^m) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m<-1

Derivation: Integration by parts

Basis: (∂_x)((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)]))==((b f+a g+2 (c f+b g) x+3 c g (x^2))/(2 (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))

Rule 1.2.1.4.10.1.1.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m<-1, then

∫(((d+e x))^m) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])dx  ⟶  

(((((d+e x))^(m+1)) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)]))/(e (m+1)))-(1/(2 e (m+1)))∫(((((d+e x))^(m+1)) (b f+a g+2 (c f+b g) x+3 c g (x^2)))/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx

Program code:

Int[(d_.+e_.*x_)^m_.*Sqrt[f_.+g_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
  (d+e*x)^(m+1)*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]/(e*(m+1)) - 
  1/(2*e*(m+1))*Int[(d+e*x)^(m+1)/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2])*Simp[b*f+a*g+2*(c*f+b*g)*x+3*c*g*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[2*m] && LtQ[m,-1]

Int[(d_.+e_.*x_)^m_.*Sqrt[f_.+g_.*x_]*Sqrt[a_+c_.*x_^2],x_Symbol] :=
  (d+e*x)^(m+1)*Sqrt[f+g*x]*Sqrt[a+c*x^2]/(e*(m+1)) - 
  1/(2*e*(m+1))*Int[(d+e*x)^(m+1)/(Sqrt[f+g*x]*Sqrt[a+c*x^2])*Simp[a*g+2*c*f*x+3*c*g*x^2,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegerQ[2*m] && LtQ[m,-1]

2:  ∫(((d+e x))^m) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m≮-1

Rule 1.2.1.4.10.1.1.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m≮-1, then

∫(((d+e x))^m) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])dx  ⟶  

((2 (((d+e x))^(m+1)) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)]))/(e (2 m+5)))-(1/(e (2 m+5)))∫(((((d+e x))^m) (b d f-3 a e f+a d g+2 (c d f-b e f+b d g-a e g) x-(c e f-3 c d g+b e g) (x^2)))/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx

Program code:

Int[(d_.+e_.*x_)^m_.*Sqrt[f_.+g_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
  2*(d+e*x)^(m+1)*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]/(e*(2*m+5)) - 
  1/(e*(2*m+5))*Int[(d+e*x)^m/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2])*
    Simp[b*d*f-3*a*e*f+a*d*g+2*(c*d*f-b*e*f+b*d*g-a*e*g)*x-(c*e*f-3*c*d*g+b*e*g)*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,g,m},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[2*m] && Not[LtQ[m,-1]]

Int[(d_.+e_.*x_)^m_.*Sqrt[f_.+g_.*x_]*Sqrt[a_+c_.*x_^2],x_Symbol] :=
  2*(d+e*x)^(m+1)*Sqrt[f+g*x]*Sqrt[a+c*x^2]/(e*(2*m+5)) + 
  1/(e*(2*m+5))*Int[(d+e*x)^m/(Sqrt[f+g*x]*Sqrt[a+c*x^2])*
    Simp[3*a*e*f-a*d*g-2*(c*d*f-a*e*g)*x+(c*e*f-3*c*d*g)*x^2,x],x] /;
FreeQ[{a,c,d,e,f,g,m},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegerQ[2*m] && Not[LtQ[m,-1]]

2.  ∫(((((d+e x))^m) (Sqrt[a+b x+c (x^2)]))/(Sqrt[f+g x]))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ

1:  ∫(((((d+e x))^m) (Sqrt[a+b x+c (x^2)]))/(Sqrt[f+g x]))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m>0

Rule 1.2.1.4.10.1.2.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m>0, then

∫(((((d+e x))^m) (Sqrt[a+b x+c (x^2)]))/(Sqrt[f+g x]))dx  ⟶  

((2 (((d+e x))^m) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)]))/(g (2 m+3)))-(1/(g (2 m+3)))∫((((d+e x))^(m-1))/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))·
(b d f+2 a (e f m-d g (m+1))+(2 c d f-2 a e g+b (e f-d g) (2 m+1)) x-(b e g+2 c (d g m-e f (m+1))) (x^2))dx

Program code:

Int[(d_.+e_.*x_)^m_.*Sqrt[a_.+b_.*x_+c_.*x_^2]/Sqrt[f_.+g_.*x_],x_Symbol] :=
  2*(d+e*x)^m*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]/(g*(2*m+3)) - 
  1/(g*(2*m+3))*Int[(d+e*x)^(m-1)/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2])*
    Simp[b*d*f+2*a*(e*f*m-d*g*(m+1))+(2*c*d*f-2*a*e*g+b*(e*f-d*g)*(2*m+1))*x-(b*e*g+2*c*(d*g*m-e*f*(m+1)))*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[2*m] && GtQ[m,0]

Int[(d_.+e_.*x_)^m_.*Sqrt[a_+c_.*x_^2]/Sqrt[f_.+g_.*x_],x_Symbol] :=
  2*(d+e*x)^m*Sqrt[f+g*x]*Sqrt[a+c*x^2]/(g*(2*m+3)) - 
  1/(g*(2*m+3))*Int[(d+e*x)^(m-1)/(Sqrt[f+g*x]*Sqrt[a+c*x^2])*
    Simp[2*a*(e*f*m-d*g*(m+1))+(2*c*d*f-2*a*e*g)*x-(2*c*(d*g*m-e*f*(m+1)))*x^2,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegerQ[2*m] && GtQ[m,0]

2.  ∫(((((d+e x))^m) (Sqrt[a+b x+c (x^2)]))/(Sqrt[f+g x]))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m<0

1:  ∫((Sqrt[a+b x+c (x^2)])/((d+e x) (Sqrt[f+g x])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Algebraic expansion

Basis: ((Sqrt[a+b x+c (x^2)])/(d+e x))==((c (d^2)-b d e+a (e^2))/((e^2) (d+e x) (Sqrt[a+b x+c (x^2)])))-((c d-b e-c e x)/((e^2) (Sqrt[a+b x+c (x^2)])))

Rule 1.2.1.4.10.1.2.2.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫((Sqrt[a+b x+c (x^2)])/((d+e x) (Sqrt[f+g x])))dx  ⟶  ((c (d^2)-b d e+a (e^2))/(e^2)) ∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx-(1/(e^2)) ∫((c d-b e-c e x)/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx

Program code:

Int[Sqrt[a_.+b_.*x_+c_.*x_^2]/((d_.+e_.*x_)*Sqrt[f_.+g_.*x_]),x_Symbol] :=
  (c*d^2-b*d*e+a*e^2)/e^2*Int[1/((d+e*x)*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]),x] - 
  1/e^2*Int[(c*d-b*e-c*e*x)/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[Sqrt[a_+c_.*x_^2]/((d_.+e_.*x_)*Sqrt[f_.+g_.*x_]),x_Symbol] :=
  (c*d^2+a*e^2)/e^2*Int[1/((d+e*x)*Sqrt[f+g*x]*Sqrt[a+c*x^2]),x] - 
  1/e^2*Int[(c*d-c*e*x)/(Sqrt[f+g*x]*Sqrt[a+c*x^2]),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0]

2:  ∫(((((d+e x))^m) (Sqrt[a+b x+c (x^2)]))/(Sqrt[f+g x]))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m<-1

Rule 1.2.1.4.10.1.2.2.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m<-1, then

∫(((((d+e x))^m) (Sqrt[a+b x+c (x^2)]))/(Sqrt[f+g x]))dx  ⟶  

(((((d+e x))^(m+1)) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)]))/((m+1) (e f-d g)))-(1/(2 (m+1) (e f-d g)))∫(((((d+e x))^(m+1)) (b f+a g (2 m+3)+2 (c f+b g (m+2)) x+c g (2 m+5) (x^2)))/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx

Program code:

Int[(d_.+e_.*x_)^m_.*Sqrt[a_.+b_.*x_+c_.*x_^2]/Sqrt[f_.+g_.*x_],x_Symbol] :=
  (d+e*x)^(m+1)*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]/((m+1)*(e*f-d*g)) - 
  1/(2*(m+1)*(e*f-d*g))*Int[(d+e*x)^(m+1)/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2])*
    Simp[b*f+a*g*(2*m+3)+2*(c*f+b*g*(m+2))*x+c*g*(2*m+5)*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[2*m] && LtQ[m,-1]

Int[(d_.+e_.*x_)^m_.*Sqrt[a_+c_.*x_^2]/Sqrt[f_.+g_.*x_],x_Symbol] :=
  (d+e*x)^(m+1)*Sqrt[f+g*x]*Sqrt[a+c*x^2]/((m+1)*(e*f-d*g)) - 
  1/(2*(m+1)*(e*f-d*g))*Int[(d+e*x)^(m+1)/(Sqrt[f+g*x]*Sqrt[a+c*x^2])*
    Simp[a*g*(2*m+3)+2*(c*f)*x+c*g*(2*m+5)*x^2,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegerQ[2*m] && LtQ[m,-1]

2.  ∫(((((d+e x))^m) (((f+g x))^n))/(Sqrt[a+b x+c (x^2)]))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ (n^2)==(1/4)

1.  ∫((((d+e x))^m)/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ

1.  ∫((((d+e x))^m)/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m>0

1:  ∫((Sqrt[d+e x])/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Piecewise constant extraction and integration by substitution

Rule 1.2.1.4.10.2.1.1.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, let q->(Sqrt[(b^2)-4 a c]), then

∫((Sqrt[d+e x])/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  ⟶  

(((Sqrt[2])(Sqrt[2 c f-g  (b+q)]) (Sqrt[b-q+2 c x]) (d+e x) (Sqrt[(((e f-d g) (b+q+2 c x))/((2 c f-g (b+q)) (d+e x)))]) (Sqrt[(((e f-d g) (2 a+(b+q) x))/((b f+q f-2 a g) (d+e x)))]))/(g (Sqrt[2 c d-e(b+q)]) (Sqrt[((2 a c)/(b+q))+c x]) (Sqrt[a+b x+c (x^2)])))·
EllipticPi[((e (2 c f-g (b+q)))/(g (2 c d-e (b+q)))),ArcSin[(((Sqrt[2 c d-e (b+q)]) (Sqrt[f+g x]))/((Sqrt[2 c f-g (b+q)]) (Sqrt[d+e x])))],(((b d+q d-2 a e) (2 c f-g (b+q)))/((b f+q f-2 a g) (2 c d-e (b+q))))]

Program code:

Int[Sqrt[d_.+e_.*x_]/(Sqrt[f_.+g_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  Sqrt[2]*Sqrt[2*c*f-g*(b+q)]*Sqrt[b-q+2*c*x]*(d+e*x)*
    Sqrt[(e*f-d*g)*(b+q+2*c*x)/((2*c*f-g*(b+q))*(d+e*x))]*
    Sqrt[(e*f-d*g)*(2*a+(b+q)*x)/((b*f+q*f-2*a*g)*(d+e*x))]/
   (g*Sqrt[2*c*d-e*(b+q)]*Sqrt[2*a*c/(b+q)+c*x]*Sqrt[a+b*x+c*x^2])*
    EllipticPi[e*(2*c*f-g*(b+q))/(g*(2*c*d-e*(b+q))),
      ArcSin[Sqrt[2*c*d-e*(b+q)]*Sqrt[f+g*x]/(Sqrt[2*c*f-g*(b+q)]*Sqrt[d+e*x])],
      (b*d+q*d-2*a*e)*(2*c*f-g*(b+q))/((b*f+q*f-2*a*g)*(2*c*d-e*(b+q)))]] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[Sqrt[d_.+e_.*x_]/(Sqrt[f_.+g_.*x_]*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  With[{q=Rt[-4*a*c,2]},
  Sqrt[2]*Sqrt[2*c*f-g*q]*Sqrt[-q+2*c*x]*(d+e*x)*
    Sqrt[(e*f-d*g)*(q+2*c*x)/((2*c*f-g*q)*(d+e*x))]*
    Sqrt[(e*f-d*g)*(2*a+q*x)/((q*f-2*a*g)*(d+e*x))]/
   (g*Sqrt[2*c*d-e*q]*Sqrt[2*a*c/q+c*x]*Sqrt[a+c*x^2])*
    EllipticPi[e*(2*c*f-g*q)/(g*(2*c*d-e*q)),
      ArcSin[Sqrt[2*c*d-e*q]*Sqrt[f+g*x]/(Sqrt[2*c*f-g*q]*Sqrt[d+e*x])],
      (q*d-2*a*e)*(2*c*f-g*q)/((q*f-2*a*g)*(2*c*d-e*q))]] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0]

2:  ∫((((d+e x))^(3/2))/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Algebraic expansion

Basis: ((((d+e x))^(3/2))/(Sqrt[f+g x]))==((e (Sqrt[d+e x]) (Sqrt[f+g x]))/g)-(((e f-d g) (Sqrt[d+e x]))/(g (Sqrt[f+g x])))

Rule 1.2.1.4.10.2.1.1.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫((((d+e x))^(3/2))/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  ⟶  (e/g) ∫(((Sqrt[d+e x]) (Sqrt[f+g x]))/(Sqrt[a+b x+c (x^2)]))dx-(((e f-d g) )/g) ∫((Sqrt[d+e x])/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx

Program code:

Int[(d_.+e_.*x_)^(3/2)/(Sqrt[f_.+g_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  e/g*Int[Sqrt[d+e*x]*Sqrt[f+g*x]/Sqrt[a+b*x+c*x^2],x] - 
  (e*f-d*g)/g*Int[Sqrt[d+e*x]/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[(d_.+e_.*x_)^(3/2)/(Sqrt[f_.+g_.*x_]*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  e/g*Int[Sqrt[d+e*x]*Sqrt[f+g*x]/Sqrt[a+c*x^2],x] - 
  (e*f-d*g)/g*Int[Sqrt[d+e*x]/(Sqrt[f+g*x]*Sqrt[a+c*x^2]),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0]

3:  ∫((((d+e x))^m)/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m≥2

Rule 1.2.1.4.10.2.1.1.3: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m≥2, then

∫((((d+e x))^m)/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  ⟶  

((2 (e^2) (((d+e x))^(m-2)) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)]))/(c g (2 m-1)))-
(1/(c g (2 m-1)))∫((((d+e x))^(m-3))/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))·
(b d (e^2) f+a (e^2) (d g+2 e f (m-2))-c (d^3) g (2 m-1)+e (e (2 b d g+e (b f+a g) (2 m-3))+c d (2 e f-3 d g (2 m-1))) x+2 (e^2) (c e f-3 c d g+b e g) (m-1) (x^2))dx

Program code:

Int[(d_.+e_.*x_)^m_/(Sqrt[f_.+g_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  2*e^2*(d+e*x)^(m-2)*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]/(c*g*(2*m-1)) - 
  1/(c*g*(2*m-1))*Int[(d+e*x)^(m-3)/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2])*
    Simp[b*d*e^2*f+a*e^2*(d*g+2*e*f*(m-2))-c*d^3*g*(2*m-1)+
      e*(e*(2*b*d*g+e*(b*f+a*g)*(2*m-3))+c*d*(2*e*f-3*d*g*(2*m-1)))*x+
      2*e^2*(c*e*f-3*c*d*g+b*e*g)*(m-1)*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[2*m] && GeQ[m,2]

Int[(d_.+e_.*x_)^m_/(Sqrt[f_.+g_.*x_]*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  2*e^2*(d+e*x)^(m-2)*Sqrt[f+g*x]*Sqrt[a+c*x^2]/(c*g*(2*m-1)) - 
  1/(c*g*(2*m-1))*Int[(d+e*x)^(m-3)/(Sqrt[f+g*x]*Sqrt[a+c*x^2])*
    Simp[a*e^2*(d*g+2*e*f*(m-2))-c*d^3*g*(2*m-1)+e*(e*(a*e*g*(2*m-3))+c*d*(2*e*f-3*d*g*(2*m-1)))*x+2*e^2*(c*e*f-3*c*d*g)*(m-1)*x^2,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegerQ[2*m] && GeQ[m,2]

2.  ∫((((d+e x))^m)/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m<0

1.  ∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1.  ∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[a+c (x^2)])))dx  when e f-d g≠0 ∧ c (d^2)+a (e^2)≠0

1:  ∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[a+c (x^2)])))dx  when e f-d g≠0 ∧ c (d^2)+a (e^2)≠0 ∧ a>0

Derivation: Algebraic expansion

Basis: If  a>0, let q->(Sqrt[-(c/a)]), then (Sqrt[a+c (x^2)])==(Sqrt[a]) (Sqrt[1-q x]) (Sqrt[1+q x])

Rule 1.2.1.4.10.2.1.2.1.1.1: If  e f-d g≠0 ∧ c (d^2)+a (e^2)≠0 ∧ a>0, let q->(Sqrt[-(c/a)]), then

∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[a+c (x^2)])))dx  ⟶  (1/(Sqrt[a]))∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[1-q x]) (Sqrt[1+q x])))dx

Program code:

Int[1/((d_.+e_.*x_)*Sqrt[f_.+g_.*x_]*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  With[{q=Rt[-c/a,2]},
  1/Sqrt[a]*Int[1/((d+e*x)*Sqrt[f+g*x]*Sqrt[1-q*x]*Sqrt[1+q*x]),x]] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && GtQ[a,0]

2:  ∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[a+c (x^2)])))dx  when e f-d g≠0 ∧ c (d^2)+a (e^2)≠0 ∧ a≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[1+((c (x^2))/a)])/(Sqrt[a+c (x^2)]))==0

Basis: Let q->(Sqrt[-(c/a)]), then (Sqrt[1+((c (x^2))/a)])==(Sqrt[1-q x]) (Sqrt[1+q x])

Rule 1.2.1.4.10.2.1.2.1.1.2: If  e f-d g≠0 ∧ c (d^2)+a (e^2)≠0 ∧ a≯0, let q->(Sqrt[-(c/a)]), then

∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[a+c (x^2)])))dx  ⟶  ((Sqrt[1+((c (x^2))/a)])/(Sqrt[a+c (x^2)]))∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[1-q x]) (Sqrt[1+q x])))dx

Program code:

Int[1/((d_.+e_.*x_)*Sqrt[f_.+g_.*x_]*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  With[{q=Rt[-c/a,2]},
  Sqrt[1+c*x^2/a]/Sqrt[a+c*x^2]*Int[1/((d+e*x)*Sqrt[f+g*x]*Sqrt[1-q*x]*Sqrt[1+q*x]),x]] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && Not[GtQ[a,0]]

2:  ∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Piecewise constant extraction

Basis: Let q->(Sqrt[(b^2)-4 a c]), then (∂_x)(((Sqrt[b-q+2 c x]) (Sqrt[b+q+2 c x]))/(Sqrt[a+b x+c (x^2)]))==0

Rule 1.2.1.4.10.2.1.2.1.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, let q->(Sqrt[(b^2)-4 a c]), then

∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  ⟶  (((Sqrt[b-q+2 c x]) (Sqrt[b+q+2 c x]))/(Sqrt[a+b x+c (x^2)]))∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[b-q+2 c x]) (Sqrt[b+q+2 c x])))dx

Program code:

Int[1/((d_.+e_.*x_)*Sqrt[f_.+g_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  Sqrt[b-q+2*c*x]*Sqrt[b+q+2*c*x]/Sqrt[a+b*x+c*x^2]*Int[1/((d+e*x)*Sqrt[f+g*x]*Sqrt[b-q+2*c*x]*Sqrt[b+q+2*c*x]),x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

2:  ∫(1/((Sqrt[d+e x]) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(((d+e x) (Sqrt[(((((e f-d g))^2) (a+b x+c (x^2)))/((c (f^2)-b f g+a (g^2)) (((d+e x))^2)))]))/(Sqrt[a+b x+c (x^2)]))==0

Basis: (1/((((d+e x))^(3/2)) (Sqrt[f+g x]) (Sqrt[(((((e f-d g))^2) (a+b x+c (x^2)))/((c (f^2)-b f g+a (g^2)) (((d+e x))^2)))])))==-(2/(e f-d g)) Subst[(1/(Sqrt[1-(((2 c d f-b e f-b d g+2 a e g) (x^2))/(c (f^2)-b f g+a (g^2)))+(((c (d^2)-b d e+a (e^2)) (x^4))/(c (f^2)-b f g+a (g^2)))])),x,((Sqrt[f+g x])/(Sqrt[d+e x]))] (∂_x)((Sqrt[f+g x])/(Sqrt[d+e x]))

Rule 1.2.1.4.10.2.1.2.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫(1/((Sqrt[d+e x]) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  ⟶  (((d+e x) (Sqrt[(((((e f-d g))^2) (a+b x+c (x^2)))/((c (f^2)-b f g+a (g^2)) (((d+e x))^2)))]))/(Sqrt[a+b x+c (x^2)])) ∫(1/((((d+e x))^(3/2)) (Sqrt[f+g x]) (Sqrt[(((((e f-d g))^2) (a+b x+c (x^2)))/((c (f^2)-b f g+a (g^2)) (((d+e x))^2)))])))dx
  ⟶  -((2 (d+e x) (Sqrt[(((((e f-d g))^2) (a+b x+c (x^2)))/((c (f^2)-b f g+a (g^2)) (((d+e x))^2)))]))/((e f-d g) (Sqrt[a+b x+c (x^2)]))) Subst[∫(1/(Sqrt[1-(((2 c d f-b e f-b d g+2 a e g) (x^2))/(c (f^2)-b f g+a (g^2)))+(((c (d^2)-b d e+a (e^2)) (x^4))/(c (f^2)-b f g+a (g^2)))]))dx,x,((Sqrt[f+g x])/(Sqrt[d+e x]))]

Program code:

Int[1/(Sqrt[d_.+e_.*x_]*Sqrt[f_.+g_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  -2*(d+e*x)*Sqrt[(e*f-d*g)^2*(a+b*x+c*x^2)/((c*f^2-b*f*g+a*g^2)*(d+e*x)^2)]/((e*f-d*g)*Sqrt[a+b*x+c*x^2])*
  Subst[
    Int[1/Sqrt[1-(2*c*d*f-b*e*f-b*d*g+2*a*e*g)*x^2/(c*f^2-b*f*g+a*g^2)+(c*d^2-b*d*e+a*e^2)*x^4/(c*f^2-b*f*g+a*g^2)],x],
    x,
    Sqrt[f+g*x]/Sqrt[d+e*x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[1/(Sqrt[d_.+e_.*x_]*Sqrt[f_.+g_.*x_]*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  -2*(d+e*x)*Sqrt[(e*f-d*g)^2*(a+c*x^2)/((c*f^2+a*g^2)*(d+e*x)^2)]/((e*f-d*g)*Sqrt[a+c*x^2])*
  Subst[
    Int[1/Sqrt[1-(2*c*d*f+2*a*e*g)*x^2/(c*f^2+a*g^2)+(c*d^2+a*e^2)*x^4/(c*f^2+a*g^2)],x],x,Sqrt[f+g*x]/Sqrt[d+e*x]] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0]

3:  ∫(1/((((d+e x))^(3/2)) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Algebraic expansion

Basis: (1/((((d+e x))^(3/2)) (Sqrt[f+g x])))==-(g/((e f-d g) (Sqrt[d+e x]) (Sqrt[f+g x])))+((e (Sqrt[f+g x]))/((e f-d g) (((d+e x))^(3/2))))

Rule 1.2.1.4.10.2.1.2.3: If    when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫(1/((((d+e x))^(3/2)) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  ⟶  

-(g/(e f-d g)) ∫(1/((Sqrt[d+e x]) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx+(e/(e f-d g)) ∫((Sqrt[f+g x])/((((d+e x))^(3/2)) (Sqrt[a+b x+c (x^2)])))dx

Program code:

Int[1/((d_.+e_.*x_)^(3/2)*Sqrt[f_.+g_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  -g/(e*f-d*g)*Int[1/(Sqrt[d+e*x]*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]),x] + 
  e/(e*f-d*g)*Int[Sqrt[f+g*x]/((d+e*x)^(3/2)*Sqrt[a+b*x+c*x^2]),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[1/((d_.+e_.*x_)^(3/2)*Sqrt[f_.+g_.*x_]*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  -g/(e*f-d*g)*Int[1/(Sqrt[d+e*x]*Sqrt[f+g*x]*Sqrt[a+c*x^2]),x] + 
  e/(e*f-d*g)*Int[Sqrt[f+g*x]/((d+e*x)^(3/2)*Sqrt[a+c*x^2]),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0]

4:  ∫((((d+e x))^m)/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m≤-2

Rule 1.2.1.4.10.2.1.2.4: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m≤-2, then

∫((((d+e x))^m)/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx  ⟶  

(((e^2) (((d+e x))^(m+1)) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)]))/((m+1) (e f-d g) (c (d^2)-b d e+a (e^2))))+
(1/(2 (m+1) (e f-d g) (c (d^2)-b d e+a (e^2))))∫((((d+e x))^(m+1))/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))·
 (2 d (c e f-c d g+b e g) (m+1)-(e^2) (b f+a g) (2 m+3)+2 e (c d g (m+1)-e (c f+b g) (m+2)) x-c (e^2) g (2 m+5) (x^2))dx

Program code:

Int[(d_.+e_.*x_)^m_/(Sqrt[f_.+g_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  e^2*(d+e*x)^(m+1)*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]/((m+1)*(e*f-d*g)*(c*d^2-b*d*e+a*e^2)) + 
  1/(2*(m+1)*(e*f-d*g)*(c*d^2-b*d*e+a*e^2))*Int[(d+e*x)^(m+1)/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2])*
    Simp[2*d*(c*e*f-c*d*g+b*e*g)*(m+1)-e^2*(b*f+a*g)*(2*m+3)+2*e*(c*d*g*(m+1)-e*(c*f+b*g)*(m+2))*x-c*e^2*g*(2*m+5)*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[2*m] && LeQ[m,-2]

Int[(d_.+e_.*x_)^m_/(Sqrt[f_.+g_.*x_]*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  e^2*(d+e*x)^(m+1)*Sqrt[f+g*x]*Sqrt[a+c*x^2]/((m+1)*(e*f-d*g)*(c*d^2+a*e^2)) + 
  1/(2*(m+1)*(e*f-d*g)*(c*d^2+a*e^2))*Int[(d+e*x)^(m+1)/(Sqrt[f+g*x]*Sqrt[a+c*x^2])*
    Simp[2*d*(c*e*f-c*d*g)*(m+1)-a*e^2*g*(2*m+3)+2*e*(c*d*g*(m+1)-c*e*f*(m+2))*x-c*e^2*g*(2*m+5)*x^2,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegerQ[2*m] && LeQ[m,-2]

2.  ∫(((((d+e x))^m) (Sqrt[f+g x]))/(Sqrt[a+b x+c (x^2)]))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ

1.  ∫(((((d+e x))^m) (Sqrt[f+g x]))/(Sqrt[a+b x+c (x^2)]))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m>0

x:  ∫(((Sqrt[d+e x]) (Sqrt[f+g x]))/(Sqrt[a+b x+c (x^2)]))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Algebraic expansion

Rule 1.2.1.4.10.2.2.1.x: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫(((Sqrt[d+e x]) (Sqrt[f+g x]))/(Sqrt[a+b x+c (x^2)]))dx  ⟶  

(((Sqrt[a+b x]) (Sqrt[c+d x]) (Sqrt[g+h x]))/(h (Sqrt[e+f x])))+(((d e-c f) (b f g+b e h-2 a f h))/(2 (f^2) h)) ∫(1/((Sqrt[a+b x]) (Sqrt[c+d x]) (Sqrt[e+f x]) (Sqrt[g+h x])))dx+
(((a d f h-b (d f g+d e h-c f h)))/(2 (f^2) h)) ∫((Sqrt[e+f x])/((Sqrt[a+b x]) (Sqrt[c+d x]) (Sqrt[g+h x])))dx-(((d e-c f) (f g-e h) )/(2 f h)) ∫((Sqrt[a+b x])/((Sqrt[c+d x]) (((e+f x))^(3/2)) (Sqrt[g+h x])))dx

Program code:

(* Int[Sqrt[d_.+e_.*x_]*Sqrt[f_.+g_.*x_]/Sqrt[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
  0 /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] *)

2:  ∫(((((d+e x))^m) (Sqrt[f+g x]))/(Sqrt[a+b x+c (x^2)]))dx  when  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m>1

Rule 1.2.1.4.10.2.2.1.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m>1, then

∫(((((d+e x))^m) (Sqrt[f+g x]))/(Sqrt[a+b x+c (x^2)]))dx  ⟶  

((2 e (((d+e x))^(m-1)) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)]))/(c (2 m+1)))-(1/(c (2 m+1)))∫((((d+e x))^(m-2))/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))·
(e (b d f+a (d g+2 e f (m-1)))-c (d^2) f (2 m+1)+(a (e^2) g (2 m-1)-c d (4 e f m+d g (2 m+1))+b e (2 d g+e f (2 m-1))) x+e (2 b e g m-c (e f+d g (4 m-1))) (x^2))dx

Program code:

Int[(d_.+e_.*x_)^m_*Sqrt[f_.+g_.*x_]/Sqrt[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
  2*e*(d+e*x)^(m-1)*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]/(c*(2*m+1)) - 
  1/(c*(2*m+1))*Int[(d+e*x)^(m-2)/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2])*
    Simp[e*(b*d*f+a*(d*g+2*e*f*(m-1)))-c*d^2*f*(2*m+1)+
      (a*e^2*g*(2*m-1)-c*d*(4*e*f*m+d*g*(2*m+1))+b*e*(2*d*g+e*f*(2*m-1)))*x+
      e*(2*b*e*g*m-c*(e*f+d*g*(4*m-1)))*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[2*m] && GtQ[m,1]

Int[(d_.+e_.*x_)^m_*Sqrt[f_.+g_.*x_]/Sqrt[a_+c_.*x_^2],x_Symbol] :=
  2*e*(d+e*x)^(m-1)*Sqrt[f+g*x]*Sqrt[a+c*x^2]/(c*(2*m+1)) - 
  1/(c*(2*m+1))*Int[(d+e*x)^(m-2)/(Sqrt[f+g*x]*Sqrt[a+c*x^2])*
    Simp[a*e*(d*g+2*e*f*(m-1))-c*d^2*f*(2*m+1)+(a*e^2*g*(2*m-1)-c*d*(4*e*f*m+d*g*(2*m+1)))*x-c*e*(e*f+d*g*(4*m-1))*x^2,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegerQ[2*m] && GtQ[m,1]

2.  ∫(((((d+e x))^m) (Sqrt[f+g x]))/(Sqrt[a+b x+c (x^2)]))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m<0

1:  ∫((Sqrt[f+g x])/((d+e x) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Algebraic expansion

Basis: ((Sqrt[f+g x])/(d+e x))==(g/(e (Sqrt[f+g x])))+((e f-d g)/(e (d+e x) (Sqrt[f+g x])))

Rule 1.2.1.4.10.2.2.2.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫((Sqrt[f+g x])/((d+e x) (Sqrt[a+b x+c (x^2)])))dx  ⟶  (g/e) ∫(1/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx+(((e f-d g) )/e) ∫(1/((d+e x) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))dx

Program code:

Int[Sqrt[f_.+g_.*x_]/((d_.+e_.*x_)*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  g/e*Int[1/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]),x] + 
  (e*f-d*g)/e*Int[1/((d+e*x)*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[Sqrt[f_.+g_.*x_]/((d_.+e_.*x_)*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  g/e*Int[1/(Sqrt[f+g*x]*Sqrt[a+c*x^2]),x] + 
  (e*f-d*g)/e*Int[1/((d+e*x)*Sqrt[f+g*x]*Sqrt[a+c*x^2]),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0]

x:  ∫((Sqrt[f+g x])/((((d+e x))^(3/2)) (Sqrt[a+b x+c (x^2)])))dx

3:  ∫(((((d+e x))^m) (Sqrt[f+g x]))/(Sqrt[a+b x+c (x^2)]))dx  when  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m≤-2

Rule 1.2.1.4.10.2.2.2.3: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 m∈ℤ ∧ m≤-2, then

∫(((((d+e x))^m) (Sqrt[f+g x]))/(Sqrt[a+b x+c (x^2)]))dx  ⟶  

((e (((d+e x))^(m+1)) (Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)]))/((m+1)(c (d^2)-b d e+a (e^2))))+(1/(2 (m+1)(c (d^2)-b d e+a (e^2))))∫((((d+e x))^(m+1))/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)])))·
(2 c d f (m+1)-e (a g+b f (2 m+3))-2 (b e g (2+m)-c (d g (m+1)-e f (m+2))) x-c e g (2 m+5) (x^2))dx

Program code:

Int[(d_.+e_.*x_)^m_*Sqrt[f_.+g_.*x_]/Sqrt[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
  e*(d+e*x)^(m+1)*Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]/((m+1)*(c*d^2-b*d*e+a*e^2)) + 
  1/(2*(m+1)*(c*d^2-b*d*e+a*e^2))*Int[(d+e*x)^(m+1)/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2])*
    Simp[2*c*d*f*(m+1)-e*(a*g+b*f*(2*m+3))-2*(b*e*g*(2+m)-c*(d*g*(m+1)-e*f*(m+2)))*x-c*e*g*(2*m+5)*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[2*m] && LeQ[m,-2]

Int[(d_.+e_.*x_)^m_*Sqrt[f_.+g_.*x_]/Sqrt[a_+c_.*x_^2],x_Symbol] :=
  e*(d+e*x)^(m+1)*Sqrt[f+g*x]*Sqrt[a+c*x^2]/((m+1)*(c*d^2+a*e^2)) + 
  1/(2*(m+1)*(c*d^2+a*e^2))*Int[(d+e*x)^(m+1)/(Sqrt[f+g*x]*Sqrt[a+c*x^2])*
    Simp[2*c*d*f*(m+1)-e*(a*g)+2*c*(d*g*(m+1)-e*f*(m+2))*x-c*e*g*(2*m+5)*x^2,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegerQ[2*m] && LeQ[m,-2]

11.  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])

1:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ]) ∧ m∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.1.4.11.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ]) ∧ m∈(SuperPlus[ℤ]), then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  ∫ExpandIntegrand[(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p),x]dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^n*(a+b*x+c*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[p,0] && 
  (IGtQ[m,0] || EqQ[m,-2] && EqQ[p,1] && EqQ[2*c*d-b*e,0])

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^n*(a+c*x^2)^p,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IGtQ[p,0] && 
  (IGtQ[m,0] || EqQ[m,-2] && EqQ[p,1] && EqQ[d,0])

2:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ m<-1

Derivation: Algebraic expansion and linear recurrence 3

Basis: Let Q[x]->PolynomialQuotient[(((a+b x+c (x^2)))^p),d+e x,x]and R->PolynomialRemainder[(((a+b x+c (x^2)))^p),d+e x,x], 
				then (((a+b x+c (x^2)))^p)==Q[x] (d+e x)+R

Note: If  m∈(SuperMinus[ℤ]), incrementing m rather than n produces simpler antiderivatives.

Rule 1.2.1.4.11.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ m<-1, 
		let Q[x]->PolynomialQuotient[(((a+b x+c (x^2)))^p),d+e x,x]and R->PolynomialRemainder[(((a+b x+c (x^2)))^p),d+e x,x], then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  

∫Q[x] (((d+e x))^(m+1)) (((f+g x))^n)dx+R ∫(((d+e x))^m) (((f+g x))^n)dx  ⟶  

((R (((d+e x))^(m+1)) (((f+g x))^(n+1)))/((m+1) (e f-d g)))+(1/((m+1) (e f-d g))) ∫(((d+e x))^(m+1)) (((f+g x))^n)((m+1) (e f-d g)Q[x]-g R (m+n+2))dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  With[{Qx=PolynomialQuotient[(a+b*x+c*x^2)^p,d+e*x,x],R=PolynomialRemainder[(a+b*x+c*x^2)^p,d+e*x,x]},
  R*(d+e*x)^(m+1)*(f+g*x)^(n+1)/((m+1)*(e*f-d*g)) + 
  1/((m+1)*(e*f-d*g))*Int[(d+e*x)^(m+1)*(f+g*x)^n*ExpandToSum[(m+1)*(e*f-d*g)*Qx-g*R*(m+n+2),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[p,0] && LtQ[m,-1]

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_.,x_Symbol] :=
  With[{Qx=PolynomialQuotient[(a+c*x^2)^p,d+e*x,x],R=PolynomialRemainder[(a+c*x^2)^p,d+e*x,x]},
  R*(d+e*x)^(m+1)*(f+g*x)^(n+1)/((m+1)*(e*f-d*g)) + 
  1/((m+1)*(e*f-d*g))*Int[(d+e*x)^(m+1)*(f+g*x)^n*ExpandToSum[(m+1)*(e*f-d*g)*Qx-g*R*(m+n+2),x],x]] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IGtQ[p,0] && LtQ[m,-1]

3:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ m+n+2 p+1≠0

Derivation: Algebraic expansion and linear recurrence 2

Rule 1.2.1.4.11.3: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ m+n+2 p+1≠0, then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  

(1/(e^(2 p))) ∫((e^(2 p)) (((a+b x+c (x^2)))^p)-(c^p) (((d+e x))^(2 p))) (((d+e x))^m) (((f+g x))^n)dx+((c^p)/(e^(2 p))) ∫(((d+e x))^(m+2 p)) (((f+g x))^n)dx  ⟶  

(((c^p) (((d+e x))^(m+2 p)) (((f+g x))^(n+1)))/(g (e^(2 p)) (m+n+2 p+1)))+(1/(g (e^(2 p)) (m+n+2 p+1))) ∫(((d+e x))^m) (((f+g x))^n)·
(g (m+n+2 p+1) ((e^(2 p)) (((a+b x+c (x^2)))^p)-(c^p) (((d+e x))^(2 p)))-(c^p) (e f-d g) (m+2 p) (((d+e x))^(2 p-1)))dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  c^p*(d+e*x)^(m+2*p)*(f+g*x)^(n+1)/(g*e^(2*p)*(m+n+2*p+1)) + 
  1/(g*e^(2*p)*(m+n+2*p+1))*Int[(d+e*x)^m*(f+g*x)^n*
    ExpandToSum[g*(m+n+2*p+1)*(e^(2*p)*(a+b*x+c*x^2)^p-c^p*(d+e*x)^(2*p))-c^p*(e*f-d*g)*(m+2*p)*(d+e*x)^(2*p-1),x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[p,0] && NeQ[m+n+2*p+1,0] && 
  (IntegerQ[n] || Not[IntegerQ[m]])

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_.,x_Symbol] :=
  c^p*(d+e*x)^(m+2*p)*(f+g*x)^(n+1)/(g*e^(2*p)*(m+n+2*p+1)) + 
  1/(g*e^(2*p)*(m+n+2*p+1))*Int[(d+e*x)^m*(f+g*x)^n*
    ExpandToSum[g*(m+n+2*p+1)*(e^(2*p)*(a+c*x^2)^p-c^p*(d+e*x)^(2*p))-c^p*(e*f-d*g)*(m+2*p)*(d+e*x)^(2*p-1),x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IGtQ[p,0] && NeQ[m+n+2*p+1,0] && 
  (IntegerQ[n] || Not[IntegerQ[m]])

12.  ∫(((((f+g x))^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ n∉ℤ ∧ p∉ℤ

1:  ∫(((((f+g x))^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ n∉ℤ ∧ p∉ℤ ∧ p>0 ∧ n<-1

Reference: Algebraic expansion

Basis: ((a+b x+c (x^2))/(d+e x))==(((c (d^2)-b d e+a (e^2))(f+g x))/(e (e f-d g) (d+e x)))-((c d f-b e f+a e g-c (e f-d g) x)/(e (e f-d g)))

Rule 1.2.1.4.12.1: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ n∉ℤ ∧ p∉ℤ ∧ p>0 ∧ n<-1, then

∫(((((f+g x))^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  ⟶  
((c (d^2)-b d e+a (e^2))/(e (e f-d g)))∫(((((f+g x))^(n+1)) (((a+b x+c (x^2)))^(p-1)))/(d+e x))dx-(1/(e (e f-d g)))∫(((f+g x))^n) (c d f-b e f+a e g-c (e f-d g) x) (((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_/(d_.+e_.*x_),x_Symbol] :=
  (c*d^2-b*d*e+a*e^2)/(e*(e*f-d*g))*Int[(f+g*x)^(n+1)*(a+b*x+c*x^2)^(p-1)/(d+e*x),x] - 
  1/(e*(e*f-d*g))*Int[(f+g*x)^n*(c*d*f-b*e*f+a*e*g-c*(e*f-d*g)*x)*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[n]] && Not[IntegerQ[p]] && GtQ[p,0] && LtQ[n,-1]

Int[(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_/(d_.+e_.*x_),x_Symbol] :=
  (c*d^2+a*e^2)/(e*(e*f-d*g))*Int[(f+g*x)^(n+1)*(a+c*x^2)^(p-1)/(d+e*x),x] - 
  1/(e*(e*f-d*g))*Int[(f+g*x)^n*(c*d*f+a*e*g-c*(e*f-d*g)*x)*(a+c*x^2)^(p-1),x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[n]] && Not[IntegerQ[p]] && GtQ[p,0] && LtQ[n,-1]

2:  ∫(((((f+g x))^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ n∉ℤ ∧ p∉ℤ ∧ p<-1 ∧ n>0

Reference: Algebraic expansion

Basis: ((f+g x)/(d+e x))==((e (e f-d g)(a+b x+c (x^2)))/((c (d^2)-b d e+a (e^2)) (d+e x)))+((c d f-b e f+a e g-c (e f-d g) x)/(c (d^2)-b d e+a (e^2)))

Rule 1.2.1.4.12.2: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ n∉ℤ ∧ p∉ℤ ∧ p<-1 ∧ n>0, then

∫(((((f+g x))^n) (((a+b x+c (x^2)))^p))/(d+e x))dx  ⟶  
((e (e f-d g))/(c (d^2)-b d e+a (e^2)))∫(((((f+g x))^(n-1)) (((a+b x+c (x^2)))^(p+1)))/(d+e x))dx+(1/(c (d^2)-b d e+a (e^2)))∫(((f+g x))^(n-1)) (c d f-b e f+a e g-c (e f-d g) x) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_/(d_.+e_.*x_),x_Symbol] :=
  e*(e*f-d*g)/(c*d^2-b*d*e+a*e^2)*Int[(f+g*x)^(n-1)*(a+b*x+c*x^2)^(p+1)/(d+e*x),x] + 
  1/(c*d^2-b*d*e+a*e^2)*Int[(f+g*x)^(n-1)*(c*d*f-b*e*f+a*e*g-c*(e*f-d*g)*x)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && 
  Not[IntegerQ[n]] && Not[IntegerQ[p]] && LtQ[p,-1] && GtQ[n,0]

Int[(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_/(d_.+e_.*x_),x_Symbol] :=
  e*(e*f-d*g)/(c*d^2+a*e^2)*Int[(f+g*x)^(n-1)*(a+c*x^2)^(p+1)/(d+e*x),x] + 
  1/(c*d^2+a*e^2)*Int[(f+g*x)^(n-1)*(c*d*f+a*e*g-c*(e*f-d*g)*x)*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && 
  Not[IntegerQ[n]] && Not[IntegerQ[p]] && LtQ[p,-1] && GtQ[n,0]

3:  ∫((((f+g x))^n)/((d+e x) (Sqrt[a+b x+c (x^2)])))dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ n+(1/2)∈ℤ

Reference: Algebraic expansion

Rule 1.2.1.4.12.3: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ n+(1/2)∈ℤ, then

∫((((f+g x))^n)/((d+e x) (Sqrt[a+b x+c (x^2)])))dx  ⟶  ∫(1/((Sqrt[f+g x]) (Sqrt[a+b x+c (x^2)]))) ExpandIntegrand[((((f+g x))^(n+(1/2)))/(d+e x)),x]dx

Program code:

Int[(f_.+g_.*x_)^n_/((d_.+e_.*x_)*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  Int[ExpandIntegrand[1/(Sqrt[f+g*x]*Sqrt[a+b*x+c*x^2]),(f+g*x)^(n+1/2)/(d+e*x),x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[n+1/2]

Int[(f_.+g_.*x_)^n_/((d_.+e_.*x_)*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  Int[ExpandIntegrand[1/(Sqrt[f+g*x]*Sqrt[a+c*x^2]),(f+g*x)^(n+1/2)/(d+e*x),x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && IntegerQ[n+1/2]

13:  ∫(((((g x))^n) (((a+c (x^2)))^p))/(d+e x))dx  when c (d^2)+a (e^2)≠0 ∧ p∉ℤ ∧ ¬(n∈ℤ ∧ 2 p∈ℤ)

Derivation: Algebraic expansion

Basis: (1/(d+e x))==(d/((d^2)-(e^2) (x^2)))-((e x)/((d^2)-(e^2) (x^2)))

Note: Resulting integrands are of the form (((x^m) (((a+b (x^2)))^p))/(c+d (x^2))) which are integrable in terms of the Appell hypergeometric function .

Rule 1.2.1.4.13: If  c (d^2)+a (e^2)≠0 ∧ p∉ℤ ∧ ¬(n∈ℤ ∧ 2 p∈ℤ), then

∫(((((g x))^n) (((a+c (x^2)))^p))/(d+e x))dx  ⟶  ((d (((g x))^n))/(x^n)) ∫(((x^n) (((a+c (x^2)))^p))/((d^2)-(e^2) (x^2)))dx-((e (((g x))^n))/(x^n)) ∫(((x^(n+1)) (((a+c (x^2)))^p))/((d^2)-(e^2) (x^2)))dx

Program code:

Int[(g_.*x_)^n_.*(a_+c_.*x_^2)^p_/(d_+e_.*x_),x_Symbol] :=
  d*(g*x)^n/x^n*Int[(x^n*(a+c*x^2)^p)/(d^2-e^2*x^2),x] - 
  e*(g*x)^n/x^n*Int[(x^(n+1)*(a+c*x^2)^p)/(d^2-e^2*x^2),x] /;
FreeQ[{a,c,d,e,g,n,p},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && Not[IntegersQ[n,2*p]]

14:  ∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  when e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (p∈ℤ ∨ (m|n)∈ℤ)

Derivation: Algebraic expansion

Rule 1.2.1.4.14: If  e f-d g≠0 ∧ (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (p∈ℤ ∨ (m|n)∈ℤ), then

∫(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p)dx  ⟶  ∫ExpandIntegrand[(((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p),x]dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^n*(a+b*x+c*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && (IntegerQ[p] || ILtQ[m,0] && ILtQ[n,0]) && 
  Not[IGtQ[m,0] || IGtQ[n,0]]

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^n*(a+c*x^2)^p,x],x] /;
FreeQ[{a,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && NeQ[c*d^2+a*e^2,0] && (IntegerQ[p] || ILtQ[m,0] && ILtQ[n,0]) && 
  Not[IGtQ[m,0] || IGtQ[n,0]]

15:  ∫(((g x))^n) (((d+e x))^m) (((a+c (x^2)))^p)dx  when c (d^2)+a (e^2)≠0 ∧ m∈(SuperMinus[ℤ])∧ p∉ℤ ∧ n∉ℤ

Derivation: Algebraic expansion

Basis: If  m∈ℤ, then (((d+e x))^m)==((((d/((d^2)-(e^2) (x^2)))-((e x)/((d^2)-(e^2) (x^2)))))^(-m))

Note: Resulting integrands are of the form (x^m) (((a+b (x^2)))^p) (((c+d (x^2)))^q) which are integrable in terms of the Appell hypergeometric function .

Rule 1.2.1.4.15: If  c (d^2)+a (e^2)≠0 ∧ m∈(SuperMinus[ℤ])∧ p∉ℤ ∧ n∉ℤ, then

∫(((g x))^n) (((d+e x))^m) (((a+c (x^2)))^p)dx  ⟶  ((((g x))^n)/(x^n)) ∫(x^n) (((a+c (x^2)))^p) ExpandIntegrand[((((d/((d^2)-(e^2) (x^2)))-((e x)/((d^2)-(e^2) (x^2)))))^(-m)),x]dx

Program code:

Int[(g_.*x_)^n_.*(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (g*x)^n/x^n*Int[ExpandIntegrand[x^n*(a+c*x^2)^p,(d/(d^2-e^2*x^2)-e*x/(d^2-e^2*x^2))^(-m),x],x] /;
FreeQ[{a,c,d,e,g,n,p},x] && NeQ[c*d^2+a*e^2,0] && ILtQ[m,0] && Not[IntegerQ[p]] && Not[IntegerQ[n]]

U:  ∫(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)dx

Rule 1.2.1.4.U:

∫(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)dx  ⟶  ∫(((d+e x))^m) (((f+g x))^n)(((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  Unintegrable[(d+e*x)^m*(f+g*x)^n*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && Not[IGtQ[m,0] || IGtQ[n,0]]

Int[(d_.+e_.*x_)^m_*(f_.+g_.*x_)^n_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  Unintegrable[(d+e*x)^m*(f+g*x)^n*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,f,g,m,n,p},x] && Not[IGtQ[m,0] || IGtQ[n,0]]

S:  ∫(((d+e u))^m)(((f+g u))^n)(((a+b u+c (u^2)))^p)dx  when  u==h+j x

Derivation: Integration by substitution

Rule 1.2.1.4.S: If  u==h+j x, then

∫(((d+e u))^m)(((f+g u))^n)(((a+b u+c (u^2)))^p)dx  ⟶  (1/j)Subst[∫(((d+e x))^m)(((f+g x))^n)(((a+b x+c (x^2)))^p)dx,x,u]

Program code:

Int[(d_.+e_.*u_)^m_.*(f_.+g_.*u_)^n_.*(a_+b_.*u_+c_.*u_^2)^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(d+e*x)^m*(f+g*x)^n*(a+b*x+c*x^2)^p,x],x,u] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && LinearQ[u,x] && NeQ[u,x]

Int[(d_.+e_.*u_)^m_.*(f_.+g_.*u_)^n_.*(a_+c_.*u_^2)^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(d+e*x)^m*(f+g*x)^n*(a+c*x^2)^p,x],x,u] /;
FreeQ[{a,c,d,e,f,g,m,n,p},x] && LinearQ[u,x] && NeQ[u,x]