Rules for integrands of the form  u (((a+b Log[c (((d+e x))^n)]))^p)

1:  ∫(((a+b Log[c (((d+e x))^n)]))^p)dx

Derivation: Integration by substitution

Rule:

∫(((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  (1/e) Subst[∫(((a+b Log[c (x^n)]))^p)dx,x,d+e x]

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  1/e*Subst[Int[(a+b*Log[c*x^n])^p,x],x,d+e*x] /;
FreeQ[{a,b,c,d,e,n,p},x]

2.  ∫(((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx

1.  ∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx

1:  ∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  e f-d g==0

Derivation: Integration by substitution

Basis: If  e f-d g==0, then (((f+g x))^q) F[d+e x]==(1/e) Subst[(((((f x)/d)))^q) F[x],x,d+e x] (∂_x)(d+e x)

Rule: If  e f-d g==0, then

∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  (1/e) Subst[∫(((((f x)/d)))^q) (((a+b Log[c (x^n)]))^p)dx,x,d+e x]

Program code:

Int[(f_+g_.x_)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  1/e*Subst[Int[(f*x/d)^q*(a+b*Log[c*x^n])^p,x],x,d+e*x] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q},x] && EqQ[e*f-d*g,0]

2.  ∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  e f-d g≠0

1.  ∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  e f-d g≠0 ∧ p>0

1.  ∫(((f+g x))^q) (a+b Log[c (((d+e x))^n)])dx  when  e f-d g≠0

1.  ∫(((a+b Log[c (((d+e x))^n)]))/(f+g x))dx  when  e f-d g≠0 ∧ p∈(SuperPlus[ℤ])

1.  ∫((a+b Log[c (d+e x)])/x)dx  when  c d>0

1:  ∫((Log[c (d+e (x^n))])/x)dx  when  c d==1

Rule: If  c d==1, then

∫((Log[c (d+e (x^n))])/x)dx  ⟶  -((PolyLog[2,-c e (x^n)])/n)

Program code:

Int[Log[c_.*(d_+e_.*x_^n_.)]/x_,x_Symbol] :=
  -PolyLog[2,-c*e*x^n]/n /;
FreeQ[{c,d,e,n},x] && EqQ[c*d,1]

2:  ∫((a+b Log[c (d+e x)])/x)dx  when  c d>0

Derivation: Algebraic expansion

Basis: If  c d>0, then Log[c (d+e x)]==Log[c d]+Log[1+((e x)/d)]

Rule: If  c d>0, then

∫((a+b Log[c (d+e x)])/x)dx  ⟶  (a+b Log[c d]) Log[x]+b∫((Log[1+((e x)/d)])/x)dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)])/x_,x_Symbol] :=
  (a+b*Log[c*d])*Log[x] + b*Int[Log[1+e*x/d]/x,x] /;
FreeQ[{a,b,c,d,e},x] && GtQ[c*d,0]

2:  ∫((a+b Log[c (d+e x)])/(f+g x))dx  when  e f-d g≠0 ∧ g+c (e f-d g)==0

Derivation: Integration by substitution

Basis: If  g+c (e f-d g)==0, then F[c (d+e x)]==(1/g) Subst[F[1+((c e x)/g)],x,f+g x] (∂_x)(f+g x)

Rule: If  e f-d g≠0 ∧ g+c (e f-d g)==0, then

∫((a+b Log[c (d+e x)])/(f+g x))dx  ⟶  (1/g) Subst[∫((a+b Log[1+((c e x)/g)])/x)dx,x,f+g x]

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)])/(f_.+g_.x_),x_Symbol] :=
  1/g*Subst[Int[(a+b*Log[1+c*e*x/g])/x,x],x,f+g*x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[e*f-d*g,0] && EqQ[g+c*(e*f-d*g),0]

3:  ∫((a+b Log[c (((d+e x))^n)])/(f+g x))dx  when  e f-d g≠0

Derivation: Integration by parts

Basis: (1/(f+g x))==(1/g) (∂_x)Log[((e (f+g x))/(e f-d g))]

Rule: If  e f-d g≠0, then

∫((a+b Log[c (((d+e x))^n)])/(f+g x))dx  ⟶  ((Log[((e (f+g x))/(e f-d g))] (a+b Log[c (((d+e x))^n)]))/g)-((b e n)/g) ∫((Log[((e (f+g x))/(e f-d g))])/(d+e x))dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])/(f_.+g_.x_),x_Symbol] :=
  Log[e*(f+g*x)/(e*f-d*g)]*(a+b*Log[c*(d+e*x)^n])/g - b*e*n/g*Int[Log[(e*(f+g*x))/(e*f-d*g)]/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && NeQ[e*f-d*g,0]

2:  ∫(((f+g x))^q) (a+b Log[c (((d+e x))^n)])dx  when  e f-d g≠0 ∧ q≠-1

Reference: G&R 2.728.1, CRC 501, A&S 4.1.50'

Derivation: Integration by parts

Basis: (((f+g x))^q)==(∂_x)((((f+g x))^(q+1))/(g (q+1)))

Rule: If  e f-d g≠0 ∧ q≠-1, then

∫(((f+g x))^q) (a+b Log[c (((d+e x))^n)])dx  ⟶  (((((f+g x))^(q+1)) (a+b Log[c (((d+e x))^n)]))/(g (q+1)))-((b e n)/(g (q+1)))∫((((f+g x))^(q+1))/(d+e x))dx

Program code:

Int[(f_.+g_.*x_)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.]),x_Symbol] :=
  (f+g*x)^(q+1)*(a+b*Log[c*(d+e*x)^n])/(g*(q+1)) - 
  b*e*n/(g*(q+1))*Int[(f+g*x)^(q+1)/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,n,q},x] && NeQ[e*f-d*g,0] && NeQ[q,-1]

2:  ∫((((a+b Log[c (((d+e x))^n)]))^p)/(f+g x))dx  when  e f-d g≠0 ∧ p-1∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (1/(f+g x))==(1/g) (∂_x)Log[((e (f+g x))/(e f-d g))]

Basis: (∂_x)(((a+b Log[c (((d+e x))^n)]))^p)==((b e n p (((a+b Log[c (((d+e x))^n)]))^(p-1)))/(d+e x))

Rule: If  e f-d g≠0 ∧ p-1∈(SuperPlus[ℤ]), then

