Rules for integrands of the form(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)

1.  ∫(((f x))^m) (((e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx

x:  ∫(((f x))^m) (((e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when m∈q

Derivation: Algebraic simplification

Basis: If  m∈q, then (((e (x^2)))^q)==((e^q)/(f^(2 q))) (((f x))^(2 q))

Rule 1.2.2.4.1.1: If  m∈q, then

∫(((f x))^m) (((e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((e^q)/(f^(2 q)))∫(((f x))^(m+2 q)) (((a+b (x^2)+c (x^4)))^p)dx

Program code:

(* Int[(f_.*x_)^m_.*(e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  e^q/f^(2*q)*Int[(f*x)^(m+2*q)*(a+b*x^2+c*x^4)^p,x] /;
FreeQ[{a,b,c,e,f,m,p},x] && IntegerQ[q] *)

(* Int[(f_.*x_)^m_.*(e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  e^q/f^(2*q)*Int[(f*x)^(m+2*q)*(a+c*x^4)^p,x] /;
FreeQ[{a,c,e,f,m,p},x] && IntegerQ[q] *)

2.  ∫(((f x))^m) (((e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when q∉ℤ

1:  ∫(x^m) (((e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p) dx  when q∉ℤ ∧ ((m-1)/2)∈ℤ

Derivation: Integration by substitution

Basis: If  ((m-1)/2)∈ℤ, then (x^m) (((e (x^2)))^q)==(1/(e^((m-1)/2))) x (((e (x^2)))^(q+((m-1)/2)))

Basis: x F[(x^2)]==(1/2) Subst[F[x],x,(x^2)] (∂_x)(x^2)

Rule 1.2.2.4.1.2.1: If q∉ℤ ∧ ((m-1)/2)∈ℤ, then

∫(x^m) (((e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p) dx  ⟶  (1/(2 (e^((m-1)/2)))) Subst[∫(((e x))^(q+((m-1)/2))) (((a+b x+c (x^2)))^p)dx,x,(x^2)]

Program code:

Int[x_^m_.*(e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  1/(2*e^((m-1)/2))*Subst[Int[(e*x)^(q+(m-1)/2)*(a+b*x+c*x^2)^p,x],x,x^2] /;
FreeQ[{a,b,c,e,p,q},x] && Not[IntegerQ[q]] && IntegerQ[(m-1)/2]

Int[x_^m_.*(e_.*x_^2)^q_*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  1/(2*e^((m-1)/2))*Subst[Int[(e*x)^(q+(m-1)/2)*(a+c*x^2)^p,x],x,x^2] /;
FreeQ[{a,c,e,p,q},x] && Not[IntegerQ[q]] && IntegerQ[(m-1)/2]

2:  ∫(((f x))^m) (((e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when q∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e (x^2)))^q)/(((f x))^(2 q)))==0

Rule 1.2.2.4.1.2.2: If  q∉ℤ, then

∫(((f x))^m) (((e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (((e^(IntPart[q])) (((e (x^2)))^(FracPart[q])))/((f^(2 IntPart[q])) (((f x))^(2 FracPart[q]))))∫(((f x))^(m+2 q)) (((a+b (x^2)+c (x^4)))^p)dx

Program code:

Int[(f_.*x_)^m_.*(e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  e^IntPart[q]*(e*x^2)^FracPart[q]/(f^(2*IntPart[q])*(f*x)^(2*FracPart[q]))*Int[(f*x)^(m+2*q)*(a+b*x^2+c*x^4)^p,x] /;
FreeQ[{a,b,c,e,f,m,p,q},x] && Not[IntegerQ[q]]

Int[(f_.*x_)^m_.*(e_.*x_^2)^q_*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  e^IntPart[q]*(e*x^2)^FracPart[q]/(f^(2*IntPart[q])*(f*x)^(2*FracPart[q]))*Int[(f*x)^(m+2*q)*(a+c*x^4)^p,x] /;
FreeQ[{a,c,e,f,m,p,q},x] && Not[IntegerQ[q]]

2:  ∫x (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx

Derivation: Integration by substitution

Basis: x F[(x^2)]==(1/2) Subst[F[x],x,(x^2)] (∂_x)(x^2)

Rule 1.2.2.4.2:

∫x (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (1/2)Subst[∫(((d+e x))^q) (((a+b x+c (x^2)))^p)dx,x,(x^2)]

Program code:

Int[x_*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  1/2*Subst[Int[(d+e*x)^q*(a+b*x+c*x^2)^p,x],x,x^2] /;
FreeQ[{a,b,c,d,e,p,q},x]

Int[x_*(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  1/2*Subst[Int[(d+e*x)^q*(a+c*x^2)^p,x],x,x^2] /;
FreeQ[{a,c,d,e,p,q},x]

3.  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0

x:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  (b^2)-4 a c==0, then a+b z+c (z^2)==(1/c) ((((b/2)+c z))^2)

Rule 1.2.2.4.3.1: If  (b^2)-4 a c==0 ∧ p∈ℤ, then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (1/(c^p))∫(((f x))^m) (((d+e (x^2)))^q) ((((b/2)+c (x^2)))^(2 p))dx

Program code:

(* Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  1/c^p*Int[(f*x)^m*(d+e*x^2)^q*(b/2+c*x^2)^(2*p),x] /;
FreeQ[{a,b,c,d,e,f,m,p,q},x] && EqQ[b^2-4*a*c,0] && IntegerQ[p] *)

2.  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

1:  ∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ ((m+1)/2)∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: If ((m+1)/2)∈ℤ, then (x^m) F[(x^2)]==(1/2) Subst[(x^((m-1)/2)) F[x],x,(x^2)] (∂_x)(x^2)

Note: If this substitution rule is applied when m∈(SuperMinus[ℤ]), expressions of the form Log[(x^2)] rather than Log[x] may appear in the antiderivative.

Rule 1.2.2.4.3.2.1: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ ((m+1)/2)∈(SuperPlus[ℤ]), then

∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (1/2) Subst[∫(x^((m-1)/2)) (((d+e x))^q) (((a+b x+c (x^2)))^p)dx,x,(x^2)]

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  1/2*Subst[Int[x^((m-1)/2)*(d+e*x)^q*(a+b*x+c*x^2)^p,x],x,x^2] /;
FreeQ[{a,b,c,d,e,p,q},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && IGtQ[(m+1)/2,0]

2:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b (x^2)+c (x^4)))^p)/((((b/2)+c (x^2)))^(2 p)))==0

Basis: If  (b^2)-4 a c==0, then ((((a+b (x^2)+c (x^4)))^p)/((((b/2)+c (x^2)))^(2 p)))==((((a+b (x^2)+c (x^4)))^(FracPart[p]))/((c^(IntPart[p])) ((((b/2)+c (x^2)))^(2 FracPart[p]))))

Rule 1.2.2.4.3.2.2: If  (b^2)-4 a c==0 ∧ p∉ℤ, then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((((a+b (x^2)+c (x^4)))^(FracPart[p]))/((c^(IntPart[p])) ((((b/2)+c (x^2)))^(2 FracPart[p]))))∫(((f x))^m) (((d+e (x^2)))^q)((((b/2)+c (x^2)))^(2 p))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (a+b*x^2+c*x^4)^FracPart[p]/(c^IntPart[p]*(b/2+c*x^2)^(2*FracPart[p]))*
    Int[(f*x)^m*(d+e*x^2)^q*(b/2+c*x^2)^(2*p),x] /;
FreeQ[{a,b,c,d,e,f,m,p,q},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]]

4:  ∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when ((m-1)/2)∈ℤ

Derivation: Integration by substitution

Basis: If ((m-1)/2)∈ℤ, then (x^m)F[(x^2)]==(1/2) Subst[(x^((m-1)/2)) F[x],x,(x^2)] (∂_x)(x^2)

Rule 1.2.2.4.4.: If ((m-1)/2)∈ℤ, then

∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (1/2) Subst[∫(x^((m-1)/2)) (((d+e x))^q) (((a+b x+c (x^2)))^p)dx,x,(x^2)]

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  1/2*Subst[Int[x^((m-1)/2)*(d+e*x)^q*(a+b*x+c*x^2)^p,x],x,x^2] /;
FreeQ[{a,b,c,d,e,p,q},x] && IntegerQ[(m-1)/2]

Int[x_^m_.*(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  1/2*Subst[Int[x^((m-1)/2)*(d+e*x)^q*(a+c*x^2)^p,x],x,x^2] /;
FreeQ[{a,c,d,e,p,q},x] && IntegerQ[(m+1)/2]

5.  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0

1:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then a+b z+c (z^2)==(d+e z) ((a/d)+((c z)/e))

Rule 1.2.2.4.5.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ, then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫(((f x))^m)(((d+e (x^2)))^(q+p)) ((((a/d)+((c (x^2))/e)))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  Int[(f*x)^m*(d+e*x^2)^(q+p)*(a/d+c/e*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[p]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  Int[(f*x)^m*(d+e*x^2)^(q+p)*(a/d+c/e*x^2)^p,x] /;
FreeQ[{a,c,d,e,f,q,m,q},x] && EqQ[c*d^2+a*e^2,0] && IntegerQ[p]

2:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  c (d^2)-b d e+a (e^2)==0, then (∂_x)((((a+b (x^2)+c (x^4)))^p)/((((d+e (x^2)))^p) ((((a/d)+((c (x^2))/e)))^p)))==0

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((((a+b (x^2)+c (x^4)))^p)/((((d+e (x^2)))^p) ((((a/d)+((c (x^2))/e)))^p)))==((((a+b (x^2)+c (x^4)))^(FracPart[p]))/((((d+e (x^2)))^(FracPart[p])) ((((a/d)+((c (x^2))/e)))^(FracPart[p]))))

Rule 1.2.2.4.5.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ, then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((((a+b (x^2)+c (x^4)))^(FracPart[p]))/((((d+e (x^2)))^(FracPart[p])) ((((a/d)+((c (x^2))/e)))^(FracPart[p]))))∫(((f x))^m)(((d+e (x^2)))^(q+p)) ((((a/d)+((c (x^2))/e)))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (a+b*x^2+c*x^4)^FracPart[p]/((d+e*x^2)^FracPart[p]*(a/d+(c*x^2)/e)^FracPart[p])*
    Int[(f*x)^m*(d+e*x^2)^(q+p)*(a/d+c/e*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,f,m,p,q},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_,x_Symbol] :=
  (a+c*x^4)^FracPart[p]/((d+e*x^2)^FracPart[p]*(a/d+(c*x^2)/e)^FracPart[p])*Int[(f*x)^m*(d+e*x^2)^(q+p)*(a/d+c/e*x^2)^p,x] /;
FreeQ[{a,c,d,e,f,m,p,q},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]]

6.  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when  (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])

1.  ∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when  (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ ((m/2)|q)∈ℤ ∧ q<-1

1:  ∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ ((m/2)|q)∈ℤ ∧ q<-1 ∧ m>0

Derivation: Algebraic expansion and binomial recurrence 2b

Note: If  p∈(SuperPlus[ℤ])∧ ((m/2)|q)∈ℤ ∧ q<0, then ((((-d))^(m/2))/(e^(2 p+m/2))) (∑_(k=0)^(2 p))(((-d))^k) (e^(2 p-k)) (Subscript[P, 2 p])[(x^2),k] is the coefficient of the (((d+e (x^2)))^q) term of the partial fraction expansion of (x^m) (Subscript[P, 2 p])[(x^2)] (((d+e (x^2)))^q).

Note: If  p∈(SuperPlus[ℤ])∧ ((m/2)|q)∈ℤ ∧ q<-1 ∧ m>0, then 2 (e^(2 p+m/2)) (q+1)(x^m)(((a+b (x^2)+c (x^4)))^p)-(((-d))^(m/2-1)) (((c (d^2)-b d e+a (e^2)))^p) (d+e (2 q+3) (x^2)) will be divisible by a+b (x^2).

Note: In the resulting integrand the degree of the polynomial in (x^2) is at most q-1 .

Rule 1.2.2.4.6.1.1: If  (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ ((m/2)|q)∈ℤ ∧ q<-1 ∧ m>0, then

∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

((((-d))^(m/2))/(e^(2 p+m/2))) (((c (d^2)-b d e+a (e^2)))^p) ∫(((d+e (x^2)))^q)dx+(1/(e^(2 p+m/2))) ∫(((d+e (x^2)))^q) ((e^(2 p+m/2)) (x^m)(((a+b (x^2)+c (x^4)))^p)-(((-d))^(m/2)) (((c (d^2)-b d e+a (e^2)))^p))dx  ⟶  

(((((-d))^(m/2-1)) (((c (d^2)-b d e+a (e^2)))^p) x (((d+e (x^2)))^(q+1)))/(2 (e^(2 p+m/2)) (q+1)))+
(1/(2 (e^(2 p+m/2)) (q+1)))∫(((d+e (x^2)))^(q+1)) (((2 (e^(2 p+m/2)) (q+1)(x^m)(((a+b (x^2)+c (x^4)))^p)-(((-d))^(m/2-1)) (((c (d^2)-b d e+a (e^2)))^p) (d+e (2 q+3) (x^2)))/(d+e (x^2))) )dx

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  (-d)^(m/2-1)*(c*d^2-b*d*e+a*e^2)^p*x*(d+e*x^2)^(q+1)/(2*e^(2*p+m/2)*(q+1)) + 
  1/(2*e^(2*p+m/2)*(q+1))*Int[(d+e*x^2)^(q+1)*
    ExpandToSum[Together[1/(d+e*x^2)*(2*e^(2*p+m/2)*(q+1)*x^m*(a+b*x^2+c*x^4)^p-
      (-d)^(m/2-1)*(c*d^2-b*d*e+a*e^2)^p*(d+e*(2*q+3)*x^2))],x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && IGtQ[p,0] && ILtQ[q,-1] && IGtQ[m/2,0]

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  (-d)^(m/2-1)*(c*d^2+a*e^2)^p*x*(d+e*x^2)^(q+1)/(2*e^(2*p+m/2)*(q+1)) + 
  1/(2*e^(2*p+m/2)*(q+1))*Int[(d+e*x^2)^(q+1)*
    ExpandToSum[Together[1/(d+e*x^2)*(2*e^(2*p+m/2)*(q+1)*x^m*(a+c*x^4)^p-
      (-d)^(m/2-1)*(c*d^2+a*e^2)^p*(d+e*(2*q+3)*x^2))],x],x] /;
FreeQ[{a,c,d,e},x] && IGtQ[p,0] && ILtQ[q,-1] && IGtQ[m/2,0]

2:  ∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ ((m/2)|q)∈ℤ ∧ q<-1 ∧ m<0

Derivation: Algebraic expansion and binomial recurrence 2b

Note: If  p∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<0, then ((((-d))^(m/2))/(e^(2 p+m/2))) (∑_(k=0)^(2 p))(((-d))^k) (e^(2 p-k)) (Subscript[P, 2 p])[(x^2),k] is the coefficient of the (((d+e (x^2)))^q) term of the partial fraction expansion of (x^m) (Subscript[P, 2 p])[(x^2)] (((d+e (x^2)))^q).

Note: If  p∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<-1 ∧ m<0, then 2 (((-d))^(-m/2+1)) (e^(2 p))(q+1) (((a+b (x^2)+c (x^4)))^p)-(e^(-m/2)) (((c (d^2)-b d e+a (e^2)))^p) (x^(-m)) (d+e (2 q+3) (x^2)) will be divisible by a+b (x^2).

Note: In the resulting integrand the degree of the polynomial in (x^2) is at most q-1 .

Rule 1.2.2.4.6.1.2: If  (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ ((m/2)|q)∈ℤ ∧ q<-1 ∧ m<0, then

∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

((((-d))^(m/2))/(e^(2 p+m/2))) (((c (d^2)-b d e+a (e^2)))^p) ∫(((d+e (x^2)))^q)dx+
((((-d))^(m/2))/(e^(2 p))) ∫(x^m)(((d+e (x^2)))^q) ((((-d))^(-m/2)) (e^(2 p)) (((a+b (x^2)+c (x^4)))^p)-(e^(-m/2)) (((c (d^2)-b d e+a (e^2)))^p) (x^(-m)))dx  ⟶  

(((((-d))^(m/2-1)) (((c (d^2)-b d e+a (e^2)))^p) x (((d+e (x^2)))^(q+1)))/(2 (e^(2 p+m/2)) (q+1)))+
((((-d))^(m/2-1))/(2 (e^(2 p)) (q+1)))∫(x^m) (((d+e (x^2)))^(q+1)) (((2 (((-d))^(-m/2+1)) (e^(2 p))(q+1) (((a+b (x^2)+c (x^4)))^p)-(e^(-m/2)) (((c (d^2)-b d e+a (e^2)))^p) (x^(-m)) (d+e (2 q+3) (x^2)))/(d+e (x^2))))dx

Program code:

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  (-d)^(m/2-1)*(c*d^2-b*d*e+a*e^2)^p*x*(d+e*x^2)^(q+1)/(2*e^(2*p+m/2)*(q+1)) + 
  (-d)^(m/2-1)/(2*e^(2*p)*(q+1))*Int[x^m*(d+e*x^2)^(q+1)*
    ExpandToSum[Together[1/(d+e*x^2)*(2*(-d)^(-m/2+1)*e^(2*p)*(q+1)*(a+b*x^2+c*x^4)^p - 
      (e^(-m/2)*(c*d^2-b*d*e+a*e^2)^p*x^(-m))*(d+e*(2*q+3)*x^2))],x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && IGtQ[p,0] && ILtQ[q,-1] && ILtQ[m/2,0]

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  (-d)^(m/2-1)*(c*d^2+a*e^2)^p*x*(d+e*x^2)^(q+1)/(2*e^(2*p+m/2)*(q+1)) + 
  (-d)^(m/2-1)/(2*e^(2*p)*(q+1))*Int[x^m*(d+e*x^2)^(q+1)*
    ExpandToSum[Together[1/(d+e*x^2)*(2*(-d)^(-m/2+1)*e^(2*p)*(q+1)*(a+c*x^4)^p - 
      (e^(-m/2)*(c*d^2+a*e^2)^p*x^(-m))*(d+e*(2*q+3)*x^2))],x],x] /;
FreeQ[{a,c,d,e},x] && IGtQ[p,0] && ILtQ[q,-1] && ILtQ[m/2,0]

2:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ q+2∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.2.4.6.2: If  (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ q+2∈(SuperPlus[ℤ]), then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫ExpandIntegrand[(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m(d+e*x^2)^q*(a+b*x^2+c*x^4)^p,x],x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && NeQ[b^2-4*a*c,0] && IGtQ[p,0] && IGtQ[q,-2]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m(d+e*x^2)^q*(a+c*x^4)^p,x],x] /;
FreeQ[{a,c,d,e,f,m,q},x] && IGtQ[p,0] && IGtQ[q,-2]

3:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ q<-1 ∧ m>0

Derivation: Algebraic expansion and quadratic recurrence 2a

Rule 1.2.2.4.6.3: If  (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ q<-1 ∧ m>0, 
    let Q[x]->PolynomialQuotient[(((a+b (x^2)+c (x^4)))^p),d+e (x^2),x] and R->PolynomialRemainder[(((a+b (x^2)+c (x^4)))^p),d+e (x^2),x], then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

R ∫(((f x))^m) (((d+e (x^2)))^q)dx+∫(((f x))^(m-1)) (f x) Q[x] (((d+e (x^2)))^(q+1))dx  ⟶  

-((R (((f x))^(m+1)) (((d+e (x^2)))^(q+1)))/(2 d f (q+1)))+(f/(2 d (q+1))) ∫(((f x))^(m-1)) (((d+e (x^2)))^(q+1))(2 d (q+1) x Q[x]+R (m+2 q+3) x) dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  With[{Qx=PolynomialQuotient[(a+b*x^2+c*x^4)^p,d+e*x^2,x],
        R=Coeff[PolynomialRemainder[(a+b*x^2+c*x^4)^p,d+e*x^2,x],x,0]},
  -R*(f*x)^(m+1)*(d+e*x^2)^(q+1)/(2*d*f*(q+1)) + 
  f/(2*d*(q+1))*Int[(f*x)^(m-1)*(d+e*x^2)^(q+1)*ExpandToSum[2*d*(q+1)*x*Qx+R*(m+2*q+3)*x,x],x]] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && IGtQ[p,0] && LtQ[q,-1] && GtQ[m,0]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  With[{Qx=PolynomialQuotient[(a+c*x^4)^p,d+e*x^2,x],
        R=Coeff[PolynomialRemainder[(a+c*x^4)^p,d+e*x^2,x],x,0]},
  -R*(f*x)^(m+1)*(d+e*x^2)^(q+1)/(2*d*f*(q+1)) + 
  f/(2*d*(q+1))*Int[(f*x)^(m-1)*(d+e*x^2)^(q+1)*ExpandToSum[2*d*(q+1)*x*Qx+R*(m+2*q+3)*x,x],x]] /;
FreeQ[{a,c,d,e,f},x] && IGtQ[p,0] && LtQ[q,-1] && GtQ[m,0]

4:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ m<-1

Derivation: Algebraic expansion and quadratic recurrence 3b

Rule 1.2.2.4.6.4: If  (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ m<-1, 
    let Q[x]->PolynomialQuotient[(((a+b (x^2)+c (x^4)))^p),f x,x]and R->PolynomialRemainder[(((a+b (x^2)+c (x^4)))^p),f x,x], then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

R ∫(((f x))^m)(((d+e (x^2)))^q)dx+∫(((f x))^(m+1)) Q[x] (((d+e (x^2)))^q)dx  ⟶  

((R (((f x))^(m+1)) (((d+e (x^2)))^(q+1)))/(d f (m+1)))+(1/(d (f^2) (m+1))) ∫(((f x))^(m+2)) (((d+e (x^2)))^q)(((d f (m+1) Q[x])/x)-e R (m+2 q+3))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  With[{Qx=PolynomialQuotient[(a+b*x^2+c*x^4)^p,f*x,x], R=PolynomialRemainder[(a+b*x^2+c*x^4)^p,f*x,x]},
  R*(f*x)^(m+1)*(d+e*x^2)^(q+1)/(d*f*(m+1)) + 
  1/(d*f^2*(m+1))*Int[(f*x)^(m+2)*(d+e*x^2)^q*ExpandToSum[d*f*(m+1)*Qx/x-e*R*(m+2*q+3),x],x]] /;
FreeQ[{a,b,c,d,e,f,q},x] && NeQ[b^2-4*a*c,0] && IGtQ[p,0] && LtQ[m,-1]

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  With[{Qx=PolynomialQuotient[(a+c*x^4)^p,f*x,x], R=PolynomialRemainder[(a+c*x^4)^p,f*x,x]},
  R*(f*x)^(m+1)*(d+e*x^2)^(q+1)/(d*f*(m+1)) + 
  1/(d*f^2*(m+1))*Int[(f*x)^(m+2)*(d+e*x^2)^q*ExpandToSum[d*f*(m+1)*Qx/x-e*R*(m+2*q+3),x],x]] /;
FreeQ[{a,c,d,e,f,q},x] && IGtQ[p,0] && LtQ[m,-1]

5:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ q∉ℤ ∧ m+4 p+2 q+1≠0

Reference: G&R 2.104

Derivation: Algebraic expansion and binomial recurrence 3a

Rule 1.2.2.4.6.5: If  (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ q∉ℤ ∧ m+4 p+2 q+1≠0, then

∫(((f x))^m)  (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

((c^p)/(f^(4 p)))∫(((f x))^(m+4 p))(((d+e (x^2)))^q)dx+∫(((f x))^m)  (((d+e (x^2)))^q) ((((a+b (x^2)+c (x^4)))^p)- (x^(4 p)))dx  ⟶  

(((c^p) (((f x))^(m+4 p-1)) (((d+e (x^2)))^(q+1)))/(e (f^(4 p-1)) (m+4 p+2 q+1)))+(1/(e (m+4 p+2 q+1)))∫(((f x))^m) (((d+e (x^2)))^q) (e (m+4 p+2 q+1) ((((a+b (x^2)+c (x^4)))^p)-(c^p) (x^(4 p)))-d (c^p) (m+4 p-1)(x^(4 p-2)))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  c^p*(f*x)^(m+4*p-1)*(d+e*x^2)^(q+1)/(e*f^(4*p-1)*(m+4*p+2*q+1)) + 
  1/(e*(m+4*p+2*q+1))*Int[(f*x)^m*(d+e*x^2)^q*
    ExpandToSum[e*(m+4*p+2*q+1)*((a+b*x^2+c*x^4)^p-c^p*x^(4*p))-d*c^p*(m+4*p-1)*x^(4*p-2),x],x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && NeQ[b^2-4*a*c,0] && IGtQ[p,0] && Not[IntegerQ[q]] && NeQ[m+4*p+2*q+1,0]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  c^p*(f*x)^(m+4*p-1)*(d+e*x^2)^(q+1)/(e*f^(4*p-1)*(m+4*p+2*q+1)) + 
  1/(e*(m+4*p+2*q+1))*Int[(f*x)^m*(d+e*x^2)^q*
    ExpandToSum[e*(m+4*p+2*q+1)*((a+c*x^4)^p-c^p*x^(4*p))-d*c^p*(m+4*p-1)*x^(4*p-2),x],x] /;
FreeQ[{a,c,d,e,f,m,q},x] && IGtQ[p,0] && Not[IntegerQ[q]] && NeQ[m+4*p+2*q+1,0]

7:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when  (b^2)-4 a c≠0 ∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (((f x))^m) F[x]==(k/f) Subst[(x^(k (m+1)-1))F[((x^k)/f)],x,(((f x))^(1/k))] (∂_x)(((f x))^(1/k))

Rule 1.2.2.4.7: If  (b^2)-4 a c≠0 ∧ m∈𝔽, let k=Denominator[m], then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (k/f) Subst[∫(x^(k (m+1)-1)) (((d+((e (x^(2 k)))/(f^2))))^q) (((a+((b (x^(2 k)))/(f^2))+((c (x^(4 k)))/(f^4))))^p) dx,x,(((f x))^(1/k))]

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  k/f*Subst[Int[x^(k*(m+1)-1)*(d+e*x^(2*k)/f^2)^q*(a+b*x^(2*k)/f^k+c*x^(4*k)/f^4)^p,x],x,(f*x)^(1/k)]] /;
FreeQ[{a,b,c,d,e,f,p,q},x] && NeQ[b^2-4*a*c,0] && FractionQ[m] && IntegerQ[p]

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  k/f*Subst[Int[x^(k*(m+1)-1)*(d+e*x^(2*k)/f)^q*(a+c*x^(4*k)/f)^p,x],x,(f*x)^(1/k)]] /;
FreeQ[{a,c,d,e,f,p,q},x] && FractionQ[m] && IntegerQ[p]

8.  ∫(((f x))^m) (d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0

1.  ∫(((f x))^m) (d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p>0

1:  ∫(((f x))^m)(d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p>0 ∧ m<-1 ∧ m+2 (2 p+1)+1≠0

Derivation: Trinomial recurrence 1a

Rule 1.2.2.4.8.1.1: If  (b^2)-4 a c≠0 ∧ p>0 ∧ m<-1 ∧ m+2 (2 p+1)+1≠0, then

∫(((f x))^m) (d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  ⟶  

(((((f x))^(m+1)) (((a+b (x^2)+c (x^4)))^p) (d (4 p+m+3)+e (m+1) (x^2)))/(f (m+1) (m+4 p+3)))+
((2 p)/((f^2) (m+1) (m+4 p+3)))∫(((f x))^(m+2)) (((a+b (x^2)+c (x^4)))^(p-1))(2 a e (m+1)-b d (m+4 p+3)+(b e (m+1)-2 c d (m+4 p+3)) (x^2))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  (f*x)^(m+1)*(a+b*x^2+c*x^4)^p*(d*(m+4*p+3)+e*(m+1)*x^2)/(f*(m+1)*(m+4*p+3)) + 
  2*p/(f^2*(m+1)*(m+4*p+3))*Int[(f*x)^(m+2)*(a+b*x^2+c*x^4)^(p-1)*
    Simp[2*a*e*(m+1)-b*d*(m+4*p+3)+(b*e*(m+1)-2*c*d*(m+4*p+3))*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && GtQ[p,0] && LtQ[m,-1] && m+4*p+3≠0 && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  (f*x)^(m+1)*(a+c*x^4)^p*(d*(m+4*p+3)+e*(m+1)*x^2)/(f*(m+1)*(m+4*p+3)) + 
  4*p/(f^2*(m+1)*(m+4*p+3))*Int[(f*x)^(m+2)*(a+c*x^4)^(p-1)*(a*e*(m+1)-c*d*(m+4*p+3)*x^2),x] /;
FreeQ[{a,c,d,e,f},x] && GtQ[p,0] && LtQ[m,-1] && m+4*p+3≠0 && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

2:  ∫(((f x))^m)(d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p>0 ∧ m+4 p+1≠0 ∧ m+4 p+3≠0

Derivation: Trinomial recurrence 1b

Rule 1.2.2.4.8.1.2: If  (b^2)-4 a c≠0 ∧ p>0 ∧ m+4 p+1≠0 ∧ m+4 p+3≠0, then

∫(((f x))^m) (d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
(((((f x))^(m+1)) (((a+b (x^2)+c (x^4)))^p) (2 b e p+c d (m+4 p+3)+c e(4 p+m+1) (x^2)))/(c f (m+4 p+1) (m+4 p+3)))+
((2 p)/(c (m+4 p+1) (m+4 p+3)))∫(((f x))^m) (((a+b (x^2)+c (x^4)))^(p-1))·
(2 a c d(m+4 p+3)-a b e (m+1)+(2 a c e(m+4 p+1)+b c d (m+4 p+3)-(b^2) e (m+2 p+1)) (x^2))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  (f*x)^(m+1)*(a+b*x^2+c*x^4)^p*(b*e*2*p+c*d*(m+4*p+3)+c*e*(4*p+m+1)*x^2)/
    (c*f*(4*p+m+1)*(m+4*p+3)) + 
  2*p/(c*(4*p+m+1)*(m+4*p+3))*Int[(f*x)^m*(a+b*x^2+c*x^4)^(p-1)*
    Simp[2*a*c*d*(m+4*p+3)-a*b*e*(m+1)+(2*a*c*e*(4*p+m+1)+b*c*d*(m+4*p+3)-b^2*e*(m+2*p+1))*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && NeQ[b^2-4*a*c,0] && GtQ[p,0] && NeQ[4*p+m+1,0] && NeQ[m+4*p+3,0] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  (f*x)^(m+1)*(a+c*x^4)^p*(c*d*(m+4*p+3)+c*e*(4*p+m+1)*x^2)/(c*f*(4*p+m+1)*(m+4*p+3)) + 
  4*a*p/((4*p+m+1)*(m+4*p+3))*Int[(f*x)^m*(a+c*x^4)^(p-1)*Simp[d*(m+4*p+3)+e*(4*p+m+1)*x^2,x],x] /;
FreeQ[{a,c,d,e,f,m},x] && GtQ[p,0] && NeQ[4*p+m+1,0] && NeQ[m+4*p+3,0] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

2.  ∫(((f x))^m) (d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1

1:  ∫(((f x))^m)(d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1 ∧ m>1

Derivation: Trinomial recurrence 2a

Rule 1.2.2.4.8.2.1: If  (b^2)-4 a c≠0 ∧ p<-1 ∧ m>1, then

∫(((f x))^m) (d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
(( f (((f x))^(m-1)) (((a+b (x^2)+c (x^4)))^(p+1)) (b d-2 a e-(b e-2 c d) (x^2)))/(2 (p+1) ((b^2)-4 a c)))-
((f^2)/(2 (p+1) ((b^2)-4 a c) ))∫(((f x))^(m-2)) (((a+b (x^2)+c (x^4)))^(p+1)) ((m-1)(b d-2 a e)-(4 p+m+5) (b e-2 c d) (x^2))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  f*(f*x)^(m-1)*(a+b*x^2+c*x^4)^(p+1)*(b*d-2*a*e-(b*e-2*c*d)*x^2)/(2*(p+1)*(b^2-4*a*c)) - 
  f^2/(2*(p+1)*(b^2-4*a*c))*Int[(f*x)^(m-2)*(a+b*x^2+c*x^4)^(p+1)*
    Simp[(m-1)*(b*d-2*a*e)-(4*p+4+m+1)*(b*e-2*c*d)*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && GtQ[m,1] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  f*(f*x)^(m-1)*(a+c*x^4)^(p+1)*(a*e-c*d*x^2)/(4*a*c*(p+1)) - 
  f^2/(4*a*c*(p+1))*Int[(f*x)^(m-2)*(a+c*x^4)^(p+1)*(a*e*(m-1)-c*d*(4*p+4+m+1)*x^2),x] /;
FreeQ[{a,c,d,e,f},x] && LtQ[p,-1] && GtQ[m,1] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

2:  ∫(((f x))^m)(d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1

Derivation: Trinomial recurrence 2b

Rule 1.2.2.4.8.2.2: If  (b^2)-4 a c≠0 ∧ p<-1, then

∫(((f x))^m) (d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
-(((((f x))^(m+1)) (((a+b (x^2)+c (x^4)))^(p+1)) (d((b^2)-2 a c)-a b e+(b d-2 a e) c (x^2)))/(2 a f (p+1) ((b^2)-4 a c)))+
(1/(2 a (p+1)((b^2)-4 a c) ))∫(((f x))^m) (((a+b (x^2)+c (x^4)))^(p+1))·
(d ((b^2) (m+2 p+3)-2 a c (m+4 (p+1)+1))-a b e (m+1)+c (m+2 (2p+3)+1)(b d-2 a e) (x^2))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  -(f*x)^(m+1)*(a+b*x^2+c*x^4)^(p+1)*(d*(b^2-2*a*c)-a*b*e+(b*d-2*a*e)*c*x^2)/(2*a*f*(p+1)*(b^2-4*a*c)) + 
  1/(2*a*(p+1)*(b^2-4*a*c))*Int[(f*x)^m*(a+b*x^2+c*x^4)^(p+1)*
    Simp[d*(b^2*(m+2*(p+1)+1)-2*a*c*(m+4*(p+1)+1))-a*b*e*(m+1)+c*(m+2*(2*p+3)+1)*(b*d-2*a*e)*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+c_.*x_^4)^p_,x_Symbol] :=
  -(f*x)^(m+1)*(a+c*x^4)^(p+1)*(d+e*x^2)/(4*a*f*(p+1)) + 
  1/(4*a*(p+1))*Int[(f*x)^m*(a+c*x^4)^(p+1)*Simp[d*(m+4*(p+1)+1)+e*(m+2*(2*p+3)+1)*x^2,x],x] /;
FreeQ[{a,c,d,e,f,m},x] && LtQ[p,-1] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

3:  ∫(((f x))^m)(d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ m>1 ∧ m+4 p+3≠0

Derivation: Trinomial recurrence 3a

Rule 1.2.2.4.8.3: If  (b^2)-4 a c≠0 ∧ m>1 ∧ m+4 p+3≠0, then

∫(((f x))^m) (d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
((e f (((f x))^(m-1))(((a+b (x^2)+c (x^4)))^(p+1)))/(c (m+4 p+3)))-
((f^2)/(c (m+4 p+3)))∫(((f x))^(m-2)) (((a+b (x^2)+c (x^4)))^p) (a e (m-1)+(b e (m+2 p+1)-c d (m+4 p+3)) (x^2))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  e*f*(f*x)^(m-1)*(a+b*x^2+c*x^4)^(p+1)/(c*(m+4*p+3)) - 
  f^2/(c*(m+4*p+3))*Int[(f*x)^(m-2)*(a+b*x^2+c*x^4)^p*Simp[a*e*(m-1)+(b*e*(m+2*p+1)-c*d*(m+4*p+3))*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,p},x] && NeQ[b^2-4*a*c,0] && GtQ[m,1] && NeQ[m+4*p+3,0] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+c_.*x_^4)^p_,x_Symbol] :=
  e*f*(f*x)^(m-1)*(a+c*x^4)^(p+1)/(c*(m+4*p+3)) - 
  f^2/(c*(m+4*p+3))*Int[(f*x)^(m-2)*(a+c*x^4)^p*(a*e*(m-1)-c*d*(m+4*p+3)*x^2),x] /;
FreeQ[{a,c,d,e,f,p},x] && GtQ[m,1] && NeQ[m+4*p+3,0] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

4:  ∫(((f x))^m)(d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ m<-1

Derivation: Trinomial recurrence 3b

Rule 1.2.2.4.4.8.4: If  (b^2)-4 a c≠0 ∧ m<-1, then

∫(((f x))^m) (d+e (x^2))(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
((d (((f x))^(m+1)) (((a+b (x^2)+c (x^4)))^(p+1)))/(a f (m+1)))+
(1/(a (f^2) (m+1))) ∫(((f x))^(m+2)) (((a+b (x^2)+c (x^4)))^p) (a e (m+1)-b d (m+2 p+3)-c d(m+4 p+5) (x^2))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  d*(f*x)^(m+1)*(a+b*x^2+c*x^4)^(p+1)/(a*f*(m+1)) + 
  1/(a*f^2*(m+1))*Int[(f*x)^(m+2)*(a+b*x^2+c*x^4)^p*Simp[a*e*(m+1)-b*d*(m+2*p+3)-c*d*(m+4*p+5)*x^2,x],x] /;
FreeQ[{a,b,c,d,e,f,p},x] && NeQ[b^2-4*a*c,0] && LtQ[m,-1] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_+c_.*x_^4)^p_,x_Symbol] :=
  d*(f*x)^(m+1)*(a+c*x^4)^(p+1)/(a*f*(m+1)) + 
  1/(a*f^2*(m+1))*Int[(f*x)^(m+2)*(a+c*x^4)^p*(a*e*(m+1)-c*d*(m+4*p+5)*x^2),x] /;
FreeQ[{a,c,d,e,f,p},x] && LtQ[m,-1] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

5.  ∫(((((f x))^m) (d+e (x^2)))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0

1:  ∫(((((f x))^m)(d+e (x^2)))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (d/e)>0 ∧ (c/e)(2 c d-b e)>0

Derivation: Algebraic expansion

Basis: If  c (d^2)-a (e^2)=0, let r=(Sqrt[(c/e)(2 c d-b e)]), then ((d+e (x^2))/(a+b (x^2)+c (x^4)))==(e/(2(((c d)/e)+r x+c (x^2))))+(e/(2(((c d)/e)-r x+c (x^2))))

Rule 1.2.2.4.8.5.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (d/e)>0 ∧ (c/e)(2 c d-b e)>0, let r=(Sqrt[(c/e)(2 c d-b e)]), then

∫(((((f x))^m)(d+e (x^2)))/(a+b (x^2)+c (x^4)))dx  ⟶  (e/2)∫((((f x))^m)/(((c d)/e)-r x+c (x^2)))dx+(e/2)∫((((f x))^m)/(((c d)/e)+r x+c (x^2)))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)/(a_+b_.*x_^2+c_.*x_^4), x_Symbol] :=
  With[{r=Rt[c/e*(2*c*d-b*e),2]},
  e/2*Int[(f*x)^m/(c*d/e-r*x+c*x^2),x] + 
  e/2*Int[(f*x)^m/(c*d/e+r*x+c*x^2),x]] /;
FreeQ[{a,b,c,d,e,f,m},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-a*e^2,0] && GtQ[d/e,0] && PosQ[c/e*(2*c*d-b*e)]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)/(a_+c_.*x_^4), x_Symbol] :=
  With[{r=Rt[2*c^2*d/e,2]},
  e/2*Int[(f*x)^m/(c*d/e-r*x+c*x^2),x] + 
  e/2*Int[(f*x)^m/(c*d/e+r*x+c*x^2),x]] /;
FreeQ[{a,c,d,e,f,m},x] && EqQ[c*d^2-a*e^2,0] && GtQ[d/e,0]

2:  ∫(((((f x))^m) (d+e (x^2)))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then ((d+e z)/(a+b z+c (z^2)))==((e/2)+((2 c d-b e)/(2 q))) (1/((b/2)-(q/2)+c z))+((e/2)-((2 c d-b e)/(2 q))) (1/((b/2)+(q/2)+c z))

Rule 1.2.2.4.8.5.2: If  (b^2)-4 a c≠0, let q->(Sqrt[(b^2)-4 a c]), then

∫(((((f x))^m) (d+e (x^2)))/(a+b (x^2)+c (x^4)))dx  ⟶  ((e/2)+((2 c d-b e)/(2 q)))∫((((f x))^m)/((b/2)-(q/2)+c (x^2)))dx+((e/2)-((2 c d-b e)/(2 q)))∫((((f x))^m)/((b/2)+(q/2)+c (x^2)))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (e/2+(2*c*d-b*e)/(2*q))*Int[(f*x)^m/(b/2-q/2+c*x^2),x] + (e/2-(2*c*d-b*e)/(2*q))*Int[(f*x)^m/(b/2+q/2+c*x^2),x]] /;
FreeQ[{a,b,c,d,e,f,m},x] && NeQ[b^2-4*a*c,0]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)/(a_+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  -(e/2+c*d/(2*q))*Int[(f*x)^m/(q-c*x^2),x] + (e/2-c*d/(2*q))*Int[(f*x)^m/(q+c*x^2),x]] /;
FreeQ[{a,c,d,e,f,m},x]

9.  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0

1.  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ q∈ℤ

1:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ q∈ℤ ∧ m∈ℤ

Derivation: Algebraic expansion

Rule 1.2.2.4.9.1.1: If  (b^2)-4 a c≠0 ∧ q∈ℤ ∧ m∈ℤ, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  ∫ExpandIntegrand[(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4))),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_./(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^2)^q/(a+b*x^2+c*x^4),x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && NeQ[b^2-4*a*c,0] && IntegerQ[q] && IntegerQ[m]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_./(a_+c_.*x_^4),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^2)^q/(a+c*x^4),x],x] /;
FreeQ[{a,c,d,e,f,m},x] && IntegerQ[q] && IntegerQ[m]

2:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ q∈ℤ ∧ m∉ℤ

Derivation: Algebraic expansion

Rule 1.2.2.4.9.1.2: If  (b^2)-4 a c≠0 ∧ q∈ℤ ∧ m∉ℤ, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  ∫(((f x))^m) ExpandIntegrand[((((d+e (x^2)))^q)/(a+b (x^2)+c (x^4))),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_./(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m,(d+e*x^2)^q/(a+b*x^2+c*x^4),x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && NeQ[b^2-4*a*c,0] && IntegerQ[q] && Not[IntegerQ[m]]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_./(a_+c_.*x_^4),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m,(d+e*x^2)^q/(a+c*x^4),x],x] /;
FreeQ[{a,c,d,e,f,m},x] && IntegerQ[q] && Not[IntegerQ[m]]

2.  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ q∉ℤ

1.  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q>0

1.  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q>0 ∧ m>1

1:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q>0 ∧ m>3

Reference: Algebraic expansion

Basis: ((d+e z)/(a+b z+c (z^2)))==((c d-b e+c e z)/((c^2) (z^2)))-((a (c d-b e)+(b c d-(b^2) e+a c e) z)/((c^2) (z^2) (a+b z+c (z^2))))

Rule 1.2.2.4.9.2.1.1.1: If  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q>0 ∧ m>3, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  
((f^4)/(c^2))∫(((f x))^(m-4))(c d-b e+c e (x^2))(((d+e (x^2)))^(q-1))dx-((f^4)/(c^2))∫(((((f x))^(m-4)) (((d+e (x^2)))^(q-1)) (a (c d-b e)+(b c d-(b^2) e+a c e) (x^2)))/(a+b (x^2)+c (x^4)))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  f^4/c^2*Int[(f*x)^(m-4)*(c*d-b*e+c*e*x^2)*(d+e*x^2)^(q-1),x] - 
  f^4/c^2*Int[(f*x)^(m-4)*(d+e*x^2)^(q-1)*Simp[a*(c*d-b*e)+(b*c*d-b^2*e+a*c*e)*x^2,x]/(a+b*x^2+c*x^4),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && Not[IntegerQ[q]] && GtQ[q,0] && GtQ[m,3]

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  f^4/c*Int[(f*x)^(m-4)*(d+e*x^2)^q,x] - 
  a*f^4/c*Int[(f*x)^(m-4)*(d+e*x^2)^q/(a+c*x^4),x] /;
FreeQ[{a,c,d,e,f,q},x] && Not[IntegerQ[q]] && GtQ[m,3]

2:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q>0 ∧ 1<m≤3

Reference: Algebraic expansion

Basis: ((d+e z)/(a+b z+c (z^2)))==(e/(c z))-((a e-(c d-b e) z)/(c z (a+b z+c (z^2))))

Rule 1.2.2.4.9.2.1.1.2: If  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q>0 ∧ 1<m≤3, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  ((e (f^2))/c)∫(((f x))^(m-2))(((d+e (x^2)))^(q-1))dx-((f^2)/c)∫(((((f x))^(m-2)) (((d+e (x^2)))^(q-1)) (a e-(c d-b e) (x^2)))/(a+b (x^2)+c (x^4)))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  e*f^2/c*Int[(f*x)^(m-2)*(d+e*x^2)^(q-1),x] - 
  f^2/c*Int[(f*x)^(m-2)*(d+e*x^2)^(q-1)*Simp[a*e-(c*d-b*e)*x^2,x]/(a+b*x^2+c*x^4),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && Not[IntegerQ[q]] && GtQ[q,0] && GtQ[m,1] && LeQ[m,3]

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  e*f^2/c*Int[(f*x)^(m-2)*(d+e*x^2)^(q-1),x] - 
  f^2/c*Int[(f*x)^(m-2)*(d+e*x^2)^(q-1)*Simp[a*e-c*d*x^2,x]/(a+c*x^4),x] /;
FreeQ[{a,c,d,e,f},x] && Not[IntegerQ[q]] && GtQ[q,0] && GtQ[m,1] && LeQ[m,3]

2:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q>0 ∧ m<0

Reference: Algebraic expansion

Basis: ((d+e z)/(a+b z+c (z^2)))==(d/a)-((z (b d-a e+c d z))/(a (a+b z+c (z^2))))

Rule 1.2.2.4.9.2.1.2: If  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q>0 ∧ m<0, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  (d/a)∫(((f x))^m) (((d+e (x^2)))^(q-1))dx-(1/(a (f^2)))∫(((((f x))^(m+2)) (((d+e (x^2)))^(q-1)) (b d-a e+c d (x^2)))/(a+b (x^2)+c (x^4)))dx

Program code:

Int[(f_.*x_)^m_*(d_.+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  d/a*Int[(f*x)^m*(d+e*x^2)^(q-1),x] - 
  1/(a*f^2)*Int[(f*x)^(m+2)*(d+e*x^2)^(q-1)*Simp[b*d-a*e+c*d*x^2,x]/(a+b*x^2+c*x^4),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && Not[IntegerQ[q]] && GtQ[q,0] && LtQ[m,0]

Int[(f_.*x_)^m_*(d_.+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  d/a*Int[(f*x)^m*(d+e*x^2)^(q-1),x] + 
  1/(a*f^2)*Int[(f*x)^(m+2)*(d+e*x^2)^(q-1)*Simp[a*e-c*d*x^2,x]/(a+c*x^4),x] /;
FreeQ[{a,c,d,e,f},x] && Not[IntegerQ[q]] && GtQ[q,0] && LtQ[m,0]

2.  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q<-1

1.  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q<-1 ∧ m>1

1:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q<-1 ∧ m>3

Reference: Algebraic expansion

Basis: (1/(a+b z+c (z^2)))==((d^2)/((c (d^2)-b d e+a (e^2)) (z^2)))-(((d+e z) (a d+(b d-a e) z))/((c (d^2)-b d e+a (e^2)) (z^2) (a+b z+c (z^2))))

Rule 1.2.2.4.9.2.2.1.1: If  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q<-1 ∧ m>3, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  (((d^2) (f^4))/(c (d^2)-b d e+a (e^2)))∫(((f x))^(m-4)) (((d+e (x^2)))^q)dx-((f^4)/(c (d^2)-b d e+a (e^2)))∫(((((f x))^(m-4)) (((d+e (x^2)))^(q+1)) (a d+(b d-a e) (x^2)))/(a+b (x^2)+c (x^4)))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  d^2*f^4/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-4)*(d+e*x^2)^q,x] - 
  f^4/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-4)*(d+e*x^2)^(q+1)*Simp[a*d+(b*d-a*e)*x^2,x]/(a+b*x^2+c*x^4),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && Not[IntegerQ[q]] && LtQ[q,-1] && GtQ[m,3]

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  d^2*f^4/(c*d^2+a*e^2)*Int[(f*x)^(m-4)*(d+e*x^2)^q,x] - 
  a*f^4/(c*d^2+a*e^2)*Int[(f*x)^(m-4)*(d+e*x^2)^(q+1)*(d-e*x^2)/(a+c*x^4),x] /;
FreeQ[{a,c,d,e,f},x] && Not[IntegerQ[q]] && LtQ[q,-1] && GtQ[m,3]

2:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q<-1 ∧ 1<m≤3

Reference: Algebraic expansion

Basis: (1/(a+b z+c (z^2)))==-((d e)/((c (d^2)-b d e+a (e^2)) z))+(((d+e z) (a e+c d z))/((c (d^2)-b d e+a (e^2)) z (a+b z+c (z^2))))

Rule 1.2.2.4.9.2.2.1.2: If  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q<-1 ∧ 1<m≤3, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  -((d e (f^2))/(c (d^2)-b d e+a (e^2)))∫(((f x))^(m-2)) (((d+e (x^2)))^q)dx+((f^2)/(c (d^2)-b d e+a (e^2)))∫(((((f x))^(m-2)) (((d+e (x^2)))^(q+1)) (a e+c d (x^2)))/(a+b (x^2)+c (x^4)))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  -d*e*f^2/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-2)*(d+e*x^2)^q,x] + 
  f^2/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-2)*(d+e*x^2)^(q+1)*Simp[a*e+c*d*x^2,x]/(a+b*x^2+c*x^4),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && Not[IntegerQ[q]] && LtQ[q,-1] && GtQ[m,1] && LeQ[m,3]

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  -d*e*f^2/(c*d^2+a*e^2)*Int[(f*x)^(m-2)*(d+e*x^2)^q,x] + 
  f^2/(c*d^2+a*e^2)*Int[(f*x)^(m-2)*(d+e*x^2)^(q+1)*Simp[a*e+c*d*x^2,x]/(a+c*x^4),x] /;
FreeQ[{a,c,d,e,f},x] && Not[IntegerQ[q]] && LtQ[q,-1] && GtQ[m,1] && LeQ[m,3]

2:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q<-1

Derivation: Algebraic expansion

Basis: (1/(a+b z+c (z^2)))==((e^2)/(c (d^2)-b d e+a (e^2)))+(((d+e z) (c d-b e-c e z))/((c (d^2)-b d e+a (e^2)) (a+b z+c (z^2))))

Rule 1.2.2.4.9.2.2.2: If  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ q<-1, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  ((e^2)/(c (d^2)-b d e+a (e^2)))∫(((f x))^m) (((d+e (x^2)))^q)dx+(1/(c (d^2)-b d e+a (e^2)))∫(((((f x))^m) (((d+e (x^2)))^(q+1)) (c d-b e-c e (x^2)))/(a+b (x^2)+c (x^4)))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  e^2/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^m*(d+e*x^2)^q,x] + 
  1/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^m*(d+e*x^2)^(q+1)*Simp[c*d-b*e-c*e*x^2,x]/(a+b*x^2+c*x^4),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && NeQ[b^2-4*a*c,0] && Not[IntegerQ[q]] && LtQ[q,-1]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  e^2/(c*d^2+a*e^2)*Int[(f*x)^m*(d+e*x^2)^q,x] + 
  c/(c*d^2+a*e^2)*Int[(f*x)^m*(d+e*x^2)^(q+1)*(d-e*x^2)/(a+c*x^4),x] /;
FreeQ[{a,c,d,e,f,m},x] && Not[IntegerQ[q]] && LtQ[q,-1]

3:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ m∈ℤ

Derivation: Algebraic expansion

Basis: If  q=(Sqrt[(b^2)-4a c]), then (1/(a+b z+c (z^2)))==((2c)/(q(b-q+2 c z)))-((2c)/(q(b+q+2 c z)))

Rule 1.2.2.4.9.2.3: If  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ m∈ℤ, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  ∫(((d+e (x^2)))^q) ExpandIntegrand[((((f x))^m)/(a+b (x^2)+c (x^4))),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^q,(f*x)^m/(a+b*x^2+c*x^4),x],x] /;
FreeQ[{a,b,c,d,e,f,q},x] && NeQ[b^2-4*a*c,0] && Not[IntegerQ[q]] && IntegerQ[m]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^q,(f*x)^m/(a+c*x^4),x],x] /;
FreeQ[{a,c,d,e,f,q},x] && Not[IntegerQ[q]] && IntegerQ[m]

4:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ m∉ℤ

Derivation: Algebraic expansion

Basis: If  q=(Sqrt[(b^2)-4a c]), then (1/(a+b z+c (z^2)))==((2c)/(q(b-q+2 c z)))-((2c)/(q(b+q+2 c z)))

Rule 1.2.2.4.9.2.4: If  (b^2)-4 a c≠0 ∧ q∉ℤ ∧ m∉ℤ, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  ∫(((f x))^m) (((d+e (x^2)))^q) ExpandIntegrand[(1/(a+b (x^2)+c (x^4))),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^2)^q,1/(a+b*x^2+c*x^4),x],x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && NeQ[b^2-4*a*c,0] && Not[IntegerQ[q]] && Not[IntegerQ[m]]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^2)^q,1/(a+c*x^4),x],x] /;
FreeQ[{a,c,d,e,f,m,q},x] && Not[IntegerQ[q]] && Not[IntegerQ[m]]

10:  ∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  when  (b^2)-4 a c≠0

Derivation: Algebraic expansion

Basis: If  r=(Sqrt[(b^2)-4a c]), then (1/(a+b z+c (z^2)))==((2c)/(r(b-r+2 c z)))-((2c)/(r(b+r+2 c z)))

Rule 1.2.2.4.10: If  (b^2)-4 a c≠0, then

∫(((((f x))^m) (((d+e (x^2)))^q))/(a+b (x^2)+c (x^4)))dx  ⟶  ((2 c)/r)∫(((((f x))^m) (((d+e (x^2)))^q))/(b-r+2 c (x^2)))dx-((2 c)/r)∫(((((f x))^m) (((d+e (x^2)))^q))/(b+r+2 c (x^2)))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{r=Rt[b^2-4*a*c,2]},
  2*c/r*Int[(f*x)^m*(d+e*x^2)^q/(b-r+2*c*x^2),x] - 2*c/r*Int[(f*x)^m*(d+e*x^2)^q/(b+r+2*c*x^2),x]] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && NeQ[b^2-4*a*c,0]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_/(a_+c_.*x_^4),x_Symbol] :=
  With[{r=Rt[-a*c,2]},
  -c/(2*r)*Int[(f*x)^m*(d+e*x^2)^q/(r-c*x^2),x] - c/(2*r)*Int[(f*x)^m*(d+e*x^2)^q/(r+c*x^2),x]] /;
FreeQ[{a,c,d,e,f,m,q},x]

11.  ∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  when (b^2)-4 a c≠0

1.  ∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  when (b^2)-4 a c≠0 ∧ p>0 ∧ m<0

1:  ∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  when (b^2)-4 a c≠0 ∧ p>0 ∧ m<-2

Reference: Algebraic expansion

Basis: ((a+b z+c (z^2))/(d+e z))==((a d+(b d-a e) z)/(d^2))+(((c (d^2)-b d e+a (e^2)) (z^2))/((d^2) (d+e z)))

Rule 1.2.2.4.11.1.1: If  (b^2)-4 a c≠0 ∧ p>0 ∧ m<-2, then

∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  ⟶  
(1/(d^2))∫(((f x))^m) (a d+(b d-a e) (x^2)) (((a+b (x^2)+c (x^4)))^(p-1))dx+((c (d^2)-b d e+a (e^2))/((d^2) (f^4)))∫(((((f x))^(m+4)) (((a+b (x^2)+c (x^4)))^(p-1)))/(d+e (x^2)))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*x_^2+c_.*x_^4)^p_./(d_.+e_.*x_^2),x_Symbol] :=
  1/d^2*Int[(f*x)^m*(a*d+(b*d-a*e)*x^2)*(a+b*x^2+c*x^4)^(p-1),x] + 
  (c*d^2-b*d*e+a*e^2)/(d^2*f^4)*Int[(f*x)^(m+4)*(a+b*x^2+c*x^4)^(p-1)/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && GtQ[p,0] && LtQ[m,-2]

Int[(f_.*x_)^m_*(a_+c_.*x_^4)^p_./(d_.+e_.*x_^2),x_Symbol] :=
  a/d^2*Int[(f*x)^m*(d-e*x^2)*(a+c*x^4)^(p-1),x] + 
  (c*d^2+a*e^2)/(d^2*f^4)*Int[(f*x)^(m+4)*(a+c*x^4)^(p-1)/(d+e*x^2),x] /;
FreeQ[{a,c,d,e,f},x] && GtQ[p,0] && LtQ[m,-2]

2:  ∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  when (b^2)-4 a c≠0 ∧ p>0 ∧ m<0

Reference: Algebraic expansion

Basis: ((a+b z+c (z^2))/(d+e z))==((a e+c d z)/(d e))-(((c (d^2)-b d e+a (e^2))z)/(d e(d+e z)))

Rule 1.2.2.4.11.1.2: If  (b^2)-4 a c≠0 ∧ p>0 ∧ m<0, then

∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  ⟶  
(1/(d e))∫(((f x))^m) (a e+c d (x^2)) (((a+b (x^2)+c (x^4)))^(p-1))dx-((c (d^2)-b d e+a (e^2))/(d e (f^2)))∫(((((f x))^(m+2)) (((a+b (x^2)+c (x^4)))^(p-1)))/(d+e (x^2)))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*x_^2+c_.*x_^4)^p_./(d_.+e_.*x_^2),x_Symbol] :=
  1/(d*e)*Int[(f*x)^m*(a*e+c*d*x^2)*(a+b*x^2+c*x^4)^(p-1),x] - 
  (c*d^2-b*d*e+a*e^2)/(d*e*f^2)*Int[(f*x)^(m+2)*(a+b*x^2+c*x^4)^(p-1)/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && GtQ[p,0] && LtQ[m,0]

Int[(f_.*x_)^m_*(a_+c_.*x_^4)^p_./(d_.+e_.*x_^2),x_Symbol] :=
  1/(d*e)*Int[(f*x)^m*(a*e+c*d*x^2)*(a+c*x^4)^(p-1),x] - 
  (c*d^2+a*e^2)/(d*e*f^2)*Int[(f*x)^(m+2)*(a+c*x^4)^(p-1)/(d+e*x^2),x] /;
FreeQ[{a,c,d,e,f},x] && GtQ[p,0] && LtQ[m,0]

2.  ∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  when (b^2)-4 a c≠0 ∧ p<-1 ∧ m>0

1:  ∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  when (b^2)-4 a c≠0 ∧ p<-1 ∧ m>2

Reference: Algebraic expansion

Basis: ((z^2)/(d+e z))==-((a d+(b d-a e) z)/(c (d^2)-b d e+a (e^2)))+(((d^2)(a+b z+c (z^2)))/((c (d^2)-b d e+a (e^2)) (d+e z)))

Rule 1.2.2.4.11.2.1: If  (b^2)-4 a c≠0 ∧ p<-1 ∧ m>2, then

∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  ⟶  
-((f^4)/(c (d^2)-b d e+a (e^2)))∫(((f x))^(m-4)) (a d+(b d-a e) (x^2)) (((a+b (x^2)+c (x^4)))^p)dx+(((d^2) (f^4))/(c (d^2)-b d e+a (e^2)))∫(((((f x))^(m-4)) (((a+b (x^2)+c (x^4)))^(p+1)))/(d+e (x^2)))dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*x_^2+c_.*x_^4)^p_/(d_.+e_.*x_^2),x_Symbol] :=
  -f^4/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-4)*(a*d+(b*d-a*e)*x^2)*(a+b*x^2+c*x^4)^p,x] + 
  d^2*f^4/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-4)*(a+b*x^2+c*x^4)^(p+1)/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && GtQ[m,2]

Int[(f_.*x_)^m_.*(a_+c_.*x_^4)^p_/(d_.+e_.*x_^2),x_Symbol] :=
  -a*f^4/(c*d^2+a*e^2)*Int[(f*x)^(m-4)*(d-e*x^2)*(a+c*x^4)^p,x] + 
  d^2*f^4/(c*d^2+a*e^2)*Int[(f*x)^(m-4)*(a+c*x^4)^(p+1)/(d+e*x^2),x] /;
FreeQ[{a,c,d,e,f},x] && LtQ[p,-1] && GtQ[m,2]

2:  ∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  when (b^2)-4 a c≠0 ∧ p<-1 ∧ m>0

Reference: Algebraic expansion

Basis: (z/(d+e z))==((a e+c d z)/(c (d^2)-b d e+a (e^2)))-((d e(a+b z+c (z^2)))/((c (d^2)-b d e+a (e^2)) (d+e z)))

Rule 1.2.2.4.11.2.2: If  (b^2)-4 a c≠0 ∧ p<-1 ∧ m>0, then

∫(((((f x))^m) (((a+b (x^2)+c (x^4)))^p))/(d+e (x^2)))dx  ⟶  
((f^2)/(c (d^2)-b d e+a (e^2)))∫(((f x))^(m-2)) (a e+c d (x^2)) (((a+b (x^2)+c (x^4)))^p)dx-((d e (f^2))/(c (d^2)-b d e+a (e^2)))∫(((((f x))^(m-2)) (((a+b (x^2)+c (x^4)))^(p+1)))/(d+e (x^2)))dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*x_^2+c_.*x_^4)^p_/(d_.+e_.*x_^2),x_Symbol] :=
  f^2/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-2)*(a*e+c*d*x^2)*(a+b*x^2+c*x^4)^p,x] - 
  d*e*f^2/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-2)*(a+b*x^2+c*x^4)^(p+1)/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && GtQ[m,0]

Int[(f_.*x_)^m_.*(a_+c_.*x_^4)^p_/(d_.+e_.*x_^2),x_Symbol] :=
  f^2/(c*d^2+a*e^2)*Int[(f*x)^(m-2)*(a*e+c*d*x^2)*(a+c*x^4)^p,x] - 
  d*e*f^2/(c*d^2+a*e^2)*Int[(f*x)^(m-2)*(a+c*x^4)^(p+1)/(d+e*x^2),x] /;
FreeQ[{a,c,d,e,f},x] && LtQ[p,-1] && GtQ[m,0]

3.  ∫((x^m)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ (m/2)∈ℤ

1.  ∫((x^m)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ (m/2)∈(SuperPlus[ℤ])

1.  ∫((x^2)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0

1:  ∫((x^2)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (c/a)>0 ∧ c (d^2)-a (e^2)==0

Derivation: Algebraic expansion

Rule 1.2.2.4.11.3.1.1.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (c/a)>0 ∧ c (d^2)-a (e^2)==0, then

∫((x^2)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  (d/(2 d e)) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx-(d/(2 d e)) ∫((d-e (x^2))/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[x_^2/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  d/(2*d*e)*Int[1/Sqrt[a+b*x^2+c*x^4],x] - 
  d/(2*d*e)*Int[(d-e*x^2)/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4]),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && PosQ[c/a] && EqQ[c*d^2-a*e^2,0]

Int[x_^2/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  d/(2*d*e)*Int[1/Sqrt[a+c*x^4],x] - 
  d/(2*d*e)*Int[(d-e*x^2)/((d+e*x^2)*Sqrt[a+c*x^4]),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && PosQ[c/a] && EqQ[c*d^2-a*e^2,0]

2:  ∫((x^2)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (c/a)>0 ∧ c (d^2)-a (e^2)≠0

Derivation: Algebraic expansion

Basis: ((x^2)/(d+e (x^2)))==(1/(e-d q))-((d (1+q (x^2)))/((e-d q) (d+e (x^2))))

Rule 1.2.2.4.11.3.1.1.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (c/a)>0 ∧ c (d^2)-a (e^2)≠0, let q->(Sqrt[(c/a)]), then

∫((x^2)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  -((a (e+d q))/(c (d^2)-a (e^2)))∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx+((a d (e+d q))/(c (d^2)-a (e^2)))∫((1+q (x^2))/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[x_^2/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[c/a,2]},
  -a*(e+d*q)/(c*d^2-a*e^2)*Int[1/Sqrt[a+b*x^2+c*x^4],x] + 
  a*d*(e+d*q)/(c*d^2-a*e^2)*Int[(1+q*x^2)/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4]),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && PosQ[c/a] && NeQ[c*d^2-a*e^2,0]

Int[x_^2/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[c/a,2]},
  -a*(e+d*q)/(c*d^2-a*e^2)*Int[1/Sqrt[a+c*x^4],x] + 
  a*d*(e+d*q)/(c*d^2-a*e^2)*Int[(1+q*x^2)/((d+e*x^2)*Sqrt[a+c*x^4]),x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && PosQ[c/a] && NeQ[c*d^2-a*e^2,0]

2.  ∫((x^4)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ (c/a)>0

1:  ∫((x^4)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ (c/a)>0 ∧ c (d^2)-a (e^2)==0

Derivation: Algebraic expansion

Rule 1.2.2.4.11.3.1.2.1: If  (b^2)-4 a c≠0 ∧ (c/a)>0 ∧ c (d^2)-a (e^2)==0, then

∫((x^4)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  -(1/(e^2)) ∫((d-e (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx+((d^2)/(e^2)) ∫(1/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[x_^4/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  -1/e^2*Int[(d-e*x^2)/Sqrt[a+b*x^2+c*x^4],x] + d^2/e^2*Int[1/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4]),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && PosQ[c/a] && EqQ[c*d^2-a*e^2,0]

Int[x_^4/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  -1/e^2*Int[(d-e*x^2)/Sqrt[a+c*x^4],x] + d^2/e^2*Int[1/((d+e*x^2)*Sqrt[a+c*x^4]),x] /;
FreeQ[{a,c,d,e},x] && PosQ[c/a] && EqQ[c*d^2-a*e^2,0]

2:  ∫((x^4)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ (c/a)>0 ∧ c (d^2)-a (e^2)≠0

Derivation: Algebraic expansion

Rule 1.2.2.4.11.3.1.2.2: If  (b^2)-4 a c≠0 ∧ (c/a)>0 ∧ c (d^2)-a (e^2)≠0, let q->(Sqrt[(c/a)]), then

∫((x^4)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  
-((2 c d-a e q)/(c e (e-d q))) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx-(1/(e q)) ∫((1-q (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx+((d^2)/(e (e-d q))) ∫((1+q (x^2))/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[x_^4/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[c/a,2]},
  -1/(e*q)*Int[(1-q*x^2)/Sqrt[a+b*x^2+c*x^4],x] + 
  d^2/(e*(e-d*q))*Int[(1+q*x^2)/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4]),x] /;
 EqQ[2*c*d-a*e*q,0]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && PosQ[c/a] && NeQ[c*d^2-a*e^2,0]

Int[x_^4/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[c/a,2]},
  -1/(e*q)*Int[(1-q*x^2)/Sqrt[a+c*x^4],x] + 
  d^2/(e*(e-d*q))*Int[(1+q*x^2)/((d+e*x^2)*Sqrt[a+c*x^4]),x] /;
 EqQ[2*c*d-a*e*q,0]] /;
FreeQ[{a,c,d,e},x] && PosQ[c/a] && NeQ[c*d^2-a*e^2,0]

Int[x_^4/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[c/a,2]},
  -(2*c*d-a*e*q)/(c*e*(e-d*q))*Int[1/Sqrt[a+b*x^2+c*x^4],x] - 
  1/(e*q)*Int[(1-q*x^2)/Sqrt[a+b*x^2+c*x^4],x] + 
  d^2/(e*(e-d*q))*Int[(1+q*x^2)/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4]),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && PosQ[c/a] && NeQ[c*d^2-a*e^2,0]

Int[x_^4/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  With[{q=Rt[c/a,2]},
  -(2*c*d-a*e*q)/(c*e*(e-d*q))*Int[1/Sqrt[a+c*x^4],x] - 
  1/(e*q)*Int[(1-q*x^2)/Sqrt[a+c*x^4],x] + 
  d^2/(e*(e-d*q))*Int[(1+q*x^2)/((d+e*x^2)*Sqrt[a+c*x^4]),x]] /;
FreeQ[{a,c,d,e},x] && PosQ[c/a] && NeQ[c*d^2-a*e^2,0]

3:  ∫((x^m)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ (m/2)-2∈(SuperPlus[ℤ])

Rule 1.2.2.4.11.3.1.3: If  (b^2)-4 a c≠0 ∧ (m/2)-2∈(SuperPlus[ℤ]), then

∫((x^m)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  
(((x^(m-5)) (Sqrt[a+b (x^2)+c (x^4)]))/(c e (m-3)))-(1/(c e (m-3))) ∫(((x^(m-6)) (a d (m-5)+(a e (m-5)+b d (m-4)) (x^2)+(b e (m-4)+c d (m-3)) (x^4)))/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[x_^m_/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  x^(m-5)*Sqrt[a+b*x^2+c*x^4]/(c*e*(m-3)) - 
  1/(c*e*(m-3))*Int[x^(m-6)/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4])*
    Simp[a*d*(m-5)+(a*e*(m-5)+b*d*(m-4))*x^2+(b*e*(m-4)+c*d*(m-3))*x^4,x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && IGtQ[m/2,2]

Int[x_^m_/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  x^(m-5)*Sqrt[a+c*x^4]/(c*e*(m-3)) - 
  1/(c*e*(m-3))*Int[x^(m-6)/((d+e*x^2)*Sqrt[a+c*x^4])*Simp[a*d*(m-5)+a*e*(m-5)*x^2+c*d*(m-3)*x^4,x],x] /;
FreeQ[{a,c,d,e},x] && IGtQ[m/2,2]

2:  ∫((x^m)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ (m/2)∈(SuperMinus[ℤ])

Rule 1.2.2.4.11.3.2: If  (b^2)-4 a c≠0 ∧ (m/2)∈(SuperMinus[ℤ]), then

∫((x^m)/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  
(((x^(m+1)) (Sqrt[a+b (x^2)+c (x^4)]))/(a d (m+1)))-(1/(a d (m+1))) ∫(((x^(m+2)) (a e (m+1)+b d (m+2)+(b e (m+2)+c d (m+3)) (x^2)+c e (m+3) (x^4)))/((d+e (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[x_^m_/((d_+e_.*x_^2)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  x^(m+1)*Sqrt[a+b*x^2+c*x^4]/(a*d*(m+1)) - 
  1/(a*d*(m+1))*Int[x^(m+2)/((d+e*x^2)*Sqrt[a+b*x^2+c*x^4])*
    Simp[a*e*(m+1)+b*d*(m+2)+(b*e*(m+2)+c*d*(m+3))*x^2+c*e*(m+3)*x^4,x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && ILtQ[m/2,0]

Int[x_^m_/((d_+e_.*x_^2)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  x^(m+1)*Sqrt[a+c*x^4]/(a*d*(m+1)) - 
  1/(a*d*(m+1))*Int[x^(m+2)/((d+e*x^2)*Sqrt[a+c*x^4])*Simp[a*e*(m+1)+c*d*(m+3)*x^2+c*e*(m+3)*x^4,x],x] /;
FreeQ[{a,c,d,e},x] && ILtQ[m/2,0]

12:  ∫((x^m)/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))dx  when (b^2)-4 a c≠0 ∧ (m/2)∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((x (Sqrt[e+(d/(x^2))]))/(Sqrt[d+e (x^2)]))==0

Basis: (∂_x)(((x^2) (Sqrt[c+(b/(x^2))+(a/(x^4))]))/(Sqrt[a+b (x^2)+c (x^4)]))==0

Note: Since m-3 is odd, the resulting integrand can be reduced to an integrand of the form (1/((x^(m/2))(Sqrt[e+d x]) (Sqrt[c+b x+a (x^2)]))) using the substitution x->(1/(x^2)).

Rule 1.2.2.4.12: If  (b^2)-4 a c≠0 ∧ (m/2)∈ℤ, then

∫((x^m)/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  (((x^3) (Sqrt[e+(d/(x^2))]) (Sqrt[c+(b/(x^2))+(a/(x^4))]))/((Sqrt[d+e (x^2)]) (Sqrt[a+b (x^2)+c (x^4)])))∫((x^(m-3))/((Sqrt[e+(d/(x^2))]) (Sqrt[c+(b/(x^2))+(a/(x^4))])))dx

Program code:

Int[x_^m_/(Sqrt[d_+e_.*x_^2]*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  x^3*Sqrt[e+d/x^2]*Sqrt[c+b/x^2+a/x^4]/(Sqrt[d+e*x^2]*Sqrt[a+b*x^2+c*x^4])*
    Int[x^(m-3)/(Sqrt[e+d/x^2]*Sqrt[c+b/x^2+a/x^4]),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && IntegerQ[m/2]

Int[x_^m_/(Sqrt[d_+e_.*x_^2]*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  x^3*Sqrt[e+d/x^2]*Sqrt[c+a/x^4]/(Sqrt[d+e*x^2]*Sqrt[a+c*x^4])*
    Int[x^(m-3)/(Sqrt[e+d/x^2]*Sqrt[c+a/x^4]),x] /;
FreeQ[{a,c,d,e},x] && IntegerQ[m/2]

13.  ∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1 ∧ q-1∈(SuperPlus[ℤ])∧ (m/2)∈ℤ

1:  ∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1 ∧ q-1∈(SuperPlus[ℤ])∧ (m/2)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion and trinomial recurrence 2b

Rule 1.2.2.4.13.1: If  (b^2)-4 a c≠0 ∧ p<-1 ∧ q-1∈(SuperPlus[ℤ])∧ (m/2)∈(SuperPlus[ℤ]), 
		let Q[x]->PolynomialQuotient[(x^m) (((d+e (x^2)))^q),a+b (x^2)+c (x^4),x]and f+g (x^2)->PolynomialRemainder[(x^m) (((d+e (x^2)))^q),a+b (x^2)+c (x^4),x], then

∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

∫(f+g (x^2)) (((a+b (x^2)+c (x^4)))^p)dx+∫Q[x] (((a+b (x^2)+c (x^4)))^(p+1))dx  ⟶  

((x (((a+b (x^2)+c (x^4)))^(p+1)) (a b g-f ((b^2)-2 a c)-c (b f-2 a g) (x^2)))/(2 a (p+1) ((b^2)-4 a c)))+
(1/(2 a (p+1) ((b^2)-4 a c)))∫(((a+b (x^2)+c (x^4)))^(p+1))·
(2 a (p+1) ((b^2)-4 a c) Q[x]+(b^2) f (2 p+3)-2 a c f (4 p+5)-a b g+c (4 p+7)(b f-2 a g) (x^2)) dx

Program code:

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  With[{f=Coeff[PolynomialRemainder[x^m*(d+e*x^2)^q,a+b*x^2+c*x^4,x],x,0],
        g=Coeff[PolynomialRemainder[x^m*(d+e*x^2)^q,a+b*x^2+c*x^4,x],x,2]},
  x*(a+b*x^2+c*x^4)^(p+1)*(a*b*g-f*(b^2-2*a*c)-c*(b*f-2*a*g)*x^2)/(2*a*(p+1)*(b^2-4*a*c)) + 
  1/(2*a*(p+1)*(b^2-4*a*c))*Int[(a+b*x^2+c*x^4)^(p+1)*
    Simp[ExpandToSum[2*a*(p+1)*(b^2-4*a*c)*PolynomialQuotient[x^m*(d+e*x^2)^q,a+b*x^2+c*x^4,x]+
      b^2*f*(2*p+3)-2*a*c*f*(4*p+5)-a*b*g+c*(4*p+7)*(b*f-2*a*g)*x^2,x],x],x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && IGtQ[q,1] && IGtQ[m/2,0]

2:  ∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1 ∧ q-1∈(SuperPlus[ℤ])∧ (m/2)∈(SuperMinus[ℤ])

Derivation: Algebraic expansion and trinomial recurrence 2b

Rule 1.2.2.4.13.2: If  (b^2)-4 a c≠0 ∧ p<-1 ∧ q-1∈(SuperPlus[ℤ])∧ (m/2)∈(SuperMinus[ℤ]), 
		let Q[x]->PolynomialQuotient[(x^m) (((d+e (x^2)))^q),a+b (x^2)+c (x^4),x]and f+g (x^2)->PolynomialRemainder[(x^m) (((d+e (x^2)))^q),a+b (x^2)+c (x^4),x], then

∫(x^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  

∫(f+g (x^2)) (((a+b (x^2)+c (x^4)))^p)dx+∫Q[x] (((a+b (x^2)+c (x^4)))^(p+1))dx  ⟶  

((x (((a+b (x^2)+c (x^4)))^(p+1)) (a b g-f ((b^2)-2 a c)-c (b f-2 a g) (x^2)))/(2 a (p+1) ((b^2)-4 a c)))+
(1/(2 a (p+1) ((b^2)-4 a c)))∫(x^m) (((a+b (x^2)+c (x^4)))^(p+1))·
(2 a (p+1) ((b^2)-4 a c) (x^(-m)) Q[x]+((b^2) f (2 p+3)-2 a c f (4 p+5)-a b g) (x^(-m))+c (4 p+7)(b f-2 a g) (x^(2-m))) dx

Program code:

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  With[{f=Coeff[PolynomialRemainder[x^m*(d+e*x^2)^q,a+b*x^2+c*x^4,x],x,0],
        g=Coeff[PolynomialRemainder[x^m*(d+e*x^2)^q,a+b*x^2+c*x^4,x],x,2]},
  x*(a+b*x^2+c*x^4)^(p+1)*(a*b*g-f*(b^2-2*a*c)-c*(b*f-2*a*g)*x^2)/(2*a*(p+1)*(b^2-4*a*c)) + 
  1/(2*a*(p+1)*(b^2-4*a*c))*Int[x^m*(a+b*x^2+c*x^4)^(p+1)*
    Simp[ExpandToSum[2*a*(p+1)*(b^2-4*a*c)*x^(-m)*PolynomialQuotient[x^m*(d+e*x^2)^q,a+b*x^2+c*x^4,x]+
      (b^2*f*(2*p+3)-2*a*c*f*(4*p+5)-a*b*g)*x^(-m)+c*(4*p+7)*(b*f-2*a*g)*x^(2-m),x],x],x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && IGtQ[q,1] && ILtQ[m/2,0]

14:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ (p∈(SuperPlus[ℤ]) ∨ q∈(SuperPlus[ℤ]) ∨ (m|q)∈ℤ)

Derivation: Algebraic expansion

Rule 1.2.2.4.14: If  (b^2)-4 a c≠0 ∧ (p∈(SuperPlus[ℤ]) ∨ q∈(SuperPlus[ℤ]) ∨ (m|q)∈ℤ), then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫ExpandIntegrand[(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^2)^q*(a+b*x^2+c*x^4)^p,x],x] /;
FreeQ[{a,b,c,d,e,f,m,p,q},x] && NeQ[b^2-4*a*c,0] && (IGtQ[p,0] || IGtQ[q,0] || IntegersQ[m,q])

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^2)^q*(a+c*x^4)^p,x],x] /;
FreeQ[{a,c,d,e,f,m,p,q},x] && (IGtQ[p,0] || IGtQ[q,0] || IntegersQ[m,q])

15:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+c (x^4)))^p)dx  when p∉ℤ ∧ q∈(SuperMinus[ℤ])

Derivation: Algebraic expansion

Basis: If  q∈ℤ, then (((d+e (x^2)))^q)==((((d/((d^2)-(e^2) (x^4)))-((e (x^2))/((d^2)-(e^2) (x^4)))))^(-q))

Note: Resulting integrands are of the form (x^m) (((a+b (x^2)))^p) (((c+d (x^2)))^q) which are integrable.

Rule 1.2.2.4.15: If  p∉ℤ ∧ q∈(SuperMinus[ℤ]), then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+c (x^4)))^p)dx  ⟶  ((((f x))^m)/(x^m)) ∫(x^m) (((a+c (x^4)))^p) ExpandIntegrand[((((d/((d^2)-(e^2) (x^4)))-((e (x^2))/((d^2)-(e^2) (x^4)))))^(-q)),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_*(a_+c_.*x_^4)^p_,x_Symbol] :=
  (f*x)^m/x^m*Int[ExpandIntegrand[x^m*(a+c*x^4)^p,(d/(d^2-e^2*x^4)-e*x^2/(d^2-e^2*x^4))^(-q),x],x] /;
FreeQ[{a,c,d,e,f,m,p},x] && Not[IntegerQ[p]] && ILtQ[q,0]

U:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx

Rule 1.2.2.4.U:

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b (x^2)+c (x^4)))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  Unintegrable[(f*x)^m*(d+e*x^2)^q*(a+b*x^2+c*x^4)^p,x] /;
FreeQ[{a,b,c,d,e,f,m,p,q},x]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  Unintegrable[(f*x)^m*(d+e*x^2)^q*(a+c*x^4)^p,x] /;
FreeQ[{a,c,d,e,f,m,p,q},x]