Rules for integrands of the form(((a+b Sinh[c+d (x^n)]))^p)

1.  ∫(((a+b Sinh[c+d (x^n)]))^p)dx  when n∈ℤ ∧ p∈ℤ

1.  ∫(((a+b Sinh[c+d (x^n)]))^p)dx  when n-1∈(SuperPlus[ℤ]) ∧ p∈(SuperPlus[ℤ])

1:  ∫Sinh[c+d (x^n)]dx  when n-1∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: Sinh[z]==((e^z)/2)-((e^(-z))/2)

Basis: Cosh[z]==((e^z)/2)+((e^(-z))/2)

Rule: If  n-1∈(SuperPlus[ℤ]), then

∫Sinh[c+d (x^n)]dx  ⟶  (1/2)∫(e^(c+d (x^n)))dx-(1/2)∫(e^(-c-d (x^n)))dx

Program code:

Int[Sinh[c_.+d_.*x_^n_],x_Symbol] :=
  1/2*Int[E^(c+d*x^n),x] - 1/2*Int[E^(-c-d*x^n),x] /;
FreeQ[{c,d},x] && IGtQ[n,1]

Int[Cosh[c_.+d_.*x_^n_],x_Symbol] :=
  1/2*Int[E^(c+d*x^n),x] + 1/2*Int[E^(-c-d*x^n),x] /;
FreeQ[{c,d},x] && IGtQ[n,1]

2:  ∫(((a+b Sinh[c+d (x^n)]))^p)dx  when n-1∈(SuperPlus[ℤ])∧ p-1∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  n-1∈(SuperPlus[ℤ])∧ p-1∈(SuperPlus[ℤ]), then

