Rules for integrands of the form (((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])

1:  ∫((Sin[e+f x])^n) (((a+b Sin[e+f x]))^m) (A+B Sin[e+f x])dx  when  A b+a B==0∧ (a^2)-(b^2)==0 ∧ m∈ℤ ∧ n∈ℤ

Derivation:  Algebraic expansion

Rule: If  A b+a B==0∧ (a^2)-(b^2)==0 ∧ m∈ℤ ∧ n∈ℤ, then

∫((Sin[e+f x])^n) (((a+b Sin[e+f x]))^m) (A+B Sin[e+f x])dx  ⟶  ∫ExpandTrig[((Sin[e+f x])^n) (((a+b Sin[e+f x]))^m) (A+B Sin[e+f x]),x]dx

Program code:

Int[sin[e_.+f_.*x_]^n_.*(a_+b_.*sin[e_.+f_.*x_])^m_.*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  Int[ExpandTrig[sin[e+f*x]^n*(a+b*sin[e+f*x])^m*(A+B*sin[e+f*x]),x],x] /;
FreeQ[{a,b,e,f,A,B},x] && EqQ[A*b+a*B,0] && EqQ[a^2-b^2,0] && IntegerQ[m] && IntegerQ[n]

2:  ∫(((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∈ℤ

Derivation: Algebraic simplification

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then (a+b Sin[z]) (c+d Sin[z])==a c ((Cos[z])^2)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∈ℤ, then

∫(((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  (a^m) (c^m)∫((Cos[e+f x])^(2m)) (((c+d Sin[e+f x]))^(n-m))(A+B Sin[e+f x])dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_.*(c_+d_.*sin[e_.+f_.*x_])^n_.*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  a^m*c^m*Int[Cos[e+f*x]^(2*m)*(c+d*Sin[e+f*x])^(n-m)*(A+B*Sin[e+f*x]),x] /;
FreeQ[{a,b,c,d,e,f,A,B,n},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IntegerQ[m] && Not[IntegerQ[n] && (LtQ[m,0] && GtQ[n,0] || LtQ[0,n,m] || LtQ[m,n,0])]

3:  ∫(((a+b Sin[e+f x]))^m)(c+d Sin[e+f x])(A+B Sin[e+f x])dx  when  b c-a d≠0

Derivation: Algebraic expansion

Rule: If  b c-a d≠0, then

∫(((a+b Sin[e+f x]))^m)(c+d Sin[e+f x])(A+B Sin[e+f x])dx  ⟶  ∫(((a+b Sin[e+f x]))^m)(A c+(B c+A d) Sin[e+f x]+B d ((Sin[e+f x])^2))dx

Program code:

Int[(a_.+b_.*sin[e_.+f_.*x_])^m_.*(c_.+d_.*sin[e_.+f_.*x_])*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  Int[(a+b*Sin[e+f*x])^m*(A*c+(B*c+A*d)*Sin[e+f*x]+B*d*Sin[e+f*x]^2),x] /;
FreeQ[{a,b,c,d,e,f,A,B,m},x] && NeQ[b*c-a*d,0]

4.  ∫(((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∉ℤ ∧ n∉ℤ

1.  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∉ℤ ∧ n∉ℤ ∧ A b (m+n+1)+a B (m-n)==0

1:  ∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]])))dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0

Derivation: Algebraic expansion

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then b c+a d==0

Basis: If  b c+a d==0, then ((A+B z)/((Sqrt[a+b z]) (Sqrt[c+d z])))==(((A b+a B) (Sqrt[a+b z]))/(2 a b (Sqrt[c+d z])))+(((B c+A d) (Sqrt[c+d z]))/(2 c d (Sqrt[a+b z])))

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then

∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]])))dx  ⟶  ((A b+a B)/(2 a b))∫((Sqrt[a+b Sin[e+f x]])/(Sqrt[c+d Sin[e+f x]]))dx +((B c+A d)/(2 c d))∫((Sqrt[c+d Sin[e+f x]])/(Sqrt[a+b Sin[e+f x]]))dx

Program code:

Int[(A_.+B_.*sin[e_.+f_.*x_])/(Sqrt[a_+b_.*sin[e_.+f_.*x_]]*Sqrt[c_+d_.*sin[e_.+f_.*x_]]),x_Symbol] :=
  (A*b+a*B)/(2*a*b)*Int[Sqrt[a+b*Sin[e+f*x]]/Sqrt[c+d*Sin[e+f*x]],x] + 
  (B*c+A*d)/(2*c*d)*Int[Sqrt[c+d*Sin[e+f*x]]/Sqrt[a+b*Sin[e+f*x]],x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0]

2:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∉ℤ ∧ n∉ℤ ∧ A b (m+n+1)+a B (m-n)==0 ∧ m≠-(1/2)

Derivation: Algebraic expansion and doubly degenerate sine recurrence 1c with p->0 and A b (m+n+1)+a B (m-n)==0

Basis: A+B z==((A b-a B)/b)+((B (a+b z))/b)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ A b (m+n+1)+a B (m-n)==0 ∧ m∉ℤ ∧ m≠-(1/2), then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  -((B Cos[e+f x] (((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n))/(f (m+n+1)))

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(c_+d_.*sin[e_.+f_.*x_])^n_.*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -B*Cos[e+f*x]*(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^n/(f*(m+n+1)) /;
FreeQ[{a,b,c,d,e,f,A,B,m,n},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && EqQ[A*b*(m+n+1)+a*B*(m-n),0] && NeQ[m,-1/2]

2:  ∫(Sqrt[a+b Sin[e+f x]]) (((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0

Derivation: Algebraic expansion

Baisi: A+B z==((B (c+d z))/d)-((B c-A d)/d)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then

∫(Sqrt[a+b Sin[e+f x]]) (((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
(B/d)∫(Sqrt[a+b Sin[e+f x]]) (((c+d Sin[e+f x]))^(n+1))dx-((B c-A d)/d)∫(Sqrt[a+b Sin[e+f x]]) (((c+d Sin[e+f x]))^n)dx

Program code:

Int[Sqrt[a_.+b_.*sin[e_.+f_.*x_]]*(c_+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  B/d*Int[Sqrt[a+b*Sin[e+f*x]]*(c+d*Sin[e+f*x])^(n+1),x] - 
  (B*c-A*d)/d*Int[Sqrt[a+b*Sin[e+f*x]]*(c+d*Sin[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,A,B,n},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0]

3:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m<-(1/2)

Derivation: Algebraic expansion and doubly degenerate sine recurrence 1c with p->0

Basis: A+B z==((A b-a B)/b)+((B (a+b z))/b)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m<-(1/2), then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
(((A b-a B) Cos[e+f x] (((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n))/(a f(2 m+1)))+((a B (m-n)+A b (m+n+1))/(a b (2 m+1)))∫(((a+b Sin[e+f x]))^(m+1)) (((c+d Sin[e+f x]))^n)dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(c_+d_.*sin[e_.+f_.*x_])^n_.*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  (A*b-a*B)*Cos[e+f*x]*(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^n/(a*f*(2*m+1)) + 
  (a*B*(m-n)+A*b*(m+n+1))/(a*b*(2*m+1))*Int[(a+b*Sin[e+f*x])^(m+1)*(c+d*Sin[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,A,B,m,n},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && (LtQ[m,-1/2] || ILtQ[m+n,0] && Not[SumSimplerQ[n,1]]) && NeQ[2*m+1,0]

4:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m≮-(1/2)

Derivation: Algebraic expansion and doubly degenerate sine recurrence 1b with m->m+1,p->0

Basis: A+B z==((A b-a B)/b)+((B (a+b z))/b)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m≮-(1/2), then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
-((B Cos[e+f x] (((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n))/(f(m+n+1)))-((B c (m-n)-A d (m+n+1))/(d (m+n+1)))∫(((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n)dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_.*(c_+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -B*Cos[e+f*x]*(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^n/(f*(m+n+1)) - 
  (B*c*(m-n)-A*d*(m+n+1))/(d*(m+n+1))*Int[(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,A,B,m,n},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && Not[LtQ[m,-1/2]] && NeQ[m+n+1,0]

5.  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0

1:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m+n+2==0 ∧ A (a d m+b c (n+1))-B (a c m+b d (n+1))==0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m+n+2==0 ∧ A (a d m+b c (n+1))-B (a c m+b d (n+1))==0, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
(((B c-A d) Cos[e+f x] (((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^(n+1)))/(f (n+1)((c^2)-(d^2))))

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  (B*c-A*d)*Cos[e+f*x]*(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^(n+1)/(f*(n+1)*(c^2-d^2)) /;
FreeQ[{a,b,c,d,e,f,A,B,m,n},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && EqQ[m+n+2,0] && EqQ[A*(a*d*m+b*c*(n+1))-B*(a*c*m+b*d*(n+1)),0]

2.  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m>(1/2)

1:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m>(1/2) ∧ n<-1

Derivation: Singly degenerate sine recurrence 1a with p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m>(1/2) ∧ n<-1, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
-(((b^2) (B c-A d) Cos[e+f x] (((a+b Sin[e+f x]))^(m-1)) (((c+d Sin[e+f x]))^(n+1)))/(d f (n+1)(b c+a d)))-
(b/(d(n+1)(b c+a d)))∫(((a+b Sin[e+f x]))^(m-1)) (((c+d Sin[e+f x]))^(n+1))·
(a A d (m-n-2)-B (a c (m-1)+b d (n+1))-(A b d (m+n+1)-B (b c m-a d (n+1))) Sin[e+f x])dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -b^2*(B*c-A*d)*Cos[e+f*x]*(a+b*Sin[e+f*x])^(m-1)*(c+d*Sin[e+f*x])^(n+1)/(d*f*(n+1)*(b*c+a*d)) - 
  b/(d*(n+1)*(b*c+a*d))*Int[(a+b*Sin[e+f*x])^(m-1)*(c+d*Sin[e+f*x])^(n+1)*
    Simp[a*A*d*(m-n-2)-B*(a*c*(m-1)+b*d*(n+1))-(A*b*d*(m+n+1)-B*(b*c*m-a*d*(n+1)))*Sin[e+f*x],x],x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && GtQ[m,1/2] && LtQ[n,-1] && 
  IntegerQ[2*m] && (IntegerQ[2*n] || EqQ[c,0])

2:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m>(1/2) ∧ n≮-1

Derivation: Singly degenerate sine recurrence 1b with p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m>(1/2) ∧ n≮-1, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
-((b B Cos[e+f x] (((a+b Sin[e+f x]))^(m-1)) (((c+d Sin[e+f x]))^(n+1)))/(d f (m+n+1)))+
(1/(d (m+n+1)))∫(((a+b Sin[e+f x]))^(m-1)) (((c+d Sin[e+f x]))^n)·
(a A d (m+n+1)+B (a c (m-1)+b d (n+1))+(A b d (m+n+1)-B (b c m-a d (2 m+n))) Sin[e+f x])dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -b*B*Cos[e+f*x]*(a+b*Sin[e+f*x])^(m-1)*(c+d*Sin[e+f*x])^(n+1)/(d*f*(m+n+1)) + 
  1/(d*(m+n+1))*Int[(a+b*Sin[e+f*x])^(m-1)*(c+d*Sin[e+f*x])^n*
    Simp[a*A*d*(m+n+1)+B*(a*c*(m-1)+b*d*(n+1))+(A*b*d*(m+n+1)-B*(b*c*m-a*d*(2*m+n)))*Sin[e+f*x],x],x] /;
FreeQ[{a,b,c,d,e,f,A,B,n},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && GtQ[m,1/2] && Not[LtQ[n,-1]] && IntegerQ[2*m] && 
  (IntegerQ[2*n] || EqQ[c,0])

3.  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m<-(1/2)

1:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m<-(1/2) ∧ n>0

Derivation: Singly degenerate sine recurrence 2a with p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m<-(1/2) ∧ n>0, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
(((A b-a B) Cos[e+f x] (((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n))/(a f (2m+1)))-
(1/(a b (2m+1)))∫(((a+b Sin[e+f x]))^(m+1)) (((c+d Sin[e+f x]))^(n-1))·
(A (a d n-b c (m+1))-B (a c m+b d n)-d (a B (m-n)+A b (m+n+1)) Sin[e+f x])dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  (A*b-a*B)*Cos[e+f*x]*(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^n/(a*f*(2*m+1)) - 
  1/(a*b*(2*m+1))*Int[(a+b*Sin[e+f*x])^(m+1)*(c+d*Sin[e+f*x])^(n-1)*
    Simp[A*(a*d*n-b*c*(m+1))-B*(a*c*m+b*d*n)-d*(a*B*(m-n)+A*b*(m+n+1))*Sin[e+f*x],x],x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && LtQ[m,-1/2] && GtQ[n,0] && IntegerQ[2*m] && 
  (IntegerQ[2*n] || EqQ[c,0])

2:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m<-(1/2) ∧ n≯0

Derivation: Singly degenerate sine recurrence 2b with p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m<-(1/2) ∧ n≯0, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
((b (A b-a B) Cos[e+f x] (((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^(n+1)))/(a f (2 m+1)(b c-a d)))+
(1/(a(2 m+1)(b c-a d)))∫(((a+b Sin[e+f x]))^(m+1)) (((c+d Sin[e+f x]))^n)·
(B (a c m+b d (n+1))+A (b c (m+1)-a d (2 m+n+2))+d(A b-a B)(m+n+2) Sin[e+f x])dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  b*(A*b-a*B)*Cos[e+f*x]*(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^(n+1)/(a*f*(2*m+1)*(b*c-a*d)) + 
  1/(a*(2*m+1)*(b*c-a*d))*Int[(a+b*Sin[e+f*x])^(m+1)*(c+d*Sin[e+f*x])^n*
    Simp[B*(a*c*m+b*d*(n+1))+A*(b*c*(m+1)-a*d*(2*m+n+2))+d*(A*b-a*B)*(m+n+2)*Sin[e+f*x],x],x] /;
FreeQ[{a,b,c,d,e,f,A,B,n},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && LtQ[m,-1/2] && Not[GtQ[n,0]] && IntegerQ[2*m] && 
  (IntegerQ[2*n] || EqQ[c,0])

4.  ∫(Sqrt[a+b Sin[e+f x]])(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0

1:  ∫(Sqrt[a+b Sin[e+f x]])(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ A b d (2 n+3)-B (b c-2 a d (n+1))==0

Derivation: Singly degenerate sine recurrence 1a with B->-((A b (3+2 n))/(2 a (1+n))),m->(1/2),p->0

Derivation: Singly degenerate sine recurrence 1b with B->-((A b (3+2 n))/(2 a (1+n))),m->(1/2),p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ A b d (2 n+3)-B (b c-2 a d (n+1))==0, then

∫(Sqrt[a+b Sin[e+f x]])(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  -((2b B Cos[e+f x] (((c+d Sin[e+f x]))^(n+1)))/(d f (2n+3) (Sqrt[a+b Sin[e+f x]])))

Program code:

Int[Sqrt[a_+b_.*sin[e_.+f_.*x_]]*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -2*b*B*Cos[e+f*x]*(c+d*Sin[e+f*x])^(n+1)/(d*f*(2*n+3)*Sqrt[a+b*Sin[e+f*x]]) /;
FreeQ[{a,b,c,d,e,f,A,B,n},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && EqQ[A*b*d*(2*n+3)-B*(b*c-2*a*d*(n+1)),0]

2:  ∫(Sqrt[a+b Sin[e+f x]])(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ n<-1

Derivation: Singly degenerate sine recurrence 1a with m->(1/2),p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ n<-1, then

∫(Sqrt[a+b Sin[e+f x]])(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
-(((b^2) (B c-A d) Cos[e+f x] (((c+d Sin[e+f x]))^(n+1)))/(d f(n+1)(b c+a d)(Sqrt[a+b Sin[e+f x]])))+
((A b d (2 n+3)-B (b c-2 a d (n+1)))/(2d(n+1)(b c+a d)))∫(Sqrt[a+b Sin[e+f x]])(((c+d Sin[e+f x]))^(n+1))dx

Program code:

Int[Sqrt[a_+b_.*sin[e_.+f_.*x_]]*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -b^2*(B*c-A*d)*Cos[e+f*x]*(c+d*Sin[e+f*x])^(n+1)/(d*f*(n+1)*(b*c+a*d)*Sqrt[a+b*Sin[e+f*x]]) + 
  (A*b*d*(2*n+3)-B*(b*c-2*a*d*(n+1)))/(2*d*(n+1)*(b*c+a*d))*Int[Sqrt[a+b*Sin[e+f*x]]*(c+d*Sin[e+f*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && LtQ[n,-1]

3:  ∫(Sqrt[a+b Sin[e+f x]])(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ n≮-1

Derivation: Singly degenerate sine recurrence 1b with m->(1/2),p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ n≮-1, then

∫(Sqrt[a+b Sin[e+f x]])(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
-((2b B Cos[e+f x] (((c+d Sin[e+f x]))^(n+1)))/(d f (2n+3) (Sqrt[a+b Sin[e+f x]])))+
((A b d (2 n+3)-B (b c-2 a d (n+1)))/(b d (2n+3)))∫(Sqrt[a+b Sin[e+f x]])(((c+d Sin[e+f x]))^n)dx

Program code:

Int[Sqrt[a_+b_.*sin[e_.+f_.*x_]]*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -2*b*B*Cos[e+f*x]*(c+d*Sin[e+f*x])^(n+1)/(d*f*(2*n+3)*Sqrt[a+b*Sin[e+f*x]]) + 
  (A*b*d*(2*n+3)-B*(b*c-2*a*d*(n+1)))/(b*d*(2*n+3))*Int[Sqrt[a+b*Sin[e+f*x]]*(c+d*Sin[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,A,B,n},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && Not[LtQ[n,-1]]

5:  ∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Baisi: A+B z==((A b-a B)/b)+((B (a+b z))/b)

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0, then

∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]])))dx  ⟶  ((A b-a B)/b)∫(1/((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]])))dx+(B/b)∫((Sqrt[a+b Sin[e+f x]])/(Sqrt[c+d Sin[e+f x]]))dx

Program code:

Int[(A_.+B_.*sin[e_.+f_.*x_])/(Sqrt[a_+b_.*sin[e_.+f_.*x_]]*Sqrt[c_.+d_.*sin[e_.+f_.*x_]]),x_Symbol] :=
  (A*b-a*B)/b*Int[1/(Sqrt[a+b*Sin[e+f*x]]*Sqrt[c+d*Sin[e+f*x]]),x] + 
  B/b*Int[Sqrt[a+b*Sin[e+f*x]]/Sqrt[c+d*Sin[e+f*x]],x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

6:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ n>0

Derivation: Singly degenerate sine recurrence 2c with p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ n>0, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
-((B Cos[e+f x] (((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n))/(f (m+n+1)))+
(1/(b (m+n+1)))∫(((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^(n-1)) (A b c (m+n+1)+B (a c m+b d n)+(A b d (m+n+1)+B (a d m+b c n)) Sin[e+f x])dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -B*Cos[e+f*x]*(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^n/(f*(m+n+1)) + 
  1/(b*(m+n+1))*Int[(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^(n-1)*
    Simp[A*b*c*(m+n+1)+B*(a*c*m+b*d*n)+(A*b*d*(m+n+1)+B*(a*d*m+b*c*n))*Sin[e+f*x],x],x] /;
FreeQ[{a,b,c,d,e,f,A,B,m},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && GtQ[n,0] && (IntegerQ[n] || EqQ[m+1/2,0])

7:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ n<-1

Derivation: Singly degenerate sine recurrence 1c with p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ n<-1, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
(((B c-A d) Cos[e+f x] (((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^(n+1)))/(f (n+1)((c^2)-(d^2))))+
(1/(b (n+1)((c^2)-(d^2))))∫(((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^(n+1)) (A (a d m+b c (n+1))-B (a c m+b d (n+1))+b (B c-A d) (m+n+2) Sin[e+f x])dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  (B*c-A*d)*Cos[e+f*x]*(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^(n+1)/(f*(n+1)*(c^2-d^2)) + 
  1/(b*(n+1)*(c^2-d^2))*Int[(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^(n+1)*
    Simp[A*(a*d*m+b*c*(n+1))-B*(a*c*m+b*d*(n+1))+b*(B*c-A*d)*(m+n+2)*Sin[e+f*x],x],x] /;
FreeQ[{a,b,c,d,e,f,A,B,m},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && LtQ[n,-1] && (IntegerQ[n] || EqQ[m+1/2,0])

8.  ∫(((((a+b Sin[e+f x]))^m)(A+B Sin[e+f x]))/(c+d Sin[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0

1:  ∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]]) (c+d Sin[e+f x])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: ((A+B z)/((Sqrt[a+b z]) (c+d z)))==((A b-a B)/((b c-a d) (Sqrt[a+b z])))+(((B c-A d) (Sqrt[a+b z]))/((b c-a d) (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0, then

∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]]) (c+d Sin[e+f x])))dx  ⟶  ((A b-a B)/(b c-a d))∫(1/(Sqrt[a+b Sin[e+f x]]))dx+((B c-A d)/(b c-a d))∫((Sqrt[a+b Sin[e+f x]])/(c+d Sin[e+f x]))dx

Program code:

Int[(A_.+B_.*sin[e_.+f_.*x_])/(Sqrt[a_+b_.*sin[e_.+f_.*x_]]*(c_.+d_.*sin[e_.+f_.*x_])),x_Symbol] :=
  (A*b-a*B)/(b*c-a*d)*Int[1/Sqrt[a+b*Sin[e+f*x]],x] + 
  (B*c-A*d)/(b*c-a*d)*Int[Sqrt[a+b*Sin[e+f*x]]/(c+d*Sin[e+f*x]),x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

2:  ∫(((((a+b Sin[e+f x]))^m)(A+B Sin[e+f x]))/(c+d Sin[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m≠-(1/2)

Derivation: Algebraic expansion

Baisi: ((A+B z)/(c+d z))==(B/d)-((B c-A d)/(d (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ m≠-(1/2), then

∫(((((a+b Sin[e+f x]))^m)(A+B Sin[e+f x]))/(c+d Sin[e+f x]))dx  ⟶  (B/d)∫(((a+b Sin[e+f x]))^m)dx-((B c-A d)/d)∫((((a+b Sin[e+f x]))^m)/(c+d Sin[e+f x]))dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(A_.+B_.*sin[e_.+f_.*x_])/(c_.+d_.*sin[e_.+f_.*x_]),x_Symbol] :=
  B/d*Int[(a+b*Sin[e+f*x])^m,x] - (B*c-A*d)/d*Int[(a+b*Sin[e+f*x])^m/(c+d*Sin[e+f*x]),x] /;
FreeQ[{a,b,c,d,e,f,A,B,m},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && NeQ[m+1/2,0]

9:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Baisi: A+B z==((A b-a B)/b)+((B (a+b z))/b)

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
((A b-a B)/b)∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)dx+(B/b)∫(((a+b Sin[e+f x]))^(m+1))(((c+d Sin[e+f x]))^n)dx

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_.*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  (A*b-a*B)/b*Int[(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^n,x] + 
  B/b*Int[(a+b*Sin[e+f*x])^(m+1)*(c+d*Sin[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,A,B,m,n},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && NeQ[A*b+a*B,0]

6.  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

1.  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m>1

1.  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m>1 ∧ n<-1

1:  ∫(((a+b Sin[e+f x]))^2)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ n<-1

Derivation: Nondegenerate sine recurrence 1a with A->a A,B->A b+a B,C->b B,m->m-1,p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ n<-1, then

∫(((a+b Sin[e+f x]))^2)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
(((B c-A d) (((b c-a d))^2) Cos[e+f x] (((c+d Sin[e+f x]))^(n+1)))/(f (d^2) (n+1) ((c^2)-(d^2))))-
(1/((d^2) (n+1)((c^2)-(d^2))))∫(((c+d Sin[e+f x]))^(n+1))·
(d (n+1) (B (((b c-a d))^2)-A d ((a^2) c+(b^2) c-2 a b d))-
((B c-A d) ((a^2) (d^2) (n+2)+(b^2) ((c^2)+(d^2) (n+1)))+2 a b d (A c d (n+2)-B ((c^2)+(d^2) (n+1)))) Sin[e+f x]-
(b^2) B d (n+1) ((c^2)-(d^2)) ((Sin[e+f x])^2))dx

Program code:

Int[(a_.+b_.*sin[e_.+f_.*x_])^2*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  (B*c-A*d)*(b*c-a*d)^2*Cos[e+f*x]*(c+d*Sin[e+f*x])^(n+1)/(f*d^2*(n+1)*(c^2-d^2)) - 
  1/(d^2*(n+1)*(c^2-d^2))*Int[(c+d*Sin[e+f*x])^(n+1)*
    Simp[d*(n+1)*(B*(b*c-a*d)^2-A*d*(a^2*c+b^2*c-2*a*b*d))-
      ((B*c-A*d)*(a^2*d^2*(n+2)+b^2*(c^2+d^2*(n+1)))+2*a*b*d*(A*c*d*(n+2)-B*(c^2+d^2*(n+1))))*Sin[e+f*x]-
      b^2*B*d*(n+1)*(c^2-d^2)*Sin[e+f*x]^2,x],x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && LtQ[n,-1]

2:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m>1 ∧ n<-1

Derivation: Nondegenerate sine recurrence 1a with A->a A,B->A b+a B,C->b B,m->m-1,p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m>1 ∧ n<-1, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
-(((b c-a d) (B c-A d) Cos[e+f x] (((a+b Sin[e+f x]))^(m-1)) (((c+d Sin[e+f x]))^(n+1)))/(d f (n+1)((c^2)-(d^2))))+
(1/(d (n+1)((c^2)-(d^2))))∫(((a+b Sin[e+f x]))^(m-2)) (((c+d Sin[e+f x]))^(n+1))·
(b (b c-a d) (B c-A d) (m-1)+a d (a A c+b B c-(A b+a B) d) (n+1)+
(b (b d (B c-A d)+a (A c d+B ((c^2)-2 (d^2)))) (n+1)-a (b c-a d) (B c-A d) (n+2)) Sin[e+f x]+
b (d (A b c+a B c-a A d) (m+n+1)-b B ((c^2) m+(d^2) (n+1))) ((Sin[e+f x])^2))dx

Program code:

Int[(a_.+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -(b*c-a*d)*(B*c-A*d)*Cos[e+f*x]*(a+b*Sin[e+f*x])^(m-1)*(c+d*Sin[e+f*x])^(n+1)/(d*f*(n+1)*(c^2-d^2)) + 
  1/(d*(n+1)*(c^2-d^2))*Int[(a+b*Sin[e+f*x])^(m-2)*(c+d*Sin[e+f*x])^(n+1)*
    Simp[b*(b*c-a*d)*(B*c-A*d)*(m-1)+a*d*(a*A*c+b*B*c-(A*b+a*B)*d)*(n+1)+
      (b*(b*d*(B*c-A*d)+a*(A*c*d+B*(c^2-2*d^2)))*(n+1)-a*(b*c-a*d)*(B*c-A*d)*(n+2))*Sin[e+f*x]+
      b*(d*(A*b*c+a*B*c-a*A*d)*(m+n+1)-b*B*(c^2*m+d^2*(n+1)))*Sin[e+f*x]^2,x],x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && GtQ[m,1] && LtQ[n,-1]

2:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m>1 ∧ n≮-1

Derivation: Nondegenerate sine recurrence 1b with A->a A,B->A b+a B,C->b B,m->m-1,p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m>1 ∧ n≮-1, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
-((b B Cos[e+f x] (((a+b Sin[e+f x]))^(m-1)) (((c+d Sin[e+f x]))^(n+1)))/(d f (m+n+1)))+
(1/(d (m+n+1)))∫(((a+b Sin[e+f x]))^(m-2)) (((c+d Sin[e+f x]))^n)·
((a^2) A d (m+n+1)+b B (b c (m-1)+a d (n+1))+
(a d(2 A b+a B)(m+n+1)-b B (a c-b d (m+n))) Sin[e+f x]+
b (A b d (m+n+1)-B (b c m-a d (2 m+n))) ((Sin[e+f x])^2))dx

Program code:

Int[(a_.+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -b*B*Cos[e+f*x]*(a+b*Sin[e+f*x])^(m-1)*(c+d*Sin[e+f*x])^(n+1)/(d*f*(m+n+1)) + 
  1/(d*(m+n+1))*Int[(a+b*Sin[e+f*x])^(m-2)*(c+d*Sin[e+f*x])^n*
    Simp[a^2*A*d*(m+n+1)+b*B*(b*c*(m-1)+a*d*(n+1))+
      (a*d*(2*A*b+a*B)*(m+n+1)-b*B*(a*c-b*d*(m+n)))*Sin[e+f*x]+
      b*(A*b*d*(m+n+1)-B*(b*c*m-a*d*(2*m+n)))*Sin[e+f*x]^2,x],x] /;
FreeQ[{a,b,c,d,e,f,A,B,n},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && GtQ[m,1] && Not[IGtQ[n,1] && 
  (Not[IntegerQ[m]] || EqQ[a,0] && NeQ[c,0])]

2.  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m<-1

1.  ∫(((Sqrt[c+d Sin[e+f x]])(A+B Sin[e+f x]))/(((a+b Sin[e+f x]))^(3/2)))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

1:  ∫(((Sqrt[c+d Sin[e+f x]])(A+B Sin[e+f x]))/(((b Sin[e+f x]))^(3/2)))dx  when  (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: (((A+B z) (Sqrt[c+d z]))/(((b z))^(3/2)))==((B d (Sqrt[b z]))/((b^2) (Sqrt[c+d z])))+((A c+(B c+A d) z)/((((b z))^(3/2)) (Sqrt[c+d z])))

Rule: If  b c-a d≠0 ∧ (c^2)-(d^2)≠0, then

∫(((Sqrt[c+d Sin[e+f x]])(A+B Sin[e+f x]))/(((b Sin[e+f x]))^(3/2)))dx  ⟶  ((B d)/(b^2))∫((Sqrt[b Sin[e+f x]])/(Sqrt[c+d Sin[e+f x]]))dx+∫((A c+(B c+A d) Sin[e+f x])/((((b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx

Program code:

Int[Sqrt[c_+d_.*sin[e_.+f_.*x_]]*(A_.+B_.*sin[e_.+f_.*x_])/(b_.*sin[e_.+f_.*x_])^(3/2),x_Symbol] :=
  B*d/b^2*Int[Sqrt[b*Sin[e+f*x]]/Sqrt[c+d*Sin[e+f*x]],x] + 
  Int[(A*c+(B*c+A*d)*Sin[e+f*x])/((b*Sin[e+f*x])^(3/2)*Sqrt[c+d*Sin[e+f*x]]),x] /;
FreeQ[{b,c,d,e,f,A,B},x] && NeQ[c^2-d^2,0]

2:  ∫(((Sqrt[c+d Sin[e+f x]])(A+B Sin[e+f x]))/(((a+b Sin[e+f x]))^(3/2)))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: ((A+B z)/(a+b z))==(B/b)+((A b-a B)/(b (a+b z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫(((Sqrt[c+d Sin[e+f x]])(A+B Sin[e+f x]))/(((a+b Sin[e+f x]))^(3/2)))dx  ⟶  (B/b)∫((Sqrt[c+d Sin[e+f x]])/(Sqrt[a+b Sin[e+f x]]))dx+((A b-a B)/b)∫((Sqrt[c+d Sin[e+f x]])/(((a+b Sin[e+f x]))^(3/2)))dx

Program code:

Int[Sqrt[c_.+d_.*sin[e_.+f_.*x_]]*(A_.+B_.*sin[e_.+f_.*x_])/(a_+b_.*sin[e_.+f_.*x_])^(3/2),x_Symbol] :=
  B/b*Int[Sqrt[c+d*Sin[e+f*x]]/Sqrt[a+b*Sin[e+f*x]],x] + 
  (A*b-a*B)/b*Int[Sqrt[c+d*Sin[e+f*x]]/(a+b*Sin[e+f*x])^(3/2),x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

2.  ∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

1:  ∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[d Sin[e+f x]])))dx  when  (a^2)-(b^2)≠0

Derivation: Nondegenerate sine recurrence 1a with c->0,C->0,m->-(3/2),n->-(1/2),p->0

Rule: If  (a^2)-(b^2)≠0, then

∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[d Sin[e+f x]])))dx  ⟶  ((2 (A b-a B) Cos[e+f x])/(f((a^2)-(b^2)) (Sqrt[a+b Sin[e+f x]])(Sqrt[d Sin[e+f x]])))+(d/(((a^2)-(b^2))))∫((A b-a B+(a A-b B) Sin[e+f x])/((Sqrt[a+b Sin[e+f x]])(((d Sin[e+f x]))^(3/2))))dx

Program code:

Int[(A_.+B_.*sin[e_.+f_.*x_])/((a_+b_.*sin[e_.+f_.*x_])^(3/2)*Sqrt[d_.*sin[e_.+f_.*x_]]),x_Symbol] :=
  2*(A*b-a*B)*Cos[e+f*x]/(f*(a^2-b^2)*Sqrt[a+b*Sin[e+f*x]]*Sqrt[d*Sin[e+f*x]]) + 
  d/(a^2-b^2)*Int[(A*b-a*B+(a*A-b*B)*Sin[e+f*x])/(Sqrt[a+b*Sin[e+f*x]]*(d*Sin[e+f*x])^(3/2)),x] /;
FreeQ[{a,b,d,e,f,A,B},x] && NeQ[a^2-b^2,0]

2.  ∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

1.  ∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ A==B

1.  ∫((A+B Sin[e+f x])/((((b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  when  (c^2)-(d^2)≠0 ∧ A==B

1:  ∫((A+B Sin[e+f x])/((((b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  when  (c^2)-(d^2)≠0 ∧ A==B ∧ ((c+d)/b)>0

Rule: If  (c^2)-(d^2)≠0 ∧ A==B ∧ ((c+d)/b)>0, then

∫((A+B Sin[e+f x])/((((b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  ⟶  
-((2A(c-d)Tan[e+f x])/(f b (c^2)))(Sqrt[((c+d)/b)])(Sqrt[((c (1+Csc[e+f x]))/(c-d))])(Sqrt[((c (1-Csc[e+f x]))/(c+d))])EllipticE[ArcSin[((Sqrt[c+d Sin[e+f x]])/(Sqrt[b Sin[e+f x]]))/(Sqrt[((c+d)/b)])],-((c+d)/(c-d))]

Program code:

Int[(A_+B_.*sin[e_.+f_.*x_])/((b_.*sin[e_.+f_.*x_])^(3/2)*Sqrt[c_+d_.*sin[e_.+f_.*x_]]),x_Symbol] :=
  -2*A*(c-d)*Tan[e+f*x]/(f*b*c^2)*Rt[(c+d)/b,2]*Sqrt[c*(1+Csc[e+f*x])/(c-d)]*Sqrt[c*(1-Csc[e+f*x])/(c+d)]*
    EllipticE[ArcSin[Sqrt[c+d*Sin[e+f*x]]/Sqrt[b*Sin[e+f*x]]/Rt[(c+d)/b,2]],-(c+d)/(c-d)] /;
FreeQ[{b,c,d,e,f,A,B},x] && NeQ[c^2-d^2,0] && EqQ[A,B] && PosQ[(c+d)/b]

2:  ∫((A+B Sin[e+f x])/((((b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  when  (c^2)-(d^2)≠0 ∧ A==B ∧ ((c+d)/b)≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[-F[x]])/(Sqrt[F[x]]))==0

Rule: If  (c^2)-(d^2)≠0 ∧ A==B ∧ ((c+d)/b)≯0, then

∫((A+B Sin[e+f x])/((((b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  ⟶  -((Sqrt[-b Sin[e+f x]])/(Sqrt[b Sin[e+f x]]))∫((A+B Sin[e+f x])/((((-b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx

Program code:

Int[(A_+B_.*sin[e_.+f_.*x_])/((b_.*sin[e_.+f_.*x_])^(3/2)*Sqrt[c_+d_.*sin[e_.+f_.*x_]]),x_Symbol] :=
  -Sqrt[-b*Sin[e+f*x]]/Sqrt[b*Sin[e+f*x]]*Int[(A+B*Sin[e+f*x])/((-b*Sin[e+f*x])^(3/2)*Sqrt[c+d*Sin[e+f*x]]),x] /;
FreeQ[{b,c,d,e,f,A,B},x] && NeQ[c^2-d^2,0] && EqQ[A,B] && NegQ[(c+d)/b]

2.  ∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ A==B

1:  ∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ A==B ∧ ((a+b)/(c+d))>0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ A==B ∧ ((a+b)/(c+d))>0, then

∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  ⟶  
-((2A(c-d)(a+b Sin[e+f x]))/(f(((b c-a d))^2)(Sqrt[((a+b)/(c+d))]) Cos[e+f x]))(Sqrt[(((b c-a d) (1+Sin[e+f x]))/((c-d) (a+b Sin[e+f x])))])(Sqrt[-(((b c-a d) (1-Sin[e+f x]))/((c+d) (a+b Sin[e+f x])))])EllipticE[ArcSin[(Sqrt[((a+b)/(c+d))])((Sqrt[c+d Sin[e+f x]])/(Sqrt[a+b Sin[e+f x]]))],(((a-b) (c+d))/((a+b) (c-d)))]

Program code:

Int[(A_+B_.*sin[e_.+f_.*x_])/((a_+b_.*sin[e_.+f_.*x_])^(3/2)*Sqrt[c_+d_.*sin[e_.+f_.*x_]]),x_Symbol] :=
  -2*A*(c-d)*(a+b*Sin[e+f*x])/(f*(b*c-a*d)^2*Rt[(a+b)/(c+d),2]*Cos[e+f*x])*
    Sqrt[(b*c-a*d)*(1+Sin[e+f*x])/((c-d)*(a+b*Sin[e+f*x]))]*
    Sqrt[-(b*c-a*d)*(1-Sin[e+f*x])/((c+d)*(a+b*Sin[e+f*x]))]*
    EllipticE[ArcSin[Rt[(a+b)/(c+d),2]*Sqrt[c+d*Sin[e+f*x]]/Sqrt[a+b*Sin[e+f*x]]],(a-b)*(c+d)/((a+b)*(c-d))] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && EqQ[A,B] && PosQ[(a+b)/(c+d)]

2:  ∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ A==B ∧ ((a+b)/(c+d))≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[-F[x]])/(Sqrt[F[x]]))==0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ A==B ∧ ((a+b)/(c+d))≯0, then

∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  ⟶  ((Sqrt[-c-d Sin[e+f x]])/(Sqrt[c+d Sin[e+f x]]))∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[-c-d Sin[e+f x]])))dx

Program code:

Int[(A_+B_.*sin[e_.+f_.*x_])/((a_+b_.*sin[e_.+f_.*x_])^(3/2)*Sqrt[c_+d_.*sin[e_.+f_.*x_]]),x_Symbol] :=
  Sqrt[-c-d*Sin[e+f*x]]/Sqrt[c+d*Sin[e+f*x]]*Int[(A+B*Sin[e+f*x])/((a+b*Sin[e+f*x])^(3/2)*Sqrt[-c-d*Sin[e+f*x]]),x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && EqQ[A,B] && NegQ[(a+b)/(c+d)]

2:  ∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ A≠B

Derivation: Algebraic expansion

Basis: ((A+B z)/(((a+b z))^(3/2)))==((A-B)/((a-b) (Sqrt[a+b z])))-(((A b-a B) (1+z))/((a-b) (((a+b z))^(3/2))))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ A≠B, then

∫((A+B Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx  ⟶  
((A-B)/(a-b))∫(1/((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]])))dx-((A b-a B)/(a-b))∫((1+Sin[e+f x])/((((a+b Sin[e+f x]))^(3/2)) (Sqrt[c+d Sin[e+f x]])))dx

Program code:

Int[(A_.+B_.*sin[e_.+f_.*x_])/((a_.+b_.*sin[e_.+f_.*x_])^(3/2)*Sqrt[c_+d_.*sin[e_.+f_.*x_]]),x_Symbol] :=
  (A-B)/(a-b)*Int[1/(Sqrt[a+b*Sin[e+f*x]]*Sqrt[c+d*Sin[e+f*x]]),x] - 
  (A*b-a*B)/(a-b)*Int[(1+Sin[e+f*x])/((a+b*Sin[e+f*x])^(3/2)*Sqrt[c+d*Sin[e+f*x]]),x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && NeQ[A,B]

3.  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m<-1

1:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m<-1 ∧ n>0

Derivation: Nondegenerate sine recurrence 1a with C->0,p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m<-1 ∧ n>0, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
(((B a-A b) Cos[e+f x] (((a+b Sin[e+f x]))^(m+1)) (((c+d Sin[e+f x]))^n))/(f (m+1)((a^2)-(b^2))))+
(1/((m+1)((a^2)-(b^2))))∫(((a+b Sin[e+f x]))^(m+1)) (((c+d Sin[e+f x]))^(n-1))·
(c(a A-b B) (m+1)+d n(A b-a B)+(d(a A-b B) (m+1)-c(A b-a B)(m+2)) Sin[e+f x]-d(A b-a B) (m+n+2) ((Sin[e+f x])^2))dx

Program code:

Int[(a_.+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  (B*a-A*b)*Cos[e+f*x]*(a+b*Sin[e+f*x])^(m+1)*(c+d*Sin[e+f*x])^n/(f*(m+1)*(a^2-b^2)) + 
  1/((m+1)*(a^2-b^2))*Int[(a+b*Sin[e+f*x])^(m+1)*(c+d*Sin[e+f*x])^(n-1)*
    Simp[c*(a*A-b*B)*(m+1)+d*n*(A*b-a*B)+(d*(a*A-b*B)*(m+1)-c*(A*b-a*B)*(m+2))*Sin[e+f*x]-d*(A*b-a*B)*(m+n+2)*Sin[e+f*x]^2,x],x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && LtQ[m,-1] && GtQ[n,0]

2:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m<-1 ∧ n≯0

Derivation: Nondegenerate sine recurrence 1c with C->0,p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ m<-1 ∧ n≯0, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
-((b(A b-a B) Cos[e+f x] (((a+b Sin[e+f x]))^(m+1)) (((c+d Sin[e+f x]))^(n+1)))/(f (m+1)(b c-a d)((a^2)-(b^2))))+
(1/((m+1)(b c-a d)((a^2)-(b^2))))∫(((a+b Sin[e+f x]))^(m+1)) (((c+d Sin[e+f x]))^n)·
((a A-b B) (b c-a d) (m+1)+b d(A b-a B)(m+n+2)+(A b-a B) (a d (m+1)-b c (m+2)) Sin[e+f x]-b d(A b-a B)(m+n+3) ((Sin[e+f x])^2))dx

Program code:

Int[(a_.+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -(A*b^2-a*b*B)*Cos[e+f*x]*(a+b*Sin[e+f*x])^(m+1)*(c+d*Sin[e+f*x])^(1+n)/(f*(m+1)*(b*c-a*d)*(a^2-b^2)) + 
  1/((m+1)*(b*c-a*d)*(a^2-b^2))*Int[(a+b*Sin[e+f*x])^(m+1)*(c+d*Sin[e+f*x])^n*
    Simp[(a*A-b*B)*(b*c-a*d)*(m+1)+b*d*(A*b-a*B)*(m+n+2)+
      (A*b-a*B)*(a*d*(m+1)-b*c*(m+2))*Sin[e+f*x]-
      b*d*(A*b-a*B)*(m+n+3)*Sin[e+f*x]^2,x],x] /;
FreeQ[{a,b,c,d,e,f,A,B,n},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && RationalQ[m] && m<-1 && 
  (EqQ[a,0] && IntegerQ[m] && Not[IntegerQ[n]] || Not[IntegerQ[2*n] && LtQ[n,-1] && (IntegerQ[n] && Not[IntegerQ[m]] || EqQ[a,0])])

3.  ∫(((((a+b Sin[e+f x]))^m)(A+B Sin[e+f x]))/(c+d Sin[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

1:  ∫((A+B Sin[e+f x])/((a+b Sin[e+f x])(c+d Sin[e+f x])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: ((A+B z)/((a+b z) (c+d z)))==((A b-a B)/((b c-a d) (a+b z)))+((B c-A d)/((b c-a d) (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫((A+B Sin[e+f x])/((a+b Sin[e+f x])(c+d Sin[e+f x])))dx  ⟶  ((A b-a B)/(b c-a d))∫(1/(a+b Sin[e+f x]))dx+((B c-A d)/(b c-a d))∫(1/(c+d Sin[e+f x]))dx

Program code:

Int[(A_.+B_.*sin[e_.+f_.*x_])/((a_.+b_.*sin[e_.+f_.*x_])*(c_.+d_.*sin[e_.+f_.*x_])),x_Symbol] :=
  (A*b-a*B)/(b*c-a*d)*Int[1/(a+b*Sin[e+f*x]),x] + (B*c-A*d)/(b*c-a*d)*Int[1/(c+d*Sin[e+f*x]),x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

2:  ∫(((((a+b Sin[e+f x]))^m)(A+B Sin[e+f x]))/(c+d Sin[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: ((A+B z)/(c+d z))==(B/d)-((B c-A d)/(d (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫(((((a+b Sin[e+f x]))^m)(A+B Sin[e+f x]))/(c+d Sin[e+f x]))dx  ⟶ (B/d) ∫(((a+b Sin[e+f x]))^m)dx-((B c-A d)/d)∫((((a+b Sin[e+f x]))^m)/(c+d Sin[e+f x]))dx

Program code:

Int[(a_.+b_.*sin[e_.+f_.*x_])^m_*(A_.+B_.*sin[e_.+f_.*x_])/(c_.+d_.*sin[e_.+f_.*x_]),x_Symbol] :=
  B/d*Int[(a+b*Sin[e+f*x])^m,x] - (B*c-A*d)/d*Int[(a+b*Sin[e+f*x])^m/(c+d*Sin[e+f*x]),x] /;
FreeQ[{a,b,c,d,e,f,A,B,m},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

4:  ∫(Sqrt[a+b Sin[e+f x]]) (((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ (n^2)==(1/4)

Derivation:  Nondegenerate sine recurrence 1b with A->A c,B->B c+A d,C->B d,n->n-1,p->0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ (n^2)==(1/4), then

∫(Sqrt[a+b Sin[e+f x]]) (((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  
-((2 B Cos[e+f x] (Sqrt[a+b Sin[e+f x]]) (((c+d Sin[e+f x]))^n))/(f (2 n+3)))+(1/(2 n+3))∫((((c+d Sin[e+f x]))^(n-1))/(Sqrt[a+b Sin[e+f x]]))·
(a A c (2 n+3)+B (b c+2 a d n)+(B (a c+b d) (2 n+1)+A (b c+a d) (2 n+3)) Sin[e+f x]+(A b d (2 n+3)+B (a d+2 b c n)) ((Sin[e+f x])^2))dx

Program code:

Int[Sqrt[a_.+b_.*sin[e_.+f_.*x_]]*(c_.+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  -2*B*Cos[e+f*x]*Sqrt[a+b*Sin[e+f*x]]*(c+d*Sin[e+f*x])^n/(f*(2*n+3)) + 
  1/(2*n+3)*Int[(c+d*Sin[e+f*x])^(n-1)/Sqrt[a+b*Sin[e+f*x]]*
    Simp[a*A*c*(2*n+3)+B*(b*c+2*a*d*n)+
      (B*(a*c+b*d)*(2*n+1)+A*(b*c+a*d)*(2*n+3))*Sin[e+f*x]+
      (A*b*d*(2*n+3)+B*(a*d+2*b*c*n))*Sin[e+f*x]^2,x],x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && EqQ[n^2,1/4]

5.  ∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

1.  ∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]])(Sqrt[d Sin[e+f x]])))dx  when  b>0 ∧ (b^2)-(a^2)>0 ∧ A==B

1:  ∫((A+B Sin[e+f x])/((Sqrt[Sin[e+f x]]) (Sqrt[a+b Sin[e+f x]])))dx  when  b>0 ∧ (b^2)-(a^2)>0 ∧ A==B

Derivation: Algebraic expansion

Basis: If  b>0 ∧ b-a>0, then (Sqrt[a+b z])=(Sqrt[1+z]) (Sqrt[((a+b z)/(1+z))])

Rule: If  b>0 ∧ (b^2)-(a^2)>0 ∧ A==B, then

∫((A+B Sin[e+f x])/((Sqrt[Sin[e+f x]]) (Sqrt[a+b Sin[e+f x]])))dx  ⟶  ((4A)/(f(Sqrt[a+b])))EllipticPi[-1,-ArcSin[((Cos[e+f x])/(1+Sin[e+f x]))],-((a-b)/(a+b))]

Program code:

Int[(A_+B_.*sin[e_.+f_.*x_])/(Sqrt[sin[e_.+f_.*x_]]*Sqrt[a_+b_.*sin[e_.+f_.*x_]]),x_Symbol] :=
  4*A/(f*Sqrt[a+b])*EllipticPi[-1,-ArcSin[Cos[e+f*x]/(1+Sin[e+f*x])],-(a-b)/(a+b)] /;
FreeQ[{a,b,e,f,A,B},x] && GtQ[b,0] && GtQ[b^2-a^2,0] && EqQ[A,B]

2:  ∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]])(Sqrt[d Sin[e+f x]])))dx  when  b>0 ∧ (b^2)-(a^2)>0 ∧ A==B

Derivation: Piecewise constant extraction

Basis: (∂_z)((Sqrt[f[z]])/(Sqrt[d f[z]]))==0

Rule: If  (a^2)-(b^2)≠0 ∧ A==B, then

∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]])(Sqrt[d Sin[e+f x]])))dx  ⟶  ((Sqrt[Sin[e+f x]])/(Sqrt[d Sin[e+f x]]))∫((A+B Sin[e+f x])/((Sqrt[Sin[e+f x]]) (Sqrt[a+b Sin[e+f x]])))dx

Program code:

Int[(A_+B_.*sin[e_.+f_.*x_])/(Sqrt[a_+b_.*sin[e_.+f_.*x_]]*Sqrt[d_*sin[e_.+f_.*x_]]),x_Symbol] :=
  Sqrt[Sin[e+f*x]]/Sqrt[d*Sin[e+f*x]]*Int[(A+B*Sin[e+f*x])/(Sqrt[Sin[e+f*x]]*Sqrt[a+b*Sin[e+f*x]]),x] /;
FreeQ[{a,b,e,f,d,A,B},x] && GtQ[b,0] && GtQ[b^2-a^2,0] && EqQ[A,B]

2:  ∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: ((A+B z)/(Sqrt[c+d z]))==((B(Sqrt[c+d z]))/d)-((B c-A d)/(d (Sqrt[c+d z])))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫((A+B Sin[e+f x])/((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]])))dx  ⟶  (B/d)∫((Sqrt[c+d Sin[e+f x]])/(Sqrt[a+b Sin[e+f x]]))dx-((B c-A d)/d)∫(1/((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]])))dx

Program code:

Int[(A_.+B_.*sin[e_.+f_.*x_])/(Sqrt[a_+b_.*sin[e_.+f_.*x_]]*Sqrt[c_.+d_.*sin[e_.+f_.*x_]]),x_Symbol] :=
  B/d*Int[Sqrt[c+d*Sin[e+f*x]]/Sqrt[a+b*Sin[e+f*x]],x] - 
  (B*c-A*d)/d*Int[1/(Sqrt[a+b*Sin[e+f*x]]*Sqrt[c+d*Sin[e+f*x]]),x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

X:  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx  ⟶  ∫(((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(A+B Sin[e+f x])dx

Program code:

Int[(a_.+b_.*sin[e_.+f_.*x_])^m_*(c_.+d_.*sin[e_.+f_.*x_])^n_.*(A_.+B_.*sin[e_.+f_.*x_]),x_Symbol] :=
  Unintegrable[(a+b*Sin[e+f*x])^m*(c+d*Sin[e+f*x])^n*(A+B*Sin[e+f*x]),x] /;
FreeQ[{a,b,c,d,e,f,A,B,m,n},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

Rules for integrands of the form (((a+b Sin[e+f x]))^m)(((c+d Sin[e+f x]))^n)(((A+B Sin[e+f x]))^p)

x:  ∫(((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n)(((A+B Sin[e+f x]))^p)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∈ℤ

Derivation: Algebraic simplification

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then (a+b Sin[z]) (c+d Sin[z])==a c ((Cos[z])^2)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∈ℤ, then

∫(((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n)(((A+B Sin[e+f x]))^p)dx  ⟶  (a^m) (c^m)∫((Cos[e+f x])^(2m)) (((c+d Sin[e+f x]))^(n-m))(((A+B Sin[e+f x]))^p)dx

Program code:

(* Int[(a_+b_.*sin[e_.+f_.*x_])^m_*(c_+d_.*sin[e_.+f_.*x_])^n_*(A_.+B_.*sin[e_.+f_.*x_])^p_,x_Symbol] :=
  a^m*c^m*Int[Cos[e+f*x]^(2*m)*(c+d*Sin[e+f*x])^(n-m)*(A+B*Sin[e+f*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,A,B,n,p},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IntegerQ[m] && 
  Not[IntegerQ[n] && (LtQ[m,0] && GtQ[n,0] || LtQ[0,n,m] || LtQ[m,n,0])] *)

(* Int[(a_+b_.*cos[e_.+f_.*x_])^m_*(c_+d_.*cos[e_.+f_.*x_])^n_*(A_.+B_.*cos[e_.+f_.*x_])^p_,x_Symbol] :=
  a^m*c^m*Int[Sin[e+f*x]^(2*m)*(c+d*Cos[e+f*x])^(n-m)*(A+B*Cos[e+f*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,A,B,n,p},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IntegerQ[m] && 
  Not[IntegerQ[n] && (LtQ[m,0] && GtQ[n,0] || LtQ[0,n,m] || LtQ[m,n,0])] *)

2:  ∫(((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n) (((A+B Sin[e+f x]))^p)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∉ℤ ∧ n∉ℤ ∧ p∉ℤ

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then (∂_x)(((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]]))/(Cos[e+f x]))==0

Basis: Cos[e+f x]==(1/f)(∂_x)Sin[e+f x]

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∉ℤ ∧ n∉ℤ, then

∫(((a+b Sin[e+f x]))^m) (((c+d Sin[e+f x]))^n) (((A+B Sin[e+f x]))^p)dx  ⟶  

(((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]]))/(Cos[e+f x]))∫Cos[e+f x] (((a+b Sin[e+f x]))^(m-(1/2))) (((c+d Sin[e+f x]))^(n-(1/2))) (((A+B Sin[e+f x]))^p)dx  ⟶  

(((Sqrt[a+b Sin[e+f x]]) (Sqrt[c+d Sin[e+f x]]))/(f Cos[e+f x]))Subst[∫(((a+b x))^(m-(1/2))) (((c+d x))^(n-(1/2))) (((A+B x))^p)dx,x,Sin[e+f x]]

Program code:

Int[(a_+b_.*sin[e_.+f_.*x_])^m_.*(c_+d_.*sin[e_.+f_.*x_])^n_.*(A_.+B_.*sin[e_.+f_.*x_])^p_,x_Symbol] :=
  Sqrt[a+b*Sin[e+f*x]]*Sqrt[c+d*Sin[e+f*x]]/(f*Cos[e+f*x])*
    Subst[Int[(a+b*x)^(m-1/2)*(c+d*x)^(n-1/2)*(A+B*x)^p,x],x,Sin[e+f*x]] /;
FreeQ[{a,b,c,d,e,f,A,B,m,n,p},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0]

Int[(a_+b_.*cos[e_.+f_.*x_])^m_.*(c_+d_.*cos[e_.+f_.*x_])^n_.*(A_.+B_.*cos[e_.+f_.*x_])^p_,x_Symbol] :=
  -Sqrt[a+b*Cos[e+f*x]]*Sqrt[c+d*Cos[e+f*x]]/(f*Sin[e+f*x])*
    Subst[Int[(a+b*x)^(m-1/2)*(c+d*x)^(n-1/2)*(A+B*x)^p,x],x,Cos[e+f*x]] /;
FreeQ[{a,b,c,d,e,f,A,B,m,n,p},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0]