∫((((a+b Log[c (((d+e x))^n)]))^p)/(f+g x))dx  ⟶  ((Log[((e (f+g x))/(e f-d g))] (((a+b Log[c (((d+e x))^n)]))^p))/g)-((b e n p)/g) ∫((Log[((e (f+g x))/(e f-d g))] (((a+b Log[c (((d+e x))^n)]))^(p-1)))/(d+e x))dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_/(f_.+g_.x_),x_Symbol] :=
  Log[e*(f+g*x)/(e*f-d*g)]*(a+b*Log[c*(d+e*x)^n])^p/g - 
  b*e*n*p/g*Int[Log[(e*(f+g*x))/(e*f-d*g)]*(a+b*Log[c*(d+e*x)^n])^(p-1)/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && NeQ[e*f-d*g,0] && IGtQ[p,1]

3:  ∫((((a+b Log[c (((d+e x))^n)]))^p)/(((f+g x))^2))dx  when  e f-d g≠0 ∧ p>0

Derivation: Integration by parts

Basis: (1/(((f+g x))^2))==(∂_x)((d+e x)/((e f-d g) (f+g x)))

Rule: If  e f-d g≠0 ∧ p>0, then

∫((((a+b Log[c (((d+e x))^n)]))^p)/(((f+g x))^2))dx  ⟶  (((d+e x)(((a+b Log[c (((d+e x))^n)]))^p))/((e f-d g)(f+g x)))-((b e n p)/(e f-d g))∫((((a+b Log[c (((d+e x))^n)]))^(p-1))/(f+g x))dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_/(f_.+g_.*x_)^2,x_Symbol] :=
  (d+e*x)*(a+b*Log[c*(d+e*x)^n])^p/((e*f-d*g)*(f+g*x)) - 
  b*e*n*p/(e*f-d*g)*Int[(a+b*Log[c*(d+e*x)^n])^(p-1)/(f+g*x),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && NeQ[e*f-d*g,0] && GtQ[p,0]

4:  ∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  e f-d g≠0 ∧ p>0 ∧ q≠-1

Reference: G&R 2.728.1, CRC 501, A&S 4.1.50'

Derivation: Integration by parts

Basis: (((f+g x))^q)==(∂_x)((((f+g x))^(q+1))/(g (q+1)))

Rule: If  e f-d g≠0 ∧ p>0 ∧ q≠-1, then

∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  (((((f+g x))^(q+1)) (((a+b Log[c (((d+e x))^n)]))^p))/(g (q+1)))-((b e n p)/(g (q+1)))∫(((((f+g x))^(q+1))(((a+b Log[c (((d+e x))^n)]))^(p-1)))/(d+e x))dx

Program code:

Int[(f_.+g_.*x_)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_,x_Symbol] :=
  (f+g*x)^(q+1)*(a+b*Log[c*(d+e*x)^n])^p/(g*(q+1)) - 
  b*e*n*p/(g*(q+1))*Int[(f+g*x)^(q+1)*(a+b*Log[c*(d+e*x)^n])^(p-1)/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,n,q},x] && NeQ[e*f-d*g,0] && GtQ[p,0] && NeQ[q,-1] && IntegersQ[2*p,2*q] && 
  (Not[IGtQ[q,0]] || EqQ[p,2] && NeQ[q,1])

2.  ∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  e f-d g≠0 ∧ p<0

1:  ∫((((f+g x))^q)/(a+b Log[c (((d+e x))^n)]))dx  when  e f-d g≠0 ∧ q∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Note: ExpandIntegrand expresses (((f+g x))^q) as a polynomial in d+e x so the above rule for when e f-d g==0 will apply.

Rule: If  e f-d g≠0 ∧ q∈(SuperPlus[ℤ]), then

∫((((f+g x))^q)/(a+b Log[c (((d+e x))^n)]))dx  ⟶  ∫ExpandIntegrand[((((f+g x))^q)/(a+b Log[c (((d+e x))^n)])),x]dx

Program code:

Int[(f_.+g_.*x_)^q_./(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.]),x_Symbol] :=
  Int[ExpandIntegrand[(f+g*x)^q/(a+b*Log[c*(d+e*x)^n]),x],x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && NeQ[e*f-d*g,0] && IGtQ[q,0]

2:  ∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  e f-d g≠0 ∧ p<-1 ∧ q>0

Rule: If  e f-d g≠0 ∧ p<-1 ∧ q>0, then

∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  

(((d+e x)(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^(p+1)))/(b e n (p+1)))+
((q(e f-d g))/(b e n (p+1)))∫(((f+g x))^(q-1)) (((a+b Log[c (((d+e x))^n)]))^(p+1))dx-((q+1)/(b n (p+1)))∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^(p+1))dx

Program code:

Int[(f_.+g_.*x_)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_,x_Symbol] :=
  (d+e*x)*(f+g*x)^q*(a+b*Log[c*(d+e*x)^n])^(p+1)/(b*e*n*(p+1)) + 
  q*(e*f-d*g)/(b*e*n*(p+1))*Int[(f+g*x)^(q-1)*(a+b*Log[c*(d+e*x)^n])^(p+1),x] - 
  (q+1)/(b*n*(p+1))*Int[(f+g*x)^q*(a+b*Log[c*(d+e*x)^n])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && NeQ[e*f-d*g,0] && LtQ[p,-1] && GtQ[q,0]

3:  ∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  e f-d g≠0 ∧ q∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Note: ExpandIntegrand expresses (((f+g x))^q) as a polynomial in d+e x so the above rules for when e f-d g==0 will apply.

Rule: If  e f-d g≠0 ∧ q∈(SuperPlus[ℤ]), then

∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  ∫ExpandIntegrand[(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p),x]dx

Program code:

Int[(f_.+g_.*x_)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_,x_Symbol] :=
  Int[ExpandIntegrand[(f+g*x)^q*(a+b*Log[c*(d+e*x)^n])^p,x],x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && NeQ[e*f-d*g,0] && IGtQ[q,0]

2.  ∫((a+b Log[(c/(d+e x))])/(f+g (x^2)))dx  when  (e^2) f+(d^2) g==0 ∧ (c/(2 d))>0

1:  ∫((Log[((2 d)/(d+e x))])/(f+g (x^2)))dx  when  (e^2) f+(d^2) g==0

Derivation: Integration by substitution

Basis: If  (e^2) f+(d^2) g==0, then ((F[(1/(d+e x))])/(f+g (x^2)))==-(e/g) Subst[((F[x])/(1-2 d x)),x,(1/(d+e x))] (∂_x)(1/(d+e x))

Rule: If  (e^2) f+(d^2) g==0, then

∫((Log[((2 d)/(d+e x))])/(f+g (x^2)))dx  ⟶  -(e/g) Subst[∫((Log[2 d x])/(1-2 d x))dx,x,(1/(d+e x))]

Program code:

Int[Log[c_./(d_+e_.*x_)]/(f_+g_.*x_^2),x_Symbol] :=
  -e/g*Subst[Int[Log[2*d*x]/(1-2*d*x),x],x,1/(d+e*x)] /;
FreeQ[{c,d,e,f,g},x] && EqQ[c,2*d] && EqQ[e^2*f+d^2*g,0]

2:  ∫((a+b Log[(c/(d+e x))])/(f+g (x^2)))dx  when  (e^2) f+(d^2) g==0 ∧ (c/(2 d))>0

Derivation: Algebraic expansion

Basis: If (c/(2 d))>0, then Log[(c/(d+e x))]==Log[(c/(2 d))] Log[((2 d)/(d+e x))]

Rule: If  (e^2) f+(d^2) g==0 ∧ (c/(2 d))>0, then

∫((a+b Log[(c/(d+e x))])/(f+g (x^2)))dx  ⟶  (a+b Log[(c/(2 d))])∫(1/(f+g (x^2)))dx+b∫((Log[((2 d)/(d+e x))])/(f+g (x^2)))dx

Program code:

Int[(a_.+b_.*Log[c_./(d_+e_.*x_)])/(f_+g_.*x_^2),x_Symbol] :=
  (a+b*Log[c/(2*d)])*Int[1/(f+g*x^2),x] + b*Int[Log[2*d/(d+e*x)]/(f+g*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[e^2*f+d^2*g,0] && GtQ[c/(2*d),0]

3.  ∫((a+b Log[c (((d+e x))^n)])/(Sqrt[f+g (x^2)]))dx

1:  ∫((a+b Log[c (((d+e x))^n)])/(Sqrt[f+g (x^2)]))dx  when  f>0

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (((d+e x))^n)])==((b e n)/(d+e x))

Note: If  f>0, then ∫(1/(Sqrt[f+g (x^2)]))dx involves the inverse sine of a linear function of x, otherwise it involves the inverse tangent of a nonlinear function of x.

Rule: If  f>0,  let u->∫(1/(Sqrt[f+g (x^2)]))dx, then

∫((a+b Log[c (((d+e x))^n)])/(Sqrt[f+g (x^2)]))dx  ⟶  u (a+b Log[c (((d+e x))^n)])-b e n ∫(u/(d+e x))dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])/Sqrt[f_+g_.*x_^2],x_Symbol] :=
  With[{u=IntHide[1/Sqrt[f+g*x^2],x]},  
  u*(a+b*Log[c*(d+e*x)^n]) - b*e*n*Int[SimplifyIntegrand[u/(d+e*x),x],x]] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && GtQ[f,0]

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])/(Sqrt[f1_+g1_.*x_]*Sqrt[f2_+g2_.*x_]),x_Symbol] :=
  With[{u=IntHide[1/Sqrt[f1*f2+g1*g2*x^2],x]},  
  u*(a+b*Log[c*(d+e*x)^n]) - b*e*n*Int[SimplifyIntegrand[u/(d+e*x),x],x]] /;
