Rules for integrands of the form  u (((a+b ArcSech[c+d x]))^p)

1.  ∫(((a+b ArcSec[c+d x]))^p)dx

1:  ∫ArcSec[c+d x]dx

Reference: G&R 2.821.2, CRC 445, A&S 4.4.62

Reference: G&R 2.821.1, CRC 446, A&S 4.4.61

Derivation: Integration by parts

Rule:

∫ArcSec[c+d x]dx  ⟶  (((c+d x) ArcSec[c+d x])/d)-∫(1/((c+d x) (Sqrt[1-(1/(((c+d x))^2))])))dx

Program code:

Int[ArcSec[c_+d_.*x_],x_Symbol] :=
  (c+d*x)*ArcSec[c+d*x]/d - 
  Int[1/((c+d*x)*Sqrt[1-1/(c+d*x)^2]),x] /;
FreeQ[{c,d},x]

Int[ArcCsc[c_+d_.*x_],x_Symbol] :=
  (c+d*x)*ArcCsc[c+d*x]/d + 
  Int[1/((c+d*x)*Sqrt[1-1/(c+d*x)^2]),x] /;
FreeQ[{c,d},x]

2:  ∫(((a+b ArcSec[c+d x]))^p)dx  when  p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Rule: If  p∈(SuperPlus[ℤ]), then

∫(((a+b ArcSec[c+d x]))^p)dx  ⟶  (1/d) Subst[∫(((a+b ArcSec[x]))^p)dx,x,c+d x]

Program code:

