Rules for integrands of the form u (((a+b ArcSec[c x]))^n)

1.  ∫(((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫ArcSec[c x]dx

Reference: G&R 2.821.2, CRC 445, A&S 4.4.62

Reference: G&R 2.821.1, CRC 446, A&S 4.4.61

Derivation: Integration by parts

Rule:

∫ArcSec[c x]dx  ⟶  x ArcSec[c x]-(1/c)∫(1/(x (Sqrt[1-(1/((c^2) (x^2)))])))dx

Program code:

Int[ArcSec[c_.*x_],x_Symbol] :=
  x*ArcSec[c*x] - 1/c*Int[1/(x*Sqrt[1-1/(c^2*x^2)]),x] /;
FreeQ[c,x]

Int[ArcCsc[c_.*x_],x_Symbol] :=
  x*ArcCsc[c*x] + 1/c*Int[1/(x*Sqrt[1-1/(c^2*x^2)]),x] /;
FreeQ[c,x]

2:  ∫(((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: 1==(1/c)Sec[ArcSec[c x]]Tan[ArcSec[c x]] (∂_x)ArcSec[c x]

Rule: If  n∈(SuperPlus[ℤ]), then

∫(((a+b ArcSec[c x]))^n)dx  ⟶  (1/c) Subst[∫(((a+b x))^n)Sec[x] Tan[x]dx,x,ArcSec[c x]]

Program code:

Int[(a_.+b_.*ArcSec[c_.*x_])^n_,x_Symbol] :=
  1/c*Subst[Int[(a+b*x)^n*Sec[x]*Tan[x],x],x,ArcSec[c*x]] /;
FreeQ[{a,b,c,n},x] && IGtQ[n,0]

Int[(a_.+b_.*ArcCsc[c_.*x_])^n_,x_Symbol] :=
  -1/c*Subst[Int[(a+b*x)^n*Csc[x]*Cot[x],x],x,ArcCsc[c*x]] /;
FreeQ[{a,b,c,n},x] && IGtQ[n,0]

2.  ∫(((d x))^m) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1.  ∫(((d x))^m) (a+b ArcSec[c x])dx

1:  ∫((a+b ArcSec[c x])/x)dx

Derivation: Integration by substitution

Basis: ArcSec[z]==ArcCos[(1/z)]

Basis: ((F[(1/x)])/x)==-Subst[((F[x])/x),x,(1/x)](∂_x)(1/x)

Rule:

∫((a+b ArcSec[c x])/x)dx  ⟶  ∫((a+b ArcCos[(1/(c x))])/x)dx  ⟶  -Subst[∫((a+b ArcCos[(x/c)])/x)dx,x,(1/x)]

Program code:

Int[(a_.+b_.*ArcSec[c_.*x_])/x_,x_Symbol] :=
  -Subst[Int[(a+b*ArcCos[x/c])/x,x],x,1/x] /;
FreeQ[{a,b,c},x]

Int[(a_.+b_.*ArcCsc[c_.*x_])/x_,x_Symbol] :=
  -Subst[Int[(a+b*ArcSin[x/c])/x,x],x,1/x] /;
FreeQ[{a,b,c},x]

2:  ∫(((d x))^m)(a+b ArcSec[c x])dx  when  m≠-1

Reference: CRC 474

Reference: CRC 477

Derivation: Integration by parts

Rule: If  m≠-1, then

∫(((d x))^m) (a+b ArcSec[c x])dx  ⟶  (((((d x))^(m+1)) (a+b ArcSec[c x]))/(d (m+1)))-((b d)/(c(m+1)))∫((((d x))^(m-1))/(Sqrt[1-(1/((c^2) (x^2)))]))dx

Program code:

Int[(d_.*x_)^m_.*(a_.+b_.*ArcSec[c_.*x_]),x_Symbol] :=
  (d*x)^(m+1)*(a+b*ArcSec[c*x])/(d*(m+1)) - 
  b*d/(c*(m+1))*Int[(d*x)^(m-1)/Sqrt[1-1/(c^2*x^2)],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1]

Int[(d_.*x_)^m_.*(a_.+b_.*ArcCsc[c_.*x_]),x_Symbol] :=
  (d*x)^(m+1)*(a+b*ArcCsc[c*x])/(d*(m+1)) + 
  b*d/(c*(m+1))*Int[(d*x)^(m-1)/Sqrt[1-1/(c^2*x^2)],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1]

2:  ∫(x^m) (((a+b ArcSec[c x]))^n)dx  when  n∈ℤ∧ m∈ℤ ∧ (n>0 ∨ m<-1)

Derivation: Integration by substitution

Basis: If  m∈ℤ, then (x^m) F[ArcSec[c x]]==(1/(c^(m+1)))Subst[F[x] ((Sec[x])^(m+1))Tan[x],x,ArcSec[c x]] (∂_x)ArcSec[c x]

Rule: If  n∈ℤ∧ m∈ℤ ∧ (n>0 ∨ m<-1), then

∫(x^m) (((a+b ArcSec[c x]))^n)dx  ⟶  (1/(c^(m+1))) Subst[∫(((a+b x))^n)((Sec[x])^(m+1)) Tan[x]dx,x,ArcSec[c x]]

Program code:

Int[x_^m_.*(a_.+b_.*ArcSec[c_.*x_])^n_,x_Symbol] :=
  1/c^(m+1)*Subst[Int[(a+b*x)^n*Sec[x]^(m+1)*Tan[x],x],x,ArcSec[c*x]] /;
FreeQ[{a,b,c},x] && IntegerQ[n] && IntegerQ[m] && (GtQ[n,0] || LtQ[m,-1])

Int[x_^m_.*(a_.+b_.*ArcCsc[c_.*x_])^n_,x_Symbol] :=
  -1/c^(m+1)*Subst[Int[(a+b*x)^n*Csc[x]^(m+1)*Cot[x],x],x,ArcCsc[c*x]] /;
FreeQ[{a,b,c},x] && IntegerQ[n] && IntegerQ[m] && (GtQ[n,0] || LtQ[m,-1])

3.  ∫(((d+e x))^m) (a+b ArcSec[c x])dx

1:  ∫((a+b ArcSec[c x])/(d+e x))dx

Derivation: Integration by parts

Basis: (1/(d+e x))==(1/e) (∂_x)(Log[1+(((e-(Sqrt[-(c^2) (d^2)+(e^2)])) (e^(i ArcSec[c x])))/(c d))]+Log[1+(((e+(Sqrt[-(c^2) (d^2)+(e^2)])) (e^(i ArcSec[c x])))/(c d))]-Log[1+(e^(2 i ArcSec[c x]))])

Basis: (1/(d+e x))==(1/e) (∂_x)(Log[1-((i (e-(Sqrt[-(c^2) (d^2)+(e^2)])) (e^(i ArcCsc[c x])))/(c d))]+Log[1-((i (e+(Sqrt[-(c^2) (d^2)+(e^2)])) (e^(i ArcCsc[c x])))/(c d))]-Log[1-(e^(2 i ArcCsc[c x]))])

Rule:

∫((a+b ArcSec[c x])/(d+e x))dx  ⟶  
(((a+b ArcSec[c x]) Log[1+(((e-(Sqrt[-(c^2) (d^2)+(e^2)])) (e^(i ArcSec[c x])))/(c d))])/e)+(((a+b ArcSec[c x]) Log[1+(((e+(Sqrt[-(c^2) (d^2)+(e^2)])) (e^(i ArcSec[c x])))/(c d))])/e)-
(((a+b ArcSec[c x]) Log[1+(e^(2 i ArcSec[c x]))])/e)-(b/(c e)) ∫((Log[1+(((e-(Sqrt[-(c^2) (d^2)+(e^2)])) (e^(i ArcSec[c x])))/(c d))])/((x^2) (Sqrt[1-(1/((c^2) (x^2)))])))dx-
(b/(c e)) ∫((Log[1+(((e+(Sqrt[-(c^2) (d^2)+(e^2)])) (e^(i ArcSec[c x])))/(c d))])/((x^2) (Sqrt[1-(1/((c^2) (x^2)))])))dx+(b/(c e)) ∫((Log[1+(e^(2 i ArcSec[c x]))])/((x^2) (Sqrt[1-(1/((c^2) (x^2)))])))dx

Program code:

Int[(a_.+b_.*ArcSec[c_.*x_])/(d_.+e_.*x_),x_Symbol] :=
  (a+b*ArcSec[c*x])*Log[1+(e-Sqrt[-c^2*d^2+e^2])*E^(I*ArcSec[c*x])/(c*d)]/e + 
  (a+b*ArcSec[c*x])*Log[1+(e+Sqrt[-c^2*d^2+e^2])*E^(I*ArcSec[c*x])/(c*d)]/e - 
  (a+b*ArcSec[c*x])*Log[1+E^(2*I*ArcSec[c*x])]/e - 
  b/(c*e)*Int[Log[1+(e-Sqrt[-c^2*d^2+e^2])*E^(I*ArcSec[c*x])/(c*d)]/(x^2*Sqrt[1-1/(c^2*x^2)]),x] - 
  b/(c*e)*Int[Log[1+(e+Sqrt[-c^2*d^2+e^2])*E^(I*ArcSec[c*x])/(c*d)]/(x^2*Sqrt[1-1/(c^2*x^2)]),x] + 
  b/(c*e)*Int[Log[1+E^(2*I*ArcSec[c*x])]/(x^2*Sqrt[1-1/(c^2*x^2)]),x] /;
FreeQ[{a,b,c,d,e},x]

Int[(a_.+b_.*ArcCsc[c_.*x_])/(d_.+e_.*x_),x_Symbol] :=
  (a+b*ArcCsc[c*x])*Log[1-I*(e-Sqrt[-c^2*d^2+e^2])*E^(I*ArcCsc[c*x])/(c*d)]/e + 
  (a+b*ArcCsc[c*x])*Log[1-I*(e+Sqrt[-c^2*d^2+e^2])*E^(I*ArcCsc[c*x])/(c*d)]/e - 
  (a+b*ArcCsc[c*x])*Log[1-E^(2*I*ArcCsc[c*x])]/e + 
  b/(c*e)*Int[Log[1-I*(e-Sqrt[-c^2*d^2+e^2])*E^(I*ArcCsc[c*x])/(c*d)]/(x^2*Sqrt[1-1/(c^2*x^2)]),x] + 
  b/(c*e)*Int[Log[1-I*(e+Sqrt[-c^2*d^2+e^2])*E^(I*ArcCsc[c*x])/(c*d)]/(x^2*Sqrt[1-1/(c^2*x^2)]),x] - 
  b/(c*e)*Int[Log[1-E^(2*I*ArcCsc[c*x])]/(x^2*Sqrt[1-1/(c^2*x^2)]),x] /;
FreeQ[{a,b,c,d,e},x]

2:  ∫(((d+e x))^m)(a+b ArcSec[c x])dx  when  m≠-1

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcSec[c x])==(b/(c (x^2) (Sqrt[1-(1/((c^2) (x^2)))])))

Rule: If  m≠-1, then

∫(((d+e x))^m)(a+b ArcSec[c x])dx  ⟶  (((((d+e x))^(m+1)) (a+b ArcSec[c x]))/(e(m+1)))-(b/(c e(m+1)))∫((((d+e x))^(m+1))/((x^2) (Sqrt[1-(1/((c^2) (x^2)))])))dx

Program code:

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcSec[c_.*x_]),x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*ArcSec[c*x])/(e*(m+1)) - 
  b/(c*e*(m+1))*Int[(d+e*x)^(m+1)/(x^2*Sqrt[1-1/(c^2*x^2)]),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[m,-1]

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcCsc[c_.*x_]),x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*ArcCsc[c*x])/(e*(m+1)) + 
  b/(c*e*(m+1))*Int[(d+e*x)^(m+1)/(x^2*Sqrt[1-1/(c^2*x^2)]),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[m,-1]

4.  ∫(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫(((d+e (x^2)))^p) (a+b ArcSec[c x])dx  when  p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ])

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcSec[c x])==((b c)/((Sqrt[(c^2) (x^2)]) (Sqrt[(c^2) (x^2)-1])))

Basis: (∂_x)(x/(Sqrt[(c^2) (x^2)]))==0

Note: If p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ]), then ∫(((d+e (x^2)))^p)dx is expressible as an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If  p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ]), let u=∫(((d+e (x^2)))^p)dx, then