FreeQ[{a,b,c,d,e,f1,g1,f2,g2,n},x] && EqQ[f2*g1+f1*g2,0] && GtQ[f1,0] && GtQ[f2,0]

2:  ∫((a+b Log[c (((d+e x))^n)])/(Sqrt[f+g (x^2)]))dx  when  f≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[1+(g/f) (x^2)])/(Sqrt[f+g (x^2)]))==0

Rule: If  f≯0, then

∫((a+b Log[c (((d+e x))^n)])/(Sqrt[f+g (x^2)]))dx  ⟶  ((Sqrt[1+(g/f) (x^2)])/(Sqrt[f+g (x^2)])) ∫((a+b Log[c (((d+e x))^n)])/(Sqrt[1+(g/f) (x^2)]))dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])/Sqrt[f_+g_.*x_^2],x_Symbol] :=
  Sqrt[1+g/f*x^2]/Sqrt[f+g*x^2]*Int[(a+b*Log[c*(d+e*x)^n])/Sqrt[1+g/f*x^2],x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && Not[GtQ[f,0]]

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])/(Sqrt[f1_+g1_.*x_]*Sqrt[f2_+g2_.*x_]),x_Symbol] :=
  Sqrt[1+g1*g2/(f1*f2)*x^2]/(Sqrt[f1+g1*x]*Sqrt[f2+g2*x])*Int[(a+b*Log[c*(d+e*x)^n])/Sqrt[1+g1*g2/(f1*f2)*x^2],x] /;
FreeQ[{a,b,c,d,e,f1,g1,f2,g2,n},x] && EqQ[f2*g1+f1*g2,0]

