Rules for integrating miscellaneous algebraic functions

1.  ∫(u/(e(Sqrt[a+b x])+f(Sqrt[c+d x])))dx

1:  ∫(u/(e(Sqrt[a+b x])+f(Sqrt[c+d x])))dx  when  b c-a d≠0 ∧ a (e^2)-c (f^2)==0

Derivation: Algebraic expansion

Basis: If  a (e^2)-c (f^2)==0, then (1/(e (Sqrt[a+b x])+f (Sqrt[c+d x])))==((c (Sqrt[a+b x]))/(e(b c-a d)x))-((a (Sqrt[c+d x]))/(f(b c-a d) x))

Rule 1.3.3.1.1: If  b c-a d≠0 ∧ a (e^2)-c (f^2)==0, then

∫(u/(e(Sqrt[a+b x])+f(Sqrt[c+d x])))dx  ⟶  (c/(e(b c-a d)))∫((u(Sqrt[a+b x]))/x)dx-(a/(f(b c-a d)))∫((u(Sqrt[c+d x]))/x)dx

Program code:

Int[u_/(e_.*Sqrt[a_.+b_.*x_]+f_.*Sqrt[c_.+d_.*x_]),x_Symbol] :=
  c/(e*(b*c-a*d))*Int[(u*Sqrt[a+b*x])/x,x] - a/(f*(b*c-a*d))*Int[(u*Sqrt[c+d*x])/x,x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && EqQ[a*e^2-c*f^2,0]

2:  ∫(u/(e(Sqrt[a+b x])+f(Sqrt[c+d x])))dx  when  b c-a d≠0 ∧ b (e^2)-d (f^2)==0

Derivation: Algebraic expansion

Basis: If  b (e^2)-d (f^2)==0, then (1/(e (Sqrt[a+b x])+f (Sqrt[c+d x])))==-((d (Sqrt[a+b x]))/(e(b c-a d)))+((b (Sqrt[c+d x]))/(f(b c-a d)))

Rule 1.3.3.1.2: If  b c-a d≠0 ∧ b (e^2)-d (f^2)==0, then

∫(u/(e(Sqrt[a+b x])+f(Sqrt[c+d x])))dx  ⟶  -(d/(e(b c-a d)))∫u (Sqrt[a+b x])dx+(b/(f(b c-a d)))∫u (Sqrt[c+d x])dx

Program code:

Int[u_/(e_.*Sqrt[a_.+b_.*x_]+f_.*Sqrt[c_.+d_.*x_]),x_Symbol] :=
  -d/(e*(b*c-a*d))*Int[u*Sqrt[a+b*x],x] + b/(f*(b*c-a*d))*Int[u*Sqrt[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && EqQ[b*e^2-d*f^2,0]

3:  ∫(u/(e(Sqrt[a+b x])+f(Sqrt[c+d x])))dx  when  a (e^2)-c (f^2)≠0 ∧ b (e^2)-d (f^2)≠0

Derivation: Algebraic expansion

Basis: (1/(e (Sqrt[a+b x])+f (Sqrt[c+d x])))==((e (Sqrt[a+b x]))/(a (e^2)-c (f^2)+(b (e^2)-d (f^2)) x))-((f (Sqrt[c+d x]))/(a (e^2)-c (f^2)+(b (e^2)-d (f^2)) x))

Rule 1.3.3.1.3: If  a (e^2)-c (f^2)≠0 ∧ b (e^2)-d (f^2)≠0, then

∫(u/(e(Sqrt[a+b x])+f(Sqrt[c+d x])))dx  ⟶  e∫((u (Sqrt[a+b x]))/(a (e^2)-c (f^2)+(b (e^2)-d (f^2)) x))dx-f ∫((u (Sqrt[c+d x]))/(a (e^2)-c (f^2)+(b (e^2)-d (f^2)) x))dx

Program code:

Int[u_/(e_.*Sqrt[a_.+b_.*x_]+f_.*Sqrt[c_.+d_.*x_]),x_Symbol] :=
  e*Int[(u*Sqrt[a+b*x])/(a*e^2-c*f^2+(b*e^2-d*f^2)*x),x] - 
  f*Int[(u*Sqrt[c+d*x])/(a*e^2-c*f^2+(b*e^2-d*f^2)*x),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[a*e^2-c*f^2,0] && NeQ[b*e^2-d*f^2,0]

2.  ∫(u/(d (x^n)+c (Sqrt[a+b (x^(2 n))])))dx

1:  ∫(u/(d (x^n)+c (Sqrt[a+b (x^(2 n))])))dx  when  b (c^2)-(d^2)==0

Derivation: Algebraic expansion

Basis: If  b (c^2)-(d^2)==0, then (1/(d (x^n)+c (Sqrt[a+b (x^(2 n))])))==-((b (x^n))/(a d))+((Sqrt[a+b (x^(2 n))])/(a c))

Rule 1.3.3.2.1: If  b (c^2)-(d^2)==0, then

∫(u/(d (x^n)+c (Sqrt[a+b (x^(2 n))])))dx  ⟶ -(b/(a d))∫u (x^n)dx+(1/(a c)) ∫u (Sqrt[a+b (x^(2 n))])dx

Program code:

Int[u_./(d_.*x_^n_.+c_.*Sqrt[a_.+b_.*x_^p_.]),x_Symbol] :=
  -b/(a*d)*Int[u*x^n,x] + 1/(a*c)*Int[u*Sqrt[a+b*x^(2*n)],x] /;
FreeQ[{a,b,c,d,n},x] && EqQ[p,2*n] && EqQ[b*c^2-d^2,0]

2:  ∫((x^m)/(d (x^n)+c (Sqrt[a+b (x^(2 n))])))dx  when  b (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: (1/(d (x^n)+c (Sqrt[a+b (x^(2 n))])))==-((d (x^n))/(a (c^2)+(b (c^2)-(d^2)) (x^(2 n))))+((c (Sqrt[a+b (x^(2 n))]))/(a (c^2)+(b (c^2)-(d^2)) (x^(2 n))))

Rule 1.3.3.2.2: If  b (c^2)-(d^2)≠0, then

∫((x^m)/(d (x^n)+c (Sqrt[a+b (x^(2 n))])))dx  ⟶ -d ∫((x^(m+n))/(a (c^2)+(b (c^2)-(d^2)) (x^(2 n))))dx+c ∫(((x^m) (Sqrt[a+b (x^(2 n))]))/(a (c^2)+(b (c^2)-(d^2)) (x^(2 n))))dx

Program code:

Int[x_^m_./(d_.*x_^n_.+c_.*Sqrt[a_.+b_.*x_^p_.]),x_Symbol] :=
  -d*Int[x^(m+n)/(a*c^2+(b*c^2-d^2)*x^(2*n)),x] + 
  c*Int[(x^m*Sqrt[a+b*x^(2*n)])/(a*c^2+(b*c^2-d^2)*x^(2*n)),x] /;
FreeQ[{a,b,c,d,m,n},x] && EqQ[p,2*n] && NeQ[b*c^2-d^2,0]

3.  ∫(1/((a+b (x^3))(Sqrt[d+e x+f (x^2)])))dx

1:  ∫(1/((a+b (x^3))(Sqrt[d+e x+f (x^2)])))dx  when (a/b)>0

Derivation: Algebraic expansion

Basis: If  (r/s)=((((a/b)))^(1/3)), then (1/(a+b (z^3)))==(r/(3 a (r+s z)))+((r (2 r-s z))/(3 a((r^2)-r s z+(s^2)(z^2))))

Rule 1.3.3.3.1: If  (a/b)>0, let (r/s)=((((a/b)))^(1/3)), then

∫(1/((a+b (x^3))(Sqrt[d+e x+f (x^2)])))dx  ⟶  (r/(3 a))∫(1/((r+s x)(Sqrt[d+e x+f (x^2)])))dx+(r/(3 a))∫((2 r-s x)/(((r^2)-r s x+(s^2) (x^2))(Sqrt[d+e x+f (x^2)])))dx

Program code:

Int[1/((a_+b_.*x_^3)*Sqrt[d_.+e_.*x_+f_.*x_^2]),x_Symbol] :=
  With[{r=Numerator[Rt[a/b,3]], s=Denominator[Rt[a/b,3]]},
  r/(3*a)*Int[1/((r+s*x)*Sqrt[d+e*x+f*x^2]),x] +
  r/(3*a)*Int[(2*r-s*x)/((r^2-r*s*x+s^2*x^2)*Sqrt[d+e*x+f*x^2]),x]] /;
FreeQ[{a,b,d,e,f},x] && PosQ[a/b]

Int[1/((a_+b_.*x_^3)*Sqrt[d_.+f_.*x_^2]),x_Symbol] :=
  With[{r=Numerator[Rt[a/b,3]], s=Denominator[Rt[a/b,3]]},
  r/(3*a)*Int[1/((r+s*x)*Sqrt[d+f*x^2]),x] +
  r/(3*a)*Int[(2*r-s*x)/((r^2-r*s*x+s^2*x^2)*Sqrt[d+f*x^2]),x]] /;
FreeQ[{a,b,d,f},x] && PosQ[a/b]

2:  ∫(1/((a+b (x^3))(Sqrt[d+e x+f (x^2)])))dx  when (a/b)≯0

Derivation: Algebraic expansion

Basis: If  (r/s)=(((-(a/b)))^(1/3)), then (1/(a+b (z^3)))==(r/(3 a (r-s z)))+((r (2 r+s z))/(3 a((r^2)+r s z+(s^2)(z^2))))

Rule 1.3.3.3.2: If  (a/b)≯0, let (r/s)=(((-(a/b)))^(1/3)), then

∫(1/((a+b (x^3))(Sqrt[d+e x+f (x^2)])))dx  ⟶  (r/(3 a))∫(1/((r-s x)(Sqrt[d+e x+f (x^2)])))dx+(r/(3 a))∫((2 r+s x)/(((r^2)+r s x+(s^2) (x^2))(Sqrt[d+e x+f (x^2)])))dx

Program code:

Int[1/((a_+b_.*x_^3)*Sqrt[d_.+e_.*x_+f_.*x_^2]),x_Symbol] :=
  With[{r=Numerator[Rt[-a/b,3]], s=Denominator[Rt[-a/b,3]]},
  r/(3*a)*Int[1/((r-s*x)*Sqrt[d+e*x+f*x^2]),x] +
  r/(3*a)*Int[(2*r+s*x)/((r^2+r*s*x+s^2*x^2)*Sqrt[d+e*x+f*x^2]),x]] /;
FreeQ[{a,b,d,e,f},x] && NegQ[a/b]

Int[1/((a_+b_.*x_^3)*Sqrt[d_.+f_.*x_^2]),x_Symbol] :=
  With[{r=Numerator[Rt[-a/b,3]], s=Denominator[Rt[-a/b,3]]},
  r/(3*a)*Int[1/((r-s*x)*Sqrt[d+f*x^2]),x] +
  r/(3*a)*Int[(2*r+s*x)/((r^2+r*s*x+s^2*x^2)*Sqrt[d+f*x^2]),x]] /;
FreeQ[{a,b,d,f},x] && NegQ[a/b]

4:  ∫((A+B (x^4))/((d+e (x^2)+f (x^4))(Sqrt[a+b (x^2)+c (x^4)])))dx  when a B+A c==0 ∧ c d-a f==0

Derivation: Integration by substitution

Basis: If  a B+A c==0 ∧ c d-a f==0, then ((A+B (x^4))/((d+e (x^2)+f (x^4))(Sqrt[a+b (x^2)+c (x^4)])))==A Subst[(1/(d-(b d-a e) (x^2))),x,(x/(Sqrt[a+b (x^2)+c (x^4)]))] (∂_x)(x/(Sqrt[a+b (x^2)+c (x^4)]))

Rule 1.3.3.4: If  a B+A c==0 ∧ c d-a f==0, then

∫((A+B (x^4))/((d+e (x^2)+f (x^4))(Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  A Subst[∫(1/(d-(b d-a e) (x^2)))dx,x,(x/(Sqrt[a+b (x^2)+c (x^4)]))]

Program code:

Int[u_*(A_+B_.*x_^4)/Sqrt[v_],x_Symbol] :=
  With[{a=Coeff[v,x,0],b=Coeff[v,x,2],c=Coeff[v,x,4],d=Coeff[1/u,x,0],e=Coeff[1/u,x,2],f=Coeff[1/u,x,4]},
  A*Subst[Int[1/(d-(b*d-a*e)*x^2),x],x,x/Sqrt[v]] /;
 EqQ[a*B+A*c,0] && EqQ[c*d-a*f,0]] /;
FreeQ[{A,B},x] && PolyQ[v,x^2,2] && PolyQ[1/u,x^2,2]

5:  ∫(1/((a+b x) (Sqrt[c+d (x^2)]) (Sqrt[e+f (x^2)])))dx

Derivation: Algebraic expansion

Basis: (1/(a+b x))==(a/((a^2)-(b^2) (x^2)))-((b x)/((a^2)-(b^2) (x^2)))

Rule 1.3.3.5:

∫(1/((a+b x) (Sqrt[c+d (x^2)]) (Sqrt[e+f (x^2)])))dx  ⟶  a ∫(1/(((a^2)-(b^2) (x^2)) (Sqrt[c+d (x^2)]) (Sqrt[e+f (x^2)])))dx-b ∫(x/(((a^2)-(b^2) (x^2)) (Sqrt[c+d (x^2)]) (Sqrt[e+f (x^2)])))dx

Program code:

Int[1/((a_+b_.*x_)*Sqrt[c_+d_.*x_^2]*Sqrt[e_+f_.*x_^2]),x_Symbol] :=
  a*Int[1/((a^2-b^2*x^2)*Sqrt[c+d*x^2]*Sqrt[e+f*x^2]),x] - b*Int[x/((a^2-b^2*x^2)*Sqrt[c+d*x^2]*Sqrt[e+f*x^2]),x] /;
FreeQ[{a,b,c,d,e,f},x]

6.  ∫u(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx  when  (d^2)-a (f^2)==0

1:  ∫(g+h x) (Sqrt[d+e x+f (Sqrt[a+b x+c (x^2)])])dx  when  (((e g-d h))^2)-(f^2) (c (g^2)-b g h+a (h^2))==0 ∧ 2 (e^2) g-2 d e h-(f^2) (2 c g-b h)==0

Author: Martin Welz via email on 21 July 2014

Derivation: Integration by substitution

Rule 1.3.3.6.1: If (((e g-d h))^2)-(f^2) (c (g^2)-b g h+a (h^2))==0 ∧ 2 (e^2) g-2 d e h-(f^2) (2 c g-b h)==0, then

∫(g+h x) (Sqrt[d+e x+f (Sqrt[a+b x+c (x^2)])])dx  ⟶  
((2 (f (5 b c (g^2)-2 (b^2) g h-3 a c g h+2 a b (h^2))+c f (10 c (g^2)-b g h+a (h^2)) x+9 (c^2) f g h (x^2)+3 (c^2) f (h^2) (x^3)-(e g-d h) (5 c g-2 b h+c h x) (Sqrt[a+b x+c (x^2)])))/(15 (c^2) f (g+h x)))(Sqrt[d+e x+f (Sqrt[a+b x+c (x^2)])])

Program code:

Int[(g_.+h_.*x_)*Sqrt[d_.+e_.*x_+f_.*Sqrt[a_.+b_.*x_+c_.*x_^2]],x_Symbol] :=
  2*(f*(5*b*c*g^2-2*b^2*g*h-3*a*c*g*h+2*a*b*h^2)+c*f*(10*c*g^2-b*g*h+a*h^2)*x+9*c^2*f*g*h*x^2+3*c^2*f*h^2*x^3-
    (e*g-d*h)*(5*c*g-2*b*h+c*h*x)*Sqrt[a+b*x+c*x^2])/
  (15*c^2*f*(g+h*x))*Sqrt[d+e*x+f*Sqrt[a+b*x+c*x^2]] /;
FreeQ[{a,b,c,d,e,f,g,h},x] && EqQ[(e*g-d*h)^2-f^2*(c*g^2-b*g*h+a*h^2),0] && EqQ[2*e^2*g-2*d*e*h-f^2*(2*c*g-b*h),0]

2:  ∫(((g+h x))^m)(((u+f (j+k(Sqrt[v]))))^n)dx  when  u==d+e x ∧ v==a+b x+c (x^2) ∧ (((e g-h (d+f j)))^2)-(f^2)(k^2)(c (g^2)-b g h+a (h^2))==0

Derivation: Algebraic normalization

Rule 1.3.3.6.2: If  u==d+e x ∧ v==a+b x+c (x^2) ∧ (((e g-h (d+f j)))^2)-(f^2)(k^2)(c (g^2)-b g h+a (h^2))==0, then

∫(((g+h x))^m)(((u+f (j+k(Sqrt[v]))))^n)dx  ⟶  ∫(((g+h x))^m)(((d+f j+e x+f k(Sqrt[a+b x+c (x^2)])))^n)dx

Program code:

Int[(g_.+h_.*x_)^m_.*(u_+f_.*(j_.+k_.*Sqrt[v_]))^n_.,x_Symbol] :=
  Int[(g+h*x)^m*(ExpandToSum[u+f*j,x]+f*k*Sqrt[ExpandToSum[v,x]])^n,x] /;
FreeQ[{f,g,h,j,k,m,n},x] && LinearQ[u,x] && QuadraticQ[v,x] && 
  Not[LinearMatchQ[u,x] && QuadraticMatchQ[v,x] && (EqQ[j,0] || EqQ[f,1])] && 
  EqQ[(Coefficient[u,x,1]*g-h*(Coefficient[u,x,0]+f*j))^2-f^2*k^2*(Coefficient[v,x,2]*g^2-Coefficient[v,x,1]*g*h+Coefficient[v,x,0]*h^2),0]

7.  ∫u(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx  when  (e^2)-c (f^2)==0

x:  ∫(1/(d+e x+f (Sqrt[a+b x+c (x^2)])))dx  when  (e^2)-c (f^2)==0

Derivation: Algebraic expansion

Basis: If  (e^2)-c (f^2)==0, then (1/(d+e x+f (Sqrt[a+b x+c (x^2)])))==((d+e x-f (Sqrt[a+b x+c (x^2)]))/((d^2)-a (f^2)+(2 d e-b (f^2)) x))==((d+e x)/((d^2)-a (f^2)+(2 d e-b (f^2)) x))-((f (Sqrt[a+b x+c (x^2)]))/((d^2)-a (f^2)+(2 d e-b (f^2)) x))

Note: Unfortunately this does not give as simple an antiderivative as the Euler substitution.

Rule 1.3.3.7.x: If  (e^2)-c (f^2)==0, then

∫(1/(d+e x+f (Sqrt[a+b x+c (x^2)])))dx  ⟶  ∫((d+e x)/((d^2)-a (f^2)+(2 d e-b (f^2)) x))dx-f∫((Sqrt[a+b x+c (x^2)])/((d^2)-a (f^2)+(2 d e-b (f^2)) x))dx

Program code:

(* Int[1/(d_.+e_.*x_+f_.*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  Int[(d+e*x)/(d^2-a*f^2+(2*d*e-b*f^2)*x),x] - 
  f*Int[Sqrt[a+b*x+c*x^2]/(d^2-a*f^2+(2*d*e-b*f^2)*x),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e^2-c*f^2,0] *)

(* Int[1/(d_.+e_.*x_+f_.*Sqrt[a_.+c_.*x_^2]),x_Symbol] :=
  Int[(d+e*x)/(d^2-a*f^2+2*d*e*x),x] - 
  f*Int[Sqrt[a+c*x^2]/(d^2-a*f^2+2*d*e*x),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[e^2-c*f^2,0] *)

1.  ∫(((g+h(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)))^p)dx  when  (e^2)-c (f^2)==0

1:  ∫(((g+h(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)))^p)dx  when  (e^2)-c (f^2)==0 ∧ p∈ℤ

Derivation: Integration by substitution

Basis: If  (e^2)-c (f^2)==0, then 1==2 Subst[((((d^2) e-(b d-a e) (f^2)-(2 d e-b (f^2)) x+e (x^2)))/(((-2 d e+b (f^2)+2 e x))^2)),x,d+e x+f(Sqrt[a+b x+c (x^2)])](∂_x)(d+e x+f(Sqrt[a+b x+c (x^2)]))

Note: This is a special case of Euler substitution #2

Rule 1.3.3.7.1.1: If  (e^2)-c (f^2)==0 ∧ p∈ℤ, then

∫(((g+h(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)))^p)dx  ⟶  2 Subst[∫(((((g+h (x^n)))^p)((d^2) e-(b d-a e) (f^2)-(2 d e-b (f^2)) x+e (x^2)))/(((-2 d e+b (f^2)+2 e x))^2))dx,x,d+e x+f(Sqrt[a+b x+c (x^2)])]

Program code:

Int[(g_.+h_.*(d_.+e_.*x_+f_.*Sqrt[a_.+b_.*x_+c_.*x_^2])^n_)^p_.,x_Symbol] :=
  2*Subst[Int[(g+h*x^n)^p*(d^2*e-(b*d-a*e)*f^2-(2*d*e-b*f^2)*x+e*x^2)/(-2*d*e+b*f^2+2*e*x)^2,x],x,d+e*x+f*Sqrt[a+b*x+c*x^2]] /;
FreeQ[{a,b,c,d,e,f,g,h,n},x] && EqQ[e^2-c*f^2,0] && IntegerQ[p]

Int[(g_.+h_.*(d_.+e_.*x_+f_.*Sqrt[a_+c_.*x_^2])^n_)^p_.,x_Symbol] :=
  1/(2*e)*Subst[Int[(g+h*x^n)^p*(d^2+a*f^2-2*d*x+x^2)/(d-x)^2,x],x,d+e*x+f*Sqrt[a+c*x^2]] /;
FreeQ[{a,c,d,e,f,g,h,n},x] && EqQ[e^2-c*f^2,0] && IntegerQ[p]

2:  ∫(((g+h(((u+f (Sqrt[v])))^n)))^p)dx  when  u==d+e x ∧ v==a+b x+c (x^2) ∧ (e^2)-c (f^2)==0 ∧ p∈ℤ

Derivation: Algebraic normalization

Rule 1.3.3.7.1.2: If  u==d+e x ∧ v==a+b x+c (x^2) ∧ (e^2)-c (f^2)==0 ∧ p∈ℤ, then

∫(((g+h(((u+f (Sqrt[v])))^n)))^p)dx  ⟶  ∫(((g+h(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)))^p)dx

Program code:

Int[(g_.+h_.*(u_+f_.Sqrt[v_])^n_)^p_.,x_Symbol] :=
  Int[(g+h*(ExpandToSum[u,x]+f*Sqrt[ExpandToSum[v,x]])^n)^p,x] /;
FreeQ[{f,g,h,n},x] && LinearQ[u,x] && QuadraticQ[v,x] && Not[LinearMatchQ[u,x] && QuadraticMatchQ[v,x]] && 
  EqQ[Coefficient[u,x,1]^2-Coefficient[v,x,2]*f^2,0] && IntegerQ[p]

2:  ∫(((g+h x))^m)(((e x+f(Sqrt[a+c (x^2)])))^n)dx  when  (e^2)-c (f^2)==0 ∧ m∈ℤ

Derivation: Integration by substitution

Basis: If  (e^2)-c (f^2)==0 ∧ m∈ℤ, then (((g+h x))^m)==(1/((2^(m+1))(e^(m+1)))) Subst[(((a (f^2)+(x^2))(((-a (f^2) h+2 e g x+h (x^2)))^m))/(x^(m+2))),x,e x+f(Sqrt[a+c (x^2)])](∂_x)(e x+f(Sqrt[a+c (x^2)]))

Note: This is a special case of Euler substitution #2

Rule 1.3.3.7.2: If  (e^2)-c (f^2)==0 ∧ m∈ℤ, then

∫(((g+h x))^m)(((e x+f(Sqrt[a+c (x^2)])))^n)dx  ⟶  (1/((2^(m+1))(e^(m+1)))) Subst[∫(x^(n-m-2))(a (f^2)+(x^2))(((-a (f^2) h+2 e g x+h (x^2)))^m)dx,x,e x+f(Sqrt[a+c (x^2)])]

Program code:

Int[(g_.+h_.*x_)^m_.*(e_.*x_+f_.*Sqrt[a_.+c_.*x_^2])^n_.,x_Symbol] :=
  1/(2^(m+1)*e^(m+1))*Subst[Int[x^(n-m-2)*(a*f^2+x^2)*(-a*f^2*h+2*e*g*x+h*x^2)^m,x],x,e*x+f*Sqrt[a+c*x^2]] /;
FreeQ[{a,c,e,f,g,h,n},x] && EqQ[e^2-c*f^2,0] && IntegerQ[m]

3:  ∫(x^p)(((g+i (x^2)))^m)(((e x+f(Sqrt[a+c (x^2)])))^n)dx  when  (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ (p|2m)∈ℤ ∧ (m∈ℤ ∨ (i/c)>0)

Derivation: Integration by substitution

Basis: If  (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ (p|2m)∈ℤ ∧ (m∈ℤ ∨ (i/c)>0), then 
	(x^p)(((g+i (x^2)))^m)==((((i/c)))^m)(x^p)(((a+c (x^2)))^m)==(1/((2^(2 m+p+1)) (e^(p+1)) (f^(2 m))))((((i/c)))^m)Subst[(((((-a (f^2)+(x^2)))^p) (((a (f^2)+(x^2)))^(2 m+1)))/(x^(2 m+p+2))),x,e x+f(Sqrt[a+c (x^2)])](∂_x)(e x+f(Sqrt[a+c (x^2)]))

Note: This is a special case of Euler substitution #2

Rule 1.3.3.7.3: If  (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ (p|2m)∈ℤ ∧ (m∈ℤ ∨ (i/c)>0), then

∫(x^p)(((g+i (x^2)))^m)(((e x+f(Sqrt[a+c (x^2)])))^n)dx  ⟶  (1/((2^(2 m+p+1)) (e^(p+1)) (f^(2 m)))) ((((i/c)))^m)Subst[∫(x^(n-2 m-p-2))(((-a (f^2)+(x^2)))^p) (((a (f^2)+(x^2)))^(2 m+1))dx,x,e x+f(Sqrt[a+c (x^2)])]

Program code:

Int[x_^p_.*(g_+i_.*x_^2)^m_.*(e_.*x_+f_.*Sqrt[a_+c_.*x_^2])^n_.,x_Symbol] :=
  1/(2^(2*m+p+1)*e^(p+1)*f^(2*m))*(i/c)^m*Subst[Int[x^(n-2*m-p-2)*(-a*f^2+x^2)^p*(a*f^2+x^2)^(2*m+1),x],x,e*x+f*Sqrt[a+c*x^2]] /;
FreeQ[{a,c,e,f,g,i,n},x] && EqQ[e^2-c*f^2,0] && EqQ[c*g-a*i,0] && IntegersQ[p,2*m] && (IntegerQ[m] || GtQ[i/c,0])

4.  ∫(((g+h x+i (x^2)))^m)(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx  when  (e^2)-c (f^2)==0

1:  ∫(((g+h x+i (x^2)))^m)(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx  when  (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ c h-b i==0 ∧ 2m∈ℤ ∧ (m∈ℤ ∨ (i/c)>0)

Derivation: Integration by substitution

Basis: If  (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ c h-b i==0 ∧ 2m∈ℤ ∧ (m∈ℤ ∨ (i/c)>0), then
	(((g+h x+i (x^2)))^m)==((((i/c)))^m)(((a+b x+c (x^2)))^m)==(2/(f^(2m))) ((((i/c)))^m)Subst[(((((d^2) e-(b d-a e) (f^2)-(2 d e-b (f^2)) x+e (x^2)))^(2 m+1))/(((-2 d e+b (f^2)+2 e x))^(2 (m+1)))),x,d+e x+f(Sqrt[a+b x+c (x^2)])](∂_x)(d+e x+f(Sqrt[a+b x+c (x^2)]))

Note: This is a special case of Euler substitution #2

Rule 1.3.3.7.4.1: If  (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ c h-b i==0 ∧ 2m∈ℤ ∧ (m∈ℤ ∨ (i/c)>0), then

∫(((g+h x+i (x^2)))^m)(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx  ⟶  (2/(f^(2m)))((((i/c)))^m) Subst[∫(((x^n)((((d^2) e-(b d-a e) (f^2)-(2 d e-b (f^2)) x+e (x^2)))^(2 m+1)))/(((-2 d e+b (f^2)+2 e x))^(2 (m+1))))dx,x,d+e x+f(Sqrt[a+b x+c (x^2)])]

Program code:

Int[(g_.+h_.*x_+i_.*x_^2)^m_.*(d_.+e_.*x_+f_.*Sqrt[a_.+b_.*x_+c_.*x_^2])^n_.,x_Symbol] :=
  2/f^(2*m)*(i/c)^m*
    Subst[Int[x^n*(d^2*e-(b*d-a*e)*f^2-(2*d*e-b*f^2)*x+e*x^2)^(2*m+1)/(-2*d*e+b*f^2+2*e*x)^(2*(m+1)),x],x,d+e*x+f*Sqrt[a+b*x+c*x^2]] /;
FreeQ[{a,b,c,d,e,f,g,h,i,n},x] && EqQ[e^2-c*f^2,0] && EqQ[c*g-a*i,0] && EqQ[c*h-b*i,0] && IntegerQ[2*m] && (IntegerQ[m] || GtQ[i/c,0])

Int[(g_+i_.*x_^2)^m_.*(d_.+e_.*x_+f_.*Sqrt[a_+c_.*x_^2])^n_.,x_Symbol] :=
  1/(2^(2*m+1)*e*f^(2*m))*(i/c)^m*
    Subst[Int[x^n*(d^2+a*f^2-2*d*x+x^2)^(2*m+1)/(-d+x)^(2*(m+1)),x],x,d+e*x+f*Sqrt[a+c*x^2]] /;
FreeQ[{a,c,d,e,f,g,i,n},x] && EqQ[e^2-c*f^2,0] && EqQ[c*g-a*i,0] && IntegerQ[2*m] && (IntegerQ[m] || GtQ[i/c,0])

2.  ∫(((g+h x+i (x^2)))^m)(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx  when (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ c h-b i==0 ∧ m+(1/2)∈ℤ ∧ (i/c)≯0

1:  ∫(((g+h x+i (x^2)))^m)(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx  when  (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ c h-b i==0 ∧ m+(1/2)∈(SuperPlus[ℤ])∧ (i/c)≯0

Derivation: Piecewise constant extraction

Basis: If  c g-a i==0 ∧ c h-b i==0, then (∂_x)((Sqrt[g+h x+i (x^2)])/(Sqrt[a+b x+c (x^2)]))==0

Rule 1.3.3.7.4.2.1: If  (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ c h-b i==0 ∧ m+(1/2)∈(SuperPlus[ℤ]) ∧ (i/c)≯0, then

∫(((g+h x+i (x^2)))^m)(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx  ⟶  ((((i/c)))^(m-(1/2)))((Sqrt[g+h x+i (x^2)])/(Sqrt[a+b x+c (x^2)]))∫(((a+b x+c (x^2)))^m)(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx

Program code:

Int[(g_.+h_.*x_+i_.*x_^2)^m_.*(d_.+e_.*x_+f_.*Sqrt[a_.+b_.*x_+c_.*x_^2])^n_.,x_Symbol] :=
  (i/c)^(m-1/2)*Sqrt[g+h*x+i*x^2]/Sqrt[a+b*x+c*x^2]*Int[(a+b*x+c*x^2)^m*(d+e*x+f*Sqrt[a+b*x+c*x^2])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,n},x] && EqQ[e^2-c*f^2,0] && EqQ[c*g-a*i,0] && EqQ[c*h-b*i,0] && IGtQ[m+1/2,0] && Not[GtQ[i/c,0]]

Int[(g_+i_.*x_^2)^m_.*(d_.+e_.*x_+f_.*Sqrt[a_+c_.*x_^2])^n_.,x_Symbol] :=
  (i/c)^(m-1/2)*Sqrt[g+i*x^2]/Sqrt[a+c*x^2]*Int[(a+c*x^2)^m*(d+e*x+f*Sqrt[a+c*x^2])^n,x] /;
FreeQ[{a,c,d,e,f,g,i,n},x] && EqQ[e^2-c*f^2,0] && EqQ[c*g-a*i,0] && IGtQ[m+1/2,0] && Not[GtQ[i/c,0]]

2:  ∫(((g+h x+i (x^2)))^m)(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx  when  (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ c h-b i==0 ∧ m-(1/2)∈(SuperMinus[ℤ])∧ (i/c)≯0

Derivation: Piecewise constant extraction

Basis: If  c g-a i==0 ∧ c h-b i==0, then (∂_x)((Sqrt[a+b x+c (x^2)])/(Sqrt[g+h x+i (x^2)]))==0

Rule 1.3.3.7.4.2.2: If  (e^2)-c (f^2)==0 ∧ c g-a i==0 ∧ c h-b i==0 ∧ m-(1/2)∈(SuperMinus[ℤ])∧ (i/c)≯0, then

∫(((g+h x+i (x^2)))^m)(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx  ⟶  ((((i/c)))^(m+(1/2)))((Sqrt[a+b x+c (x^2)])/(Sqrt[g+h x+i (x^2)]))∫(((a+b x+c (x^2)))^m)(((d+e x+f(Sqrt[a+b x+c (x^2)])))^n)dx

Program code:

Int[(g_.+h_.*x_+i_.*x_^2)^m_.*(d_.+e_.*x_+f_.*Sqrt[a_.+b_.*x_+c_.*x_^2])^n_.,x_Symbol] :=
  (i/c)^(m+1/2)*Sqrt[a+b*x+c*x^2]/Sqrt[g+h*x+i*x^2]*Int[(a+b*x+c*x^2)^m*(d+e*x+f*Sqrt[a+b*x+c*x^2])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,n},x] && EqQ[e^2-c*f^2,0] && EqQ[c*g-a*i,0] && EqQ[c*h-b*i,0] && ILtQ[m-1/2,0] && Not[GtQ[i/c,0]]

Int[(g_+i_.*x_^2)^m_.*(d_.+e_.*x_+f_.*Sqrt[a_+c_.*x_^2])^n_.,x_Symbol] :=
  (i/c)^(m+1/2)*Sqrt[a+c*x^2]/Sqrt[g+i*x^2]*Int[(a+c*x^2)^m*(d+e*x+f*Sqrt[a+c*x^2])^n,x] /;
FreeQ[{a,c,d,e,f,g,i,n},x] && EqQ[e^2-c*f^2,0] && EqQ[c*g-a*i,0] && ILtQ[m-1/2,0] && Not[GtQ[i/c,0]]

3:  ∫(w^m)(((u+f (j+k(Sqrt[v]))))^n)dx  when  u==d+e x ∧ v==a+b x+c (x^2)∧ w==g+h x+i (x^2)∧ (e^2)-c (f^2)(k^2)==0

Derivation: Algebraic normalization

Rule 1.3.3.7.4.3: If  u==d+e x ∧ v==a+b x+c (x^2)∧ w==g+h x+i (x^2)∧ (e^2)-c (f^2)(k^2)==0, then

∫(w^m)(((u+f (j+k(Sqrt[v]))))^n)dx  ⟶  ∫(((g+h x+i (x^2)))^m)(((d+f j+e x+f k(Sqrt[a+b x+c (x^2)])))^n)dx

Program code:

Int[w_^m_.*(u_+f_.*(j_.+k_.*Sqrt[v_]))^n_.,x_Symbol] :=
  Int[ExpandToSum[w,x]^m*(ExpandToSum[u+f*j,x]+f*k*Sqrt[ExpandToSum[v,x]])^n,x] /;
FreeQ[{f,j,k,m,n},x] && LinearQ[u,x] && QuadraticQ[{v,w},x] && 
  Not[LinearMatchQ[u,x] && QuadraticMatchQ[{v,w},x] && (EqQ[j,0] || EqQ[f,1])] && 
  EqQ[Coefficient[u,x,1]^2-Coefficient[v,x,2]*f^2*k^2,0]

8:  ∫(1/((a+b (x^n)) (Sqrt[c (x^2)+d (((a+b (x^n)))^(2/n))])))dx

Reference: Integration of Functions (1948) by A.F. Timofeev

Derivation: Integration by substitution

Basis: (1/((a+b (x^n)) (Sqrt[c (x^2)+d (((a+b (x^n)))^(2/n))])))==(1/a) Subst[(1/(1-c (x^2))),x,(x/(Sqrt[c (x^2)+d (((a+b (x^n)))^(2/n))]))] (∂_x)(x/(Sqrt[c (x^2)+d (((a+b (x^n)))^(2/n))]))

Rule 1.3.3.8:

∫(1/((a+b (x^n)) (Sqrt[c (x^2)+d (((a+b (x^n)))^(2/n))])))dx  ⟶  (1/a) Subst[∫(1/(1-c (x^2)))dx,x,(x/(Sqrt[c (x^2)+d (((a+b (x^n)))^(2/n))]))]

Program code:

Int[1/((a_+b_.*x_^n_.)*Sqrt[c_.*x_^2+d_.*(a_+b_.*x_^n_.)^p_.]),x_Symbol] :=
  1/a*Subst[Int[1/(1-c*x^2),x],x,x/Sqrt[c*x^2+d*(a+b*x^n)^(2/n)]] /;
FreeQ[{a,b,c,d,n},x] && EqQ[p,2/n]

9:  ∫(Sqrt[a+b(Sqrt[c+d (x^2)])])dx  when  (a^2)-(b^2) c==0

Derivation: Integration by substitution

Basis: If  (a^2)-(b^2) c==0, then (Sqrt[a+b(Sqrt[c+d (x^2)])])==-2 a Subst[(((b^2) d+(x^2))/((((b^2) d-(x^2)))^2))(Sqrt[-((2 a (x^2))/((b^2) d-(x^2)))]),x,((a+b(Sqrt[c+d (x^2)]))/x)](∂_x)((a+b(Sqrt[c+d (x^2)]))/x)

Note: This is a special case of Euler substitution #1, if  (d^2)-(f^2) a==0, then 
	(Sqrt[d+f(Sqrt[a+b x+c (x^2)])])==-2 Subst[((c d (f^2)+b (f^2) x+d (x^2))/(((c (f^2)-(x^2)))^2))(Sqrt[d-((c d (f^2)+b (f^2) x+d (x^2))/(c (f^2)-(x^2)))]),x,((d+f(Sqrt[a+b x+c (x^2)]))/x)](∂_x)((d+f(Sqrt[a+b x+c (x^2)]))/x)

Rule 1.3.3.9: If  (a^2)-(b^2) c==0, then

∫(Sqrt[a+b(Sqrt[c+d (x^2)])])dx  ⟶  -2 a Subst[∫(((b^2) d+(x^2))/((((b^2) d-(x^2)))^2))(Sqrt[-((2 a (x^2))/((b^2) d-(x^2)))])dx,x,((a+b(Sqrt[c+d (x^2)]))/x)]
  ⟶  ((2 (b^2) d (x^3))/(3 (((a+b (Sqrt[c+d (x^2)])))^(3/2))))+((2 a x)/(Sqrt[a+b (Sqrt[c+d (x^2)])]))

Program code:

Int[Sqrt[a_+b_.*Sqrt[c_+d_.*x_^2]],x_Symbol] :=
  2*b^2*d*x^3/(3*(a+b*Sqrt[c+d*x^2])^(3/2)) + 2*a*x/Sqrt[a+b*Sqrt[c+d*x^2]] /;
FreeQ[{a,b,c,d},x] && EqQ[a^2-b^2*c,0]

10:  ∫((Sqrt[a (x^2)+b x (Sqrt[c+d (x^2)])])/(x (Sqrt[c+d (x^2)])))dx  when  (a^2)-(b^2) d==0 ∧ (b^2)c+a==0

Derivation: Integration by substitution

Basis: If  (a^2)-(b^2) d==0 ∧ (b^2)c+a==0, then ((Sqrt[a (x^2)+b x (Sqrt[c+d (x^2)])])/(x (Sqrt[c+d (x^2)])))==(((Sqrt[2]) b)/a)Subst[(1/(Sqrt[1+((x^2)/a)])),x,a x+b (Sqrt[c+d (x^2)])](∂_x)(a x+b (Sqrt[c+d (x^2)]))

Rule 1.3.3.10: If  (a^2)-(b^2) d==0 ∧ (b^2)c+a==0, then

∫((Sqrt[a (x^2)+b x (Sqrt[c+d (x^2)])])/(x (Sqrt[c+d (x^2)])))dx  ⟶  (((Sqrt[2]) b)/a)Subst[∫(1/(Sqrt[1+((x^2)/a)]))dx,x,a x+b (Sqrt[c+d (x^2)])]

Program code:

Int[Sqrt[a_.*x_^2+b_.*x_*Sqrt[c_+d_.*x_^2]]/(x_*Sqrt[c_+d_.*x_^2]),x_Symbol] :=
  Sqrt[2]*b/a*Subst[Int[1/Sqrt[1+x^2/a],x],x,a*x+b*Sqrt[c+d*x^2]] /;
FreeQ[{a,b,c,d},x] && EqQ[a^2-b^2*d,0] && EqQ[b^2*c+a,0]

11:  ∫((Sqrt[e x(a x+b (Sqrt[c+d (x^2)]))])/(x (Sqrt[c+d (x^2)])))dx  when  (a^2)-(b^2) d==0 ∧ (b^2)c e+a==0

Derivation: Algebraic normalization

Rule 1.3.3.11: If  (a^2)-(b^2) d==0 ∧ (b^2)c e+a==0, then

∫((Sqrt[e x(a x+b (Sqrt[c+d (x^2)]))])/(x (Sqrt[c+d (x^2)])))dx  ⟶  ∫((Sqrt[a e (x^2)+b e x (Sqrt[c+d (x^2)])])/(x (Sqrt[c+d (x^2)])))dx

Program code:

Int[Sqrt[e_.*x_*(a_.*x_+b_.*Sqrt[c_+d_.*x_^2])]/(x_*Sqrt[c_+d_.*x_^2]),x_Symbol] :=
  Int[Sqrt[a*e*x^2+b*e*x*Sqrt[c+d*x^2]]/(x*Sqrt[c+d*x^2]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[a^2-b^2*d,0] && EqQ[b^2*c*e+a,0]

12.  ∫((u(Sqrt[c (x^2)+d(Sqrt[a+b (x^4)])]))/(Sqrt[a+b (x^4)]))dx

1:  ∫((Sqrt[c (x^2)+d(Sqrt[a+b (x^4)])])/(Sqrt[a+b (x^4)]))dx  when (c^2)-b (d^2)==0

Derivation: Integration by substitution

Basis: If  (c^2)-b (d^2)==0, then ((Sqrt[c (x^2)+d(Sqrt[a+b (x^4)])])/(Sqrt[a+b (x^4)]))==d Subst[(1/(1-2 c (x^2))),x,(x/(Sqrt[c (x^2)+d(Sqrt[a+b (x^4)])]))] (∂_x)(x/(Sqrt[c (x^2)+d(Sqrt[a+b (x^4)])]))

Rule 1.3.3.12.1: If  (c^2)-b (d^2)==0, then

∫((Sqrt[c (x^2)+d(Sqrt[a+b (x^4)])])/(Sqrt[a+b (x^4)]))dx  ⟶  d Subst[∫(1/(1-2 c (x^2)))dx,x,(x/(Sqrt[c (x^2)+d(Sqrt[a+b (x^4)])]))]

Program code:

Int[Sqrt[c_.*x_^2+d_.*Sqrt[a_+b_.*x_^4]]/Sqrt[a_+b_.*x_^4],x_Symbol] :=
  d*Subst[Int[1/(1-2*c*x^2),x],x,x/Sqrt[c*x^2+d*Sqrt[a+b*x^4]]] /;
FreeQ[{a,b,c,d},x] && EqQ[c^2-b*d^2,0]

2:  ∫(((((c+d x))^m) (Sqrt[b (x^2)+(Sqrt[a+(b^2) (x^4)])]))/(Sqrt[a+(b^2) (x^4)]))dx

Author: Martin Welz on the sci.math.symbolic Usenet group

Derivation: Algebraic expansion

Basis: If  a>0, then (Sqrt[a+(z^2)])==(Sqrt[(Sqrt[a])-i z])(Sqrt[(Sqrt[a])+i z])

Basis: If  a>0, then ((Sqrt[z+(Sqrt[a+(z^2)])])/(Sqrt[a+(z^2)]))==((1-i)/(2 (Sqrt[(Sqrt[a])-i z])))+((1+i)/(2 (Sqrt[(Sqrt[a])+i z])))

Rule 1.3.3.12.2: If  a>0, then

∫(((((c+d x))^m) (Sqrt[b (x^2)+(Sqrt[a+(b^2) (x^4)])]))/(Sqrt[a+(b^2) (x^4)]))dx  ⟶  ((1-i)/2)∫((((c+d x))^m)/(Sqrt[(Sqrt[a])-i b (x^2)]))dx+((1+i)/2)∫((((c+d x))^m)/(Sqrt[(Sqrt[a])+i b (x^2)]))dx

Program code:

Int[(c_.+d_.*x_)^m_.*Sqrt[b_.*x_^2+Sqrt[a_+e_.*x_^4]]/Sqrt[a_+e_.*x_^4],x_Symbol] :=
  (1-I)/2*Int[(c+d*x)^m/Sqrt[Sqrt[a]-I*b*x^2],x] +
  (1+I)/2*Int[(c+d*x)^m/Sqrt[Sqrt[a]+I*b*x^2],x] /;
FreeQ[{a,b,c,d,m},x] && EqQ[e,b^2] && GtQ[a,0]

13.  ∫u (((a+b (x^3)))^p)dx  when  (p^2)==(1/4)

1.  ∫(1/((c+d x) (Sqrt[a+b (x^3)])))dx

1:  ∫(1/((c+d x) (Sqrt[a+b (x^3)])))dx  when  b (c^3)-4 a (d^3)==0

Derivation: Algebraic expansion

Basis: (1/(c+d x))==(2/(3 c))+((c-2 d x)/(3 c (c+d x)))

Note: Second integrand is of the form ((e+f x)/((c+d x) (Sqrt[a+b (x^3)]))) where b (c^3)-4 a (d^3)==0 ∧ 2 d e+c f==0.

Rule 1.3.3.13.1.1: If  b (c^3)-4 a (d^3)==0, then

∫(1/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  (2/(3 c)) ∫(1/(Sqrt[a+b (x^3)]))dx+(1/(3 c)) ∫((c-2 d x)/((c+d x) (Sqrt[a+b (x^3)])))dx

Program code:

Int[1/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  2/(3*c)*Int[1/Sqrt[a+b*x^3],x] + 1/(3*c)*Int[(c-2*d*x)/((c+d*x)*Sqrt[a+b*x^3]),x] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c^3-4*a*d^3,0]

2:  ∫(1/((c+d x) (Sqrt[a+b (x^3)])))dx  when  (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0

Derivation: Algebraic expansion

Basis: (1/(c+d x))==(1/(c (3-z)))+((c (2-z)-d x)/(c (3-z) (c+d x)))

Basis: (1/(c+d x))==-((6 a (d^3))/(c (b (c^3)-28 a (d^3))))+((c (b (c^3)-22 a (d^3))+6 a (d^4) x)/(c (b (c^3)-28 a (d^3)) (c+d x)))

Note: Second integrand is of the form ((e+f x)/((c+d x) (Sqrt[a+b (x^3)]))) where (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0 ∧ 6 a (d^4) e-c f (b (c^3)-22 a (d^3))==0.

Rule 1.3.3.13.1.2: If  (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0, then

∫(1/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  -((6 a (d^3))/(c (b (c^3)-28 a (d^3)))) ∫(1/(Sqrt[a+b (x^3)]))dx+(1/(c (b (c^3)-28 a (d^3)))) ∫((c (b (c^3)-22 a (d^3))+6 a (d^4) x)/((c+d x) (Sqrt[a+b (x^3)])))dx

Program code:

Int[1/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  -6*a*d^3/(c*(b*c^3-28*a*d^3))*Int[1/Sqrt[a+b*x^3],x] + 
  1/(c*(b*c^3-28*a*d^3))*Int[Simp[c*(b*c^3-22*a*d^3)+6*a*d^4*x,x]/((c+d*x)*Sqrt[a+b*x^3]),x] /;
FreeQ[{a,b,c,d},x] && EqQ[b^2*c^6-20*a*b*c^3*d^3-8*a^2*d^6,0]

3:  ∫(1/((c+d x) (Sqrt[a+b (x^3)])))dx  when  (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)≠0

Derivation: Algebraic expansion

Basis: (1/(c+d x))==-(q/((1+(Sqrt[3])) d-c q))+((d (1+(Sqrt[3])+q x))/(((1+(Sqrt[3])) d-c q) (c+d x)))

Note: Second integrand is of the form ((e+f x)/((c+d x) (Sqrt[a+b (x^3)]))) where (b^2) (e^6)-20 a b (e^3) (f^3)-8 (a^2) (f^6)==0.

Rule 1.3.3.13.1.3: If  (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)≠0, let q->((((b/a)))^(1/3)), then

∫(1/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  -(q/((1+(Sqrt[3])) d-c q))∫(1/(Sqrt[a+b (x^3)]))dx+(d/((1+(Sqrt[3])) d-c q))∫((1+(Sqrt[3])+q x)/((c+d x) (Sqrt[a+b (x^3)])))dx

Program code:

Int[1/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  With[{q=Rt[b/a,3]},
  -q/((1+Sqrt[3])*d-c*q)*Int[1/Sqrt[a+b*x^3],x] + 
  d/((1+Sqrt[3])*d-c*q)*Int[(1+Sqrt[3]+q*x)/((c+d*x)*Sqrt[a+b*x^3]),x]] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2*c^6-20*a*b*c^3*d^3-8*a^2*d^6,0]

2.  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0

1.  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ (b (c^3)-4 a (d^3)==0 ∨ b (c^3)+8 a (d^3)==0)

1.  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ (b (c^3)-4 a (d^3)==0 ∨ b (c^3)+8 a (d^3)==0) ∧ 2 d e+c f==0

1:  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ b (c^3)-4 a (d^3)==0 ∧ 2 d e+c f==0

Derivation: Integration by substitution

Basis: If  b (c^3)-4 a (d^3)==0 ∧ 2 d e+c f==0, then ((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))==((2 e)/d) Subst[(1/(1+3 a (x^2))),x,(( 1+((2 d x)/c))/(Sqrt[a+b (x^3)]))] (∂_x)(( 1+((2 d x)/c))/(Sqrt[a+b (x^3)]))

Rule 1.3.3.13.2.1.1.1: If  d e-c f≠0 ∧ b (c^3)-4 a (d^3)==0 ∧ 2 d e+c f==0, then

∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  ((2 e)/d) Subst[∫(1/(1+3 a (x^2)))dx,x,(( 1+((2 d x)/c))/(Sqrt[a+b (x^3)]))]

Program code:

Int[(e_+f_.*x_)/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  2*e/d*Subst[Int[1/(1+3*a*x^2),x],x,(1+2*d*x/c)/Sqrt[a+b*x^3]] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[d*e-c*f,0] && EqQ[b*c^3-4*a*d^3,0] && EqQ[2*d*e+c*f,0]

2:  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ b (c^3)+8 a (d^3)==0 ∧ 2 d e+c f==0

Derivation: Integration by substitution

Basis: If  b (c^3)+8 a (d^3)==0 ∧ 2 d e+c f==0, then ((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))==-((2 e)/d) Subst[(1/(9-a (x^2))),x,((((1+((f x)/e)))^2)/(Sqrt[a+b (x^3)]))] (∂_x)((((1+((f x)/e)))^2)/(Sqrt[a+b (x^3)]))

Rule 1.3.3.13.2.1.1.2: If  d e-c f≠0 ∧ b (c^3)+8 a (d^3)==0 ∧ 2 d e+c f==0, then

∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  -((2 e)/d) Subst[∫(1/(9-a (x^2)))dx,x,((((1+((f x)/e)))^2)/(Sqrt[a+b (x^3)]))]

Program code:

Int[(e_+f_.*x_)/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  -2*e/d*Subst[Int[1/(9-a*x^2),x],x,(1+f*x/e)^2/Sqrt[a+b*x^3]] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[d*e-c*f,0] && EqQ[b*c^3+8*a*d^3,0] && EqQ[2*d*e+c*f,0]

2:  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ (b (c^3)-4 a (d^3)==0 ∨ b (c^3)+8 a (d^3)==0) ∧ 2 d e+c f≠0

Derivation: Algebraic expansion

Basis: ((e+f x)/(c+d x))==((2 d e+c f)/(3 c d))+(((d e-c f) (c-2 d x))/(3 c d (c+d x)))

Note: Second integrand is of the form ((e+f x)/((c+d x) (Sqrt[a+b (x^3)]))) where (b (c^3)-4 a (d^3)==0 ∨ b (c^3)+8 a (d^3)==0) ∧ 2 d e+c f==0.

Rule 1.3.3.13.2.1.2: If  d e-c f≠0 ∧ (b (c^3)-4 a (d^3)==0 ∨ b (c^3)+8 a (d^3)==0) ∧ 2 d e+c f≠0, then

∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  ((2 d e+c f)/(3 c d)) ∫(1/(Sqrt[a+b (x^3)]))dx+((d e-c f)/(3 c d)) ∫((c-2 d x)/((c+d x) (Sqrt[a+b (x^3)])))dx

Program code:

Int[(e_.+f_.*x_)/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  (2*d*e+c*f)/(3*c*d)*Int[1/Sqrt[a+b*x^3],x] + 
  (d*e-c*f)/(3*c*d)*Int[(c-2*d*x)/((c+d*x)*Sqrt[a+b*x^3]),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[d*e-c*f,0] && (EqQ[b*c^3-4*a*d^3,0] || EqQ[b*c^3+8*a*d^3,0]) && NeQ[2*d*e+c*f,0]

2.  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0

1:  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0 ∧ 6 a (d^4) e-c f (b (c^3)-22 a (d^3))==0

Derivation: Integration by substitution

Basis: If  (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0 ∧ 6 a (d^4) e-c f (b (c^3)-22 a (d^3))==0, let k->((d e+2 c f)/(c f)), then ((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))==(((1+k) e)/d) Subst[(1/(1+(3+2 k) a (x^2))),x,((1+(((1+k) d x)/c))/(Sqrt[a+b (x^3)]))] (∂_x)((1+(((1+k) d x)/c))/(Sqrt[a+b (x^3)]))

Note: If  (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0 ∧ 6 a (d^4) e-c f (b (c^3)-22 a (d^3))==0, then (d^2) (e^2)+4 c d e f+(c^2) (f^2)==0, so ((d e+2 c f)/(c f)) must equal (Sqrt[3]) or -(Sqrt[3]).

Rule 1.3.3.13.2.2.1: If  d e-c f≠0 ∧ (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0 ∧ 6 a (d^4) e-c f (b (c^3)-22 a (d^3))==0, let k->((d e+2 c f)/(c f)), then

∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  (((1+k) e)/d) Subst[∫(1/(1+(3+2 k) a (x^2)))dx,x,((1+(((1+k) d x)/c))/(Sqrt[a+b (x^3)]))]

Program code:

Int[(e_+f_.*x_)/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  With[{k=Simplify[(d*e+2*c*f)/(c*f)]},
  (1+k)*e/d*Subst[Int[1/(1+(3+2*k)*a*x^2),x],x,(1+(1+k)*d*x/c)/Sqrt[a+b*x^3]]] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[d*e-c*f,0] && EqQ[b^2*c^6-20*a*b*c^3*d^3-8*a^2*d^6,0] && EqQ[6*a*d^4*e-c*f*(b*c^3-22*a*d^3),0]

2:  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0 ∧ 6 a (d^4) e-c f (b (c^3)-22 a (d^3))≠0

Derivation: Algebraic expansion

Basis: ((e+f x)/(c+d x))==((d e+(2-z) c f)/(c d (3-z)))+(((d e-c f) ((2-z) c-d x))/(c d (3-z) (c+d x)))

Basis: ((e+f x)/(c+d x))==-((6 a (d^4) e-c (b (c^3)-22 a (d^3)) f)/(c d (b (c^3)-28 a (d^3))))+(((d e-c f) (c (b (c^3)-22 a (d^3))+6 a (d^4) x))/(c d (b (c^3)-28 a (d^3)) (c+d x)))

Note: Second integrand is of the form ((e+f x)/((c+d x) (Sqrt[a+b (x^3)]))) where (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0 ∧ 6 a (d^4) e-c f (b (c^3)-22 a (d^3))==0.

Rule 1.3.3.13.2.2.2: If  d e-c f≠0 ∧ (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)==0 ∧ 6 a (d^4) e-c f (b (c^3)-22 a (d^3))≠0, then

∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  -((6 a (d^4) e-c f (b (c^3)-22 a (d^3)))/(c d (b (c^3)-28 a (d^3)))) ∫(1/(Sqrt[a+b (x^3)]))dx+((d e-c f)/(c d (b (c^3)-28 a (d^3)))) ∫((c (b (c^3)-22 a (d^3))+6 a (d^4) x)/((c+d x) (Sqrt[a+b (x^3)])))dx

Program code:

Int[(e_.+f_.*x_)/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  -(6*a*d^4*e-c*f*(b*c^3-22*a*d^3))/(c*d*(b*c^3-28*a*d^3))*Int[1/Sqrt[a+b*x^3],x] + 
  (d*e-c*f)/(c*d*(b*c^3-28*a*d^3))*Int[(c*(b*c^3-22*a*d^3)+6*a*d^4*x)/((c+d*x)*Sqrt[a+b*x^3]),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[d*e-c*f,0] && EqQ[b^2*c^6-20*a*b*c^3*d^3-8*a^2*d^6,0] && NeQ[6*a*d^4*e-c*f*(b*c^3-22*a*d^3),0]

3.  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ (b^2) (e^6)-20 a b (e^3) (f^3)-8 (a^2) (f^6)==0

1:  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ b (e^3)-2 (5+3 (Sqrt[3])) a (f^3)==0 ∧ b (c^3)-2 (5-3 (Sqrt[3])) a (d^3)≠0

Reference: G&R 3.139

Derivation: Piecewise constant extraction and integration by substitution (the Möbius transformation)

Basis: Let q->((((b/a)))^(1/3)), then (∂_x)(((((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))]))/(Sqrt[a+b (x^3)]))==0

Basis: (1/((c+d x) (1+(Sqrt[3])+q x) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))])))==4 (3^(1/4)) (Sqrt[2-(Sqrt[3])])Subst[(1/(((1-(Sqrt[3])) d-c q+((1+(Sqrt[3])) d-c q) x) (Sqrt[(1-(x^2)) (7-4 (Sqrt[3])+(x^2))]))),x,((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))] (∂_x)((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))

Basis: (Sqrt[(1-(x^2)) (7-4 (Sqrt[3])+(x^2))])==(Sqrt[1-(x^2)]) (Sqrt[7-4 (Sqrt[3])+(x^2)])

Rule 1.3.3.13.2.3.1: If  d e-c f≠0 ∧ b (e^3)-2 (5+3 (Sqrt[3])) a (f^3)==0 ∧ b (c^3)-2 (5-3 (Sqrt[3])) a (d^3)≠0, let q->((((b/a)))^(1/3))->(((1+(Sqrt[3])) f)/e), then

∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  ((f (((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))]))/(q (Sqrt[a+b (x^3)]))) ∫(1/((c+d x) (1+(Sqrt[3])+q x) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))])))dx
  ⟶  ((4 (3^(1/4)) (Sqrt[2-(Sqrt[3])]) f (((1+(Sqrt[3])+q x))^2) (Sqrt[((1+(q^3) (x^3))/(((1+(Sqrt[3])+q x))^4))]))/(q (Sqrt[a+b (x^3)]))) Subst[∫(1/( ((1-(Sqrt[3])) d-c q+((1+(Sqrt[3])) d-c q) x) (Sqrt[(1-(x^2)) (7-4 (Sqrt[3])+(x^2))])))dx,x,((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))]

  ⟶  ((4 (3^(1/4)) (Sqrt[2-(Sqrt[3])]) f (1+q x) (Sqrt[((1-q x+(q^2) (x^2))/(((1+(Sqrt[3])+q x))^2))]))/(q (Sqrt[a+b (x^3)]) (Sqrt[((1+q x)/(((1+(Sqrt[3])+q x))^2))]))) Subst[∫(1/(((1-(Sqrt[3])) d-c q+((1+(Sqrt[3])) d-c q) x) (Sqrt[1-(x^2)]) (Sqrt[7-4 (Sqrt[3])+(x^2)])))dx,x,((-1+(Sqrt[3])-q x)/(1+(Sqrt[3])+q x))]

Program code:

(* Int[(e_+f_.*x_)/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  With[{q=(1+Sqrt[3])*f/e},
  4*3^(1/4)*Sqrt[2-Sqrt[3]]*f*(1+Sqrt[3]+q*x)^2*Sqrt[(1+q^3*x^3)/(1+Sqrt[3]+q*x)^4]/(q*Sqrt[a+b*x^3])*
  Subst[Int[1/(((1-Sqrt[3])*d-c*q+((1+Sqrt[3])*d-c*q)*x)*
      Sqrt[7-4*Sqrt[3]-2*(3-2*Sqrt[3])*x^2-x^4]),x],x,(-1+Sqrt[3]-q*x)/(1+Sqrt[3]+q*x)]] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[d*e-c*f,0] && EqQ[b*e^3-2*(5+3*Sqrt[3])*a*f^3,0] && NeQ[b*c^3-2*(5-3*Sqrt[3])*a*d^3,0] *)

Int[(e_+f_.*x_)/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  With[{q=Simplify[(1+Sqrt[3])*f/e]},
  4*3^(1/4)*Sqrt[2-Sqrt[3]]*f*(1+q*x)*Sqrt[(1-q*x+q^2*x^2)/(1+Sqrt[3]+q*x)^2]/
    (q*Sqrt[a+b*x^3]*Sqrt[(1+q*x)/(1+Sqrt[3]+q*x)^2])*
    Subst[Int[1/(((1-Sqrt[3])*d-c*q+((1+Sqrt[3])*d-c*q)*x)*Sqrt[1-x^2]*Sqrt[7-4*Sqrt[3]+x^2]),x],x,(-1+Sqrt[3]-q*x)/(1+Sqrt[3]+q*x)]] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[d*e-c*f,0] && EqQ[b*e^3-2*(5+3*Sqrt[3])*a*f^3,0] && NeQ[b*c^3-2*(5-3*Sqrt[3])*a*d^3,0]

2:  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ b (e^3)-2 (5-3 (Sqrt[3])) a (f^3)==0 ∧ b (c^3)-2 (5+3 (Sqrt[3])) a (d^3)≠0

Reference: G&R 3.139

Derivation: Piecewise constant extraction and integration by substitution (the Möbius transformation)

Basis: Let q->(((-(b/a)))^(1/3)), then (∂_x)(((((1-(Sqrt[3])-q x))^2) (Sqrt[-((1-(q^3) (x^3))/(((1-(Sqrt[3])-q x))^4))]))/(Sqrt[a+b (x^3)]))==0

Basis: (1/((c+d x) (1-(Sqrt[3])-q x) (Sqrt[-((1-(q^3) (x^3))/(((1-(Sqrt[3])-q x))^4))])))==4 (3^(1/4)) (Sqrt[2+(Sqrt[3])])Subst[(1/(((1+(Sqrt[3])) d+c q+((1-(Sqrt[3])) d+c q) x) (Sqrt[(1-(x^2)) (7+4 (Sqrt[3])+(x^2))]))),x,((1+(Sqrt[3])-q x)/(-1+(Sqrt[3])+q x))] (∂_x)((1+(Sqrt[3])-q x)/(-1+(Sqrt[3])+q x))

Basis: (Sqrt[(1-(x^2)) (7+4 (Sqrt[3])+(x^2))])==(Sqrt[1-(x^2)]) (Sqrt[7+4 (Sqrt[3])+(x^2)])

Rule 1.3.3.13.2.3.2: If  d e-c f≠0 ∧ b (e^3)-2 (5-3 (Sqrt[3])) a (f^3)==0 ∧ b (c^3)-2 (5+3 (Sqrt[3])) a (d^3)≠0, let q->(((-1+(Sqrt[3])) f)/e), then

∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  -((f (((1-(Sqrt[3])-q x))^2) (Sqrt[-((1-(q^3) (x^3))/(((1-(Sqrt[3])-q x))^4))]))/(q (Sqrt[a+b (x^3)]))) ∫(1/((c+d x) (1-(Sqrt[3])-q x) (Sqrt[-((1-(q^3) (x^3))/(((1-(Sqrt[3])-q x))^4))])))dx
  ⟶  -((4 (3^(1/4)) (Sqrt[2+(Sqrt[3])]) f (((1-(Sqrt[3])-q x))^2) (Sqrt[-((1-(q^3) (x^3))/(((1-(Sqrt[3])-q x))^4))]))/(q (Sqrt[a+b (x^3)]))) Subst[∫(1/(((1+(Sqrt[3])) d+c q+((1-(Sqrt[3])) d+c q) x) (Sqrt[(1-(x^2)) (7+4 (Sqrt[3])+(x^2))])))dx,x,((1+(Sqrt[3])-q x)/(-1+(Sqrt[3])+q x))]

  ⟶  ((4 (3^(1/4)) (Sqrt[2+(Sqrt[3])]) f (1-q x) (Sqrt[((1+q x+(q^2) (x^2))/(((1-(Sqrt[3])-q x))^2))]))/(q (Sqrt[a+b (x^3)]) (Sqrt[-((1-q x)/(((1-(Sqrt[3])-q x))^2))]))) Subst[∫(1/(((1+(Sqrt[3])) d+c q+((1-(Sqrt[3])) d+c q) x) (Sqrt[1-(x^2)]) (Sqrt[7+4 (Sqrt[3])+(x^2)])))dx,x,((1+(Sqrt[3])-q x)/(-1+(Sqrt[3])+q x))]

Program code:

Int[(e_+f_.*x_)/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  With[{q=Simplify[(-1+Sqrt[3])*f/e]},
  4*3^(1/4)*Sqrt[2+Sqrt[3]]*f*(1-q*x)*Sqrt[(1+q*x+q^2*x^2)/(1-Sqrt[3]-q*x)^2]/
    (q*Sqrt[a+b*x^3]*Sqrt[-(1-q*x)/(1-Sqrt[3]-q*x)^2])*
  Subst[Int[1/(((1+Sqrt[3])*d+c*q+((1-Sqrt[3])*d+c*q)*x)*Sqrt[1-x^2]*Sqrt[7+4*Sqrt[3]+x^2]),x],x,(1+Sqrt[3]-q*x)/(-1+Sqrt[3]+q*x)]] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[d*e-c*f,0] && EqQ[b*e^3-2*(5-3*Sqrt[3])*a*f^3,0] && NeQ[b*c^3-2*(5+3*Sqrt[3])*a*d^3,0]

4:  ∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  when  d e-c f≠0 ∧ (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)≠0 ∧ (b^2) (e^6)-20 a b (e^3) (f^3)-8 (a^2) (f^6)≠0

Derivation: Algebraic expansion

Basis: ((e+f x)/(c+d x))==(((1+(Sqrt[3])) f-e q)/((1+(Sqrt[3])) d-c q))+(((d e-c f) (1+(Sqrt[3])+q x))/(((1+(Sqrt[3])) d-c q) (c+d x)))

Note: Second integrand is of the form ((e+f x)/((c+d x) (Sqrt[a+b (x^3)]))) where (b^2) (e^6)-20 a b (e^3) (f^3)-8 (a^2) (f^6)==0.

Rule 1.3.3.13.2.4: If  d e-c f≠0 ∧ (b^2) (c^6)-20 a b (c^3) (d^3)-8 (a^2) (d^6)≠0 ∧ (b^2) (e^6)-20 a b (e^3) (f^3)-8 (a^2) (f^6)≠0, let q->((((b/a)))^(1/3)), then

∫((e+f x)/((c+d x) (Sqrt[a+b (x^3)])))dx  ⟶  (((1+(Sqrt[3])) f-e q)/((1+(Sqrt[3])) d-c q))∫(1/(Sqrt[a+b (x^3)]))dx+((d e-c f)/((1+(Sqrt[3])) d-c q))∫((1+(Sqrt[3])+q x)/((c+d x) (Sqrt[a+b (x^3)])))dx

Program code:

Int[(e_.+f_.*x_)/((c_+d_.*x_)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  With[{q=Rt[b/a,3]},
  ((1+Sqrt[3])*f-e*q)/((1+Sqrt[3])*d-c*q)*Int[1/Sqrt[a+b*x^3],x] + 
  (d*e-c*f)/((1+Sqrt[3])*d-c*q)*Int[(1+Sqrt[3]+q*x)/((c+d*x)*Sqrt[a+b*x^3]),x]] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[d*e-c*f,0] && NeQ[b^2*c^6-20*a*b*c^3*d^3-8*a^2*d^6,0] && NeQ[b^2*e^6-20*a*b*e^3*f^3-8*a^2*f^6,0]

3:  ∫((f+g x+h (x^2))/((c+d x+e (x^2)) (Sqrt[a+b (x^3)])))dx  when  b d f-2 a e h≠0 ∧ b (g^3)-8 a (h^3)==0 ∧ (g^2)+2 f h==0 ∧ b d f+b c g-4 a e h==0

Derivation: Integration by substitution

Basis: If  b (g^3)-8 a (h^3)==0 ∧ (g^2)+2 f h==0 ∧ b d f+b c g-4 a e h==0 , then ((f+g x+h (x^2))/((c+d x+e (x^2)) (Sqrt[a+b (x^3)])))==-2 g h Subst[(1/(2 e h-(b d f-2 a e h) (x^2))),x,((1+((2 h x)/g))/(Sqrt[a+b (x^3)]))] (∂_x)((1+((2 h x)/g))/(Sqrt[a+b (x^3)]))

Rule 1.3.3.13.3: If  b d f-2 a e h≠0 ∧ b (g^3)-8 a (h^3)==0 ∧ (g^2)+2 f h==0 ∧ b d f+b c g-4 a e h==0 , then

∫((f+g x+h (x^2))/((c+d x+e (x^2)) (Sqrt[a+b (x^3)])))dx  ⟶  -2 g h Subst[∫(1/(2 e h-(b d f-2 a e h) (x^2)))dx ,x,((1+((2 h x)/g))/(Sqrt[a+b (x^3)]))]

Program code:

Int[(f_+g_.*x_+h_.*x_^2)/((c_+d_.*x_+e_.*x_^2)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  -2*g*h*Subst[Int[1/(2*e*h-(b*d*f-2*a*e*h)*x^2),x],x,(1+2*h*x/g)/Sqrt[a+b*x^3]] /;
FreeQ[{a,b,c,d,e,f,g,h},x] && NeQ[b*d*f-2*a*e*h,0] && EqQ[b*g^3-8*a*h^3,0] && EqQ[g^2+2*f*h,0] && EqQ[b*d*f+b*c*g-4*a*e*h,0]

Int[(f_+g_.*x_+h_.*x_^2)/((c_+e_.*x_^2)*Sqrt[a_+b_.*x_^3]),x_Symbol] :=
  -g/e*Subst[Int[1/(1+a*x^2),x],x,(1+2*h*x/g)/Sqrt[a+b*x^3]] /;
FreeQ[{a,b,c,e,f,g,h},x] && EqQ[b*g^3-8*a*h^3,0] && EqQ[g^2+2*f*h,0] && EqQ[b*c*g-4*a*e*h,0]

4.  ∫((Sqrt[a+b (x^3)])/(c+d x))dx  when  d e-c f≠0

1:  ∫((Sqrt[a+b (x^3)])/(c+d x))dx  when  b (c^3)-a (d^3)==0

Derivation: Algebraic expansion

Basis: If  b (c^3)-a (d^3)==0, then ((Sqrt[a+b (x^3)])/(c+d x))==((b (x^2))/(d (Sqrt[a+b (x^3)])))+((b c (c-d x))/((d^3) (Sqrt[a+b (x^3)])))

Rule 1.3.3.13.4.2: If  b (c^3)-a (d^3)==0, then

∫((Sqrt[a+b (x^3)])/(c+d x))dx  ⟶  (b/d)∫((x^2)/(Sqrt[a+b (x^3)]))dx+((b c)/(d^3))∫((c-d x)/(Sqrt[a+b (x^3)]))dx

Program code:

Int[Sqrt[a_+b_.*x_^3]/(c_+d_.*x_),x_Symbol] :=
  b/d*Int[x^2/Sqrt[a+b*x^3],x] + 
  b*c/d^3*Int[(c-d*x)/Sqrt[a+b*x^3],x] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c^3-a*d^3,0]

2:  ∫((Sqrt[a+b (x^3)])/(c+d x))dx  when  b (c^3)-a (d^3)≠0

Derivation: Algebraic expansion

Basis: ((Sqrt[a+b (x^3)])/(c+d x))==((b (x^2))/(d (Sqrt[a+b (x^3)])))+((b c (c-d x))/((d^3) (Sqrt[a+b (x^3)])))-((b (c^3)-a (d^3))/((d^3) (c+d x) (Sqrt[a+b (x^3)])))

Rule 1.3.3.13.4.2: If  b (c^3)-a (d^3)≠0, then

∫((Sqrt[a+b (x^3)])/(c+d x))dx  ⟶  (b/d)∫((x^2)/(Sqrt[a+b (x^3)]))dx+((b c)/(d^3))∫((c-d x)/(Sqrt[a+b (x^3)]))dx-((b (c^3)-a (d^3))/(d^3))∫(1/((c+d x) (Sqrt[a+b (x^3)])))dx

Program code:

Int[Sqrt[a_+b_.*x_^3]/(c_+d_.*x_),x_Symbol] :=
  b/d*Int[x^2/Sqrt[a+b*x^3],x] + 
  b*c/d^3*Int[(c-d*x)/Sqrt[a+b*x^3],x] - 
  (b*c^3-a*d^3)/d^3*Int[1/((c+d*x)*Sqrt[a+b*x^3]),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c^3-a*d^3,0]

14.  ∫(u/((c+d x) (((a+b (x^3)))^(1/3))))dx

1.  ∫(1/((c+d x) (((a+b (x^3)))^(1/3))))dx

1:  ∫(1/((c+d x) (((a+b (x^3)))^(1/3))))dx  when  b (c^3)+a (d^3)==0

Rule 1.3.3.14.1.1: If  b (c^3)+a (d^3)==0, then

∫(1/((c+d x) (((a+b (x^3)))^(1/3))))dx  ⟶  (((Sqrt[3]) ArcTan[((1-(((2^(1/3)) (b^(1/3)) (c-d x))/(d (((a+b (x^3)))^(1/3)))))/(Sqrt[3]))])/((2^(4/3)) (b^(1/3)) c))+((Log[(((c+d x))^2) (c-d x)])/((2^(7/3)) (b^(1/3)) c))-((3 Log[(b^(1/3)) (c-d x)+(2^(2/3)) d (((a+b (x^3)))^(1/3))])/((2^(7/3)) (b^(1/3)) c))

Program code:

Int[1/((c_+d_.*x_)*(a_+b_.*x_^3)^(1/3)),x_Symbol] :=
  Sqrt[3]*ArcTan[(1-2^(1/3)*Rt[b,3]*(c-d*x)/(d*(a+b*x^3)^(1/3)))/Sqrt[3]]/(2^(4/3)*Rt[b,3]*c) + 
  Log[(c+d*x)^2*(c-d*x)]/(2^(7/3)*Rt[b,3]*c) - 
  (3*Log[Rt[b,3]*(c-d*x)+2^(2/3)*d*(a+b*x^3)^(1/3)])/(2^(7/3)*Rt[b,3]*c) /;
FreeQ[{a,b,c,d},x] && EqQ[b*c^3+a*d^3,0]

2:  ∫(1/((c+d x) (((a+b (x^3)))^(1/3))))dx  when  2 b (c^3)-a (d^3)==0

Derivation: Algebraic expansion

Basis: (1/(c+d x))==(1/(2 c))+((c-d x)/(2 c (c+d x)))

Rule 1.3.3.14.1.2: If  2 b (c^3)-a (d^3)==0, then

∫(1/((c+d x) (((a+b (x^3)))^(1/3))))dx  ⟶  (1/(2 c)) ∫(1/(((a+b (x^3)))^(1/3)))dx+(1/(2 c)) ∫((c-d x)/((c+d x) (((a+b (x^3)))^(1/3))))dx

Program code:

Int[1/((c_+d_.*x_)*(a_+b_.*x_^3)^(1/3)),x_Symbol] :=
  1/(2*c)*Int[1/(a+b*x^3)^(1/3),x] + 1/(2*c)*Int[(c-d*x)/((c+d*x)*(a+b*x^3)^(1/3)),x] /;
FreeQ[{a,b,c,d},x] && EqQ[2*b*c^3-a*d^3,0]

2.  ∫((e+f x)/((c+d x) (((a+b (x^3)))^(1/3))))dx

1:  ∫((e+f x)/((c+d x) (((a+b (x^3)))^(1/3))))dx  when  d e+c f==0 ∧ 2 b (c^3)-a (d^3)==0

Rule 1.3.3.14.2.1: If  d e+c f==0 ∧ 2 b (c^3)-a (d^3)==0, then

∫((e+f x)/((c+d x) (((a+b (x^3)))^(1/3))))dx  ⟶  (((Sqrt[3]) f ArcTan[((1+((2 (b^(1/3)) (2 c+d x))/(d (((a+b (x^3)))^(1/3)))))/(Sqrt[3]))])/((b^(1/3)) d))+((f Log[c+d x])/((b^(1/3)) d))-((3 f Log[(b^(1/3)) (2 c+d x)-d (((a+b (x^3)))^(1/3))])/(2 (b^(1/3)) d))

Program code:

Int[(e_+f_.*x_)/((c_+d_.*x_)*(a_+b_.*x_^3)^(1/3)),x_Symbol] :=
  Sqrt[3]*f*ArcTan[(1+2*Rt[b,3]*(2*c+d*x)/(d*(a+b*x^3)^(1/3)))/Sqrt[3]]/(Rt[b,3]*d) + 
  (f*Log[c+d*x])/(Rt[b,3]*d) - 
  (3*f*Log[Rt[b,3]*(2*c+d*x)-d*(a+b*x^3)^(1/3)])/(2*Rt[b,3]*d) /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[d*e+c*f,0] && EqQ[2*b*c^3-a*d^3,0]

2:  ∫((e+f x)/((c+d x) (((a+b (x^3)))^(1/3))))dx

Derivation: Algebraic expansion

Basis: ((e+f x)/(c+d x))==(f/d)+((d e-c f)/(d (c+d x)))

Rule 1.3.3.14.2.2:

∫((e+f x)/((c+d x) (((a+b (x^3)))^(1/3))))dx  ⟶  (f/d) ∫(1/(((a+b (x^3)))^(1/3)))dx+((d e-c f)/d) ∫(1/((c+d x) (((a+b (x^3)))^(1/3))))dx

Program code:

Int[(e_.+f_.*x_)/((c_.+d_.*x_)*(a_+b_.*x_^3)^(1/3)),x_Symbol] :=
  f/d*Int[1/(a+b*x^3)^(1/3),x] + (d*e-c*f)/d*Int[1/((c+d*x)*(a+b*x^3)^(1/3)),x] /;
FreeQ[{a,b,c,d,e,f},x]

?:  ∫((((a+b (x^3)))^(2/3))/(c+d x))dx

Derivation: Algebraic expansion

Basis: ((((a+b (x^3)))^(2/3))/(c+d x))==((b (x^2))/(d (((a+b (x^3)))^(1/3))))-((b c x)/((d^2) (((a+b (x^3)))^(1/3))))+((a (d^2)+b (c^2) x)/((d^2) (c+d x) (((a+b (x^3)))^(1/3))))

Rule 1.3.3.?:

∫((((a+b (x^3)))^(2/3))/(c+d x))dx  ⟶  ((((a+b (x^3)))^(2/3))/(2 d))-((b c)/(d^2)) ∫(x/(((a+b (x^3)))^(1/3)))dx+(1/(d^2)) ∫((a (d^2)+b (c^2) x)/((c+d x) (((a+b (x^3)))^(1/3))))dx

Program code:

Int[(a_+b_.*x_^3)^(2/3)/(c_+d_.*x_),x_Symbol] :=
  (a+b*x^3)^(2/3)/(2*d) - 
  b*c/d^2*Int[x/(a+b*x^3)^(1/3),x] + 
  1/d^2*Int[(a*d^2+b*c^2*x)/((c+d*x)*(a+b*x^3)^(1/3)),x] /;
FreeQ[{a,b,c,d},x]

?:  ∫(1/((c+d x) (((a+b (x^3)))^(2/3))))dx  when  2 b (c^3)-a (d^3)==0

Derivation: Algebraic expansion

Basis: (1/(c+d x))==((d x)/(2 (c^2)))+((2 (c^2)-c d x-(d^2) (x^2))/(2 (c^2) (c+d x)))

Rule 1.3.3.?: If  2 b (c^3)-a (d^3)==0, let q->(b^(1/3)), then

∫(1/((c+d x) (((a+b (x^3)))^(2/3))))dx

  ⟶  (d/(2 (c^2))) ∫(1/(((a+b (x^3)))^(2/3)))dx+(1/(2 (c^2))) ∫((2 (c^2)-c d x-(d^2) (x^2))/((c+d x) (((a+b (x^3)))^(2/3))))dx

  ⟶  -((d ArcTan[((1+((2 q x)/(((a+b (x^3)))^(1/3))))/(Sqrt[3]))])/(2 (Sqrt[3]) (q^2) (c^2)))+(((Sqrt[3]) d ArcTan[((1+((2 q (2 c+d x))/(d (((a+b (x^3)))^(1/3)))))/(Sqrt[3]))])/(2 (q^2) (c^2)))-((d Log[c+d x])/(2 (q^2) (c^2)))-((d Log[q x-(((a+b (x^3)))^(1/3))])/(4 (q^2) (c^2)))+((3 d Log[q (2 c+d x)-d (((a+b (x^3)))^(1/3))])/(4 (q^2) (c^2)))

Program code:

Int[1/((c_+d_.*x_)*(a_+b_.*x_^3)^(2/3)),x_Symbol] :=
  With[{q=Rt[b,3]},
  -d*ArcTan[(1+2*q*x/(a+b*x^3)^(1/3))/Sqrt[3]]/(2*Sqrt[3]*q^2*c^2) + 
  Sqrt[3]*d*ArcTan[(1+2*q*(2*c+d*x)/(d*(a+b*x^3)^(1/3)))/Sqrt[3]]/(2*q^2*c^2) - 
  d*Log[c+d*x]/(2*q^2*c^2) - 
  d*Log[q*x-(a+b*x^3)^(1/3)]/(4*q^2*c^2) + 
  3*d*Log[q*(2*c+d*x)-d*(a+b*x^3)^(1/3)]/(4*q^2*c^2)] /;
FreeQ[{a,b,c,d},x] && EqQ[2*b*c^3-a*d^3,0]

?:  ∫(x^m) P[x] (((c+d x))^q) (((a+b (x^3)))^p)dx  when  q∈(SuperMinus[ℤ])∧ m∈ℤ ∧ Denominator[p]==3

Attribution: Martin Welz on 8 November 2018 via email

Derivation: Algebraic expansion

Basis: c+d x==(((c^3)+(d^3) (x^3))/((c^2)-c d x+(d^2) (x^2)))

Note: The terms of the expanded integrand are of the form A (x^n)((((c^3)+(d^3) (x^3)))^q) (((a+b (x^3)))^p) where n, q, and 3 p are integers, and are thus integrable.

Rule: If  q∈(SuperMinus[ℤ])∧ m∈ℤ ∧ Denominator[p]==3, then

∫(x^m) P[x] (((c+d x))^q) (((a+b (x^3)))^p)dx  ⟶  ∫((((c^3)+(d^3) (x^3)))^q) (((a+b (x^3)))^p) ExpandIntegrand[(((x^m) P[x])/((((c^2)-c d x+(d^2) (x^2)))^q)),x]dx

Program code:

Int[x_^m_.*Px_*(c_+d_.*x_)^q_*(a_+b_.*x_^3)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(c^3+d^3*x^3)^q*(a+b*x^3)^p,x^m*Px/(c^2-c*d*x+d^2*x^2)^q,x],x] /;
FreeQ[{a,b,c,d,m,p},x] && PolyQ[Px,x] && ILtQ[q,0] && IntegerQ[m] && RationalQ[p] && EqQ[Denominator[p],3]

Int[Px_.*(c_+d_.*x_)^q_*(a_+b_.*x_^3)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(c^3+d^3*x^3)^q*(a+b*x^3)^p,Px/(c^2-c*d*x+d^2*x^2)^q,x],x] /;
FreeQ[{a,b,c,d,p},x] && PolyQ[Px,x] && ILtQ[q,0] && RationalQ[p] && EqQ[Denominator[p],3]

?:  ∫(x^m) P[x] (((c+d x+e (x^2)))^q) (((a+b (x^3)))^p)dx  when  (d^2)-c e==0 ∧ q∈(SuperMinus[ℤ])∧ m∈ℤ ∧ Denominator[p]==3

Attribution: Martin Welz on 8 November 2018 via email

Derivation: Algebraic expansion

Basis: If  (d^2)-c e==0, then c+d x+e (x^2)==(((c^3)-(d^3) (x^3))/(c (c-d x)))

Note: The terms of the expanded integrand are of the form A (x^n)((((c^3)-(d^3) (x^3)))^q) (((a+b (x^3)))^p) where n, q, and 3 p are integers, and are thus integrable.

Rule: If  (d^2)-c e==0 ∧ q∈(SuperMinus[ℤ])∧ m∈ℤ ∧ Denominator[p]==3, then

∫(x^m) P[x] (((c+d x+e (x^2)))^q) (((a+b (x^3)))^p)dx  ⟶  (1/(c^q)) ∫((((c^3)-(d^3) (x^3)))^q) (((a+b (x^3)))^p) ExpandIntegrand[(((x^m) P[x])/(((c-d x))^q)),x]dx

Program code:

Int[x_^m_.*Px_*(c_+d_.*x_+e_.*x_^2)^q_*(a_+b_.*x_^3)^p_.,x_Symbol] :=
  1/c^q*Int[ExpandIntegrand[(c^3-d^3*x^3)^q*(a+b*x^3)^p,x^m*Px/(c-d*x)^q,x],x] /;
FreeQ[{a,b,c,d,e,m,p},x] && PolyQ[Px,x] && EqQ[d^2-c*e,0] && ILtQ[q,0] && IntegerQ[m] && RationalQ[p] && EqQ[Denominator[p],3]

Int[Px_.*(c_+d_.*x_+e_.*x_^2)^q_*(a_+b_.*x_^3)^p_.,x_Symbol] :=
  1/c^q*Int[ExpandIntegrand[(c^3-d^3*x^3)^q*(a+b*x^3)^p,Px/(c-d*x)^q,x],x] /;
FreeQ[{a,b,c,d,e,p},x] && PolyQ[Px,x] && EqQ[d^2-c*e,0] && ILtQ[q,0] && RationalQ[p] && EqQ[Denominator[p],3]

15.  ∫u (((c+d (x^n)))^q) (((a+b (x^nn)))^p)dx  when  p∉ℤ ∧ q∈(SuperMinus[ℤ])∧ Log[2,(nn/n)]∈(SuperPlus[ℤ])

1:  ∫(((c+d (x^n)))^q) (((a+b (x^nn)))^p)dx  when p∉ℤ ∧ q∈(SuperMinus[ℤ])∧ Log[2,(nn/n)]∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: If  q∈ℤ, then (((c+d (x^n)))^q)==((((c/((c^2)-(d^2) (x^(2 n))))-((d (x^n))/((c^2)-(d^2) (x^(2 n))))))^(-q))

Note: Resulting integrands are of the form (x^m) (((a+b (x^nn)))^p) (((c+d (x^(2 n))))^q) which are integrable in terms of the Appell hypergeometric function .

Rule 1.3.3.15.1: If  p∉ℤ ∧ q∈(SuperMinus[ℤ])∧ Log[2,(nn/n)]∈(SuperPlus[ℤ]), then

∫(((c+d (x^n)))^q) (((a+b (x^nn)))^p)dx  ⟶  ∫(((a+b (x^nn)))^p) ExpandIntegrand[((((c/((c^2)-(d^2) (x^(2 n))))-((d (x^n))/((c^2)-(d^2) (x^(2 n))))))^(-q)),x]dx

Program code:

Int[(c_+d_.*x_^n_.)^q_*(a_+b_.*x_^nn_.)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*x^nn)^p,(c/(c^2-d^2*x^(2*n))-d*x^n/(c^2-d^2*x^(2*n)))^(-q),x],x] /;
FreeQ[{a,b,c,d,n,nn,p},x] && Not[IntegerQ[p]] && ILtQ[q,0] && IGtQ[Log[2,nn/n],0]

2:  ∫(((e x))^m) (((c+d (x^n)))^q) (((a+b (x^nn)))^p)dx  when p∉ℤ ∧ q∈(SuperMinus[ℤ])∧ Log[2,(nn/n)]∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: If  q∈ℤ, then (((c+d (x^n)))^q)==((((c/((c^2)-(d^2) (x^(2 n))))-((d (x^n))/((c^2)-(d^2) (x^(2 n))))))^(-q))

Note: Resulting integrands are of the form (x^m) (((a+b (x^nn)))^p) (((c+d (x^(2 n))))^q) which are integrable in terms of the Appell hypergeometric function .

Rule 1.3.3.15.2.1: If  p∉ℤ ∧ q∈(SuperMinus[ℤ])∧ Log[2,(nn/n)]∈(SuperPlus[ℤ]), then

∫(((e x))^m) (((c+d (x^n)))^q) (((a+b (x^nn)))^p)dx  ⟶  ((((e x))^m)/(x^m)) ∫(x^m) (((a+b (x^nn)))^p) ExpandIntegrand[((((c/((c^2)-(d^2) (x^(2 n))))-((d (x^n))/((c^2)-(d^2) (x^(2 n))))))^(-q)),x]dx

Program code:

Int[(e_.*x_)^m_.*(c_+d_.*x_^n_.)^q_*(a_+b_.*x_^nn_.)^p_,x_Symbol] :=
  (e*x)^m/x^m*Int[ExpandIntegrand[x^m*(a+b*x^nn)^p,(c/(c^2-d^2*x^(2*n))-d*x^n/(c^2-d^2*x^(2*n)))^(-q),x],x] /;
FreeQ[{a,b,c,d,e,m,n,nn,p},x] && Not[IntegerQ[p]] && ILtQ[q,0] && IGtQ[Log[2,nn/n],0]

16.  ∫(u/(c+d (x^n)+e (Sqrt[a+b (x^n)])))dx  when  b c-a d==0

1:  ∫((x^m)/(c+d (x^n)+e (Sqrt[a+b (x^n)])))dx  when  b c-a d==0 ∧ ((m+1)/n)∈ℤ

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m)F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Rule 1.3.3.16.1: If  b c-a d==0 ∧ ((m+1)/n)∈ℤ, then

∫((x^m)/(c+d (x^n)+e (Sqrt[a+b (x^n)])))dx  ⟶  (1/n) Subst[∫((x^(((m+1)/n)-1))/(c+d x+e (Sqrt[a+b x])))dx,x,(x^n)]

Program code:

Int[x_^m_./(c_+d_.*x_^n_+e_.*Sqrt[a_+b_.*x_^n_]),x_Symbol] :=
  1/n*Subst[Int[x^((m+1)/n-1)/(c+d*x+e*Sqrt[a+b*x]),x],x,x^n] /;
FreeQ[{a,b,c,d,e,m,n},x] && EqQ[b*c-a*d,0] && IntegerQ[(m+1)/n]

2:  ∫(u/(c+d (x^n)+e (Sqrt[a+b (x^n)])))dx  when  b c-a d==0

Derivation: Algebraic expansion

Basis: If  b c-a d==0, then (1/(c+d z+e (Sqrt[a+b z])))==(c/((c^2)-a (e^2)+c d z))-((a e)/(((c^2)-a (e^2)+c d z) (Sqrt[a+b z])))

Rule 1.3.3.16.2: If  b c-a d==0, then

∫(u/(c+d (x^n)+e (Sqrt[a+b (x^n)])))dx  ⟶  c ∫(u/((c^2)-a (e^2)+c d (x^n)))dx-a e ∫(u/(((c^2)-a (e^2)+c d (x^n)) (Sqrt[a+b (x^n)])))dx

Program code:

Int[u_./(c_+d_.*x_^n_+e_.*Sqrt[a_+b_.*x_^n_]),x_Symbol] :=
  c*Int[u/(c^2-a*e^2+c*d*x^n),x] - a*e*Int[u/((c^2-a*e^2+c*d*x^n)*Sqrt[a+b*x^n]),x] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[b*c-a*d,0]