Rules for integrands involving inverse sines and cosines

1.  ∫u(((a+b ArcSin[c+d x]))^n)dx

1:  ∫(((a+b ArcSin[c+d x]))^n)dx

Derivation: Integration by substitution

Rule:

∫(((a+b ArcSin[c+d x]))^n)dx  ⟶  (1/d) Subst[∫(((a+b ArcSin[x]))^n)dx,x,c+d x]

Program code:

Int[(a_.+b_.*ArcSin[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[(a+b*ArcSin[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,n},x]

Int[(a_.+b_.*ArcCos[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[(a+b*ArcCos[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,n},x]

2:  ∫(((e+f x))^m)(((a+b ArcSin[c+d x]))^n)dx

Derivation: Integration by substitution

Rule:

∫(((e+f x))^m)(((a+b ArcSin[c+d x]))^n)dx  ⟶  (1/d)Subst[∫(((((d e-c f)/d)+((f x)/d)))^m)(((a+b ArcSin[x]))^n)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcSin[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(a+b*ArcSin[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m,n},x]

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcCos[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(a+b*ArcCos[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m,n},x]

3:  ∫(((A+B x+C (x^2)))^p)(((a+b ArcSin[c+d x]))^n)dx  when  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0

Derivation: Integration by substitution

Basis: If  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0, then A+B x+C (x^2)==-(C/(d^2))+(C/(d^2))(((c+d x))^2)

Rule: If  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0, then

∫(((A+B x+C (x^2)))^p)(((a+b ArcSin[c+d x]))^n)dx  ⟶  (1/d)Subst[∫(((-(C/(d^2))+((C (x^2))/(d^2))))^p)(((a+b ArcSin[x]))^n)dx,x,c+d x]

Program code:

Int[(A_.+B_.*x_+C_.*x_^2)^p_.*(a_.+b_.*ArcSin[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[(-C/d^2+C/d^2*x^2)^p*(a+b*ArcSin[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,A,B,C,n,p},x] && EqQ[B*(1-c^2)+2*A*c*d,0] && EqQ[2*c*C-B*d,0]

Int[(A_.+B_.*x_+C_.*x_^2)^p_.*(a_.+b_.*ArcCos[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[(-C/d^2+C/d^2*x^2)^p*(a+b*ArcCos[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,A,B,C,n,p},x] && EqQ[B*(1-c^2)+2*A*c*d,0] && EqQ[2*c*C-B*d,0]

4:  ∫(((e+f x))^m)(((A+B x+C (x^2)))^p)(((a+b ArcSin[c+d x]))^n)dx  when  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0

Derivation: Integration by substitution

Basis: If  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0, then A+B x+C (x^2)==-(C/(d^2))+(C/(d^2))(((c+d x))^2)

Rule: If  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0, then

∫(((e+f x))^m)(((A+B x+C (x^2)))^p)(((a+b ArcSin[c+d x]))^n)dx  ⟶  (1/d)Subst[∫(((((d e-c f)/d)+((f x)/d)))^m)(((-(C/(d^2))+((C (x^2))/(d^2))))^p)(((a+b ArcSin[x]))^n)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*(A_.+B_.*x_+C_.*x_^2)^p_.*(a_.+b_.*ArcSin[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(-C/d^2+C/d^2*x^2)^p*(a+b*ArcSin[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,A,B,C,m,n,p},x] && EqQ[B*(1-c^2)+2*A*c*d,0] && EqQ[2*c*C-B*d,0]

Int[(e_.+f_.*x_)^m_.*(A_.+B_.*x_+C_.*x_^2)^p_.*(a_.+b_.*ArcCos[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(-C/d^2+C/d^2*x^2)^p*(a+b*ArcCos[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,A,B,C,m,n,p},x] && EqQ[B*(1-c^2)+2*A*c*d,0] && EqQ[2*c*C-B*d,0]

2.  ∫(((a+b ArcSin[c+d (x^2)]))^n)dx  when  (c^2)==1

1.  ∫(((a+b ArcSin[c+d (x^2)]))^n)dx  when  (c^2)==1 ∧ n>0

1.  ∫(Sqrt[a+b ArcSin[c+d (x^2)]])dx  when  (c^2)==1

1:  ∫(Sqrt[a+b ArcSin[c+d (x^2)]])dx  when  (c^2)==1

Derivation: Integration by parts

Rule: If  (c^2)==1, then

∫(Sqrt[a+b ArcSin[c+d (x^2)]])dx  ⟶  x (Sqrt[a+b ArcSin[c+d (x^2)]])-b d∫((x^2)/((Sqrt[-2 c d (x^2)-(d^2) (x^4)]) (Sqrt[a+b ArcSin[c+d (x^2)]])))dx

  ⟶  x (Sqrt[a+b ArcSin[c+d (x^2)]])-
(((Sqrt[π]) x (Cos[(a/(2 b))]+c Sin[(a/(2 b))]) FresnelC[(Sqrt[(c/(π b))])(Sqrt[a+b ArcSin[c+d (x^2)]])])/((Sqrt[(c/b)]) (Cos[(1/2) ArcSin[c+d (x^2)]]-c Sin[(1/2) ArcSin[c+d (x^2)]])))+(((Sqrt[π]) x (Cos[(a/(2 b))]-c Sin[(a/(2 b))]) FresnelS[(Sqrt[(c/(π b))])(Sqrt[a+b ArcSin[c+d (x^2)]])])/((Sqrt[(c/b)]) (Cos[(1/2) ArcSin[c+d (x^2)]]-c Sin[(1/2) ArcSin[c+d (x^2)]])))

Program code:

Int[Sqrt[a_.+b_.*ArcSin[c_+d_.*x_^2]],x_Symbol] :=
  x*Sqrt[a+b*ArcSin[c+d*x^2]] - 
  Sqrt[Pi]*x*(Cos[a/(2*b)]+c*Sin[a/(2*b)])*FresnelC[Sqrt[c/(Pi*b)]*Sqrt[a+b*ArcSin[c+d*x^2]]]/
    (Sqrt[c/b]*(Cos[ArcSin[c+d*x^2]/2]-c*Sin[ArcSin[c+d*x^2]/2])) + 
  Sqrt[Pi]*x*(Cos[a/(2*b)]-c*Sin[a/(2*b)])*FresnelS[Sqrt[c/(Pi*b)]*Sqrt[a+b*ArcSin[c+d*x^2]]]/
    (Sqrt[c/b]*(Cos[ArcSin[c+d*x^2]/2]-c*Sin[ArcSin[c+d*x^2]/2])) /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1]

2.  ∫(Sqrt[a+b ArcCos[c+d (x^2)]])dx  when  (c^2)==1

1:  ∫(Sqrt[a+b ArcCos[1+d (x^2)]])dx

Rule:

∫(Sqrt[a+b ArcCos[1+d (x^2)]])dx  ⟶  
-((2 (Sqrt[a+b ArcCos[1+d (x^2)]]) ((Sin[(1/2) ArcCos[1+d (x^2)]])^2))/(d x))+
-((2 (Sqrt[π]) Sin[(a/(2 b))] Sin[(1/2) ArcCos[1+d (x^2)]] FresnelC[(Sqrt[(1/(π b))])(Sqrt[a+b ArcCos[1+d (x^2)]])])/((Sqrt[(1/b)]) d x))+((2 (Sqrt[π]) Cos[(a/(2 b))] Sin[(1/2) ArcCos[1+d (x^2)]] FresnelS[(Sqrt[(1/(π b))])(Sqrt[a+b ArcCos[1+d (x^2)]])])/((Sqrt[(1/b)]) d x))

Program code:

Int[Sqrt[a_.+b_.*ArcCos[1+d_.*x_^2]],x_Symbol] :=
  -2*Sqrt[a+b*ArcCos[1+d*x^2]]*Sin[ArcCos[1+d*x^2]/2]^2/(d*x) - 
  2*Sqrt[Pi]*Sin[a/(2*b)]*Sin[ArcCos[1+d*x^2]/2]*FresnelC[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[1+d*x^2]]]/(Sqrt[1/b]*d*x) + 
  2*Sqrt[Pi]*Cos[a/(2*b)]*Sin[ArcCos[1+d*x^2]/2]*FresnelS[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[1+d*x^2]]]/(Sqrt[1/b]*d*x) /;
FreeQ[{a,b,d},x]

2:  ∫(Sqrt[a+b ArcCos[-1+d (x^2)]])dx

Rule:

∫(Sqrt[a+b ArcCos[-1+d (x^2)]])dx  ⟶  
((2 (Sqrt[a+b ArcCos[-1+d (x^2)]]) ((Cos[(1/2) ArcCos[-1+d (x^2)]])^2))/(d x))-
((2 (Sqrt[π]) Cos[(a/(2 b))] Cos[(1/2) ArcCos[-1+d (x^2)]] FresnelC[(Sqrt[(1/(π b))])(Sqrt[a+b ArcCos[-1+d (x^2)]])])/((Sqrt[(1/b)]) d x))-((2 (Sqrt[π]) Sin[(a/(2 b))] Cos[(1/2) ArcCos[-1+d (x^2)]] FresnelS[(Sqrt[(1/(π b))])(Sqrt[a+b ArcCos[-1+d (x^2)]])])/((Sqrt[(1/b)]) d x))

Program code:

Int[Sqrt[a_.+b_.*ArcCos[-1+d_.*x_^2]],x_Symbol] :=
  2*Sqrt[a+b*ArcCos[-1+d*x^2]]*Cos[(1/2)*ArcCos[-1+d*x^2]]^2/(d*x) - 
  2*Sqrt[Pi]*Cos[a/(2*b)]*Cos[ArcCos[-1+d*x^2]/2]*FresnelC[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[-1+d*x^2]]]/(Sqrt[1/b]*d*x) - 
  2*Sqrt[Pi]*Sin[a/(2*b)]*Cos[ArcCos[-1+d*x^2]/2]*FresnelS[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[-1+d*x^2]]]/(Sqrt[1/b]*d*x) /;
FreeQ[{a,b,d},x]

2:  ∫(((a+b ArcSin[c+d (x^2)]))^n)dx  when  (c^2)==1 ∧ n>1

Derivation: Integration by parts twice

Basis: If  (c^2)==1, then (∂_x)(((a+b ArcSin[c+d (x^2)]))^n)==((2 b d n x (((a+b ArcSin[c+d (x^2)]))^(n-1)))/(Sqrt[-2 c d (x^2)-(d^2) (x^4)]))

Basis: ((x^2)/(Sqrt[-d (x^2) (2 c+d (x^2))]))==-(∂_x)((Sqrt[-2 c d (x^2)-(d^2) (x^4)])/((d^2) x))

Rule: If  (c^2)==1 ∧ n>1, then

∫(((a+b ArcSin[c+d (x^2)]))^n)dx  ⟶  x (((a+b ArcSin[c+d (x^2)]))^n)-2 b d n∫(((x^2) (((a+b ArcSin[c+d (x^2)]))^(n-1)))/(Sqrt[-2 c d (x^2)-(d^2) (x^4)]))dx

  ⟶  x (((a+b ArcSin[c+d (x^2)]))^n)+((2 b n (Sqrt[-2 c d (x^2)-(d^2) (x^4)]) (((a+b ArcSin[c+d (x^2)]))^(n-1)))/(d x))-4 (b^2)n (n-1)∫(((a+b ArcSin[c+d (x^2)]))^(n-2))dx

Program code:

Int[(a_.+b_.*ArcSin[c_+d_.*x_^2])^n_,x_Symbol] :=
  x*(a+b*ArcSin[c+d*x^2])^n + 
  2*b*n*Sqrt[-2*c*d*x^2-d^2*x^4]*(a+b*ArcSin[c+d*x^2])^(n-1)/(d*x) - 
  4*b^2*n*(n-1)*Int[(a+b*ArcSin[c+d*x^2])^(n-2),x] /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1] && GtQ[n,1]

Int[(a_.+b_.*ArcCos[c_+d_.*x_^2])^n_,x_Symbol] :=
  x*(a+b*ArcCos[c+d*x^2])^n - 
  2*b*n*Sqrt[-2*c*d*x^2-d^2*x^4]*(a+b*ArcCos[c+d*x^2])^(n-1)/(d*x) - 
  4*b^2*n*(n-1)*Int[(a+b*ArcCos[c+d*x^2])^(n-2),x] /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1] && GtQ[n,1]

2.  ∫(((a+b ArcSin[c+d (x^2)]))^n)dx  when  (c^2)==1 ∧ n<0

1.  ∫(1/(a+b ArcSin[c+d (x^2)]))dx  when  (c^2)==1

1:  ∫(1/(a+b ArcSin[c+d (x^2)]))dx  when  (c^2)==1

Rule: If  (c^2)==1, then

∫(1/(a+b ArcSin[c+d (x^2)]))dx  ⟶  
-((x (c Cos[(a/(2 b))]-Sin[(a/(2 b))])CosIntegral[(c/(2 b))(a+b ArcSin[c+d (x^2)])])/(2 b (Cos[(1/2) ArcSin[c+d (x^2)]]-c Sin[(1/2) ArcSin[c+d (x^2)]])))-((x (c Cos[(a/(2 b))]+Sin[(a/(2 b))]) SinIntegral[(c/(2 b))(a+b ArcSin[c+d (x^2)])])/(2 b (Cos[(1/2) ArcSin[c+d (x^2)]]-c Sin[(1/2) ArcSin[c+d (x^2)]])))

Program code:

Int[1/(a_.+b_.*ArcSin[c_+d_.*x_^2]),x_Symbol] :=
  -x*(c*Cos[a/(2*b)]-Sin[a/(2*b)])*CosIntegral[(c/(2*b))*(a+b*ArcSin[c+d*x^2])]/
    (2*b*(Cos[ArcSin[c+d*x^2]/2]-c*Sin[ArcSin[c+d*x^2]/2])) - 
  x*(c*Cos[a/(2*b)]+Sin[a/(2*b)])*SinIntegral[(c/(2*b))*(a+b*ArcSin[c+d*x^2])]/
    (2*b*(Cos[ArcSin[c+d*x^2]/2]-c*Sin[ArcSin[c+d*x^2]/2])) /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1]

2.  ∫(1/(a+b ArcCos[c+d (x^2)]))dx  when  (c^2)==1

1:  ∫(1/(a+b ArcCos[1+d (x^2)]))dx

Rule:

∫(1/(a+b ArcCos[1+d (x^2)]))dx  ⟶  
((x Cos[(a/(2 b))] CosIntegral[(1/(2 b))(a+b ArcCos[1+d (x^2)])])/((Sqrt[2]) b (Sqrt[-d (x^2)])))+((x Sin[(a/(2 b))] SinIntegral[(1/(2 b))(a+b ArcCos[1+d (x^2)])])/((Sqrt[2]) b (Sqrt[-d (x^2)])))

Program code:

Int[1/(a_.+b_.*ArcCos[1+d_.*x_^2]),x_Symbol] :=
  x*Cos[a/(2*b)]*CosIntegral[(a+b*ArcCos[1+d*x^2])/(2*b)]/(Sqrt[2]*b*Sqrt[-d*x^2]) + 
  x*Sin[a/(2*b)]*SinIntegral[(a+b*ArcCos[1+d*x^2])/(2*b)]/(Sqrt[2]*b*Sqrt[-d*x^2]) /;
FreeQ[{a,b,d},x]

2:  ∫(1/(a+b ArcCos[-1+d (x^2)]))dx

Rule:

∫(1/(a+b ArcCos[-1+d (x^2)]))dx  ⟶  
((x Sin[(a/(2 b))]CosIntegral[(1/(2 b))(a+b ArcCos[-1+d (x^2)])])/((Sqrt[2]) b (Sqrt[d (x^2)])))-((x Cos[(a/(2 b))] SinIntegral[(1/(2 b))(a+b ArcCos[-1+d (x^2)])])/((Sqrt[2]) b (Sqrt[d (x^2)])))

Program code:

Int[1/(a_.+b_.*ArcCos[-1+d_.*x_^2]),x_Symbol] :=
  x*Sin[a/(2*b)]*CosIntegral[(a+b*ArcCos[-1+d*x^2])/(2*b)]/(Sqrt[2]*b*Sqrt[d*x^2]) - 
  x*Cos[a/(2*b)]*SinIntegral[(a+b*ArcCos[-1+d*x^2])/(2*b)]/(Sqrt[2]*b*Sqrt[d*x^2]) /;
FreeQ[{a,b,d},x]

2.  ∫(1/(Sqrt[a+b ArcSin[c+d (x^2)]]))dx  when  (c^2)==1

1:  ∫(1/(Sqrt[a+b ArcSin[c+d (x^2)]]))dx  when  (c^2)==1

Rule: If  (c^2)==1, then

∫(1/(Sqrt[a+b ArcSin[c+d (x^2)]]))dx  ⟶  
-(((Sqrt[π]) x (Cos[(a/(2 b))]-c Sin[(a/(2 b))]) FresnelC[(1/((Sqrt[b c]) (Sqrt[π])))(Sqrt[a+b ArcSin[c+d (x^2)]])])/((Sqrt[b c]) (Cos[(1/2) ArcSin[c+d (x^2)]]-c Sin[(1/2) ArcSin[c+d (x^2)]])))-(((Sqrt[π]) x (Cos[(a/(2 b))]+c Sin[(a/(2 b))]) FresnelS[(1/((Sqrt[b c]) (Sqrt[π])))(Sqrt[a+b ArcSin[c+d (x^2)]])])/((Sqrt[b c]) (Cos[(1/2) ArcSin[c+d (x^2)]]-c Sin[(1/2) ArcSin[c+d (x^2)]])))

Program code:

Int[1/Sqrt[a_.+b_.*ArcSin[c_+d_.*x_^2]],x_Symbol] :=
  -Sqrt[Pi]*x*(Cos[a/(2*b)]-c*Sin[a/(2*b)])*FresnelC[1/(Sqrt[b*c]*Sqrt[Pi])*Sqrt[a+b*ArcSin[c+d*x^2]]]/
    (Sqrt[b*c]*(Cos[ArcSin[c+d*x^2]/2]-c*Sin[ArcSin[c+d*x^2]/2])) - 
  Sqrt[Pi]*x*(Cos[a/(2*b)]+c*Sin[a/(2*b)])*FresnelS[(1/(Sqrt[b*c]*Sqrt[Pi]))*Sqrt[a+b*ArcSin[c+d*x^2]]]/
    (Sqrt[b*c]*(Cos[ArcSin[c+d*x^2]/2]-c*Sin[ArcSin[c+d*x^2]/2])) /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1]

2.  ∫(1/(Sqrt[a+b ArcCos[c+d (x^2)]]))dx  when  (c^2)==1

1:  ∫(1/(Sqrt[a+b ArcCos[1+d (x^2)]]))dx

Rule:

∫(1/(Sqrt[a+b ArcCos[1+d (x^2)]]))dx  ⟶  
-((2 (Sqrt[(π/b)]) Cos[(a/(2 b))] Sin[(1/2) ArcCos[1+d (x^2)]]FresnelC[(Sqrt[(1/(π b))]) (Sqrt[a+b ArcCos[1+d (x^2)]])])/(d x))-((2 (Sqrt[(π/b)])Sin[(a/(2 b))] Sin[(1/2) ArcCos[1+d (x^2)]]FresnelS[(Sqrt[(1/(π b))]) (Sqrt[a+b ArcCos[1+d (x^2)]])])/(d x))

Program code:

Int[1/Sqrt[a_.+b_.*ArcCos[1+d_.*x_^2]],x_Symbol] :=
  -2*Sqrt[Pi/b]*Cos[a/(2*b)]*Sin[ArcCos[1+d*x^2]/2]*FresnelC[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[1+d*x^2]]]/(d*x) - 
   2*Sqrt[Pi/b]*Sin[a/(2*b)]*Sin[ArcCos[1+d*x^2]/2]*FresnelS[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[1+d*x^2]]]/(d*x) /;
FreeQ[{a,b,d},x]

2:  ∫(1/(Sqrt[a+b ArcCos[-1+d (x^2)]]))dx

Rule:

∫(1/(Sqrt[a+b ArcCos[-1+d (x^2)]]))dx  ⟶  
((2 (Sqrt[(π/b)]) Sin[(a/(2 b))]Cos[(1/2) ArcCos[-1+d (x^2)]] FresnelC[(Sqrt[(1/(π b))]) (Sqrt[a+b ArcCos[-1+d (x^2)]])])/(d x))-((2 (Sqrt[(π/b)]) Cos[(a/(2 b))] Cos[(1/2) ArcCos[-1+d (x^2)]] FresnelS[(Sqrt[(1/(π b))]) (Sqrt[a+b ArcCos[-1+d (x^2)]])])/(d x))

Program code:

Int[1/Sqrt[a_.+b_.*ArcCos[-1+d_.*x_^2]],x_Symbol] :=
  2*Sqrt[Pi/b]*Sin[a/(2*b)]*Cos[ArcCos[-1+d*x^2]/2]*FresnelC[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[-1+d*x^2]]]/(d*x) - 
  2*Sqrt[Pi/b]*Cos[a/(2*b)]*Cos[ArcCos[-1+d*x^2]/2]*FresnelS[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[-1+d*x^2]]]/(d*x) /;
FreeQ[{a,b,d},x]

3.  ∫(((a+b ArcSin[c+d (x^2)]))^n)dx  when  (c^2)==1 ∧ n<-1

1.  ∫(1/(((a+b ArcSin[c+d (x^2)]))^(3/2)))dx  when  (c^2)==1

1:  ∫(1/(((a+b ArcSin[c+d (x^2)]))^(3/2)))dx  when  (c^2)==1

Derivation: Integration by parts

Basis: If  (c^2)==1, then -((b d x)/((Sqrt[-2 c d (x^2)-(d^2) (x^4)]) (((a+b ArcSin[c+d (x^2)]))^(3/2))))==(∂_x)(1/(Sqrt[a+b ArcSin[c+d (x^2)]]))

Rule: If  (c^2)==1, then

∫(1/(((a+b ArcSin[c+d (x^2)]))^(3/2)))dx  ⟶  -((Sqrt[-2 c d (x^2)-(d^2) (x^4)])/(b d x(Sqrt[a+b ArcSin[c+d (x^2)]])))-(d/b)∫((x^2)/((Sqrt[-2 c d (x^2)-(d^2) (x^4)]) (Sqrt[a+b ArcSin[c+d (x^2)]])))dx

  ⟶  -((Sqrt[-2 c d (x^2)-(d^2) (x^4)])/(b d x (Sqrt[a+b ArcSin[c+d (x^2)]])))-
((((((c/b)))^(3/2)) (Sqrt[π]) x (Cos[(a/(2 b))]+c Sin[(a/(2 b))]) FresnelC[(Sqrt[(c/(π b))]) (Sqrt[a+b ArcSin[c+d (x^2)]])])/(Cos[(1/2) ArcSin[c+d (x^2)]]-c Sin[(1/2) ArcSin[c+d (x^2)]]))+
((((((c/b)))^(3/2)) (Sqrt[π]) x (Cos[(a/(2 b))]-c Sin[(a/(2 b))]) FresnelS[(Sqrt[(c/(π b))]) (Sqrt[a+b ArcSin[c+d (x^2)]])])/(Cos[(1/2) ArcSin[c+d (x^2)]]-c Sin[(1/2) ArcSin[c+d (x^2)]]))

Program code:

Int[1/(a_.+b_.*ArcSin[c_+d_.*x_^2])^(3/2),x_Symbol] :=
  -Sqrt[-2*c*d*x^2-d^2*x^4]/(b*d*x*Sqrt[a+b*ArcSin[c+d*x^2]]) - 
  (c/b)^(3/2)*Sqrt[Pi]*x*(Cos[a/(2*b)]+c*Sin[a/(2*b)])*FresnelC[Sqrt[c/(Pi*b)]*Sqrt[a+b*ArcSin[c+d*x^2]]]/
    (Cos[(1/2)*ArcSin[c+d*x^2]]-c*Sin[ArcSin[c+d*x^2]/2]) + 
  (c/b)^(3/2)*Sqrt[Pi]*x*(Cos[a/(2*b)]-c*Sin[a/(2*b)])*FresnelS[Sqrt[c/(Pi*b)]*Sqrt[a+b*ArcSin[c+d*x^2]]]/
    (Cos[(1/2)*ArcSin[c+d*x^2]]-c*Sin[ArcSin[c+d*x^2]/2]) /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1]

2.  ∫(1/(((a+b ArcCos[c+d (x^2)]))^(3/2)))dx  when  (c^2)==1

1:  ∫(1/(((a+b ArcCos[1+d (x^2)]))^(3/2)))dx

Derivation: Integration by parts

Basis: ((b d x)/((Sqrt[-2 d (x^2)-(d^2) (x^4)]) (((a+b ArcCos[1+d (x^2)]))^(3/2))))==(∂_x)(1/(Sqrt[a+b ArcCos[1+d (x^2)]]))

Rule:

∫(1/(((a+b ArcCos[1+d (x^2)]))^(3/2)))dx  ⟶  ((Sqrt[-2 d (x^2)-(d^2) (x^4)])/(b d x (Sqrt[a+b ArcCos[1+d (x^2)]])))+(d/b)∫((x^2)/((Sqrt[-2 d (x^2)-(d^2) (x^4)]) (Sqrt[a+b ArcCos[1+d (x^2)]])))dx

  ⟶  ((Sqrt[-2 d (x^2)-(d^2) (x^4)])/(b d x (Sqrt[a+b ArcCos[1+d (x^2)]])))-
((2 ((((1/b)))^(3/2)) (Sqrt[π]) Sin[(a/(2 b))] Sin[(1/2) ArcCos[1+d (x^2)]] FresnelC[(Sqrt[(1/(π b))]) (Sqrt[a+b ArcCos[1+d (x^2)]])])/(d x))+
((2 ((((1/b)))^(3/2)) (Sqrt[π]) Cos[(a/(2 b))] Sin[(1/2) ArcCos[1+d (x^2)]] FresnelS[(Sqrt[(1/(π b))]) (Sqrt[a+b ArcCos[1+d (x^2)]])])/(d x))

Program code:

Int[1/(a_.+b_.*ArcCos[1+d_.*x_^2])^(3/2),x_Symbol] :=
  Sqrt[-2*d*x^2-d^2*x^4]/(b*d*x*Sqrt[a+b*ArcCos[1+d*x^2]]) - 
  2*(1/b)^(3/2)*Sqrt[Pi]*Sin[a/(2*b)]*Sin[ArcCos[1+d*x^2]/2]*FresnelC[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[1+d*x^2]]]/(d*x) + 
  2*(1/b)^(3/2)*Sqrt[Pi]*Cos[a/(2*b)]*Sin[ArcCos[1+d*x^2]/2]*FresnelS[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[1+d*x^2]]]/(d*x) /;
FreeQ[{a,b,d},x]

2:  ∫(1/(((a+b ArcCos[-1+d (x^2)]))^(3/2)))dx

Derivation: Integration by parts

Basis: ((b d x)/((Sqrt[2 d (x^2)-(d^2) (x^4)]) (((a+b ArcCos[-1+d (x^2)]))^(3/2))))==(∂_x)(1/(Sqrt[a+b ArcCos[-1+d (x^2)]]))

Rule:

∫(1/(((a+b ArcCos[-1+d (x^2)]))^(3/2)))dx  ⟶  ((Sqrt[2 d (x^2)-(d^2) (x^4)])/(b d x (Sqrt[a+b ArcCos[-1+d (x^2)]])))+(d/b)∫((x^2)/((Sqrt[2 d (x^2)-(d^2) (x^4)]) (Sqrt[a+b ArcCos[-1+d (x^2)]])))dx

  ⟶  ((Sqrt[2 d (x^2)-(d^2) (x^4)])/(b d x (Sqrt[a+b ArcCos[-1+d (x^2)]])))-
((2 ((((1/b)))^(3/2)) (Sqrt[π]) Cos[(a/(2 b))] Cos[(1/2) ArcCos[-1+d (x^2)]] FresnelC[(Sqrt[(1/(π b))]) (Sqrt[a+b ArcCos[-1+d (x^2)]])])/(d x))-
((2 ((((1/b)))^(3/2)) (Sqrt[π]) Sin[(a/(2 b))] Cos[(1/2) ArcCos[-1+d (x^2)]] FresnelS[(Sqrt[(1/(π b))]) (Sqrt[a+b ArcCos[-1+d (x^2)]])])/(d x))

Program code:

Int[1/(a_.+b_.*ArcCos[-1+d_.*x_^2])^(3/2),x_Symbol] :=
  Sqrt[2*d*x^2-d^2*x^4]/(b*d*x*Sqrt[a+b*ArcCos[-1+d*x^2]]) - 
  2*(1/b)^(3/2)*Sqrt[Pi]*Cos[a/(2*b)]*Cos[ArcCos[-1+d*x^2]/2]*FresnelC[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[-1+d*x^2]]]/(d*x) - 
  2*(1/b)^(3/2)*Sqrt[Pi]*Sin[a/(2*b)]*Cos[ArcCos[-1+d*x^2]/2]*FresnelS[Sqrt[1/(Pi*b)]*Sqrt[a+b*ArcCos[-1+d*x^2]]]/(d*x) /;
FreeQ[{a,b,d},x]

2.  ∫(1/(((a+b ArcSin[c+d (x^2)]))^2))dx  when  (c^2)==1

1:  ∫(1/(((a+b ArcSin[c+d (x^2)]))^2))dx  when  (c^2)==1

Derivation: Integration by parts

Basis: If  (c^2)==1, then -((2 b d x)/((Sqrt[-2 c d (x^2)-(d^2) (x^4)]) (((a+b ArcSin[c+d (x^2)]))^2)))==(∂_x)(1/(a+b ArcSin[c+d (x^2)]))

Rule: If  (c^2)==1, then

∫(1/(((a+b ArcSin[c+d (x^2)]))^2))dx  ⟶  -((Sqrt[-2 c d (x^2)-(d^2) (x^4)])/(2 b d x (a+b ArcSin[c+d (x^2)])))-(d/(2 b))∫((x^2)/((Sqrt[-2 c d (x^2)-(d^2) (x^4)]) (a+b ArcSin[c+d (x^2)])))dx

  ⟶  -((Sqrt[-2 c d (x^2)-(d^2) (x^4)])/(2 b d x (a+b ArcSin[c+d (x^2)])))-((x (Cos[(a/(2 b))]+c Sin[(a/(2 b))])CosIntegral[(c/(2 b))(a+b ArcSin[c+d (x^2)])])/(4 (b^2) (Cos[(1/2) ArcSin[c+d (x^2)]]-c Sin[(1/2) ArcSin[c+d (x^2)]])))+((x (Cos[(a/(2 b))]-c Sin[(a/(2 b))]) SinIntegral[(c/(2 b))(a+b ArcSin[c+d (x^2)])])/(4 (b^2) (Cos[(1/2) ArcSin[c+d (x^2)]]-c Sin[(1/2) ArcSin[c+d (x^2)]])))

Program code:

Int[1/(a_.+b_.*ArcSin[c_+d_.*x_^2])^2,x_Symbol] :=
  -Sqrt[-2*c*d*x^2-d^2*x^4]/(2*b*d*x*(a+b*ArcSin[c+d*x^2])) - 
  x*(Cos[a/(2*b)]+c*Sin[a/(2*b)])*CosIntegral[(c/(2*b))*(a+b*ArcSin[c+d*x^2])]/
    (4*b^2*(Cos[ArcSin[c+d*x^2]/2]-c*Sin[ArcSin[c+d*x^2]/2])) + 
  x*(Cos[a/(2*b)]-c*Sin[a/(2*b)])*SinIntegral[(c/(2*b))*(a+b*ArcSin[c+d*x^2])]/
    (4*b^2*(Cos[ArcSin[c+d*x^2]/2]-c*Sin[ArcSin[c+d*x^2]/2])) /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1]

2.  ∫(1/(((a+b ArcCos[c+d (x^2)]))^2))dx  when  (c^2)==1

1:  ∫(1/(((a+b ArcCos[1+d (x^2)]))^2))dx

Rule:

∫(1/(((a+b ArcCos[1+d (x^2)]))^2))dx  ⟶  
((Sqrt[-2 d (x^2)-(d^2) (x^4)])/(2 b d x (a+b ArcCos[1+d (x^2)])))+((x Sin[(a/(2 b))] CosIntegral[(1/(2 b))(a+b ArcCos[1+d (x^2)])])/(2 (Sqrt[2]) (b^2) (Sqrt[-d (x^2)])))-((x Cos[(a/(2 b))] SinIntegral[(1/(2 b))(a+b ArcCos[1+d (x^2)])])/(2 (Sqrt[2]) (b^2) (Sqrt[-d (x^2)])))

Program code:

Int[1/(a_.+b_.*ArcCos[1+d_.*x_^2])^2,x_Symbol] :=
  Sqrt[-2*d*x^2-d^2*x^4]/(2*b*d*x*(a+b*ArcCos[1+d*x^2])) + 
  x*Sin[a/(2*b)]*CosIntegral[(a+b*ArcCos[1+d*x^2])/(2*b)]/(2*Sqrt[2]*b^2*Sqrt[(-d)*x^2]) - 
  x*Cos[a/(2*b)]*SinIntegral[(a+b*ArcCos[1+d*x^2])/(2*b)]/(2*Sqrt[2]*b^2*Sqrt[(-d)*x^2]) /;
FreeQ[{a,b,d},x]

2:  ∫(1/(((a+b ArcCos[-1+d (x^2)]))^2))dx

Rule:

∫(1/(((a+b ArcCos[-1+d (x^2)]))^2))dx  ⟶  
((Sqrt[2 d (x^2)-(d^2) (x^4)])/(2 b d x (a+b ArcCos[-1+d (x^2)])))-((x Cos[(a/(2 b))] CosIntegral[(1/(2 b))(a+b ArcCos[-1+d (x^2)])])/(2 (Sqrt[2]) (b^2) (Sqrt[d (x^2)])))-((x Sin[(a/(2 b))] SinIntegral[(1/(2 b))(a+b ArcCos[-1+d (x^2)])])/(2 (Sqrt[2]) (b^2) (Sqrt[d (x^2)])))

Program code:

Int[1/(a_.+b_.*ArcCos[-1+d_.*x_^2])^2,x_Symbol] :=
  Sqrt[2*d*x^2-d^2*x^4]/(2*b*d*x*(a+b*ArcCos[-1+d*x^2])) - 
  x*Cos[a/(2*b)]*CosIntegral[(a+b*ArcCos[-1+d*x^2])/(2*b)]/(2*Sqrt[2]*b^2*Sqrt[d*x^2]) - 
  x*Sin[a/(2*b)]*SinIntegral[(a+b*ArcCos[-1+d*x^2])/(2*b)]/(2*Sqrt[2]*b^2*Sqrt[d*x^2]) /;
FreeQ[{a,b,d},x]

3:  ∫(((a+b ArcSin[c+d (x^2)]))^n)dx  when  (c^2)==1 ∧ n<-1 ∧ n≠-2

Derivation: Inverted integration by parts twice

Rule: If  (c^2)==1 ∧ n<-1 ∧ n≠-2, then

∫(((a+b ArcSin[c+d (x^2)]))^n)dx  ⟶  
((x (((a+b ArcSin[c+d (x^2)]))^(n+2)))/(4 (b^2) (n+1) (n+2)))+(((Sqrt[-2 c d (x^2)-(d^2) (x^4)]) (((a+b ArcSin[c+d (x^2)]))^(n+1)))/(2 b d (n+1) x))-(1/(4 (b^2) (n+1) (n+2)))∫(((a+b ArcSin[c+d (x^2)]))^(n+2))dx

Program code:

Int[(a_.+b_.*ArcSin[c_+d_.*x_^2])^n_,x_Symbol] :=
  x*(a+b*ArcSin[c+d*x^2])^(n+2)/(4*b^2*(n+1)*(n+2)) + 
  Sqrt[-2*c*d*x^2-d^2*x^4]*(a+b*ArcSin[c+d*x^2])^(n+1)/(2*b*d*(n+1)*x) - 
  1/(4*b^2*(n+1)*(n+2))*Int[(a+b*ArcSin[c+d*x^2])^(n+2),x] /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1] && LtQ[n,-1] && NeQ[n,-2]

Int[(a_.+b_.*ArcCos[c_+d_.*x_^2])^n_,x_Symbol] :=
  x*(a+b*ArcCos[c+d*x^2])^(n+2)/(4*b^2*(n+1)*(n+2)) - 
  Sqrt[-2*c*d*x^2-d^2*x^4]*(a+b*ArcCos[c+d*x^2])^(n+1)/(2*b*d*(n+1)*x) - 
  1/(4*b^2*(n+1)*(n+2))*Int[(a+b*ArcCos[c+d*x^2])^(n+2),x] /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1] && LtQ[n,-1] && NeQ[n,-2]

3:  ∫(((ArcSin[a (x^p)])^n)/x)dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: (((ArcSin[a (x^p)])^n)/x)==(1/p) ((ArcSin[a (x^p)])^n) Cot[ArcSin[a (x^p)]] (∂_x)ArcSin[a (x^p)]

Rule: If  n∈(SuperPlus[ℤ]), then

∫(((ArcSin[a (x^p)])^n)/x)dx  ⟶  (1/p) Subst[∫(x^n) Cot[x]dx,x,ArcSin[a (x^p)]]

Program code:

Int[ArcSin[a_.*x_^p_]^n_./x_,x_Symbol] :=
  1/p*Subst[Int[x^n*Cot[x],x],x,ArcSin[a*x^p]] /;
FreeQ[{a,p},x] && IGtQ[n,0]

Int[ArcCos[a_.*x_^p_]^n_./x_,x_Symbol] :=
  -1/p*Subst[Int[x^n*Tan[x],x],x,ArcCos[a*x^p]] /;
FreeQ[{a,p},x] && IGtQ[n,0]

4:  ∫u ((ArcSin[(c/(a+b (x^n)))])^m)dx

Derivation:  Algebraic simplification

Basis: ArcSin[z]==ArcCsc[(1/z)]

Rule:

∫u ((ArcSin[(c/(a+b (x^n)))])^m)dx  ⟶  ∫u ((ArcCsc[(a/c)+((b (x^n))/c)])^m)dx

Program code:

Int[u_.*ArcSin[c_./(a_.+b_.*x_^n_.)]^m_.,x_Symbol] :=
  Int[u*ArcCsc[a/c+b*x^n/c]^m,x] /;
FreeQ[{a,b,c,n,m},x]

Int[u_.*ArcCos[c_./(a_.+b_.*x_^n_.)]^m_.,x_Symbol] :=
  Int[u*ArcSec[a/c+b*x^n/c]^m,x] /;
FreeQ[{a,b,c,n,m},x]

5:  ∫(((ArcSin[(Sqrt[1+b (x^2)])])^n)/(Sqrt[1+b (x^2)]))dx

Derivation:  Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[-b (x^2)])/x)==0

Basis: ((x ((ArcSin[(Sqrt[1+b (x^2)])])^n))/((Sqrt[-b (x^2)]) (Sqrt[1+b (x^2)])))==(1/b)Subst[(((ArcSin[x])^n)/(Sqrt[1-(x^2)])),x,(Sqrt[1+b (x^2)])] (∂_x)(Sqrt[1+b (x^2)])

Rule:

∫(((ArcSin[(Sqrt[1+b (x^2)])])^n)/(Sqrt[1+b (x^2)]))dx  ⟶  (( (Sqrt[-b (x^2)]))/x) ∫((x ((ArcSin[(Sqrt[1+b (x^2)])])^n))/((Sqrt[-b (x^2)]) (Sqrt[1+b (x^2)])))dx
  ⟶  (( (Sqrt[-b (x^2)]))/(b x)) Subst[∫(((ArcSin[x])^n)/(Sqrt[1-(x^2)]))dx,x,(Sqrt[1+b (x^2)])]

Program code:

Int[ArcSin[Sqrt[1+b_.*x_^2]]^n_./Sqrt[1+b_.*x_^2],x_Symbol] :=
  Sqrt[-b*x^2]/(b*x)*Subst[Int[ArcSin[x]^n/Sqrt[1-x^2],x],x,Sqrt[1+b*x^2]] /;
FreeQ[{b,n},x]

Int[ArcCos[Sqrt[1+b_.*x_^2]]^n_./Sqrt[1+b_.*x_^2],x_Symbol] :=
  Sqrt[-b*x^2]/(b*x)*Subst[Int[ArcCos[x]^n/Sqrt[1-x^2],x],x,Sqrt[1+b*x^2]] /;
FreeQ[{b,n},x]

6:  ∫u (f^(c ((ArcSin[a+b x])^n)))dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[x,ArcSin[a+b x]]==(1/b)Subst[F[-(a/b)+((Sin[x])/b),x] Cos[x],x,ArcSin[a+b x]] (∂_x)ArcSin[a+b x]

Rule: If  n∈(SuperPlus[ℤ]), then

∫u (f^(c ((ArcSin[a+b x])^n)))dx  ⟶  (1/b)Subst[∫Subst[u,x,-(a/b)+((Sin[x])/b)] (f^(c (x^n)))Cos[x]dx,x,ArcSin[a+b x]]

Program code:

Int[u_.*f_^(c_.*ArcSin[a_.+b_.*x_]^n_.),x_Symbol] :=
  1/b*Subst[Int[ReplaceAll[u,x->-a/b+Sin[x]/b]*f^(c*x^n)*Cos[x],x],x,ArcSin[a+b*x]] /;
FreeQ[{a,b,c,f},x] && IGtQ[n,0]

Int[u_.*f_^(c_.*ArcCos[a_.+b_.*x_]^n_.),x_Symbol] :=
  -1/b*Subst[Int[ReplaceAll[u,x->-a/b+Cos[x]/b]*f^(c*x^n)*Sin[x],x],x,ArcCos[a+b*x]] /;
FreeQ[{a,b,c,f},x] && IGtQ[n,0]

7.  ∫v (a+b ArcSin[u])dx  when  u is free of inverse functions

1.  ∫v (a+b ArcSin[u])dx  when  u is free of inverse functions

1:  ∫ArcSin[a (x^2)+b (Sqrt[c+d (x^2)])]dx  when  (b^2) c==1

Derivation: Integration by parts and piecewise constant extraction

Basis: If  (b^2) c==1, then 1-(((a (x^2)+b (Sqrt[c+d (x^2)])))^2)==-(x^2) ((b^2) d+(a^2) (x^2)+2 a b (Sqrt[c+d (x^2)]))

Basis: (∂_x)((x (Sqrt[(b^2) d+(a^2) (x^2)+2 a b (Sqrt[c+d (x^2)])]))/(Sqrt[-(x^2) ((b^2) d+(a^2) (x^2)+2 a b (Sqrt[c+d (x^2)]))]))==0

Note: The resulting integrand is of the form x F[(x^2)] which can be integrated by substitution.

Rule: If  (b^2) c==1, then

∫ArcSin[a (x^2)+b (Sqrt[c+d (x^2)])]dx  ⟶  x ArcSin[a (x^2)+b (Sqrt[c+d (x^2)])]-∫(((x^2) (b d+2 a (Sqrt[c+d (x^2)])))/((Sqrt[c+d (x^2)]) (Sqrt[-(x^2) ((b^2) d+(a^2) (x^2)+2 a b (Sqrt[c+d (x^2)]))])))dx
  ⟶  x ArcSin[a (x^2)+b (Sqrt[c+d (x^2)])]-((x (Sqrt[(b^2) d+(a^2) (x^2)+2 a b (Sqrt[c+d (x^2)])]))/(Sqrt[-(x^2) ((b^2) d+(a^2) (x^2)+2 a b (Sqrt[c+d (x^2)]))])) ∫((x (b d+2 a (Sqrt[c+d (x^2)])))/((Sqrt[c+d (x^2)]) (Sqrt[(b^2) d+(a^2) (x^2)+2 a b (Sqrt[c+d (x^2)])])))dx

Program code:

Int[ArcSin[a_.*x_^2+b_.*Sqrt[c_+d_.*x_^2]],x_Symbol] :=
  x*ArcSin[a*x^2+b*Sqrt[c+d*x^2]] - 
  x*Sqrt[b^2*d+a^2*x^2+2*a*b*Sqrt[c+d*x^2]]/Sqrt[(-x^2)*(b^2*d+a^2*x^2+2*a*b*Sqrt[c+d*x^2])]*
    Int[x*(b*d+2*a*Sqrt[c+d*x^2])/(Sqrt[c+d*x^2]*Sqrt[b^2*d +a^2*x^2+2*a*b*Sqrt[c+d*x^2]]),x] /;
FreeQ[{a,b,c,d},x] && EqQ[b^2*c,1]

Int[ArcCos[a_.*x_^2+b_.*Sqrt[c_+d_.*x_^2]],x_Symbol] :=
  x*ArcCos[a*x^2+b*Sqrt[c+d*x^2]] + 
  x*Sqrt[b^2*d+a^2*x^2+2*a*b*Sqrt[c+d*x^2]]/Sqrt[(-x^2)*(b^2*d+a^2*x^2+2*a*b*Sqrt[c+d*x^2])]*
    Int[x*(b*d+2*a*Sqrt[c+d*x^2])/(Sqrt[c+d*x^2]*Sqrt[b^2*d+a^2*x^2+2*a*b*Sqrt[c+d*x^2]]),x] /;
FreeQ[{a,b,c,d},x] && EqQ[b^2*c,1]

2:  ∫ArcSin[u]dx  when  u is free of inverse functions

Derivation: Integration by parts

Rule: If u is free of inverse functions, then

∫ArcSin[u]dx  ⟶  x ArcSin[u]-∫((x (∂_x)u)/(Sqrt[1-(u^2)]))dx

Program code:

Int[ArcSin[u_],x_Symbol] :=
  x*ArcSin[u] -
  Int[SimplifyIntegrand[x*D[u,x]/Sqrt[1-u^2],x],x] /;
InverseFunctionFreeQ[u,x] && Not[FunctionOfExponentialQ[u,x]]

Int[ArcCos[u_],x_Symbol] :=
  x*ArcCos[u] +
  Int[SimplifyIntegrand[x*D[u,x]/Sqrt[1-u^2],x],x] /;
InverseFunctionFreeQ[u,x] && Not[FunctionOfExponentialQ[u,x]]

2:  ∫(((c+d x))^m)(a+b ArcSin[u])dx  when  m≠-1 ∧ u is free of inverse functions

Derivation: Integration by parts

Rule: If  m≠-1 ∧ u is free of inverse functions, then

∫(((c+d x))^m)(a+b ArcSin[u])dx  ⟶  (((((c+d x))^(m+1)) (a+b ArcSin[u]))/(d(m+1)))-(b/(d(m+1)))∫(((((c+d x))^(m+1)) (∂_x)u)/(Sqrt[1-(u^2)]))dx

Program code:

Int[(c_.+d_.*x_)^m_.*(a_.+b_.*ArcSin[u_]),x_Symbol] :=
  (c+d*x)^(m+1)*(a+b*ArcSin[u])/(d*(m+1)) -
  b/(d*(m+1))*Int[SimplifyIntegrand[(c+d*x)^(m+1)*D[u,x]/Sqrt[1-u^2],x],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1] && InverseFunctionFreeQ[u,x] && Not[FunctionOfQ[(c+d*x)^(m+1),u,x]] && Not[FunctionOfExponentialQ[u,x]]

Int[(c_.+d_.*x_)^m_.*(a_.+b_.*ArcCos[u_]),x_Symbol] :=
  (c+d*x)^(m+1)*(a+b*ArcCos[u])/(d*(m+1)) +
  b/(d*(m+1))*Int[SimplifyIntegrand[(c+d*x)^(m+1)*D[u,x]/Sqrt[1-u^2],x],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1] && InverseFunctionFreeQ[u,x] && Not[FunctionOfQ[(c+d*x)^(m+1),u,x]] && Not[FunctionOfExponentialQ[u,x]]

3:  ∫v (a+b ArcSin[u])dx  when  u and ∫vdx  are free of inverse functions

Derivation: Integration by parts

Rule: If u is free of inverse functions, let  w==∫vdx, if w is free of inverse functions, then

∫v (a+b ArcSin[u])dx  ⟶  w (a+b ArcSin[u])-b∫((w (∂_x)u)/(Sqrt[1-(u^2)]))dx

Program code:

Int[v_*(a_.+b_.*ArcSin[u_]),x_Symbol] :=
  With[{w=IntHide[v,x]},  
  Dist[(a+b*ArcSin[u]),w,x] -
  b*Int[SimplifyIntegrand[w*D[u,x]/Sqrt[1-u^2],x],x] /;
 InverseFunctionFreeQ[w,x]] /;
FreeQ[{a,b},x] && InverseFunctionFreeQ[u,x] && Not[MatchQ[v, (c_.+d_.*x)^m_. /; FreeQ[{c,d,m},x]]]

Int[v_*(a_.+b_.*ArcCos[u_]),x_Symbol] :=
  With[{w=IntHide[v,x]},  
  Dist[(a+b*ArcCos[u]),w,x] +
  b*Int[SimplifyIntegrand[w*D[u,x]/Sqrt[1-u^2],x],x] /;
 InverseFunctionFreeQ[w,x]] /;
FreeQ[{a,b},x] && InverseFunctionFreeQ[u,x] && Not[MatchQ[v, (c_.+d_.*x)^m_. /; FreeQ[{c,d,m},x]]]