Rules for integrands of the form  u (((a+b ArcSin[c x]))^n)

1.  ∫(((d+e x))^m) (((a+b ArcSin[c x]))^n)dx

1.  ∫(((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫((((a+b ArcSin[c x]))^n)/(d+e x))dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: (1/(d+e x))==Subst[((Cos[x])/(c d+e Sin[x])),x,ArcSin[c x]](∂_x)ArcSin[c x]

Note: (((((a+b x))^n) Cos[x])/(c d+e Sin[x])) is not integrable unless n∈(SuperPlus[ℤ]).

Rule: If  n∈(SuperPlus[ℤ]), then

∫((((a+b ArcSin[c x]))^n)/(d+e x))dx  ⟶  Subst[∫(((((a+b x))^n) Cos[x])/(c d+e Sin[x]))dx,x,ArcSin[c x]]

Program code:

Int[(a_.+b_.*ArcSin[c_.*x_])^n_./(d_+e_.*x_),x_Symbol] :=
  Subst[Int[(a+b*x)^n*Cos[x]/(c*d+e*Sin[x]),x],x,ArcSin[c*x]] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[n,0]

Int[(a_.+b_.*ArcCos[c_.*x_])^n_./(d_+e_.*x_),x_Symbol] :=
  -Subst[Int[(a+b*x)^n*Sin[x]/(c*d+e*Cos[x]),x],x,ArcCos[c*x]] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[n,0]

2:  ∫(((d+e x))^m)(((a+b ArcSin[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ m≠-1

Reference: G&R 2.831, CRC 453, A&S 4.4.65

Reference: G&R 2.832, CRC 454, A&S 4.4.67

Derivation: Integration by parts

Basis: If  m≠-1, then (((d+e x))^m)==(∂_x)((((d+e x))^(m+1))/(e (m+1)))

Rule: If  n∈(SuperPlus[ℤ])∧ m≠-1, then

∫(((d+e x))^m)(((a+b ArcSin[c x]))^n)dx  ⟶  (((((d+e x))^(m+1))(((a+b ArcSin[c x]))^n))/(e(m+1)))-((b c n)/(e(m+1)))∫(((((d+e x))^(m+1))(((a+b ArcSin[c x]))^(n-1)))/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[(d_+e_.*x_)^m_.*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*ArcSin[c*x])^n/(e*(m+1)) - 
  b*c*n/(e*(m+1))*Int[(d+e*x)^(m+1)*(a+b*ArcSin[c*x])^(n-1)/Sqrt[1-c^2*x^2],x] /;
FreeQ[{a,b,c,d,e,m},x] && IGtQ[n,0] && NeQ[m,-1]

Int[(d_+e_.*x_)^m_.*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*ArcCos[c*x])^n/(e*(m+1)) + 
  b*c*n/(e*(m+1))*Int[(d+e*x)^(m+1)*(a+b*ArcCos[c*x])^(n-1)/Sqrt[1-c^2*x^2],x] /;
FreeQ[{a,b,c,d,e,m},x] && IGtQ[n,0] && NeQ[m,-1]

2.  ∫(((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  when  m∈(SuperPlus[ℤ])

1:  ∫(((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  when  m∈(SuperPlus[ℤ])∧ n<-1

Derivation: Algebraic expansion

Rule: If  m∈(SuperPlus[ℤ])∧ n<-1, then

∫(((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(((d+e x))^m) (((a+b ArcSin[c x]))^n),x]dx

Program code:

Int[(d_+e_.*x_)^m_.*(a_.+b_.*ArcSin[c_.*x_])^n_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(a+b*ArcSin[c*x])^n,x],x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[m,0] && LtQ[n,-1]

Int[(d_+e_.*x_)^m_.*(a_.+b_.*ArcCos[c_.*x_])^n_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(a+b*ArcCos[c*x])^n,x],x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[m,0] && LtQ[n,-1]

2:  ∫(((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  when  m∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[x]==(1/c)F[((Sin[ArcSin[c x]])/c)]Cos[ArcSin[c x]](∂_x)ArcSin[c x]

Note: If  m∈(SuperPlus[ℤ]), then (((a+b x))^n)Cos[x](((c d+e Sin[x]))^m) is integrable in closed-form.

Rule: If  m∈(SuperPlus[ℤ]), then

∫(((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  ⟶  (1/(c^(m+1))) Subst[∫(((a+b x))^n) Cos[x] (((c d+e Sin[x]))^m)dx,x,ArcSin[c x]]

Program code:

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcSin[c_.*x_])^n_,x_Symbol] :=
  1/c^(m+1)*Subst[Int[(a+b*x)^n*Cos[x]*(c*d+e*Sin[x])^m,x],x,ArcSin[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[m,0]

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcCos[c_.*x_])^n_,x_Symbol] :=
  -1/c^(m+1)*Subst[Int[(a+b*x)^n*Sin[x]*(c*d+e*Cos[x])^m,x],x,ArcCos[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[m,0]

2.  ∫(Subscript[P, x]) (((a+b ArcSin[c x]))^n)dx

1:  ∫(Subscript[P, x]) (a+b ArcSin[c x])dx

Derivation: Integration by parts

Rule: Let  u=∫(Subscript[P, x])dx, then

∫(Subscript[P, x]) (a+b ArcSin[c x])dx  ⟶  u (a+b ArcSin[c x])-b c∫(u/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[Px_*(a_.+b_.*ArcSin[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[ExpandExpression[Px,x],x]},  
  Dist[a+b*ArcSin[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c},x] && PolynomialQ[Px,x]

Int[Px_*(a_.+b_.*ArcCos[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[ExpandExpression[Px,x],x]},  
  Dist[a+b*ArcCos[c*x],u,x] + b*c*Int[SimplifyIntegrand[u/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c},x] && PolynomialQ[Px,x]

x:  ∫(Subscript[P, x]) (((a+b ArcSin[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  n∈(SuperPlus[ℤ]), let  u=∫(Subscript[P, x])dx, then

∫(Subscript[P, x]) (((a+b ArcSin[c x]))^n)dx  ⟶  u (((a+b ArcSin[c x]))^n)-b c n ∫((u (((a+b ArcSin[c x]))^(n-1)))/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

(* Int[Px_*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  With[{u=IntHide[Px,x]},  
  Dist[(a+b*ArcSin[c*x])^n,u,x] - b*c*n*Int[SimplifyIntegrand[u*(a+b*ArcSin[c*x])^(n-1)/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c},x] && PolynomialQ[Px,x] && IGtQ[n,0] *)

(* Int[Px_*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  With[{u=IntHide[Px,x]},  
  Dist[(a+b*ArcCos[c*x])^n,u,x] + b*c*n*Int[SimplifyIntegrand[u*(a+b*ArcCos[c*x])^(n-1)/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c},x] && PolynomialQ[Px,x] && IGtQ[n,0] *)

2:  ∫(Subscript[P, x])(((a+b ArcSin[c x]))^n)dx  when  n≠1

Derivation: Algebraic expansion

Rule: If  n≠1, then

∫(Subscript[P, x])(((a+b ArcSin[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(Subscript[P, x])(((a+b ArcSin[c x]))^n),x]dx

Program code:

Int[Px_*(a_.+b_.*ArcSin[c_.*x_])^n_,x_Symbol] :=
  Int[ExpandIntegrand[Px*(a+b*ArcSin[c*x])^n,x],x] /;
FreeQ[{a,b,c,n},x] && PolynomialQ[Px,x]

Int[Px_*(a_.+b_.*ArcCos[c_.*x_])^n_,x_Symbol] :=
  Int[ExpandIntegrand[Px*(a+b*ArcCos[c*x])^n,x],x] /;
FreeQ[{a,b,c,n},x] && PolynomialQ[Px,x]

3.  ∫(Subscript[P, x]) (((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫(Subscript[P, x]) (((d+e x))^m) (a+b ArcSin[c x])dx

Derivation: Integration by parts

Rule: Let  u=∫(Subscript[P, x])(((d+e x))^m)dx, then

∫(Subscript[P, x]) (((d+e x))^m) (a+b ArcSin[c x])dx  ⟶  u (a+b ArcSin[c x])-b c ∫(u/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[Px_*(d_.+e_.*x_)^m_.*(a_.+b_.*ArcSin[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[Px*(d+e*x)^m,x]},  
  Dist[a+b*ArcSin[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e,m},x] && PolynomialQ[Px,x]

Int[Px_*(d_.+e_.*x_)^m_.*(a_.+b_.*ArcCos[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[Px*(d+e*x)^m,x]},  
  Dist[a+b*ArcCos[c*x],u,x] + b*c*Int[SimplifyIntegrand[u/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e,m},x] && PolynomialQ[Px,x]

2:  ∫(((f+g x))^p) (((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  when  (n|p)∈(SuperPlus[ℤ])∧ m∈(SuperMinus[ℤ])∧ m+p+1<0

Derivation: Integration by parts

Note: If  p∈(SuperPlus[ℤ])∧ m∈(SuperMinus[ℤ])∧ m+p+1<0, then ∫(((f+g x))^p) (((d+e x))^m)dx is a rational function.

Rule: If  (n|p)∈(SuperPlus[ℤ])∧ m∈(SuperMinus[ℤ])∧ m+p+1<0, let  u=∫(((f+g x))^p) (((d+e x))^m)dx, then

∫(((f+g x))^p) (((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  ⟶  u (((a+b ArcSin[c x]))^n)-b c n ∫((u (((a+b ArcSin[c x]))^(n-1)))/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[(f_.+g_.*x_)^p_.*(d_+e_.*x_)^m_*(a_.+b_.*ArcSin[c_.*x_])^n_,x_Symbol] :=
  With[{u=IntHide[(f+g*x)^p*(d+e*x)^m,x]},  
  Dist[(a+b*ArcSin[c*x])^n,u,x] - b*c*n*Int[SimplifyIntegrand[u*(a+b*ArcSin[c*x])^(n-1)/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[n,0] && IGtQ[p,0] && ILtQ[m,0] && LtQ[m+p+1,0]

Int[(f_.+g_.*x_)^p_.*(d_+e_.*x_)^m_*(a_.+b_.*ArcCos[c_.*x_])^n_,x_Symbol] :=
  With[{u=IntHide[(f+g*x)^p*(d+e*x)^m,x]},  
  Dist[(a+b*ArcCos[c*x])^n,u,x] + b*c*n*Int[SimplifyIntegrand[u*(a+b*ArcCos[c*x])^(n-1)/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[n,0] && IGtQ[p,0] && ILtQ[m,0] && LtQ[m+p+1,0]

3:  ∫(((((f+g x+h (x^2)))^p) (((a+b ArcSin[c x]))^n))/(((d+e x))^2))dx  when  (n|p)∈(SuperPlus[ℤ])∧ e g-2 d h==0

Derivation: Integration by parts

Note: If  p∈(SuperPlus[ℤ])∧ e g-2 d h==0, then ∫((((f+g x+h (x^2)))^p)/(((d+e x))^2))dx is a rational function.

Rule: If  (n|p)∈(SuperPlus[ℤ])∧ e g-2 d h==0, let  u=∫((((f+g x+h (x^2)))^p)/(((d+e x))^2))dx, then

∫(((((f+g x+h (x^2)))^p) (((a+b ArcSin[c x]))^n))/(((d+e x))^2))dx  ⟶  u (((a+b ArcSin[c x]))^n)-b c n ∫((u (((a+b ArcSin[c x]))^(n-1)))/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[(f_.+g_.*x_+h_.*x_^2)^p_.*(a_.+b_.*ArcSin[c_.*x_])^n_/(d_+e_.*x_)^2,x_Symbol] :=
  With[{u=IntHide[(f+g*x+h*x^2)^p/(d+e*x)^2,x]},  
  Dist[(a+b*ArcSin[c*x])^n,u,x] - b*c*n*Int[SimplifyIntegrand[u*(a+b*ArcSin[c*x])^(n-1)/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e,f,g,h},x] && IGtQ[n,0] && IGtQ[p,0] && EqQ[e*g-2*d*h,0]

Int[(f_.+g_.*x_+h_.*x_^2)^p_.*(a_.+b_.*ArcCos[c_.*x_])^n_/(d_+e_.*x_)^2,x_Symbol] :=
  With[{u=IntHide[(f+g*x+h*x^2)^p/(d+e*x)^2,x]},  
  Dist[(a+b*ArcCos[c*x])^n,u,x] + b*c*n*Int[SimplifyIntegrand[u*(a+b*ArcCos[c*x])^(n-1)/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e,f,g,h},x] && IGtQ[n,0] && IGtQ[p,0] && EqQ[e*g-2*d*h,0]

4:  ∫(Subscript[P, x]) (((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ])∧ m∈ℤ, then

∫(Subscript[P, x]) (((d+e x))^m) (((a+b ArcSin[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(Subscript[P, x])(((d+e x))^m) (((a+b ArcSin[c x]))^n),x]dx

Program code:

Int[Px_*(d_+e_.*x_)^m_.*(a_.+b_.*ArcSin[c_.*x_])^n_,x_Symbol] :=
  Int[ExpandIntegrand[Px*(d+e*x)^m*(a+b*ArcSin[c*x])^n,x],x] /;
FreeQ[{a,b,c,d,e},x] && PolynomialQ[Px,x] && IGtQ[n,0] && IntegerQ[m]

Int[Px_*(d_+e_.*x_)^m_.*(a_.+b_.*ArcCos[c_.*x_])^n_,x_Symbol] :=
  Int[ExpandIntegrand[Px*(d+e*x)^m*(a+b*ArcCos[c*x])^n,x],x] /;
FreeQ[{a,b,c,d,e},x] && PolynomialQ[Px,x] && IGtQ[n,0] && IntegerQ[m]

4.  ∫(((f+g x))^m) (((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ m∈ℤ ∧ p-(1/2)∈ℤ

1.  ∫(((f+g x))^m) (((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ m∈ℤ ∧ p-(1/2)∈ℤ ∧ d>0

1:  ∫(((f+g x))^m) (((d+e (x^2)))^p) (a+b ArcSin[c x])dx  when  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ p+(1/2)∈(SuperMinus[ℤ])∧ d>0 ∧ (m<-2 p-1 ∨ m>3)

Derivation: Integration by parts

Note: If  m∈ℤ ∧ p+(1/2)∈ℤ ∧ 0<m<-2 p-1, then ∫(((f+g x))^m) (((d+e (x^2)))^p)dx is an algebraic function.

Rule: If  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ p+(1/2)∈(SuperMinus[ℤ])∧ d>0 ∧ (m<-2 p-1 ∨ m>3), let  u=∫(((f+g x))^m) (((d+e (x^2)))^p)dx, then

∫(((f+g x))^m) (((d+e (x^2)))^p) (a+b ArcSin[c x])dx  ⟶  u (a+b ArcSin[c x])-b c∫(u/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSin[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f+g*x)^m*(d+e*x^2)^p,x]},  
  Dist[a+b*ArcSin[c*x],u,x] - b*c*Int[Dist[1/Sqrt[1-c^2*x^2],u,x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && IGtQ[m,0] && ILtQ[p+1/2,0] && GtQ[d,0] && (LtQ[m,-2*p-1] || GtQ[m,3])

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCos[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f+g*x)^m*(d+e*x^2)^p,x]},  
  Dist[a+b*ArcCos[c*x],u,x] + b*c*Int[Dist[1/Sqrt[1-c^2*x^2],u,x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && IGtQ[m,0] && ILtQ[p+1/2,0] && GtQ[d,0] && (LtQ[m,-2*p-1] || GtQ[m,3])

2:  ∫(((f+g x))^m) (((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ p+(1/2)∈ℤ ∧ d>0 ∧ n∈(SuperPlus[ℤ]) ∧ (m==1 ∨ p>0 ∨ (n==1 ∧ p>-1) ∨ (m==2 ∧ p<-2))

Derivation: Algebraic expansion

Rule: If  (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ ∧ d>0 ∧ n∈(SuperPlus[ℤ])∧ m>0, then

∫(((f+g x))^m)(((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  ⟶  ∫(((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n) ExpandIntegrand[(((f+g x))^m),x]dx

Program code:

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^p*(a+b*ArcSin[c*x])^n,(f+g*x)^m,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && IGtQ[m,0] && IntegerQ[p+1/2] && GtQ[d,0] && IGtQ[n,0] && 
  (m==1 || p>0 || n==1 && p>-1 || m==2 && p<-2)

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^p*(a+b*ArcCos[c*x])^n,(f+g*x)^m,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && IGtQ[m,0] && IntegerQ[p+1/2] && GtQ[d,0] && IGtQ[n,0] && 
  (m==1 || p>0 || n==1 && p>-1 || m==2 && p<-2)

3.  ∫(((f+g x))^m) (((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈(SuperPlus[ℤ])∧ d>0

1:  ∫(((f+g x))^m) (Sqrt[d+e (x^2)]) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ m∈(SuperMinus[ℤ])∧ d>0 ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: If  (c^2) d+e==0 ∧ d>0, then ((((a+b ArcSin[c x]))^n)/(Sqrt[d+e (x^2)]))==(∂_x)((((a+b ArcSin[c x]))^(n+1))/(b c (Sqrt[d]) (n+1)))

Rule: If  (c^2) d+e==0 ∧ m∈(SuperMinus[ℤ])∧ d>0 ∧ n∈(SuperPlus[ℤ]), then

∫(((f+g x))^m) (Sqrt[d+e (x^2)]) (((a+b ArcSin[c x]))^n)dx  ⟶  
(((((f+g x))^m)(d+e (x^2)) (((a+b ArcSin[c x]))^(n+1)))/(b c (Sqrt[d])(n+1)))-
(1/(b c (Sqrt[d])(n+1)))∫(d g m+2 e f x+e g (m+2) (x^2)) (((f+g x))^(m-1)) (((a+b ArcSin[c x]))^(n+1))dx

Program code:

Int[(f_+g_.*x_)^m_*Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  (f+g*x)^m*(d+e*x^2)*(a+b*ArcSin[c*x])^(n+1)/(b*c*Sqrt[d]*(n+1)) - 
  1/(b*c*Sqrt[d]*(n+1))*Int[(d*g*m+2*e*f*x+e*g*(m+2)*x^2)*(f+g*x)^(m-1)*(a+b*ArcSin[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && ILtQ[m,0] && GtQ[d,0] && IGtQ[n,0]

Int[(f_+g_.*x_)^m_*Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  -(f+g*x)^m*(d+e*x^2)*(a+b*ArcCos[c*x])^(n+1)/(b*c*Sqrt[d]*(n+1)) + 
  1/(b*c*Sqrt[d]*(n+1))*Int[(d*g*m+2*e*f*x+e*g*(m+2)*x^2)*(f+g*x)^(m-1)*(a+b*ArcCos[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && ILtQ[m,0] && GtQ[d,0] && IGtQ[n,0]

2:  ∫(((f+g x))^m)(((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈(SuperPlus[ℤ])∧ d>0 ∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈(SuperPlus[ℤ])∧ d>0 ∧ n∈(SuperPlus[ℤ]), then

∫(((f+g x))^m)(((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  ⟶  ∫(Sqrt[d+e (x^2)]) (((a+b ArcSin[c x]))^n) ExpandIntegrand[(((f+g x))^m) (((d+e (x^2)))^(p-1/2)),x]dx

Program code:

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[Sqrt[d+e*x^2]*(a+b*ArcSin[c*x])^n,(f+g*x)^m*(d+e*x^2)^(p-1/2),x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && IntegerQ[m] && IGtQ[p+1/2,0] && GtQ[d,0] && IGtQ[n,0]

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[Sqrt[d+e*x^2]*(a+b*ArcCos[c*x])^n,(f+g*x)^m*(d+e*x^2)^(p-1/2),x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && IntegerQ[m] && IGtQ[p+1/2,0] && GtQ[d,0] && IGtQ[n,0]

3:  ∫(((f+g x))^m) (((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ m∈(SuperMinus[ℤ])∧ p-(1/2)∈(SuperPlus[ℤ])∧ d>0 ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: If  (c^2) d+e==0 ∧ d>0, then ((((a+b ArcSin[c x]))^n)/(Sqrt[d+e (x^2)]))==(∂_x)((((a+b ArcSin[c x]))^(n+1))/(b c (Sqrt[d]) (n+1)))

Rule: If  (c^2) d+e==0 ∧ m∈(SuperMinus[ℤ])∧ p-(1/2)∈(SuperPlus[ℤ])∧ d>0 ∧ n∈(SuperPlus[ℤ]), then

∫(((f+g x))^m) (((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  ⟶  
(((((f+g x))^m) (((d+e (x^2)))^(p+(1/2))) (((a+b ArcSin[c x]))^(n+1)))/(b c (Sqrt[d])(n+1)))-
(1/(b c (Sqrt[d])(n+1)))∫(((f+g x))^(m-1)) (((a+b ArcSin[c x]))^(n+1)) ExpandIntegrand[(d g m+e f (2 p+1) x+e g (m+2 p+1) (x^2)) (((d+e (x^2)))^(p-(1/2))),x]dx

Program code:

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  (f+g*x)^m*(d+e*x^2)^(p+1/2)*(a+b*ArcSin[c*x])^(n+1)/(b*c*Sqrt[d]*(n+1)) - 
  1/(b*c*Sqrt[d]*(n+1))*
    Int[ExpandIntegrand[(f+g*x)^(m-1)*(a+b*ArcSin[c*x])^(n+1),(d*g*m+e*f*(2*p+1)*x+e*g*(m+2*p+1)*x^2)*(d+e*x^2)^(p-1/2),x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && ILtQ[m,0] && IGtQ[p-1/2,0] && GtQ[d,0] && IGtQ[n,0]

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  -(f+g*x)^m*(d+e*x^2)^(p+1/2)*(a+b*ArcCos[c*x])^(n+1)/(b*c*Sqrt[d]*(n+1)) + 
  1/(b*c*Sqrt[d]*(n+1))*
    Int[ExpandIntegrand[(f+g*x)^(m-1)*(a+b*ArcCos[c*x])^(n+1),(d*g*m+e*f*(2*p+1)*x+e*g*(m+2*p+1)*x^2)*(d+e*x^2)^(p-1/2),x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && ILtQ[m,0] && IGtQ[p-1/2,0] && GtQ[d,0] && IGtQ[n,0]

4.  ∫(((f+g x))^m) (((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ m∈ℤ ∧ p-(1/2)∈(SuperMinus[ℤ])∧ d>0

1.  ∫(((((f+g x))^m) (((a+b ArcSin[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ m∈ℤ ∧ d>0

1:  ∫(((((f+g x))^m) (((a+b ArcSin[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ d>0 ∧ n<-1

Derivation: Integration by parts

Basis: If  (c^2) d+e==0 ∧ d>0, then ((((a+b ArcSin[c x]))^n)/(Sqrt[d+e (x^2)]))==(∂_x)((((a+b ArcSin[c x]))^(n+1))/(b c (Sqrt[d])(n+1)))

Rule: If  (c^2) d+e==0 ∧ m∈ℤ ∧ d>0 ∧ m>0 ∧ n<-1, then

∫(((((f+g x))^m) (((a+b ArcSin[c x]))^n))/(Sqrt[d+e (x^2)]))dx  ⟶  (((((f+g x))^m)(((a+b ArcSin[c x]))^(n+1)))/(b c (Sqrt[d])(n+1)))-((g m)/(b c (Sqrt[d])(n+1)))∫(((f+g x))^(m-1))(((a+b ArcSin[c x]))^(n+1))dx

Program code:

Int[(f_+g_.*x_)^m_.*(a_.+b_.*ArcSin[c_.*x_])^n_/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  (f+g*x)^m*(a+b*ArcSin[c*x])^(n+1)/(b*c*Sqrt[d]*(n+1)) - 
  g*m/(b*c*Sqrt[d]*(n+1))*Int[(f+g*x)^(m-1)*(a+b*ArcSin[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && IGtQ[m,0] && GtQ[d,0] && LtQ[n,-1]

Int[(f_+g_.*x_)^m_.*(a_.+b_.*ArcCos[c_.*x_])^n_/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -(f+g*x)^m*(a+b*ArcCos[c*x])^(n+1)/(b*c*Sqrt[d]*(n+1)) + 
  g*m/(b*c*Sqrt[d]*(n+1))*Int[(f+g*x)^(m-1)*(a+b*ArcCos[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && IGtQ[m,0] && GtQ[d,0] && LtQ[n,-1]

2:  ∫(((((f+g x))^m) (((a+b ArcSin[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ m∈ℤ ∧ d>0 ∧ (m>0 ∨ n∈(SuperPlus[ℤ]))

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0 ∧ d>0, then ((F[x])/(Sqrt[d+e (x^2)]))==(1/(c(Sqrt[d]))) Subst[F[((Sin[x])/c)],x,ArcSin[c x]](∂_x)ArcSin[c x]

Rule: If  (c^2) d+e==0 ∧ m∈ℤ ∧ d>0 ∧ (m>0 ∨ n∈(SuperPlus[ℤ])), then

∫(((((f+g x))^m) (((a+b ArcSin[c x]))^n))/(Sqrt[d+e (x^2)]))dx  ⟶  (1/((c^(m+1))(Sqrt[d]))) Subst[∫(((a+b x))^n)(((c f+g Sin[x]))^m)dx,x,ArcSin[c x]]

Program code:

Int[(f_+g_.*x_)^m_.*(a_.+b_.*ArcSin[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  1/(c^(m+1)*Sqrt[d])*Subst[Int[(a+b*x)^n*(c*f+g*Sin[x])^m,x],x,ArcSin[c*x]] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[c^2*d+e,0] && IntegerQ[m] && GtQ[d,0] && (GtQ[m,0] || IGtQ[n,0])

Int[(f_+g_.*x_)^m_.*(a_.+b_.*ArcCos[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -1/(c^(m+1)*Sqrt[d])*Subst[Int[(a+b*x)^n*(c*f+g*Cos[x])^m,x],x,ArcCos[c*x]] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[c^2*d+e,0] && IntegerQ[m] && GtQ[d,0] && (GtQ[m,0] || IGtQ[n,0])

2:  ∫(((f+g x))^m)(((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈(SuperMinus[ℤ])∧ d>0 ∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈(SuperMinus[ℤ])∧ d>0 ∧ n∈(SuperPlus[ℤ]), then

∫(((f+g x))^m)(((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  ⟶  ∫((((a+b ArcSin[c x]))^n)/(Sqrt[d+e (x^2)])) ExpandIntegrand[(((f+g x))^m) (((d+e (x^2)))^(p+1/2)),x]dx

Program code:

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcSin[c*x])^n/Sqrt[d+e*x^2],(f+g*x)^m*(d+e*x^2)^(p+1/2),x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && IntegerQ[m] && ILtQ[p+1/2,0] && GtQ[d,0] && IGtQ[n,0]

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCos[c*x])^n/Sqrt[d+e*x^2],(f+g*x)^m*(d+e*x^2)^(p+1/2),x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*d+e,0] && IntegerQ[m] && ILtQ[p+1/2,0] && GtQ[d,0] && IGtQ[n,0]

2:  ∫(((f+g x))^m)(((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ m∈ℤ ∧ p-(1/2)∈ℤ ∧ d≯0

Derivation: Piecewise constant extraction

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/(((1-(c^2) (x^2)))^p))==0

Rule: If  (c^2) d+e==0 ∧ m∈ℤ ∧ p-(1/2)∈ℤ ∧ d≯0, then

∫(((f+g x))^m)(((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  ⟶  ((((d+e (x^2)))^p)/(((1-(c^2) (x^2)))^p))∫(((f+g x))^m)(((1-(c^2) (x^2)))^p)(((a+b ArcSin[c x]))^n)dx

Program code:

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  Simp[(d+e*x^2)^p/(1-c^2*x^2)^p]*Int[(f+g*x)^m*(1-c^2*x^2)^p*(a+b*ArcSin[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[c^2*d+e,0] && IntegerQ[m] && IntegerQ[p-1/2] && Not[GtQ[d,0]]

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  Simp[(d+e*x^2)^p/(1-c^2*x^2)^p]*Int[(f+g*x)^m*(1-c^2*x^2)^p*(a+b*ArcCos[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[c^2*d+e,0] && IntegerQ[m] && IntegerQ[p-1/2] && Not[GtQ[d,0]]

5.  ∫Log[h (((f+g x))^m)](((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ p-(1/2)∈ℤ

1.  ∫Log[h (((f+g x))^m)](((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ p-(1/2)∈ℤ ∧ d>0

1:  ∫((Log[h (((f+g x))^m)] (((a+b ArcSin[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ d>0 ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: If  (c^2) d+e==0 ∧ d>0, then ((((a+b ArcSin[c x]))^n)/(Sqrt[d+e (x^2)]))==(∂_x)((((a+b ArcSin[c x]))^(n+1))/(b c (Sqrt[d]) (n+1)))

Note: If  n∈(SuperPlus[ℤ]), then ((((a+b ArcSin[c x]))^(n+1))/(f+g x)) is integrable in closed-form.

Rule: If  (c^2) d+e==0 ∧ d>0 ∧ n∈(SuperPlus[ℤ]), then

∫((Log[h (((f+g x))^m)] (((a+b ArcSin[c x]))^n))/(Sqrt[d+e (x^2)]))dx  ⟶  ((Log[h (((f+g x))^m)](((a+b ArcSin[c x]))^(n+1)))/(b c (Sqrt[d])(n+1)))-((g m)/(b c (Sqrt[d])(n+1)))∫((((a+b ArcSin[c x]))^(n+1))/(f+g x))dx

Program code:

Int[Log[h_.*(f_.+g_.*x_)^m_.]*(a_.+b_.*ArcSin[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  Log[h*(f+g*x)^m]*(a+b*ArcSin[c*x])^(n+1)/(b*c*Sqrt[d]*(n+1)) - 
  g*m/(b*c*Sqrt[d]*(n+1))*Int[(a+b*ArcSin[c*x])^(n+1)/(f+g*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,m},x] && EqQ[c^2*d+e,0] && GtQ[d,0] && IGtQ[n,0]

Int[Log[h_.*(f_.+g_.*x_)^m_.]*(a_.+b_.*ArcCos[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -Log[h*(f+g*x)^m]*(a+b*ArcCos[c*x])^(n+1)/(b*c*Sqrt[d]*(n+1)) + 
  g*m/(b*c*Sqrt[d]*(n+1))*Int[(a+b*ArcCos[c*x])^(n+1)/(f+g*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,m},x] && EqQ[c^2*d+e,0] && GtQ[d,0] && IGtQ[n,0]

2:  ∫Log[h (((f+g x))^m)] (((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ p-(1/2)∈ℤ ∧ d≯0

Derivation: Piecewise constant extraction

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/(((1-(c^2) (x^2)))^p))==0

Rule: If  (c^2) d+e==0 ∧ p-(1/2)∈ℤ ∧ d≯0, then

∫Log[h (((f+g x))^m)] (((d+e (x^2)))^p) (((a+b ArcSin[c x]))^n)dx  ⟶  ((((d+e (x^2)))^p)/(((1-(c^2) (x^2)))^p))∫Log[h (((f+g x))^m)] (((1-(c^2) (x^2)))^p)(((a+b ArcSin[c x]))^n)dx

Program code:

Int[Log[h_.*(f_.+g_.*x_)^m_.]*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  Simp[(d+e*x^2)^p/(1-c^2*x^2)^p]*Int[Log[h*(f+g*x)^m]*(1-c^2*x^2)^p*(a+b*ArcSin[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n},x] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2] && Not[GtQ[d,0]]

Int[Log[h_.*(f_.+g_.*x_)^m_.]*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  Simp[(d+e*x^2)^p/(1-c^2*x^2)^p]*Int[Log[h*(f+g*x)^m]*(1-c^2*x^2)^p*(a+b*ArcCos[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n},x] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2] && Not[GtQ[d,0]]

6.  ∫(((d+e x))^m)(((f+g x))^m)(((a+b ArcSin[c x]))^n)dx

1:  ∫(((d+e x))^m)(((f+g x))^m) (a+b ArcSin[c x])dx  when  m+(1/2)∈(SuperMinus[ℤ])

Derivation: Integration by parts

Rule: If  m+(1/2)∈(SuperMinus[ℤ]), let u=∫(((d+e x))^m)(((f+g x))^m)dx, then

∫(((d+e x))^m)(((f+g x))^m) (a+b ArcSin[c x])dx  ⟶  u (a+b ArcSin[c x])-b c∫(u/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[(d_+e_.*x_)^m_*(f_+g_.*x_)^m_*(a_.+b_.*ArcSin[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x)^m*(f+g*x)^m,x]},  
  Dist[a+b*ArcSin[c*x],u,x] - b*c*Int[Dist[1/Sqrt[1-c^2*x^2],u,x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && ILtQ[m+1/2,0]

Int[(d_+e_.*x_)^m_*(f_+g_.*x_)^m_*(a_.+b_.*ArcCos[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x)^m*(f+g*x)^m,x]},  
  Dist[a+b*ArcCos[c*x],u,x] + b*c*Int[Dist[1/Sqrt[1-c^2*x^2],u,x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && ILtQ[m+1/2,0]

2:  ∫(((d+e x))^m)(((f+g x))^m)(((a+b ArcSin[c x]))^n)dx  when  m∈ℤ

Derivation: Algebraic expansion

Rule: If  m∈ℤ, then

∫(((d+e x))^m)(((f+g x))^m)(((a+b ArcSin[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(((d+e x))^m)(((f+g x))^m)(((a+b ArcSin[c x]))^n),x]dx

Program code:

Int[(d_+e_.*x_)^m_.*(f_+g_.*x_)^m_.*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^m*(a+b*ArcSin[c*x])^n,x],x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && IntegerQ[m]

Int[(d_+e_.*x_)^m_.*(f_+g_.*x_)^m_.*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(f+g*x)^m*(a+b*ArcCos[c*x])^n,x],x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && IntegerQ[m]

7:  ∫u (a+b ArcSin[c x])dx  when  ∫udx  is free of inverse functions

Derivation: Integration by parts

Rule: Let  v==∫udx, if v is free of inverse functions, then

∫u (a+b ArcSin[c x])dx  ⟶  v (a+b ArcSin[c x])-b c∫(v/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[u_*(a_.+b_.*ArcSin[c_.*x_]),x_Symbol] :=
  With[{v=IntHide[u,x]},  
  Dist[a+b*ArcSin[c*x],v,x] - b*c*Int[SimplifyIntegrand[v/Sqrt[1-c^2*x^2],x],x] /;
 InverseFunctionFreeQ[v,x]] /;
FreeQ[{a,b,c},x]

Int[u_*(a_.+b_.*ArcCos[c_.*x_]),x_Symbol] :=
  With[{v=IntHide[u,x]},  
  Dist[a+b*ArcCos[c*x],v,x] + b*c*Int[SimplifyIntegrand[v/Sqrt[1-c^2*x^2],x],x] /;
 InverseFunctionFreeQ[v,x]] /;
FreeQ[{a,b,c},x]

8.  ∫(Subscript[P, x])u(((a+b ArcSin[c x]))^n)dx

1:  ∫(Subscript[P, x])(((d+e (x^2)))^p)(((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ p-(1/2)∈ℤ

Derivation: Algebraic expansion

Rule: If  (c^2) d+e==0 ∧ p-(1/2)∈ℤ, then

∫(Subscript[P, x])(((d+e (x^2)))^p)(((a+b ArcSin[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(Subscript[P, x])(((d+e (x^2)))^p)(((a+b ArcSin[c x]))^n),x]dx

Program code:

Int[Px_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[Px*(d+e*x^2)^p*(a+b*ArcSin[c*x])^n,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,n},x] && PolynomialQ[Px,x] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2]

Int[Px_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[Px*(d+e*x^2)^p*(a+b*ArcCos[c*x])^n,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,n},x] && PolynomialQ[Px,x] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2]

2:  ∫(Subscript[P, x])(((f+g(((d+e (x^2)))^p)))^m)(((a+b ArcSin[c x]))^n)dx  when  (c^2) d+e==0 ∧ p+(1/2)∈(SuperPlus[ℤ])∧ (m|n)∈ℤ

Derivation: Algebraic expansion

Rule: If  (c^2) d+e==0 ∧ p+(1/2)∈(SuperPlus[ℤ])∧ (m|n)∈ℤ, then

∫(Subscript[P, x])(((f+g(((d+e (x^2)))^p)))^m)(((a+b ArcSin[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(Subscript[P, x])(((f+g(((d+e (x^2)))^p)))^m)(((a+b ArcSin[c x]))^n),x]dx

Program code:

Int[Px_.*(f_+g_.*(d_+e_.*x_^2)^p_)^m_.*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[Px*(f+g*(d+e*x^2)^p)^m*(a+b*ArcSin[c*x])^n,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,g},x] && PolynomialQ[Px,x] && EqQ[c^2*d+e,0] && IGtQ[p+1/2,0] && IntegersQ[m,n]

Int[Px_.*(f_+g_.*(d_+e_.*x_^2)^p_)^m_.*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[Px*(f+g*(d+e*x^2)^p)^m*(a+b*ArcCos[c*x])^n,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,g},x] && PolynomialQ[Px,x] && EqQ[c^2*d+e,0] && IGtQ[p+1/2,0] && IntegersQ[m,n]

9.  ∫(Subscript[RF, x])u(((a+b ArcSin[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1.  ∫(Subscript[RF, x])(((a+b ArcSin[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫(Subscript[RF, x])((ArcSin[c x])^n)dx  when  n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ]), then

∫(Subscript[RF, x])((ArcSin[c x])^n)dx  ⟶  ∫((ArcSin[c x])^n)ExpandIntegrand[(Subscript[RF, x]),x]dx

Program code:

Int[RFx_*ArcSin[c_.*x_]^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[ArcSin[c*x]^n,RFx,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[c,x] && RationalFunctionQ[RFx,x] && IGtQ[n,0]

Int[RFx_*ArcCos[c_.*x_]^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[ArcCos[c*x]^n,RFx,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[c,x] && RationalFunctionQ[RFx,x] && IGtQ[n,0]

2:  ∫(Subscript[RF, x])(((a+b ArcSin[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ]), then

∫(Subscript[RF, x])(((a+b ArcSin[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(Subscript[RF, x])(((a+b ArcSin[c x]))^n),x]dx

Program code:

Int[RFx_*(a_+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[RFx*(a+b*ArcSin[c*x])^n,x],x] /;
FreeQ[{a,b,c},x] && RationalFunctionQ[RFx,x] && IGtQ[n,0]

Int[RFx_*(a_+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[RFx*(a+b*ArcCos[c*x])^n,x],x] /;
FreeQ[{a,b,c},x] && RationalFunctionQ[RFx,x] && IGtQ[n,0]

2.  ∫(Subscript[RF, x])(((d+e (x^2)))^p)(((a+b ArcSin[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p-(1/2)∈ℤ

1:  ∫(Subscript[RF, x])(((d+e (x^2)))^p)((ArcSin[c x])^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p-(1/2)∈ℤ

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p-(1/2)∈ℤ, then

∫(Subscript[RF, x])(((d+e (x^2)))^p)((ArcSin[c x])^n)dx  ⟶  ∫(((d+e (x^2)))^p)((ArcSin[c x])^n)ExpandIntegrand[(Subscript[RF, x]),x]dx

Program code:

Int[RFx_*(d_+e_.*x_^2)^p_*ArcSin[c_.*x_]^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(d+e*x^2)^p*ArcSin[c*x]^n,RFx,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{c,d,e},x] && RationalFunctionQ[RFx,x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2]

Int[RFx_*(d_+e_.*x_^2)^p_*ArcCos[c_.*x_]^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(d+e*x^2)^p*ArcCos[c*x]^n,RFx,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{c,d,e},x] && RationalFunctionQ[RFx,x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2]

2:  ∫(Subscript[RF, x])(((d+e (x^2)))^p)(((a+b ArcSin[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p-(1/2)∈ℤ

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p-(1/2)∈ℤ, then

∫(Subscript[RF, x])(((d+e (x^2)))^p)(((a+b ArcSin[c x]))^n)dx  ⟶  ∫(((d+e (x^2)))^p)ExpandIntegrand[(Subscript[RF, x])(((a+b ArcSin[c x]))^n),x]dx

Program code:

Int[RFx_*(d_+e_.*x_^2)^p_*(a_+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^p,RFx*(a+b*ArcSin[c*x])^n,x],x] /;
FreeQ[{a,b,c,d,e},x] && RationalFunctionQ[RFx,x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2]

Int[RFx_*(d_+e_.*x_^2)^p_*(a_+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^2)^p,RFx*(a+b*ArcCos[c*x])^n,x],x] /;
FreeQ[{a,b,c,d,e},x] && RationalFunctionQ[RFx,x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2]

U:  ∫u(((a+b ArcSin[c x]))^n)dx

Rule:

∫u(((a+b ArcSin[c x]))^n)dx  ⟶  ∫u(((a+b ArcSin[c x]))^n)dx

Program code:

Int[u_.*(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcSin[c*x])^n,x] /;
FreeQ[{a,b,c,n},x]

Int[u_.*(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcCos[c*x])^n,x] /;
FreeQ[{a,b,c,n},x]