4:  ∫(((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  r∈𝔽 ∧ p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then F[x]==k Subst[(x^(k-1))F[(x^k)],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  r∈𝔽 ∧ p∈(SuperPlus[ℤ]), let k->Denominator[r], then

∫(((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  k Subst[∫(x^(k-1)) (((f+g (x^(k r))))^q) (((a+b Log[c (((d+e (x^k)))^n)]))^p)dx,x,(x^(1/k))]

Program code:

Int[(f_.+g_.*x_^r_)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  With[{k=Denominator[r]},
  k*Subst[Int[x^(k-1)*(f+g*x^(k*r))^q*(a+b*Log[c*(d+e*x^k)^n])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q},x] && FractionQ[r] && IGtQ[p,0]

5:  ∫(((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  p∈(SuperPlus[ℤ])∧ q∈ℤ ∧ (q>0 ∨ (r∈ℤ ∧ r≠1))

Derivation: Algebraic expansion

Rule: If  p∈(SuperPlus[ℤ])∧ q∈ℤ ∧ (q>0 ∨ (r∈ℤ ∧ r≠1)), then

∫(((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  ∫(((a+b Log[c (((d+e x))^n)]))^p)ExpandIntegrand[(((f+g (x^r)))^q),x]dx

Program code:

Int[(f_+g_.*x_^r_)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*Log[c*(d+e*x)^n])^p,(f+g*x^r)^q,x],x] /;
FreeQ[{a,b,c,d,e,f,g,n,r},x] && IGtQ[p,0] && IntegerQ[q] && (GtQ[q,0] || IntegerQ[r] && NeQ[r,1])

3.  ∫(((f+g x))^q) (((h+i x))^r) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  e f-d g==0

1:  ∫(((x^m) Log[c (d+e x)])/(f+g x))dx  when  e f-d g==0 ∧ c d==1 ∧ m∈ℤ

Derivation: Algebraic expansion

Rule: If  e f-d g==0 ∧ c d==1 ∧ m∈ℤ, then

∫(((x^m) Log[c (d+e x)])/(f+g x))dx  ⟶  ∫Log[c (d+e x)] ExpandIntegrand[((x^m)/(f+g x)),x]dx

Program code:

Int[x_^m_.*Log[c_.*(d_+e_.*x_)]/(f_+g_.x_),x_Symbol] :=
  Int[ExpandIntegrand[Log[c*(d+e*x)],x^m/(f+g*x),x],x] /;
FreeQ[{c,d,e,f,g},x] && EqQ[e*f-d*g,0] && EqQ[c*d,1] && IntegerQ[m]

2:  ∫(((f+g x))^q) (((h+i x))^r) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  e f-d g==0

Derivation: Integration by substitution

Basis: F[x]==(1/e) Subst[F[((x-d)/e)],x,d+e x] (∂_x)(d+e x)

Rule: If  e f-d g==0, then

∫(((f+g x))^q) (((h+i x))^r) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  (1/e) Subst[∫(((((g x)/e)))^q) (((((e h-d i)/e)+((i x)/e)))^r) (((a+b Log[c (x^n)]))^p)dx,x,d+e x]

Program code:

Int[(f_.+g_.x_)^q_.*(h_.+i_.x_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  1/e*Subst[Int[(g*x/e)^q*((e*h-d*i)/e+i*x/e)^r*(a+b*Log[c*x^n])^p,x],x,d+e*x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,n,p,q,r},x] && EqQ[e*f-d*g,0] && (IGtQ[p,0] || IGtQ[r,0]) && IntegerQ[2*r]

4.  ∫(((h x))^m) (((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx

1:  ∫(x^m) (((f+(g/x)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  m==q ∧ q∈ℤ

Derivation: Algebraic simplification

Rule: If  m==q ∧ q∈ℤ, then

∫(x^m) (((f+(g/x)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  ∫(((g+f x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx

Program code:

Int[x_^m_.*(f_+g_./x_)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  Int[(g+f*x)^q*(a+b*Log[c*(d+e*x)^n])^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p,q},x] && EqQ[m,q] && IntegerQ[q]

2:  ∫(x^m) (((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  m==r-1 ∧ q≠-1 ∧ p∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: If  m==r-1 ∧ q≠-1, then (x^m) (((f+g (x^r)))^q)==(∂_x)((((f+g (x^r)))^(q+1))/(g r (q+1)))

Rule: If  m==r-1 ∧ q≠-1 ∧ p∈(SuperPlus[ℤ]), then

∫(x^m) (((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  (((((f+g (x^r)))^(q+1)) (((a+b Log[c (((d+e x))^n)]))^p))/(g r (q+1)))-((b e n p)/(g r (q+1))) ∫(((((f+g (x^r)))^(q+1)) (((a+b Log[c (((d+e x))^n)]))^(p-1)))/(d+e x))dx

Program code:

Int[x_^m_.*(f_.+g_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  (f+g*x^r)^(q+1)*(a+b*Log[c*(d+e*x)^n])^p/(g*r*(q+1)) - 
  b*e*n*p/(g*r*(q+1))*Int[(f+g*x^r)^(q+1)*(a+b*Log[c*(d+e*x)^n])^(p-1)/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,q,r},x] && EqQ[m,r-1] && NeQ[q,-1] && IGtQ[p,0]

3:  ∫(x^m) (((f+g (x^r)))^q) (a+b Log[c (((d+e x))^n)])dx  when  m∈ℤ ∧ q∈ℤ ∧ r∈ℤ

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (((d+e x))^n)])==((b e n)/(d+e x))

Rule: If  m∈ℤ ∧ q∈ℤ ∧ r∈ℤ, let u->∫(x^m) (((f+g (x^r)))^q)dx, then

∫(x^m) (((f+g (x^r)))^q) (a+b Log[c (((d+e x))^n)])dx  ⟶  u (a+b Log[c (((d+e x))^n)])-b e n ∫(u/(d+e x))dx

Program code:

Int[x_^m_.*(f_+g_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.]),x_Symbol] :=
  With[{u=IntHide[x^m*(f+g*x^r)^q,x]},  
  Dist[(a+b*Log[c*(d+e*x)^n]),u,x] - b*e*n*Int[SimplifyIntegrand[u/(d+e*x),x],x] /;
 InverseFunctionFreeQ[u,x]] /;
FreeQ[{a,b,c,d,e,f,g,m,n,q,r},x] && IntegerQ[m] && IntegerQ[q] && IntegerQ[r]

4:  ∫(x^m) (((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  r∈𝔽 ∧ p∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then F[x]==k Subst[(x^(k-1))F[(x^k)],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  r∈𝔽 ∧ p∈(SuperPlus[ℤ])∧ m∈ℤ, let k->Denominator[r], then

∫(x^m) (((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  k Subst[∫(x^(k (m+1)-1)) (((f+g (x^(k r))))^q) (((a+b Log[c (((d+e (x^k)))^n)]))^p)dx,x,(x^(1/k))]

Program code:

Int[x_^m_.*(f_.+g_.*x_^r_)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  With[{k=Denominator[r]},
  k*Subst[Int[x^(k*(m+1)-1)*(f+g*x^(k*r))^q*(a+b*Log[c*(d+e*x^k)^n])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q},x] && FractionQ[r] && IGtQ[p,0] && IntegerQ[m]

5:  ∫(((h x))^m) (((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  when  m∈ℤ ∧ q∈ℤ

Derivation: Algebraic expansion

Rule: If  m∈ℤ ∧ q∈ℤ, then

∫(((h x))^m) (((f+g (x^r)))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  ∫ExpandIntegrand[(((a+b Log[c (((d+e x))^n)]))^p),(((h x))^m) (((f+g (x^r)))^q),x]dx

Program code:

Int[(h_.*x_)^m_.*(f_+g_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*Log[c*(d+e*x)^n])^p,(h*x)^m*(f+g*x^r)^q,x],x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n,p,q,r},x] && IntegerQ[m] && IntegerQ[q]

5.  ∫AF[x] (((a+b Log[c (((d+e x))^n)]))^p)dx

1:  ∫Poly[x] (((a+b Log[c (((d+e x))^n)]))^p)dx

Derivation: Algebraic expansion

Rule:

∫Poly[x] (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  ∫ExpandIntegrand[Poly[x] (((a+b Log[c (((d+e x))^n)]))^p),x]dx

Program code:

Int[Polyx_*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[Polyx*(a+b*Log[c*(d+e*x)^n])^p,x],x] /;
FreeQ[{a,b,c,d,e,n,p},x] && PolynomialQ[Polyx,x]

2:  ∫RF[x] (((a+b Log[c (((d+e x))^n)]))^p)dx  when  p∈ℤ

Derivation: Algebraic expansion

Rule: If  p∈ℤ, then

∫RF[x] (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  ∫(((a+b Log[c (((d+e x))^n)]))^p) ExpandIntegrand[RF[x],x]dx

Program code:

Int[RFx_*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*Log[c*(d+e*x)^n])^p,RFx,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,n},x] && RationalFunctionQ[RFx,x] && IntegerQ[p]

Int[RFx_*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[RFx*(a+b*Log[c*(d+e*x)^n])^p,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,n},x] && RationalFunctionQ[RFx,x] && IntegerQ[p]

U:  ∫AF[x] (((a+b Log[c (((d+e x))^n)]))^p)dx

Rule:

∫AF[x] (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  ∫AF[x] (((a+b Log[c (((d+e x))^n)]))^p)dx

Program code:

Int[AFx_*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  Unintegrable[AFx*(a+b*Log[c*(d+e*x)^n])^p,x] /;
FreeQ[{a,b,c,d,e,n,p},x] && AlgebraicFunctionQ[AFx,x,True]

N:  ∫(u^q)(((a+b Log[c (v^n)]))^p)dx  when  u==f+g (x^r) ∧ v==d+e x

Derivation: Algebraic normalization

Rule: If  u==f+g (x^r) ∧ v==d+e x, then

∫(u^q)(((a+b Log[c (v^n)]))^p)dx  ⟶  ∫(((f+g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx

Program code:

Int[u_^q_.*(a_.+b_.*Log[c_.*v_^n_.])^p_.,x_Symbol] :=
  Int[ExpandToSum[u,x]^q*(a+b*Log[c*ExpandToSum[v,x]^n])^p,x] /;
FreeQ[{a,b,c,n,p,q},x] && BinomialQ[u,x] && LinearQ[v,x] && Not[BinomialMatchQ[u,x] && LinearMatchQ[v,x]]

6.  ∫Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx

1:  ∫Log[f (x^m)] (a+b Log[c (((d+e x))^n)])dx

Derivation: Integration by parts

Basis: Log[f (x^m)]==-(∂_x)(x (m-Log[f (x^m)]))

Rule:

∫Log[f (x^m)] (a+b Log[c (((d+e x))^n)])dx  ⟶  
-x (m-Log[f (x^m)]) (a+b Log[c (((d+e x))^n)])+b e m n ∫(x/(d+e x))dx-b e n ∫((x Log[f (x^m)])/(d+e x))dx

Program code:

Int[Log[f_.*x_^m_.]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.]),x_Symbol] :=
  -x*(m-Log[f*x^m])*(a+b*Log[c*(d+e*x)^n]) + b*e*m*n*Int[x/(d+e*x),x] - b*e*n*Int[(x*Log[f*x^m])/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x]

2:  ∫Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  p-1∈(SuperPlus[ℤ]), let u->∫(((a+b Log[c (((d+e x))^n)]))^p)dx, then

∫Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  u Log[f (x^m)]-m ∫(u/x)dx

Program code:

Int[Log[f_.*x_^m_.]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_,x_Symbol] :=
  With[{u=IntHide[(a+b*Log[c*(d+e*x)^n])^p,x]},
  Dist[Log[f*x^m],u,x] - m*Int[Dist[1/x,u,x],x]] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && IGtQ[p,1]

U:  ∫Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx

Rule:

∫Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  ∫Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx

Program code:

Int[Log[f_.*x_^m_.]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  Unintegrable[Log[f*x^m]*(a+b*Log[c*(d+e*x)^n])^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p},x]

7.  ∫(((g x))^q) Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx

1.  ∫(((g x))^q) Log[f (x^m)] (a+b Log[c (((d+e x))^n)])dx

1:  ∫((Log[f (x^m)] (a+b Log[c (((d+e x))^n)]))/x)dx

Derivation: Integration by parts

Basis: ((Log[f (x^m)])/x)==(∂_x)(((Log[f (x^m)])^2)/(2 m))

Rule:

∫((Log[f (x^m)] (a+b Log[c (((d+e x))^n)]))/x)dx  ⟶  ((((Log[f (x^m)])^2) (a+b Log[c (((d+e x))^n)]))/(2 m))-((b e n)/(2 m)) ∫(((Log[f (x^m)])^2)/(d+e x))dx

Program code:

Int[Log[f_.*x_^m_.]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])/x_,x_Symbol] :=
  Log[f*x^m]^2*(a+b*Log[c*(d+e*x)^n])/(2*m) - b*e*n/(2*m)*Int[Log[f*x^m]^2/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x]

2:  ∫(((g x))^q) Log[f (x^m)] (a+b Log[c (((d+e x))^n)])dx  when  q≠-1

Derivation: Integration by parts

Basis: (((g x))^q) Log[f (x^m)]==-(1/(g (q+1))) (∂_x)(((m (((g x))^(q+1)))/(q+1))-(((g x))^(q+1)) Log[f (x^m)])

Rule: If  q≠-1, then

∫(((g x))^q) Log[f (x^m)] (a+b Log[c (((d+e x))^n)])dx  ⟶  
-(1/(g (q+1))) (((m (((g x))^(q+1)))/(q+1))-(((g x))^(q+1)) Log[f (x^m)]) (a+b Log[c (((d+e x))^n)])+((b e m n)/(g (((q+1))^2))) ∫((((g x))^(q+1))/(d+e x))dx-((b e n)/(g (q+1))) ∫(((((g x))^(q+1)) Log[f (x^m)])/(d+e x))dx

Program code:

Int[(g_.*x_)^q_.*Log[f_.*x_^m_.]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.]),x_Symbol] :=
  -1/(g*(q+1))*(m*(g*x)^(q+1)/(q+1)-(g*x)^(q+1)*Log[f*x^m])*(a+b*Log[c*(d+e*x)^n]) + 
  b*e*m*n/(g*(q+1)^2)*Int[(g*x)^(q+1)/(d+e*x),x] - 
  b*e*n/(g*(q+1))*Int[(g*x)^(q+1)*Log[f*x^m]/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,q},x] && NeQ[q,-1]

?:  ∫((Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: ((Log[f (x^m)])/x)==(∂_x)(((Log[f (x^m)])^2)/(2 m))

Rule: If  p∈(SuperPlus[ℤ]), then

∫((Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p))/x)dx  ⟶  ((((Log[f (x^m)])^2) (((a+b Log[c (((d+e x))^n)]))^p))/(2 m))-((b e n p)/(2 m)) ∫((((Log[f (x^m)])^2) (((a+b Log[c (((d+e x))^n)]))^(p-1)))/(d+e x))dx

Program code:

Int[Log[f_.*x_^m_.]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_./x_,x_Symbol] :=
  Log[f*x^m]^2*(a+b*Log[c*(d+e*x)^n])^p/(2*m) - b*e*n*p/(2*m)*Int[Log[f*x^m]^2*(a+b*Log[c*(d+e*x)^n])^(p-1)/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && IGtQ[p,0]

2:  ∫(((g x))^q) Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  p-1∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ]), let u->∫(((g x))^q) (((a+b Log[c (((d+e x))^n)]))^p)dx, then

∫(((g x))^q) Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  u Log[f (x^m)]-m ∫(u/x)dx

Program code:

Int[(g_.*x_)^q_.*Log[f_.*x_^m_.]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_,x_Symbol] :=
  With[{u=IntHide[(g*x)^q*(a+b*Log[c*(d+e*x)^n])^p,x]},
  Dist[Log[f*x^m],u,x] - m*Int[Dist[1/x,u,x],x]] /;
FreeQ[{a,b,c,d,e,f,g,m,n,q},x] && IGtQ[p,1] && IGtQ[q,0]

x:  ∫(((g x))^q) Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (∂_x)((((g x))^q) Log[f (x^m)])==g m (((g x))^(q-1))+g q (((g x))^(q-1)) Log[f (x^m)]

Rule: If  p-1∈(SuperPlus[ℤ]), let u->∫(((a+b Log[c (((d+e x))^n)]))^p)dx, then

∫(((g x))^q) Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  u (((g x))^q) Log[f (x^m)]-g m ∫u (((g x))^(q-1))dx-g q ∫u (((g x))^(q-1)) Log[f (x^m)]dx

Program code:

(* Int[(g_.*x_)^q_.*Log[f_.*x_^m_.]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_,x_Symbol] :=
  With[{u=IntHide[(a+b*Log[c*(d+e*x)^n])^p,x]},
  Dist[(g*x)^q*Log[f*x^m],u,x] - g*m*Int[Dist[(g*x)^(q-1),u,x],x] - g*q*Int[Dist[(g*x)^(q-1)*Log[f*x^m],u,x],x]] /;
FreeQ[{a,b,c,d,e,f,g,m,n,q},x] && IGtQ[p,1] *)

U:  ∫(((g x))^q) Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx

Rule:

∫(((g x))^q) Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  ∫(((g x))^q) Log[f (x^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx

Program code:

Int[(g_.*x_)^q_.*Log[f_.*x_^m_.]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  Unintegrable[(g*x)^q*Log[f*x^m]*(a+b*Log[c*(d+e*x)^n])^p,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p,q},x]

8.  ∫(((a+b Log[c (((d+e x))^n)]))^p) (((f+g Log[h (((i+j x))^m)]))^q)dx

1:  ∫Log[f (((g+h x))^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx  when  e g-d h==0

Derivation: Integration by substitution

Basis: If  e g-d h==0, then F[g+h x,x]==(1/e) Subst[F[((g x)/d),((x-d)/e)],x,d+e x] (∂_x)(d+e x)

Rule: If  e g-d h==0, then

∫Log[f (((g+h x))^m)] (((a+b Log[c (((d+e x))^n)]))^p)dx  ⟶  (1/e) Subst[∫Log[f (((((g x)/d)))^m)] (((a+b Log[c (x^n)]))^p)dx,x,d+e x]

Program code:

Int[Log[f_.*(g_.+h_.*x_)^m_.]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.,x_Symbol] :=
  1/e*Subst[Int[Log[f*(g*x/d)^m]*(a+b*Log[c*x^n])^p,x],x,d+e*x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n,p},x] && EqQ[e*f-d*g,0]

2:  ∫(a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)])dx

Derivation: Integration by parts

Basis: (∂_x)((a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)]))==((e n (b f+a g+2 b g Log[c (((d+e x))^n)]))/(d+e x))

Rule:

∫(a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)]) dx  ⟶  
x (a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)])-e n ∫((x (b f+a g+2 b g Log[c (((d+e x))^n)]))/(d+e x))dx

Pmogram code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])*(f_.+g_.*Log[c_.*(d_+e_.*x_)^n_.]),x_Symbol] :=
  x*(a+b*Log[c*(d+e*x)^n])*(f+g*Log[c*(d+e*x)^n]) - 
  e*n*Int[(x*(b*f+a*g+2*b*g*Log[c*(d+e*x)^n]))/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x]

3:  ∫(((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)])dx when  p∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (∂_x)((f+g Log[h (((i+j x))^m)]) (((a+b Log[c (((d+e x))^n)]))^p))==((g j m (((a+b Log[c (((d+e x))^n)]))^p))/(i+j x))+((b e n p (((a+b Log[c (((d+e x))^n)]))^(-1+p)) (f+g Log[h (((i+j x))^m)]))/(d+e x))

Rule: If  p∈(SuperPlus[ℤ]), then

∫(((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)])dx  ⟶  
x (((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)])-g j m ∫((x (((a+b Log[c (((d+e x))^n)]))^p))/(i+j x))dx-b e n p ∫((x (((a+b Log[c (((d+e x))^n)]))^(p-1)) (f+g Log[h (((i+j x))^m)]))/(d+e x))dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.*(f_.+g_.*Log[h_.*(i_.+j_.*x_)^m_.]),x_Symbol] :=
  x*(a+b*Log[c*(d+e*x)^n])^p*(f+g*Log[h*(i+j*x)^m]) - 
  g*j*m*Int[x*(a+b*Log[c*(d+e*x)^n])^p/(i+j*x),x] - 
  b*e*n*p*Int[x*(a+b*Log[c*(d+e*x)^n])^(p-1)*(f+g*Log[h*(i+j*x)^m])/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,j,m,n},x] && IGtQ[p,0]

U:  ∫(((a+b Log[c (((d+e x))^n)]))^p) (((f+g Log[h (((i+j x))^m)]))^q)dx

Rule:

∫(((a+b Log[c (((d+e x))^n)]))^p) (((f+g Log[h (((i+j x))^m)]))^q)dx  ⟶  ∫(((a+b Log[c (((d+e x))^n)]))^p) (((f+g Log[h (((i+j x))^m)]))^q)dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.*(f_.+g_.*Log[h_.*(i_.+j_.*x_)^m_.])^q_.,x_Symbol] :=
  Unintegrable[(a+b*Log[c*(d+e*x)^n])^p*(f+g*Log[h*(i+j*x)^m])^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,j,m,n,p},x]

9.  ∫(((k+l x))^r) (((a+b Log[c (((d+e x))^n)]))^p) (((f+g Log[h (((i+j x))^m)]))^q)dx

1:  ∫(((k+l x))^r) (((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)])dx  when  e k-d l==0

Derivation: Integration by substitution

Basis: If  e k-d l==0, then (((k+l x))^r) F[x]==(1/e) Subst[(((((k x)/d)))^r) F[((x-d)/e)],x,d+e x] (∂_x)(d+e x)

Rule: If  e k-d l==0, then

∫(((k+l x))^r) (((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)])dx  ⟶  (1/e) Subst[∫(((((k x)/d)))^r) (((a+b Log[c (x^n)]))^p) (f+g Log[h (((((e i-d j)/e)+((j x)/e)))^m)])dx,x,d+e x]

Program code:

Int[(k_.+l_.*x_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.*(f_.+g_.*Log[h_.*(i_.+j_.*x_)^m_.]),x_Symbol] :=
  1/e*Subst[Int[(k*x/d)^r*(a+b*Log[c*x^n])^p*(f+g*Log[h*((e*i-d*j)/e+j*x/e)^m]),x],x,d+e*x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,j,k,l,n,p,r},x] && EqQ[e*k-d*l,0]

2.  ∫(x^r) (((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)])dx when  p∈(SuperPlus[ℤ])∧ r∈ℤ ∧(p==1 ∨ r>0)

1.  ∫(x^m) (a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)])dx

1:  ∫(((a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)]))/x)dx

Derivation: Integration by parts

Basis: (∂_x)((a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)]))==((e n (b f+a g+2 b g Log[c (((d+e x))^n)]))/(d+e x))

Rule:

∫(((a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)]))/x) dx  ⟶  
Log[x] (a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)])-e n ∫((Log[x] (b f+a g+2 b g Log[c (((d+e x))^n)]))/(d+e x))dx

Pmogram code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])*(f_.+g_.*Log[c_.*(d_+e_.*x_)^n_.])/x_,x_Symbol] :=
  Log[x]*(a+b*Log[c*(d+e*x)^n])*(f+g*Log[c*(d+e*x)^n]) - 
  e*n*Int[(Log[x]*(b*f+a*g+2*b*g*Log[c*(d+e*x)^n]))/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x]

2:  ∫(x^m) (a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)])dx when  m≠-1

Derivation: Integration by parts

Basis: (∂_x)((a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)]))==((e n (b f+a g+2 b g Log[c (((d+e x))^n)]))/(d+e x))

Rule: If  m≠-1, then

∫(x^m) (a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)]) dx  ⟶  
(((x^(m+1)) (a+b Log[c (((d+e x))^n)]) (f+g Log[c (((d+e x))^n)]))/(m+1))-((e n)/(m+1)) ∫(((x^(m+1)) (b f+a g+2 b g Log[c (((d+e x))^n)]))/(d+e x))dx

Pmogram code:

Int[x_^m_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])*(f_.+g_.*Log[c_.*(d_+e_.*x_)^n_.]),x_Symbol] :=
  x^(m+1)*(a+b*Log[c*(d+e*x)^n])*(f+g*Log[c*(d+e*x)^n])/(m+1) - 
  e*n/(m+1)*Int[(x^(m+1)*(b*f+a*g+2*b*g*Log[c*(d+e*x)^n]))/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,n,m},x] && NeQ[m,-1]

1.  ∫(((((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)]))/x)dx

1.  ∫(((a+b Log[c (((d+e x))^n)]) (f+g Log[h (((i+j x))^m)]))/x)dx

1:  ∫(((a+b Log[c (((d+e x))^n)]) (f+g Log[h (((i+j x))^m)]))/x)dx  when  e i-d j==0

Derivation: Integration by parts

Basis: If  e i-d j==0, then (∂_x)((a+b Log[c (((d+e x))^n)]) (f+g Log[h (((i+j x))^m)]))==((e g m (a+b Log[c (((d+e x))^n)]))/(d+e x))+((b j n (f+g Log[h (((i+j x))^m)]))/(i+j x))

Rule: If  e i-d j==0, then

∫(((a+b Log[c (((d+e x))^n)]) (f+g Log[h (((i+j x))^m)]))/x)dx  ⟶  
Log[x] (a+b Log[c (((d+e x))^n)]) (f+g Log[h (((i+j x))^m)])-e g m ∫((Log[x] (a+b Log[c (((d+e x))^n)]))/(d+e x))dx-b j n ∫((Log[x] (f+g Log[h (((i+j x))^m)]))/(i+j x))dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])*(f_.+g_.*Log[h_.*(i_.+j_.*x_)^m_.])/x_,x_Symbol] :=
  Log[x]*(a+b*Log[c*(d+e*x)^n])*(f+g*Log[h*(i+j*x)^m]) - 
  e*g*m*Int[Log[x]*(a+b*Log[c*(d+e*x)^n])/(d+e*x),x] - 
  b*j*n*Int[Log[x]*(f+g*Log[h*(i+j*x)^m])/(i+j*x),x]/;
FreeQ[{a,b,c,d,e,f,g,h,i,j,m,n},x] && EqQ[e*i-d*j,0]

2.  ∫(((a+b Log[c (((d+e x))^n)]) (f+g Log[h (((i+j x))^m)]))/x)dx  when  e i-d j≠0

1.  ∫((Log[c (((d+e x))^n)] Log[h (((i+j x))^m)])/x)dx  when  e i-d j≠0

1:  ∫((Log[d+e x] Log[i+j x])/x)dx  when  e i-d j≠0

Derivation: Integration by parts and ???

Rule: If  b c-a d≠0, then

∫((Log[a+b x] Log[c+d x])/x)dx  ⟶  Log[-((b x)/a)] Log[a+b x] Log[c+d x]-∫(((d Log[-((b x)/a)] Log[a+b x])/(c+d x))+((b Log[-((b x)/a)] Log[c+d x])/(a+b x)))dx

  ⟶ Log[-((b x)/a)] Log[a+b x] Log[c+d x]-d (Log[-((b x)/a)]-Log[-((d x)/c)]) ∫((Log[a+b x]+Log[((a (c+d x))/(c (a+b x)))])/(c+d x))dx-
(b c-a d)∫((Log[-((b x)/a)] Log[((a (c+d x))/(c (a+b x)))])/((a+b x) (c+d x)))dx-b ∫((Log[-((b x)/a)] (Log[c+d x]-Log[((a (c+d x))/(c (a+b x)))]))/(a+b x))dx-d ∫((Log[-((d x)/c)] (Log[a+b x]+Log[((a (c+d x))/(c (a+b x)))]))/(c+d x))dx

  ⟶  Log[-((b x)/a)] Log[a+b x] Log[c+d x]-(1/2) (Log[-((b x)/a)]-Log[-((d x)/c)]) (((Log[a+b x]+Log[((a (c+d x))/(c (a+b x)))]))^2)+
(1/2) (Log[-((b x)/a)]-Log[-(((b c-a d) x)/(a (c+d x)))]+Log[((b c-a d)/(b (c+d x)))]) ((Log[((a (c+d x))/(c (a+b x)))])^2)+
(Log[c+d x]-Log[((a (c+d x))/(c (a+b x)))]) PolyLog[2,1+((b x)/a)]+(Log[a+b x]+Log[((a (c+d x))/(c (a+b x)))]) PolyLog[2,1+((d x)/c)]-
Log[((a (c+d x))/(c (a+b x)))] PolyLog[2,((d (a+b x))/(b (c+d x)))]+Log[((a (c+d x))/(c (a+b x)))] PolyLog[2,((c (a+b x))/(a (c+d x)))]-
PolyLog[3,1+((b x)/a)]-PolyLog[3,1+((d x)/c)]-PolyLog[3,((d (a+b x))/(b (c+d x)))]+PolyLog[3,((c (a+b x))/(a (c+d x)))]

Program code:

Int[Log[a_+b_.*x_]*Log[c_+d_.*x_]/x_,x_Symbol] :=
  Log[-b*x/a]*Log[a+b*x]*Log[c+d*x] - 
  1/2*(Log[-b*x/a]-Log[-d*x/c])*(Log[a+b*x]+Log[a*(c+d*x)/(c*(a+b*x))])^2 + 
  1/2*(Log[-b*x/a]-Log[-(b*c-a*d)*x/(a*(c+d*x))]+Log[(b*c-a*d)/(b*(c+d*x))])*Log[a*(c+d*x)/(c*(a+b*x))]^2 + 
  (Log[c+d*x]-Log[a*(c+d*x)/(c*(a+b*x))])*PolyLog[2,1+b*x/a] + 
  (Log[a+b*x]+Log[a*(c+d*x)/(c*(a+b*x))])*PolyLog[2,1+d*x/c] - 
  Log[a*(c+d*x)/(c*(a+b*x))]*PolyLog[2,d*(a+b*x)/(b*(c+d*x))] + 
  Log[a*(c+d*x)/(c*(a+b*x))]*PolyLog[2,c*(a+b*x)/(a*(c+d*x))] - 
  PolyLog[3,1+b*x/a] - PolyLog[3,1+d*x/c] - PolyLog[3,d*(a+b*x)/(b*(c+d*x))] + PolyLog[3,c*(a+b*x)/(a*(c+d*x))]/;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

Int[Log[v_]*Log[w_]/x_,x_Symbol] :=
  Int[Log[ExpandToSum[v,x]]*Log[ExpandToSum[w,x]]/x,x] /;
LinearQ[{v,w},x] && Not[LinearMatchQ[{v,w},x]]

2:  ∫((Log[c (((d+e x))^n)] Log[h (((i+j x))^m)])/x)dx  when  e i-d j≠0

Derivation: Algebraic expansion and piecewise constant extraction

Basis: (∂_x)(m Log[i+j x]-Log[h (((i+j x))^m)])==0

Rule: If  e i-d j≠0, then

∫((Log[c (((d+e x))^n)] Log[h (((i+j x))^m)])/x)dx  ⟶  m ∫((Log[i+j x] Log[c (((d+e x))^n)])/x)dx-(m Log[i+j x]-Log[h (((i+j x))^m)]) ∫((Log[c (((d+e x))^n)])/x)dx

Int[Log[c_.*(d_+e_.*x_)^n_.]*Log[h_.*(i_.+j_.*x_)^m_.]/x_,x_Symbol] :=
  m*Int[Log[i+j*x]*Log[c*(d+e*x)^n]/x,x] - (m*Log[i+j*x]-Log[h*(i+j*x)^m])*Int[Log[c*(d+e*x)^n]/x,x]/;
FreeQ[{c,d,e,h,i,j,m,n},x] && NeQ[e*i-d*j,0] && NeQ[i+j*x,h*(i+j*x)^m]

2:  ∫(((a+b Log[c (((d+e x))^n)]) (f+g Log[h (((i+j x))^m)]))/x)dx  when  e g-d h≠0

Derivation: Algebraic expansion

Rule: If  e i-d j≠0, then

∫(((a+b Log[c (((d+e x))^n)]) (f+g Log[h (((i+j x))^m)]))/x)dx  ⟶  f ∫((a+b Log[c (((d+e x))^n)])/x)dx+g ∫((Log[h (((i+j x))^m)] (a+b Log[c (((d+e x))^n)]))/x)dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])*(f_+g_.*Log[h_.*(i_.+j_.*x_)^m_.])/x_,x_Symbol] :=
  f*Int[(a+b*Log[c*(d+e*x)^n])/x,x] + g*Int[Log[h*(i+j*x)^m]*(a+b*Log[c*(d+e*x)^n])/x,x]/;
