Rules for integrands of the form(((a+b (x^2)+c (x^4)))^p)

1.  ∫(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0

x:  ∫(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  (b^2)-4 a c==0, then a+b z+c (z^2)==(1/c) ((((b/2)+c z))^2)

Rule 1.2.2.1.1.1: If  (b^2)-4 a c==0 ∧ p∈ℤ, then

∫(((a+b (x^2)+c (x^4)))^p)dx  ⟶  (1/(c^p))∫((((b/2)+c (x^2)))^(2 p))dx

Program code:

(* Int[(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  1/c^p*Int[(b/2+c*x^2)^(2*p),x] /;
FreeQ[{a,b,c,p},x] && EqQ[b^2-4*a*c,0] && IntegerQ[p] *)

2.  ∫(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

x:  ∫(1/(((a+b (x^2)+c (x^4)))^(5/4)))dx  when (b^2)-4 a c==0

Derivation: Square trinomial recurrence 2c with m+4 (p+1)+1==0

Rule 1.2.2.1.1.2.1: If  (b^2)-4 a c==0, then

∫(1/(((a+b (x^2)+c (x^4)))^(5/4)))dx  ⟶  ((2 x)/(3 a (((a+b (x^2)+c (x^4)))^(1/4))))+((x (2 a+b (x^2)))/(6 a (((a+b (x^2)+c (x^4)))^(5/4))))

Program code:

(* Int[1/(a_+b_.*x_^2+c_.*x_^4)^(5/4),x_Symbol] :=
  2*x/(3*a*(a+b*x^2+c*x^4)^(1/4)) + x*(2*a+b*x^2)/(6*a*(a+b*x^2+c*x^4)^(5/4)) /;
FreeQ[{a,b,c},x] && EqQ[b^2-4*a*c,0] *)

2:  ∫(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b (x^2)+c (x^4)))^p)/(((b+2 c (x^2)))^(2 p)))==0

Note: If  (b^2)-4 a c==0, then a+b z+c (z^2)==(1/(4 c)) (((b+2 c z))^2)

Rule 1.2.2.1.1.2.2: If  (b^2)-4 a c==0 ∧ p∉ℤ, then

∫(((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((((a+b (x^2)+c (x^4)))^p)/(((b+2 c (x^2)))^(2 p)))∫(((b+2 c (x^2)))^(2 p))dx

Program code:

Int[(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (a+b*x^2+c*x^4)^p/(b+2*c*x^2)^(2*p)*Int[(b+2*c*x^2)^(2*p),x] /;
FreeQ[{a,b,c,p},x] && EqQ[b^2-4*a*c,0] && IntegerQ[p-1/2]

Int[(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  a^IntPart[p]*(a+b*x^2+c*x^4)^FracPart[p]/(1+2*c*x^2/b)^(2*FracPart[p])*Int[(1+2*c*x^2/b)^(2*p),x] /;
FreeQ[{a,b,c,p},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[2*p]]

2.  ∫(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p>0

1:  ∫(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.2.1.2.1: If  (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ]), then

∫(((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫ExpandIntegrand[(((a+b (x^2)+c (x^4)))^p),x]dx

Program code:

Int[(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*x^2+c*x^4)^p,x],x] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && IGtQ[p,0]

2:  ∫(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4a c≠0 ∧ p>0

Derivation: Trinomial recurrence 1b with m=0, A=1 and B=0

Rule 1.2.2.1.2.2: If  (b^2)-4a c≠0 ∧ p>0, then

∫(((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((x(((a+b (x^2)+c (x^4)))^p))/(4 p+1))+((2 p)/(4 p+1)) ∫(2 a+b (x^2)) (((a+b (x^2)+c (x^4)))^(p-1))dx

Program code:

Int[(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  x*(a+b*x^2+c*x^4)^p/(4*p+1) + 
  2*p/(4*p+1)*Int[(2*a+b*x^2)*(a+b*x^2+c*x^4)^(p-1),x] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && GtQ[p,0] && IntegerQ[2*p]

3:  ∫(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4a c≠0 ∧ p<-1

Reference: G&R 2.161.5

Derivation: Trinomial recurrence 2b with m=0, A=1 and B=0

Note: G&R 2.161.4 is a special case of G&R 2.161.5.

Rule 1.2.2.1.3: If  (b^2)-4a c≠0 ∧ p<-1, then

∫(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
-((x ((b^2)-2 a c+b c (x^2))(((a+b (x^2)+c (x^4)))^(p+1)))/(2 a (p+1) ((b^2)-4 a c)))+
(1/(2 a(p+1) ((b^2)-4 a c)))∫((b^2)-2 a c+2(p+1) ((b^2)-4 a c)+b c(4 p+7)(x^2)) (((a+b (x^2)+c (x^4)))^(p+1))dx

Program code:

Int[(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  -x*(b^2-2*a*c+b*c*x^2)*(a+b*x^2+c*x^4)^(p+1)/(2*a*(p+1)*(b^2-4*a*c)) +
  1/(2*a*(p+1)*(b^2-4*a*c))*Int[(b^2-2*a*c+2*(p+1)*(b^2-4*a*c)+b*c*(4*p+7)*x^2)*(a+b*x^2+c*x^4)^(p+1),x] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && IntegerQ[2*p]

4.  ∫(1/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0

1:  ∫(1/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ (b^2)-4 a c>0

Reference: G&R 2.161.1a

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then (1/(a+b z+c (z^2)))==(c/q)(1/((b/2)-(q/2)+c z))-(c/q)(1/((b/2)+(q/2)+c z))

Rule 1.2.2.1.4.1: If  (b^2)-4 a c≠0, let q->(Sqrt[(b^2)-4 a c]), then

∫(1/(a+b (x^2)+c (x^4)))dx  ⟶  (c/q)∫(1/((b/2)-(q/2)+c (x^2)))dx-(c/q)∫(1/((b/2)+(q/2)+c (x^2)))dx

Program code:

Int[1/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  c/q*Int[1/(b/2-q/2+c*x^2),x] - c/q*Int[1/(b/2+q/2+c*x^2),x]] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && PosQ[b^2-4*a*c]

2:  ∫(1/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ (b^2)-4 a c≯0

Derivation: Algebraic expansion

Basis: If  q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then (1/(a+b (z^2)+c (z^4)))==((r-z)/(2 c q r (q-r z+(z^2))))+((r+z)/(2 c q r (q+r z+(z^2))))

Note: If (a|b|c)∈ℝ ∧ (b^2)-4 a c<0, then (a/c)>0 and 2 (Sqrt[(a/c)])-(b/c)>0.

Rule 1.2.2.1.4.2: If  (b^2)-4 a c≠0 ∧ (b^2)-4 a c≯0, let q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then

∫(1/(a+b (x^2)+c (x^4)))dx  ⟶  (1/(2 c q r))∫((r-x)/(q-r x+(x^2)))dx+(1/(2 c q r))∫((r+x)/(q+r x+(x^2)))dx

Program code:

Int[1/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[a/c,2]},
  With[{r=Rt[2*q-b/c,2]},
  1/(2*c*q*r)*Int[(r-x)/(q-r*x+x^2),x] + 1/(2*c*q*r)*Int[(r+x)/(q+r*x+x^2),x]]] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && NegQ[b^2-4*a*c]

5.  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0

1.  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0

1:  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ c<0

Derivation: Algebraic expansion

Basis: If  (b^2)-4 a c>0 ∧ c<0, let q->(Sqrt[(b^2)-4 a c]), then  (Sqrt[a+b (x^2)+c (x^4)])==(1/(2 (Sqrt[-c]))) (Sqrt[b+q+2 c (x^2)]) (Sqrt[-b+q-2 c (x^2)])

Rule 1.2.2.1.5.1.1: If  (b^2)-4 a c>0 ∧ c<0, let q->(Sqrt[(b^2)-4 a c]), then

∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  2 (Sqrt[-c])∫(1/((Sqrt[b+q+2 c (x^2)]) (Sqrt[-b+q-2 c (x^2)])))dx

Program code:

Int[1/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  2*Sqrt[-c]*Int[1/(Sqrt[b+q+2*c*x^2]*Sqrt[-b+q-2*c*x^2]),x]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0] && LtQ[c,0]

2.  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ c≮0

1:  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ (c/a)>0 ∧ (b/a)<0

Reference: G&R 3.165.2

Derivation: Piecewise constant extraction

Basis: Let  q=((((c/a)))^(1/4)), then  (∂_x)(((1+(q^2) (x^2)) (Sqrt[(((a+b (x^2)+c (x^4)))/(a(((1+(q^2) (x^2)))^2)))]))/(Sqrt[a+b (x^2)+c (x^4)]))==0

Rule 1.2.2.1.5.1.2.1: If  (b^2)-4 a c>0 ∧ (c/a)>0 ∧ (b/a)<0, let q->((((c/a)))^(1/4)), then

∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (((1+(q^2) (x^2)) (Sqrt[(((a+b (x^2)+c (x^4)))/(a(((1+(q^2) (x^2)))^2)))]))/(2 q (Sqrt[a+b (x^2)+c (x^4)]))) EllipticF[2 ArcTan[q x],(1/2)-((b (q^2))/(4 c))]

Program code:

Int[1/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[c/a,4]},
  (1+q^2*x^2)*Sqrt[(a+b*x^2+c*x^4)/(a*(1+q^2*x^2)^2)]/(2*q*Sqrt[a+b*x^2+c*x^4])*EllipticF[2*ArcTan[q*x],1/2-b*q^2/(4*c)]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0] && GtQ[c/a,0] && LtQ[b/a,0]

2:  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ a<0 ∧ c>0

Reference: G&R 3.152.3+

Note: Not sure if the shorter rule is valid for all q.

Rule 1.2.2.1.5.1.2.2: If  (b^2)-4 a c>0 ∧ a<0 ∧ c>0, let q->(Sqrt[(b^2)-4 a c]), then

∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (((Sqrt[((2 a+(b-q) (x^2))/(2 a+(b+q) (x^2)))]) (Sqrt[((2 a+(b+q) (x^2))/q)]))/(2 (Sqrt[a+b (x^2)+c (x^4)]) (Sqrt[(a/(2 a+(b+q) (x^2)))]))) EllipticF[ArcSin[(x/(Sqrt[((2 a+(b+q) (x^2))/(2 q))]))],((b+q)/(2 q))]

∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (((Sqrt[-2 a-(b-q) (x^2)]) (Sqrt[((2 a+(b+q) (x^2))/q)]))/(2 (Sqrt[-a])(Sqrt[a+b (x^2)+c (x^4)]))) EllipticF[ArcSin[(x/(Sqrt[((2 a+(b+q) (x^2))/(2 q))]))],((b+q)/(2 q))]

Program code:

Int[1/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  Sqrt[-2*a-(b-q)*x^2]*Sqrt[(2*a+(b+q)*x^2)/q]/(2*Sqrt[-a]*Sqrt[a+b*x^2+c*x^4])*
    EllipticF[ArcSin[x/Sqrt[(2*a+(b+q)*x^2)/(2*q)]],(b+q)/(2*q)] /;
  IntegerQ[q]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0] && LtQ[a,0] && GtQ[c,0]

Int[1/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  Sqrt[(2*a+(b-q)*x^2)/(2*a+(b+q)*x^2)]*Sqrt[(2*a+(b+q)*x^2)/q]/(2*Sqrt[a+b*x^2+c*x^4]*Sqrt[a/(2*a+(b+q)*x^2)])*
    EllipticF[ArcSin[x/Sqrt[(2*a+(b+q)*x^2)/(2*q)]],(b+q)/(2*q)]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0] && LtQ[a,0] && GtQ[c,0]

3.  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b±(Sqrt[(b^2)-4 a c]))/a)>0

1:  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b+(Sqrt[(b^2)-4 a c]))/a)>0

Reference: G&R 3.152.1+

Rule 1.2.2.1.5.1.2.3.1: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if ((b+q)/a)>0, then

∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (((2 a+(b+q)(x^2)) (Sqrt[((2 a+(b-q) (x^2))/(2 a+(b+q) (x^2)))]))/(2 a (Sqrt[((b+q)/(2 a))]) (Sqrt[a+b (x^2)+c (x^4)]))) EllipticF[ArcTan[(Sqrt[((b+q)/(2 a))]) x],((2 q)/(b+q))]

Program code:

Int[1/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (2*a+(b+q)*x^2)*Sqrt[(2*a+(b-q)*x^2)/(2*a+(b+q)*x^2)]/(2*a*Rt[(b+q)/(2*a),2]*Sqrt[a+b*x^2+c*x^4])*
    EllipticF[ArcTan[Rt[(b+q)/(2*a),2]*x],2*q/(b+q)] /;
 PosQ[(b+q)/a] && Not[PosQ[(b-q)/a] && SimplerSqrtQ[(b-q)/(2*a),(b+q)/(2*a)]]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0]

2:  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b-(Sqrt[(b^2)-4 a c]))/a)>0

Reference: G&R 3.152.1-

Rule 1.2.2.1.5.1.2.3.2: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if ((b-q)/a)>0 then

∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (((2 a+(b-q)(x^2)) (Sqrt[((2 a+(b+q) (x^2))/(2 a+(b-q) (x^2)))]))/(2 a (Sqrt[((b-q)/(2 a))]) (Sqrt[a+b (x^2)+c (x^4)]))) EllipticF[ArcTan[(Sqrt[((b-q)/(2 a))]) x],-((2 q)/(b-q))]

Program code:

Int[1/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (2*a+(b-q)*x^2)*Sqrt[(2*a+(b+q)*x^2)/(2*a+(b-q)*x^2)]/(2*a*Rt[(b-q)/(2*a),2]*Sqrt[a+b*x^2+c*x^4])*
    EllipticF[ArcTan[Rt[(b-q)/(2*a),2]*x],-2*q/(b-q)] /;
 PosQ[(b-q)/a]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0]

4.  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b±(Sqrt[(b^2)-4 a c]))/a)≯0

1:  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b+(Sqrt[(b^2)-4 a c]))/a)≯0

Reference: G&R 3.152.7+

Rule 1.2.2.1.5.1.2.4.1: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if  ((b+q)/a)≯0 then

∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (( (Sqrt[1+(((b+q) (x^2))/(2 a))]) (Sqrt[1+(((b-q) (x^2))/(2 a))]))/((Sqrt[-((b+q)/(2 a))]) (Sqrt[a+b (x^2)+c (x^4)]))) EllipticF[ArcSin[(Sqrt[-((b+q)/(2 a))]) x],((b-q)/(b+q))]

Program code:

Int[1/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  Sqrt[1+(b+q)*x^2/(2*a)]*Sqrt[1+(b-q)*x^2/(2*a)]/(Rt[-(b+q)/(2*a),2]*Sqrt[a+b*x^2+c*x^4])*
    EllipticF[ArcSin[Rt[-(b+q)/(2*a),2]*x],(b-q)/(b+q)] /;
 NegQ[(b+q)/a] && Not[NegQ[(b-q)/a] && SimplerSqrtQ[-(b-q)/(2*a),-(b+q)/(2*a)]]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0]

2:  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b-(Sqrt[(b^2)-4 a c]))/a)≯0

Reference: G&R 3.152.7-

Rule 1.2.2.1.5.1.2.4.2: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if  ((b-q)/a)≯0 then

∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (( (Sqrt[1+(((b-q) (x^2) )/(2 a))]) (Sqrt[1+(((b+q) (x^2))/(2 a))]))/((Sqrt[-((b-q)/(2 a))]) (Sqrt[a+b (x^2)+c (x^4)]))) EllipticF[ArcSin[(Sqrt[-((b-q)/(2 a))]) x],((b+q)/(b-q))]

Program code:

Int[1/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  Sqrt[1+(b-q)*x^2/(2*a)]*Sqrt[1+(b+q)*x^2/(2*a)]/(Rt[-(b-q)/(2*a),2]*Sqrt[a+b*x^2+c*x^4])*
    EllipticF[ArcSin[Rt[-(b-q)/(2*a),2]*x],(b+q)/(b-q)] /;
 NegQ[(b-q)/a]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0]

2.  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≱0

1:  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4a c≠0 ∧ (c/a)>0

Reference: G&R 3.165.2

Derivation: Piecewise constant extraction

Basis: Let  q=((((c/a)))^(1/4)), then  (∂_x)(((1+(q^2) (x^2)) (Sqrt[(((a+b (x^2)+c (x^4)))/(a(((1+(q^2) (x^2)))^2)))]))/(Sqrt[a+b (x^2)+c (x^4)]))==0

Rule 1.2.2.1.5.2.1: If  (b^2)-4a c≠0 ∧ (c/a)>0, let q->((((c/a)))^(1/4)), then

∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (((1+(q^2) (x^2)) (Sqrt[(((a+b (x^2)+c (x^4)))/(a(((1+(q^2) (x^2)))^2)))]))/(2 q (Sqrt[a+b (x^2)+c (x^4)]))) EllipticF[2 ArcTan[q x],(1/2)-((b (q^2))/(4 c))]

Program code:

Int[1/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[c/a,4]},
  (1+q^2*x^2)*Sqrt[(a+b*x^2+c*x^4)/(a*(1+q^2*x^2)^2)]/(2*q*Sqrt[a+b*x^2+c*x^4])*EllipticF[2*ArcTan[q*x],1/2-b*q^2/(4*c)]] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && PosQ[c/a]

2:  ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4a c≠0 ∧ (c/a)≯0

Derivation: Piecewise constant extraction

Basis: If  q->(Sqrt[(b^2)-4 a c]), then  (∂_x)(((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))]))/(Sqrt[a+b (x^2)+c (x^4)]))=0

Rule 1.2.2.1.5.2.2: If  (b^2)-4a c≠0 ∧ (c/a)≯0, let q->(Sqrt[(b^2)-4 a c]), then

∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))]))/(Sqrt[a+b (x^2)+c (x^4)]))∫(1/((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))])))dx