∫(((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  ∫TrigReduce[(((a+b Sinh[c+d (x^n)]))^p),x]dx

Program code:

Int[(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandTrigReduce[(a+b*Sinh[c+d*x^n])^p,x],x] /;
FreeQ[{a,b,c,d},x] && IGtQ[n,1] && IGtQ[p,1]

Int[(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandTrigReduce[(a+b*Cosh[c+d*x^n])^p,x],x] /;
FreeQ[{a,b,c,d},x] && IGtQ[n,1] && IGtQ[p,1]

2:  ∫(((a+b Sinh[c+d (x^n)]))^p)dx  when  n∈(SuperMinus[ℤ])∧ p∈ℤ

Derivation: Integration by substitution

Basis: If  n∈ℤ, then F[(x^n)]==-Subst[((F[(x^(-n))])/(x^2)),x,(1/x)] (∂_x)(1/x)

Rule: If  n∈(SuperMinus[ℤ])∧ p∈ℤ, then

∫(((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  -Subst[∫((((a+b Sinh[c+d (x^(-n))]))^p)/(x^2))dx,x,(1/x)]

Program code:

Int[(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  -Subst[Int[(a+b*Sinh[c+d*x^(-n)])^p/x^2,x],x,1/x] /;
FreeQ[{a,b,c,d},x] && ILtQ[n,0] && IntegerQ[p]

Int[(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  -Subst[Int[(a+b*Cosh[c+d*x^(-n)])^p/x^2,x],x,1/x] /;
FreeQ[{a,b,c,d},x] && ILtQ[n,0] && IntegerQ[p]

2:  ∫(((a+b Sinh[c+d (x^n)]))^p)dx  when  n∈𝔽 ∧ p∈ℤ

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then F[(x^n)]==k Subst[(x^(k-1))F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  n∈𝔽 ∧ p∈ℤ, let k=Denominator[n], then

∫(((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  k Subst[∫(x^(k-1))(((a+b Sinh[c+d (x^(k n))]))^p)dx,x,(x^(1/k))]

Program code:

Int[(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  Module[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*Sinh[c+d*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d},x] && FractionQ[n] && IntegerQ[p]

Int[(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  Module[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*Cosh[c+d*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d},x] && FractionQ[n] && IntegerQ[p]

3.  ∫(((a+b Sinh[c+d (x^n)]))^p)dx  when p∈(SuperPlus[ℤ])

1:  ∫Sinh[c+d (x^n)]dx

Derivation: Algebraic expansion

Basis: Sinh[z]==((e^z)/2)-((e^(-z))/2)

Basis: Cosh[z]==((e^z)/2)+((e^(-z))/2)

Rule:

∫Sinh[c+d (x^n)]dx  ⟶  (1/2)∫(e^(c+d (x^n)))dx-(1/2)∫(e^(-c-d (x^n)))dx

Program code:

Int[Sinh[c_.+d_.*x_^n_],x_Symbol] :=
  1/2*Int[E^(c+d*x^n),x] - 1/2*Int[E^(-c-d*x^n),x] /;
FreeQ[{c,d,n},x]

Int[Cosh[c_.+d_.*x_^n_],x_Symbol] :=
  1/2*Int[E^(c+d*x^n),x] + 1/2*Int[E^(-c-d*x^n),x] /;
FreeQ[{c,d,n},x]

2:  ∫(((a+b Sinh[c+d (x^n)]))^p)dx  when p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p∈(SuperPlus[ℤ]), then

∫(((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  ∫TrigReduce[(((a+b Sinh[c+d (x^n)]))^p),x]dx

Program code:

Int[(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandTrigReduce[(a+b*Sinh[c+d*x^n])^p,x],x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[p,0]

Int[(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandTrigReduce[(a+b*Cosh[c+d*x^n])^p,x],x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[p,0]

S:  ∫(((a+b Sinh[c+d (u^n)]))^p)dx  when  p∈ℤ ∧ u==e+f x

Derivation: Integration by substitution

Rule: If  p∈ℤ ∧ u==e+f x, then

∫(((a+b Sinh[c+d (u^n)]))^p)dx  ⟶  (1/f)Subst[∫(((a+b Sinh[c+d (x^n)]))^p)dx,x,u]

Program code:

Int[(a_.+b_.*Sinh[c_.+d_.*u_^n_])^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(a+b*Sinh[c+d*x^n])^p,x],x,u] /;
FreeQ[{a,b,c,d,n},x] && IntegerQ[p] && LinearQ[u,x] && NeQ[u,x]

Int[(a_.+b_.*Cosh[c_.+d_.*u_^n_])^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(a+b*Cosh[c+d*x^n])^p,x],x,u] /;
FreeQ[{a,b,c,d,n},x] && IntegerQ[p] && LinearQ[u,x] && NeQ[u,x]

X:  ∫(((a+b Sinh[c+d (u^n)]))^p)dx

Rule:

∫(((a+b Sinh[c+d (u^n)]))^p)dx  ⟶  ∫(((a+b Sinh[c+d (u^n)]))^p)dx

Program code:

Int[(a_.+b_.*Sinh[c_.+d_.*u_^n_])^p_,x_Symbol] :=
  Unintegrable[(a+b*Sinh[c+d*u^n])^p,x] /;
FreeQ[{a,b,c,d,n,p},x] && LinearQ[u,x]

Int[(a_.+b_.*Cosh[c_.+d_.*u_^n_])^p_,x_Symbol] :=
  Unintegrable[(a+b*Cosh[c+d*u^n])^p,x] /;
FreeQ[{a,b,c,d,n,p},x] && LinearQ[u,x]

N:  ∫(((a+b Sinh[u]))^p)dx  when  u==c+d (x^n)

Derivation: Algebraic normalization

Rule: If  u==c+d (x^n), then

∫(((a+b Sinh[u]))^p)dx  ⟶  ∫(((a+b Sinh[c+d (x^n)]))^p)dx

Program code:

Int[(a_.+b_.*Sinh[u_])^p_.,x_Symbol] :=
  Int[(a+b*Sinh[ExpandToSum[u,x]])^p,x] /;
FreeQ[{a,b,p},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

Int[(a_.+b_.*Cosh[u_])^p_.,x_Symbol] :=
  Int[(a+b*Cosh[ExpandToSum[u,x]])^p,x] /;
FreeQ[{a,b,p},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

Rules for integrands of the form(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)

1.  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when ((m+1)/n)∈ℤ

1.  ∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when ((m+1)/n)∈ℤ

1.  ∫((Sinh[c+d (x^n)])/x)dx

1:  ∫((Sinh[d (x^n)])/x)dx

Derivation: Primitive rule

Basis: SinhIntegral'[z]==((Sinh[z])/z)

Rule:

∫((Sinh[d (x^n)])/x)dx  ⟶  ((SinhIntegral[d (x^n)])/n)

Program code:

Int[Sinh[d_.*x_^n_]/x_,x_Symbol] :=
  SinhIntegral[d*x^n]/n /;
FreeQ[{d,n},x]

Int[Cosh[d_.*x_^n_]/x_,x_Symbol] :=
  CoshIntegral[d*x^n]/n /;
FreeQ[{d,n},x]

2:  ∫((Sinh[c+d (x^n)])/x)dx

Derivation: Algebraic expansion

Basis: Sinh[w+z]==Sinh[w] Cosh[z]+Cosh[w] Sinh[z]

Rule:

∫((Sinh[c+d (x^n)])/x)dx  ⟶  Sinh[c]∫((Cosh[d (x^n)])/x)dx+Cosh[c]∫((Sinh[d (x^n)])/x)dx

Program code:

Int[Sinh[c_+d_.*x_^n_]/x_,x_Symbol] :=
  Sinh[c]*Int[Cosh[d*x^n]/x,x] + Cosh[c]*Int[Sinh[d*x^n]/x,x] /;
FreeQ[{c,d,n},x]

Int[Cosh[c_+d_.*x_^n_]/x_,x_Symbol] :=
  Cosh[c]*Int[Cosh[d*x^n]/x,x] + Sinh[c]*Int[Sinh[d*x^n]/x,x] /;
FreeQ[{c,d,n},x]

2:  ∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when ((m+1)/n)∈ℤ ∧ (p==1 ∨ m==n-1 ∨ p∈ℤ ∧ ((m+1)/n)>0)

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m)F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Rule: If ((m+1)/n)∈ℤ ∧ (p==1 ∨ m==n-1 ∨ p∈ℤ ∧ ((m+1)/n)>0), then

∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((a+b Sinh[c+d x]))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a+b*Sinh[c+d*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,d,m,n,p},x] && IntegerQ[Simplify[(m+1)/n]] && (EqQ[p,1] || EqQ[m,n-1] || IntegerQ[p] && GtQ[Simplify[(m+1)/n],0])

Int[x_^m_.*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a+b*Cosh[c+d*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,d,m,n,p},x] && IntegerQ[Simplify[(m+1)/n]] && (EqQ[p,1] || EqQ[m,n-1] || IntegerQ[p] && GtQ[Simplify[(m+1)/n],0])

2:  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when ((m+1)/n)∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e x))^m)/(x^m))==0

Rule: If ((m+1)/n)∈ℤ, then

∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  (((e^(IntPart[m])) (((e x))^(FracPart[m])))/(x^(FracPart[m]))) ∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx

Program code:

Int[(e_*x_)^m_*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*Sinh[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && IntegerQ[Simplify[(m+1)/n]]

Int[(e_*x_)^m_*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*Cosh[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && IntegerQ[Simplify[(m+1)/n]]

2.  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when p∈ℤ ∧ n∈ℤ

1.  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when p∈ℤ ∧ n∈(SuperPlus[ℤ])

1.  ∫(((e x))^m)Sinh[c+d (x^n)]dx

1:  ∫(((e x))^m)Sinh[c+d (x^n)]dx  when  n∈(SuperPlus[ℤ])∧ 0<n<m+1

Reference: CRC 392, A&S 4.3.119

Reference: CRC 396, A&S 4.3.123

Derivation: Integration by parts

Basis: If  n∈ℤ, then (((e x))^m) Sinh[c+d (x^n)]==-(((e^(n-1)) (((e x))^(m-n+1)))/(d n))(∂_x)Cosh[c+d (x^n)]

Rule: If  n∈(SuperPlus[ℤ])∧ 0<n<m+1, then

∫(((e x))^m)Sinh[c+d (x^n)]dx  ⟶  (((e^(n-1)) (((e x))^(m-n+1)) Cosh[c+d (x^n)])/(d n))-(((e^n) (m-n+1))/(d n))∫(((e x))^(m-n)) Cosh[c+d (x^n)]dx

Program code:

Int[(e_.*x_)^m_.*Sinh[c_.+d_.*x_^n_],x_Symbol] :=
  e^(n-1)*(e*x)^(m-n+1)*Cosh[c+d*x^n]/(d*n) - 
  e^n*(m-n+1)/(d*n)*Int[(e*x)^(m-n)*Cosh[c+d*x^n],x] /;
FreeQ[{c,d,e},x] && IGtQ[n,0] && LtQ[0,n,m+1]

Int[(e_.*x_)^m_.*Cosh[c_.+d_.*x_^n_],x_Symbol] :=
  e^(n-1)*(e*x)^(m-n+1)*Sinh[c+d*x^n]/(d*n) - 
  e^n*(m-n+1)/(d*n)*Int[(e*x)^(m-n)*Sinh[c+d*x^n],x] /;
FreeQ[{c,d,e},x] && IGtQ[n,0] && LtQ[0,n,m+1]

2:  ∫(((e x))^m)Sinh[c+d (x^n)]dx  when  n∈(SuperPlus[ℤ])∧ m<-1

Reference: CRC 405, A&S 4.3.120

Reference: CRC 406, A&S 4.3.124

Derivation: Integration by parts

Rule: If  n∈(SuperPlus[ℤ])∧ m<-1, then

∫(((e x))^m)Sinh[c+d (x^n)]dx  ⟶  (((((e x))^(m+1)) Sinh[c+d (x^n)])/(e (m+1)))-((d n)/((e^n) (m+1)))∫(((e x))^(m+n)) Cosh[c+d (x^n)]dx

Program code:

Int[(e_.*x_)^m_*Sinh[c_.+d_.*x_^n_],x_Symbol] :=
  (e*x)^(m+1)*Sinh[c+d*x^n]/(e*(m+1)) - 
  d*n/(e^n*(m+1))*Int[(e*x)^(m+n)*Cosh[c+d*x^n],x] /;
FreeQ[{c,d,e},x] && IGtQ[n,0] && LtQ[m,-1]

Int[(e_.*x_)^m_*Cosh[c_.+d_.*x_^n_],x_Symbol] :=
  (e*x)^(m+1)*Cosh[c+d*x^n]/(e*(m+1)) - 
  d*n/(e^n*(m+1))*Int[(e*x)^(m+n)*Sinh[c+d*x^n],x] /;
FreeQ[{c,d,e},x] && IGtQ[n,0] && LtQ[m,-1]

3:  ∫(((e x))^m) Sinh[c+d (x^n)]dx  when n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: Sinh[z]==((e^z)/2)-((e^(-z))/2)

Basis: Cosh[z]==((e^z)/2)+((e^(-z))/2)

Rule: If  n∈(SuperPlus[ℤ]), then

∫(((e x))^m) Sinh[c+d (x^n)]dx  ⟶  (1/2)∫(((e x))^m) (e^(c+d (x^n)))dx-(1/2)∫(((e x))^m) (e^(-c-d (x^n)))dx

Program code:

Int[(e_.*x_)^m_.*Sinh[c_.+d_.*x_^n_],x_Symbol] :=
  1/2*Int[(e*x)^m*E^(c+d*x^n),x] - 1/2*Int[(e*x)^m*E^(-c-d*x^n),x] /;
FreeQ[{c,d,e,m},x] && IGtQ[n,0]

Int[(e_.*x_)^m_.*Cosh[c_.+d_.*x_^n_],x_Symbol] :=
  1/2*Int[(e*x)^m*E^(c+d*x^n),x] + 1/2*Int[(e*x)^m*E^(-c-d*x^n),x] /;
FreeQ[{c,d,e,m},x] && IGtQ[n,0]

2.  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when  p>1

1:  ∫(((Sinh[a+b (x^n)])^p)/(x^n))dx  when (n|p)∈ℤ ∧ p>1 ∧ n≠1

Derivation: Integration by parts

Rule: If  (n|p)∈ℤ ∧ p>1 ∧ n≠1, then

∫(((Sinh[a+b (x^n)])^p)/(x^n))dx  ⟶  -(((Sinh[a+b (x^n)])^p)/((n-1)(x^(n-1))))+((b n p)/(n-1))∫((Sinh[a+b (x^n)])^(p-1)) Cosh[a+b (x^n)]dx

Program code:

Int[x_^m_.*Sinh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  -Sinh[a+b*x^n]^p/((n-1)*x^(n-1)) + 
  b*n*p/(n-1)*Int[Sinh[a+b*x^n]^(p-1)*Cosh[a+b*x^n],x] /;
FreeQ[{a,b},x] && IntegersQ[n,p] && EqQ[m+n,0] && GtQ[p,1] && NeQ[n,1]

Int[x_^m_.*Cosh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  -Cosh[a+b*x^n]^p/((n-1)*x^(n-1)) + 
  b*n*p/(n-1)*Int[Cosh[a+b*x^n]^(p-1)*Sinh[a+b*x^n],x] /;
FreeQ[{a,b},x] && IntegersQ[n,p] && EqQ[m+n,0] && GtQ[p,1] && NeQ[n,1]

2:  ∫(x^m)((Sinh[a+b (x^n)])^p)dx  when m-2n+1==0 ∧ p>1

Reference: G&R 2.471.1b' special case when m-2n+1==0

Reference: G&R 2.471.1a' special case with m-2n+1==0

Rule: If  m-2n+1==0 ∧ p>1, then

∫(x^m)((Sinh[a+b (x^n)])^p)dx  ⟶  -((n ((Sinh[a+b (x^n)])^p))/((b^2) (n^2) (p^2)))+(((x^n) Cosh[a+b (x^n)] ((Sinh[a+b (x^n)])^(p-1)))/(b n p))-((p-1)/p)∫(x^m)((Sinh[a+b (x^n)])^(p-2))dx

Program code:

Int[x_^m_.*Sinh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  -n*Sinh[a+b*x^n]^p/(b^2*n^2*p^2) +
  x^n*Cosh[a+b*x^n]*Sinh[a+b*x^n]^(p-1)/(b*n*p) -
  (p-1)/p*Int[x^m*Sinh[a+b*x^n]^(p-2),x] /;
FreeQ[{a,b,m,n},x] && EqQ[m-2*n+1] && GtQ[p,1]

Int[x_^m_.*Cosh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  -n*Cosh[a+b*x^n]^p/(b^2*n^2*p^2) +
  x^n*Sinh[a+b*x^n]*Cosh[a+b*x^n]^(p-1)/(b*n*p) +
  (p-1)/p*Int[x^m*Cosh[a+b*x^n]^(p-2),x] /;
FreeQ[{a,b,m,n},x] && EqQ[m-2*n+1] && GtQ[p,1]

3:  ∫(x^m)((Sinh[a+b (x^n)])^p)dx  when (m|n)∈ℤ ∧ p>1 ∧ 0<2n<m+1

Reference: G&R 2.471.1b'

Reference: G&R 2.631.3'

Rule: If  (m|n)∈ℤ ∧ p>1 ∧ 0<2n<m+1, then

∫(x^m)((Sinh[a+b (x^n)])^p)dx  ⟶  
-(((m-n+1) (x^(m-2 n+1)) ((Sinh[a+b (x^n)])^p))/((b^2) (n^2) (p^2)))+(((x^(m-n+1)) Cosh[a+b (x^n)] ((Sinh[a+b (x^n)])^(p-1)))/(b n p))-((p-1)/p)∫(x^m) ((Sinh[a+b (x^n)])^(p-2))dx+(((m-n+1) (m-2 n+1))/((b^2) (n^2) (p^2)))∫(x^(m-2 n)) ((Sinh[a+b (x^n)])^p)dx

Program code:

Int[x_^m_.*Sinh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  -(m-n+1)*x^(m-2*n+1)*Sinh[a+b*x^n]^p/(b^2*n^2*p^2) +
  x^(m-n+1)*Cosh[a+b*x^n]*Sinh[a+b*x^n]^(p-1)/(b*n*p) -
  (p-1)/p*Int[x^m*Sinh[a+b*x^n]^(p-2),x] +
  (m-n+1)*(m-2*n+1)/(b^2*n^2*p^2)*Int[x^(m-2*n)*Sinh[a+b*x^n]^p,x] /;
FreeQ[{a,b},x] && IntegersQ[m,n] && GtQ[p,1] && LtQ[0,2*n,m+1]

Int[x_^m_.*Cosh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  -(m-n+1)*x^(m-2*n+1)*Cosh[a+b*x^n]^p/(b^2*n^2*p^2) +
  x^(m-n+1)*Sinh[a+b*x^n]*Cosh[a+b*x^n]^(p-1)/(b*n*p) +
  (p-1)/p*Int[x^m*Cosh[a+b*x^n]^(p-2),x] +
  (m-n+1)*(m-2*n+1)/(b^2*n^2*p^2)*Int[x^(m-2*n)*Cosh[a+b*x^n]^p,x] /;
FreeQ[{a,b},x] && IntegersQ[m,n] && GtQ[p,1] && LtQ[0,2*n,m+1]

4:  ∫(x^m)((Sinh[a+b (x^n)])^p)dx  when (m|n)∈ℤ ∧ p>1 ∧ 0<2n<1-m ∧ m+n+1≠0

Reference: G&R 2.475.1'

Reference: G&R 2.475.2'

Rule: If  (m|n)∈ℤ ∧ p>1 ∧ 0<2n<1-m ∧ m+n+1≠0, then

∫(x^m)((Sinh[a+b (x^n)])^p)dx  ⟶  
(((x^(m+1)) ((Sinh[a+b (x^n)])^p))/(m+1))-((b n p (x^(m+n+1)) Cosh[a+b (x^n)] ((Sinh[a+b (x^n)])^(p-1)))/((m+1) (m+n+1)))+(((b^2) (n^2) (p^2))/((m+1) (m+n+1)))∫(x^(m+2 n)) ((Sinh[a+b (x^n)])^p)dx+(((b^2) (n^2) p (p-1))/((m+1) (m+n+1)))∫(x^(m+2 n)) ((Sinh[a+b (x^n)])^(p-2))dx

Program code:

Int[x_^m_.*Sinh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  x^(m+1)*Sinh[a+b*x^n]^p/(m+1) - 
  b*n*p*x^(m+n+1)*Cosh[a+b*x^n]*Sinh[a+b*x^n]^(p-1)/((m+1)*(m+n+1)) + 
  b^2*n^2*p^2/((m+1)*(m+n+1))*Int[x^(m+2*n)*Sinh[a+b*x^n]^p,x] + 
  b^2*n^2*p*(p-1)/((m+1)*(m+n+1))*Int[x^(m+2*n)*Sinh[a+b*x^n]^(p-2),x] /;
FreeQ[{a,b},x] && IntegersQ[m,n] && GtQ[p,1] && LtQ[0,2*n,1-m] && NeQ[m+n+1,0]

Int[x_^m_.*Cosh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  x^(m+1)*Cosh[a+b*x^n]^p/(m+1) - 
  b*n*p*x^(m+n+1)*Sinh[a+b*x^n]*Cosh[a+b*x^n]^(p-1)/((m+1)*(m+n+1)) + 
  b^2*n^2*p^2/((m+1)*(m+n+1))*Int[x^(m+2*n)*Cosh[a+b*x^n]^p,x] - 
  b^2*n^2*p*(p-1)/((m+1)*(m+n+1))*Int[x^(m+2*n)*Cosh[a+b*x^n]^(p-2),x] /;
FreeQ[{a,b},x] && IntegersQ[m,n] && GtQ[p,1] && LtQ[0,2*n,1-m] && NeQ[m+n+1,0]

5:  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when  p∈ℤ ∧ n∈(SuperPlus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (((e x))^m) F[x]==(k/e) Subst[(x^(k (m+1)-1))F[((x^k)/e)],x,(((e x))^(1/k))] (∂_x)(((e x))^(1/k))

Rule: If  p∈ℤ ∧ n∈(SuperPlus[ℤ])∧ m∈𝔽, let k=Denominator[m], then

∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  (k/e) Subst[∫(x^(k (m+1)-1)) (((a+b Sinh[c+((d (x^(k n)))/(e^n))]))^p) dx,x,(((e x))^(1/k))]

Program code:

Int[(e_.*x_)^m_*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  With[{k=Denominator[m]},
  k/e*Subst[Int[x^(k*(m+1)-1)*(a+b*Sinh[c+d*x^(k*n)/e^n])^p,x],x,(e*x)^(1/k)]] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[p] && IGtQ[n,0] && FractionQ[m]

Int[(e_.*x_)^m_*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  With[{k=Denominator[m]},
  k/e*Subst[Int[x^(k*(m+1)-1)*(a+b*Cosh[c+d*x^(k*n)/e^n])^p,x],x,(e*x)^(1/k)]] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[p] && IGtQ[n,0] && FractionQ[m]

6:  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ]), then

∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  ∫(((e x))^m) TrigReduce[(((a+b Sinh[c+d (x^n)]))^p),x]dx

Program code:

Int[(e_.*x_)^m_.*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandTrigReduce[(e*x)^m,(a+b*Sinh[c+d*x^n])^p,x],x] /;
FreeQ[{a,b,c,d,e,m},x] && IGtQ[p,1] && IGtQ[n,0]

Int[(e_.*x_)^m_.*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandTrigReduce[(e*x)^m,(a+b*Cosh[c+d*x^n])^p,x],x] /;
FreeQ[{a,b,c,d,e,m},x] && IGtQ[p,1] && IGtQ[n,0]

3.  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when  p<-1

1:  ∫(x^m)((Sinh[a+b (x^n)])^p)dx  when m-2n+1==0 ∧ p<-1 ∧ p≠-2

Reference: G&R 2.477.1 special case when m-2n+1=0

Reference: G&R 2.477.2' special case with m-2n+1=0

Rule: If  m-2n+1==0 ∧ p<-1 ∧ p≠-2, then

∫(x^m)((Sinh[a+b (x^n)])^p)dx  ⟶  (((x^n) Cosh[a+b (x^n)] ((Sinh[a+b (x^n)])^(p+1)))/(b n (p+1)))-((n ((Sinh[a+b (x^n)])^(p+2)))/((b^2) (n^2) (p+1) (p+2)))-((p+2)/(p+1))∫(x^m) ((Sinh[a+b (x^n)])^(p+2))dx

Program code:

Int[x_^m_.*Sinh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  x^n*Cosh[a+b*x^n]*Sinh[a+b*x^n]^(p+1)/(b*n*(p+1)) - 
  n*Sinh[a+b*x^n]^(p+2)/(b^2*n^2*(p+1)*(p+2)) - 
  (p+2)/(p+1)*Int[x^m*Sinh[a+b*x^n]^(p+2),x] /;
FreeQ[{a,b,m,n},x] && EqQ[m-2*n+1,0] && LtQ[p,-1] && NeQ[p,-2]

Int[x_^m_.*Cosh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  -x^n*Sinh[a+b*x^n]*Cosh[a+b*x^n]^(p+1)/(b*n*(p+1)) + 
  n*Cosh[a+b*x^n]^(p+2)/(b^2*n^2*(p+1)*(p+2)) + 
  (p+2)/(p+1)*Int[x^m*Cosh[a+b*x^n]^(p+2),x] /;
FreeQ[{a,b,m,n},x] && EqQ[m-2*n+1,0] && LtQ[p,-1] && NeQ[p,-2]

2:  ∫(x^m)((Sinh[a+b (x^n)])^p)dx  when (m|n)∈ℤ ∧ p<-1 ∧ p≠-2 ∧ 0<2n<m+1

Reference: G&R 2.477.1

Reference: G&R 2.477.2

Rule: If  (m|n)∈ℤ ∧ p<-1 ∧ p≠-2 ∧ 0<2n<m+1, then

∫(x^m)((Sinh[a+b (x^n)])^p)dx  ⟶  
(((x^(m-n+1)) Cosh[a+b (x^n)] ((Sinh[a+b (x^n)])^(p+1)))/(b n (p+1)))-(((m-n+1) (x^(m-2 n+1)) ((Sinh[a+b (x^n)])^(p+2)))/((b^2) (n^2) (p+1) (p+2)))-((p+2)/(p+1))∫(x^m) ((Sinh[a+b (x^n)])^(p+2))dx+(((m-n+1) (m-2 n+1))/((b^2) (n^2) (p+1) (p+2)))∫(x^(m-2 n)) ((Sinh[a+b (x^n)])^(p+2))dx

Program code:

Int[x_^m_.*Sinh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  x^(m-n+1)*Cosh[a+b*x^n]*Sinh[a+b*x^n]^(p+1)/(b*n*(p+1)) -
  (m-n+1)*x^(m-2*n+1)*Sinh[a+b*x^n]^(p+2)/(b^2*n^2*(p+1)*(p+2)) -
  (p+2)/(p+1)*Int[x^m*Sinh[a+b*x^n]^(p+2),x] +
  (m-n+1)*(m-2*n+1)/(b^2*n^2*(p+1)*(p+2))*Int[x^(m-2*n)*Sinh[a+b*x^n]^(p+2),x] /;
FreeQ[{a,b},x] && IntegersQ[m,n] && LtQ[p,-1] && NeQ[p,-2] && LtQ[0,2*n,m+1]

Int[x_^m_.*Cosh[a_.+b_.*x_^n_]^p_,x_Symbol] :=
  -x^(m-n+1)*Sinh[a+b*x^n]*Cosh[a+b*x^n]^(p+1)/(b*n*(p+1)) +
  (m-n+1)*x^(m-2*n+1)*Cosh[a+b*x^n]^(p+2)/(b^2*n^2*(p+1)*(p+2)) +
  (p+2)/(p+1)*Int[x^m*Cosh[a+b*x^n]^(p+2),x] -
  (m-n+1)*(m-2*n+1)/(b^2*n^2*(p+1)*(p+2))*Int[x^(m-2*n)*Cosh[a+b*x^n]^(p+2),x] /;
FreeQ[{a,b},x] && IntegersQ[m,n] && LtQ[p,-1] && NeQ[p,-2] && LtQ[0,2*n,m+1]

2.  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when  p∈ℤ ∧ n∈(SuperMinus[ℤ])

1.  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when  p∈ℤ ∧ n∈(SuperMinus[ℤ])∧ m∈ℚ

1:  ∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when  p∈ℤ ∧ n∈(SuperMinus[ℤ])∧ m∈ℤ

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ m∈ℤ, then (x^m) F[(x^n)]==-Subst[((F[(x^(-n))])/(x^(m+2))),x,(1/x)] (∂_x)(1/x)

Rule: If  p∈ℤ ∧ n∈(SuperMinus[ℤ])∧ m∉ℚ, then

∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  -Subst[∫((((a+b Sinh[c+d (x^(-n))]))^p)/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[x_^m_.*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  -Subst[Int[(a+b*Sinh[c+d*x^(-n)])^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,d},x] && IntegerQ[p] && ILtQ[n,0] && IntegerQ[m]

Int[x_^m_.*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  -Subst[Int[(a+b*Cosh[c+d*x^(-n)])^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,d},x] && IntegerQ[p] && ILtQ[n,0] && IntegerQ[m]

2:  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when  p∈ℤ ∧ n∈(SuperMinus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ k>1, then (((e x))^m) F[(x^n)]==-(k/e)Subst[ ((F[(e^(-n)) (x^(-k n))])/(x^(k (m+1)+1))),x,(1/(((e x))^(1/k)))] (∂_x)(1/(((e x))^(1/k)))

Rule: If  p∈ℤ ∧ n∈(SuperMinus[ℤ])∧ m∈𝔽, let k=Denominator[m], then

∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  -(k/e) Subst[∫((((a+b Sinh[c+d (e^(-n)) (x^(-k n))]))^p)/(x^(k (m+1)+1)))dx,x,(1/(((e x))^(1/k)))]

Program code:

Int[(e_.*x_)^m_*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  With[{k=Denominator[m]},
  -k/e*Subst[Int[(a+b*Sinh[c+d/(e^n*x^(k*n))])^p/x^(k*(m+1)+1),x],x,1/(e*x)^(1/k)]] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[p] && ILtQ[n,0] && FractionQ[m]

Int[(e_.*x_)^m_*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  With[{k=Denominator[m]},
  -k/e*Subst[Int[(a+b*Cosh[c+d/(e^n*x^(k*n))])^p/x^(k*(m+1)+1),x],x,1/(e*x)^(1/k)]] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[p] && ILtQ[n,0] && FractionQ[m]

2:  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when  p∈ℤ ∧ n∈(SuperMinus[ℤ])∧ m∉ℚ

Derivation:  Piecewise constant extraction and integration by substitution

Basis: (∂_x)((((e x))^m) ((((x^(-1))))^m))==0

Basis: F[x]==-Subst[((F[(x^(-1))] )/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  p∈ℤ ∧ n∈(SuperMinus[ℤ])∧ m∉ℚ, then

∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  (((e x))^m) ((((x^(-1))))^m)∫((((a+b Sinh[c+d (x^n)]))^p)/((((x^(-1))))^m))dx  ⟶  -(((e x))^m) ((((x^(-1))))^m) Subst[∫((((a+b Sinh[c+d (x^(-n))]))^p)/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[(e_.*x_)^m_*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  -(e*x)^m*(x^(-1))^m*Subst[Int[(a+b*Sinh[c+d*x^(-n)])^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,d,e,m},x] && IntegerQ[p] && ILtQ[n,0] && Not[RationalQ[m]]

Int[(e_.*x_)^m_*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  -(e*x)^m*(x^(-1))^m*Subst[Int[(a+b*Cosh[c+d*x^(-n)])^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,d,e,m},x] && IntegerQ[p] && ILtQ[n,0] && Not[RationalQ[m]]

3.  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when p∈ℤ ∧ n∈𝔽

1:  ∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when  p∈ℤ ∧ n∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (x^m)F[(x^n)]==k Subst[(x^(k(m+1)-1))F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  p∈ℤ ∧ n∈𝔽, let k=Denominator[n], then

∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  k Subst[∫(x^(k(m+1)-1))(((a+b Sinh[c+d (x^(k n))]))^p)dx,x,(x^(1/k))]

Program code:

Int[x_^m_.*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  Module[{k=Denominator[n]},
  k*Subst[Int[x^(k*(m+1)-1)*(a+b*Sinh[c+d*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d,m},x] && IntegerQ[p] && FractionQ[n]

Int[x_^m_.*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  Module[{k=Denominator[n]},
  k*Subst[Int[x^(k*(m+1)-1)*(a+b*Cosh[c+d*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d,m},x] && IntegerQ[p] && FractionQ[n]

2:  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when p∈ℤ ∧ n∈𝔽

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e x))^m)/(x^m))==0

Rule: If  p∈ℤ ∧ n∈𝔽, then

∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  (((e^(IntPart[m])) (((e x))^(FracPart[m])))/(x^(FracPart[m]))) ∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx

Program code:

Int[(e_*x_)^m_*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*Sinh[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m},x] && IntegerQ[p] && FractionQ[n]

Int[(e_*x_)^m_*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*Cosh[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m},x] && IntegerQ[p] && FractionQ[n]

4.  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when p∈ℤ ∧ m≠-1 ∧ (n/(m+1))∈(SuperPlus[ℤ])

1:  ∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when  p∈ℤ ∧ m≠-1 ∧ (n/(m+1))∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: If (n/(m+1))∈ℤ, then (x^m)F[(x^n)]==(1/(m+1))Subst[F[(x^(n/(m+1)))],x,(x^(m+1))](∂_x)(x^(m+1))

Rule: If  p∈ℤ ∧ m≠-1 ∧ (n/(m+1))∈(SuperPlus[ℤ]), then

∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  (1/(m+1))Subst[∫(((a+b Sinh[c+d (x^(n/(m+1)))]))^p)dx,x,(x^(m+1))]

Program code:

Int[x_^m_.*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  1/(m+1)*Subst[Int[(a+b*Sinh[c+d*x^Simplify[n/(m+1)]])^p,x],x,x^(m+1)] /;
FreeQ[{a,b,c,d,m,n},x] && IntegerQ[p] && NeQ[m,-1] && IGtQ[Simplify[n/(m+1)],0] && Not[IntegerQ[n]]

Int[x_^m_.*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  1/(m+1)*Subst[Int[(a+b*Cosh[c+d*x^Simplify[n/(m+1)]])^p,x],x,x^(m+1)] /;
FreeQ[{a,b,c,d,m,n},x] && IntegerQ[p] && NeQ[m,-1] && IGtQ[Simplify[n/(m+1)],0] && Not[IntegerQ[n]]

2:  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when p∈ℤ ∧ m≠-1 ∧ (n/(m+1))∈(SuperPlus[ℤ])

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e x))^m)/(x^m))==0

Rule: If  p∈ℤ ∧ m≠-1 ∧ (n/(m+1))∈(SuperPlus[ℤ]), then

∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  (((e^(IntPart[m])) (((e x))^(FracPart[m])))/(x^(FracPart[m]))) ∫(x^m) (((a+b Sinh[c+d (x^n)]))^p)dx

Program code:

Int[(e_*x_)^m_*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*Sinh[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IntegerQ[p] && NeQ[m,-1] && IGtQ[Simplify[n/(m+1)],0] && Not[IntegerQ[n]]

Int[(e_*x_)^m_*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*Cosh[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IntegerQ[p] && NeQ[m,-1] && IGtQ[Simplify[n/(m+1)],0] && Not[IntegerQ[n]]

5.  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when p∈(SuperPlus[ℤ])

1:  ∫(((e x))^m) Sinh[c+d (x^n)]dx

Derivation: Algebraic expansion

Basis: Sinh[z]==((e^z)/2)-((e^(-z))/2)

Basis: Cosh[z]==((e^z)/2)+((e^(-z))/2)

Rule:

∫(((e x))^m) Sinh[c+d (x^n)]dx  ⟶  (1/2)∫(((e x))^m) (e^(c+d (x^n)))dx-(1/2)∫(((e x))^m) (e^(-c-d (x^n)))dx

Program code:

Int[(e_.*x_)^m_.*Sinh[c_.+d_.*x_^n_],x_Symbol] :=
  1/2*Int[(e*x)^m*E^(c+d*x^n),x] - 1/2*Int[(e*x)^m*E^(-c-d*x^n),x] /;
FreeQ[{c,d,e,m,n},x]

Int[(e_.*x_)^m_.*Cosh[c_.+d_.*x_^n_],x_Symbol] :=
  1/2*Int[(e*x)^m*E^(c+d*x^n),x] + 1/2*Int[(e*x)^m*E^(-c-d*x^n),x] /;
FreeQ[{c,d,e,m,n},x]

2:  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  when p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p∈(SuperPlus[ℤ]), then

∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx  ⟶  ∫(((e x))^m) TrigReduce[(((a+b Sinh[c+d (x^n)]))^p),x]dx

Program code:

Int[(e_.*x_)^m_.*(a_.+b_.*Sinh[c_.+d_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandTrigReduce[(e*x)^m,(a+b*Sinh[c+d*x^n])^p,x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IGtQ[p,0]

Int[(e_.*x_)^m_.*(a_.+b_.*Cosh[c_.+d_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandTrigReduce[(e*x)^m,(a+b*Cosh[c+d*x^n])^p,x],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IGtQ[p,0]

S:  ∫(x^m) (((a+b Sinh[c+d (u^n)]))^p)dx  when  u==f+g x ∧ m∈ℤ

Derivation: Integration by substitution

Basis: If  m∈ℤ, then (x^m)F[f+g x]==(1/(g^(m+1)))Subst[(((x-f))^m) F[x],x,f+g x](∂_x)(f+g x)

Rule: If  u==f+g x ∧ m∈ℤ, then

∫(x^m) (((a+b Sinh[c+d (u^n)]))^p)dx  ⟶  (1/(g^(m+1)))Subst[∫(((x-f))^m)(((a+b Sinh[c+d (x^n)]))^p)dx,x,u]

Program code:

Int[x_^m_.*(a_.+b_.*Sinh[c_.+d_.*u_^n_])^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]^(m+1)*Subst[Int[(x-Coefficient[u,x,0])^m*(a+b*Sinh[c+d*x^n])^p,x],x,u] /;
FreeQ[{a,b,c,d,n,p},x] && LinearQ[u,x] && NeQ[u,x] && IntegerQ[m]

Int[x_^m_.*(a_.+b_.*Cosh[c_.+d_.*u_^n_])^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]^(m+1)*Subst[Int[(x-Coefficient[u,x,0])^m*(a+b*Cosh[c+d*x^n])^p,x],x,u] /;
FreeQ[{a,b,c,d,n,p},x] && LinearQ[u,x] && NeQ[u,x] && IntegerQ[m]

X:  ∫(((e x))^m) (((a+b Sinh[c+d (u^n)]))^p)dx  when  u==f+g x

Rule:

∫(((e x))^m) (((a+b Sinh[c+d (u^n)]))^p)dx  ⟶  ∫(((e x))^m) (((a+b Sinh[c+d (u^n)]))^p)dx

Program code:

Int[(e_.*x_)^m_.*(a_.+b_.*Sinh[c_.+d_.*u_^n_])^p_.,x_Symbol] :=
  Unintegrable[(e*x)^m*(a+b*Sinh[c+d*u^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && LinearQ[u,x]

Int[(e_.*x_)^m_.*(a_.+b_.*Cosh[c_.+d_.*u_^n_])^p_.,x_Symbol] :=
  Unintegrable[(e*x)^m*(a+b*Cosh[c+d*u^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && LinearQ[u,x]

N:  ∫(((e x))^m) (((a+b Sinh[u]))^p)dx  when  u==c+d (x^n)

Derivation: Algebraic normalization

Rule: If  u==c+d (x^n), then

∫(((e x))^m) (((a+b Sinh[u]))^p)dx  ⟶  ∫(((e x))^m) (((a+b Sinh[c+d (x^n)]))^p)dx

Program code:

Int[(e_*x_)^m_.*(a_.+b_.*Sinh[u_])^p_.,x_Symbol] :=
  Int[(e*x)^m*(a+b*Sinh[ExpandToSum[u,x]])^p,x] /;
FreeQ[{a,b,e,m,p},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

Int[(e_*x_)^m_.*(a_.+b_.*Cosh[u_])^p_.,x_Symbol] :=
  Int[(e*x)^m*(a+b*Cosh[ExpandToSum[u,x]])^p,x] /;
FreeQ[{a,b,e,m,p},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

Rules for integrands of the form(x^m) ((Sinh[a+b (x^n)])^p) Cosh[a+b (x^n)]

1:  ∫(x^(n-1)) ((Sinh[a+b (x^n)])^p) Cosh[a+b (x^n)]dx  when  p≠-1

Derivation: Power rule for integration

Rule: If  p≠-1, then

∫(x^(n-1)) ((Sinh[a+b (x^n)])^p) Cosh[a+b (x^n)]dx  ⟶  (((Sinh[a+b (x^n)])^(p+1))/(b n (p+1)))

Program code:

Int[x_^m_.*Sinh[a_.+b_.*x_^n_]^p_.*Cosh[a_.+b_.*x_^n_.],x_Symbol] :=
  Sinh[a+b*x^n]^(p+1)/(b*n*(p+1)) /;
FreeQ[{a,b,m,n,p},x] && EqQ[m,n-1] && NeQ[p,-1]

Int[x_^m_.*Cosh[a_.+b_.*x_^n_]^p_.*Sinh[a_.+b_.*x_^n_.],x_Symbol] :=
  Cosh[a+b*x^n]^(p+1)/(b*n*(p+1)) /;
FreeQ[{a,b,m,n,p},x] && EqQ[m,n-1] && NeQ[p,-1]

2:  ∫(x^m) ((Sinh[a+b (x^n)])^p) Cosh[a+b (x^n)]dx  when  0<n<m+1 ∧ p≠-1

Reference: G&R 2.479.6

Reference: G&R 2.479.3

Derivation: Integration by parts

Basis: (x^m) Cosh[a+b (x^n)] ((Sinh[a+b (x^n)])^p)==(x^(m-n+1))(∂_x)(((Sinh[a+b (x^n)])^(p+1))/(b n (p+1)))

Rule: If  0<n<m+1 ∧ p≠-1, then

∫(x^m) ((Sinh[a+b (x^n)])^p) Cosh[a+b (x^n)]dx  ⟶  (((x^(m-n+1)) ((Sinh[a+b (x^n)])^(p+1)))/(b n (p+1)))-((m-n+1)/(b n (p+1)))∫(x^(m-n)) ((Sinh[a+b (x^n)])^(p+1))dx

Program code:

Int[x_^m_.*Sinh[a_.+b_.*x_^n_.]^p_.*Cosh[a_.+b_.*x_^n_.],x_Symbol] :=
  x^(m-n+1)*Sinh[a+b*x^n]^(p+1)/(b*n*(p+1)) -
  (m-n+1)/(b*n*(p+1))*Int[x^(m-n)*Sinh[a+b*x^n]^(p+1),x] /;
FreeQ[{a,b,p},x] && LtQ[0,n,m+1] && NeQ[p,-1]

Int[x_^m_.*Cosh[a_.+b_.*x_^n_.]^p_.*Sinh[a_.+b_.*x_^n_.],x_Symbol] :=
  x^(m-n+1)*Cosh[a+b*x^n]^(p+1)/(b*n*(p+1)) -
  (m-n+1)/(b*n*(p+1))*Int[x^(m-n)*Cosh[a+b*x^n]^(p+1),x] /;
FreeQ[{a,b,p},x] && LtQ[0,n,m+1] && NeQ[p,-1]