FreeQ[{a,b,c,d,e,f,g,h,i,j,m,n},x] && NeQ[e*i-d*j,0]

2:  ∫(x^r) (((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)])dx when  p∈(SuperPlus[ℤ])∧ r∈ℤ ∧(p==1 ∨ r>0)∧ r≠-1

Derivation: Integration by parts

Basis: (∂_x)((((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)]))==((g j m (((a+b Log[c (((d+e x))^n)]))^p))/(i+j x))+((b e n p (((a+b Log[c (((d+e x))^n)]))^(-1+p)) (f+g Log[h (((i+j x))^m)]))/(d+e x))

Rule: If  p∈(SuperPlus[ℤ])∧ r∈ℤ ∧(p==1 ∨ r>0)∧ r≠-1, then

∫(x^r) (((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)]) dx  ⟶  

(((x^(r+1)) (((a+b Log[c (((d+e x))^n)]))^p) (f+g Log[h (((i+j x))^m)]))/(r+1))-
((g j m)/(r+1)) ∫(((x^(r+1)) (((a+b Log[c (((d+e x))^n)]))^p))/(i+j x))dx-((b e n p)/(r+1)) ∫(((x^(r+1)) (((a+b Log[c (((d+e x))^n)]))^(p-1)) (f+g Log[h (((i+j x))^m)]))/(d+e x))dx

