Rules for integrands of the form(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)

x.  ∫(((d x))^m) (((b (x^n)+c (x^(2 n))))^p)dx

1.  ∫(((d x))^m) (((b (x^n)+c (x^(2 n))))^p)dx  when p∈ℤ

1:  ∫(((d x))^m) (((b (x^n)+c (x^(2 n))))^p)dx  when p∈ℤ ∧ (m∈ℤ ∨ d>0)

Derivation: Algebraic simplification

Basis: If  p∈ℤ, then (((b (x^n)+c (x^(2 n))))^p)==(x^(n p)) (((b+c (x^n)))^p)

Rule 1.2.3.2.0.1.1: If  p∈ℤ ∧ (m∈ℤ ∨ d>0), then

∫(((d x))^m) (((b (x^n)+c (x^(2 n))))^p)dx  ⟶  (d^m) ∫(x^(m+n p)) (((b+c (x^n)))^p)dx

Program code:

(* Int[(d_.*x_)^m_.*(b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  d^m*Int[x^(m+n*p)*(b+c*x^n)^p,x] /;
FreeQ[{b,c,d,m,n},x] && EqQ[n2,2*n] && IntegerQ[p] && (IntegerQ[m] || GtQ[d,0]) *)

2:  ∫(((d x))^m) (((b (x^n)+c (x^(2 n))))^p)dx  when p∈ℤ ∧ n∈ℤ

Derivation: Algebraic simplification

Basis: If  p∈ℤ ∧ n∈ℤ, then (((b (x^n)+c (x^(2 n))))^p)==(1/(d^(n p))) (((d x))^(n p)) (((b+c (x^n)))^p)

Rule 1.2.3.2.0.1.2: If  p∈ℤ ∧ n∈ℤ, then

∫(((d x))^m) (((b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/(d^(n p))) ∫(((d x))^(m+n p)) (((b+c (x^n)))^p)dx

Program code:

(* Int[(d_.*x_)^m_.*(b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  1/d^(n*p)*Int[(d*x)^(m+n*p)*(b+c*x^n)^p,x] /;
FreeQ[{b,c,d,m},x] && EqQ[n2,2*n] && IntegerQ[p] && IntegerQ[n] *)

3:  ∫(((d x))^m) (((b (x^n)+c (x^(2 n))))^p)dx  when p∈ℤ ∧ ¬(m∈ℤ ∨ d>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((d x))^m)/(x^m))==0

Rule 1.2.3.2.0.1.3: If  p∈ℤ ∧ ¬(m∈ℤ ∨ d>0), then

∫(((d x))^m) (((b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((((d x))^m)/(x^m)) ∫(x^(m+n p)) (((b+c (x^n)))^p)dx

Program code:

(* Int[(d_.*x_)^m_.*(b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  (d*x)^m/x^m*Int[x^(m+n*p)*(b+c*x^n)^p,x] /;
FreeQ[{b,c,d,m,n},x] && EqQ[n2,2*n] && IntegerQ[p] && Not[IntegerQ[m] || GtQ[d,0]] *)

2:  ∫(((d x))^m) (((b (x^n)+c (x^(2 n))))^p)dx  when p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((b (x^n)+c (x^(2 n))))^p)/((((d x))^(n p))(((b+c (x^n)))^p)))==0

Rule 1.2.3.2.0.2: If  p∉ℤ, then

∫(((d x))^m) (((b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((((b (x^n)+c (x^(2 n))))^p)/((((d x))^(n p))(((b+c (x^n)))^p))) ∫(((d x))^(m+n p)) (((b+c (x^n)))^p)dx

Program code:

(* Int[(d_.*x_)^m_.*(b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  (b*x^n+c*x^(2*n))^p/((d*x)^(n*p)*(b+c*x^n)^p)*Int[(d*x)^(m+n*p)*(b+c*x^2)^p,x] /;
FreeQ[{b,c,d,m,n,p},x] && EqQ[n2,2*n] && Not[IntegerQ[p]] *)

1:  ∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  m-n+1==0

Derivation: Integration by substitution

Basis: (x^(n-1))F[(x^n)]==(1/n) Subst[F[x],x,(x^n)] (∂_x)(x^n)

Rule 1.2.3.2.1: If  m-n+1==0, then

∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/n) Subst[∫(((a+b x+c (x^2)))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  1/n*Subst[Int[(a+b*x+c*x^2)^p,x],x,x^n] /;
FreeQ[{a,b,c,m,n,p},x] && EqQ[n2,2*n] && EqQ[Simplify[m-n+1],0]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.3.2.2: If  p∈(SuperPlus[ℤ]), then

∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫ExpandIntegrand[(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p),x]dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d*x)^m*(a+b*x^n+c*x^(2*n))^p,x],x] /;
FreeQ[{a,b,c,d,m,n},x] && EqQ[n2,2*n] && IGtQ[p,0] && Not[IntegerQ[Simplify[(m+1)/n]]]

3:  ∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when p∈(SuperMinus[ℤ])∧ n<0

Derivation: Algebraic simplification

Basis: If  p∈ℤ, then (((a+b (x^n)+c (x^(2 n))))^p)==(x^(2 n p))(((c+b (x^(-n))+a (x^(-2 n))))^p)

Rule 1.2.3.2.3: If  p∈(SuperMinus[ℤ])∧ n<0, then

∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(x^(m+2 n p))(((c+b (x^(-n))+a (x^(-2 n))))^p)dx

Program code:

Int[x_^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  Int[x^(m+2*n*p)*(c+b*x^(-n)+a*x^(-2*n))^p,x] /;
FreeQ[{a,b,c,m,n},x] && EqQ[n2,2*n] && ILtQ[p,0] && NegQ[n]

4.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0

x:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  (b^2)-4 a c==0, then a+b z+c (z^2)==(1/c) ((((b/2)+c z))^2)

Rule 1.2.3.2.4.1: If  (b^2)-4 a c==0 ∧ p∈ℤ, then

∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/(c^p))∫(((d x))^m) ((((b/2)+c (x^n)))^(2 p))dx

Program code:

(* Int[(d_.*x_)^m_.*(a_+b_.*x_^n_.+c_.*x_^n2_.)^p_,x_Symbol] :=
  1/c^p*Int[(d*x)^m*(b/2+c*x^n)^(2*p),x] /;
FreeQ[{a,b,c,d,m,n,p},x] && EqQ[n2,2*n] && EqQ[b^2-4*a*c,0] && IntegerQ[p] *)

2.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

x:  ∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ m+2 n (p+1)+1==0 ∧ p≠-(1/2)

Derivation: Square trinomial recurrence 2c with m+2 n (p+1)+1==0

Rule 1.2.3.2.4.2.1: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ m+2 n (p+1)+1==0 ∧ p≠-(1/2), then

∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((((d x))^(m+1))(((a+b (x^n)+c (x^(2 n))))^(p+1)))/(2 a d n (p+1) (2p+1)))-(((((d x))^(m+1)) (2 a+b (x^n))(((a+b (x^n)+c (x^(2 n))))^p))/(2 a d n(2p+1)))

Program code:

(* Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  (d*x)^(m+1)*(a+b*x^n+c*x^(2*n))^(p+1)/(2*a*d*n*(p+1)*(2*p+1)) - 
  (d*x)^(m+1)*(2*a+b*x^n)*(a+b*x^n+c*x^(2*n))^p/(2*a*d*n*(2*p+1)) /;
FreeQ[{a,b,c,d,m,n,p},x] && EqQ[n2,2*n] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && EqQ[m+2*n*(p+1)+1,0] && NeQ[2*p+1,0] *)

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b (x^n)+c (x^(2 n))))^p)/(((1+((2 c (x^n))/b)))^(2 p)))==0

Rule 1.2.3.2.4.2.2: If  (b^2)-4 a c==0 ∧ p∉ℤ, then

∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((a^(IntPart[p])) (((a+b (x^n)+c (x^(2 n))))^(FracPart[p])))/(((1+((2 c (x^n))/b)))^(2 FracPart[p])))∫(((d x))^m) (((1+((2 c (x^n))/b)))^(2 p))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_.+c_.*x_^n2_.)^p_,x_Symbol] :=
  (a+b*x^n+c*x^(2*n))^FracPart[p]/(c^IntPart[p]*(b/2+c*x^n)^(2*FracPart[p]))*Int[(d*x)^m*(b/2+c*x^n)^(2*p),x] /;
FreeQ[{a,b,c,d,m,n,p},x] && EqQ[n2,2*n] && EqQ[b^2-4*a*c,0] && IntegerQ[p-1/2]

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_.+c_.*x_^n2_.)^p_,x_Symbol] :=
  a^IntPart[p]*(a+b*x^n+c*x^(2*n))^FracPart[p]/(1+2*c*x^n/b)^(2*FracPart[p])*Int[(d*x)^m*(1+2*c*x^n/b)^(2*p),x] /;
FreeQ[{a,b,c,d,m,n,p},x] && EqQ[n2,2*n] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[2*p]]