Program code:

Int[1/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  Sqrt[1+2*c*x^2/(b-q)]*Sqrt[1+2*c*x^2/(b+q)]/Sqrt[a+b*x^2+c*x^4]*
    Int[1/(Sqrt[1+2*c*x^2/(b-q)]*Sqrt[1+2*c*x^2/(b+q)]),x]] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && NegQ[c/a]

6:  ∫(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0

Derivation: Piecewise constant extraction

Basis: If q->(Sqrt[(b^2)-4 a c]), then (∂_x)(( (((a+b (x^2)+c (x^4)))^p))/((((1+((2 c (x^2))/(b+q))))^p) (((1+((2 c (x^2))/(b-q))))^p)))==0

Rule 1.2.2.1.6: If  (b^2)-4 a c≠0, let q->(Sqrt[(b^2)-4 a c]), then

∫(((a+b (x^2)+c (x^4)))^p)dx  ⟶  (( (a^(IntPart[p])) (((a+b (x^2)+c (x^4)))^(FracPart[p])))/((((1+((2 c (x^2))/(b+q))))^(FracPart[p])) (((1+((2 c (x^2))/(b-q))))^(FracPart[p])))) ∫(((1+((2 c (x^2))/(b+q))))^p) (((1+((2 c (x^2))/(b-q))))^p)dx

Program code:

Int[(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  a^IntPart[p]*(a+b*x^2+c*x^4)^FracPart[p]/((1+2*c*x^2/(b+q))^FracPart[p]*(1+2*c*x^2/(b-q))^FracPart[p])*
    Int[(1+2*c*x^2/(b+q))^p*(1+2*c*x^2/(b-q))^p,x]] /;
FreeQ[{a,b,c,p},x] && NeQ[b^2-4*a*c,0]

S:  ∫(((a+b x+c (x^2)+d (x^3)+e (x^4)))^p)dx  when  (d^3)-4 c d e+8 b (e^2)==0 ∧ p∉{1,2,3}

Derivation: Integration by substitution

Basis: If  (d^3)-4 c d e+8 b (e^2)==0, then  (((a+b x+c (x^2)+d (x^3)+e (x^4)))^p)==Subst[(((a+((d^4)/(256 (e^3)))-((b d)/(8 e))+(c-((3 (d^2))/(8 e))) (x^2)+e (x^4)))^p),x,(d/(4 e))+x] (∂_x)((d/(4 e))+x)

Note: The substitution transforms a dense quartic polynomial into a symmetric quartic trinomial.

Rule: If  (d^3)-4 c d e+8 b (e^2)==0 ∧ p∉{1,2,3}, then

∫(((a+b x+c (x^2)+d (x^3)+e (x^4)))^p)dx  ⟶  Subst[∫(((a+((d^4)/(256 (e^3)))-((b d)/(8 e))+(c-((3 (d^2))/(8 e))) (x^2)+e (x^4)))^p)dx,x,(d/(4 e))+x]

Program code:

Int[P4_^p_,x_Symbol] :=
  With[{a=Coeff[P4,x,0],b=Coeff[P4,x,1],c=Coeff[P4,x,2],d=Coeff[P4,x,3],e=Coeff[P4,x,4]},
  Subst[Int[SimplifyIntegrand[(a+d^4/(256*e^3)-b*d/(8*e)+(c-3*d^2/(8*e))*x^2+e*x^4)^p,x],x],x,d/(4*e)+x] /;
 EqQ[d^3-4*c*d*e+8*b*e^2,0] && NeQ[d,0]] /;
FreeQ[p,x] && PolyQ[P4,x,4] && NeQ[p,2] && NeQ[p,3]