Rules for integrands of the form(((a+b ArcTan[c (x^n)]))^p)

1:  ∫(((a+b ArcTan[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])∧(n==1∨p==1)

Derivation: Integration by parts

Basis: (∂_x)(((a+b ArcTan[c (x^n)]))^p)==b c n p (((x^(n-1)) (((a+b ArcTan[c (x^n)]))^(p-1)))/(1+(c^2) (x^(2 n))))

Rule: If  p∈(SuperPlus[ℤ])∧(n==1∨p==1), then

∫(((a+b ArcTan[c (x^n)]))^p)dx  ⟶  x (((a+b ArcTan[c (x^n)]))^p)-b c n p ∫(((x^n) (((a+b ArcTan[c (x^n)]))^(p-1)))/(1+(c^2) (x^(2 n))))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_^n_.])^p_.,x_Symbol] :=
  x*(a+b*ArcTan[c*x^n])^p - 
  b*c*n*p*Int[x^n*(a+b*ArcTan[c*x^n])^(p-1)/(1+c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,n},x] && IGtQ[p,0] && (EqQ[n,1] || EqQ[p,1])

Int[(a_.+b_.*ArcCot[c_.*x_^n_.])^p_.,x_Symbol] :=
  x*(a+b*ArcCot[c*x^n])^p + 
  b*c*n*p*Int[x^n*(a+b*ArcCot[c*x^n])^(p-1)/(1+c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,n},x] && IGtQ[p,0] && (EqQ[n,1] || EqQ[p,1])

2.  ∫(((a+b ArcTan[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈ℤ

1:  ∫(((a+b ArcTan[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: ArcTan[z]==((i Log[1-i z])/2)-((i Log[1+i z])/2)

Basis: ArcCot[z]==((i Log[1-i (z^(-1))])/2)-((i Log[1+i (z^(-1))])/2)

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ]), then

∫(((a+b ArcTan[c (x^n)]))^p)dx  ⟶  ∫ExpandIntegrand[(((a+((i b Log[1-i c (x^n)])/2)-((i b Log[1+i c (x^n)])/2)))^p),x]dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+(I*b*Log[1-I*c*x^n])/2-(I*b*Log[1+I*c*x^n])/2)^p,x],x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && IGtQ[n,0]

Int[(a_.+b_.*ArcCot[c_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+(I*b*Log[1-I*x^(-n)/c])/2-(I*b*Log[1+I*x^(-n)/c])/2)^p,x],x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && IGtQ[n,0]

2:  ∫(((a+b ArcTan[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: ArcTan[z]==ArcCot[(1/z)]

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈(SuperMinus[ℤ]), then

∫(((a+b ArcTan[c (x^n)]))^p)dx  ⟶  ∫(((a+b ArcCot[((x^(-n))/c)]))^p)dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_^n_])^p_,x_Symbol] :=
  Int[(a+b*ArcCot[x^(-n)/c])^p,x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && ILtQ[n,0]

Int[(a_.+b_.*ArcCot[c_.*x_^n_])^p_,x_Symbol] :=
  Int[(a+b*ArcTan[x^(-n)/c])^p,x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && ILtQ[n,0]

3:  ∫(((a+b ArcTan[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈𝔽

Derivation: Integration by substitution

Basis: If k∈(SuperPlus[ℤ]), then F[x]==k Subst[(x^(k-1)) F[(x^k)],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈𝔽, let k->Denominator[n], then

∫(((a+b ArcTan[c (x^n)]))^p)dx  ⟶  k Subst[∫(x^(k-1)) (((a+b ArcTan[c (x^(k n))]))^p)dx,x,(x^(1/k))]

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_^n_])^p_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*ArcTan[c*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && FractionQ[n]

Int[(a_.+b_.*ArcCot[c_.*x_^n_])^p_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*ArcCot[c*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && FractionQ[n]

U:  ∫(((a+b ArcTan[c (x^n)]))^p)dx

Rule:

∫(((a+b ArcTan[c (x^n)]))^p)dx  ⟶  ∫(((a+b ArcTan[c (x^n)]))^p)dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_^n_.])^p_,x_Symbol] :=
  Unintegrable[(a+b*ArcTan[c*x^n])^p,x] /;
FreeQ[{a,b,c,n,p},x]

Int[(a_.+b_.*ArcCot[c_.*x_^n_.])^p_,x_Symbol] :=
  Unintegrable[(a+b*ArcCot[c*x^n])^p,x] /;
FreeQ[{a,b,c,n,p},x]