Program code:

Int[x_^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.*(f_.+g_.*Log[h_.*(i_.+j_.*x_)^m_.]),x_Symbol] :=
  x^(r+1)*(a+b*Log[c*(d+e*x)^n])^p*(f+g*Log[h*(i+j*x)^m])/(r+1) - 
  g*j*m/(r+1)*Int[x^(r+1)*(a+b*Log[c*(d+e*x)^n])^p/(i+j*x),x] - 
  b*e*n*p/(r+1)*Int[x^(r+1)*(a+b*Log[c*(d+e*x)^n])^(p-1)*(f+g*Log[h*(i+j*x)^m])/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,j,m,n},x] && IGtQ[p,0] && IntegerQ[r] && (EqQ[p,1] || GtQ[r,0]) && NeQ[r,-1]

3:  ∫(((k+l x))^r) (a+b Log[c (((d+e x))^n)]) (f+g Log[h (((i+j x))^m)])dx  when  r∈ℤ

Derivation: Integration by substitution

Rule: If  r∈ℤ, then

∫(((k+l x))^r) (a+b Log[c (((d+e x))^n)]) (f+g Log[h (((i+j x))^m)])dx  ⟶  
(1/l) Subst[∫(x^r) (a+b Log[c (((-((e k-d l)/l)+((e x)/l)))^n)]) (f+g Log[h (((-((j k-i l)/l)+((j x)/l)))^m)])dx,x,k+l x]

