Rules for integrands of the formu ((Trig[d (a+b Log[c (x^n)])])^p)

1.  ∫u ((Sin[d (a+b Log[c (x^n)])])^p)dx

1.  ∫((Sin[d (a+b Log[c (x^n)])])^p)dx

1.  ∫((Sin[d (a+b Log[c (x^n)])])^p)dx  when  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)+1≠0

1:  ∫Sin[d (a+b Log[c (x^n)])]dx  when  (b^2) (d^2) (n^2)+1≠0

Rule: If  (b^2) (d^2) (n^2)+1≠0, then

∫Sin[d (a+b Log[c (x^n)])]dx  ⟶  ((x Sin[d (a+b Log[c (x^n)])])/((b^2) (d^2) (n^2)+1))-((b d n x Cos[d (a+b Log[c (x^n)])])/((b^2) (d^2) (n^2)+1))

Program code:

Int[Sin[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  x*Sin[d*(a+b*Log[c*x^n])]/(b^2*d^2*n^2+1) - 
  b*d*n*x*Cos[d*(a+b*Log[c*x^n])]/(b^2*d^2*n^2+1) /;
FreeQ[{a,b,c,d,n},x] && NeQ[b^2*d^2*n^2+1,0]

Int[Cos[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  x*Cos[d*(a+b*Log[c*x^n])]/(b^2*d^2*n^2+1) + 
  b*d*n*x*Sin[d*(a+b*Log[c*x^n])]/(b^2*d^2*n^2+1) /;
FreeQ[{a,b,c,d,n},x] && NeQ[b^2*d^2*n^2+1,0]

2:  ∫((Sin[d (a+b Log[c (x^n)])])^p)dx  when  p-1∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)+1≠0

Rule: If  p-1∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)+1≠0, then

∫((Sin[d (a+b Log[c (x^n)])])^p)dx  ⟶  
((x ((Sin[d (a+b Log[c (x^n)])])^p))/((b^2) (d^2) (n^2) (p^2)+1))-((b d n p x Cos[d (a+b Log[c (x^n)])] ((Sin[d (a+b Log[c (x^n)])])^(p-1)))/((b^2) (d^2) (n^2) (p^2)+1))+(((b^2) (d^2) (n^2) p (p-1))/((b^2) (d^2) (n^2) (p^2)+1))∫((Sin[d (a+b Log[c (x^n)])])^(p-2))dx

Program code:

Int[Sin[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_,x_Symbol] :=
  x*Sin[d*(a+b*Log[c*x^n])]^p/(b^2*d^2*n^2*p^2+1) -
  b*d*n*p*x*Cos[d*(a+b*Log[c*x^n])]*Sin[d*(a+b*Log[c*x^n])]^(p-1)/(b^2*d^2*n^2*p^2+1) +
  b^2*d^2*n^2*p*(p-1)/(b^2*d^2*n^2*p^2+1)*Int[Sin[d*(a+b*Log[c*x^n])]^(p-2),x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[p,1] && NeQ[b^2*d^2*n^2*p^2+1,0]

Int[Cos[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_,x_Symbol] :=
  x*Cos[d*(a+b*Log[c*x^n])]^p/(b^2*d^2*n^2*p^2+1) +
  b*d*n*p*x*Cos[d*(a+b*Log[c*x^n])]^(p-1)*Sin[d*(a+b*Log[c*x^n])]/(b^2*d^2*n^2*p^2+1) +
  b^2*d^2*n^2*p*(p-1)/(b^2*d^2*n^2*p^2+1)*Int[Cos[d*(a+b*Log[c*x^n])]^(p-2),x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[p,1] && NeQ[b^2*d^2*n^2*p^2+1,0]

2.  ∫((Sin[d (a+b Log[x])])^p)dx

1:  ∫((Sin[d (a+b Log[x])])^p)dx  when  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (p^2)+1==0

Derivation: Algebraic expansion

Basis: If  (b^2) (d^2) (p^2)+1==0 ∧ p∈ℤ, then ((Sin[d (a+b Log[x])])^p)==(1/((2^p) (b^p) (d^p) (p^p))) ((((e^(a b (d^2) p)) (x^(-(1/p)))-(e^(-a b (d^2) p)) (x^(1/p))))^p)

Basis: If  (b^2) (d^2) (p^2)+1==0 ∧ p∈ℤ, then ((Cos[d (a+b Log[x])])^p)==(1/(2^p)) ((((e^(a b (d^2) p)) (x^(-(1/p)))+(e^(-a b (d^2) p)) (x^(1/p))))^p)

Note: The above identities need to be formally derived, and possibly the domain of p expanded.

Rule: If  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (p^2)+1==0, then

∫((Sin[d (a+b Log[x])])^p)dx  ⟶  (1/((2^p) (b^p) (d^p) (p^p))) ∫ExpandIntegrand[((((e^(a b (d^2) p)) (x^(-(1/p)))-(e^(-a b (d^2) p)) (x^(1/p))))^p),x]dx

Program code:

Int[Sin[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  1/(2^p*b^p*d^p*p^p)*Int[ExpandIntegrand[(E^(a*b*d^2*p)*x^(-1/p)-E^(-a*b*d^2*p)*x^(1/p))^p,x],x] /;
FreeQ[{a,b,d},x] && IGtQ[p,0] && EqQ[b^2*d^2*p^2+1,0]

Int[Cos[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  1/2^p*Int[ExpandIntegrand[(E^(a*b*d^2*p)*x^(-1/p)+E^(-a*b*d^2*p)*x^(1/p))^p,x],x] /;
FreeQ[{a,b,d},x] && IGtQ[p,0] && EqQ[b^2*d^2*p^2+1,0]

x:  ∫((Sin[d (a+b Log[x])])^p)dx  when  p∈ℤ

Derivation: Algebraic expansion

Basis: Sin[d (a+b Log[x])]==((1-(e^(2 i a d)) (x^(2 i b d)))/(-2 i (e^(i a d)) (x^(i b d))))

Basis: Cos[d (a+b Log[x])]==((1+(e^(2 i a d)) (x^(2 i b d)))/(2 (e^(i a d)) (x^(i b d))))

Rule: If  p∈ℤ, then

∫((Sin[d (a+b Log[x])])^p)dx  ⟶  (1/((((-2 i))^p) (e^(i a d p)))) ∫((((1-(e^(2 i a d)) (x^(2 i b d))))^p)/(x^(i b d p)))dx

Program code:

(* Int[Sin[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  1/((-2*I)^p*E^(I*a*d*p))*Int[(1-E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p),x] /;
FreeQ[{a,b,d},x] && IntegerQ[p] *)

(* Int[Cos[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  1/(2^p*E^(I*a*d*p))*Int[(1+E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p),x] /;
FreeQ[{a,b,d},x] && IntegerQ[p] *)

2:  ∫((Sin[d (a+b Log[x])])^p)dx  when  p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((Sin[d (a+b Log[x])])^p) (x^(i b d p)))/(((1-(e^(2 i a d)) (x^(2 i b d))))^p))==0

Basis: (∂_x)((((Cos[d (a+b Log[x])])^p) (x^(i b d p)))/(((1+(e^(2 i a d)) (x^(2 i b d))))^p))==0

Rule: If  p∉ℤ, then

∫((Sin[d (a+b Log[x])])^p)dx  ⟶  ((((Sin[d (a+b Log[x])])^p) (x^(i b d p)))/(((1-(e^(2 i a d)) (x^(2 i b d))))^p)) ∫((((1-(e^(2 i a d)) (x^(2 i b d))))^p)/(x^(i b d p)))dx

Program code:

Int[Sin[d_.*(a_.+b_.*Log[x_])]^p_,x_Symbol] :=
  Sin[d*(a+b*Log[x])]^p*x^(I*b*d*p)/(1-E^(2*I*a*d)*x^(2*I*b*d))^p*
    Int[(1-E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p),x] /;
FreeQ[{a,b,d,p},x] && Not[IntegerQ[p]]

Int[Cos[d_.*(a_.+b_.*Log[x_])]^p_,x_Symbol] :=
  Cos[d*(a+b*Log[x])]^p*x^(I*b*d*p)/(1+E^(2*I*a*d)*x^(2*I*b*d))^p*
    Int[(1+E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p),x] /;
FreeQ[{a,b,d,p},x] && Not[IntegerQ[p]]

3:  ∫((Sin[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫((Sin[d (a+b Log[c (x^n)])])^p)dx  ⟶  (x/(((c (x^n)))^(1/n))) ∫(((((c (x^n)))^(1/n)) ((Sin[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  (x/(n (((c (x^n)))^(1/n)))) Subst[∫(x^(1/n-1)) ((Sin[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[Sin[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Sin[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[Cos[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Cos[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

2.  ∫(((e x))^m)((Sin[d (a+b Log[c (x^n)])])^p)dx

1.  ∫(((e x))^m)((Sin[d (a+b Log[c (x^n)])])^p)dx  when  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)+(((m+1))^2)≠0

1:  ∫(((e x))^m)Sin[d (a+b Log[c (x^n)])]dx  when  (b^2) (d^2) (n^2)+(((m+1))^2)≠0

Rule: If  (b^2) (d^2) (n^2)+(((m+1))^2)≠0, then

∫(((e x))^m)Sin[d (a+b Log[c (x^n)])]dx  ⟶  (((m+1) (((e x))^(m+1)) Sin[d (a+b Log[c (x^n)])])/((b^2) (d^2) e (n^2)+e (((m+1))^2)))-((b d n (((e x))^(m+1)) Cos[d (a+b Log[c (x^n)])])/((b^2) (d^2) e (n^2)+e (((m+1))^2)))

Program code:

Int[(e_.*x_)^m_.*Sin[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  (m+1)*(e*x)^(m+1)*Sin[d*(a+b*Log[c*x^n])]/(b^2*d^2*e*n^2+e*(m+1)^2) - 
  b*d*n*(e*x)^(m+1)*Cos[d*(a+b*Log[c*x^n])]/(b^2*d^2*e*n^2+e*(m+1)^2) /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[b^2*d^2*n^2+(m+1)^2,0]

Int[(e_.*x_)^m_.*Cos[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  (m+1)*(e*x)^(m+1)*Cos[d*(a+b*Log[c*x^n])]/(b^2*d^2*e*n^2+e*(m+1)^2) + 
  b*d*n*(e*x)^(m+1)*Sin[d*(a+b*Log[c*x^n])]/(b^2*d^2*e*n^2+e*(m+1)^2) /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[b^2*d^2*n^2+(m+1)^2,0]

2:  ∫(((e x))^m)((Sin[d (a+b Log[c (x^n)])])^p)dx  when  p-1∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)+(((m+1))^2)≠0

Rule: If  p-1∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)+(((m+1))^2)≠0, then

∫(((e x))^m)((Sin[d (a+b Log[c (x^n)])])^p)dx  ⟶  

(((m+1) (((e x))^(m+1)) ((Sin[d (a+b Log[c (x^n)])])^p))/((b^2) (d^2) e (n^2) (p^2)+e (((m+1))^2)))-((b d n p (((e x))^(m+1)) Cos[d (a+b Log[c (x^n)])] ((Sin[d (a+b Log[c (x^n)])])^(p-1)))/((b^2) (d^2) e (n^2) (p^2)+e (((m+1))^2)))+
(((b^2) (d^2) (n^2) p (p-1))/((b^2) (d^2) (n^2) (p^2)+(((m+1))^2)))∫(((e x))^m) ((Sin[d (a+b Log[c (x^n)])])^(p-2))dx

Program code:

Int[(e_.*x_)^m_.*Sin[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_,x_Symbol] :=
  (m+1)*(e*x)^(m+1)*Sin[d*(a+b*Log[c*x^n])]^p/(b^2*d^2*e*n^2*p^2+e*(m+1)^2) - 
  b*d*n*p*(e*x)^(m+1)*Cos[d*(a+b*Log[c*x^n])]*Sin[d*(a+b*Log[c*x^n])]^(p-1)/(b^2*d^2*e*n^2*p^2+e*(m+1)^2) + 
  b^2*d^2*n^2*p*(p-1)/(b^2*d^2*n^2*p^2+(m+1)^2)*Int[(e*x)^m*Sin[d*(a+b*Log[c*x^n])]^(p-2),x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IGtQ[p,1] && NeQ[b^2*d^2*n^2*p^2+(m+1)^2,0]

Int[(e_.*x_)^m_.*Cos[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_,x_Symbol] :=
  (m+1)*(e*x)^(m+1)*Cos[d*(a+b*Log[c*x^n])]^p/(b^2*d^2*e*n^2*p^2+e*(m+1)^2) + 
  b*d*n*p*(e*x)^(m+1)*Sin[d*(a+b*Log[c*x^n])]*Cos[d*(a+b*Log[c*x^n])]^(p-1)/(b^2*d^2*e*n^2*p^2+e*(m+1)^2) + 
  b^2*d^2*n^2*p*(p-1)/(b^2*d^2*n^2*p^2+(m+1)^2)*Int[(e*x)^m*Cos[d*(a+b*Log[c*x^n])]^(p-2),x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IGtQ[p,1] && NeQ[b^2*d^2*n^2*p^2+(m+1)^2,0]

2.  ∫(((e x))^m) ((Sin[d (a+b Log[x])])^p)dx

1:  ∫(((e x))^m)((Sin[d (a+b Log[x])])^p)dx  when  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (p^2)+(((m+1))^2)==0

Derivation: Algebraic expansion

Basis: If  (b^2) (d^2) (p^2)+(((m+1))^2)==0 ∧ p∈ℤ, then ((Sin[d (a+b Log[x])])^p)==((((m+1))^p)/((2^p) (b^p) (d^p) (p^p)))((((e^((a b (d^2) p)/(m+1)))(x^(-((m+1)/p)))-(e^(-((a b (d^2) p)/(m+1))))(x^((m+1)/p))))^p)

Basis: If  (b^2) (d^2) (p^2)+(((m+1))^2)==0 ∧ p∈ℤ, then ((Cos[d (a+b Log[x])])^p)==(1/(2^p))((((e^((a b (d^2) p)/(m+1)))(x^(-((m+1)/p)))+(e^(-((a b (d^2) p)/(m+1)))) (x^((m+1)/p))))^p)

Note: The above identities need to be formally derived, and possibly the domain of p expanded.

Rule: If  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (p^2)+(((m+1))^2)==0, then

∫(((e x))^m)((Sin[d (a+b Log[x])])^p)dx  ⟶  ((((m+1))^p)/((2^p) (b^p) (d^p) (p^p))) ∫ExpandIntegrand[(((e x))^m)((((e^((a b (d^2) p)/(m+1)))(x^(-((m+1)/p)))-(e^(-((a b (d^2) p)/(m+1))))(x^((m+1)/p))))^p),x]dx

Program code:

Int[(e_.*x_)^m_.*Sin[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  (m+1)^p/(2^p*b^p*d^p*p^p)*
    Int[ExpandIntegrand[(e*x)^m*(E^(a*b*d^2*p/(m+1))*x^(-(m+1)/p)-E^(-a*b*d^2*p/(m+1))*x^((m+1)/p))^p,x],x] /;
FreeQ[{a,b,d,e,m},x] && IGtQ[p,0] && EqQ[b^2*d^2*p^2+(m+1)^2,0]

Int[(e_.*x_)^m_.*Cos[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  1/2^p*Int[ExpandIntegrand[(e*x)^m*(E^(a*b*d^2*p/(m+1))*x^(-(m+1)/p)+E^(-a*b*d^2*p/(m+1))*x^((m+1)/p))^p,x],x] /;
FreeQ[{a,b,d,e,m},x] && IGtQ[p,0] && EqQ[b^2*d^2*p^2+(m+1)^2,0]

x:  ∫(((e x))^m) ((Sin[d (a+b Log[x])])^p)dx  when  p∈ℤ

Derivation: Algebraic expansion

Basis: Sin[d (a+b Log[x])]==((1-(e^(2 i a d)) (x^(2 i b d)))/(-2 i (e^(i a d)) (x^(i b d))))

Basis: Cos[d (a+b Log[x])]==((1+(e^(2 i a d)) (x^(2 i b d)))/(2 (e^(i a d)) (x^(i b d))))

Rule: If  p∈ℤ, then

∫(((e x))^m) ((Sin[d (a+b Log[x])])^p)dx  ⟶  (1/((((-2 i))^p) (e^(i a d p)))) ∫(((((e x))^m) (((1-(e^(2 i a d)) (x^(2 i b d))))^p))/(x^(i b d p)))dx

Program code:

(* Int[(e_.*x_)^m_.*Sin[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  1/((-2*I)^p*E^(I*a*d*p))*Int[(e*x)^m*(1-E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p),x] /;
FreeQ[{a,b,d,e,m},x] && IntegerQ[p] *)

(* Int[(e_.*x_)^m_.*Cos[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  1/(2^p*E^(I*a*d*p))*Int[(e*x)^m*(1+E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p),x] /;
FreeQ[{a,b,d,e,m},x] && IntegerQ[p] *)

2:  ∫(((e x))^m) ((Sin[d (a+b Log[x])])^p)dx  when  p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((Sin[d (a+b Log[x])])^p) (x^(i b d p)))/(((1-(e^(2 i a d)) (x^(2 i b d))))^p))==0

Basis: (∂_x)((((Cos[d (a+b Log[x])])^p) (x^(i b d p)))/(((1+(e^(2 i a d)) (x^(2 i b d))))^p))==0

Rule: If  p∉ℤ, then

∫(((e x))^m) ((Sin[d (a+b Log[x])])^p)dx  ⟶  ((((Sin[d (a+b Log[x])])^p) (x^(i b d p)))/(((1-(e^(2 i a d)) (x^(2 i b d))))^p)) ∫(((((e x))^m) (((1-(e^(2 i a d)) (x^(2 i b d))))^p))/(x^(i b d p)))dx

Program code:

Int[(e_.*x_)^m_.*Sin[d_.*(a_.+b_.*Log[x_])]^p_,x_Symbol] :=
  Sin[d*(a+b*Log[x])]^p*x^(I*b*d*p)/(1-E^(2*I*a*d)*x^(2*I*b*d))^p*
    Int[(e*x)^m*(1-E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p),x] /;
FreeQ[{a,b,d,e,m,p},x] && Not[IntegerQ[p]]

Int[(e_.*x_)^m_.*Cos[d_.*(a_.+b_.*Log[x_])]^p_,x_Symbol] :=
  Cos[d*(a+b*Log[x])]^p*x^(I*b*d*p)/(1+E^(2*I*a*d)*x^(2*I*b*d))^p*
    Int[(e*x)^m*(1+E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p),x] /;
FreeQ[{a,b,d,e,m,p},x] && Not[IntegerQ[p]]

3:  ∫(((e x))^m) ((Sin[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫(((e x))^m) ((Sin[d (a+b Log[c (x^n)])])^p)dx  ⟶  ((((e x))^(m+1))/(e (((c (x^n)))^((m+1)/n)))) ∫(((((c (x^n)))^((m+1)/n)) ((Sin[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  ((((e x))^(m+1))/(e n (((c (x^n)))^((m+1)/n)))) Subst[∫(x^((m+1)/n-1)) ((Sin[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[(e_.*x_)^m_.*Sin[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Sin[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[(e_.*x_)^m_.*Cos[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Cos[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

3:  ∫(((h (e+f Log[g (x^m)])))^q) Sin[d (a+b Log[c (x^n)])]dx

Derivation: Algebraic expansion and piecewise constant extraction

Basis: Sin[d (a+b Log[z])]==(i/2) (e^(-i a d)) (z^(-i b d))-(i/2) (e^(i a d)) (z^(i b d))

Basis: Cos[d (a+b Log[z])]==(1/2) (e^(-i a d)) (z^(-i b d))+(1/2) (e^(i a d)) (z^(i b d))

Rule:

∫(((h (e+f Log[g (x^m)])))^q) Sin[d (a+b Log[c (x^n)])]dx  ⟶  
((i (e^(-i a d)) (((c (x^n)))^(-i b d)))/(2 (x^(-i b d n)))) ∫(x^(-i b d n)) (((h (e+f Log[g (x^m)])))^q)dx-((i (e^(i a d)) (((c (x^n)))^(i b d)))/(2 (x^(i b d n)))) ∫(x^(i b d n)) (((h (e+f Log[g (x^m)])))^q)dx

Program code:

Int[(h_.*(e_.+f_.*Log[g_.*x_^m_.]))^q_.*Sin[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  I*E^(-I*a*d)*(c*x^n)^(-I*b*d)/(2*x^(-I*b*d*n))*Int[x^(-I*b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] - 
  I*E^(I*a*d)*(c*x^n)^(I*b*d)/(2*x^(I*b*d*n))*Int[x^(I*b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n,q},x]

Int[(h_.*(e_.+f_.*Log[g_.*x_^m_.]))^q_.*Cos[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  E^(-I*a*d)*(c*x^n)^(-I*b*d)/(2*x^(-I*b*d*n))*Int[x^(-I*b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] + 
  E^(I*a*d)*(c*x^n)^(I*b*d)/(2*x^(I*b*d*n))*Int[x^(I*b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n,q},x]

4:  ∫(((i x))^r) (((h (e+f Log[g (x^m)])))^q) Sin[d (a+b Log[c (x^n)])]dx

Derivation: Algebraic expansion and piecewise constant extraction

Basis: Sin[d (a+b Log[z])]==(i/2) (e^(-i a d)) (z^(-i b d))-(i/2) (e^(i a d)) (z^(i b d))

Basis: Cos[d (a+b Log[z])]==(1/2) (e^(-i a d)) (z^(-i b d))+(1/2) (e^(i a d)) (z^(i b d))

Rule:

∫(((i x))^r) (((h (e+f Log[g (x^m)])))^q) Sin[d (a+b Log[c (x^n)])]dx  ⟶  
((i (e^(-i a d)) (((i x))^r) (((c (x^n)))^(-i b d)))/(2 (x^(r-i b d n)))) ∫(x^(r-i b d n)) (((h (e+f Log[g (x^m)])))^q)dx-((i (e^(i a d)) (((i x))^r) (((c (x^n)))^(i b d)))/(2 (x^(r+i b d n)))) ∫(x^(r+i b d n)) (((h (e+f Log[g (x^m)])))^q)dx

Program code:

Int[(i_.*x_)^r_.*(h_.*(e_.+f_.*Log[g_.*x_^m_.]))^q_.*Sin[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  I*E^(-I*a*d)*(i*x)^r*(c*x^n)^(-I*b*d)/(2*x^(r-I*b*d*n))*Int[x^(r-I*b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] - 
  I*E^(I*a*d)*(i*x)^r*(c*x^n)^(I*b*d)/(2*x^(r+I*b*d*n))*Int[x^(r+I*b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,m,n,q,r},x]

Int[(i_.*x_)^r_.*(h_.*(e_.+f_.*Log[g_.*x_^m_.]))^q_.*Cos[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  E^(-I*a*d)*(i*x)^r*(c*x^n)^(-I*b*d)/(2*x^(r-I*b*d*n))*Int[x^(r-I*b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] + 
  E^(I*a*d)*(i*x)^r*(c*x^n)^(I*b*d)/(2*x^(r+I*b*d*n))*Int[x^(r+I*b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,m,n,q,r},x]

2.  ∫u ((Tan[d (a+b Log[c (x^n)])])^p)dx

1.  ∫((Tan[d (a+b Log[c (x^n)])])^p)dx

1:  ∫((Tan[d (a+b Log[x])])^p)dx

Derivation: Algebraic expansion

Basis: Tan[z]==((i -i (e^(2 i z)))/(1+(e^(2 i z))))

Basis: Cot[z]==((-i -i (e^(2 i z)))/(1-(e^(2 i z))))

Rule:

∫((Tan[d (a+b Log[x])])^p)dx  ⟶  ∫(((((i-i (e^(2 i a d)) (x^(2 i b d)))/(1+(e^(2 i a d)) (x^(2 i b d))))))^p)dx

Program code:

Int[Tan[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Int[((I-I*E^(2*I*a*d)*x^(2*I*b*d))/(1+E^(2*I*a*d)*x^(2*I*b*d)))^p,x] /;
FreeQ[{a,b,d,p},x]

Int[Cot[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Int[((-I-I*E^(2*I*a*d)*x^(2*I*b*d))/(1-E^(2*I*a*d)*x^(2*I*b*d)))^p,x] /;
FreeQ[{a,b,d,p},x]

2:  ∫((Tan[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫((Tan[d (a+b Log[c (x^n)])])^p)dx  ⟶  (x/(((c (x^n)))^(1/n))) ∫(((((c (x^n)))^(1/n)) ((Tan[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  (x/(n (((c (x^n)))^(1/n)))) Subst[∫(x^(1/n-1)) ((Tan[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[Tan[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Tan[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[Cot[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Cot[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

2.  ∫(((e x))^m)((Tan[d (a+b Log[c (x^n)])])^p)dx

1:  ∫(((e x))^m) ((Tan[d (a+b Log[x])])^p)dx

Derivation: Algebraic expansion

Basis: Tan[z]==((i -i (e^(2 i z)))/(1+(e^(2 i z))))

Basis: Cot[z]==((-i -i (e^(2 i z)))/(1-(e^(2 i z))))

Rule:

∫(((e x))^m) ((Tan[d (a+b Log[x])])^p)dx  ⟶  ∫(((e x))^m) (((((i-i (e^(2 i a d)) (x^(2 i b d)))/(1+(e^(2 i a d)) (x^(2 i b d))))))^p)dx

Program code:

Int[(e_.*x_)^m_.*Tan[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Int[(e*x)^m*((I-I*E^(2*I*a*d)*x^(2*I*b*d))/(1+E^(2*I*a*d)*x^(2*I*b*d)))^p,x] /;
FreeQ[{a,b,d,e,m,p},x]

Int[(e_.*x_)^m_.*Cot[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Int[(e*x)^m*((-I-I*E^(2*I*a*d)*x^(2*I*b*d))/(1-E^(2*I*a*d)*x^(2*I*b*d)))^p,x] /;
FreeQ[{a,b,d,e,m,p},x]

2:  ∫(((e x))^m) ((Tan[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫(((e x))^m) ((Tan[d (a+b Log[c (x^n)])])^p)dx  ⟶  ((((e x))^(m+1))/(e (((c (x^n)))^((m+1)/n)))) ∫(((((c (x^n)))^((m+1)/n)) ((Tan[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  ((((e x))^(m+1))/(e n (((c (x^n)))^((m+1)/n)))) Subst[∫(x^((m+1)/n-1)) ((Tan[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[(e_.*x_)^m_.*Tan[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Tan[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[(e_.*x_)^m_.*Cot[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Cot[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

3.  ∫u ((Sec[d (a+b Log[c (x^n)])])^p)dx

1.  ∫((Sec[d (a+b Log[c (x^n)])])^p)dx

1.  ∫((Sec[d (a+b Log[x])])^p)dx

1:  ∫((Sec[d (a+b Log[x])])^p)dx  when  p∈ℤ

Derivation: Algebraic expansion

Basis: Sec[d (a+b Log[x])]==((2 (e^(i a d)) (x^(i b d)))/(1+(e^(2 i a d)) (x^(2 i b d))))

Basis: Csc[d (a+b Log[x])]==-((2 i (e^(i a d)) (x^(i b d)))/(1-(e^(2 i a d)) (x^(2 i b d))))

Rule: If  p∈ℤ, then

∫((Sec[d (a+b Log[x])])^p)dx  ⟶  (2^p) (e^(i a d p)) ∫((x^(i b d p))/(((1+(e^(2 i a d)) (x^(2 i b d))))^p))dx

Program code:

Int[Sec[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  2^p*E^(I*a*d*p)*Int[x^(I*b*d*p)/(1+E^(2*I*a*d)*x^(2*I*b*d))^p,x] /;
FreeQ[{a,b,d},x] && IntegerQ[p]

Int[Csc[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  (-2*I)^p*E^(I*a*d*p)*Int[x^(I*b*d*p)/(1-E^(2*I*a*d)*x^(2*I*b*d))^p,x] /;
FreeQ[{a,b,d},x] && IntegerQ[p]

2:  ∫((Sec[d (a+b Log[x])])^p)dx  when  p∉ℤ

Derivation: Algebraic expansion and piecewise constant extraction

Basis: (∂_x)((((Sec[d (a+b Log[x])])^p) (((1+(e^(2 i a d)) (x^(2 i b d))))^p))/(x^(i b d p)))==0

Basis: (∂_x)((((Csc[d (a+b Log[x])])^p) (((1-(e^(2 i a d)) (x^(2 i b d))))^p))/(x^(i b d p)))==0

Rule: If  p∉ℤ, then

∫((Sec[d (a+b Log[x])])^p)dx  ⟶  ((((Sec[d (a+b Log[x])])^p) (((1+(e^(2 i a d)) (x^(2 i b d))))^p))/(x^(i b d p))) ∫((x^(i b d p))/(((1+(e^(2 i a d)) (x^(2 i b d))))^p))dx

Program code:

Int[Sec[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Sec[d*(a+b*Log[x])]^p*(1+E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p)*
    Int[x^(I*b*d*p)/(1+E^(2*I*a*d)*x^(2*I*b*d))^p,x] /;
FreeQ[{a,b,d,p},x] && Not[IntegerQ[p]]

Int[Csc[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Csc[d*(a+b*Log[x])]^p*(1-E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p)*
    Int[x^(I*b*d*p)/(1-E^(2*I*a*d)*x^(2*I*b*d))^p,x] /;
FreeQ[{a,b,d,p},x] && Not[IntegerQ[p]]

2:  ∫((Sec[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫((Sec[d (a+b Log[c (x^n)])])^p)dx  ⟶  (x/(((c (x^n)))^(1/n))) ∫(((((c (x^n)))^(1/n)) ((Sec[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  (x/(n (((c (x^n)))^(1/n)))) Subst[∫(x^(1/n-1)) ((Sec[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[Sec[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Sec[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[Csc[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Csc[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

2.  ∫(((e x))^m) ((Sec[d (a+b Log[c (x^n)])])^p)dx

1.  ∫(((e x))^m) ((Sec[d (a+b Log[x])])^p)dx

1:  ∫(((e x))^m) ((Sec[d (a+b Log[x])])^p)dx  when  p∈ℤ

Derivation: Algebraic expansion

Basis: Sec[d (a+b Log[x])]==((2 (e^(i a d)) (x^(i b d)))/(1+(e^(2 i a d)) (x^(2 i b d))))

Basis: Csc[d (a+b Log[x])]==-((2 i (e^(i a d)) (x^(i b d)))/(1-(e^(2 i a d)) (x^(2 i b d))))

Rule: If  p∈ℤ, then

∫(((e x))^m) ((Sec[d (a+b Log[x])])^p)dx  ⟶  (2^p) (e^(i a d p)) ∫(((((e x))^m) (x^(i b d p)))/(((1+(e^(2 i a d)) (x^(2 i b d))))^p))dx

Program code:

Int[(e_.*x_)^m_.*Sec[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  2^p*E^(I*a*d*p)*Int[(e*x)^m*x^(I*b*d*p)/(1+E^(2*I*a*d)*x^(2*I*b*d))^p,x] /;
FreeQ[{a,b,d,e,m},x] && IntegerQ[p]

Int[(e_.*x_)^m_.*Csc[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  (-2*I)^p*E^(I*a*d*p)*Int[(e*x)^m*x^(I*b*d*p)/(1-E^(2*I*a*d)*x^(2*I*b*d))^p,x] /;
FreeQ[{a,b,d,e,m},x] && IntegerQ[p]

2:  ∫(((e x))^m) ((Sec[d (a+b Log[x])])^p)dx  when  p∉ℤ

Derivation: Algebraic expansion and piecewise constant extraction

Basis: (∂_x)((((Sec[d (a+b Log[x])])^p) (((1+(e^(2 i a d)) (x^(2 i b d))))^p))/(x^(i b d p)))==0

Basis: (∂_x)((((Csc[d (a+b Log[x])])^p) (((1-(e^(2 i a d)) (x^(2 i b d))))^p))/(x^(i b d p)))==0

Rule: If  p∉ℤ, then

∫(((e x))^m) ((Sec[d (a+b Log[x])])^p)dx  ⟶  ((((Sec[d (a+b Log[x])])^p) (((1+(e^(2 i a d)) (x^(2 i b d))))^p))/(x^(i b d p))) ∫(((((e x))^m) (x^(i b d p)))/(((1+(e^(2 i a d)) (x^(2 i b d))))^p))dx

Program code:

Int[(e_.*x_)^m_.*Sec[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Sec[d*(a+b*Log[x])]^p*(1+E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p)*
    Int[(e*x)^m*x^(I*b*d*p)/(1+E^(2*I*a*d)*x^(2*I*b*d))^p,x] /;
FreeQ[{a,b,d,e,m,p},x] && Not[IntegerQ[p]]

Int[(e_.*x_)^m_.*Csc[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Csc[d*(a+b*Log[x])]^p*(1-E^(2*I*a*d)*x^(2*I*b*d))^p/x^(I*b*d*p)*
    Int[(e*x)^m*x^(I*b*d*p)/(1-E^(2*I*a*d)*x^(2*I*b*d))^p,x] /;
FreeQ[{a,b,d,e,m,p},x] && Not[IntegerQ[p]]

2:  ∫(((e x))^m) ((Sec[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫(((e x))^m) ((Sec[d (a+b Log[c (x^n)])])^p)dx  ⟶  ((((e x))^(m+1))/(e (((c (x^n)))^((m+1)/n)))) ∫(((((c (x^n)))^((m+1)/n)) ((Sec[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  ((((e x))^(m+1))/(e n (((c (x^n)))^((m+1)/n)))) Subst[∫(x^((m+1)/n-1)) ((Sec[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[(e_.*x_)^m_.*Sec[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Sec[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[(e_.*x_)^m_.*Csc[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Csc[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Rules for integrands of the formu Trig[a (x^n) Log[b x]] Log[b x]

1.  ∫u Sin[a (x^n) Log[b x]] Log[b x]dx

1:  ∫Sin[a x Log[b x]] Log[b x]dx

Rule:

∫Sin[a x Log[b x]] Log[b x]dx  ⟶  -((Cos[a x Log[b x]])/a)-∫Sin[a x Log[b x]]dx

Program code:

Int[Sin[a_.*x_*Log[b_.*x_]]*Log[b_.*x_],x_Symbol] :=
  -Cos[a*x*Log[b*x]]/a - Int[Sin[a*x*Log[b*x]],x] /;
FreeQ[{a,b},x]

Int[Cos[a_.*x_*Log[b_.*x_]]*Log[b_.*x_],x_Symbol] :=
  Sin[a*x*Log[b*x]]/a - Int[Cos[a*x*Log[b*x]],x] /;
FreeQ[{a,b},x]

2:  ∫(x^m)Sin[a (x^n) Log[b x]] Log[b x]dx  when  m==n-1

Rule: If  m==n-1, then

∫(x^m)Sin[a (x^n) Log[b x]] Log[b x]dx  ⟶  -((Cos[a (x^n) Log[b x]])/(a n))-(1/n)∫(x^m) Sin[a (x^n) Log[b x]]dx

Program code:

Int[x_^m_.*Sin[a_.*x_^n_.*Log[b_.*x_]]*Log[b_.*x_],x_Symbol] :=
  -Cos[a*x^n*Log[b*x]]/(a*n) - 1/n*Int[x^m*Sin[a*x^n*Log[b*x]],x] /;
FreeQ[{a,b,m,n},x] && EqQ[m,n-1]

Int[x_^m_.*Cos[a_.*x_^n_.*Log[b_.*x_]]*Log[b_.*x_],x_Symbol] :=
  Sin[a*x^n*Log[b*x]]/(a*n) - 1/n*Int[x^m*Cos[a*x^n*Log[b*x]],x] /;
FreeQ[{a,b,m,n},x] && EqQ[m,n-1]