Rules for integrands of the form(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)

0.  ∫(((d+e (x^2)))^q)(((b (x^2)+c (x^4)))^p)dx  when p∉ℤ

1.  ∫(d+e (x^2))(((b (x^2)+c (x^4)))^p)dx  when p∉ℤ

1:  ∫((d+e (x^2))/(((b (x^2)+c (x^4)))^(3/4)))dx

Derivation: Trinomial recurrence 2a with a=0, m=0 and n (2 p+1)+1==0 composed with trinomial recurrene 5 with a=0

Rule 1.2.2.3.0.1.1:

∫((d+e (x^2))/(((b (x^2)+c (x^4)))^(3/4)))dx  ⟶  -((2 (c d-b e) (((b (x^2)+c (x^4)))^(1/4)))/(b c x))+(e/c)∫((((b (x^2)+c (x^4)))^(1/4))/(x^2))dx

Program code:

Int[(d_+e_.*x_^2)/(b_.*x_^2+c_.*x_^4)^(3/4),x_Symbol] :=
  -2*(c*d-b*e)*(b*x^2+c*x^4)^(1/4)/(b*c*x) + e/c*Int[(b*x^2+c*x^4)^(1/4)/x^2,x] /;
FreeQ[{b,c,d,e},x]

2:  ∫(d+e (x^2))(((b (x^2)+c (x^4)))^p)dx  when p∉ℤ ∧ p≠-(3/4) ∧ b e (2 p+1)-c d (4 p+3)==0

Derivation: Trinomial recurrence 3a with a=0 with b e (n p+1)-c d (n (2 p+1)+1)==0

Rule 1.2.2.3.0.1.2: If  p∉ℤ ∧ p≠-(3/4) ∧ b e (2 p+1)-c d (4 p+3)==0, then

∫(d+e (x^2))(((b (x^2)+c (x^4)))^p)dx  ⟶  ((e (((b (x^2)+c (x^4)))^(p+1)))/(c (4 p+3) x))

Program code:

Int[(d_+e_.*x_^2)*(b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  e*(b*x^2+c*x^4)^(p+1)/(c*(4*p+3)*x) /;
FreeQ[{b,c,d,e,p},x] && Not[IntegerQ[p]] && NeQ[4*p+3,0] && EqQ[b*e*(2*p+1)-c*d*(4*p+3),0]

3:  ∫(d+e (x^2))(((b (x^2)+c (x^4)))^p)dx  when p∉ℤ ∧ p≠-(3/4) ∧ b e (2 p+1)-c d (4 p+3)≠0

Derivation: Trinomial recurrence 3a with a=0

Rule 1.2.2.3.0.1.3: If  p∉ℤ ∧ p≠-(3/4) ∧ b e (2 p+1)-c d (4 p+3)≠0, then

∫(d+e (x^2))(((b (x^2)+c (x^4)))^p)dx  ⟶  ((e (((b (x^2)+c (x^4)))^(p+1)))/(c (4 p+3) x))-((b e (2 p+1)-c d (4 p+3))/(c (4 p+3)))∫(((b (x^2)+c (x^4)))^p)dx

Program code:

Int[(d_+e_.*x_^2)*(b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  e*(b*x^2+c*x^4)^(p+1)/(c*(4*p+3)*x) - ((b*e*(2*p+1)-c*d*(4*p+3))/(c*(4*p+3)))*Int[(b*x^2+c*x^4)^p,x] /;
FreeQ[{b,c,d,e,p},x] && Not[IntegerQ[p]] && NeQ[4*p+3,0] && NeQ[b*e*(2*p+1)-c*d*(4*p+3),0]

2:  ∫(((d+e (x^2)))^q)(((b (x^2)+c (x^4)))^p)dx  when p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((b (x^2)+c (x^4)))^p)/((x^(2 p))(((b+c (x^2)))^p)))==0

Basis: ((((b (x^2)+c (x^4)))^(FracPart[p]))/((x^(2 FracPart[p]))(((b+c (x^2)))^(FracPart[p]))))==((((b (x^2)+c (x^4)))^(FracPart[p]))/((x^(2 FracPart[p]))(((b+c (x^2)))^(FracPart[p]))))

Rule 1.2.2.3.0.2: If  p∉ℤ, then

∫(((d+e (x^2)))^q)(((b (x^2)+c (x^4)))^p)dx  ⟶  ((((b (x^2)+c (x^4)))^(FracPart[p]))/((x^(2 FracPart[p]))(((b+c (x^2)))^(FracPart[p]))))∫(x^(2 p))(((d+e (x^2)))^q)(((b+c (x^2)))^p)dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (b*x^2+c*x^4)^FracPart[p]/(x^(2*FracPart[p])*(b+c*x^2)^FracPart[p])*Int[x^(2*p)*(d+e*x^2)^q*(b+c*x^2)^p,x] /;
FreeQ[{b,c,d,e,p,q},x] && Not[IntegerQ[p]]

1.  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0

x:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  (b^2)-4 a c==0, then a+b z+c (z^2)==(1/c) ((((b/2)+c z))^2)

Rule 1.2.2.2.1.x: If  (b^2)-4 a c==0 ∧ p∈ℤ, then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (1/(c^p))∫(((d+e (x^2)))^q) ((((b/2)+c (x^2)))^(2 p))dx

Program code:

(* Int[(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  1/c^p*Int[(d+e*x^2)^q*(b/2+c*x^2)^(2*p),x] /;
FreeQ[{a,b,c,d,e,p,q},x] && EqQ[b^2-4*a*c,0] && IntegerQ[p] *)

2.  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

1:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0             Necessary??

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0 ∧ 2 c d-b e==0, then (∂_x)((((a+b (x^2)+c (x^4)))^p)/(((d+e (x^2)))^(2 p)))==0

Note: If  (b^2)-4 a c==0 ∧ 2 c d-b e==0, then a+b z+c (z^2)==(c/(e^2)) (((d+e z))^2)

Rule 1.2.2.3.1.2.1: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0, then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((((a+b (x^2)+c (x^4)))^p)/(((d+e (x^2)))^(2 p))) ∫(((d+e (x^2)))^(q+2 p))dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (a+b*x^2+c*x^4)^p/(d+e*x^2)^(2*p)*Int[(d+e*x^2)^(q+2*p),x] /;
FreeQ[{a,b,c,d,e,p,q},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && EqQ[2*c*d-b*e,0]

2:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b (x^2)+c (x^4)))^p)/((((b/2)+c (x^2)))^(2 p)))==0

Note: If  (b^2)-4 a c==0, then a+b z+c (z^2)==(1/c) ((((b/2)+c z))^2)

Rule 1.2.2.3.1.2.2: If  (b^2)-4 a c==0 ∧ p∉ℤ, then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((((a+b (x^2)+c (x^4)))^(FracPart[p]))/((c^(IntPart[p]))((((b/2)+c (x^2)))^(2 FracPart[p]))))∫(((d+e (x^2)))^q) ((((b/2)+c (x^2)))^(2 p))dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (a+b*x^2+c*x^4)^FracPart[p]/(c^IntPart[p]*(b/2+c*x^2)^(2*FracPart[p]))*Int[(d+e*x^2)^q*(b/2+c*x^2)^(2*p),x] /;
FreeQ[{a,b,c,d,e,p,q},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]]

2.  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0

1:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then a+b z+c (z^2)==(d+e z) ((a/d)+((c z)/e))