Program code:

Int[(k_+l_.*x_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])*(f_.+g_.*Log[h_.*(i_.+j_.*x_)^m_.]),x_Symbol] :=
  1/l*Subst[Int[x^r*(a+b*Log[c*(-(e*k-d*l)/l+e*x/l)^n])*(f+g*Log[h*(-(j*k-i*l)/l+j*x/l)^m]),x],x,k+l*x]/;
FreeQ[{a,b,c,d,e,f,g,h,i,j,k,l,m,n},x] && IntegerQ[r]

U:  ∫(((k+l x))^r) (((a+b Log[c (((d+e x))^n)]))^p) (((f+g Log[h (((i+j x))^m)]))^q)dx

Rule:

∫(((k+l x))^r) (((a+b Log[c (((d+e x))^n)]))^p) (((f+g Log[h (((i+j x))^m)]))^q)dx  ⟶  ∫(((k+l x))^r) (((a+b Log[c (((d+e x))^n)]))^p) (((f+g Log[h (((i+j x))^m)]))^q)dx

Program code:

Int[(k_.+l_.*x_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_.*(f_.+g_.*Log[h_.*(i_.+j_.*x_)^m_.])^q_.,x_Symbol] :=
  Unintegrable[(k+l*x)^r*(a+b*Log[c*(d+e*x)^n])^p*(f+g*Log[h*(i+j*x)^m])^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,j,k,l,m,n,p,q,r},x]