∫(((d+e (x^2)))^p) (a+b ArcSec[c x])dx  ⟶  u (a+b ArcSec[c x])-b c∫(u/((Sqrt[(c^2) (x^2)]) (Sqrt[(c^2) (x^2)-1])))dx  ⟶  u (a+b ArcSec[u])-((b c x)/(Sqrt[(c^2) (x^2)]))∫(u/(x(Sqrt[(c^2) (x^2)-1])))dx

Program code:

Int[(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcSec[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^p,x]},  
  Dist[(a+b*ArcSec[c*x]),u,x] - b*c*x/Sqrt[c^2*x^2]*Int[SimplifyIntegrand[u/(x*Sqrt[c^2*x^2-1]),x],x]] /;
FreeQ[{a,b,c,d,e},x] && (IGtQ[p,0] || ILtQ[p+1/2,0])

Int[(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcCsc[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^p,x]},  
  Dist[(a+b*ArcCsc[c*x]),u,x] + b*c*x/Sqrt[c^2*x^2]*Int[SimplifyIntegrand[u/(x*Sqrt[c^2*x^2-1]),x],x]] /;
FreeQ[{a,b,c,d,e},x] && (IGtQ[p,0] || ILtQ[p+1/2,0])

2:  ∫(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ p∈ℤ

Derivation: Integration by substitution

Basis: ArcSec[z]==ArcCos[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  n∈(SuperPlus[ℤ])∧ p∈ℤ, then

∫(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  ⟶  ∫((((1/x)))^(-2p))(((e+(d/(x^2))))^p) (((a+b ArcCos[(1/(c x))]))^n)dx
  ⟶  -Subst[∫(((((e+d (x^2)))^p) (((a+b ArcCos[(x/c)]))^n))/(x^(2(p+1))))dx,x,(1/x)]

Program code:

Int[(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcSec[c_.*x_])^n_.,x_Symbol] :=
  -Subst[Int[(e+d*x^2)^p*(a+b*ArcCos[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && IntegerQ[p]

Int[(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcCsc[c_.*x_])^n_.,x_Symbol] :=
  -Subst[Int[(e+d*x^2)^p*(a+b*ArcSin[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && IntegerQ[p]

3.  ∫(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p+(1/2)∈ℤ

1:  ∫(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p+(1/2)∈ℤ ∧ e>0 ∧ d<0

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[d+e (x^2)])/(x (Sqrt[e+(d/(x^2))])))==0

Basis: ArcSec[z]==ArcCos[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Basis: If  e>0 ∧ d<0, then ((Sqrt[d+e (x^2)])/(Sqrt[e+(d/(x^2))]))==(Sqrt[(x^2)])

Rule: If  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p+(1/2)∈ℤ ∧ e>0 ∧ d<0, then

∫(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  ⟶  ((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))∫((((1/x)))^(-2p))(((e+(d/(x^2))))^p) (((a+b ArcCos[(1/(c x))]))^n)dx
  ⟶  -((Sqrt[(x^2)])/x)Subst[∫(((((e+d (x^2)))^p) (((a+b ArcCos[(x/c)]))^n))/(x^(2(p+1))))dx,x,(1/x)]

Program code:

Int[(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcSec[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[x^2]/x*Subst[Int[(e+d*x^2)^p*(a+b*ArcCos[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[p+1/2] && GtQ[e,0] && LtQ[d,0]

Int[(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcCsc[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[x^2]/x*Subst[Int[(e+d*x^2)^p*(a+b*ArcSin[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[p+1/2] && GtQ[e,0] && LtQ[d,0]

2:  ∫(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p+(1/2)∈ℤ ∧ ¬(e>0 ∧ d<0)

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[d+e (x^2)])/(x (Sqrt[e+(d/(x^2))])))==0

Basis: ArcSec[z]==ArcCos[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p+(1/2)∈ℤ ∧ ¬(e>0 ∧ d<0), then

∫(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  ⟶  ((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))∫((((1/x)))^(-2p))(((e+(d/(x^2))))^p) (((a+b ArcCos[(1/(c x))]))^n)dx
  ⟶  -((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))Subst[∫(((((e+d (x^2)))^p) (((a+b ArcCos[(x/c)]))^n))/(x^(2(p+1))))dx,x,(1/x)]

Program code:

Int[(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcSec[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[d+e*x^2]/(x*Sqrt[e+d/x^2])*Subst[Int[(e+d*x^2)^p*(a+b*ArcCos[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[p+1/2] && Not[GtQ[e,0] && LtQ[d,0]]

Int[(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcCsc[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[d+e*x^2]/(x*Sqrt[e+d/x^2])*Subst[Int[(e+d*x^2)^p*(a+b*ArcSin[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[p+1/2] && Not[GtQ[e,0] && LtQ[d,0]]

5.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSec[c x])dx  when  
			(p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ]))

1:  ∫x(((d+e (x^2)))^p) (a+b ArcSec[c x])dx  when  p≠-1

Derivation: Integration by parts and piecewise constant extraction

Basis: x(((d+e (x^2)))^p)==(∂_x)((((d+e (x^2)))^(p+1))/(2 e (p+1)))

Basis: (∂_x)(a+b ArcSec[c x])==((b c)/((Sqrt[(c^2) (x^2)]) (Sqrt[(c^2) (x^2)-1])))

Basis: (∂_x)(x/(Sqrt[(c^2) (x^2)]))==0

Rule: If  p≠-1, then

∫x(((d+e (x^2)))^p) (a+b ArcSec[c x])dx  ⟶  (((((d+e (x^2)))^(p+1))(a+b ArcSec[c x]))/(2 e (p+1)))-((b c)/(2 e (p+1)))∫((((d+e (x^2)))^(p+1))/((Sqrt[(c^2) (x^2)]) (Sqrt[(c^2) (x^2)-1])))dx
  ⟶  (((((d+e (x^2)))^(p+1))(a+b ArcSec[c x]))/(2 e (p+1)))-((b c x)/(2 e (p+1)(Sqrt[(c^2) (x^2)])))∫((((d+e (x^2)))^(p+1))/(x(Sqrt[(c^2) (x^2)-1])))dx

Program code:

Int[x_*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcSec[c_.*x_]),x_Symbol] :=
  (d+e*x^2)^(p+1)*(a+b*ArcSec[c*x])/(2*e*(p+1)) - 
  b*c*x/(2*e*(p+1)*Sqrt[c^2*x^2])*Int[(d+e*x^2)^(p+1)/(x*Sqrt[c^2*x^2-1]),x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[p,-1]

Int[x_*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcCsc[c_.*x_]),x_Symbol] :=
  (d+e*x^2)^(p+1)*(a+b*ArcCsc[c*x])/(2*e*(p+1)) + 
  b*c*x/(2*e*(p+1)*Sqrt[c^2*x^2])*Int[(d+e*x^2)^(p+1)/(x*Sqrt[c^2*x^2-1]),x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[p,-1]

2:  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSec[c x])dx  when  
				(p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ]))

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcSec[c x])==((b c)/((Sqrt[(c^2) (x^2)]) (Sqrt[(c^2) (x^2)-1])))

Basis: (∂_x)(x/(Sqrt[(c^2) (x^2)]))==0

Note: If (p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ])),
	then ∫(((f x))^m)(((d+e (x^2)))^p)dx is expressible as an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If  (p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ])), 
		let u=∫(((f x))^m)(((d+e (x^2)))^p)dx, then

∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSec[c x])dx  ⟶  u (a+b ArcSec[c x])-b c∫(u/((Sqrt[(c^2) (x^2)]) (Sqrt[(c^2) (x^2)-1])))dx
  ⟶  u (a+b ArcSec[u])-((b c x)/(Sqrt[(c^2) (x^2)]))∫(u/(x(Sqrt[(c^2) (x^2)-1])))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcSec[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^p,x]},  
  Dist[(a+b*ArcSec[c*x]),u,x] - b*c*x/Sqrt[c^2*x^2]*Int[SimplifyIntegrand[u/(x*Sqrt[c^2*x^2-1]),x],x]] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && (
  IGtQ[p,0] && Not[ILtQ[(m-1)/2,0] && GtQ[m+2*p+3,0]] || 
  IGtQ[(m+1)/2,0] && Not[ILtQ[p,0] && GtQ[m+2*p+3,0]] || 
  ILtQ[(m+2*p+1)/2,0] && Not[ILtQ[(m-1)/2,0]])

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcCsc[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^p,x]},  
  Dist[(a+b*ArcCsc[c*x]),u,x] + b*c*x/Sqrt[c^2*x^2]*Int[SimplifyIntegrand[u/(x*Sqrt[c^2*x^2-1]),x],x]] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && (
  IGtQ[p,0] && Not[ILtQ[(m-1)/2,0] && GtQ[m+2*p+3,0]] || 
  IGtQ[(m+1)/2,0] && Not[ILtQ[p,0] && GtQ[m+2*p+3,0]] || 
  ILtQ[(m+2*p+1)/2,0] && Not[ILtQ[(m-1)/2,0]])

2:  ∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ m∈ℤ ∧ p∈ℤ

Derivation: Integration by substitution

Basis: ArcSec[z]==ArcCos[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  n∈(SuperPlus[ℤ])∧ m∈ℤ ∧ p∈ℤ, then

∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  ⟶  ∫((((1/x)))^(-m-2p))(((e+(d/(x^2))))^p) (((a+b ArcCos[(1/(c x))]))^n)dx
  ⟶  -Subst[∫(((((e+d (x^2)))^p)(((a+b ArcCos[(x/c)]))^n))/(x^(m+2 (p+1))))dx,x,(1/x)]

Program code:

Int[x_^m_.*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcSec[c_.*x_])^n_.,x_Symbol] :=
  -Subst[Int[(e+d*x^2)^p*(a+b*ArcCos[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && IntegerQ[m] && IntegerQ[p]

Int[x_^m_.*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcCsc[c_.*x_])^n_.,x_Symbol] :=
  -Subst[Int[(e+d*x^2)^p*(a+b*ArcSin[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && IntegerQ[m] && IntegerQ[p]

3.  ∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ

1:  ∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ ∧ e>0 ∧ d<0

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[d+e (x^2)])/(x (Sqrt[e+(d/(x^2))])))==0

Basis: ArcSec[z]==ArcCos[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Basis: If  e>0 ∧ d<0, then ((Sqrt[d+e (x^2)])/(Sqrt[e+(d/(x^2))]))==(Sqrt[(x^2)])

Rule: If  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ ∧ e>0 ∧ d<0, then

∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  ⟶  ((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))∫((((1/x)))^(-m-2p))(((e+(d/(x^2))))^p) (((a+b ArcCos[(1/(c x))]))^n)dx
  ⟶  -((Sqrt[(x^2)])/x)Subst[∫(((((e+d (x^2)))^p)(((a+b ArcCos[(x/c)]))^n))/(x^(m+2 (p+1))))dx,x,(1/x)]

Program code:

Int[x_^m_.*(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcSec[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[x^2]/x*Subst[Int[(e+d*x^2)^p*(a+b*ArcCos[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[m] && IntegerQ[p+1/2] && GtQ[e,0] && LtQ[d,0]

Int[x_^m_.*(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcCsc[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[x^2]/x*Subst[Int[(e+d*x^2)^p*(a+b*ArcSin[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[m] && IntegerQ[p+1/2] && GtQ[e,0] && LtQ[d,0]

2:  ∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ ∧ ¬(e>0 ∧ d<0)

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[d+e (x^2)])/(x (Sqrt[e+(d/(x^2))])))==0

Basis: ArcSec[z]==ArcCos[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ ∧ ¬(e>0 ∧ d<0), then

∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSec[c x]))^n)dx  ⟶  ((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))∫((((1/x)))^(-m-2p))(((e+(d/(x^2))))^p) (((a+b ArcCos[(1/(c x))]))^n)dx
  ⟶  -((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))Subst[∫(((((e+d (x^2)))^p)(((a+b ArcCos[(x/c)]))^n))/(x^(m+2 (p+1))))dx,x,(1/x)]

Program code:

Int[x_^m_.*(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcSec[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[d+e*x^2]/(x*Sqrt[e+d/x^2])*Subst[Int[(e+d*x^2)^p*(a+b*ArcCos[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[m] && IntegerQ[p+1/2] && Not[GtQ[e,0] && LtQ[d,0]]

Int[x_^m_.*(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcCsc[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[d+e*x^2]/(x*Sqrt[e+d/x^2])*Subst[Int[(e+d*x^2)^p*(a+b*ArcSin[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[m] && IntegerQ[p+1/2] && Not[GtQ[e,0] && LtQ[d,0]]

6:  ∫u (a+b ArcSec[c x])dx  when  ∫udx  is free of inverse functions

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcSec[c x])==(b/(c (x^2) (Sqrt[1-(1/((c^2) (x^2)))])))

Rule: Let v->∫ udx, if v is free of inverse functions, then

∫u (a+b ArcSec[c x])dx  ⟶  v (a+b ArcSec[c x])-(b/c) ∫(v/((x^2) (Sqrt[1-(1/((c^2) (x^2)))])))dx

Program code:

Int[u_*(a_.+b_.*ArcSec[c_.*x_]),x_Symbol] :=
  With[{v=IntHide[u,x]},  
  Dist[(a+b*ArcSec[c*x]),v,x] - 
  b/c*Int[SimplifyIntegrand[v/(x^2*Sqrt[1-1/(c^2*x^2)]),x],x] /;
 InverseFunctionFreeQ[v,x]] /;
FreeQ[{a,b,c},x]

Int[u_*(a_.+b_.*ArcCsc[c_.*x_]),x_Symbol] :=
  With[{v=IntHide[u,x]},  
  Dist[(a+b*ArcCsc[c*x]),v,x] + 
  b/c*Int[SimplifyIntegrand[v/(x^2*Sqrt[1-1/(c^2*x^2)]),x],x] /;
 InverseFunctionFreeQ[v,x]] /;
FreeQ[{a,b,c},x]

X:  ∫u (((a+b ArcSec[c x]))^n)dx

Rule:

∫u(((a+b ArcSec[c x]))^n)dx  ⟶  ∫u(((a+b ArcSec[c x]))^n)dx

Program code:

Int[u_.*(a_.+b_.*ArcSec[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcSec[c*x])^n,x] /;
FreeQ[{a,b,c,n},x]

Int[u_.*(a_.+b_.*ArcCsc[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcCsc[c*x])^n,x] /;
FreeQ[{a,b,c,n},x]