Rule 1.2.2.3.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ, then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫(((d+e (x^2)))^(p+q)) ((((a/d)+((c (x^2))/e)))^p)dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  Int[(d+e*x^2)^(p+q)*(a/d+c/e*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[p]

Int[(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  Int[(d+e*x^2)^(p+q)*(a/d+c/e*x^2)^p,x] /;
FreeQ[{a,c,d,e,q},x] && EqQ[c*d^2+a*e^2,0] && IntegerQ[p]

2:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  c (d^2)-b d e+a (e^2)==0, then (∂_x)((((a+b (x^2)+c (x^4)))^p)/((((d+e (x^2)))^p) ((((a/d)+((c (x^2))/e)))^p)))==0

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((((a+b (x^2)+c (x^4)))^p)/((((d+e (x^2)))^p) ((((a/d)+((c (x^2))/e)))^p)))==((((a+b (x^2)+c (x^4)))^(FracPart[p]))/((((d+e (x^2)))^(FracPart[p])) ((((a/d)+((c (x^2))/e)))^(FracPart[p]))))

Rule 1.2.2.3.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ, then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((((a+b (x^2)+c (x^4)))^(FracPart[p]))/((((d+e (x^2)))^(FracPart[p])) ((((a/d)+((c (x^2))/e)))^(FracPart[p]))))∫(((d+e (x^2)))^(p+q)) ((((a/d)+((c (x^2))/e)))^p)dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (a+b*x^2+c*x^4)^FracPart[p]/((d+e*x^2)^FracPart[p]*(a/d+c*x^2/e)^FracPart[p])*Int[(d+e*x^2)^(p+q)*(a/d+c/e*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,p,q},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]]

Int[(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_,x_Symbol] :=
  (a+c*x^4)^FracPart[p]/((d+e*x^2)^FracPart[p]*(a/d+c*x^2/e)^FracPart[p])*Int[(d+e*x^2)^(p+q)*(a/d+c/e*x^2)^p,x] /;
FreeQ[{a,c,d,e,p,q},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]]

3.  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])

1:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ q+2∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.2.3.3.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ q+2∈(SuperPlus[ℤ]), then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫ExpandIntegrand[(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p),x]dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^q*(a+b*x^2+c*x^4)^p,x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[p,0] && IGtQ[q,-2]

Int[(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^q*(a+c*x^4)^p,x],x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && IGtQ[p,0] && IGtQ[q,-2]

2.  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ q<-1

1:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ q+(1/2)∈(SuperMinus[ℤ])∧ 4 p+2 q+1<0

Derivation: Algebraic expansion and binomial recurrence 3b

Basis: ∫(((d+e (x^2)))^q)dx==((x (((d+e (x^2)))^(q+1)))/d)-((e (2 q+3))/d) ∫(x^2) (((d+e (x^2)))^q)dx

Note: Interestingly this rule eleminates the constant term of (((a+b (x^2)+c (x^4)))^p) rather than the highest degree term.

Rule 1.2.2.3.3.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ q+(1/2)∈(SuperMinus[ℤ])∧ 4 p+2 q+1<0, then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

(a^p) ∫(((d+e (x^2)))^q)dx+∫(x^2) (((d+e (x^2)))^q) PolynomialQuotient[(((a+b (x^2)+c (x^4)))^p)-(a^p),(x^2),x]dx  ⟶  

(((a^p) x (((d+e (x^2)))^(q+1)))/d)+ (1/d)∫(x^2) (((d+e (x^2)))^q) (d PolynomialQuotient[(((a+b (x^2)+c (x^4)))^p)-(a^p),(x^2),x]-e (a^p) (2 q+3))dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  a^p*x*(d+e*x^2)^(q+1)/d + 
  1/d*Int[x^2*(d+e*x^2)^q*(d*PolynomialQuotient[(a+b*x^2+c*x^4)^p-a^p,x^2,x]-e*a^p*(2*q+3)),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[p,0] && ILtQ[q+1/2,0] && LtQ[4*p+2*q+1,0]

Int[(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  a^p*x*(d+e*x^2)^(q+1)/d + 
  1/d*Int[x^2*(d+e*x^2)^q*(d*PolynomialQuotient[(a+c*x^4)^p-a^p,x^2,x]-e*a^p*(2*q+3)),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && IGtQ[p,0] && ILtQ[q+1/2,0] && LtQ[4*p+2*q+1,0]

2:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ q<-1

Derivation: Algebraic expansion and quadratic recurrence 2a

Rule 1.2.2.3.3.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ q<-1, 
			let Q[x]->PolynomialQuotient[(((a+b (x^2)+c (x^4)))^p),d+e (x^2),x]and R->PolynomialRemainder[(((a+b (x^2)+c (x^4)))^p),d+e (x^2),x], then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

R ∫(((d+e (x^2)))^q)dx+∫Q[x] (((d+e (x^2)))^(q+1))dx  ⟶  

-((R x (((d+e (x^2)))^(q+1)))/(2 d (q+1)))+(1/(2 d (q+1)))∫(((d+e (x^2)))^(q+1))(2 d (q+1) Q[x]+R (2 q+3)) dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  With[{Qx=PolynomialQuotient[(a+b*x^2+c*x^4)^p,d+e*x^2,x],
        R=Coeff[PolynomialRemainder[(a+b*x^2+c*x^4)^p,d+e*x^2,x],x,0]},
  -R*x*(d+e*x^2)^(q+1)/(2*d*(q+1)) + 
  1/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*ExpandToSum[2*d*(q+1)*Qx+R*(2*q+3),x],x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[p,0] && LtQ[q,-1]

Int[(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  With[{Qx=PolynomialQuotient[(a+c*x^4)^p,d+e*x^2,x],
        R=Coeff[PolynomialRemainder[(a+c*x^4)^p,d+e*x^2,x],x,0]},
  -R*x*(d+e*x^2)^(q+1)/(2*d*(q+1)) + 
  1/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*ExpandToSum[2*d*(q+1)*Qx+R*(2*q+3),x],x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && IGtQ[p,0] && LtQ[q,-1]

3:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ q≰-1

Reference: G&R 2.110.5, G&R 2.104, G&R 2.160.3, CRC 88a

Derivation: Algebraic expansion and binomial recurrence 3a

Note: If  p∈(SuperPlus[ℤ])∧ q≰-1, then 4 p+2 q+1≠0.

Rule 1.2.2.3.3.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])∧ q≰-1, then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

(c^p) ∫(x^(4 p)) (((d+e (x^2)))^q)dx+∫(((d+e (x^2)))^q) ((((a+b (x^2)+c (x^4)))^p)-(c^p) (x^(4 p)))dx  ⟶  

(((c^p) (x^(4 p-1)) (((d+e (x^2)))^(q+1)))/(e (4 p+2 q+1)))+(1/(e (4 p+2 q+1))) ∫(((d+e (x^2)))^q)(e (4 p+2 q+1) (((a+b (x^2)+c (x^4)))^p)-d (c^p) (4 p-1) (x^(4 p-2))-e (c^p) (4 p+2 q+1) (x^(4 p)))dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  c^p*x^(4*p-1)*(d+e*x^2)^(q+1)/(e*(4*p+2*q+1)) + 
  1/(e*(4*p+2*q+1))*Int[(d+e*x^2)^q*ExpandToSum[e*(4*p+2*q+1)*(a+b*x^2+c*x^4)^p-d*c^p*(4*p-1)*x^(4*p-2)-e*c^p*(4*p+2*q+1)*x^(4*p),x],x] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[p,0] && Not[LtQ[q,-1]]

Int[(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  c^p*x^(4*p-1)*(d+e*x^2)^(q+1)/(e*(4*p+2*q+1)) + 
  1/(e*(4*p+2*q+1))*Int[(d+e*x^2)^q*ExpandToSum[e*(4*p+2*q+1)*(a+c*x^4)^p-d*c^p*(4*p-1)*x^(4*p-2)-e*c^p*(4*p+2*q+1)*x^(4*p),x],x] /;
FreeQ[{a,c,d,e,q},x] && NeQ[c*d^2+a*e^2,0] && IGtQ[p,0] && Not[LtQ[q,-1]]

4.  ∫((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1.  ∫((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∈ℤ

1.  ∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1.  ∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0

1:  ∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ ((2 d)/e)-(b/c)>0

Derivation: Algebraic expansion

Basis: If  c (d^2)-a (e^2)==0 and q->(Sqrt[((2 d)/e)-(b/c)]), then ((d+e (z^2))/(a+b (z^2)+c (z^4)))==((e^2)/(2 c (d+e q z+e (z^2))))+((e^2)/(2 c (d-e q z+e (z^2))))

Rule 1.2.2.3.4.1.1.1.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ ((2 d)/e)-(b/c)>0, let q->(Sqrt[((2 d)/e)-(b/c)]), then

∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  ⟶  (e/(2 c))∫(1/((d/e)+q x+(x^2)))dx+(e/(2 c))∫(1/((d/e)-q x+(x^2)))dx

Program code:

Int[(d_+e_.*x_^2)/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[2*d/e-b/c,2]},
  e/(2*c)*Int[1/Simp[d/e+q*x+x^2,x],x] + e/(2*c)*Int[1/Simp[d/e-q*x+x^2,x],x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-a*e^2,0] && (GtQ[2*d/e-b/c,0] || Not[LtQ[2*d/e-b/c,0]] && EqQ[d-e*Rt[a/c,2],0])

Int[(d_+e_.*x_^2)/(a_+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[2*d/e,2]},
  e/(2*c)*Int[1/Simp[d/e+q*x+x^2,x],x] + e/(2*c)*Int[1/Simp[d/e-q*x+x^2,x],x]] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2-a*e^2,0] && PosQ[d*e]

2:  ∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (b^2)-4 a c>0

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then ((d+e z)/(a+b z+c (z^2)))==((e/2)+((2 c d-b e)/(2 q))) (1/((b/2)-(q/2)+c z))+((e/2)-((2 c d-b e)/(2 q))) (1/((b/2)+(q/2)+c z))

Rule 1.2.2.3.4.1.1.1.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), then

∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  ⟶  ((e/2)+((2 c d-b e)/(2 q))) ∫ (1/((b/2)-(q/2)+c (x^2)))dx+((e/2)-((2 c d-b e)/(2 q))) ∫ (1/((b/2)+(q/2)+c (x^2)))dx

Program code:

Int[(d_+e_.*x_^2)/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (e/2+(2*c*d-b*e)/(2*q))*Int[1/(b/2-q/2+c*x^2),x] + (e/2-(2*c*d-b*e)/(2*q))*Int[1/(b/2+q/2+c*x^2),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-a*e^2,0] && GtQ[b^2-4*a*c,0]

3:  ∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (b^2)-4 a c≯0

Derivation: Algebraic expansion

Basis: If  c (d^2)-a (e^2)==0 and q->(Sqrt[-((2 d)/e)-(b/c)]), then ((d+e (z^2))/(a+b (z^2)+c (z^4)))==((e (q-2 z))/(2 c q ((d/e)+q z-(z^2))))+((e (q+2 z))/(2 c q ((d/e)-q z-(z^2))))

Rule 1.2.2.3.4.1.1.1.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (b^2)-4 a c≯0, let q->(Sqrt[-((2 d)/e)-(b/c)]), then

∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  ⟶  (e/(2 c q))∫((q-2 x)/((d/e)+q x-(x^2)))dx+(e/(2 c q))∫((q+2 x)/((d/e)-q x-(x^2)))dx

Program code:

Int[(d_+e_.*x_^2)/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[-2*d/e-b/c,2]},
  e/(2*c*q)*Int[(q-2*x)/Simp[d/e+q*x-x^2,x],x] + e/(2*c*q)*Int[(q+2*x)/Simp[d/e-q*x-x^2,x],x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-a*e^2,0] && Not[GtQ[b^2-4*a*c,0]]

Int[(d_+e_.*x_^2)/(a_+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[-2*d/e,2]},
  e/(2*c*q)*Int[(q-2*x)/Simp[d/e+q*x-x^2,x],x] + e/(2*c*q)*Int[(q+2*x)/Simp[d/e-q*x-x^2,x],x]] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2-a*e^2,0] && NegQ[d*e]

2.  ∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)≠0

1:  ∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)≠0 ∧ (b^2)-4 a c>0

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then ((d+e z)/(a+b z+c (z^2)))==((e/2)+((2 c d-b e)/(2 q))) (1/((b/2)-(q/2)+c z))+((e/2)-((2 c d-b e)/(2 q))) (1/((b/2)+(q/2)+c z))

Rule 1.2.2.3.4.1.1.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)≠0 ∧ (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), then

∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  ⟶  ((e/2)+((2 c d-b e)/(2 q))) ∫ (1/((b/2)-(q/2)+c (x^2)))dx+((e/2)-((2 c d-b e)/(2 q))) ∫ (1/((b/2)+(q/2)+c (x^2)))dx

Program code:

Int[(d_+e_.*x_^2)/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (e/2+(2*c*d-b*e)/(2*q))*Int[1/(b/2-q/2+c*x^2),x] + (e/2-(2*c*d-b*e)/(2*q))*Int[1/(b/2+q/2+c*x^2),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-a*e^2,0] && PosQ[b^2-4*a*c]

Int[(d_+e_.*x_^2)/(a_+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  (e/2+c*d/(2*q))*Int[1/(-q+c*x^2),x] + (e/2-c*d/(2*q))*Int[1/(q+c*x^2),x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2-a*e^2,0] && PosQ[-a*c]

2.  ∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)≠0

1:  ∫((d+e (x^2))/(a+c (x^4)))dx  when c (d^2)+a (e^2)≠0 ∧ c (d^2)-a (e^2)≠0 ∧ -a c≯0

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[a c]), then ((d+e z)/(a+c (z^2)))==((d q+a e)/(2 a c))((q+c z)/(a+c (z^2)))+((d q-a e)/(2 a c))((q-c z)/(a+c (z^2)))

Note: Resulting integrands are of the form ((d+e (x^2))/(a+c (x^4))) where c (d^2)-a (e^2)==0.

Rule 1.2.2.3.4.1.1.2.2.1: If  c (d^2)+a (e^2)≠0 ∧ c (d^2)-a (e^2)≠0 ∧ -a c≯0, let q->(Sqrt[a c]), then

∫((d+e (x^2))/(a+c (x^4)))dx  ⟶  ((d q+a e)/(2 a c))∫((q+c (x^2))/(a+c (x^4)))dx+((d q-a e)/(2 a c))∫((q-c (x^2))/(a+c (x^4)))dx

Program code:

Int[(d_+e_.*x_^2)/(a_+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[a*c,2]},
  (d*q+a*e)/(2*a*c)*Int[(q+c*x^2)/(a+c*x^4),x] + (d*q-a*e)/(2*a*c)*Int[(q-c*x^2)/(a+c*x^4),x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && NeQ[c*d^2-a*e^2,0] && NegQ[-a*c]

2:  ∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (b^2)-4 a c≯0

Derivation: Algebraic expansion

Basis: If  q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then ((d+e (z^2))/(a+b (z^2)+c (z^4)))==((d r-(d-e q) z)/(2 c q r (q-r z+(z^2))))+((d r+(d-e q) z)/(2 c q r (q+r z+(z^2))))

Note: If (a|b|c)∈ℝ ∧ (b^2)-4 a c<0, then (a/c)>0 and 2 (Sqrt[(a/c)])-(b/c)>0.

Rule 1.2.2.3.4.1.1.2.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (b^2)-4 a c≯0, let q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then

∫((d+e (x^2))/(a+b (x^2)+c (x^4)))dx  ⟶  (1/(2 c q r))∫((d r-(d-e q) x)/(q-r x+(x^2)))dx+(1/(2 c q r))∫((d r+(d-e q) x)/(q+r x+(x^2)))dx

Program code:

Int[(d_+e_.*x_^2)/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[a/c,2]},
  With[{r=Rt[2*q-b/c,2]},
  1/(2*c*q*r)*Int[(d*r-(d-e*q)*x)/(q-r*x+x^2),x] + 1/(2*c*q*r)*Int[(d*r+(d-e*q)*x)/(q+r*x+x^2),x]]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NegQ[b^2-4*a*c]

2:  ∫((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∈ℤ

Derivation: Algebraic expansion

Rule 1.2.2.3.4.1.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∈ℤ, then

∫((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4)))dx  ⟶  ∫ ExpandIntegrand[((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4))),x]dx

Program code:

Int[(d_+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^q/(a+b*x^2+c*x^4),x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[q]

Int[(d_+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^q/(a+c*x^4),x],x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && IntegerQ[q]

2.  ∫((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∉ℤ

1:  ∫((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∉ℤ ∧ q<-1

Derivation: Algebraic expansion

Basis: (1/(a+b z+c (z^2)))==((e^2)/(c (d^2)-b d e+a (e^2)))+(((d+e z) (c d-b e-c e z))/((c (d^2)-b d e+a (e^2)) (a+b z+c (z^2))))

Rule 1.2.2.3.4.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∉ℤ ∧ q<-1, then

∫((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4)))dx  ⟶  ((e^2)/(c (d^2)-b d e+a (e^2)))∫(((d+e (x^2)))^q)dx+(1/(c (d^2)-b d e+a (e^2)))∫(((((d+e (x^2)))^(q+1)) (c d-b e-c e (x^2)))/(a+b (x^2)+c (x^4)))dx

Program code:

Int[(d_+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  e^2/(c*d^2-b*d*e+a*e^2)*Int[(d+e*x^2)^q,x] + 
  1/(c*d^2-b*d*e+a*e^2)*Int[(d+e*x^2)^(q+1)*(c*d-b*e-c*e*x^2)/(a+b*x^2+c*x^4),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[q]] && LtQ[q,-1]

Int[(d_+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  e^2/(c*d^2+a*e^2)*Int[(d+e*x^2)^q,x] + 
  c/(c*d^2+a*e^2)*Int[(d+e*x^2)^(q+1)*(d-e*x^2)/(a+c*x^4),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[q]] && LtQ[q,-1]

2:  ∫((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∉ℤ ∧ q≮-1

Derivation: Algebraic expansion

Basis: If  r=(Sqrt[(b^2)-4a c]), then (1/(a+b z+c (z^2)))==((2c)/(r(b-r+2 c z)))-((2c)/(r(b+r+2 c z)))

Rule 1.2.2.3.4.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∉ℤ ∧ q≮-1, then

∫((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4)))dx  ⟶  ((2 c)/r)∫((((d+e (x^2)))^q)/(b-r+2 c (x^2)))dx-((2 c)/r)∫((((d+e (x^2)))^q)/(b+r+2 c (x^2)))dx

Program code:

Int[(d_+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{r=Rt[b^2-4*a*c,2]},
  2*c/r*Int[(d+e*x^2)^q/(b-r+2*c*x^2),x] - 2*c/r*Int[(d+e*x^2)^q/(b+r+2*c*x^2),x]] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[q]]

Int[(d_+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  With[{r=Rt[-a*c,2]},
  -c/(2*r)*Int[(d+e*x^2)^q/(r-c*x^2),x] - c/(2*r)*Int[(d+e*x^2)^q/(r+c*x^2),x]] /;
FreeQ[{a,c,d,e,q},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[q]]

5.  ∫(d+e (x^2)) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1:  ∫(d+e (x^2)) (((a+b (x^2)+c (x^4)))^p)dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p>0

Derivation: Trinomial recurrence 1b with m=0

Rule 1.2.2.3.5.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p>0, then

∫(d+e (x^2)) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  
((x (2 b e p+c d (4 p+3)+c e (4 p+1) (x^2))(((a+b (x^2)+c (x^4)))^p))/(c (4 p+1)(4 p+3)))+
((2 p)/(c (4 p+1)(4 p+3)))∫(2 a c d (4 p+3)-a b e+(2 a c e (4 p+1)+b c d (4 p+3)-(b^2)e(2 p+1))(x^2))(((a+b (x^2)+c (x^4)))^(p-1))dx

Program code:

Int[(d_+e_.*x_^2)*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  x*(2*b*e*p+c*d*(4*p+3)+c*e*(4*p+1)*x^2)*(a+b*x^2+c*x^4)^p/(c*(4*p+1)*(4*p+3)) + 
  2*p/(c*(4*p+1)*(4*p+3))*Int[Simp[2*a*c*d*(4*p+3)-a*b*e+(2*a*c*e*(4*p+1)+b*c*d*(4*p+3)-b^2*e*(2*p+1))*x^2,x]*
    (a+b*x^2+c*x^4)^(p-1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && GtQ[p,0] && FractionQ[p] && IntegerQ[2*p]

Int[(d_+e_.*x_^2)*(a_+c_.*x_^4)^p_,x_Symbol] :=
  x*(d*(4*p+3)+e*(4*p+1)*x^2)*(a+c*x^4)^p/((4*p+1)*(4*p+3)) + 
  2*p/((4*p+1)*(4*p+3))*Int[Simp[2*a*d*(4*p+3)+(2*a*e*(4*p+1))*x^2,x]*(a+c*x^4)^(p-1),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && GtQ[p,0] && FractionQ[p] && IntegerQ[2*p]

2:  ∫(d+e (x^2)) (((a+b (x^2)+c (x^4)))^p)dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p<-1

Derivation: Trinomial recurrence 2b with m=0

Rule 1.2.2.3.5.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p<-1, then

∫(d+e (x^2)) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  
((x(a b e-d ((b^2)-2 a c)-c (b d-2 a e) (x^2))(((a+b (x^2)+c (x^4)))^(p+1)))/(2 a (p+1)  ((b^2)-4 a c)))+
(1/(2 a (p+1) ((b^2)-4 a c) ))∫((2 p+3) d (b^2)-a b e-2a c d(4 p+5)+(4 p+7)(d b-2 a e) c (x^2))(((a+b (x^2)+c (x^4)))^(p+1))dx

Program code:

Int[(d_+e_.*x_^2)*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  x*(a*b*e-d*(b^2-2*a*c)-c*(b*d-2*a*e)*x^2)*(a+b*x^2+c*x^4)^(p+1)/(2*a*(p+1)*(b^2-4*a*c)) + 
  1/(2*a*(p+1)*(b^2-4*a*c))*Int[Simp[(2*p+3)*d*b^2-a*b*e-2*a*c*d*(4*p+5)+(4*p+7)*(d*b-2*a*e)*c*x^2,x]*
    (a+b*x^2+c*x^4)^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && LtQ[p,-1] && IntegerQ[2*p]

Int[(d_+e_.*x_^2)*(a_+c_.*x_^4)^p_,x_Symbol] :=
  -x*(d+e*x^2)*(a+c*x^4)^(p+1)/(4*a*(p+1)) + 
  1/(4*a*(p+1))*Int[Simp[d*(4*p+5)+e*(4*p+7)*x^2,x]*(a+c*x^4)^(p+1),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && LtQ[p,-1] && IntegerQ[2*p]

3.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0

1:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ c<0

Derivation: Algebraic expansion

Basis: If  (b^2)-4 a c>0 ∧ c<0, let q->(Sqrt[(b^2)-4 a c]), then  (Sqrt[a+b (x^2)+c (x^4)])==(1/(2 (Sqrt[-c]))) (Sqrt[b+q+2 c (x^2)]) (Sqrt[-b+q-2 c (x^2)])

Rule 1.2.2.3.5.3.1.1: If  (b^2)-4 a c>0 ∧ c<0, let q->(Sqrt[(b^2)-4 a c]), then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  2 (Sqrt[-c])∫((d+e (x^2))/((Sqrt[b+q+2 c (x^2)]) (Sqrt[-b+q-2 c (x^2)])))dx

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  2*Sqrt[-c]*Int[(d+e*x^2)/(Sqrt[b+q+2*c*x^2]*Sqrt[-b+q-2*c*x^2]),x]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0] && LtQ[c,0]

Int[(d_+e_.*x_^2)/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  Sqrt[-c]*Int[(d+e*x^2)/(Sqrt[q+c*x^2]*Sqrt[q-c*x^2]),x]] /;
FreeQ[{a,c,d,e},x] && GtQ[a,0] && LtQ[c,0]

2.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ c≮0

1.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ (c/a)>0 ∧ (b/a)<0

1:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ (c/a)>0 ∧ (b/a)<0 ∧ e+d (Sqrt[(c/a)])==0

Reference: G&R 3.165.10

Rule 1.2.2.3.5.3.1.2.1.1: If  (b^2)-4 a c>0 ∧ (c/a)>0 ∧ (b/a)<0, let q->((((c/a)))^(1/4)), if  e+d (q^2)==0, then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  -((d x (Sqrt[a+b (x^2)+c (x^4)]))/(a (1+(q^2) (x^2))))+2 d ∫((Sqrt[a+b (x^2)+c (x^4)])/(a+2 a (q^2) (x^2)+c (x^4)))dx
  ⟶  -((d x (Sqrt[a+b (x^2)+c (x^4)]))/(a (1+(q^2) (x^2))))+((d (1+(q^2) (x^2)) (Sqrt[((a+b (x^2)+c (x^4))/(a (((1+(q^2) (x^2)))^2)))]))/(q (Sqrt[a+b (x^2)+c (x^4)]))) EllipticE[2 ArcTan[q x],(1/2)-((b (q^2))/(4 c))]

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[c/a,4]},
  -d*x*Sqrt[a+b*x^2+c*x^4]/(a*(1+q^2*x^2)) + 
  d*(1+q^2*x^2)*Sqrt[(a+b*x^2+c*x^4)/(a*(1+q^2*x^2)^2)]/(q*Sqrt[a+b*x^2+c*x^4])*EllipticE[2*ArcTan[q*x],1/2-b*q^2/(4*c)] /;
 EqQ[e+d*q^2,0]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0] && GtQ[c/a,0] && LtQ[b/a,0]

2:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ (c/a)>0 ∧ (b/a)<0 ∧ e+d (Sqrt[(c/a)])≠0

Derivation: Algebraic expansion

Rule 1.2.2.3.5.3.1.2.1.2: If  (b^2)-4 a c>0 ∧ (c/a)>0 ∧ (b/a)<0, let q->(Sqrt[(c/a)]), if  e+d q≠0, then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  ((e+d q)/q) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx-(e/q) ∫((1-q (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[c/a,2]},
  (e+d*q)/q*Int[1/Sqrt[a+b*x^2+c*x^4],x] - e/q*Int[(1-q*x^2)/Sqrt[a+b*x^2+c*x^4],x] /;
 NeQ[e+d*q,0]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0] && GtQ[c/a,0] && LtQ[b/a,0]

2.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ a<0 ∧ c>0

1:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ a<0 ∧ c>0 ∧ 2 c d-e (b-(Sqrt[(b^2)-4 a c]))==0

Reference: G&R 3.153.2+

Rule 1.2.2.3.5.3.1.2.2.1: If  (b^2)-4 a c>0 ∧ a<0 ∧ c>0, let q->(Sqrt[(b^2)-4 a c]), if  2 c d-e (b-q)==0 , then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  ((e x (b+q+2 c (x^2)))/(2 c (Sqrt[a+b (x^2)+c (x^4)])))-((e q)/(2 c)) ∫((2 a+(b-q) (x^2))/(((a+b (x^2)+c (x^4)))^(3/2)))dx

  ⟶  ((e x (b+q+2 c (x^2)))/(2 c (Sqrt[a+b (x^2)+c (x^4)])))-((e q (Sqrt[((2 a+(b-q) (x^2))/(2 a+(b+q) (x^2)))]) (Sqrt[((2 a+(b+q) (x^2))/q)]))/(2 c (Sqrt[a+b (x^2)+c (x^4)]) (Sqrt[(a/(2 a+(b+q) (x^2)))]))) EllipticE[ArcSin[(x/(Sqrt[((2 a+(b+q) (x^2))/(2 q))]))],((b+q)/(2 q))]

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  e*x*(b+q+2*c*x^2)/(2*c*Sqrt[a+b*x^2+c*x^4]) - 
  e*q*Sqrt[(2*a+(b-q)*x^2)/(2*a+(b+q)*x^2)]*Sqrt[(2*a+(b+q)*x^2)/q]/(2*c*Sqrt[a+b*x^2+c*x^4]*Sqrt[a/(2*a+(b+q)*x^2)])*
    EllipticE[ArcSin[x/Sqrt[(2*a+(b+q)*x^2)/(2*q)]],(b+q)/(2*q)] /;
 EqQ[2*c*d-e*(b-q),0]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0] && LtQ[a,0] && GtQ[c,0]

Int[(d_+e_.*x_^2)/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  e*x*(q+c*x^2)/(c*Sqrt[a+c*x^4]) - 
  Sqrt[2]*e*q*Sqrt[-a+q*x^2]*Sqrt[(a+q*x^2)/q]/(Sqrt[-a]*c*Sqrt[a+c*x^4])*
    EllipticE[ArcSin[x/Sqrt[(a+q*x^2)/(2*q)]],1/2] /;
 EqQ[c*d+e*q,0] && IntegerQ[q]] /;
FreeQ[{a,c,d,e},x] && LtQ[a,0] && GtQ[c,0]

Int[(d_+e_.*x_^2)/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  e*x*(q+c*x^2)/(c*Sqrt[a+c*x^4]) - 
  Sqrt[2]*e*q*Sqrt[(a-q*x^2)/(a+q*x^2)]*Sqrt[(a+q*x^2)/q]/(c*Sqrt[a+c*x^4]*Sqrt[a/(a+q*x^2)])*
    EllipticE[ArcSin[x/Sqrt[(a+q*x^2)/(2*q)]],1/2] /;
 EqQ[c*d+e*q,0]] /;
FreeQ[{a,c,d,e},x] && LtQ[a,0] && GtQ[c,0]

2:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ a<0 ∧ c>0 ∧ 2 c d-e (b-(Sqrt[(b^2)-4 a c]))≠0

Derivation: Algebraic expansion

Rule 1.2.2.3.5.3.1.2.2.2: If  (b^2)-4 a c>0 ∧ a<0 ∧ c>0, let q->(Sqrt[(b^2)-4 a c]), if  2 c d-e (b-q)≠0, then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  ((2 c d-e (b-q))/(2 c)) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx+(e/(2 c)) ∫((b-q+2 c (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (2*c*d-e*(b-q))/(2*c)*Int[1/Sqrt[a+b*x^2+c*x^4],x] + e/(2*c)*Int[(b-q+2*c*x^2)/Sqrt[a+b*x^2+c*x^4],x] /;
 NeQ[2*c*d-e*(b-q),0]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0] && LtQ[a,0] && GtQ[c,0]

Int[(d_+e_.*x_^2)/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  (c*d+e*q)/c*Int[1/Sqrt[a+c*x^4],x] - e/c*Int[(q-c*x^2)/Sqrt[a+c*x^4],x] /;
 NeQ[c*d+e*q,0]] /;
FreeQ[{a,c,d,e},x] && LtQ[a,0] && GtQ[c,0]

3:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b±(Sqrt[(b^2)-4 a c]))/a)>0

Derivation: Algebraic expansion

Rule 1.2.2.3.5.3.1.2.3: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if ((b±q)/a)>0, then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  d ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx+e ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  d*Int[1/Sqrt[a+b*x^2+c*x^4],x] + e*Int[x^2/Sqrt[a+b*x^2+c*x^4],x] /;
 PosQ[(b+q)/a] || PosQ[(b-q)/a]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0]

Int[(d_+e_.*x_^2)/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  d*Int[1/Sqrt[a+c*x^4],x] + e*Int[x^2/Sqrt[a+c*x^4],x] /;
FreeQ[{a,c,d,e},x] && GtQ[-a*c,0]

4.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b±(Sqrt[(b^2)-4 a c]))/a)≯0

1.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b+(Sqrt[(b^2)-4 a c]))/a)≯0

1:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b+(Sqrt[(b^2)-4 a c]))/a)≯0 ∧ 2 c d-e (b+q)==0

Reference: G&R 3.153.5+

Rule 1.2.2.3.5.3.1.2.4.1.1: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if  ((b+q)/a)≯0 ∧ 2 c d-e (b+q)==0 then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  -(( a e (Sqrt[-((b+q)/(2 a))])(Sqrt[1+(((b+q) (x^2))/(2 a))]) (Sqrt[1+(((b-q) (x^2))/(2 a))]))/(c (Sqrt[a+b (x^2)+c (x^4)]))) EllipticE[ArcSin[(Sqrt[-((b+q)/(2 a))]) x],((b-q)/(b+q))]

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  -a*e*Rt[-(b+q)/(2*a),2]*Sqrt[1+(b+q)*x^2/(2*a)]*Sqrt[1+(b-q)*x^2/(2*a)]/(c*Sqrt[a+b*x^2+c*x^4])*
    EllipticE[ArcSin[Rt[-(b+q)/(2*a),2]*x],(b-q)/(b+q)] /;
 NegQ[(b+q)/a] && EqQ[2*c*d-e*(b+q),0] && Not[SimplerSqrtQ[-(b-q)/(2*a),-(b+q)/(2*a)]]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0]

2:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b+(Sqrt[(b^2)-4 a c]))/a)≯0 ∧ 2 c d-e (b+q)≠0

Derivation: Algebraic expansion

Rule 1.2.2.3.5.3.1.2.4.1.2: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if  ((b+q)/a)≯0 ∧ 2 c d-e (b+q)≠0 then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  ((2 c d-e (b+q))/(2 c)) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx+(e/(2 c)) ∫((b+q+2 c (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (2*c*d-e*(b+q))/(2*c)*Int[1/Sqrt[a+b*x^2+c*x^4],x] + e/(2*c)*Int[(b+q+2*c*x^2)/Sqrt[a+b*x^2+c*x^4],x] /;
 NegQ[(b+q)/a] && NeQ[2*c*d-e*(b+q),0] && Not[SimplerSqrtQ[-(b-q)/(2*a),-(b+q)/(2*a)]]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0]

2.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b-(Sqrt[(b^2)-4 a c]))/a)≯0

1:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b-(Sqrt[(b^2)-4 a c]))/a)≯0 ∧ 2 c d-e (b-q)==0

Reference: G&R 3.153.5-

Rule 1.2.2.3.5.3.1.2.4.2.1: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if  ((b-q)/a)≯0 ∧ 2 c d-e (b-q)==0 then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  -(( a e (Sqrt[-((b-q)/(2 a))])(Sqrt[1+(((b-q) (x^2))/(2 a))]) (Sqrt[1+(((b+q) (x^2))/(2 a))]))/(c (Sqrt[a+b (x^2)+c (x^4)]))) EllipticE[ArcSin[(Sqrt[-((b-q)/(2 a))]) x],((b+q)/(b-q))]

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  -a*e*Rt[-(b-q)/(2*a),2]*Sqrt[1+(b-q)*x^2/(2*a)]*Sqrt[1+(b+q)*x^2/(2*a)]/(c*Sqrt[a+b*x^2+c*x^4])*
    EllipticE[ArcSin[Rt[-(b-q)/(2*a),2]*x],(b+q)/(b-q)] /;
 NegQ[(b-q)/a] && EqQ[2*c*d-e*(b-q),0]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0]

2:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b-(Sqrt[(b^2)-4 a c]))/a)≯0 ∧ 2 c d-e (b-q)≠0

Derivation: Algebraic expansion

Rule 1.2.2.3.5.3.1.2.4.2.2: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if  ((b-q)/a)≯0 ∧ 2 c d-e (b-q)≠0 then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  ((2 c d-e (b-q))/(2 c)) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx+(e/(2 c)) ∫((b-q+2 c (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (2*c*d-e*(b-q))/(2*c)*Int[1/Sqrt[a+b*x^2+c*x^4],x] + e/(2*c)*Int[(b-q+2*c*x^2)/Sqrt[a+b*x^2+c*x^4],x] /;
 NegQ[(b-q)/a] && NeQ[2*c*d-e*(b-q),0]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0]

2.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≱0

1.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ (c/a)>0

1:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ (c/a)>0 ∧ e+d (Sqrt[(c/a)])==0

Reference: G&R 3.165.10

Rule 1.2.2.3.5.3.2.1.1: If  (b^2)-4 a c≠0 ∧ (c/a)>0, let q=((((c/a)))^(1/4)), if  e+d (q^2)==0, then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  -((d x (Sqrt[a+b (x^2)+c (x^4)]))/(a (1+(q^2) (x^2))))+2 d ∫((Sqrt[a+b (x^2)+c (x^4)])/(a+2 a (q^2) (x^2)+c (x^4)))dx
  ⟶  -((d x (Sqrt[a+b (x^2)+c (x^4)]))/(a (1+(q^2) (x^2))))+((d (1+(q^2) (x^2)) (Sqrt[((a+b (x^2)+c (x^4))/(a (((1+(q^2) (x^2)))^2)))]))/(q (Sqrt[a+b (x^2)+c (x^4)]))) EllipticE[2 ArcTan[q x],(1/2)-((b (q^2))/(4 c))]

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[c/a,4]},
  -d*x*Sqrt[a+b*x^2+c*x^4]/(a*(1+q^2*x^2)) + 
  d*(1+q^2*x^2)*Sqrt[(a+b*x^2+c*x^4)/(a*(1+q^2*x^2)^2)]/(q*Sqrt[a+b*x^2+c*x^4])*EllipticE[2*ArcTan[q*x],1/2-b*q^2/(4*c)] /;
 EqQ[e+d*q^2,0]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && PosQ[c/a]

Int[(d_+e_.*x_^2)/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[c/a,4]},
  -d*x*Sqrt[a+c*x^4]/(a*(1+q^2*x^2)) + 
  d*(1+q^2*x^2)*Sqrt[(a+c*x^4)/(a*(1+q^2*x^2)^2)]/(q*Sqrt[a+c*x^4])*EllipticE[2*ArcTan[q*x],1/2] /;
 EqQ[e+d*q^2,0]] /;
FreeQ[{a,c,d,e},x] && PosQ[c/a]

2:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ (c/a)>0 ∧ e+d (Sqrt[(c/a)])≠0

Derivation: Algebraic expansion

Rule 1.2.2.3.5.3.2.1.2: If  (b^2)-4 a c≠0 ∧ (c/a)>0, let q->(Sqrt[(c/a)]), if  e+d q≠0, then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  ((e+d q)/q) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx-(e/q) ∫((1-q (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[c/a,2]},
  (e+d*q)/q*Int[1/Sqrt[a+b*x^2+c*x^4],x] - e/q*Int[(1-q*x^2)/Sqrt[a+b*x^2+c*x^4],x] /;
 NeQ[e+d*q,0]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && PosQ[c/a]

Int[(d_+e_.*x_^2)/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[c/a,2]},
  (e+d*q)/q*Int[1/Sqrt[a+c*x^4],x] - e/q*Int[(1-q*x^2)/Sqrt[a+c*x^4],x] /;
 NeQ[e+d*q,0]] /;
FreeQ[{a,c,d,e},x] && PosQ[c/a]

2.  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ (c/a)≯0

1.  ∫((d+e (x^2))/(Sqrt[a+c (x^4)]))dx  when  (c/a)≯0

1.  ∫((d+e (x^2))/(Sqrt[a+c (x^4)]))dx  when  (c/a)≯0 ∧ c (d^2)+a (e^2)==0

1:  ∫((d+e (x^2))/(Sqrt[a+c (x^4)]))dx  when  (c/a)≯0 ∧ c (d^2)+a (e^2)==0 ∧ a>0

Derivation: Algebraic expansion

Basis: If  c (d^2)+a (e^2)==0 ∧ a>0, then ((d+e (x^2))/(Sqrt[a+c (x^4)]))==((d (Sqrt[1+((e (x^2))/d)]))/((Sqrt[a]) (Sqrt[1-((e (x^2))/d)])))

Rule 1.2.2.3.5.3.2.2.1.1.1: If  (c/a)≯0 ∧ c (d^2)+a (e^2)==0 ∧ a>0, then

∫((d+e (x^2))/(Sqrt[a+c (x^4)]))dx  ⟶  (( d)/(Sqrt[a]))∫((Sqrt[1+((e (x^2))/d)])/(Sqrt[1-((e (x^2))/d)]))dx

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  d/Sqrt[a]*Int[Sqrt[1+e*x^2/d]/Sqrt[1-e*x^2/d],x] /;
FreeQ[{a,c,d,e},x] && NegQ[c/a] && EqQ[c*d^2+a*e^2,0] && GtQ[a,0]

2:  ∫((d+e (x^2))/(Sqrt[a+c (x^4)]))dx  when  (c/a)≯0 ∧ c (d^2)+a (e^2)==0 ∧ a≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[1+((c (x^4))/a)])/(Sqrt[a+c (x^4)]))==0

Rule 1.2.2.3.5.3.2.2.1.1.2: If  (c/a)≯0 ∧ c (d^2)+a (e^2)==0 ∧ a≯0, then

∫((d+e (x^2))/(Sqrt[a+c (x^4)]))dx  ⟶  ((Sqrt[1+((c (x^4))/a)])/(Sqrt[a+c (x^4)]))∫((d+e (x^2))/(Sqrt[1+((c (x^4))/a)]))dx

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  Sqrt[1+c*x^4/a]/Sqrt[a+c*x^4]*Int[(d+e*x^2)/Sqrt[1+c*x^4/a],x] /;
FreeQ[{a,c,d,e},x] && NegQ[c/a] && EqQ[c*d^2+a*e^2,0] && Not[GtQ[a,0]]

2:  ∫((d+e (x^2))/(Sqrt[a+c (x^4)]))dx  when  (c/a)≯0 ∧ c (d^2)+a (e^2)≠0

Derivation: Algebraic expansion

Basis: d+e (x^2)==((d q-e)/q)+((e (1+q (x^2)))/q)

Rule 1.2.2.3.5.3.2.2.1.2: If (c/a)≯0 ∧ c (d^2)+a (e^2)≠0, let q->(Sqrt[-(c/a)]), then

∫((d+e (x^2))/(Sqrt[a+c (x^4)]))dx  ⟶  ((d q-e)/q)∫(1/(Sqrt[a+c (x^4)]))dx+(e/q)∫((1+q (x^2))/(Sqrt[a+c (x^4)]))dx

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[-c/a,2]},
  (d*q-e)/q*Int[1/Sqrt[a+c*x^4],x] + e/q*Int[(1+q*x^2)/Sqrt[a+c*x^4],x]] /;
FreeQ[{a,c,d,e},x] && NegQ[c/a] && NeQ[c*d^2+a*e^2,0]

2:  ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ (c/a)≯0

Derivation: Piecewise constant extraction

Basis: If  q->(Sqrt[(b^2)-4 a c]), then  (∂_x)(((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))]))/(Sqrt[a+b (x^2)+c (x^4)]))=0

Rule 1.2.2.3.5.3.2.2.2: If  (b^2)-4 a c≠0 ∧ (c/a)≯0, let q->(Sqrt[(b^2)-4 a c]), then

∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))]))/(Sqrt[a+b (x^2)+c (x^4)]))∫((d+e (x^2))/((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))])))dx