10:  ∫((PolyLog[k,h+i x] (((a+b Log[c (((d+e x))^n)]))^p))/(f+g x))dx  when  e f-d g==0 ∧ g h-f i==0 ∧ p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[x]==(1/e) Subst[F[((x-d)/e)],x,d+e x] (∂_x)(d+e x)

Rule: If  e f-d g==0 ∧ g h-f i==0 ∧ p∈(SuperPlus[ℤ]), then

∫((PolyLog[k,h+i x] (((a+b Log[c (((d+e x))^n)]))^p))/(f+g x))dx  ⟶  (1/g) Subst[∫((PolyLog[k,((h x)/d)] (((a+b Log[c (x^n)]))^p))/x)dx,x,d+e x]

Program code:

Int[PolyLog[k_,h_+i_.*x_]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])^p_./(f_+g_.*x_),x_Symbol] :=
  1/g*Subst[Int[PolyLog[k,h*x/d]*(a+b*Log[c*x^n])^p/x,x],x,d+e*x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,k,n},x] && EqQ[e*f-d*g,0] && EqQ[g*h-f*i,0] && IGtQ[p,0]

11:  ∫(Subscript[P, x])F[f (g+h x)] (a+b Log[c (((d+e x))^n)])dx  when  F∈{ArcSin,ArcCos,ArcTan,ArcCot,ArcSinh, ArcCosh,ArcTanh, ArcCoth}

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (((d+e x))^n)])==((b e n)/(d+e x))

Note: If  F∈{ArcSin,ArcCos,ArcTan,ArcCot,ArcSinh, ArcCosh,ArcTanh, ArcCoth}, the terms of the antiderivative of ((∫(Subscript[P, x]) F[f (g+h x)]dx)/(d+e x)) will be integrable.

Rule: If  F∈{ArcSin,ArcCos,ArcTan,ArcCot,ArcSinh, ArcCosh,ArcTanh, ArcCoth}, let u->∫(Subscript[P, x])F[f (g+h x)]dx, then

∫(Subscript[P, x])F[f (g+h x)] (a+b Log[c (((d+e x))^n)])dx  ⟶  u (a+b Log[c (((d+e x))^n)])-b e n∫(u/(d+e x))dx

Program code:

Int[Px_.*F_[f_.*(g_.+h_.*x_)]*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.]),x_Symbol] :=
  With[{u=IntHide[Px*F[f*(g+h*x)],x]},
  Dist[(a+b*Log[c*(d+e*x)^n]),u,x] - b*e*n*Int[SimplifyIntegrand[u/(d+e*x),x],x]] /;
FreeQ[{a,b,c,d,e,f,g,h,n},x] && PolynomialQ[Px,x] && 
  MemberQ[{ArcSin, ArcCos, ArcTan, ArcCot, ArcSinh, ArcCosh, ArcTanh, ArcCoth},F]

N:  ∫u (((a+b Log[c (v^n)]))^p)dx  when  v==d+e x

Derivation: Algebraic normalization

Rule: If  v==d+e x, then

∫u (((a+b Log[c (v^n)]))^p)dx  ⟶  ∫u (((a+b Log[c (((d+e x))^n)]))^p)dx

Program code:

Int[u_.*(a_.+b_.*Log[c_.*v_^n_.])^p_.,x_Symbol] :=
  Int[u*(a+b*Log[c*ExpandToSum[v,x]^n])^p,x] /;
FreeQ[{a,b,c,n,p},x] && LinearQ[v,x] && Not[LinearMatchQ[v,x]] && Not[EqQ[n,1] && MatchQ[c*v,e_.*(f_+g_.*x) /; FreeQ[{e,f,g},x]]]

Rules for integrands of the form  u (((a+b Log[c (((d (((e+f x))^m)))^n)]))^p)

S:  ∫u (((a+b Log[c (((d (((e+f x))^m)))^n)]))^p)dx  when  n∉ℤ ∧ ¬(d≠1 ∧ m≠1)

Derivation: Integration by substitution

Rule: If  n∉ℤ ∧ ¬(d≠1 ∧ m≠1), then

∫u (((a+b Log[c (((d (((e+f x))^m)))^n)]))^p)dx  ⟶  Subst[∫u (((a+b Log[c (d^n) (((e+f x))^(m n))]))^p)dx,c (d^n) (((e+f x))^(m n)),c (((d (((e+f x))^m)))^n)]

Program code:

Int[u_.*(a_.+b_.*Log[c_.*(d_.*(e_.+f_.x_)^m_.)^n_])^p_.,x_Symbol] :=
  Subst[Int[u*(a+b*Log[c*d^n*(e+f*x)^(m*n)])^p,x],c*d^n*(e+f*x)^(m*n),c*(d*(e+f*x)^m)^n] /;
FreeQ[{a,b,c,d,e,f,m,n,p},x] && Not[IntegerQ[n]] && Not[EqQ[d,1] && EqQ[m,1]] && 
  IntegralFreeQ[IntHide[u*(a+b*Log[c*d^n*(e+f*x)^(m*n)])^p,x]]

U:  ∫AF[x] (((a+b Log[c (((d (((e+f x))^m)))^n)]))^p)dx

Rule:

∫AF[x] (((a+b Log[c (((d (((e+f x))^m)))^n)]))^p)dx  ⟶  ∫AF[x] (((a+b Log[c (((d (((e+f x))^m)))^n)]))^p)dx

Program code:

Int[AFx_*(a_.+b_.*Log[c_.*(d_.*(e_.+f_.x_)^m_.)^n_])^p_.,x_Symbol] :=
  Unintegrable[AFx*(a+b*Log[c*(d*(e+f*x)^m)^n])^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p},x] && AlgebraicFunctionQ[AFx,x,True]