Rules for integrands of the form (((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)

1.  ∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0

1.  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0

1.  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m+n∈(SuperMinus[ℤ])

1:  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m+n+1==0 ∧ m≠-(1/2)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m+n+1==0 ∧ m≠-(1/2), then

∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  -((b Tan[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n))/(a f (2 m+1)))

Program code:

Int[csc[e_.+f_.*x_]*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_.,x_Symbol] :=
  b*Cot[e+f*x]*(a+b*Csc[e+f*x])^m*(c+d*Csc[e+f*x])^n/(a*f*(2*m+1)) /;
FreeQ[{a,b,c,d,e,f,m,n},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && EqQ[m+n+1,0] && NeQ[2*m+1,0]

2:  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m+n+1∈(SuperMinus[ℤ])∧ m≠-(1/2)

Note: If  n+(1/2)∈(SuperPlus[ℤ])∧ n+(1/2)<-(m+n), then it is better to drive n to (1/2) in n-(1/2) steps.

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m+n+1∈(SuperMinus[ℤ])∧ m≠-(1/2), then

∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  

-((b Tan[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n))/(a f (2 m+1)))+(((m+n+1))/(a (2 m+1)))∫Sec[e+f x] (((a+b Sec[e+f x]))^(m+1)) (((c+d Sec[e+f x]))^n) dx

Program code:

Int[csc[e_.+f_.*x_]*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_.,x_Symbol] :=
  b*Cot[e+f*x]*(a+b*Csc[e+f*x])^m*(c+d*Csc[e+f*x])^n/(a*f*(2*m+1)) + 
  (m+n+1)/(a*(2*m+1))*Int[Csc[e+f*x]*(a+b*Csc[e+f*x])^(m+1)*(c+d*Csc[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && ILtQ[m+n+1,0] && NeQ[2*m+1,0] && Not[LtQ[n,0]] && 
  Not[IGtQ[n+1/2,0] && LtQ[n+1/2,-(m+n)]]

2.  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m+(1/2)∈(SuperPlus[ℤ])

1.  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (Sqrt[c+d Sec[e+f x]])dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0

1:  ∫((Sec[e+f x] (Sqrt[c+d Sec[e+f x]]))/(Sqrt[a+b Sec[e+f x]]))dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then

∫((Sec[e+f x] (Sqrt[c+d Sec[e+f x]]))/(Sqrt[a+b Sec[e+f x]]))dx  ⟶  -((a c Log[1+(b/a) Sec[e+f x]] Tan[e+f x])/(b f (Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))

Program code:

Int[csc[e_.+f_.*x_]*Sqrt[c_+d_.*csc[e_.+f_.*x_]]/Sqrt[a_+b_.*csc[e_.+f_.*x_]],x_Symbol] :=
  a*c*Log[1+b/a*Csc[e+f*x]]*Cot[e+f*x]/(b*f*Sqrt[a+b*Csc[e+f*x]]*Sqrt[c+d*Csc[e+f*x]]) /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0]

2:  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (Sqrt[c+d Sec[e+f x]])dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m≠-(1/2)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m≠-(1/2), then

∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (Sqrt[c+d Sec[e+f x]])dx  ⟶  -((2 a c Tan[e+f x] (((a+b Sec[e+f x]))^m))/(b f (2 m+1) (Sqrt[c+d Sec[e+f x]])))

Program code:

Int[csc[e_.+f_.*x_]*(a_+b_.*csc[e_.+f_.*x_])^m_.*Sqrt[c_+d_.*csc[e_.+f_.*x_]],x_Symbol] :=
  2*a*c*Cot[e+f*x]*(a+b*Csc[e+f*x])^m/(b*f*(2*m+1)*Sqrt[c+d*Csc[e+f*x]]) /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && NeQ[m,-1/2]

2.  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m-(1/2)∈(SuperPlus[ℤ])

1:  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ n-(1/2)∈(SuperPlus[ℤ])∧ m<-(1/2)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ n-(1/2)∈(SuperPlus[ℤ])∧ m<-(1/2), then

∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  

-((2 a c Tan[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^(n-1)))/(b f (2 m+1)))-(( d (2n-1))/(b (2 m+1)))∫Sec[e+f x] (((a+b Sec[e+f x]))^(m+1)) (((c+d Sec[e+f x]))^(n-1))dx

Program code:

Int[csc[e_.+f_.*x_]*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_.,x_Symbol] :=
  2*a*c*Cot[e+f*x]*(a+b*Csc[e+f*x])^m*(c+d*Csc[e+f*x])^(n-1)/(b*f*(2*m+1)) - 
  d*(2*n-1)/(b*(2*m+1))*Int[Csc[e+f*x]*(a+b*Csc[e+f*x])^(m+1)*(c+d*Csc[e+f*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IGtQ[n-1/2,0] && LtQ[m,-1/2]

2:  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ n-(1/2)∈(SuperPlus[ℤ])∧ m≮-(1/2)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ n-(1/2)∈(SuperPlus[ℤ])∧ m≮-(1/2), then

∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n) dx  ⟶  

((d Tan[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^(n-1)))/(f (m+n)))+((c (2 n-1))/(m+n))∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^(n-1))dx

Program code:

Int[csc[e_.+f_.*x_]*(a_+b_.*csc[e_.+f_.*x_])^m_.*(c_+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  -d*Cot[e+f*x]*(a+b*Csc[e+f*x])^m*(c+d*Csc[e+f*x])^(n-1)/(f*(m+n)) + 
  c*(2*n-1)/(m+n)*Int[Csc[e+f*x]*(a+b*Csc[e+f*x])^m*(c+d*Csc[e+f*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IGtQ[n-1/2,0] && Not[LtQ[m,-1/2]] && Not[IGtQ[m-1/2,0] && LtQ[m,n]]

3.  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ n∈(SuperPlus[ℤ])∧ m<0

1:  ∫((Sec[e+f x] (((c+d Sec[e+f x]))^n))/(Sqrt[a+b Sec[e+f x]]))dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ n∈(SuperPlus[ℤ])

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ n∈(SuperPlus[ℤ]), then

∫((Sec[e+f x] (((c+d Sec[e+f x]))^n))/(Sqrt[a+b Sec[e+f x]])) dx  ⟶  
((2 d Tan[e+f x] (((c+d Sec[e+f x]))^(n-1)))/(f (2 n-1) (Sqrt[a+b Sec[e+f x]])))+((2 c (2 n-1))/(2 n-1))∫((Sec[e+f x] (((c+d Sec[e+f x]))^(n-1)))/(Sqrt[a+b Sec[e+f x]]))dx

Program code:

Int[csc[e_.+f_.*x_]*(c_+d_.*csc[e_.+f_.*x_])^n_./Sqrt[a_+b_.*csc[e_.+f_.*x_]],x_Symbol] :=
  -2*d*Cot[e+f*x]*(c+d*Csc[e+f*x])^(n-1)/(f*(2*n-1)*Sqrt[a+b*Csc[e+f*x]]) + 
  2*c*(2*n-1)/(2*n-1)*Int[Csc[e+f*x]*(c+d*Csc[e+f*x])^(n-1)/Sqrt[a+b*Csc[e+f*x]],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IGtQ[n,0]

2:  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ n∈(SuperPlus[ℤ])∧ m<-(1/2)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ n∈(SuperPlus[ℤ])∧ m<-(1/2), then

∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  

-((2 a c Tan[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^(n-1)))/(b f (2 m+1)))-(( d (2n-1))/(b (2 m+1)))∫Sec[e+f x] (((a+b Sec[e+f x]))^(m+1)) (((c+d Sec[e+f x]))^(n-1))dx

Program code:

Int[csc[e_.+f_.*x_]*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_.,x_Symbol] :=
  2*a*c*Cot[e+f*x]*(a+b*Csc[e+f*x])^m*(c+d*Csc[e+f*x])^(n-1)/(b*f*(2*m+1)) - 
  d*(2*n-1)/(b*(2*m+1))*Int[Csc[e+f*x]*(a+b*Csc[e+f*x])^(m+1)*(c+d*Csc[e+f*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IGtQ[n,0] && LtQ[m,-1/2] && IntegerQ[2*m]

4:  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∈ℤ ∧ n∈ℤ ∧ n-m≥0 ∧ m n>0

Derivation: Algebraic simplification

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then (a+b Sec[z]) (c+d Sec[z])==-a c ((Tan[z])^2)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∈ℤ ∧ n∈ℤ ∧ n-m≥0 ∧ m n>0, then

∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  (((-a c))^m) ∫(((g Sec[e+f x]))^p) ((Tan[e+f x])^(2m)) (((c+d Sec[e+f x]))^(n-m))dx

Program code:

Int[csc[e_.+f_.*x_]*(a_+b_.*csc[e_.+f_.*x_])^m_.*(c_+d_.*csc[e_.+f_.*x_])^n_.,x_Symbol] :=
  (-a*c)^m*Int[ExpandTrig[csc[e+f*x]*cot[e+f*x]^(2*m),(c+d*csc[e+f*x])^(n-m),x],x] /;
FreeQ[{a,b,c,d,e,f,n},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IntegersQ[m,n] && GeQ[n-m,0] && GtQ[m*n,0]

5:  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^m)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m-(1/2)∈(SuperMinus[ℤ])

Derivation: Algebraic expansion and piecewise constant extraction

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m+(1/2)∈ℤ, then (((a+b Sec[z]))^m) (((c+d Sec[z]))^m)==(((((-a c))^(m+(1/2))) ((Tan[z])^(2 m+1)))/((Sqrt[a+b Sec[z]]) (Sqrt[c+d Sec[z]])))

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then (∂_x)((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))==0

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m+(1/2)∈ℤ, then

∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^m)dx  ⟶  
(((((-a c))^(m+(1/2))) Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]]))) ∫ Sec[e+f x] ((Tan[e+f x])^(2 m))dx

Program code:

Int[csc[e_.+f_.*x_]*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^m_,x_Symbol] :=
  (-a*c)^(m+1/2)*Cot[e+f*x]/(Sqrt[a+b*Csc[e+f*x]]*Sqrt[c+d*Csc[e+f*x]])*Int[Csc[e+f*x]*Cot[e+f*x]^(2*m),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IntegerQ[m+1/2]

6:  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ ((m|n-(1/2))∈(SuperMinus[ℤ]) ∨ (m-(1/2)|n-(1/2))∈(SuperMinus[ℤ]))

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ (m∈(SuperMinus[ℤ]) ∨ (m-(1/2)|n-(1/2))∈(SuperMinus[ℤ])) , then

∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  

-((b Tan[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n))/(a f (2 m+1)))+(((m+n+1))/(a (2 m+1)))∫Sec[e+f x] (((a+b Sec[e+f x]))^(m+1)) (((c+d Sec[e+f x]))^n) dx

Program code:

Int[csc[e_.+f_.*x_]*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  b*Cot[e+f*x]*(a+b*Csc[e+f*x])^m*(c+d*Csc[e+f*x])^n/(a*f*(2*m+1)) + 
  (m+n+1)/(a*(2*m+1))*Int[Csc[e+f*x]*(a+b*Csc[e+f*x])^(m+1)*(c+d*Csc[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,n},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && (ILtQ[m,0] && ILtQ[n-1/2,0] || ILtQ[m-1/2,0] && ILtQ[n-1/2,0] && LtQ[m,n])

7:  ∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then (∂_x)((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))==0

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then -((a c Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))==1

Basis: Tan[e+f x] F[Sec[e+f x]]==(1/f) Subst[((F[x])/x),x,Sec[e+f x]] (∂_x)Sec[e+f x]

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then

∫Sec[e+f x] (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  

-((a c Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]]))) ∫ Tan[e+f x] Sec[e+f x] (((a+b Sec[e+f x]))^(m-(1/2))) (((c+d Sec[e+f x]))^(n-(1/2)))dx  ⟶ 

 -((a c Tan[e+f x])/(f (Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]]))) Subst[∫(((a+b x))^(m-(1/2))) (((c+d x))^(n-(1/2)))dx,x,Sec[e+f x]]

Program code:

Int[csc[e_.+f_.*x_]*(a_+b_.*csc[e_.+f_.*x_])^m_.*(c_+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  a*c*Cot[e+f*x]/(f*Sqrt[a+b*Csc[e+f*x]]*Sqrt[c+d*Csc[e+f*x]])*Subst[Int[(a+b*x)^(m-1/2)*(c+d*x)^(n-1/2),x],x,Csc[e+f*x]] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0]

2:  ∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∈ℤ ∧ n∈ℤ ∧ n-m≥0 ∧ m n>0

Derivation: Algebraic simplification

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then (a+b Sec[z]) (c+d Sec[z])==-a c ((Tan[z])^2)

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m∈ℤ ∧ n∈ℤ ∧ n-m≥0 ∧ m n>0, then

∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  (((-a c))^m) ∫(((g Sec[e+f x]))^p) ((Tan[e+f x])^(2m)) (((c+d Sec[e+f x]))^(n-m))dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^p_.*(a_+b_.*csc[e_.+f_.*x_])^m_.*(c_+d_.*csc[e_.+f_.*x_])^n_.,x_Symbol] :=
  (-a*c)^m*Int[ExpandTrig[(g*csc[e+f*x])^p*cot[e+f*x]^(2*m),(c+d*csc[e+f*x])^(n-m),x],x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IntegersQ[m,n] && GeQ[n-m,0] && GtQ[m*n,0]

3:  ∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^m)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m-(1/2)∈(SuperMinus[ℤ])

Derivation: Algebraic expansion and piecewise constant extraction

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m+(1/2)∈ℤ, then (((a+b Sec[z]))^m) (((c+d Sec[z]))^m)==(((((-a c))^(m+(1/2))) ((Tan[z])^(2 m+1)))/((Sqrt[a+b Sec[z]]) (Sqrt[c+d Sec[z]])))

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then (∂_x)((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))==0

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0 ∧ m+(1/2)∈ℤ, then

∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^m)dx  ⟶  
(((((-a c))^(m+(1/2))) Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]]))) ∫ (((g Sec[e+f x]))^p) ((Tan[e+f x])^(2 m))dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^p_.*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^m_,x_Symbol] :=
  (-a*c)^(m+1/2)*Cot[e+f*x]/(Sqrt[a+b*Csc[e+f*x]]*Sqrt[c+d*Csc[e+f*x]])*Int[(g*Csc[e+f*x])^p*Cot[e+f*x]^(2*m),x] /;
FreeQ[{a,b,c,d,e,f,g,p},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0] && IntegerQ[m+1/2]

4:  ∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c+a d==0 ∧ (a^2)-(b^2)==0

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then (∂_x)((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))==0

Basis: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then -((a c Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))==1

Basis: Tan[e+f x] F[Sec[e+f x]]==(1/f) Subst[((F[x])/x),x,Sec[e+f x]] (∂_x)Sec[e+f x]

Rule: If  b c+a d==0 ∧ (a^2)-(b^2)==0, then

∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  

-((a c Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]]))) ∫ Tan[e+f x] (((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^(m-(1/2))) (((c+d Sec[e+f x]))^(n-(1/2)))dx  ⟶ 

 -((a c g Tan[e+f x])/(f (Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]]))) Subst[∫(((g x))^(p-1)) (((a+b x))^(m-(1/2))) (((c+d x))^(n-(1/2)))dx,x,Sec[e+f x]]

Program code:

Int[(g_.*csc[e_.+f_.*x_])^p_.*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  a*c*g*Cot[e+f*x]/(f*Sqrt[a+b*Csc[e+f*x]]*Sqrt[c+d*Csc[e+f*x]])*
    Subst[Int[(g*x)^(p-1)*(a+b*x)^(m-1/2)*(c+d*x)^(n-1/2),x],x,Csc[e+f*x]] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && EqQ[b*c+a*d,0] && EqQ[a^2-b^2,0]

2.  ∫(((((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m))/(c+d Sec[e+f x]))dx  when  b c-a d≠0

1.  ∫(((((g Sec[e+f x]))^p) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0

1.  ∫(((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0

1:  ∫(((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0

Derivation: Integration by substitution

Basis: If  (a^2)-(b^2)==0, then (((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))==((2 b g)/f)Subst[(1/(b c+a d-c g (x^2))),x,((b Tan[e+f x])/((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]])))] (∂_x)((b Tan[e+f x])/((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]])))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0, then

∫(((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  ⟶  ((2 b g)/f) Subst[∫(1/(b c+a d-c g (x^2)))dx,x,((b Tan[e+f x])/((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]])))]

Program code:

Int[Sqrt[g_.*csc[e_.+f_.*x_]]*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/(c_+d_.*csc[e_.+f_.*x_]),x_Symbol] :=
  -2*b*g/f*Subst[Int[1/(b*c+a*d-c*g*x^2),x],x,b*Cot[e+f*x]/(Sqrt[g*Csc[e+f*x]]*Sqrt[a+b*Csc[e+f*x]])] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0]

2:  ∫(((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0

Derivation: Algebraic expansion

Basis: ((Sqrt[a+b z])/(c+d z))==(a/(c (Sqrt[a+b z])))+(((b c-a d) g z)/(c g (Sqrt[a+b z]) (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0, then

∫(((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  ⟶  (a/c)∫((Sqrt[g Sec[e+f x]])/(Sqrt[a+b Sec[e+f x]]))dx+((b c-a d)/(c g))∫((((g Sec[e+f x]))^(3/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx

Program code:

Int[Sqrt[g_.*csc[e_.+f_.*x_]]*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/(c_+d_.*csc[e_.+f_.*x_]),x_Symbol] :=
  a/c*Int[Sqrt[g*Csc[e+f*x]]/Sqrt[a+b*Csc[e+f*x]],x] + 
  (b*c-a*d)/(c*g)*Int[(g*Csc[e+f*x])^(3/2)/(Sqrt[a+b*Csc[e+f*x]]*(c+d*Csc[e+f*x])),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0]

2.  ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0

1:  ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0

Derivation: Integration by substitution

Basis: If  (a^2)-(b^2)==0, then ((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))==((2 b)/f)Subst[(1/(b c+a d+d (x^2))),x,((b Tan[e+f x])/(Sqrt[a+b Sec[e+f x]]))](∂_x)((b Tan[e+f x])/(Sqrt[a+b Sec[e+f x]]))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0, then

∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  ⟶  ((2 b)/f)Subst[∫(1/(b c+a d+d (x^2)))dx,x,((b Tan[e+f x])/(Sqrt[a+b Sec[e+f x]]))]

Program code:

Int[csc[e_.+f_.*x_]*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/(c_+d_.*csc[e_.+f_.*x_]),x_Symbol] :=
  -2*b/f*Subst[Int[1/(b*c+a*d+d*x^2),x],x,b*Cot[e+f*x]/Sqrt[a+b*Csc[e+f*x]]] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0]

2.  ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0

1:  ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)==0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)==0, then

∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  ⟶  (( (Sqrt[a+b Sec[e+f x]]) (Sqrt[(c/(c+d Sec[e+f x]))]))/(d f (Sqrt[((c d (a+b Sec[e+f x]))/((b c+a d) (c+d Sec[e+f x])))])))EllipticE[ArcSin[((c Tan[e+f x])/(c+d Sec[e+f x]))],-((b c-a d)/(b c+a d))]

Program code:

Int[csc[e_.+f_.*x_]*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/(c_+d_.*csc[e_.+f_.*x_]),x_Symbol] :=
  -Sqrt[a+b*Csc[e+f*x]]*Sqrt[c/(c+d*Csc[e+f*x])]/(d*f*Sqrt[c*d*(a+b*Csc[e+f*x])/((b*c+a*d)*(c+d*Csc[e+f*x]))])*
    EllipticE[ArcSin[c*Cot[e+f*x]/(c+d*Csc[e+f*x])],-(b*c-a*d)/(b*c+a*d)] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && EqQ[c^2-d^2,0]

2:  ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: ((Sqrt[a+b z])/(c+d z))==(b/(d (Sqrt[a+b z])))-((b c-a d)/(d (Sqrt[a+b z]) (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  ⟶  (b/d)∫((Sec[e+f x])/(Sqrt[a+b Sec[e+f x]]))dx-((b c-a d)/d)∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx

Program code:

Int[csc[e_.+f_.*x_]*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/(c_+d_.*csc[e_.+f_.*x_]),x_Symbol] :=
  b/d*Int[Csc[e+f*x]/Sqrt[a+b*Csc[e+f*x]],x] - 
  (b*c-a*d)/d*Int[Csc[e+f*x]/(Sqrt[a+b*Csc[e+f*x]]*(c+d*Csc[e+f*x])),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

3.  ∫(((((g Sec[e+f x]))^(3/2)) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0

1:  ∫(((((g Sec[e+f x]))^(3/2)) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0

Derivation: Algebraic expansion

Basis: ((((g z))^(3/2))/(c+d z))==((g (Sqrt[g z]))/d)-((c g (Sqrt[g z]))/(d (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0, then

∫(((((g Sec[e+f x]))^(3/2)) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  ⟶  (g/d)∫(Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]])dx-((c g)/d)∫(((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^(3/2)*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/(c_+d_.*csc[e_.+f_.*x_]),x_Symbol] :=
  g/d*Int[Sqrt[g*Csc[e+f*x]]*Sqrt[a+b*Csc[e+f*x]],x] - 
  c*g/d*Int[Sqrt[g*Csc[e+f*x]]*Sqrt[a+b*Csc[e+f*x]]/(c+d*Csc[e+f*x]),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0]

2:  ∫(((((g Sec[e+f x]))^(3/2)) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0

Derivation: Algebraic expansion

Basis: ((Sqrt[a+b z])/(c+d z))==(b/(d(Sqrt[a+b z])))-((b c-a d)/(d (Sqrt[a+b z]) (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0, then

∫(((((g Sec[e+f x]))^(3/2)) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx  ⟶  (b/d)∫((((g Sec[e+f x]))^(3/2))/(Sqrt[a+b Sec[e+f x]]))dx-((b c-a d)/d)∫((((g Sec[e+f x]))^(3/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^(3/2)*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/(c_+d_.*csc[e_.+f_.*x_]),x_Symbol] :=
  b/d*Int[(g*Csc[e+f*x])^(3/2)/Sqrt[a+b*Csc[e+f*x]],x] - 
  (b*c-a*d)/d*Int[(g*Csc[e+f*x])^(3/2)/(Sqrt[a+b*Csc[e+f*x]]*(c+d*Csc[e+f*x])),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0]

2.  ∫((((g Sec[e+f x]))^p)/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0

1.  ∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0

1:  ∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0 ∧ ((a^2)-(b^2)==0 ∨ (c^2)-(d^2)==0)

Derivation: Algebraic expansion

Basis: (1/((Sqrt[a+b z]) (c+d z)))==(b/((b c-a d) (Sqrt[a+b z])))-((d (Sqrt[a+b z]))/((b c-a d) (c+d z)))

Rule: If  b c-a d≠0 ∧ ((a^2)-(b^2)==0 ∨ (c^2)-(d^2)==0), then

∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  ⟶  (b/(b c-a d)) ∫((Sec[e+f x])/(Sqrt[a+b Sec[e+f x]]))dx-(d/(b c-a d)) ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx

Program code:

Int[csc[e_.+f_.*x_]/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*(c_+d_.*csc[e_.+f_.*x_])),x_Symbol] :=
  b/(b*c-a*d)*Int[Csc[e+f*x]/Sqrt[a+b*Csc[e+f*x]],x] - 
  d/(b*c-a*d)*Int[Csc[e+f*x]*Sqrt[a+b*Csc[e+f*x]]/(c+d*Csc[e+f*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && (EqQ[a^2-b^2,0] || EqQ[c^2-d^2,0])

2:  ∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  ⟶  
((2 Tan[e+f x])/(f(c+d) (Sqrt[a+b Sec[e+f x]]) (Sqrt[-((Tan[e+f x])^2)])))(Sqrt[((a+b Sec[e+f x])/(a+b))]) EllipticPi[((2 d)/(c+d)),ArcSin[((Sqrt[1-Sec[e+f x]])/(Sqrt[2]))],((2 b)/(a+b))]

Program code:

Int[csc[e_.+f_.*x_]/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*(c_+d_.*csc[e_.+f_.*x_])),x_Symbol] :=
  -2*Cot[e+f*x]/(f*(c+d)*Sqrt[a+b*Csc[e+f*x]]*Sqrt[-Cot[e+f*x]^2])*Sqrt[(a+b*Csc[e+f*x])/(a+b)]*
    EllipticPi[2*d/(c+d),ArcSin[Sqrt[1-Csc[e+f*x]]/Sqrt[2]],2*b/(a+b)] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

2.  ∫((((g Sec[e+f x]))^(3/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0

1:  ∫((((g Sec[e+f x]))^(3/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0

Derivation: Algebraic expansion

Basis: ((g z)/((Sqrt[a+b z]) (c+d z)))==-((a g)/((b c-a d) (Sqrt[a+b z])))+((c g (Sqrt[a+b z]))/((b c-a d) (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0, then

∫((((g Sec[e+f x]))^(3/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  ⟶  -((a g)/(b c-a d))∫((Sqrt[g Sec[e+f x]])/(Sqrt[a+b Sec[e+f x]]))dx+((c g)/(b c-a d))∫(((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^(3/2)/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*(c_+d_.*csc[e_.+f_.*x_])),x_Symbol] :=
  -a*g/(b*c-a*d)*Int[Sqrt[g*Csc[e+f*x]]/Sqrt[a+b*Csc[e+f*x]],x] + 
  c*g/(b*c-a*d)*Int[Sqrt[g*Csc[e+f*x]]*Sqrt[a+b*Csc[e+f*x]]/(c+d*Csc[e+f*x]),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0]

2:  ∫((((g Sec[e+f x]))^(3/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sqrt[g Sec[e+f x]]) (Sqrt[b+a Cos[e+f x]]))/(Sqrt[a+b Sec[e+f x]]))==0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0, then

∫((((g Sec[e+f x]))^(3/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  ⟶  ((g (Sqrt[g Sec[e+f x]])(Sqrt[b+a Cos[e+f x]]))/(Sqrt[a+b Sec[e+f x]]))∫(1/((Sqrt[b+a Cos[e+f x]]) (d+c Cos[e+f x])))dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^(3/2)/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*(c_+d_.*csc[e_.+f_.*x_])),x_Symbol] :=
  g*Sqrt[g*Csc[e+f*x]]*Sqrt[b+a*Sin[e+f*x]]/Sqrt[a+b*Csc[e+f*x]]*Int[1/(Sqrt[b+a*Sin[e+f*x]]*(d+c*Sin[e+f*x])),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0]

3.  ∫(((Sec[e+f x])^2)/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0

1:  ∫(((Sec[e+f x])^2)/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0 ∧ ((a^2)-(b^2)==0 ∨ (c^2)-(d^2)==0)

Derivation: Algebraic expansion

Basis: ((z^2)/((Sqrt[a+b z]) (c+d z)))==-((a z)/((b c-a d) (Sqrt[a+b z])))+((c z (Sqrt[a+b z]))/((b c-a d) (c+d z)))

Rule: If  b c-a d≠0 ∧ ((a^2)-(b^2)==0 ∨ (c^2)-(d^2)==0), then

∫(((Sec[e+f x])^2)/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  ⟶  -(a/(b c-a d)) ∫((Sec[e+f x])/(Sqrt[a+b Sec[e+f x]]))dx+(c/(b c-a d)) ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx

Program code:

Int[csc[e_.+f_.*x_]^2/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*(c_+d_.*csc[e_.+f_.*x_])),x_Symbol] :=
  -a/(b*c-a*d)*Int[Csc[e+f*x]/Sqrt[a+b*Csc[e+f*x]],x] + 
  c/(b*c-a*d)*Int[Csc[e+f*x]*Sqrt[a+b*Csc[e+f*x]]/(c+d*Csc[e+f*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && (EqQ[a^2-b^2,0] || EqQ[c^2-d^2,0])

2:  ∫(((Sec[e+f x])^2)/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: ((z^2)/((Sqrt[a+b z]) (c+d z)))==(z/(d (Sqrt[a+b z])))-((c z)/(d (Sqrt[a+b z]) (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫(((Sec[e+f x])^2)/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  ⟶  (1/d)∫((Sec[e+f x])/(Sqrt[a+b Sec[e+f x]]))dx-(c/d)∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx

Program code:

Int[csc[e_.+f_.*x_]^2/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*(c_+d_.*csc[e_.+f_.*x_])),x_Symbol] :=
  1/d*Int[Csc[e+f*x]/Sqrt[a+b*Csc[e+f*x]],x] - 
  c/d*Int[Csc[e+f*x]/(Sqrt[a+b*Csc[e+f*x]]*(c+d*Csc[e+f*x])),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

4.  ∫((((g Sec[e+f x]))^(5/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0

1:  ∫((((g Sec[e+f x]))^(5/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0

Derivation: Algebraic expansion

Basis: (((g^2) (z^2))/((Sqrt[a+b z]) (c+d z)))==-(((c^2) (g^2) (Sqrt[a+b z]))/(d (b c-a d) (c+d z)))+(((g^2) (a c+(b c-a d) z))/(d (b c-a d) (Sqrt[a+b z])))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0, then

∫((((g Sec[e+f x]))^(5/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  ⟶  -(((c^2)(g^2))/(d (b c-a d)))∫(((Sqrt[g Sec[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/(c+d Sec[e+f x]))dx+((g^2)/(d (b c-a d)))∫(((Sqrt[g Sec[e+f x]])(a c+(b c-a d) Sec[e+f x]))/(Sqrt[a+b Sec[e+f x]]))dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^(5/2)/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*(c_+d_.*csc[e_.+f_.*x_])),x_Symbol] :=
  -c^2*g^2/(d*(b*c-a*d))*Int[Sqrt[g*Csc[e+f*x]]*Sqrt[a+b*Csc[e+f*x]]/(c+d*Csc[e+f*x]),x] + 
  g^2/(d*(b*c-a*d))*Int[Sqrt[g*Csc[e+f*x]]*(a*c+(b*c-a*d)*Csc[e+f*x])/Sqrt[a+b*Csc[e+f*x]],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0]

2:  ∫((((g Sec[e+f x]))^(5/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0

Derivation: Algebraic expansion

Basis: ((g z)/(c+d z))==(g/d)-((c g)/(d (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0, then

∫((((g Sec[e+f x]))^(5/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx  ⟶  (g/d)∫((((g Sec[e+f x]))^(3/2))/(Sqrt[a+b Sec[e+f x]]))dx-((c g)/d)∫((((g Sec[e+f x]))^(3/2))/((Sqrt[a+b Sec[e+f x]]) (c+d Sec[e+f x])))dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^(5/2)/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*(c_+d_.*csc[e_.+f_.*x_])),x_Symbol] :=
  g/d*Int[(g*Csc[e+f*x])^(3/2)/Sqrt[a+b*Csc[e+f*x]],x] - 
  c*g/d*Int[(g*Csc[e+f*x])^(3/2)/(Sqrt[a+b*Csc[e+f*x]]*(c+d*Csc[e+f*x])),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0]

3.  ∫((((Sec[e+f x])^p) (((a+b Sec[e+f x]))^m))/(Sqrt[c+d Sec[e+f x]]))dx  when  b c-a d≠0 ∧ (m^2)==(1/4)

1.  ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(Sqrt[c+d Sec[e+f x]]))dx  when  b c-a d≠0

1:  ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(Sqrt[c+d Sec[e+f x]]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0

Derivation: Integration by substitution

Basis: If  (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0, then ((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(Sqrt[c+d Sec[e+f x]]))==((2 b)/f)Subst[(1/(1-b d (x^2))),x,((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))](∂_x)((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0, then

∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(Sqrt[c+d Sec[e+f x]]))dx  ⟶  ((2 b)/f)Subst[∫(1/(1-b d (x^2)))dx,x,((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))]

Program code:

Int[csc[e_.+f_.*x_]*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/Sqrt[c_+d_.*csc[e_.+f_.*x_]],x_Symbol] :=
  -2*b/f*Subst[Int[1/(1-b*d*x^2),x],x,Cot[e+f*x]/(Sqrt[a+b*Csc[e+f*x]]*Sqrt[c+d*Csc[e+f*x]])] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

2:  ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(Sqrt[c+d Sec[e+f x]]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)==0

Derivation: Algebraic expansion

Basis: ((Sqrt[a+b z])/(Sqrt[c+d z]))==-((b c-a d)/(d (Sqrt[a+b z]) (Sqrt[c+d z])))+((b (Sqrt[c+d z]))/(d (Sqrt[a+b z])))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)==0, then

∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(Sqrt[c+d Sec[e+f x]]))dx  ⟶  -((b c-a d)/d)∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))dx+(b/d)∫((Sec[e+f x] (Sqrt[c+d Sec[e+f x]]))/(Sqrt[a+b Sec[e+f x]]))dx

Program code:

Int[csc[e_.+f_.*x_]*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/Sqrt[c_+d_.*csc[e_.+f_.*x_]],x_Symbol] :=
  -(b*c-a*d)/d*Int[Csc[e+f*x]/(Sqrt[a+b*Csc[e+f*x]]*Sqrt[c+d*Csc[e+f*x]]),x] + 
  b/d*Int[Csc[e+f*x]*Sqrt[c+d*Csc[e+f*x]]/Sqrt[a+b*Csc[e+f*x]],x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && EqQ[c^2-d^2,0]

3:  ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(Sqrt[c+d Sec[e+f x]]))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(Sqrt[c+d Sec[e+f x]]))dx  ⟶  
((2 (a+b Sec[e+f x]))/(d f (Sqrt[((a+b)/(c+d))]) Tan[e+f x])) (Sqrt[-(((b c-a d) (1-Sec[e+f x]))/((c+d) (a+b Sec[e+f x])))]) (Sqrt[(((b c-a d) (1+Sec[e+f x]))/((c-d) (a+b Sec[e+f x])))]) EllipticPi[((b (c+d))/(d (a+b))),ArcSin[(Sqrt[((a+b)/(c+d))]) ((Sqrt[c+d Sec[e+f x]])/(Sqrt[a+b Sec[e+f x]]))],(((a-b) (c+d))/((a+b) (c-d)))]

Program code:

Int[csc[e_.+f_.*x_]*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/Sqrt[c_+d_.*csc[e_.+f_.*x_]],x_Symbol] :=
  -2*(a+b*Csc[e+f*x])/(d*f*Sqrt[(a+b)/(c+d)]*Cot[e+f*x])*
    Sqrt[-(b*c-a*d)*(1-Csc[e+f*x])/((c+d)*(a+b*Csc[e+f*x]))]*Sqrt[(b*c-a*d)*(1+Csc[e+f*x])/((c-d)*(a+b*Csc[e+f*x]))]*
    EllipticPi[b*(c+d)/(d*(a+b)),ArcSin[Sqrt[(a+b)/(c+d)]*Sqrt[c+d*Csc[e+f*x]]/Sqrt[a+b*Csc[e+f*x]]],(a-b)*(c+d)/((a+b)*(c-d))] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

2.  ∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))dx  when  b c-a d≠0

1:  ∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0

Derivation: Integration by substitution

Basis: If  (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0, then ((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))==((2 a)/(b f))Subst[(1/(2+(a c-b d) (x^2))),x,((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))](∂_x)((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0, then

∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))dx  ⟶  ((2 a)/(b f))Subst[∫(1/(2+(a c-b d) (x^2)))dx,x,((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))]

Program code:

Int[csc[e_.+f_.*x_]/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*Sqrt[c_+d_.*csc[e_.+f_.*x_]]),x_Symbol] :=
  -2*a/(b*f)*Subst[Int[1/(2+(a*c-b*d)*x^2),x],x,Cot[e+f*x]/(Sqrt[a+b*Csc[e+f*x]]*Sqrt[c+d*Csc[e+f*x]])] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

2:  ∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))dx  ⟶  
((2 (c+d Sec[e+f x]))/(f (b c-a d) (Sqrt[((c+d)/(a+b))])  Tan[e+f x])) (Sqrt[(((b c-a d) (1-Sec[e+f x]))/((a+b) (c+d Sec[e+f x])))]) (Sqrt[-(((b c-a d) (1+Sec[e+f x]))/((a-b) (c+d Sec[e+f x])))]) EllipticF[ArcSin[(Sqrt[((c+d)/(a+b))]) ((Sqrt[a+b Sec[e+f x]])/( (Sqrt[c+d Sec[e+f x]])))],(((a+b) (c-d))/((a-b) (c+d)))]

Program code:

Int[csc[e_.+f_.*x_]/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*Sqrt[c_+d_.*csc[e_.+f_.*x_]]),x_Symbol] :=
  -2*(c+d*Csc[e+f*x])/(f*(b*c-a*d)*Rt[(c+d)/(a+b),2]*Cot[e+f*x])*
    Sqrt[(b*c-a*d)*(1-Csc[e+f*x])/((a+b)*(c+d*Csc[e+f*x]))]*Sqrt[-(b*c-a*d)*(1+Csc[e+f*x])/((a-b)*(c+d*Csc[e+f*x]))]*
    EllipticF[ArcSin[Rt[(c+d)/(a+b),2]*(Sqrt[a+b*Csc[e+f*x]]/Sqrt[c+d*Csc[e+f*x]])],(a+b)*(c-d)/((a-b)*(c+d))] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

3:  ∫(((Sec[e+f x])^2)/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))dx  when  b c-a d≠0

Derivation: Algebraic expansion

Basis: (z/(Sqrt[a+b z]))==-(a/(b (Sqrt[a+b z])))+((Sqrt[a+b z])/b)

Rule: If  b c-a d≠0, then

∫(((Sec[e+f x])^2)/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))dx  ⟶  -(a/b) ∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))dx+(1/b) ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(Sqrt[c+d Sec[e+f x]]))dx

Program code:

Int[csc[e_.+f_.*x_]^2/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*Sqrt[c_+d_.*csc[e_.+f_.*x_]]),x_Symbol] :=
  -a/b*Int[Csc[e+f*x]/(Sqrt[a+b*Csc[e+f*x]]*Sqrt[c+d*Csc[e+f*x]]),x] + 
  1/b*Int[Csc[e+f*x]*Sqrt[a+b*Csc[e+f*x]]/Sqrt[c+d*Csc[e+f*x]],x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0]

4:  ∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(((c+d Sec[e+f x]))^(3/2)))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: ((Sqrt[a+b z])/(c+d z))==((a-b)/((c-d) (Sqrt[a+b z])))+(((b c-a d) (1+z))/((c-d) (Sqrt[a+b z]) (c+d z)))

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0, then

∫((Sec[e+f x] (Sqrt[a+b Sec[e+f x]]))/(((c+d Sec[e+f x]))^(3/2)))dx  ⟶  
((a-b)/(c-d)) ∫((Sec[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[c+d Sec[e+f x]])))dx+((b c-a d)/(c-d)) ∫((Sec[e+f x] (1+Sec[e+f x]))/((Sqrt[a+b Sec[e+f x]]) (((c+d Sec[e+f x]))^(3/2))))dx

Program code:

Int[csc[e_.+f_.*x_]*Sqrt[a_+b_.*csc[e_.+f_.*x_]]/(c_+d_.*csc[e_.+f_.*x_])^(3/2),x_Symbol] :=
  (a-b)/(c-d)*Int[Csc[e+f*x]/(Sqrt[a+b*Csc[e+f*x]]*Sqrt[c+d*Csc[e+f*x]]),x] + 
  (b*c-a*d)/(c-d)*Int[Csc[e+f*x]*(1+Csc[e+f*x])/(Sqrt[a+b*Csc[e+f*x]]*(c+d*Csc[e+f*x])^(3/2)),x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0]

5:  ∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ (p==1 ∨ m-(1/2)∈ℤ)

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  (a^2)-(b^2)==0, then (∂_x)((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[a-b Sec[e+f x]])))==0

Basis: If  (a^2)-(b^2)==0, then -(((a^2) Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[a-b Sec[e+f x]])))((Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[a-b Sec[e+f x]])))==1

Basis: Tan[e+f x] F[Sec[e+f x]]==(1/f) Subst[((F[x])/x),x,Sec[e+f x]] (∂_x)Sec[e+f x]

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)==0 ∧ (c^2)-(d^2)≠0 ∧ (p==1 ∨ m-(1/2)∈ℤ), then

∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  

-(((a^2) Tan[e+f x])/((Sqrt[a+b Sec[e+f x]]) (Sqrt[a-b Sec[e+f x]])))∫((Tan[e+f x] (((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^(m-(1/2))) (((c+d Sec[e+f x]))^n))/(Sqrt[a-b Sec[e+f x]]))dx  ⟶  

-(((a^2) g Tan[e+f x])/(f (Sqrt[a+b Sec[e+f x]]) (Sqrt[a-b Sec[e+f x]])))Subst[∫(((((g x))^(p-1)) (((a+b x))^(m-(1/2))) (((c+d x))^n))/(Sqrt[a-b x]))dx,x,Sec[e+f x]]

Program code:

Int[(g_.*csc[e_.+f_.*x_])^p_.*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  a^2*g*Cot[e+f*x]/(f*Sqrt[a+b*Csc[e+f*x]]*Sqrt[a-b*Csc[e+f*x]])*
    Subst[Int[(g*x)^(p-1)*(a+b*x)^(m-1/2)*(c+d*x)^n/Sqrt[a-b*x],x],x,Csc[e+f*x]] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && NeQ[b*c-a*d,0] && EqQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && (EqQ[p,1] || IntegerQ[m-1/2])

6:  ∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c-a d≠0 ∧ m∈ℤ ∧ n∈ℤ

Derivation: Algebraic normalization

Basis: If  m∈ℤ ∧ n∈ℤ, then (((a+b Sec[z]))^m) (((c+d Sec[z]))^n)==((Sec[z])^(m+n)) (((b+a Cos[z]))^m) (((d+c Cos[z]))^n)

Rule: If  b c-a d≠0 ∧ m∈ℤ ∧ n∈ℤ, then

∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  (1/(g^(m+n))) ∫(((g Sec[e+f x]))^(m+n+p)) (((b+a Cos[e+f x]))^m) (((d+c Cos[e+f x]))^n)dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^p_.*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  1/g^(m+n)*Int[(g*Csc[e+f*x])^(m+n+p)*(b+a*Sin[e+f*x])^m*(d+c*Sin[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,p},x] && NeQ[b*c-a*d,0] && IntegerQ[m] && IntegerQ[n]

7.  ∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c-a d≠0 ∧ m+n+p==0

1:  ∫(((g Sec[e+f x]))^p)(((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c-a d≠0 ∧ m+n+p==0 ∧ m∈ℤ

Derivation: Algebraic normalization and piecewise constant extraction

Basis: a+b Sec[e+f x]==Sec[e+f x](b+a Cos[e+f x])

Basis: If  m+n+p==0, then (∂_x)(((((g Sec[e+f x]))^(m+p)) (((c+d Sec[e+f x]))^n))/(((d+c Cos[e+f x]))^n))==0

Rule: If  b c-a d≠0 ∧ m+n+p==0 ∧ m∈ℤ, then

∫(((g Sec[e+f x]))^p)(((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  (1/(g^m))∫(((g Sec[e+f x]))^(m+p))(((b+a Cos[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx
  ⟶  (((((g Sec[e+f x]))^(m+p)) (((c+d Sec[e+f x]))^n))/((g^m) (((d+c Cos[e+f x]))^n)))∫(((b+a Cos[e+f x]))^m) (((d+c Cos[e+f x]))^n)dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^p_.*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  (g*Csc[e+f*x])^(m+p)*(c+d*Csc[e+f*x])^n/(g^m*(d+c*Sin[e+f*x])^n)*Int[(b+a*Sin[e+f*x])^m*(d+c*Sin[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && NeQ[b*c-a*d,0] && EqQ[m+n+p,0] && IntegerQ[m]

2:  ∫(((g Sec[e+f x]))^p)(((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c-a d≠0 ∧ m+n+p==0 ∧ m∉ℤ

Derivation: Piecewise constant extraction

Basis: If  m+n+p==0, then (∂_x)(((((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n))/((((b+a Cos[e+f x]))^m) (((d+c Cos[e+f x]))^n)))==0

Rule: If  b c-a d≠0 ∧ m+n+p==0 ∧ m∉ℤ, then

∫(((g Sec[e+f x]))^p)(((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  (((((g Sec[e+f x]))^p)(((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n))/((((b+a Cos[e+f x]))^m) (((d+c Cos[e+f x]))^n)))∫(((b+a Cos[e+f x]))^m) (((d+c Cos[e+f x]))^n)dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^p_.*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  (g*Csc[e+f*x])^p*(a+b*Csc[e+f*x])^m*(c+d*Csc[e+f*x])^n/((b+a*Sin[e+f*x])^m*(d+c*Sin[e+f*x])^n)*
    Int[(b+a*Sin[e+f*x])^m*(d+c*Sin[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && NeQ[b*c-a*d,0] && EqQ[m+n+p,0] && Not[IntegerQ[m]]

8:  ∫((Sec[e+f x])^p)(((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c-a d≠0 ∧ m-(1/2)∈ℤ ∧ n-(1/2)∈ℤ ∧ p∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sqrt[d+c Cos[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/((Sqrt[b+a Cos[e+f x]]) (Sqrt[c+d Sec[e+f x]])))==0

Note: The restriction m+n+p∈{-1,-2} can be lifted if and when the cosine integration rules are extended to handle integrands of the form  ((Cos[e+f x])^p)(((a+b Cos[e+f x]))^m) (((c+d Cos[e+f x]))^n) for arbitray p.

Rule: If  b c-a d≠0 ∧ m-(1/2)∈ℤ ∧ n-(1/2)∈ℤ ∧ p∈ℤ, then

∫((Sec[e+f x])^p)(((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  (((Sqrt[d+c Cos[e+f x]]) (Sqrt[a+b Sec[e+f x]]))/((Sqrt[b+a Cos[e+f x]]) (Sqrt[c+d Sec[e+f x]])))∫(((((b+a Cos[e+f x]))^m) (((d+c Cos[e+f x]))^n))/((Cos[e+f x])^(m+n+p)))dx

Program code:

Int[csc[e_.+f_.*x_]^p_.*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  Sqrt[d+c*Sin[e+f*x]]*Sqrt[a+b*Csc[e+f*x]]/(Sqrt[b+a*Sin[e+f*x]]*Sqrt[c+d*Csc[e+f*x]])*
    Int[(b+a*Sin[e+f*x])^m*(d+c*Sin[e+f*x])^n/Sin[e+f*x]^(m+n+p),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && NeQ[b*c-a*d,0] && IntegerQ[m-1/2] && IntegerQ[n-1/2] && IntegerQ[p] && LeQ[-2,m+n+p,-1]

9:  ∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  when  b c-a d≠0 ∧ ((m|n)∈ℤ ∨ (m|p)∈ℤ ∨ (n|p)∈ℤ)

Derivation: Algebraic expansion

Rule: If  b c-a d≠0 ∧ ((m|n)∈ℤ ∨ (m|p)∈ℤ ∨ (n|p)∈ℤ), then

∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  

∫ExpandTrig[(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n),x]dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^p_.*(a_+b_.*csc[e_.+f_.*x_])^m_*(c_+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  Int[ExpandTrig[(g*csc[e+f*x])^p*(a+b*csc[e+f*x])^m*(c+d*csc[e+f*x])^n,x],x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && NeQ[b*c-a*d,0] && (IntegersQ[m,n] || IntegersQ[m,p] || IntegersQ[n,p])

X:  ∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx

Rule:

∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx  ⟶  ∫(((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n)dx

Program code:

Int[(g_.*csc[e_.+f_.*x_])^p_.*(a_.+b_.*csc[e_.+f_.*x_])^m_*(c_.+d_.*csc[e_.+f_.*x_])^n_,x_Symbol] :=
  Unintegrable[(g*Csc[e+f*x])^p*(a+b*Csc[e+f*x])^m*(c+d*Csc[e+f*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x]

Rules for integrands of the form (((g Sec[e+f x]))^p) (((a+b Sec[e+f x]))^m) (((c+d Sec[e+f x]))^n) (A+B Sec[e+f x])

1:  ∫((Sec[e+f x] (A+B Sec[e+f x]))/((Sqrt[a+b Sec[e+f x]]) (((c+d Sec[e+f x]))^(3/2))))dx  when  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ A==B

Rule: If  b c-a d≠0 ∧ (a^2)-(b^2)≠0 ∧ (c^2)-(d^2)≠0 ∧ A==B, then

∫((Sec[e+f x] (A+B Sec[e+f x]))/((Sqrt[a+b Sec[e+f x]]) (((c+d Sec[e+f x]))^(3/2))))dx  ⟶  
((2 A(1+Sec[e+f x]) (Sqrt[(((b c-a d) (1-Sec[e+f x]))/((a+b) (c+d Sec[e+f x])))]))/(f(b c-a d)(Sqrt[((c+d)/(a+b))]) Tan[e+f x] (Sqrt[-(((b c-a d) (1+Sec[e+f x]))/((a-b) (c+d Sec[e+f x])))]))) EllipticE[ArcSin[(Sqrt[((c+d)/(a+b))]) ((Sqrt[a+b Sec[e+f x]])/( (Sqrt[c+d Sec[e+f x]])))],(((a+b) (c-d))/((a-b) (c+d)))]

Program code:

Int[sec[e_.+f_.*x_]*(A_+B_.*sec[e_.+f_.*x_])/(Sqrt[a_+b_.*sec[e_.+f_.*x_]]*(c_+d_.*sec[e_.+f_.*x_])^(3/2)),x_Symbol] :=
  2*A*(1+Sec[e+f*x])*Sqrt[(b*c-a*d)*(1-Sec[e+f*x])/((a+b)*(c+d*Sec[e+f*x]))]/
    (f*(b*c-a*d)*Rt[(c+d)/(a+b),2]*Tan[e+f*x]*Sqrt[-(b*c-a*d)*(1+Sec[e+f*x])/((a-b)*(c+d*Sec[e+f*x]))])*
    EllipticE[ArcSin[Rt[(c+d)/(a+b),2]*Sqrt[a+b*Sec[e+f*x]]/Sqrt[c+d*Sec[e+f*x]]],(a+b)*(c-d)/((a-b)*(c+d))] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && EqQ[A,B]

Int[csc[e_.+f_.*x_]*(A_+B_.*csc[e_.+f_.*x_])/(Sqrt[a_+b_.*csc[e_.+f_.*x_]]*(c_+d_.*csc[e_.+f_.*x_])^(3/2)),x_Symbol] :=
  -2*A*(1+Csc[e+f*x])*Sqrt[(b*c-a*d)*(1-Csc[e+f*x])/((a+b)*(c+d*Csc[e+f*x]))]/
    (f*(b*c-a*d)*Rt[(c+d)/(a+b),2]*Cot[e+f*x]*Sqrt[-(b*c-a*d)*(1+Csc[e+f*x])/((a-b)*(c+d*Csc[e+f*x]))])*
    EllipticE[ArcSin[Rt[(c+d)/(a+b),2]*Sqrt[a+b*Csc[e+f*x]]/Sqrt[c+d*Csc[e+f*x]]],(a+b)*(c-d)/((a-b)*(c+d))] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && NeQ[b*c-a*d,0] && NeQ[a^2-b^2,0] && NeQ[c^2-d^2,0] && EqQ[A,B]