Program code:

Int[(d_+e_.*x_^2)/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  Sqrt[1+2*c*x^2/(b-q)]*Sqrt[1+2*c*x^2/(b+q)]/Sqrt[a+b*x^2+c*x^4]*
    Int[(d+e*x^2)/(Sqrt[1+2*c*x^2/(b-q)]*Sqrt[1+2*c*x^2/(b+q)]),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NegQ[c/a]

4:  ∫(d+e (x^2)) (((a+b (x^2)+c (x^4)))^p)dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Algebraic expansion

Rule 1.2.2.3.5.4: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫(d+e (x^2)) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫ExpandIntegrand[(d+e (x^2)) (((a+b (x^2)+c (x^4)))^p),x]dx

Program code:

Int[(d_+e_.*x_^2)*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)*(a+b*x^2+c*x^4)^p,x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[(d_+e_.*x_^2)*(a_+c_.*x_^4)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)*(a+c*x^4)^p,x],x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0]

6.  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q-1∈(SuperPlus[ℤ])

x:  ∫((((d+e (x^2)))^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Rule 1.2.2.3.6.x: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫((((d+e (x^2)))^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶ 

 (((e^2) x (Sqrt[a+b (x^2)+c (x^4)]))/(3 c))+((2 (3 c d-b e))/(3 c)) ∫((d+e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx-((3 c (d^2)-2 b d e+a (e^2))/(3 c)) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

(* Int[(d_+e_.*x_^2)^2/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  e^2*x*Sqrt[a+b*x^2+c*x^4]/(3*c) + 
  2*(3*c*d-b*e)/(3*c)*Int[(d+e*x^2)/Sqrt[a+b*x^2+c*x^4],x] - 
  (3*c*d^2-2*b*d*e+a*e^2)/(3*c)*Int[1/Sqrt[a+b*x^2+c*x^4],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] *)

(* Int[(d_+e_.*x_^2)^2/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  e^2*x*Sqrt[a+c*x^4]/(3*c) + 
  2*d*Int[(d+e*x^2)/Sqrt[a+c*x^4],x] - 
  (3*c*d^2+a*e^2)/(3*c)*Int[1/Sqrt[a+c*x^4],x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] *)

x:  ∫((((d+e (x^2)))^q)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ q-2∈(SuperPlus[ℤ])

Rule 1.2.2.3.6.x: If  (b^2)-4 a c≠0 ∧ q-2∈(SuperPlus[ℤ]), then

∫((((d+e (x^2)))^q)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶ 

 (((e^2) x (((d+e (x^2)))^(q-2)) (Sqrt[a+b (x^2)+c (x^4)]))/(c (2 q-1)))+((2 (q-1) (3 c d-b e))/(c (2 q-1))) ∫((((d+e (x^2)))^(q-1))/(Sqrt[a+b (x^2)+c (x^4)]))dx-
(((2 q-3) (3 c (d^2)-2 b d e+a (e^2)))/(c (2 q-1))) ∫((((d+e (x^2)))^(q-2))/(Sqrt[a+b (x^2)+c (x^4)]))dx+((2 d (q-2) (c (d^2)-b d e+a (e^2)))/(c (2 q-1)))∫((((d+e (x^2)))^(q-3))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

(* Int[(d_+e_.*x_^2)^q_/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  e^2*x*(d+e*x^2)^(q-2)*Sqrt[a+b*x^2+c*x^4]/(c*(2*q-1)) + 
  2*(q-1)*(3*c*d-b*e)/(c*(2*q-1))*Int[(d+e*x^2)^(q-1)/Sqrt[a+b*x^2+c*x^4],x] - 
  (2*q-3)*(3*c*d^2-2*b*d*e+a*e^2)/(c*(2*q-1))*Int[(d+e*x^2)^(q-2)/Sqrt[a+b*x^2+c*x^4],x] + 
  2*d*(q-2)*(c*d^2-b*d*e+a*e^2)/(c*(2*q-1))*Int[(d+e*x^2)^(q-3)/Sqrt[a+b*x^2+c*x^4],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && IGtQ[q,2] *)

(* Int[(d_+e_.*x_^2)^q_/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  e^2*x*(d+e*x^2)^(q-2)*Sqrt[a+c*x^4]/(c*(2*q-1)) + 
  6*d*(q-1)/(2*q-1)*Int[(d+e*x^2)^(q-1)/Sqrt[a+c*x^4],x] - 
  (2*q-3)*(3*c*d^2+a*e^2)/(c*(2*q-1))*Int[(d+e*x^2)^(q-2)/Sqrt[a+c*x^4],x] + 
  2*d*(q-2)*(c*d^2+a*e^2)/(c*(2*q-1))*Int[(d+e*x^2)^(q-3)/Sqrt[a+c*x^4],x] /;
FreeQ[{a,c,d,e},x] && IGtQ[q,2] *)

1:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q-1∈(SuperPlus[ℤ]) ∧ p<-1

Derivation: Algebraic expansion and trinomial recurrence 2b

Rule 1.2.2.3.6.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q-1∈(SuperPlus[ℤ]) ∧ p<-1, 
let (Subscript[Q, q-2])[(x^2)]->PolynomialQuotient[(((d+e (x^2)))^q),a+b (x^2)+c (x^4),x] and f+g (x^2)->PolynomialRemainder[(((d+e (x^2)))^q),a+b (x^2)+c (x^4),x], then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

∫(f+g (x^2)) (((a+b (x^2)+c (x^4)))^p)dx+∫(Subscript[Q, q-2])[(x^2)] (((a+b (x^2)+c (x^4)))^(p+1))dx  ⟶  

((x (((a+b (x^2)+c (x^4)))^(p+1)) (a b g-f ((b^2)-2 a c)-c (b f-2 a g) (x^2)))/(2 a (p+1) ((b^2)-4 a c)))+(1/(2 a (p+1) ((b^2)-4 a c)))∫(((a+b (x^2)+c (x^4)))^(p+1))·
(2 a (p+1) ((b^2)-4 a c) (Subscript[Q, q-2])[(x^2)]+(b^2) f (2 p+3)-2 a c f (4 p+5)-a b g+c (4 p+7)(b f-2 a g) (x^2) dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  With[{f=Coeff[PolynomialRemainder[(d+e*x^2)^q,a+b*x^2+c*x^4,x],x,0],
        g=Coeff[PolynomialRemainder[(d+e*x^2)^q,a+b*x^2+c*x^4,x],x,2]},
  x*(a+b*x^2+c*x^4)^(p+1)*(a*b*g-f*(b^2-2*a*c)-c*(b*f-2*a*g)*x^2)/(2*a*(p+1)*(b^2-4*a*c)) + 
  1/(2*a*(p+1)*(b^2-4*a*c))*Int[(a+b*x^2+c*x^4)^(p+1)*
    ExpandToSum[2*a*(p+1)*(b^2-4*a*c)*PolynomialQuotient[(d+e*x^2)^q,a+b*x^2+c*x^4,x]+
      b^2*f*(2*p+3)-2*a*c*f*(4*p+5)-a*b*g+c*(4*p+7)*(b*f-2*a*g)*x^2,x],x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[q,1] && LtQ[p,-1]

2:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q-1∈(SuperPlus[ℤ])∧ p≮-1

Derivation: Algebraic expansion and

Note: This rule reduces the degree of the polynomial factor (((d+e (x^2)))^q) in the resulting integrand.

Rule: 1.2.2.3.6.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q-1∈(SuperPlus[ℤ])∧ p≮-1, then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

∫((((d+e (x^2)))^q)-(e^q) (x^(2 q)))(((a+b (x^2)+c (x^4)))^p)dx+(e^q)∫(x^(2 q))(((a+b (x^2)+c (x^4)))^p)dx  ⟶  

(((e^q) (x^(2 q-3)) (((a+b (x^2)+c (x^4)))^(p+1)))/(c (4 p+2 q+1)))+(1/(c (4 p+2 q+1))) ∫(((a+b (x^2)+c (x^4)))^p)·
(c (4 p+2 q+1) (((d+e (x^2)))^q)-a (2 q-3) (e^q) (x^(2 q-4))-b (2 p+2 q-1) (e^q) (x^(2 q-2))-c (4 p+2 q+1) (e^q) (x^(2 q)))dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  e^q*x^(2*q-3)*(a+b*x^2+c*x^4)^(p+1)/(c*(4*p+2*q+1)) + 
  1/(c*(4*p+2*q+1))*Int[(a+b*x^2+c*x^4)^p*
    ExpandToSum[c*(4*p+2*q+1)*(d+e*x^2)^q-a*(2*q-3)*e^q*x^(2*q-4)-b*(2*p+2*q-1)*e^q*x^(2*q-2)-c*(4*p+2*q+1)*e^q*x^(2*q),x],x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[q,1]

Int[(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_,x_Symbol] :=
  e^q*x^(2*q-3)*(a+c*x^4)^(p+1)/(c*(4*p+2*q+1)) + 
  1/(c*(4*p+2*q+1))*Int[(a+c*x^4)^p*
    ExpandToSum[c*(4*p+2*q+1)*(d+e*x^2)^q-a*(2*q-3)*e^q*x^(2*q-4)-c*(4*p+2*q+1)*e^q*x^(2*q),x],x] /;
FreeQ[{a,c,d,e,p},x] && NeQ[c*d^2+a*e^2,0] && IGtQ[q,1]

7.  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p+(1/2)∈ℤ ∧ q∈(SuperMinus[ℤ])

1.  ∫((((a+b (x^2)+c (x^4)))^p)/(d+e (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p+(1/2)∈ℤ

1:  ∫((((a+b (x^2)+c (x^4)))^p)/(d+e (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p+(1/2)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: ((a+b (x^2)+c (x^4))/(d+e (x^2)))==-((c d-b e-c e (x^2))/(e^2))+((c (d^2)-b d e+a (e^2))/((e^2) (d+e (x^2))))

Rule 1.2.2.3.7.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p+(1/2)∈(SuperPlus[ℤ]), then

∫((((a+b (x^2)+c (x^4)))^p)/(d+e (x^2)))dx  ⟶  -(1/(e^2)) ∫(c d-b e-c e (x^2)) (((a+b (x^2)+c (x^4)))^(p-1))dx+((c (d^2)-b d e+a (e^2))/(e^2)) ∫((((a+b (x^2)+c (x^4)))^(p-1))/( d+e (x^2)))dx

Program code:

Int[(a_+b_.*x_^2+c_.*x_^4)^p_/(d_+e_.*x_^2),x_Symbol] :=
  -1/e^2*Int[(c*d-b*e-c*e*x^2)*(a+b*x^2+c*x^4)^(p-1),x] + 
  (c*d^2-b*d*e+a*e^2)/e^2*Int[(a+b*x^2+c*x^4)^(p-1)/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[p+1/2,0]

Int[(a_+c_.*x_^4)^p_/(d_+e_.*x_^2),x_Symbol] :=
  -1/e^2*Int[(c*d-c*e*x^2)*(a+c*x^4)^(p-1),x] + 
  (c*d^2+a*e^2)/e^2*Int[(a+c*x^4)^(p-1)/(d+e*x^2),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && IGtQ[p+1/2,0]

2.  ∫((((a+b (x^2)+c (x^4)))^p)/(d+e (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p-(1/2)∈(SuperMinus[ℤ])

1.  ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1:  ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ c (d^2)-a (e^2)==0

Derivation: Algebraic expansion

Basis: (1/(d+e (x^2)))==(1/(2 d))+((d-e (x^2))/(2 d (d+e (x^2))))

Rule 1.2.2.3.7.2.1.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ c (d^2)-a (e^2)==0, then

∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  (1/(2 d)) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx+(1/(2 d)) ∫((d-e (x^2))/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[1/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  1/(2*d)*Int[1/Sqrt[a+b*x^2+c*x^4],x] + 1/(2*d)*Int[(d-e*x^2)/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4]),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && EqQ[c*d^2-a*e^2,0]

Int[1/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  1/(2*d)*Int[1/Sqrt[a+c*x^4],x] + 1/(2*d)*Int[(d-e*x^2)/((d+e*x^2)*Sqrt[a+c*x^4]),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && EqQ[c*d^2-a*e^2,0]

2.  ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ c (d^2)-a (e^2)≠0

1.  ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when  (b^2)-4 a c>0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ c (d^2)-a (e^2)≠0

1:  ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c>0 ∧ c<0

Derivation: Algebraic expansion

Basis: If  (b^2)-4 a c>0 ∧ c<0, let q->(Sqrt[(b^2)-4 a c]), then  (Sqrt[a+b (x^2)+c (x^4)])==(1/(2 (Sqrt[-c]))) (Sqrt[b+q+2 c (x^2)]) (Sqrt[-b+q-2 c (x^2)])

Rule 1.2.2.3.7.2.1.2.1.1: If  (b^2)-4 a c>0 ∧ c<0, let q->(Sqrt[(b^2)-4 a c]), then

∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  2 (Sqrt[-c])∫(1/((d+e (x^2)) (Sqrt[b+q+2 c (x^2)]) (Sqrt[-b+q-2 c (x^2)])))dx

Program code:

Int[1/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  2*Sqrt[-c]*Int[1/((d+e*x^2)*Sqrt[b+q+2*c*x^2]*Sqrt[-b+q-2*c*x^2]),x]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0] && LtQ[c,0]

Int[1/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  Sqrt[-c]*Int[1/((d+e*x^2)*Sqrt[q+c*x^2]*Sqrt[q-c*x^2]),x]] /;
FreeQ[{a,c,d,e},x] && GtQ[a,0] && LtQ[c,0]

2:  ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c>0 ∧ c≮0

Derivation: Algebraic expansion

Basis: (1/(d+e (x^2)))==((2 c)/(2 c d-e (b-q)))-((e (b-q+2 c (x^2)))/((2 c d-e (b-q)) (d+e (x^2))))

Rule 1.2.2.3.7.2.1.2.1.2: If  (b^2)-4 a c>0 ∧ c≮0, let q->(Sqrt[(b^2)-4 a c]), then

∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  ((2 c)/(2 c d-e (b-q)))∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx-(e/(2 c d-e (b-q)))∫((b-q+2 c (x^2))/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[1/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  2*c/(2*c*d-e*(b-q))*Int[1/Sqrt[a+b*x^2+c*x^4],x] - e/(2*c*d-e*(b-q))*Int[(b-q+2*c*x^2)/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4]),x]] /;
FreeQ[{a,b,c,d,e},x] && GtQ[b^2-4*a*c,0] && Not[LtQ[c,0]]

Int[1/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  c/(c*d+e*q)*Int[1/Sqrt[a+c*x^4],x] + e/(c*d+e*q)*Int[(q-c*x^2)/((d+e*x^2)*Sqrt[a+c*x^4]),x]] /;
FreeQ[{a,c,d,e},x] && GtQ[-a*c,0] && Not[LtQ[c,0]]

2.  ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ c (d^2)-a (e^2)≠0

1:  ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ c (d^2)-a (e^2)≠0 ∧ (c/a)>0

Derivation: Algebraic expansion

Rule 1.2.2.3.7.2.1.2.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ c (d^2)-a (e^2)≠0 ∧ (c/a)>0, let q->(Sqrt[(c/a)]), then

∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  ((c d+a e q)/(c (d^2)-a (e^2))) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx-((a e (e+d q))/(c (d^2)-a (e^2))) ∫((1+q (x^2))/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[1/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[c/a,2]},
  (c*d+a*e*q)/(c*d^2-a*e^2)*Int[1/Sqrt[a+b*x^2+c*x^4],x] - 
  (a*e*(e+d*q))/(c*d^2-a*e^2)*Int[(1+q*x^2)/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4]),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[c*d^2-a*e^2,0] && PosQ[c/a]

Int[1/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[c/a,2]},
  (c*d+a*e*q)/(c*d^2-a*e^2)*Int[1/Sqrt[a+c*x^4],x] - 
  (a*e*(e+d*q))/(c*d^2-a*e^2)*Int[(1+q*x^2)/((d+e*x^2)*Sqrt[a+c*x^4]),x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && NeQ[c*d^2-a*e^2,0] && PosQ[c/a]

2.  ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ c (d^2)-a (e^2)≠0 ∧ (c/a)≯0

1.  ∫(1/((d+e (x^2)) (Sqrt[a+c (x^4)])))dx  when (c/a)≯0

1:  ∫(1/((d+e (x^2))(Sqrt[a+c (x^4)])))dx  when (c/a)≯0 ∧ a>0

Rule 1.2.2.3.7.2.1.2.2.2.1.1: If  (c/a)≯0 ∧ a>0, let q->(((-(c/a)))^(1/4)), then

∫(1/((d+e (x^2))(Sqrt[a+c (x^4)])))dx  ⟶  (1/(d (Sqrt[a]) q))EllipticPi[-(e/(d (q^2))),ArcSin[q x],-1]

Program code:

Int[1/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[-c/a,4]},
  1/(d*Sqrt[a]*q)*EllipticPi[-e/(d*q^2),ArcSin[q*x],-1]] /;
FreeQ[{a,c,d,e},x] && NegQ[c/a] && GtQ[a,0]

2:  ∫(1/((d+e (x^2))(Sqrt[a+c (x^4)])))dx  when (c/a)≯0 ∧ a≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[((a+c (x^4))/a)])/(Sqrt[a+c (x^4)]))==0

Rule 1.2.2.3.7.1.2.2.2.1.2: If  (c/a)≯0 ∧ a≯0, then

∫(1/((d+e (x^2))(Sqrt[a+c (x^4)])))dx  ⟶  ((Sqrt[1+((c (x^4))/a)])/(Sqrt[a+c (x^4)]))∫(1/((d+e (x^2)) (Sqrt[1+((c (x^4))/a)])))dx

Program code:

Int[1/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  Sqrt[1+c*x^4/a]/Sqrt[a+c*x^4]*Int[1/((d+e*x^2)*Sqrt[1+c*x^4/a]),x] /;
FreeQ[{a,c,d,e},x] && NegQ[c/a] && Not[GtQ[a,0]]

2:  ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ (c/a)≯0

Derivation: Piecewise constant extraction

Basis: Let q->(Sqrt[(b^2)-4 a c]), then (∂_x)(((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))]))/(Sqrt[a+b (x^2)+c (x^4)]))==0

Rule 1.2.2.3.7.1.2.2.2.2: If  (b^2)-4 a c≠0 ∧ (c/a)≯0, let q->(Sqrt[(b^2)-4 a c]), then

∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  (((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))]))/(Sqrt[a+b (x^2)+c (x^4)]))∫(1/((d+e (x^2))(Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))])))dx

Program code:

Int[1/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  Sqrt[1+2*c*x^2/(b-q)]*Sqrt[1+2*c*x^2/(b+q)]/Sqrt[a+b*x^2+c*x^4]*
    Int[1/((d+e*x^2)*Sqrt[1+2*c*x^2/(b-q)]*Sqrt[1+2*c*x^2/(b+q)]),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NegQ[c/a]

2:  ∫((((a+b (x^2)+c (x^4)))^p)/(d+e (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p+(1/2)∈(SuperMinus[ℤ])

Derivation: Algebraic expansion

Basis: (1/(d+e (x^2)))==((c d-b e-c e (x^2))/(c (d^2)-b d e+a (e^2)))+(((e^2) (a+b (x^2)+c (x^4)))/((c (d^2)-b d e+a (e^2)) (d+e (x^2))))

Rule 1.2.2.3.7.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p+(1/2)∈(SuperMinus[ℤ]), then

∫((((a+b (x^2)+c (x^4)))^p)/( d+e (x^2)))dx  ⟶  (1/(c (d^2)-b d e+a (e^2))) ∫(c d-b e-c e (x^2)) (((a+b (x^2)+c (x^4)))^p)dx+((e^2)/(c (d^2)-b d e+a (e^2))) ∫((((a+b (x^2)+c (x^4)))^(p+1))/(d+e (x^2)))dx

Program code:

Int[(a_+b_.*x_^2+c_.*x_^4)^p_/(d_+e_.*x_^2),x_Symbol] :=
  1/(c*d^2-b*d*e+a*e^2)*Int[(c*d-b*e-c*e*x^2)*(a+b*x^2+c*x^4)^p,x] + 
  e^2/(c*d^2-b*d*e+a*e^2)*Int[(a+b*x^2+c*x^4)^(p+1)/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && ILtQ[p+1/2,0]

Int[(a_+c_.*x_^4)^p_/(d_+e_.*x_^2),x_Symbol] :=
  1/(c*d^2+a*e^2)*Int[(c*d-c*e*x^2)*(a+c*x^4)^p,x] + 
  e^2/(c*d^2+a*e^2)*Int[(a+c*x^4)^(p+1)/(d+e*x^2),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && ILtQ[p+1/2,0]

2.  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ p+(1/2)∈ℤ ∧ q+1∈(SuperMinus[ℤ])

1:  ∫((((d+e (x^2)))^q)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ q+1∈(SuperMinus[ℤ])

Rule 1.2.2.3.7.2.1: If  (b^2)-4 a c≠0 ∧ q+1∈(SuperMinus[ℤ]), then

∫((((d+e (x^2)))^q)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  

-(((e^2) x (((d+e (x^2)))^(q+1)) (Sqrt[a+b (x^2)+c (x^4)]))/(2 d (q+1) (c (d^2)-b d e+a (e^2))))+
(1/(2 d (q+1) (c (d^2)-b d e+a (e^2))))∫(((((d+e (x^2)))^(q+1)) (a (e^2) (2 q+3)+2 d (c d-b e) (q+1)-2 e (c d (q+1)-b e (q+2)) (x^2)+c (e^2) (2 q+5) (x^4)))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[(d_+e_.*x_^2)^q_/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  -e^2*x*(d+e*x^2)^(q+1)*Sqrt[a+b*x^2+c*x^4]/(2*d*(q+1)*(c*d^2-b*d*e+a*e^2)) + 
  1/(2*d*(q+1)*(c*d^2-b*d*e+a*e^2))*Int[(d+e*x^2)^(q+1)/Sqrt[a+b*x^2+c*x^4]*
    Simp[a*e^2*(2*q+3)+2*d*(c*d-b*e)*(q+1)-2*e*(c*d*(q+1)-b*e*(q+2))*x^2+c*e^2*(2*q+5)*x^4,x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && ILtQ[q,-1]

Int[(d_+e_.*x_^2)^q_/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  -e^2*x*(d+e*x^2)^(q+1)*Sqrt[a+c*x^4]/(2*d*(q+1)*(c*d^2+a*e^2)) + 
  1/(2*d*(q+1)*(c*d^2+a*e^2))*Int[(d+e*x^2)^(q+1)/Sqrt[a+c*x^4]*
    Simp[a*e^2*(2*q+3)+2*c*d^2*(q+1)-2*e*c*d*(q+1)*x^2+c*e^2*(2*q+5)*x^4,x],x] /;
FreeQ[{a,c,d,e},x] && ILtQ[q,-1]

2.  ∫((Sqrt[a+b (x^2)+c (x^4)])/(((d+e (x^2)))^2))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1:  ∫((Sqrt[a+b (x^2)+c (x^4)])/(((d+e (x^2)))^2))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ c (d^2)-a (e^2)==0 ∧ (e/d)>0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((d+e (x^2)) (Sqrt[(((e^2) (a+b (x^2)+c (x^4)))/(c (((d+e (x^2)))^2)))]))/(Sqrt[a+b (x^2)+c (x^4)]))==0

Rule 1.2.2.3.7.2.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ c (d^2)-a (e^2)==0 ∧ (e/d)>0, let q->(Sqrt[(e/d)]) , then

∫((Sqrt[a+b (x^2)+c (x^4)])/(((d+e (x^2)))^2))dx  ⟶  ((c (d+e (x^2)) (Sqrt[(((e^2) (a+b (x^2)+c (x^4)))/(c (((d+e (x^2)))^2)))]))/(2 d (e^2) q (Sqrt[a+b (x^2)+c (x^4)]))) EllipticE[2 ArcTan[q x],((2 c d-b e)/(4 c d))]

Program code:

Int[Sqrt[a_+b_.*x_^2+c_.*x_^4]/(d_+e_.*x_^2)^2,x_Symbol] :=
  With[{q=Rt[e/d,2]},
  c*(d+e*x^2)*Sqrt[(e^2*(a+b*x^2+c*x^4))/(c*(d+e*x^2)^2)]/(2*d*e^2*q*Sqrt[a+b*x^2+c*x^4])*
    EllipticE[2*ArcTan[q*x],(2*c*d-b*e)/(4*c*d)]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && EqQ[c*d^2-a*e^2,0] && PosQ[e/d]

2:  ∫((Sqrt[a+b (x^2)+c (x^4)])/(((d+e (x^2)))^2))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Algebraic expansion, integration by parts and algebraic expansion

Basis: (1/(((d+e (x^2)))^2))==((d-e (x^2))/(2 d (((d+e (x^2)))^2)))+(1/(2 d (d+e (x^2))))

Basis: (∂_x)(x/(d+e (x^2)))==((d-e (x^2))/(((d+e (x^2)))^2))

Basis: ((a-c (x^4))/(d+e (x^2)))==((c (d-e (x^2)))/(e^2))-((c (d^2)-a (e^2))/((e^2) (d+e (x^2))))

Rule 1.2.2.3.7.2.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫((Sqrt[a+b (x^2)+c (x^4)])/(((d+e (x^2)))^2))dx  ⟶  (1/(2 d)) ∫(((d-e (x^2)) (Sqrt[a+b (x^2)+c (x^4)]))/(((d+e (x^2)))^2))dx+(1/(2 d))∫((Sqrt[a+b (x^2)+c (x^4)])/(d+e (x^2)))dx

  ⟶  ((x (Sqrt[a+b (x^2)+c (x^4)]))/(2 d (d+e (x^2))))-(1/(2 d))∫(((x^2) (b+2 c (x^2)))/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx+(1/(2 d))∫((Sqrt[a+b (x^2)+c (x^4)])/(d+e (x^2)))dx

  ⟶  ((x (Sqrt[a+b (x^2)+c (x^4)]))/(2 d (d+e (x^2))))+(1/(2 d))∫((a-c (x^4))/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

  ⟶  ((x (Sqrt[a+b (x^2)+c (x^4)]))/(2 d (d+e (x^2))))+(c/(2 d (e^2)))∫((d-e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx-((c (d^2)-a (e^2))/(2 d (e^2))) ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[Sqrt[a_+b_.*x_^2+c_.*x_^4]/(d_+e_.*x_^2)^2,x_Symbol] :=
  x*Sqrt[a+b*x^2+c*x^4]/(2*d*(d+e*x^2)) + 
  c/(2*d*e^2)*Int[(d-e*x^2)/Sqrt[a+b*x^2+c*x^4],x] - 
  (c*d^2-a*e^2)/(2*d*e^2)*Int[1/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4]),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[Sqrt[a_+c_.*x_^4]/(d_+e_.*x_^2)^2,x_Symbol] :=
  x*Sqrt[a+c*x^4]/(2*d*(d+e*x^2)) + 
  c/(2*d*e^2)*Int[(d-e*x^2)/Sqrt[a+c*x^4],x] - 
  (c*d^2-a*e^2)/(2*d*e^2)*Int[1/((d+e*x^2)*Sqrt[a+c*x^4]),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0]

3:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∈(SuperMinus[ℤ])∧ p+(1/2)∈ℤ

Derivation: Algebraic expansion

Note: Need to replace with a recurrence!

Rule 1.2.2.3.7.2.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∈(SuperMinus[ℤ])∧ p+(1/2)∈ℤ, then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫((ExpandIntegrand[(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^(p+(1/2))),x])/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  Module[{aa,bb,cc},
  Int[ReplaceAll[ExpandIntegrand[1/Sqrt[aa+bb*x^2+cc*x^4],(d+e*x^2)^q*(aa+bb*x^2+cc*x^4)^(p+1/2),x],{aa->a,bb->b,cc->c}],x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && ILtQ[q,0] && IntegerQ[p+1/2]

Int[(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_,x_Symbol] :=
  Module[{aa,cc},
  Int[ReplaceAll[ExpandIntegrand[1/Sqrt[aa+cc*x^4],(d+e*x^2)^q*(aa+cc*x^4)^(p+1/2),x],{aa->a,cc->c}],x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && ILtQ[q,0] && IntegerQ[p+1/2]

8.  ∫(1/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1.  ∫(1/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))dx  when c d-b e==0

1:  ∫(1/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))dx  when c d-b e==0 ∧ a>0 ∧ d>0

Rule 1.2.2.3.8.1.1: If  c d-b e==0 ∧ a>0 ∧ d>0, then

∫(1/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  (1/(2 (Sqrt[a]) (Sqrt[d]) (Sqrt[-(e/d)]))) EllipticF[2 ArcSin[(Sqrt[-(e/d)]) x],((b d)/(4 a e))]

Program code:

Int[1/(Sqrt[d_+e_.*x_^2]*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  1/(2*Sqrt[a]*Sqrt[d]*Rt[-e/d,2])*EllipticF[2*ArcSin[Rt[-e/d,2]*x],b*d/(4*a*e)] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c*d-b*e,0] && GtQ[a,0] && GtQ[d,0]

2:  ∫(1/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))dx  when c d-b e==0 ∧ ¬(a>0 ∧ d>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sqrt[((a+b (x^2)+c (x^4))/a)]) (Sqrt[((d+e (x^2))/d)]))/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))==0

Rule 1.2.2.3.8.1.2: If  c d-b e==0 ∧ ¬(a>0 ∧ d>0), then

∫(1/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  (((Sqrt[((d+e (x^2))/d)]) (Sqrt[((a+b (x^2)+c (x^4))/a)]))/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))∫(1/((Sqrt[1+(e/d) (x^2)]) (Sqrt[1+(b/a) (x^2)+(c/a) (x^4)])))dx

Program code:

Int[1/(Sqrt[d_+e_.*x_^2]*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  Sqrt[(d+e*x^2)/d]*Sqrt[(a+b*x^2+c*x^4)/a]/(Sqrt[d+e*x^2]*Sqrt[a+b*x^2+c*x^4])*
    Int[1/(Sqrt[1+e/d*x^2]*Sqrt[1+b/a*x^2+c/a*x^4]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c*d-b*e,0] && Not[GtQ[a,0] && GtQ[d,0]]

2:  ∫(1/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Piecewise constant extraction

Basis: (∂_x)((x (Sqrt[e+(d/(x^2))]))/(Sqrt[d+e (x^2)]))==0

Basis: (∂_x)(((x^2) (Sqrt[c+(b/(x^2))+(a/(x^4))]))/(Sqrt[a+b (x^2)+c (x^4)]))==0

Note: The resulting integrand can be reduced to an integrand of the form (1/((Sqrt[e+d x]) (Sqrt[c+b x+a (x^2)]))) using the substitution x->(1/(x^2)).

Rule 1.2.2.3.8.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫(1/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  (((x^3) (Sqrt[e+(d/(x^2))]) (Sqrt[c+(b/(x^2))+(a/(x^4))]))/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))∫(1/((x^3) (Sqrt[e+(d/(x^2))]) (Sqrt[c+(b/(x^2))+(a/(x^4))])))dx

Program code:

Int[1/(Sqrt[d_+e_.*x_^2]*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  x^3*Sqrt[e+d/x^2]*Sqrt[c+b/x^2+a/x^4]/(Sqrt[d+e*x^2]*Sqrt[a+b*x^2+c*x^4])*
    Int[1/(x^3*Sqrt[e+d/x^2]*Sqrt[c+b/x^2+a/x^4]),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[1/(Sqrt[d_+e_.*x_^2]*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  x^3*Sqrt[e+d/x^2]*Sqrt[c+a/x^4]/(Sqrt[d+e*x^2]*Sqrt[a+c*x^4])*
    Int[1/(x^3*Sqrt[e+d/x^2]*Sqrt[c+a/x^4]),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0]

9.  ∫((Sqrt[a+b (x^2)+c (x^4)])/(Sqrt[d+e (x^2)]))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1.  ∫((Sqrt[a+b (x^2)+c (x^4)])/(Sqrt[d+e (x^2)]))dx  when c d-b e==0

1:  ∫((Sqrt[a+b (x^2)+c (x^4)])/(Sqrt[d+e (x^2)]))dx  when c d-b e==0 ∧ a>0 ∧ d>0

Rule 1.2.2.3.9.1.1: If  c d-b e==0 ∧ a>0 ∧ d>0, then

∫((Sqrt[a+b (x^2)+c (x^4)])/(Sqrt[d+e (x^2)]))dx  ⟶  ((Sqrt[a])/(2 (Sqrt[d]) (Sqrt[-(e/d)]))) EllipticE[2 ArcSin[(Sqrt[-(e/d)]) x],((b d)/(4 a e))]

Program code:

Int[Sqrt[a_+b_.*x_^2+c_.*x_^4]/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  Sqrt[a]/(2*Sqrt[d]*Rt[-e/d,2])*EllipticE[2*ArcSin[Rt[-e/d,2]*x],b*d/(4*a*e)] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c*d-b*e,0] && GtQ[a,0] && GtQ[d,0]

2:  ∫((Sqrt[a+b (x^2)+c (x^4)])/(Sqrt[d+e (x^2)]))dx  when c d-b e==0 ∧ ¬(a>0 ∧ d>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sqrt[a+b (x^2)+c (x^4)]) (Sqrt[((d+e (x^2))/d)]))/((Sqrt[d+e (x^2)]) (Sqrt[((a+b (x^2)+c (x^4))/a)])))==0

Rule 1.2.2.3.9.1.2: If  c d-b e==0 ∧ ¬(a>0 ∧ d>0), then

∫((Sqrt[a+b (x^2)+c (x^4)])/(Sqrt[d+e (x^2)]))dx  ⟶  (((Sqrt[a+b (x^2)+c (x^4)])(Sqrt[((d+e (x^2))/d)]) )/((Sqrt[d+e (x^2)])(Sqrt[((a+b (x^2)+c (x^4))/a)])))∫((Sqrt[1+(b/a) (x^2)+(c/a) (x^4)])/(Sqrt[1+(e/d) (x^2)]))dx

Program code:

Int[Sqrt[a_+b_.*x_^2+c_.*x_^4]/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  Sqrt[a+b*x^2+c*x^4]*Sqrt[(d+e*x^2)/d]/(Sqrt[d+e*x^2]*Sqrt[(a+b*x^2+c*x^4)/a])*
    Int[Sqrt[1+b/a*x^2+c/a*x^4]/Sqrt[1+e/d*x^2],x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c*d-b*e,0] && Not[GtQ[a,0] && GtQ[d,0]]

2:  ∫((Sqrt[a+b (x^2)+c (x^4)])/(Sqrt[d+e (x^2)]))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Piecewise constant extraction

Basis: (∂_x)((x (Sqrt[e+(d/(x^2))]))/(Sqrt[d+e (x^2)]))==0

Basis: (∂_x)((Sqrt[a+b (x^2)+c (x^4)])/((x^2) (Sqrt[c+(b/(x^2))+(a/(x^4))])))==0

Note: The resulting integrand can be reduced to an integrand of the form (1/((Sqrt[e+d x]) (Sqrt[c+b x+a (x^2)]))) using the substitution x->(1/(x^2)).

Rule 1.2.2.3.9.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫((Sqrt[a+b (x^2)+c (x^4)])/(Sqrt[d+e (x^2)]))dx  ⟶  (((Sqrt[e+(d/(x^2))]) (Sqrt[a+b (x^2)+c (x^4)]))/(x (Sqrt[d+e (x^2)]) (Sqrt[c+(b/(x^2))+(a/(x^4))])))∫((x (Sqrt[c+(b/(x^2))+(a/(x^4))]))/(Sqrt[e+(d/(x^2))]))dx

Program code:

Int[Sqrt[a_+b_.*x_^2+c_.*x_^4]/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  Sqrt[e+d/x^2]*Sqrt[a+b*x^2+c*x^4]/(x*Sqrt[d+e*x^2]*Sqrt[c+b/x^2+a/x^4])*
    Int[(x*Sqrt[c+b/x^2+a/x^4])/Sqrt[e+d/x^2],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[Sqrt[a_+c_.*x_^4]/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  Sqrt[e+d/x^2]*Sqrt[a+c*x^4]/(x*Sqrt[d+e*x^2]*Sqrt[c+a/x^4])*
    Int[(x*Sqrt[c+a/x^4])/Sqrt[e+d/x^2],x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0]

10:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ ((p|q)∈ℤ ∨ p∈(SuperPlus[ℤ])∨ q∈(SuperPlus[ℤ]))

Derivation: Algebraic expansion

Rule 1.2.2.3.10: If  (b^2)-4 a c≠0 ∧ ((p|q)∈ℤ ∨ p∈(SuperPlus[ℤ])∨ q∈(SuperPlus[ℤ])), then

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫ExpandIntegrand[(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p),x]dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^q*(a+b*x^2+c*x^4)^p,x],x] /;
FreeQ[{a,b,c,d,e,p,q},x] && NeQ[b^2-4*a*c,0] && (IntegerQ[p] && IntegerQ[q] || IGtQ[p,0] || IGtQ[q,0])

Int[(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^q*(a+c*x^4)^p,x],x] /;
FreeQ[{a,c,d,e,p,q},x] && (IntegerQ[p] && IntegerQ[q] || IGtQ[p,0])

11:  ∫(((d+e (x^2)))^q) (((a+c (x^4)))^p)dx  when c (d^2)+a (e^2)≠0 ∧ p∉ℤ ∧ q∈(SuperMinus[ℤ])

Derivation: Algebraic expansion

Basis: If  q∈ℤ, then (((d+e (x^2)))^q)==((((d/((d^2)-(e^2) (x^4)))-((e (x^2))/((d^2)-(e^2) (x^4)))))^(-q))

Note: Resulting integrands are of the form (x^m) (((a+b (x^4)))^p) (((c+d (x^4)))^q) which are integrable in terms of the Appell hypergeometric function .

Rule 1.2.2.3.11: If  c (d^2)+a (e^2)≠0 ∧ p∉ℤ ∧ q∈(SuperMinus[ℤ]), then

∫(((d+e (x^2)))^q) (((a+c (x^4)))^p)dx  ⟶  ∫(((a+c (x^4)))^p) ExpandIntegrand[((((d/((d^2)-(e^2) (x^4)))-((e (x^2))/((d^2)-(e^2) (x^4)))))^(-q)),x]dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+c*x^4)^p,(d/(d^2-e^2*x^4)-e*x^2/(d^2-e^2*x^4))^(-q),x],x] /;
FreeQ[{a,c,d,e,p},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && ILtQ[q,0]

U:  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx

Rule 1.2.2.3.U:

∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫(((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  Unintegrable[(d+e*x^2)^q*(a+b*x^2+c*x^4)^p,x] /;
FreeQ[{a,b,c,d,e,p,q},x]

Int[(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  Unintegrable[(d+e*x^2)^q*(a+c*x^4)^p,x] /;
FreeQ[{a,c,d,e,p,q},x]