Rules for integrands of the form (((e Trig[a+b x]))^m) (((f Trig[c+d x]))^n)

1.  ∫Trig[a+b x]Trig[c+d x]dx  when  (b^2)-(d^2)≠0

1:  ∫Sin[a+b x] Sin[c+d x]dx  when  (b^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: Sin[v] Sin[w]==(1/2) Cos[v-w]-(1/2) Cos[v+w]

Rule: If  (b^2)-(d^2)≠0, then

∫Sin[a+b x] Sin[c+d x]dx  ⟶  ((Sin[a -c+(b-d) x])/(2(b-d)))-((Sin[a +c+(b+d) x])/(2(b+d)))

Program code:

Int[sin[a_.+b_.*x_]*sin[c_.+d_.*x_],x_Symbol] :=
  Sin[a-c+(b-d)*x]/(2*(b-d)) - Sin[a+c+(b+d)*x]/(2*(b+d)) /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-d^2,0]

2:  ∫Cos[a+b x] Cos[c+d x]dx  when  (b^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: Cos[v] Cos[w]==(1/2) Cos[v-w]+(1/2) Cos[v+w]

Rule: If  (b^2)-(d^2)≠0, then

∫Cos[a+b x] Cos[c+d x]dx  ⟶  ((Sin[a -c+(b-d) x])/(2(b-d)))+((Sin[a +c+(b+d) x])/(2(b+d)))

Program code:

Int[cos[a_.+b_.*x_]*cos[c_.+d_.*x_],x_Symbol] :=
  Sin[a-c+(b-d)*x]/(2*(b-d)) + Sin[a+c+(b+d)*x]/(2*(b+d)) /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-d^2,0]

3:  ∫Sin[a+b x] Cos[c+d x]dx  when  (b^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: Sin[v] Cos[w]==(1/2) Sin[v+w]+(1/2) Sin[v-w]

Rule: If  (b^2)-(d^2)≠0, then

∫Sin[a+b x] Cos[c+d x]dx  ⟶  -((Cos[a -c+(b-d) x])/(2(b-d)))-((Cos[a +c+(b+d) x])/(2(b+d)))

Program code:

Int[sin[a_.+b_.*x_]*cos[c_.+d_.*x_],x_Symbol] :=
  -Cos[a-c+(b-d)*x]/(2*(b-d)) - Cos[a+c+(b+d)*x]/(2*(b+d)) /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-d^2,0]

2.  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2

1.  ∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2

1:  ∫((Cos[a+b x])^2)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ ((p/2)∈(SuperPlus[ℤ]) ∨ p∉ℤ)

Derivation: Algebraic expansion

Basis: ((Cos[z])^2)==(1/2)+(1/2) Cos[2 z]

Basis: ((Sin[z])^2)==(1/2)-(1/2) Cos[2 z]

Note: Although not necessary, this rule produces a slightly simpler antiderivative than the following rule.

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ ((p/2)∈(SuperPlus[ℤ]) ∨ p∉ℤ), then

∫((Cos[a+b x])^2)(((g Sin[c+d x]))^p)dx  ⟶  (1/2)∫(((g Sin[c+d x]))^p)dx+(1/2)∫Cos[c+d x](((g Sin[c+d x]))^p)dx

Program code:

Int[cos[a_.+b_.*x_]^2*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  1/2*Int[(g*Sin[c+d*x])^p,x] + 
  1/2*Int[Cos[c+d*x]*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && IGtQ[p/2,0]

Int[sin[a_.+b_.*x_]^2*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  1/2*Int[(g*Sin[c+d*x])^p,x] - 
  1/2*Int[Cos[c+d*x]*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && IGtQ[p/2,0]

2:  ∫(((e Cos[a+b x]))^m) ((Sin[c+d x])^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: Sin[z]==2 Cos[(z/2)]Sin[(z/2)]

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∈ℤ, then

∫(((e Cos[a+b x]))^m) ((Sin[c+d x])^p)dx  ⟶  ((2^p)/(e^p))∫(((e Cos[a+b x]))^(m+p))((Sin[a+b x])^p)dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_.*sin[c_.+d_.*x_]^p_.,x_Symbol] :=
  2^p/e^p*Int[(e*Cos[a+b*x])^(m+p)*Sin[a+b*x]^p,x] /;
FreeQ[{a,b,c,d,e,m},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && IntegerQ[p]

Int[(f_.*sin[a_.+b_.*x_])^n_.*sin[c_.+d_.*x_]^p_.,x_Symbol] :=
  2^p/f^p*Int[Cos[a+b*x]^p*(f*Sin[a+b*x])^(n+p),x] /;
FreeQ[{a,b,c,d,f,n},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && IntegerQ[p]

3.  ∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ

1:  ∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+p-1==0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+p-1==0, then

∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  ⟶  (((e^2)(((e Cos[a+b x]))^(m-2))(((g Sin[c+d x]))^(p+1)))/(2b g(p+1)))

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  e^2*(e*Cos[a+b*x])^(m-2)*(g*Sin[c+d*x])^(p+1)/(2*b*g*(p+1)) /;
FreeQ[{a,b,c,d,e,g,m,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && EqQ[m+p-1,0]

Int[(e_.*sin[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -e^2*(e*Sin[a+b*x])^(m-2)*(g*Sin[c+d*x])^(p+1)/(2*b*g*(p+1)) /;
FreeQ[{a,b,c,d,e,g,m,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && EqQ[m+p-1,0]

2:  ∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+2p+2==0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+2p+2==0, then

∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  ⟶  -(((((e Cos[a+b x]))^m)(((g Sin[c+d x]))^(p+1)))/(b g m))

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -(e*Cos[a+b*x])^m*(g*Sin[c+d*x])^(p+1)/(b*g*m) /;
FreeQ[{a,b,c,d,e,g,m,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && EqQ[m+2*p+2,0]

Int[(e_.*sin[a_.+b_.*x_])^m_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  (e*Sin[a+b*x])^m*(g*Sin[c+d*x])^(p+1)/(b*g*m) /;
FreeQ[{a,b,c,d,e,g,m,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && EqQ[m+2*p+2,0]

3.  ∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1

1.  ∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ p<-1

1:  ∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>2 ∧ p<-1

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>2 ∧ p<-1, then

∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  ⟶  
(((e^2)(((e Cos[a+b x]))^(m-2))(((g Sin[c+d x]))^(p+1)))/(2b g(p+1)))+(((e^4)(m+p-1))/(4(g^2)(p+1)))∫(((e Cos[a+b x]))^(m-4))(((g Sin[c+d x]))^(p+2))dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  e^2*(e*Cos[a+b*x])^(m-2)*(g*Sin[c+d*x])^(p+1)/(2*b*g*(p+1)) + 
  e^4*(m+p-1)/(4*g^2*(p+1))*Int[(e*Cos[a+b*x])^(m-4)*(g*Sin[c+d*x])^(p+2),x] /;
FreeQ[{a,b,c,d,e,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,2] && LtQ[p,-1] && (GtQ[m,3] || EqQ[p,-3/2]) && IntegersQ[2*m,2*p]

Int[(e_.*sin[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -e^2*(e*Sin[a+b*x])^(m-2)*(g*Sin[c+d*x])^(p+1)/(2*b*g*(p+1)) + 
  e^4*(m+p-1)/(4*g^2*(p+1))*Int[(e*Sin[a+b*x])^(m-4)*(g*Sin[c+d*x])^(p+2),x] /;
FreeQ[{a,b,c,d,e,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,2] && LtQ[p,-1] && (GtQ[m,3] || EqQ[p,-3/2]) && IntegersQ[2*m,2*p]

2:  ∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ p<-1 ∧ m+2p+2≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ p<-1 ∧ m+2p+2≠0, then

∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  ⟶  
(((((e Cos[a+b x]))^m)(((g Sin[c+d x]))^(p+1)))/(2b g(p+1)))+(((e^2)(m+2p+2))/(4(g^2)(p+1)))∫(((e Cos[a+b x]))^(m-2))(((g Sin[c+d x]))^(p+2))dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  (e*Cos[a+b*x])^m*(g*Sin[c+d*x])^(p+1)/(2*b*g*(p+1)) + 
  e^2*(m+2*p+2)/(4*g^2*(p+1))*Int[(e*Cos[a+b*x])^(m-2)*(g*Sin[c+d*x])^(p+2),x] /;
FreeQ[{a,b,c,d,e,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,1] && LtQ[p,-1] && NeQ[m+2*p+2,0] && 
  (LtQ[p,-2] || EqQ[m,2]) && IntegersQ[2*m,2*p]

Int[(e_.*sin[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -(e*Sin[a+b*x])^m*(g*Sin[c+d*x])^(p+1)/(2*b*g*(p+1)) + 
  e^2*(m+2*p+2)/(4*g^2*(p+1))*Int[(e*Sin[a+b*x])^(m-2)*(g*Sin[c+d*x])^(p+2),x] /;
FreeQ[{a,b,c,d,e,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,1] && LtQ[p,-1] && NeQ[m+2*p+2,0] && 
  (LtQ[p,-2] || EqQ[m,2]) && IntegersQ[2*m,2*p]

2:  ∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ m+2p≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ m+2p≠0, then

∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  ⟶  
(((e^2)(((e Cos[a+b x]))^(m-2))(((g Sin[c+d x]))^(p+1)))/(2b g(m+2p)))+(((e^2)(m+p-1))/(m+2p))∫(((e Cos[a+b x]))^(m-2))(((g Sin[c+d x]))^p)dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  e^2*(e*Cos[a+b*x])^(m-2)*(g*Sin[c+d*x])^(p+1)/(2*b*g*(m+2*p)) + 
  e^2*(m+p-1)/(m+2*p)*Int[(e*Cos[a+b*x])^(m-2)*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,g,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,1] && NeQ[m+2*p,0] && IntegersQ[2*m,2*p]

Int[(e_.*sin[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -e^2*(e*Sin[a+b*x])^(m-2)*(g*Sin[c+d*x])^(p+1)/(2*b*g*(m+2*p)) + 
  e^2*(m+p-1)/(m+2*p)*Int[(e*Sin[a+b*x])^(m-2)*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,g,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,1] && NeQ[m+2*p,0] && IntegersQ[2*m,2*p]

4:  ∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m<-1 ∧ m+2p+2≠0 ∧ m+p+1≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m<-1 ∧ m+2p+2≠0 ∧ m+p+1≠0, then

∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  ⟶  
-(((((e Cos[a+b x]))^m)(((g Sin[c+d x]))^(p+1)))/(2b g(m+p+1)))+((m+2p+2)/((e^2)(m+p+1)))∫(((e Cos[a+b x]))^(m+2))(((g Sin[c+d x]))^p)dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -(e*Cos[a+b*x])^m*(g*Sin[c+d*x])^(p+1)/(2*b*g*(m+p+1)) + 
  (m+2*p+2)/(e^2*(m+p+1))*Int[(e*Cos[a+b*x])^(m+2)*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,g,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && LtQ[m,-1] && NeQ[m+2*p+2,0] && NeQ[m+p+1,0] && IntegersQ[2*m,2*p]

Int[(e_.*sin[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  (e*Sin[a+b*x])^m*(g*Sin[c+d*x])^(p+1)/(2*b*g*(m+p+1)) + 
  (m+2*p+2)/(e^2*(m+p+1))*Int[(e*Sin[a+b*x])^(m+2)*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,g,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && LtQ[m,-1] && NeQ[m+2*p+2,0] && NeQ[m+p+1,0] && IntegersQ[2*m,2*p]

5.  ∫Cos[a+b x](((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ

1:  ∫Cos[a+b x] (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ p>0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ p>0, then

∫Cos[a+b x] (((g Sin[c+d x]))^p)dx  ⟶  ((2Sin[a+b x] (((g Sin[c+d x]))^p))/(d(2p+1)))+((2p g)/(2p+1)) ∫Sin[a+b x](((g Sin[c+d x]))^(p-1))dx

Program code:

Int[cos[a_.+b_.*x_]*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  2*Sin[a+b*x]*(g*Sin[c+d*x])^p/(d*(2*p+1)) + 2*p*g/(2*p+1)*Int[Sin[a+b*x]*(g*Sin[c+d*x])^(p-1),x] /;
FreeQ[{a,b,c,d,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[p,0] && IntegerQ[2*p]

Int[sin[a_.+b_.*x_]*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -2*Cos[a+b*x]*(g*Sin[c+d*x])^p/(d*(2*p+1)) + 2*p*g/(2*p+1)*Int[Cos[a+b*x]*(g*Sin[c+d*x])^(p-1),x] /;
FreeQ[{a,b,c,d,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[p,0] && IntegerQ[2*p]

2:  ∫Cos[a+b x] (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ p<-1

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ p<-1, then

∫Cos[a+b x] (((g Sin[c+d x]))^p)dx  ⟶  ((Cos[a+b x] (((g Sin[c+d x]))^(p+1)))/(2b g(p+1)))+((2p+3)/(2 g(p+1)))∫Sin[a+b x] (((g Sin[c+d x]))^(p+1))dx

Program code:

Int[cos[a_.+b_.*x_]*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  Cos[a+b*x]*(g*Sin[c+d*x])^(p+1)/(2*b*g*(p+1)) + 
  (2*p+3)/(2*g*(p+1))*Int[Sin[a+b*x]*(g*Sin[c+d*x])^(p+1),x] /;
FreeQ[{a,b,c,d,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && LtQ[p,-1] && IntegerQ[2*p]

Int[sin[a_.+b_.*x_]*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -Sin[a+b*x]*(g*Sin[c+d*x])^(p+1)/(2*b*g*(p+1)) + 
  (2*p+3)/(2*g*(p+1))*Int[Cos[a+b*x]*(g*Sin[c+d*x])^(p+1),x] /;
FreeQ[{a,b,c,d,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && LtQ[p,-1] && IntegerQ[2*p]

3:  ∫((Cos[a+b x])/(Sqrt[Sin[c+d x]]))dx  when  b c-a d==0 ∧ (d/b)==2

Rule: If  b c-a d==0 ∧ (d/b)==2, then

∫((Cos[a+b x])/(Sqrt[Sin[c+d x]]))dx  ⟶  -((ArcSin[Cos[a+b x]-Sin[a+b x]])/d)+((Log[Cos[a+b x]+Sin[a+b x]+(Sqrt[Sin[c+d x]])])/d)

Program code:

Int[cos[a_.+b_.*x_]/Sqrt[sin[c_.+d_.*x_]],x_Symbol] :=
  -ArcSin[Cos[a+b*x]-Sin[a+b*x]]/d + Log[Cos[a+b*x]+Sin[a+b*x]+Sqrt[Sin[c+d*x]]]/d /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2]

Int[sin[a_.+b_.*x_]/Sqrt[sin[c_.+d_.*x_]],x_Symbol] :=
  -ArcSin[Cos[a+b*x]-Sin[a+b*x]]/d - Log[Cos[a+b*x]+Sin[a+b*x]+Sqrt[Sin[c+d*x]]]/d /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2]

6:  ∫((((g Sin[c+d x]))^p)/(Cos[a+b x]))dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ

Derivation: Algebraic normalization

Basis: ((((g Sin[2 z]))^p)/(Cos[z]))==2 g Sin[z] (((g Sin[2 z]))^(p-1))

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ, then

∫((((g Sin[c+d x]))^p)/(Cos[a+b x]))dx  ⟶  2g∫Sin[a+b x](((g Sin[c+d x]))^(p-1))dx

Program code:

Int[(g_.*sin[c_.+d_.*x_])^p_/cos[a_.+b_.*x_],x_Symbol] :=
  2*g*Int[Sin[a+b*x]*(g*Sin[c+d*x])^(p-1),x] /;
FreeQ[{a,b,c,d,g,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && IntegerQ[2*p]

Int[(g_.*sin[c_.+d_.*x_])^p_/sin[a_.+b_.*x_],x_Symbol] :=
  2*g*Int[Cos[a+b*x]*(g*Sin[c+d*x])^(p-1),x] /;
FreeQ[{a,b,c,d,g,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && IntegerQ[2*p]

x:  ∫(((e Cos[a+b x]))^m) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+p∉ℤ

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+p∉ℤ, then

∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  ⟶  
-(((((e Cos[a+b x]))^(m+1))Sin[a+b x] (((g Sin[c+d x]))^p))/(b e(m+p+1)(((((Sin[a+b x])^2)))^((p+1)/2))))Hypergeometric2F1[-((p-1)/2),((m+p+1)/2),((m+p+3)/2),((Cos[a+b x])^2)]

Program code:

(* Int[(e_.*cos[a_.+b_.*x_])^m_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -(e*Cos[a+b*x])^(m+1)*Sin[a+b*x]*(g*Sin[c+d*x])^p/(b*e*(m+p+1)*(Sin[a+b*x]^2)^((p+1)/2))*
    Hypergeometric2F1[-(p-1)/2,(m+p+1)/2,(m+p+3)/2,Cos[a+b*x]^2] /;
FreeQ[{a,b,c,d,e,g,m,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && Not[IntegerQ[m+p]] *)

(* Int[(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -Cos[a+b*x]*(f*Sin[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*f*(p+1)*(Sin[a+b*x]^2)^((n+p+1)/2))*
    Hypergeometric2F1[-(n+p-1)/2,(p+1)/2,(p+3)/2,Cos[a+b*x]^2] /;
FreeQ[{a,b,c,d,f,g,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && Not[IntegerQ[n+p]] *)

7:  ∫(((e Cos[a+b x]))^m) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  b c-a d==0 ∧ (d/b)==2, then (∂_x)((((g Sin[c+d x]))^p)/((((e Cos[a+b x]))^p)((Sin[a+b x])^p)))==0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ, then

∫(((e Cos[a+b x]))^m)(((g Sin[c+d x]))^p)dx  ⟶  ((((g Sin[c+d x]))^p)/((((e Cos[a+b x]))^p)((Sin[a+b x])^p)))∫(((e Cos[a+b x]))^(m+p))((Sin[a+b x])^p)dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  (g*Sin[c+d*x])^p/((e*Cos[a+b*x])^p*Sin[a+b*x]^p)*Int[(e*Cos[a+b*x])^(m+p)*Sin[a+b*x]^p,x] /;
FreeQ[{a,b,c,d,e,g,m,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]]

Int[(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  (g*Sin[c+d*x])^p/(Cos[a+b*x]^p*(f*Sin[a+b*x])^p)*Int[Cos[a+b*x]^p*(f*Sin[a+b*x])^(n+p),x] /;
FreeQ[{a,b,c,d,f,g,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]]

2.  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2

1:  ∫((Cos[a+b x])^2)((Sin[a+b x])^2) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ ((p/2)∈(SuperPlus[ℤ]) ∨ p∉ℤ)

Derivation: Algebraic expansion

Basis: ((Cos[z])^2)((Sin[z])^2)==(1/4)-(1/4) ((Cos[2 z])^2)

Note: Although not necessary, this rule produces a slightly simpler antiderivative than the following rule.

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ ((p/2)∈(SuperPlus[ℤ]) ∨ p∉ℤ), then

∫((Cos[a+b x])^2)((Sin[a+b x])^2) (((g Sin[c+d x]))^p)dx  ⟶  (1/4)∫(((g Sin[c+d x]))^p)dx-(1/4)∫((Cos[c+d x])^2)(((g Sin[c+d x]))^p)dx

Program code:

Int[cos[a_.+b_.*x_]^2*sin[a_.+b_.*x_]^2*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  1/4*Int[(g*Sin[c+d*x])^p,x] - 
  1/4*Int[Cos[c+d*x]^2*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && IGtQ[p/2,0]

2:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) ((Sin[c+d x])^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: Sin[z]==2 Cos[(z/2)]Sin[(z/2)]

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∈ℤ, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) ((Sin[c+d x])^p)dx  ⟶  ((2^p)/((e^p)(f^p)))∫(((e Cos[a+b x]))^(m+p))(((f Sin[a+b x]))^(n+p))dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_.*(f_.*sin[a_.+b_.*x_])^n_.*sin[c_.+d_.*x_]^p_.,x_Symbol] :=
  2^p/(e^p*f^p)*Int[(e*Cos[a+b*x])^(m+p)*(f*Sin[a+b*x])^(n+p),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && IntegerQ[p]

3.  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ

1:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+p-1==0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+p-1==0, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  ((e(((e Cos[a+b x]))^(m-1))(((f Sin[a+b x]))^(n+1)) (((g Sin[c+d x]))^p))/(b f(n+p+1)))

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_.*(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  e*(e*Cos[a+b*x])^(m-1)*(f*Sin[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*f*(n+p+1)) /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && EqQ[m+p+1,0]

Int[(e_.*sin[a_.+b_.*x_])^m_*(f_.*cos[a_.+b_.*x_])^n_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -e*(e*Sin[a+b*x])^(m-1)*(f*Cos[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*f*(n+p+1)) /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && EqQ[m+p+1,0]

2:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+n+2p+2==0 ∧ m+p+1≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+n+2p+2==0 ∧ m+p+1≠0, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  -(((((e Cos[a+b x]))^(m+1))(((f Sin[a+b x]))^(n+1)) (((g Sin[c+d x]))^p))/(b e f(m+p+1)))

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_.*(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -(e*Cos[a+b*x])^(m+1)*(f*Sin[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*e*f*(m+p+1)) /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && EqQ[m+n+2*p+2,0] && NeQ[m+p+1,0]

3.  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1

1.  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ p<-1

1:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>3 ∧ p<-1 ∧ n+p+1≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>3 ∧ p<-1 ∧ n+p+1≠0, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  
(((e^2)(((e Cos[a+b x]))^(m-2))(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^(p+1)))/(2b g(n+p+1)))+(((e^4)(m+p-1))/(4(g^2)(n+p+1)))∫(((e Cos[a+b x]))^(m-4))(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^(p+2))dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(f_.*sin[a_.+b_.*x_])^n_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  e^2*(e*Cos[a+b*x])^(m-2)*(f*Sin[a+b*x])^n*(g*Sin[c+d*x])^(p+1)/(2*b*g*(n+p+1)) + 
  e^4*(m+p-1)/(4*g^2*(n+p+1))*Int[(e*Cos[a+b*x])^(m-4)*(f*Sin[a+b*x])^n*(g*Sin[c+d*x])^(p+2),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,3] && LtQ[p,-1] && NeQ[n+p+1,0] && IntegersQ[2*m,2*n,2*p]

Int[(e_.*sin[a_.+b_.*x_])^m_*(f_.*cos[a_.+b_.*x_])^n_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -e^2*(e*Sin[a+b*x])^(m-2)*(f*Cos[a+b*x])^n*(g*Sin[c+d*x])^(p+1)/(2*b*g*(n+p+1)) + 
  e^4*(m+p-1)/(4*g^2*(n+p+1))*Int[(e*Sin[a+b*x])^(m-4)*(f*Cos[a+b*x])^n*(g*Sin[c+d*x])^(p+2),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,3] && LtQ[p,-1] && NeQ[n+p+1,0] && IntegersQ[2*m,2*n,2*p]

2:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ p<-1 ∧ m+n+2p+2≠0 ∧ n+p+1≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ p<-1 ∧ m+n+2p+2≠0 ∧ n+p+1≠0, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  
(((((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^(p+1)))/(2b g(n+p+1)))+(((e^2)(m+n+2p+2))/(4(g^2)(n+p+1)))∫(((e Cos[a+b x]))^(m-2))(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^(p+2))dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  (e*Cos[a+b*x])^m*(f*Sin[a+b*x])^n*(g*Sin[c+d*x])^(p+1)/(2*b*g*(n+p+1)) + 
  e^2*(m+n+2*p+2)/(4*g^2*(n+p+1))*Int[(e*Cos[a+b*x])^(m-2)*(f*Sin[a+b*x])^n*(g*Sin[c+d*x])^(p+2),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,1] && LtQ[p,-1] && NeQ[m+n+2*p+2,0] && NeQ[n+p+1,0] && 
  IntegersQ[2*m,2*n,2*p] && (LtQ[p,-2] || EqQ[m,2] || EqQ[m,3])

Int[(e_.*sin[a_.+b_.*x_])^m_*(f_.*cos[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -(e*Sin[a+b*x])^m*(f*Cos[a+b*x])^n*(g*Sin[c+d*x])^(p+1)/(2*b*g*(n+p+1)) + 
  e^2*(m+n+2*p+2)/(4*g^2*(n+p+1))*Int[(e*Sin[a+b*x])^(m-2)*(f*Cos[a+b*x])^n*(g*Sin[c+d*x])^(p+2),x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,1] && LtQ[p,-1] && NeQ[m+n+2*p+2,0] && NeQ[n+p+1,0] && 
  IntegersQ[2*m,2*n,2*p] && (LtQ[p,-2] || EqQ[m,2] || EqQ[m,3])

2:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ n<-1 ∧ n+p+1≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ n<-1 ∧ n+p+1≠0, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  
((e(((e Cos[a+b x]))^(m-1))(((f Sin[a+b x]))^(n+1)) (((g Sin[c+d x]))^p))/(b f(n+p+1)))+(((e^2)(m+p-1))/((f^2)(n+p+1)))∫(((e Cos[a+b x]))^(m-2))(((f Sin[a+b x]))^(n+2)) (((g Sin[c+d x]))^p)dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(f_.*sin[a_.+b_.*x_])^n_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  e*(e*Cos[a+b*x])^(m-1)*(f*Sin[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*f*(n+p+1)) + 
  e^2*(m+p-1)/(f^2*(n+p+1))*Int[(e*Cos[a+b*x])^(m-2)*(f*Sin[a+b*x])^(n+2)*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,g,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,1] && LtQ[n,-1] && NeQ[n+p+1,0] && IntegersQ[2*m,2*n,2*p]

Int[(e_.*sin[a_.+b_.*x_])^m_*(f_.*cos[a_.+b_.*x_])^n_*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -e*(e*Sin[a+b*x])^(m-1)*(f*Cos[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*f*(n+p+1)) + 
  e^2*(m+p-1)/(f^2*(n+p+1))*Int[(e*Sin[a+b*x])^(m-2)*(f*Cos[a+b*x])^(n+2)*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,g,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,1] && LtQ[n,-1] && NeQ[n+p+1,0] && IntegersQ[2*m,2*n,2*p]

3:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ m+n+2p≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m>1 ∧ m+n+2p≠0, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  
((e(((e Cos[a+b x]))^(m-1))(((f Sin[a+b x]))^(n+1)) (((g Sin[c+d x]))^p))/(b f(m+n+2p)))+(((e^2)(m+p-1))/(m+n+2p))∫(((e Cos[a+b x]))^(m-2))(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  e*(e*Cos[a+b*x])^(m-1)*(f*Sin[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*f*(m+n+2*p)) + 
  e^2*(m+p-1)/(m+n+2*p)*Int[(e*Cos[a+b*x])^(m-2)*(f*Sin[a+b*x])^n*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,1] && NeQ[m+n+2*p,0] && IntegersQ[2*m,2*n,2*p]

Int[(e_.*sin[a_.+b_.*x_])^m_*(f_.*cos[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -e*(e*Sin[a+b*x])^(m-1)*(f*Cos[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*f*(m+n+2*p)) + 
  e^2*(m+p-1)/(m+n+2*p)*Int[(e*Sin[a+b*x])^(m-2)*(f*Cos[a+b*x])^n*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && GtQ[m,1] && NeQ[m+n+2*p,0] && IntegersQ[2*m,2*n,2*p]

4.  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m<-1

1:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m<-1 ∧ n>0 ∧ p>0 ∧ m+n+2p≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m<-1 ∧ n>0 ∧ p>0 ∧ m+n+2p≠0, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  
-((f(((e Cos[a+b x]))^(m+1))(((f Sin[a+b x]))^(n-1)) (((g Sin[c+d x]))^p))/(b e(m+n+2p)))+((2f g(n+p-1))/(e(m+n+2p)))∫(((e Cos[a+b x]))^(m+1))(((f Sin[a+b x]))^(n-1)) (((g Sin[c+d x]))^(p-1))dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -f*(e*Cos[a+b*x])^(m+1)*(f*Sin[a+b*x])^(n-1)*(g*Sin[c+d*x])^p/(b*e*(m+n+2*p)) + 
  2*f*g*(n+p-1)/(e*(m+n+2*p))*Int[(e*Cos[a+b*x])^(m+1)*(f*Sin[a+b*x])^(n-1)*(g*Sin[c+d*x])^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && LtQ[m,-1] && GtQ[n,0] && GtQ[p,0] && NeQ[m+n+2*p,0] && 
  IntegersQ[2*m,2*n,2*p]

Int[(e_.*sin[a_.+b_.*x_])^m_*(f_.*cos[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  f*(e*Sin[a+b*x])^(m+1)*(f*Cos[a+b*x])^(n-1)*(g*Sin[c+d*x])^p/(b*e*(m+n+2*p)) + 
  2*f*g*(n+p-1)/(e*(m+n+2*p))*Int[(e*Sin[a+b*x])^(m+1)*(f*Cos[a+b*x])^(n-1)*(g*Sin[c+d*x])^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && LtQ[m,-1] && GtQ[n,0] && GtQ[p,0] && NeQ[m+n+2*p,0] && 
  IntegersQ[2*m,2*n,2*p]

2:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m<-1 ∧ n>0 ∧ p<-1 ∧ m+n+2p+2≠0 ∧ m+p+1≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m<-1 ∧ n>0 ∧ p<-1 ∧ m+n+2p+2≠0 ∧ m+p+1≠0, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  
-(((((e Cos[a+b x]))^(m+1))(((f Sin[a+b x]))^(n+1)) (((g Sin[c+d x]))^p))/(b e f(m+p+1)))+((f(m+n+2p+2))/(2e g(m+p+1)))∫(((e Cos[a+b x]))^(m+1))(((f Sin[a+b x]))^(n-1)) (((g Sin[c+d x]))^(p+1))dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -(e*Cos[a+b*x])^(m+1)*(f*Sin[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*e*f*(m+p+1)) + 
  f*(m+n+2*p+2)/(2*e*g*(m+p+1))*Int[(e*Cos[a+b*x])^(m+1)*(f*Sin[a+b*x])^(n-1)*(g*Sin[c+d*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && LtQ[m,-1] && GtQ[n,0] && LtQ[p,-1] && NeQ[m+n+2*p+2,0] && 
  NeQ[m+p+1,0] && IntegersQ[2*m,2*n,2*p]

Int[(e_.*sin[a_.+b_.*x_])^m_*(f_.*cos[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  (e*Sin[a+b*x])^(m+1)*(f*Cos[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*e*f*(m+p+1)) + 
  f*(m+n+2*p+2)/(2*e*g*(m+p+1))*Int[(e*Sin[a+b*x])^(m+1)*(f*Cos[a+b*x])^(n-1)*(g*Sin[c+d*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && LtQ[m,-1] && GtQ[n,0] && LtQ[p,-1] && NeQ[m+n+2*p+2,0] && 
  NeQ[m+p+1,0] && IntegersQ[2*m,2*n,2*p]

3:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m<-1 ∧ m+n+2p+2≠0 ∧ m+p+1≠0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m<-1 ∧ m+n+2p+2≠0 ∧ m+p+1≠0, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  
-(((((e Cos[a+b x]))^(m+1))(((f Sin[a+b x]))^(n+1)) (((g Sin[c+d x]))^p))/(b e f(m+p+1)))+((m+n+2p+2)/((e^2)(m+p+1)))∫(((e Cos[a+b x]))^(m+2))(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_*(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -(e*Cos[a+b*x])^(m+1)*(f*Sin[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*e*f*(m+p+1)) + 
  (m+n+2*p+2)/(e^2*(m+p+1))*Int[(e*Cos[a+b*x])^(m+2)*(f*Sin[a+b*x])^n*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && LtQ[m,-1] && NeQ[m+n+2*p+2,0] && NeQ[m+p+1,0] && 
  IntegersQ[2*m,2*n,2*p]

Int[(e_.*sin[a_.+b_.*x_])^m_*(f_.*cos[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  (e*Sin[a+b*x])^(m+1)*(f*Cos[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*e*f*(m+p+1)) + 
  (m+n+2*p+2)/(e^2*(m+p+1))*Int[(e*Sin[a+b*x])^(m+2)*(f*Cos[a+b*x])^n*(g*Sin[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && LtQ[m,-1] && NeQ[m+n+2*p+2,0] && NeQ[m+p+1,0] && 
  IntegersQ[2*m,2*n,2*p]

x:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+p∉ℤ ∧ n+p∉ℤ

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ ∧ m+p∉ℤ ∧ n+p∉ℤ, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  
-(((((e Cos[a+b x]))^(m+1))(((f Sin[a+b x]))^(n+1)) (((g Sin[c+d x]))^p))/(b e f(m+p+1)(((((Sin[a+b x])^2)))^((n+p+1)/2))))Hypergeometric2F1[-((n+p-1)/2),((m+p+1)/2),((m+p+3)/2),((Cos[a+b x])^2)]

Program code:

(* Int[(e_.*cos[a_.+b_.*x_])^m_*(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  -(e*Cos[a+b*x])^(m+1)*(f*Sin[a+b*x])^(n+1)*(g*Sin[c+d*x])^p/(b*e*f*(m+p+1)*(Sin[a+b*x]^2)^((n+p+1)/2))*
    Hypergeometric2F1[-(n+p-1)/2,(m+p+1)/2,(m+p+3)/2,Cos[a+b*x]^2] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]] && Not[IntegerQ[m+p]] && Not[IntegerQ[n+p]] *)

5:  ∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  when  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  b c-a d==0 ∧ (d/b)==2, then (∂_x)((((g Sin[c+d x]))^p)/((((e Cos[a+b x]))^p)(((f Sin[a+b x]))^p)))==0

Rule: If  b c-a d==0 ∧ (d/b)==2 ∧ p∉ℤ, then

∫(((e Cos[a+b x]))^m)(((f Sin[a+b x]))^n) (((g Sin[c+d x]))^p)dx  ⟶  ((((g Sin[c+d x]))^p)/((((e Cos[a+b x]))^p)(((f Sin[a+b x]))^p)))∫(((e Cos[a+b x]))^(m+p))(((f Sin[a+b x]))^(n+p))dx

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_.*(f_.*sin[a_.+b_.*x_])^n_.*(g_.*sin[c_.+d_.*x_])^p_,x_Symbol] :=
  (g*Sin[c+d*x])^p/((e*Cos[a+b*x])^p*(f*Sin[a+b*x])^p)*Int[(e*Cos[a+b*x])^(m+p)*(f*Sin[a+b*x])^(n+p),x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p},x] && EqQ[b*c-a*d,0] && EqQ[d/b,2] && Not[IntegerQ[p]]

3:  ∫(((e Cos[a+b x]))^m) Sin[c+d x]dx  when  b c-a d==0 ∧ (d/b)==Abs[m+2]

Rule: If  b c-a d==0 ∧ (d/b)==Abs[m+2], then

∫(((e Cos[a+b x]))^m) Sin[c+d x]dx  ⟶  -(((m+2)(((e Cos[a+b x]))^(m+1)) Cos[(m+1) (a+b x)])/(d e(m+1)))

Program code:

Int[(e_.*cos[a_.+b_.*x_])^m_.*sin[c_.+d_.*x_],x_Symbol] :=
  -(m+2)*(e*Cos[a+b*x])^(m+1)*Cos[(m+1)*(a+b*x)]/(d*e*(m+1)) /;
FreeQ[{a,b,c,d,e,m},x] && EqQ[b*c-a*d,0] && EqQ[d/b,Abs[m+2]]