Int[(a_.+b_.*ArcSec[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[(a+b*ArcSec[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d},x] && IGtQ[p,0]

Int[(a_.+b_.*ArcCsc[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[(a+b*ArcCsc[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d},x] && IGtQ[p,0]

U:  ∫(((a+b ArcSec[c+d x]))^p)dx  when  p∉(SuperPlus[ℤ])

Rule: If  p∉(SuperPlus[ℤ]), then

∫(((a+b ArcSec[c+d x]))^p)dx  ⟶  ∫(((a+b ArcSec[c+d x]))^p)dx

Program code:

Int[(a_.+b_.*ArcSec[c_+d_.*x_])^p_,x_Symbol] :=
  Unintegrable[(a+b*ArcSec[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,p},x] && Not[IGtQ[p,0]]

Int[(a_.+b_.*ArcCsc[c_+d_.*x_])^p_,x_Symbol] :=
  Unintegrable[(a+b*ArcCsc[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,p},x] && Not[IGtQ[p,0]]

2.  ∫(((e+f x))^m) (((a+b ArcSec[c+d x]))^p)dx

1:  ∫(((e+f x))^m) (((a+b ArcSec[c+d x]))^p)dx  when  d e-c f==0 ∧ p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Rule: If  d e-c f==0 ∧ p∈(SuperPlus[ℤ]), then

∫(((e+f x))^m) (((a+b ArcSec[c+d x]))^p)dx  ⟶  (1/d) Subst[∫(((((f x)/d)))^m) (((a+b ArcSec[x]))^p)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcSec[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[(f*x/d)^m*(a+b*ArcSec[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[d*e-c*f,0] && IGtQ[p,0]

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcCsc[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[(f*x/d)^m*(a+b*ArcCsc[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[d*e-c*f,0] && IGtQ[p,0]

2:  ∫(((e+f x))^m) (((a+b ArcSec[c+d x]))^p)dx  when  p∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Integration by substitution

Basis: If  m∈ℤ, then (((e+f x))^m) F[ArcSec[c+d x]]==(1/(d^(m+1))) Subst[F[x] Sec[x] Tan[x] (((d e-c f+f Sec[x]))^m),x,ArcSec[c+d x]] (∂_x)ArcSec[c+d x]

Rule: If  p∈(SuperPlus[ℤ])∧ m∈ℤ, then

∫(((e+f x))^m) (((a+b ArcSec[c+d x]))^p)dx  ⟶  (1/(d^(m+1))) Subst[∫(((a+b x))^p) Sec[x]Tan[x] (((d e-c f+f Sec[x]))^m)dx,x,ArcSec[c+d x]]

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcSec[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d^(m+1)*Subst[Int[(a+b*x)^p*Sec[x]*Tan[x]*(d*e-c*f+f*Sec[x])^m,x],x,ArcSec[c+d*x]] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && IntegerQ[m]

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcCsc[c_+d_.*x_])^p_.,x_Symbol] :=
  -1/d^(m+1)*Subst[Int[(a+b*x)^p*Csc[x]*Cot[x]*(d*e-c*f+f*Csc[x])^m,x],x,ArcCsc[c+d*x]] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && IntegerQ[m]

3:  ∫(((e+f x))^m)(((a+b ArcSec[c+d x]))^p)dx  when  p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Rule: If  p∈(SuperPlus[ℤ]), then

∫(((e+f x))^m)(((a+b ArcSec[c+d x]))^p)dx  ⟶  (1/d)Subst[∫(((((d e-c f)/d)+((f x)/d)))^m)(((a+b ArcSec[x]))^p)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcSec[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(a+b*ArcSec[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[p,0]

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcCsc[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(a+b*ArcCsc[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[p,0]

U:  ∫(((e+f x))^m)(((a+b ArcSec[c+d x]))^p)dx  when  p∉(SuperPlus[ℤ])

Rule: If  p∉(SuperPlus[ℤ]), then

∫(((e+f x))^m)(((a+b ArcSec[c+d x]))^p)dx  ⟶  ∫(((e+f x))^m)(((a+b ArcSec[c+d x]))^p)dx

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcSec[c_+d_.*x_])^p_,x_Symbol] :=
  Unintegrable[(e+f*x)^m*(a+b*ArcSec[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && Not[IGtQ[p,0]]

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcCsc[c_+d_.*x_])^p_,x_Symbol] :=
  Unintegrable[(e+f*x)^m*(a+b*ArcCsc[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && Not[IGtQ[p,0]]

Rules for integrands involving inverse secants and cosecants

1:  ∫u ((ArcSec[(c/(a+b (x^n)))])^m)dx

Derivation:  Algebraic simplification

Basis: ArcSec[z]==ArcCos[(1/z)]

Rule:

∫u ((ArcSec[(c/(a+b (x^n)))])^m)dx  ⟶  ∫u ((ArcCos[(a/c)+((b (x^n))/c)])^m)dx

Program code:

Int[u_.*ArcSec[c_./(a_.+b_.*x_^n_.)]^m_.,x_Symbol] :=
  Int[u*ArcCos[a/c+b*x^n/c]^m,x] /;
FreeQ[{a,b,c,n,m},x]

Int[u_.*ArcCsc[c_./(a_.+b_.*x_^n_.)]^m_.,x_Symbol] :=
  Int[u*ArcSin[a/c+b*x^n/c]^m,x] /;
FreeQ[{a,b,c,n,m},x]

2:  ∫u (f^(c ((ArcSec[a+b x])^n)))dx

Derivation: Integration by substitution

Basis: F[x,ArcSec[a+b x]]==(1/b)Subst[F[-(a/b)+((Sec[x])/b),x] Sec[x] Tan[x],x,ArcSec[a+b x]] (∂_x)ArcSec[a+b x]

Rule: If  n∈(SuperPlus[ℤ]), then

∫u (f^(c ((ArcSec[a+b x])^n)))dx  ⟶  (1/b)Subst[∫Subst[u,x,-(a/b)+((Sec[x])/b)] (f^(c (x^n)))Sec[x]Tan[x]dx,x,ArcSec[a+b x]]

Program code:

Int[u_.*f_^(c_.*ArcSec[a_.+b_.*x_]^n_.),x_Symbol] :=
  1/b*Subst[Int[ReplaceAll[u,x->-a/b+Sec[x]/b]*f^(c*x^n)*Sec[x]*Tan[x],x],x,ArcSec[a+b*x]] /;
FreeQ[{a,b,c,f},x] && IGtQ[n,0]

Int[u_.*f_^(c_.*ArcCsc[a_.+b_.*x_]^n_.),x_Symbol] :=
  -1/b*Subst[Int[ReplaceAll[u,x->-a/b+Csc[x]/b]*f^(c*x^n)*Csc[x]*Cot[x],x],x,ArcCsc[a+b*x]] /;
FreeQ[{a,b,c,f},x] && IGtQ[n,0]

3.  ∫v (a+b ArcSec[u])dx  when  u is free of inverse functions

1:  ∫ArcSec[u]dx  whenu is free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)ArcSec[F[x]]==(((∂_x)F[x])/((Sqrt[((F[x])^2)])(Sqrt[((F[x])^2)-1])))

Basis: (∂_x)((F[x])/(Sqrt[((F[x])^2)]))==0

Rule: If u is free of inverse functions, then

∫ArcSec[u]dx  ⟶  x ArcSec[u]-∫((x (∂_x)u)/((Sqrt[(u^2)])(Sqrt[(u^2)-1])))dx  ⟶  x ArcSec[u]-(u/(Sqrt[(u^2)]))∫((x (∂_x)u)/(u(Sqrt[(u^2)-1])))dx

Program code:

Int[ArcSec[u_],x_Symbol] :=
  x*ArcSec[u] -
  u/Sqrt[u^2]*Int[SimplifyIntegrand[x*D[u,x]/(u*Sqrt[u^2-1]),x],x] /;
InverseFunctionFreeQ[u,x] && Not[FunctionOfExponentialQ[u,x]]

Int[ArcCsc[u_],x_Symbol] :=
  x*ArcCsc[u] +
  u/Sqrt[u^2]*Int[SimplifyIntegrand[x*D[u,x]/(u*Sqrt[u^2-1]),x],x] /;
InverseFunctionFreeQ[u,x] && Not[FunctionOfExponentialQ[u,x]]

2:  ∫(((c+d x))^m)(a+b ArcSec[u])dx  when  m≠-1 ∧ u is free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcSec[F[x]])==((b (∂_x)F[x])/((Sqrt[((F[x])^2)])(Sqrt[((F[x])^2)-1])))

Basis: (∂_x)((F[x])/(Sqrt[((F[x])^2)]))==0

Rule: If  m≠-1 ∧ u is free of inverse functions, then

∫(((c+d x))^m)(a+b ArcSec[u])dx  ⟶  (((((c+d x))^(m+1)) (a+b ArcSec[u]))/(d(m+1)))-(b/(d(m+1)))∫(((((c+d x))^(m+1)) (∂_x)u)/((Sqrt[(u^2)])(Sqrt[(u^2)-1])))dx
  ⟶  (((((c+d x))^(m+1)) (a+b ArcSec[u]))/(d(m+1)))-((b u)/(d(m+1)(Sqrt[(u^2)])))∫(((((c+d x))^(m+1)) (∂_x)u)/(u(Sqrt[(u^2)-1])))dx

Program code:

Int[(c_.+d_.*x_)^m_.*(a_.+b_.*ArcSec[u_]),x_Symbol] :=
  (c+d*x)^(m+1)*(a+b*ArcSec[u])/(d*(m+1)) -
  b*u/(d*(m+1)*Sqrt[u^2])*Int[SimplifyIntegrand[(c+d*x)^(m+1)*D[u,x]/(u*Sqrt[u^2-1]),x],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1] && InverseFunctionFreeQ[u,x] && Not[FunctionOfQ[(c+d*x)^(m+1),u,x]] && Not[FunctionOfExponentialQ[u,x]]

Int[(c_.+d_.*x_)^m_.*(a_.+b_.*ArcCsc[u_]),x_Symbol] :=
  (c+d*x)^(m+1)*(a+b*ArcCsc[u])/(d*(m+1)) +
  b*u/(d*(m+1)*Sqrt[u^2])*Int[SimplifyIntegrand[(c+d*x)^(m+1)*D[u,x]/(u*Sqrt[u^2-1]),x],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1] && InverseFunctionFreeQ[u,x] && Not[FunctionOfQ[(c+d*x)^(m+1),u,x]] && Not[FunctionOfExponentialQ[u,x]]

3:  ∫v (a+b ArcSec[u])dx  when  u and ∫vdx  are free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcSec[F[x]])==((b (∂_x)F[x])/((Sqrt[((F[x])^2)])(Sqrt[((F[x])^2)-1])))

Basis: (∂_x)((F[x])/(Sqrt[((F[x])^2)]))==0

Rule: If u is free of inverse functions, let  w->∫vdx, if w is free of inverse functions, then

∫v (a+b ArcSec[u])dx  ⟶  w (a+b ArcSec[u])-b∫((w (∂_x)u)/((Sqrt[(u^2)])(Sqrt[(u^2)-1])))dx  ⟶  w (a+b ArcSec[u])-((b u)/(Sqrt[(u^2)]))∫((w (∂_x)u)/(u(Sqrt[(u^2)-1])))dx

Program code:

Int[v_*(a_.+b_.*ArcSec[u_]),x_Symbol] :=
  With[{w=IntHide[v,x]},  
  Dist[(a+b*ArcSec[u]),w,x] - b*u/Sqrt[u^2]*Int[SimplifyIntegrand[w*D[u,x]/(u*Sqrt[u^2-1]),x],x] /;
 InverseFunctionFreeQ[w,x]] /;
FreeQ[{a,b},x] && InverseFunctionFreeQ[u,x] && Not[MatchQ[v, (c_.+d_.*x)^m_. /; FreeQ[{c,d,m},x]]]

Int[v_*(a_.+b_.*ArcCsc[u_]),x_Symbol] :=
  With[{w=IntHide[v,x]},  
  Dist[(a+b*ArcCsc[u]),w,x] + b*u/Sqrt[u^2]*Int[SimplifyIntegrand[w*D[u,x]/(u*Sqrt[u^2-1]),x],x] /;
 InverseFunctionFreeQ[w,x]] /;
FreeQ[{a,b},x] && InverseFunctionFreeQ[u,x] && Not[MatchQ[v, (c_.+d_.*x)^m_. /; FreeQ[{c,d,m},x]]]