Rules for integrands of the form(((a+b (x^n)))^p) Sinh[c+d x]

1:  ∫(((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p∈(SuperPlus[ℤ]), then

∫(((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  ∫Sinh[c+d x] ExpandIntegrand[(((a+b (x^n)))^p),x]dx

Int[(a_+b_.*x_^n_)^p_.*Sinh[c_.+d_.*x_],x_Symbol] :=
  Int[ExpandIntegrand[Sinh[c+d*x],(a+b*x^n)^p,x],x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[p,0]

Int[(a_+b_.*x_^n_)^p_.*Cosh[c_.+d_.*x_],x_Symbol] :=
  Int[ExpandIntegrand[Cosh[c+d*x],(a+b*x^n)^p,x],x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[p,0]

2.  ∫(((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperMinus[ℤ])∧ n∈ℤ

1.  ∫(((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperMinus[ℤ])∧ n∈(SuperPlus[ℤ])

1:  ∫(((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperMinus[ℤ])∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ n>2

Derivation: Integration by parts

Basis: (∂_x)((((a+b (x^n)))^(p+1))/(b n (p+1)))==(x^(n-1)) (((a+b (x^n)))^p)

Basis: (∂_x)((x^(-n+1)) Sinh[c+d x])==-(n-1) (x^(-n)) Sinh[c+d x]+d (x^(-n+1)) Cosh[c+d x]

Rule: If  p∈(SuperMinus[ℤ])∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ n>2, then

∫(((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  
(((x^(-n+1)) (((a+b (x^n)))^(p+1)) Sinh[c+d x])/(b n (p+1)))-(( -n+1)/(b n (p+1)))∫(x^(-n)) (((a+b (x^n)))^(p+1)) Sinh[c+d x]dx-(d/(b n (p+1)))∫(x^(-n+1)) (((a+b (x^n)))^(p+1)) Cosh[c+d x]dx

Program code:

Int[(a_+b_.*x_^n_)^p_*Sinh[c_.+d_.*x_],x_Symbol] :=
  x^(-n+1)*(a+b*x^n)^(p+1)*Sinh[c+d*x]/(b*n*(p+1)) - 
  (-n+1)/(b*n*(p+1))*Int[x^(-n)*(a+b*x^n)^(p+1)*Sinh[c+d*x],x] - 
  d/(b*n*(p+1))*Int[x^(-n+1)*(a+b*x^n)^(p+1)*Cosh[c+d*x],x] /;
FreeQ[{a,b,c,d},x] && IntegerQ[p] && IGtQ[n,0] && LtQ[p,-1] && GtQ[n,2]

Int[(a_+b_.*x_^n_)^p_*Cosh[c_.+d_.*x_],x_Symbol] :=
  x^(-n+1)*(a+b*x^n)^(p+1)*Cosh[c+d*x]/(b*n*(p+1)) - 
  (-n+1)/(b*n*(p+1))*Int[x^(-n)*(a+b*x^n)^(p+1)*Cosh[c+d*x],x] - 
  d/(b*n*(p+1))*Int[x^(-n+1)*(a+b*x^n)^(p+1)*Sinh[c+d*x],x] /;
FreeQ[{a,b,c,d},x] && IntegerQ[p] && IGtQ[n,0] && LtQ[p,-1] && GtQ[n,2]

2:  ∫(((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperMinus[ℤ])∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p∈(SuperMinus[ℤ])∧ n∈(SuperPlus[ℤ]), then

∫(((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  ∫Sinh[c+d x] ExpandIntegrand[(((a+b (x^n)))^p),x]dx

Int[(a_+b_.*x_^n_)^p_*Sinh[c_.+d_.*x_],x_Symbol] :=
  Int[ExpandIntegrand[Sinh[c+d*x],(a+b*x^n)^p,x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[p,0] && IGtQ[n,0] && (EqQ[n,2] || EqQ[p,-1])

Int[(a_+b_.*x_^n_)^p_*Cosh[c_.+d_.*x_],x_Symbol] :=
  Int[ExpandIntegrand[Cosh[c+d*x],(a+b*x^n)^p,x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[p,0] && IGtQ[n,0] && (EqQ[n,2] || EqQ[p,-1])

2:  ∫(((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperMinus[ℤ])∧ n∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: If  p∈ℤ, then (((a+b (x^n)))^p)==(x^(n p)) (((b+a (x^(-n))))^p)

Rule: If  p∈(SuperMinus[ℤ])∧ n∈(SuperMinus[ℤ]), then

∫(((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  ∫(x^(n p)) (((b+a (x^(-n))))^p) Sinh[c+d x]dx

Int[(a_+b_.*x_^n_)^p_*Sinh[c_.+d_.*x_],x_Symbol] :=
  Int[x^(n*p)*(b+a*x^(-n))^p*Sinh[c+d*x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[p,0] && ILtQ[n,0]

Int[(a_+b_.*x_^n_)^p_*Cosh[c_.+d_.*x_],x_Symbol] :=
  Int[x^(n*p)*(b+a*x^(-n))^p*Cosh[c+d*x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[p,0] && ILtQ[n,0]

X:  ∫(((a+b (x^n)))^p) Sinh[c+d x]dx

Rule:

∫(((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  ∫(((a+b (x^n)))^p) Sinh[c+d x] dx

Program code:

Int[(a_+b_.*x_^n_)^p_*Sinh[c_.+d_.*x_],x_Symbol] :=
  Unintegrable[(a+b*x^n)^p*Sinh[c+d*x],x] /;
FreeQ[{a,b,c,d,n,p},x]

Int[(a_+b_.*x_^n_)^p_*Cosh[c_.+d_.*x_],x_Symbol] :=
  Unintegrable[(a+b*x^n)^p*Cosh[c+d*x],x] /;
FreeQ[{a,b,c,d,n,p},x]

Rules for integrands of the form(((e x))^m) (((a+b (x^n)))^p) Sinh[c+d x]

1:  ∫(((e x))^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p∈(SuperPlus[ℤ]), then

∫(((e x))^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  ∫Sinh[c+d x] ExpandIntegrand[(((e x))^m) (((a+b (x^n)))^p),x]dx

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*Sinh[c_.+d_.*x_],x_Symbol] :=
  Int[ExpandIntegrand[Sinh[c+d*x],(e*x)^m*(a+b*x^n)^p,x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IGtQ[p,0]

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*Cosh[c_.+d_.*x_],x_Symbol] :=
  Int[ExpandIntegrand[Cosh[c+d*x],(e*x)^m*(a+b*x^n)^p,x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IGtQ[p,0]

2:  ∫(((e x))^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperMinus[ℤ])∧ m==n-1 ∧ p<-1 ∧ (n∈ℤ ∨ e>0)

Derivation: Integration by parts

Basis: If  m==n-1 ∧ (n∈ℤ ∨ e>0), then (∂_x)(((e^m) (((a+b (x^n)))^(p+1)))/(b n (p+1)))==(((e x))^m) (((a+b (x^n)))^p)

Rule: If  p∈ℤ ∧ m==n-1 ∧ p<-1 ∧ (n∈ℤ ∨ e>0), then

∫(((e x))^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  (((e^m) (((a+b (x^n)))^(p+1)) Sinh[c+d x])/(b n (p+1)))-((d (e^m))/(b n (p+1)))∫(((a+b (x^n)))^(p+1)) Cosh[c+d x]dx

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*Sinh[c_.+d_.*x_],x_Symbol] :=
  e^m*(a+b*x^n)^(p+1)*Sinh[c+d*x]/(b*n*(p+1)) - 
  d*e^m/(b*n*(p+1))*Int[(a+b*x^n)^(p+1)*Cosh[c+d*x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IntegerQ[p] && EqQ[m-n+1,0] && LtQ[p,-1] && (IntegerQ[n] || GtQ[e,0])

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_*Cosh[c_.+d_.*x_],x_Symbol] :=
  e^m*(a+b*x^n)^(p+1)*Cosh[c+d*x]/(b*n*(p+1)) - 
  d*e^m/(b*n*(p+1))*Int[(a+b*x^n)^(p+1)*Sinh[c+d*x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IntegerQ[p] && EqQ[m-n+1,0] && LtQ[p,-1] && (IntegerQ[n] || GtQ[e,0])

3.  ∫(x^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperMinus[ℤ])∧ (m|n)∈ℤ

1.  ∫(x^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperMinus[ℤ])∧ n∈(SuperPlus[ℤ])

1:  ∫(x^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  when  p+1∈(SuperMinus[ℤ])∧ n∈(SuperPlus[ℤ])∧ (m-n+1>0 ∨ n>2)

Derivation: Integration by parts

Basis: (∂_x)((((a+b (x^n)))^(p+1))/(b n (p+1)))==(x^(n-1)) (((a+b (x^n)))^p)

Basis: (∂_x)((x^(m-n+1)) Sinh[c+d x])==(m-n+1) (x^(m-n)) Sinh[c+d x]+d (x^(m-n+1)) Cosh[c+d x]

Rule: If  p+1∈(SuperMinus[ℤ])∧ n∈(SuperPlus[ℤ])∧ (m-n+1>0 ∨ n>2), then

∫(x^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  
(((x^(m-n+1)) (((a+b (x^n)))^(p+1)) Sinh[c+d x])/(b n (p+1)))-(( m-n+1)/(b n (p+1)))∫(x^(m-n)) (((a+b (x^n)))^(p+1)) Sinh[c+d x]dx-(d/(b n (p+1)))∫(x^(m-n+1)) (((a+b (x^n)))^(p+1)) Cosh[c+d x]dx

Program code:

Int[x_^m_.*(a_+b_.*x_^n_)^p_*Sinh[c_.+d_.*x_],x_Symbol] :=
  x^(m-n+1)*(a+b*x^n)^(p+1)*Sinh[c+d*x]/(b*n*(p+1)) - 
  (m-n+1)/(b*n*(p+1))*Int[x^(m-n)*(a+b*x^n)^(p+1)*Sinh[c+d*x],x] - 
  d/(b*n*(p+1))*Int[x^(m-n+1)*(a+b*x^n)^(p+1)*Cosh[c+d*x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[p,-1] && IGtQ[n,0] && RationalQ[m] && (GtQ[m-n+1,0] || GtQ[n,2])

Int[x_^m_.*(a_+b_.*x_^n_)^p_*Cosh[c_.+d_.*x_],x_Symbol] :=
  x^(m-n+1)*(a+b*x^n)^(p+1)*Cosh[c+d*x]/(b*n*(p+1)) - 
  (m-n+1)/(b*n*(p+1))*Int[x^(m-n)*(a+b*x^n)^(p+1)*Cosh[c+d*x],x] - 
  d/(b*n*(p+1))*Int[x^(m-n+1)*(a+b*x^n)^(p+1)*Sinh[c+d*x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[p,-1] && IGtQ[n,0] && RationalQ[m] && (GtQ[m-n+1,0] || GtQ[n,2])

2:  ∫(x^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperMinus[ℤ])∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p∈(SuperMinus[ℤ])∧ n∈(SuperPlus[ℤ]), then

∫(x^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  ∫Sinh[c+d x] ExpandIntegrand[(x^m) (((a+b (x^n)))^p),x]dx

Int[x_^m_.*(a_+b_.*x_^n_)^p_*Sinh[c_.+d_.*x_],x_Symbol] :=
  Int[ExpandIntegrand[Sinh[c+d*x],x^m*(a+b*x^n)^p,x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[p,0] && IntegerQ[m] && IGtQ[n,0] && (EqQ[n,2] || EqQ[p,-1])

Int[x_^m_.*(a_+b_.*x_^n_)^p_*Cosh[c_.+d_.*x_],x_Symbol] :=
  Int[ExpandIntegrand[Cosh[c+d*x],x^m*(a+b*x^n)^p,x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[p,0] && IntegerQ[m] && IGtQ[n,0] && (EqQ[n,2] || EqQ[p,-1])

2:  ∫(x^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  when  p∈(SuperMinus[ℤ])∧ n∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: If  p∈ℤ, then (((a+b (x^n)))^p)==(x^(n p)) (((b+a (x^(-n))))^p)

Rule: If  p∈(SuperMinus[ℤ])∧ n∈(SuperMinus[ℤ]), then

∫(x^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  ∫(x^(m+n p)) (((b+a (x^(-n))))^p) Sinh[c+d x]dx

Int[x_^m_.*(a_+b_.*x_^n_)^p_*Sinh[c_.+d_.*x_],x_Symbol] :=
  Int[x^(m+n*p)*(b+a*x^(-n))^p*Sinh[c+d*x],x] /;
FreeQ[{a,b,c,d,m},x] && ILtQ[p,0] && ILtQ[n,0]

Int[x_^m_.*(a_+b_.*x_^n_)^p_*Cosh[c_.+d_.*x_],x_Symbol] :=
  Int[x^(m+n*p)*(b+a*x^(-n))^p*Cosh[c+d*x],x] /;
FreeQ[{a,b,c,d,m},x] && ILtQ[p,0] && ILtQ[n,0]

X:  ∫(((e x))^m) (((a+b (x^n)))^p) Sinh[c+d x]dx

Rule:

∫(((e x))^m) (((a+b (x^n)))^p) Sinh[c+d x]dx  ⟶  ∫(((e x))^m) (((a+b (x^n)))^p) Sinh[c+d x] dx

Program code:

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*Sinh[c_.+d_.*x_],x_Symbol] :=
  Unintegrable[(e*x)^m*(a+b*x^n)^p*Sinh[c+d*x],x] /;
FreeQ[{a,b,c,d,e,m,n,p},x]

Int[(e_.*x_)^m_.*(a_+b_.*x_^n_)^p_.*Cosh[c_.+d_.*x_],x_Symbol] :=
  Unintegrable[(e*x)^m*(a+b*x^n)^p*Cosh[c+d*x],x] /;
FreeQ[{a,b,c,d,e,m,n,p},x]