5.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ ((m+1)/n)∈ℤ

1:  ∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ ((m+1)/n)∈ℤ

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m)F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Note: If  n∈ℤ ∧ ((m+1)/n)∈ℤ, then m∈ℤ, and (((d x))^m) automatically evaluates to (d^m)(x^m).

Rule 1.2.3.2.5.1: If  (b^2)-4 a c≠0 ∧ ((m+1)/n)∈ℤ, then

∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((a+b x+c (x^2)))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a+b*x+c*x^2)^p,x],x,x^n] /;
FreeQ[{a,b,c,m,n,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IntegerQ[Simplify[(m+1)/n]]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ ((m+1)/n)∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((d x))^m)/(x^m))==0

Basis: ((((d x))^m)/(x^m))==(((d^(IntPart[m]))(((d x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.2.3.2.5.2: If  (b^2)-4 a c≠0 ∧ ((m+1)/n)∈ℤ, then

∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((d^(IntPart[m]))(((d x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  d^IntPart[m]*(d*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,m,n,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IntegerQ[Simplify[(m+1)/n]]

6.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈ℤ

1.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])

1:  ∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈ℤ ∧ GCD[m+1,n]≠1

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ m∈ℤ, let k=GCD[m+1,n], then (x^m) F[(x^n)]==(1/k)Subst[(x^(((m+1)/k)-1)) F[(x^(n/k))],x,(x^k)] (∂_x)(x^k)

Rule 1.2.3.2.6.1.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈ℤ, let k=GCD[m+1,n], if  k≠1, then

∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/k) Subst[∫(x^(((m+1)/k)-1)) (((a+b (x^(n/k))+c (x^(2 n/k))))^p)dx,x,(x^k)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{k=GCD[m+1,n]},
  1/k*Subst[Int[x^((m+1)/k-1)*(a+b*x^(n/k)+c*x^(2*n/k))^p,x],x,x^k] /;
 k≠1] /;
FreeQ[{a,b,c,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IntegerQ[m]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (((d x))^m) F[x]==(k/d) Subst[(x^(k (m+1)-1))F[((x^k)/d)],x,(((d x))^(1/k))] (∂_x)(((d x))^(1/k))

Rule 1.2.3.2.6.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈𝔽, let k=Denominator[m], then

∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (k/d) Subst[∫(x^(k (m+1)-1)) (((a+((b (x^(k n)))/(d^n))+((c (x^(2 k n)))/(d^(2 n)))))^p) dx,x,(((d x))^(1/k))]

Program code:

Int[(d_.*x_)^m_*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  k/d*Subst[Int[x^(k*(m+1)-1)*(a+b*x^(k*n)/d^n+c*x^(2*k*n)/d^(2*n))^p,x],x,(d*x)^(1/k)]] /;
FreeQ[{a,b,c,d,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && FractionQ[m] && IntegerQ[p]

3.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])

1:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ m>n-1 ∧ m+2 n p+1≠0 ∧ m+n(2 p-1)+1≠0

Derivation: Trinomial recurrence 1b with A=0, B=1 and m=m-n

Rule 1.2.3.2.6.1.3.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ m>n-1 ∧ m+2 n p+1≠0 ∧ m+n(2 p-1)+1≠0, then

∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
(((d^(n-1))(((d x))^(m-n+1)) (((a+b (x^n)+c (x^(2 n))))^p) (b n p+c (m+n(2 p-1)+1) (x^n)))/(c (m+2 n p+1)(m+n(2 p-1)+1)))-
((n p (d^n))/(c (m+2 n p+1)(m+n(2 p-1)+1)))∫(((d x))^(m-n)) (((a+b (x^n)+c (x^(2 n))))^(p-1)) (a b(m-n+1)-(2 a c (m+n(2 p-1)+1)-(b^2)(m+n(p-1)+1)) (x^n))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  d^(n-1)*(d*x)^(m-n+1)*(a+b*x^n+c*x^(2*n))^p*(b*n*p+c*(m+n*(2*p-1)+1)*x^n)/(c*(m+2*n*p+1)*(m+n*(2*p-1)+1)) - 
  n*p*d^n/(c*(m+2*n*p+1)*(m+n*(2*p-1)+1))*
    Int[(d*x)^(m-n)*(a+b*x^n+c*x^(2*n))^(p-1)*Simp[a*b*(m-n+1)-(2*a*c*(m+n*(2*p-1)+1)-b^2*(m+n*(p-1)+1))*x^n,x],x] /;
FreeQ[{a,b,c,d},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IGtQ[p,0] && GtQ[m,n-1] && NeQ[m+2*n*p+1,0] && NeQ[m+n*(2*p-1)+1,0]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ m<-1

Reference: G&R 2.160.2

Derivation: Trinomial recurrence 1a with A=1 and B=0

Rule 1.2.3.2.6.1.3.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ m<-1, then

∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((((d x))^(m+1))(((a+b (x^n)+c (x^(2 n))))^p))/(d (m+1)))-((n p)/((d^n) (m+1)))∫(((d x))^(m+n)) (b+2 c (x^n))(((a+b (x^n)+c (x^(2 n))))^(p-1))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  (d*x)^(m+1)*(a+b*x^n+c*x^(2*n))^p/(d*(m+1)) - 
  n*p/(d^n*(m+1))*Int[(d*x)^(m+n)*(b+2*c*x^n)*(a+b*x^n+c*x^(2*n))^(p-1),x] /;
FreeQ[{a,b,c,d},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IGtQ[p,0] && LtQ[m,-1]

3:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ m+2 n p+1≠0

Derivation: Trinomial recurrence 1a with A=0, B=1 and m=m-n

Derivation: Trinomial recurrence 1b with A=1 and B=0

Rule 1.2.3.2.6.1.3.4: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ m+2 n p+1≠0, then

∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((((d x))^(m+1))(((a+b (x^n)+c (x^(2 n))))^p))/(d (m+2 n p+1)))+((n p)/(m+2 n p+1))∫(((d x))^m) (2 a+b (x^n))(((a+b (x^n)+c (x^(2 n))))^(p-1))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  (d*x)^(m+1)*(a+b*x^n+c*x^(2*n))^p/(d*(m+2*n*p+1)) + 
  n*p/(m+2*n*p+1)*Int[(d*x)^m*(2*a+b*x^n)*(a+b*x^n+c*x^(2*n))^(p-1),x] /;
FreeQ[{a,b,c,d,m},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IGtQ[p,0] && NeQ[m+2*n*p+1,0]

4.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p+1∈(SuperMinus[ℤ])

1.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p+1∈(SuperMinus[ℤ])∧ m>n-1

1:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p+1∈(SuperMinus[ℤ])∧ n-1<m≤2 n-1

Derivation: Trinomial recurrence 2a with A=1 and B=0

Derivation: Trinomial recurrence 2b with A=0, B=1 and m=m-n

Rule 1.2.3.2.6.1.4.1.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p+1∈(SuperMinus[ℤ])∧ n-1<m≤2 n-1, then

∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
(((d^(n-1)) (((d x))^(m-n+1))(b+2 c (x^n))(((a+b (x^n)+c (x^(2 n))))^(p+1)))/(n(p+1) ((b^2)-4 a c) ))-
((d^n)/(n(p+1) ((b^2)-4 a c) ))∫(((d x))^(m-n))(b(m-n+1)+2c(m+2 n(p+1)+1) (x^n))(((a+b (x^n)+c (x^(2 n))))^(p+1))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  d^(n-1)*(d*x)^(m-n+1)*(b+2*c*x^n)*(a+b*x^n+c*x^(2*n))^(p+1)/(n*(p+1)*(b^2-4*a*c)) - 
  d^n/(n*(p+1)*(b^2-4*a*c))*
    Int[(d*x)^(m-n)*(b*(m-n+1)+2*c*(m+2*n*(p+1)+1)*x^n)*(a+b*x^n+c*x^(2*n))^(p+1),x] /;
FreeQ[{a,b,c,d},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && ILtQ[p,-1] && GtQ[m,n-1] && LeQ[m,2*n-1]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p+1∈(SuperMinus[ℤ])∧ m>2 n-1

Derivation: Trinomial recurrence 2a with A=0, B=1 and m=m-n

Rule 1.2.3.2.6.1.4.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p+1∈(SuperMinus[ℤ])∧ m>2 n-1, then

∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
-(((d^(2 n-1))(((d x))^(m-2 n+1))(2 a+b (x^n))(((a+b (x^n)+c (x^(2 n))))^(p+1)))/(n(p+1) ((b^2)-4 a c)))+
((d^(2 n))/(n(p+1) ((b^2)-4 a c) ))∫(((d x))^(m-2 n)) (2 a(m-2 n+1)+b(m+n(2p+1)+1) (x^n)) (((a+b (x^n)+c (x^(2 n))))^(p+1))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  -d^(2*n-1)*(d*x)^(m-2*n+1)*(2*a+b*x^n)*(a+b*x^n+c*x^(2*n))^(p+1)/(n*(p+1)*(b^2-4*a*c)) + 
  d^(2*n)/(n*(p+1)*(b^2-4*a*c))*
    Int[(d*x)^(m-2*n)*(2*a*(m-2*n+1)+b*(m+n*(2*p+1)+1)*x^n)*(a+b*x^n+c*x^(2*n))^(p+1),x] /;
FreeQ[{a,b,c,d},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && ILtQ[p,-1] && GtQ[m,2*n-1]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p+1∈(SuperMinus[ℤ])

Derivation: Trinomial recurrence 2b with A=1 and B=0

Rule 1.2.3.2.6.1.4.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p+1∈(SuperMinus[ℤ]), then

∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
-(((((d x))^(m+1))((b^2)-2 a c+b c (x^n))(((a+b (x^n)+c (x^(2 n))))^(p+1)))/(a d n(p+1) ((b^2)-4 a c)))+
(1/(a n(p+1)((b^2)-4 a c) ))∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^(p+1)) ((b^2)(m+n (p+1)+1)-2a c(m+2 n(p+1)+1)+b c(m+n(2p+3)+1)(x^n))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  -(d*x)^(m+1)*(b^2-2*a*c+b*c*x^n)*(a+b*x^n+c*x^(2*n))^(p+1)/(a*d*n*(p+1)*(b^2-4*a*c)) + 
  1/(a*n*(p+1)*(b^2-4*a*c))*
    Int[(d*x)^m*(a+b*x^n+c*x^(2*n))^(p+1)*Simp[b^2*(m+n*(p+1)+1)-2*a*c*(m+2*n*(p+1)+1)+b*c*(m+n*(2*p+3)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,m},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && ILtQ[p,-1]

5:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m>2 n-1 ∧ m+2 n p+1≠0

Reference: G&R 2.160.3

Derivation: Trinomial recurrence 3a with A=0, B=1 and m=m-n

Note: G&R 2.174.1 is a special case of G&R 2.160.3.

Rule 1.2.3.2.6.1.5: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m>2 n-1 ∧ m+2 n p+1≠0, then

∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
(((d^(2 n-1)) (((d x))^(m-2 n+1))(((a+b (x^n)+c (x^(2 n))))^(p+1)))/(c (m+2 n p+1)))-((d^(2 n))/(c (m+2 n p+1)))∫(((d x))^(m-2 n)) (a(m-2 n+1)+b(m+n (p-1)+1)(x^n)) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  d^(2*n-1)*(d*x)^(m-2*n+1)*(a+b*x^n+c*x^(2*n))^(p+1)/(c*(m+2*n*p+1)) - 
  d^(2*n)/(c*(m+2*n*p+1))*
    Int[(d*x)^(m-2*n)*Simp[a*(m-2*n+1)+b*(m+n*(p-1)+1)*x^n,x]*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && GtQ[m,2*n-1] && NeQ[m+2*n*p+1,0] && IntegerQ[p]

6:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m<-1

Reference: G&R 2.160.1

Derivation: Trinomial recurrence 3b with A=1 and B=0

Note: G&R 2.161.6 is a special case of G&R 2.160.1.

Rule 1.2.3.2.6.1.6: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m<-1, then

∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
(((((d x))^(m+1)) (((a+b (x^n)+c (x^(2 n))))^(p+1)))/(a d (m+1)))-(1/(a (d^n) (m+1))) ∫(((d x))^(m+n)) (b (m+n (p+1)+1)+c (m+2 n (p+1)+1) (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_.*x_)^m_*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  (d*x)^(m+1)*(a+b*x^n+c*x^(2*n))^(p+1)/(a*d*(m+1)) - 
  1/(a*d^n*(m+1))*Int[(d*x)^(m+n)*(b*(m+n*(p+1)+1)+c*(m+2*n*(p+1)+1)*x^n)*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && LtQ[m,-1] && IntegerQ[p]

7.  ∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])

1:  ∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m<-1

Reference: G&R 2.176, CRC 123

Derivation: Algebraic expansion

Basis: ((((d z))^m)/(a+b z+c (z^2)))==((((d z))^m)/a)-(1/(a d))(((((d z))^(m+1)) (b+c z))/(a+b z+c (z^2)))

Rule 1.2.3.2.6.1.7.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m<-1, then

∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ((((d x))^(m+1))/(a d (m+1)))-(1/(a (d^n)))∫(((((d x))^(m+n)) (b+c (x^n)))/(a+b (x^n)+c (x^(2 n))))dx

Program code:

Int[(d_.*x_)^m_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  (d*x)^(m+1)/(a*d*(m+1)) -
  1/(a*d^n)*Int[(d*x)^(m+n)*(b+c*x^n)/(a+b*x^n+c*x^(2*n)),x] /;
FreeQ[{a,b,c,d},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && LtQ[m,-1]

2.  ∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m>2 n-1

1:  ∫((x^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m>3n-1 ∧ m∈ℤ

Derivation: Algebraic expansion

Rule 1.2.3.2.6.1.7.2.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m>3n-1 ∧ m∈ℤ, then

∫((x^m)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ∫PolynomialDivide[(x^m),a+b (x^n)+c (x^(2 n)),x]dx

Program code:

Int[x_^m_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  Int[PolynomialDivide[x^m,(a+b*x^n+c*x^(2*n)),x],x] /;
FreeQ[{a,b,c},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IGtQ[m,3*n-1]

2:  ∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m>2 n-1             Not necessary?

Reference: G&R 2.174.1, CRC 119

Derivation: Algebraic expansion

Basis: ((((d z))^m)/(a+b z+c (z^2)))==(((d^2)(((d z))^(m-2)))/c)-((d^2)/c)(((((d z))^(m-2)) (a+b z))/(a+b z+c (z^2)))

Rule 1.2.3.2.6.1.7.2.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m>2 n-1, then

∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  (((d^(2n-1)) (((d x))^(m-2 n+1)))/(c (m-2 n+1)))-((d^(2n))/c)∫(((((d x))^(m-2 n)) (a+b (x^n)))/(a+b (x^n)+c (x^(2 n))))dx

Program code:

Int[(d_.*x_)^m_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  d^(2*n-1)*(d*x)^(m-2*n+1)/(c*(m-2*n+1)) -
  d^(2*n)/c*Int[(d*x)^(m-2*n)*(a+b*x^n)/(a+b*x^n+c*x^(2*n)),x] /;
FreeQ[{a,b,c,d},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && GtQ[m,2*n-1]

3.  ∫((x^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ ((n/2)|m)∈(SuperPlus[ℤ])∧ (n/2)≤m<2 n ∧ (b^2)-4 a c≯0

1:  ∫((x^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ ((n/2)|m)∈(SuperPlus[ℤ])∧ ((3 n)/2)≤m<2 n ∧ (b^2)-4 a c≯0

Derivation: Algebraic expansion

Basis: If  q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then ((z^3)/(a+b (z^2)+c (z^4)))==((q+r z)/(2 c r (q+r z+(z^2))))-((q-r z)/(2 c r (q-r z+(z^2))))

Note: If (a|b|c)∈ℝ ∧ (b^2)-4 a c<0, then (a/c)>0 and 2 (Sqrt[(a/c)])-(b/c)>0.

Rule 1.2.3.2.6.1.7.3.1: If  (b^2)-4 a c≠0 ∧ ((n/2)|m)∈(SuperPlus[ℤ])∧ ((3 n)/2)≤m<2 n ∧ (b^2)-4 a c≯0, let q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then

∫((x^m)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  (1/(2 c r))∫(((x^(m-3n/2)) (q+r (x^(n/2))))/(q+r (x^(n/2))+(x^n)))dx-(1/(2 c r))∫(((x^(m-3n/2)) (q-r (x^(n/2))))/(q-r (x^(n/2))+(x^n)))dx

Program code:

Int[x_^m_./(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  With[{q=Rt[a/c,2]},
  With[{r=Rt[2*q-b/c,2]},
  1/(2*c*r)*Int[x^(m-3*(n/2))*(q+r*x^(n/2))/(q+r*x^(n/2)+x^n),x] - 
  1/(2*c*r)*Int[x^(m-3*(n/2))*(q-r*x^(n/2))/(q-r*x^(n/2)+x^n),x]]] /;
FreeQ[{a,b,c},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n/2,0] && IGtQ[m,0] && GeQ[m,3*n/2] && LtQ[m,2*n] && NegQ[b^2-4*a*c]

2:  ∫((x^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ ((n/2)|m)∈(SuperPlus[ℤ])∧ (n/2)≤m<((3 n)/2) ∧ (b^2)-4 a c≯0

Derivation: Algebraic expansion

Basis: If  q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then (z/(a+b (z^2)+c (z^4)))==(1/(2 c r (q-r z+(z^2))))-(1/(2 c r (q+r z+(z^2))))

Note: If (a|b|c)∈ℝ ∧ (b^2)-4 a c<0, then (a/c)>0 and 2 (Sqrt[(a/c)])-(b/c)>0.

Rule 1.2.3.2.6.1.7.3.2: If  (b^2)-4 a c≠0 ∧ ((n/2)|m)∈(SuperPlus[ℤ])∧ (n/2)≤m<((3 n)/2) ∧ (b^2)-4 a c≯0, let q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then

∫((x^m)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  (1/(2 c r))∫((x^(m-n/2))/(q-r (x^(n/2))+(x^n)))dx-(1/(2 c r))∫((x^(m-n/2))/(q+r (x^(n/2))+(x^n)))dx

Program code:

Int[x_^m_./(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  With[{q=Rt[a/c,2]},
  With[{r=Rt[2*q-b/c,2]},
  1/(2*c*r)*Int[x^(m-n/2)/(q-r*x^(n/2)+x^n),x] - 
  1/(2*c*r)*Int[x^(m-n/2)/(q+r*x^(n/2)+x^n),x]]] /;
FreeQ[{a,b,c},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n/2,0] && IGtQ[m,0] && GeQ[m,n/2] && LtQ[m,3*n/2] && NegQ[b^2-4*a*c]

4:  ∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m≥n

Reference: G&R 2.161.1a & G&R 2.161.3

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then ((((d z))^m)/(a+b z+c (z^2)))==(d/2) ((b/q)+1)((((d z))^(m-1))/((b/2)+(q/2)+c z))-(d/2) ((b/q)-1)((((d z))^(m-1))/((b/2)-(q/2)+c z))

Rule 1.2.3.2.6.1.7.4: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m≥n, let q->(Sqrt[(b^2)-4 a c]), then

∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ((d^n)/2) ((b/q)+1)∫((((d x))^(m-n))/((b/2)+(q/2)+c (x^n)))dx-((d^n)/2) ((b/q)-1)∫((((d x))^(m-n))/((b/2)-(q/2)+c (x^n)))dx

Program code:

Int[(d_.*x_)^m_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  d^n/2*(b/q+1)*Int[(d*x)^(m-n)/(b/2+q/2+c*x^n),x] - 
  d^n/2*(b/q-1)*Int[(d*x)^(m-n)/(b/2-q/2+c*x^n),x]] /;
FreeQ[{a,b,c,d},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && GeQ[m,n]

5:  ∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])

Reference: G&R 2.161.1a

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then (1/(a+b z+c (z^2)))==(c/q)(1/((b/2)-(q/2)+c z))-(c/q)(1/((b/2)+(q/2)+c z))

Rule 1.2.3.2.6.1.7.5: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ]), let q->(Sqrt[(b^2)-4 a c]), then

∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  (c/q)∫((((d x))^m)/((b/2)-(q/2)+c (x^n)))dx-(c/q)∫((((d x))^m)/((b/2)+(q/2)+c (x^n)))dx

Program code:

Int[(d_.*x_)^m_./(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  c/q*Int[(d*x)^m/(b/2-q/2+c*x^n),x] - c/q*Int[(d*x)^m/(b/2+q/2+c*x^n),x]] /;
FreeQ[{a,b,c,d,m},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0]

2.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])

1.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈ℚ

1:  ∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈ℤ

Derivation: Integration by substitution

Basis: F[x]==-Subst[((F[(x^(-1))] )/(x^2)),x,(1/x)](∂_x)(1/x)

Rule 1.2.3.2.6.2.1.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈ℤ, then

∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  -Subst[∫((((a+b (x^(-n))+c (x^(-2 n))))^p)/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  -Subst[Int[(a+b*x^(-n)+c*x^(-2*n))^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && ILtQ[n,0] && IntegerQ[m]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ k>1, then (((d x))^m) F[(x^n)]==-(k/d)Subst[ ((F[(d^(-n)) (x^(-k n))])/(x^(k (m+1)+1))),x,(1/(((d x))^(1/k)))] (∂_x)(1/(((d x))^(1/k)))

Rule 1.2.3.2.6.2.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈𝔽, let k=Denominator[m], then

∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  -(k/d)Subst[∫((((a+b (d^(-n)) (x^(-k n))+c (d^(-2 n)) (x^(-2 k n))))^p)/(x^(k (m+1)+1)))dx,x,(1/(((d x))^(1/k)))]

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  -k/d*Subst[Int[(a+b*d^(-n)*x^(-k*n)+c*d^(-2*n)*x^(-2*k*n))^p/x^(k*(m+1)+1),x],x,1/(d*x)^(1/k)]] /;
FreeQ[{a,b,c,d,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && ILtQ[n,0] && FractionQ[m]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∉ℚ

Derivation:  Piecewise constant extraction and integration by substitution

Basis: (∂_x)((((d x))^m) ((((x^(-1))))^m))==0

Basis: (((d x))^m) ((((x^(-1))))^m)==(d^(IntPart[m])) (((d x))^(FracPart[m])) ((((x^(-1))))^(FracPart[m]))

Basis: F[x]==-Subst[((F[(x^(-1))] )/(x^2)),x,(1/x)](∂_x)(1/x)

Rule 1.2.3.2.6.2.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∉ℚ, then

∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (d^(IntPart[m])) (((d x))^(FracPart[m])) ((((x^(-1))))^(FracPart[m]))∫((((a+b (x^n)+c (x^(2 n))))^p)/((((x^(-1))))^m))dx
  ⟶  -(d^(IntPart[m])) (((d x))^(FracPart[m])) ((((x^(-1))))^(FracPart[m])) Subst[∫((((a+b (x^(-n))+c (x^(-2 n))))^p)/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[(d_.*x_)^m_*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  -d^IntPart[m]*(d*x)^FracPart[m]*(x^(-1))^FracPart[m]*Subst[Int[(a+b*x^(-n)+c*x^(-2*n))^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,d,m,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && ILtQ[n,0] && Not[RationalQ[m]]

7.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈𝔽

1:  ∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (x^m)F[(x^n)]==k Subst[(x^(k(m+1)-1))F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule 1.2.3.2.7.1: If  (b^2)-4 a c≠0 ∧ n∈𝔽, let k=Denominator[n], then

∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  k Subst[∫(x^(k(m+1)-1)) (((a+b (x^(k n))+c (x^(2 k n))))^p)dx,x,(x^(1/k))]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k*(m+1)-1)*(a+b*x^(k*n)+c*x^(2*k*n))^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,m,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && FractionQ[n]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈𝔽

Derivation: Piecewise constant extraction

Basis: (∂_x)((((d x))^m)/(x^m))==0

Basis: ((((d x))^m)/(x^m))==(((d^(IntPart[m]))(((d x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.2.3.2.7.2: If  (b^2)-4 a c≠0 ∧ n∈𝔽, then

∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((d^(IntPart[m]))(((d x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_*x_)^m_*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  d^IntPart[m]*(d*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,m,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && FractionQ[n]

8.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ (n/(m+1))∈ℤ

1:  ∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ (n/(m+1))∈ℤ

Derivation: Integration by substitution

Basis: If (n/(m+1))∈ℤ, then (x^m)F[(x^n)]==(1/(m+1))Subst[F[(x^(n/(m+1)))],x,(x^(m+1))](∂_x)(x^(m+1))

Rule 1.2.3.2.8.1: If  (b^2)-4 a c≠0 ∧ (n/(m+1))∈ℤ

∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/(m+1))Subst[∫(((a+b (x^(n/(m+1)))+c (x^((2 n)/(m+1)))))^p)dx,x,(x^(m+1))]

Program code:

Int[x_^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  1/(m+1)*Subst[Int[(a+b*x^Simplify[n/(m+1)]+c*x^Simplify[2*n/(m+1)])^p,x],x,x^(m+1)] /;
FreeQ[{a,b,c,m,n,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IntegerQ[Simplify[n/(m+1)]] && Not[IntegerQ[n]]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ (n/(m+1))∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((d x))^m)/(x^m))==0

Basis: ((((d x))^m)/(x^m))==(((d^(IntPart[m]))(((d x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.2.3.2.8.2: If  (b^2)-4 a c≠0 ∧ (n/(m+1))∈ℤ, then

∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((d^(IntPart[m]))(((d x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_*x_)^m_*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  d^IntPart[m]*(d*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,m,n,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IntegerQ[Simplify[n/(m+1)]] && Not[IntegerQ[n]]

9.  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ p∈(SuperMinus[ℤ])

1:  ∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0

Reference: G&R 2.161.1a

Derivation: Algebraic expansion

Basis: Let q=(Sqrt[(b^2)-4 a c]), then (1/(a+b z+c (z^2)))==((2 c)/q)(1/(b-q+2 c z))-((2 c)/q)(1/(b+q+2 c z))

Rule 1.2.3.2.9.1: If  (b^2)-4 a c≠0, let q=(Sqrt[(b^2)-4 a c]), then

∫((((d x))^m)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ((2 c)/q)∫((((d x))^m)/(b-q+2 c (x^n)))dx-((2 c)/q)∫((((d x))^m)/(b+q+2 c (x^n)))dx

Program code:

Int[(d_.*x_)^m_./(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  2*c/q*Int[(d*x)^m/(b-q+2*c*x^n),x] -
  2*c/q*Int[(d*x)^m/(b+q+2*c*x^n),x]] /;
FreeQ[{a,b,c,d,m,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0]

2:  ∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ p+1∈(SuperMinus[ℤ])

Derivation: Trinomial recurrence 2b with A=1 and B=0

Rule 1.2.3.2.9.2: If  (b^2)-4 a c≠0 ∧ p+1∈(SuperMinus[ℤ]), then

∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
-(((((d x))^(m+1))((b^2)-2 a c+b c (x^n))(((a+b (x^n)+c (x^(2 n))))^(p+1)))/(a d n(p+1) ((b^2)-4 a c)))+
(1/(a n(p+1)((b^2)-4 a c) ))∫(((d x))^m) (((a+b (x^n)+c (x^(2 n))))^(p+1)) ((b^2)(m+n (p+1)+1)-2a c(m+2 n(p+1)+1)+b c(m+n(2p+3)+1)(x^n))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  -(d*x)^(m+1)*(b^2-2*a*c+b*c*x^n)*(a+b*x^n+c*x^(2*n))^(p+1)/(a*d*n*(p+1)*(b^2-4*a*c)) + 
  1/(a*n*(p+1)*(b^2-4*a*c))*
    Int[(d*x)^m*(a+b*x^n+c*x^(2*n))^(p+1)*Simp[b^2*(n*(p+1)+m+1)-2*a*c*(m+2*n*(p+1)+1)+b*c*(2*n*p+3*n+m+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,m,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && ILtQ[p+1,0]

10:  ∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx

Derivation: Piecewise constant extraction

Basis: (∂_x)(( (((a+b (x^n)+c (x^(2 n))))^p))/((((1+((2 c (x^n))/(b+(Sqrt[(b^2)-4 a c])))))^p) (((1+((2 c (x^n))/(b-(Sqrt[(b^2)-4 a c])))))^p)))==0

Rule 1.2.3.2.10:

∫(((d x))^m)(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (( (a^(IntPart[p])) (((a+b (x^n)+c (x^(2 n))))^(FracPart[p])))/((((1+((2 c (x^n))/(b+(Sqrt[(b^2)-4 a c])))))^(FracPart[p])) (((1+((2 c (x^n))/(b-(Sqrt[(b^2)-4 a c])))))^(FracPart[p])))) ∫(((d x))^m)(((1+((2 c (x^n))/(b+(Sqrt[(b^2)-4 a c])))))^p) (((1+((2 c (x^n))/(b-(Sqrt[(b^2)-4 a c])))))^p)dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  a^IntPart[p]*(a+b*x^n+c*x^(2*n))^FracPart[p]/
    ((1+2*c*x^n/(b+Rt[b^2-4*a*c,2]))^FracPart[p]*(1+2*c*x^n/(b-Rt[b^2-4*a*c,2]))^FracPart[p])*
    Int[(d*x)^m*(1+2*c*x^n/(b+Sqrt[b^2-4*a*c]))^p*(1+2*c*x^n/(b-Sqrt[b^2-4*a*c]))^p,x] /;
FreeQ[{a,b,c,d,m,n,p},x] && EqQ[n2,2*n]

11.  ∫(((d x))^m) (((a+b (x^(-n))+c (x^n)))^p)dx

1.  ∫(x^m) (((a+b (x^(-n))+c (x^n)))^p)dx

1:  ∫(x^m) (((a+b (x^(-n))+c (x^n)))^p)dx  when  p∈ℤ

Derivation: Algebraic normalization

Basis: a+b (x^(-n))+c (x^n)==(x^(-n)) (b+a (x^n)+c (x^(2 n)))

Rule 1.2.3.2.11.1.1: If  p∈ℤ, then

∫(x^m) (((a+b (x^(-n))+c (x^n)))^p)dx  ⟶  ∫(x^(m-n p)) (((b+a (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[x_^m_.*(a_+b_.*x_^mn_+c_.*x_^n_.)^p_.,x_Symbol] :=
  Int[x^(m-n*p)*(b+a*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,m,n},x] && EqQ[mn,-n] && IntegerQ[p] && PosQ[n]

2:  ∫(x^m) (((a+b (x^(-n))+c (x^n)))^p)dx  when  p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(n p)) (((a+b (x^(-n))+c (x^n)))^p))/(((b+a (x^n)+c (x^(2 n))))^p))==0

Basis: (((x^(n p)) (((a+b (x^(-n))+c (x^n)))^p))/(((b+a (x^n)+c (x^(2 n))))^p))==(((x^(n FracPart[p])) (((a+b (x^(-n))+c (x^n)))^(FracPart[p])))/(((b+a (x^n)+c (x^(2 n))))^(FracPart[p])))

Rule 1.2.3.2.11.1.2: If  p∉ℤ, then

∫(x^m) (((a+b (x^(-n))+c (x^n)))^p)dx  ⟶  (((x^(n FracPart[p])) (((a+b (x^(-n))+c (x^n)))^(FracPart[p])))/(((b+a (x^n)+c (x^(2 n))))^(FracPart[p])))∫(x^(m-n p)) (((b+a (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[x_^m_.*(a_+b_.*x_^mn_+c_.*x_^n_.)^p_.,x_Symbol] :=
  x^(n*FracPart[p])*(a+b/x^n+c*x^n)^FracPart[p]/(b+a*x^n+c*x^(2*n))^FracPart[p]*Int[x^(m-n*p)*(b+a*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,m,n,p},x] && EqQ[mn,-n] && Not[IntegerQ[p]] && PosQ[n]

2:  ∫(((d x))^m) (((a+b (x^(-n))+c (x^n)))^p)dx

Derivation: Piecewise constant extraction

Basis: (∂_x)((((d x))^m)/(x^m))==0

Basis: ((((d x))^m)/(x^m))==(((d^(IntPart[m]))(((d x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.2.3.2.11.2:

∫(((d x))^m) (((a+b (x^(-n))+c (x^n)))^p)dx  ⟶  (((d^(IntPart[m]))(((d x))^(FracPart[m])))/(x^(FracPart[m]))) ∫(x^m) (((a+b (x^(-n))+c (x^n)))^p)dx

Program code:

Int[(d_*x_)^m_.*(a_+b_.*x_^mn_+c_.*x_^n_.)^p_.,x_Symbol] :=
  d^IntPart[m]*(d*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*x^(-n)+c*x^n)^p,x] /;
FreeQ[{a,b,c,d,m,n,p},x] && EqQ[mn,-n]

S.  ∫(u^m) (((a+b (v^n)+c (v^(2 n))))^p)dx  when  v==d+e x ∧ u==f v

1:  ∫(x^m) (((a+b (v^n)+c (v^(2 n))))^p)dx  when  v==d+e x ∧ m∈ℤ

Derivation: Integration by substitution

Basis: If  m∈ℤ, then (x^m)F[d+e x]==(1/(e^(m+1)))Subst[(((x-d))^m) F[x],x,d+e x](∂_x)(d+e x)

Rule 1.2.3.2.S.1: If  v==d+e x ∧ m∈ℤ, then

∫(x^m) (((a+b (v^n)+c (v^(2 n))))^p)dx  ⟶  (1/(e^(m+1)))Subst[∫(((x-d))^m) (((a+b (x^n)+c (x^(2 n))))^p)dx,x,v]

Program code:

Int[x_^m_.*(a_.+b_.*v_^n_+c_.*v_^n2_.)^p_.,x_Symbol] :=
  1/Coefficient[v,x,1]^(m+1)*Subst[Int[SimplifyIntegrand[(x-Coefficient[v,x,0])^m*(a+b*x^n+c*x^(2*n))^p,x],x],x,v] /;
FreeQ[{a,b,c,n,p},x] && EqQ[n2,2*n] && LinearQ[v,x] && IntegerQ[m] && NeQ[v,x]

2:  ∫(u^m) (((a+b (v^n)+c (v^(2 n))))^p)dx  when  v==d+e x ∧ u==f v

Derivation: Integration by substitution and piecewise constant extraction

Basis: If  u==f v, then (∂_x)((u^m)/(v^m))==0

Rule 1.2.3.2.S.2: If  v==d+e x ∧ u==f v, then

∫(u^m) (((a+b (v^n)+c (v^(2 n))))^p)dx  ⟶  ((u^m)/(e (v^m)))Subst[∫(x^m) (((a+b (x^n)+c (x^(2 n))))^p)dx,x,v]

Program code:

Int[u_^m_.*(a_.+b_.*v_^n_+c_.*v_^n2_.)^p_.,x_Symbol] :=
  u^m/(Coefficient[v,x,1]*v^m)*Subst[Int[x^m*(a+b*x^n+c*x^(2*n))^p,x],x,v] /;
FreeQ[{a,b,c,m,n,p},x] && EqQ[n2,2*n] && LinearPairQ[u,v,x]