Rules for integrands of the form(((c+d x))^m)((Hyper[a+b x])^n)((Hyper[a+b x])^p)

1.  ∫(((c+d x))^m)((Hyper[a+b x])^n)((Hyper[a+b x])^p)dx

1.  ∫(((c+d x))^m)((Sinh[a+b x])^n)((Cosh[a+b x])^p)dx

1:  ∫(((c+d x))^m)((Sinh[a+b x])^n)Cosh[a+b x]dx  when  m∈(SuperPlus[ℤ])∧ n≠-1

Derivation: Integration by parts

Basis: ((Sinh[a+b x])^n)Cosh[a+b x]==(∂_x)(((Sinh[a+b x])^(n+1))/(b(n+1)))

Rule: If  m∈(SuperPlus[ℤ])∧ n≠-1, then

∫(((c+d x))^m)((Sinh[a+b x])^n)Cosh[a+b x]dx  ⟶  (((((c+d x))^m)((Sinh[a+b x])^(n+1)))/(b (n+1)))-((d m)/(b(n+1)))∫(((c+d x))^(m-1))((Sinh[a+b x])^(n+1))dx

Program code:

Int[(c_.+d_.*x_)^m_.*Sinh[a_.+b_.*x_]^n_.*Cosh[a_.+b_.*x_],x_Symbol] :=
  (c+d*x)^m*Sinh[a+b*x]^(n+1)/(b*(n+1)) - 
  d*m/(b*(n+1))*Int[(c+d*x)^(m-1)*Sinh[a+b*x]^(n+1),x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[m,0] && NeQ[n,-1]

Int[(c_.+d_.*x_)^m_.*Sinh[a_.+b_.*x_]*Cosh[a_.+b_.*x_]^n_.,x_Symbol] :=
  (c+d*x)^m*Cosh[a+b*x]^(n+1)/(b*(n+1)) - 
  d*m/(b*(n+1))*Int[(c+d*x)^(m-1)*Cosh[a+b*x]^(n+1),x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[m,0] && NeQ[n,-1]

2:  ∫(((c+d x))^m)((Sinh[a+b x])^n)((Cosh[a+b x])^p)dx  when n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ]), then

∫(((c+d x))^m)((Sinh[a+b x])^n)((Cosh[a+b x])^p)dx  ⟶  ∫(((c+d x))^m)TrigReduce[((Sinh[a+b x])^n)((Cosh[a+b x])^p)]dx

Program code:

Int[(c_.+d_.*x_)^m_.*Sinh[a_.+b_.*x_]^n_.*Cosh[a_.+b_.*x_]^p_.,x_Symbol] :=
  Int[ExpandTrigReduce[(c+d*x)^m,Sinh[a+b*x]^n*Cosh[a+b*x]^p,x],x] /;
FreeQ[{a,b,c,d,m},x] && IGtQ[n,0] && IGtQ[p,0]

2:  ∫(((c+d x))^m)((Sinh[a+b x])^n)((Tanh[a+b x])^p)dx  when  n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: ((Sinh[z])^2) ((Tanh[z])^2)==((Sinh[z])^2)-((Tanh[z])^2)

Rule: If n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ]), then

∫(((c+d x))^m)((Sinh[a+b x])^n)((Tanh[a+b x])^p)dx  ⟶  
∫(((c+d x))^m)((Sinh[a+b x])^n)((Tanh[a+b x])^(p-2))dx-∫(((c+d x))^m)((Sinh[a+b x])^(n-2))((Tanh[a+b x])^p)dx

Program code:

Int[(c_.+d_.*x_)^m_.*Sinh[a_.+b_.*x_]^n_.*Tanh[a_.+b_.*x_]^p_.,x_Symbol] :=
  Int[(c+d*x)^m*Sinh[a+b*x]^n*Tanh[a+b*x]^(p-2),x] - Int[(c+d*x)^m*Sinh[a+b*x]^(n-2)*Tanh[a+b*x]^p,x] /;
FreeQ[{a,b,c,d,m},x] && IGtQ[n,0] && IGtQ[p,0]

Int[(c_.+d_.*x_)^m_.*Cosh[a_.+b_.*x_]^n_.*Coth[a_.+b_.*x_]^p_.,x_Symbol] :=
  Int[(c+d*x)^m*Cosh[a+b*x]^n*Coth[a+b*x]^(p-2),x] + Int[(c+d*x)^m*Cosh[a+b*x]^(n-2)*Coth[a+b*x]^p,x] /;
FreeQ[{a,b,c,d,m},x] && IGtQ[n,0] && IGtQ[p,0]

3.  ∫(((c+d x))^m)((Sech[a+b x])^n)((Tanh[a+b x])^p)dx

1:  ∫(((c+d x))^m) ((Sech[a+b x])^n) Tanh[a+b x]dx  when  m>0

Derivation: Integration by parts

Basis: ((Sech[a+b x])^n)Tanh[a+b x]==-(∂_x)(((Sech[a+b x])^n)/(b n))

Note: Dummy exponent p===1 required in program code so InputForm of integrand is recognized.

Rule: If  m>0, then

∫(((c+d x))^m) ((Sech[a+b x])^n) Tanh[a+b x]dx  ⟶  -(((((c+d x))^m) ((Sech[a+b x])^n))/(b n))+((d m)/(b n))∫(((c+d x))^(m-1)) ((Sech[a+b x])^n)dx

Program code:

Int[(c_.+d_.*x_)^m_.*Sech[a_.+b_.*x_]^n_.*Tanh[a_.+b_.*x_]^p_.,x_Symbol] :=
  -(c+d*x)^m*Sech[a+b*x]^n/(b*n) + 
  d*m/(b*n)*Int[(c+d*x)^(m-1)*Sech[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x] && EqQ[p,1] && GtQ[m,0]

Int[(c_.+d_.*x_)^m_.*Csch[a_.+b_.*x_]^n_.*Coth[a_.+b_.*x_]^p_.,x_Symbol] :=
  -(c+d*x)^m*Csch[a+b*x]^n/(b*n) + 
  d*m/(b*n)*Int[(c+d*x)^(m-1)*Csch[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x] && EqQ[p,1] && GtQ[m,0]

2:  ∫(((c+d x))^m)((Sech[a+b x])^2)((Tanh[a+b x])^n)dx  when  m∈(SuperPlus[ℤ])∧ n≠-1

Derivation: Integration by parts

Basis: ((Sech[a+b x])^2)((Tanh[a+b x])^n)==(∂_x)(((Tanh[a+b x])^(n+1))/(b(n+1)))

Rule: If  m∈(SuperPlus[ℤ])∧ n≠-1, then

∫(((c+d x))^m)((Sech[a+b x])^2)((Tanh[a+b x])^n)dx  ⟶  (((((c+d x))^m)((Tanh[a+b x])^(n+1)))/(b (n+1)))-((d m)/(b (n+1)))∫(((c+d x))^(m-1))((Tanh[a+b x])^(n+1))dx

Program code:

Int[(c_.+d_.*x_)^m_.*Sech[a_.+b_.*x_]^2*Tanh[a_.+b_.*x_]^n_.,x_Symbol] :=
  (c+d*x)^m*Tanh[a+b*x]^(n+1)/(b*(n+1)) - 
  d*m/(b*(n+1))*Int[(c+d*x)^(m-1)*Tanh[a+b*x]^(n+1),x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[m,0] && NeQ[n,-1]

Int[(c_.+d_.*x_)^m_.*Csch[a_.+b_.*x_]^2*Coth[a_.+b_.*x_]^n_.,x_Symbol] :=
  -(c+d*x)^m*Coth[a+b*x]^(n+1)/(b*(n+1)) + 
  d*m/(b*(n+1))*Int[(c+d*x)^(m-1)*Coth[a+b*x]^(n+1),x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[m,0] && NeQ[n,-1]

3:  ∫(((c+d x))^m)((Sech[a+b x])^n)((Tanh[a+b x])^p)dx  when  (p/2)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: ((Tanh[z])^2)==1-((Sech[z])^2)

Rule: If (p/2)∈(SuperPlus[ℤ]), then

∫(((c+d x))^m)((Sech[a+b x])^n)((Tanh[a+b x])^p)dx  ⟶  
∫(((c+d x))^m)((Sech[a+b x])^n)((Tanh[a+b x])^(p-2))dx-∫(((c+d x))^m)((Sech[a+b x])^(n+2))((Tanh[a+b x])^(p-2))dx

Program code:

Int[(c_.+d_.*x_)^m_.*Sech[a_.+b_.*x_]*Tanh[a_.+b_.*x_]^p_,x_Symbol] :=
  Int[(c+d*x)^m*Sech[a+b*x]*Tanh[a+b*x]^(p-2),x] - Int[(c+d*x)^m*Sech[a+b*x]^3*Tanh[a+b*x]^(p-2),x] /;
FreeQ[{a,b,c,d,m},x] && IGtQ[p/2,0]

Int[(c_.+d_.*x_)^m_.*Sech[a_.+b_.*x_]^n_.*Tanh[a_.+b_.*x_]^p_,x_Symbol] :=
  Int[(c+d*x)^m*Sech[a+b*x]^n*Tanh[a+b*x]^(p-2),x] - Int[(c+d*x)^m*Sech[a+b*x]^(n+2)*Tanh[a+b*x]^(p-2),x] /;
FreeQ[{a,b,c,d,m,n},x] && IGtQ[p/2,0]

Int[(c_.+d_.*x_)^m_.*Csch[a_.+b_.*x_]*Coth[a_.+b_.*x_]^p_,x_Symbol] :=
  Int[(c+d*x)^m*Csch[a+b*x]*Coth[a+b*x]^(p-2),x] + Int[(c+d*x)^m*Csch[a+b*x]^3*Coth[a+b*x]^(p-2),x] /;
FreeQ[{a,b,c,d,m},x] && IGtQ[p/2,0]

Int[(c_.+d_.*x_)^m_.*Csch[a_.+b_.*x_]^n_.*Coth[a_.+b_.*x_]^p_,x_Symbol] :=
  Int[(c+d*x)^m*Csch[a+b*x]^n*Coth[a+b*x]^(p-2),x] + Int[(c+d*x)^m*Csch[a+b*x]^(n+2)*Coth[a+b*x]^(p-2),x] /;
FreeQ[{a,b,c,d,m,n},x] && IGtQ[p/2,0]

4:  ∫(((c+d x))^m)((Sech[a+b x])^n)((Tanh[a+b x])^p)dx  when  m∈(SuperPlus[ℤ])∧ ((n/2)∈ℤ ∨ ((p+1)/2)∈ℤ)

Derivation: Integration by parts

Rule: If  m∈(SuperPlus[ℤ])∧ ((n/2)∈ℤ ∨ ((p+1)/2)∈ℤ), let u=∫((Sech[a+b x])^n)((Tanh[a+b x])^p)dx, then

∫(((c+d x))^m)((Sech[a+b x])^n)((Tanh[a+b x])^p)dx  ⟶  u(((c+d x))^m)-d m∫u(((c+d x))^(m-1))dx

Program code:

Int[(c_.+d_.*x_)^m_.*Sech[a_.+b_.*x_]^n_.*Tanh[a_.+b_.*x_]^p_.,x_Symbol] :=
  With[{u=IntHide[Sech[a+b*x]^n*Tanh[a+b*x]^p,x]},
  Dist[(c+d*x)^m,u,x] - d*m*Int[(c+d*x)^(m-1)*u,x]] /;
FreeQ[{a,b,c,d,n,p},x] && IGtQ[m,0] && (IntegerQ[n/2] || IntegerQ[(p-1)/2])

Int[(c_.+d_.*x_)^m_.*Csch[a_.+b_.*x_]^n_.*Coth[a_.+b_.*x_]^p_.,x_Symbol] :=
  With[{u=IntHide[Csch[a+b*x]^n*Coth[a+b*x]^p,x]},
  Dist[(c+d*x)^m,u,x] - d*m*Int[(c+d*x)^(m-1)*u,x]] /;
FreeQ[{a,b,c,d,n,p},x] && IGtQ[m,0] && (IntegerQ[n/2] || IntegerQ[(p-1)/2])

4.  ∫(((c+d x))^m)((Sech[a+b x])^p)((Csch[a+b x])^n)dx

1:  ∫(((c+d x))^m)((Csch[a+b x])^n)((Sech[a+b x])^n)dx  when  n∈ℤ

Derivation: Algebraic simplification

Basis: Csch[z]Sech[z]==2 Csch[2 z]

Rule: If  n∈ℤ, then

∫(((c+d x))^m)((Csch[a+b x])^n)((Sech[a+b x])^n)dx  ⟶  (2^n)∫ (((c+d x))^m)((Csch[2a+2b x])^n)dx

Program code:

Int[(c_.+d_.*x_)^m_.*Csch[a_.+b_.*x_]^n_.*Sech[a_.+b_.*x_]^n_., x_Symbol] :=
  2^n*Int[(c+d*x)^m*Csch[2*a+2*b*x]^n,x] /;
FreeQ[{a,b,c,d},x] && RationalQ[m] && IntegerQ[n]

2:  ∫(((c+d x))^m) ((Csch[a+b x])^n)((Sech[a+b x])^p)dx  when  (n|p)∈ℤ ∧ m>0 ∧ n≠p

Derivation: Integration by parts

Rule: If  (n|p)∈ℤ ∧ m>0 ∧ n≠p, let u=∫((Csch[a+b x])^n)((Sech[a+b x])^p)dx, then

∫(((c+d x))^m) ((Csch[a+b x])^n)((Sech[a+b x])^p)dx  ⟶  (((c+d x))^m) u-d m∫(((c+d x))^(m-1)) udx

Program code:

Int[(c_.+d_.*x_)^m_.*Csch[a_.+b_.*x_]^n_.*Sech[a_.+b_.*x_]^p_., x_Symbol] :=
  With[{u=IntHide[Csch[a+b*x]^n*Sech[a+b*x]^p,x]},
  Dist[(c+d*x)^m,u,x] - d*m*Int[(c+d*x)^(m-1)*u,x]] /;
FreeQ[{a,b,c,d},x] && IntegersQ[n,p] && GtQ[m,0] && NeQ[n,p]

5:  ∫(u^m)((Hyper[v])^n)((Hyper[w])^p)dx  when  u==c+d x ∧ v==w==a+b x

Derivation: Algebraic normalization

Rule: If  u==c+d x ∧ v==w==a+b x, then

∫(u^m)((Hyper[v])^n)((Hyper[w])^p)dx  ⟶  ∫(((c+d x))^m) ((Hyper[a+b x])^n)((Hyper[a+b x])^p)dx

Program code:

Int[u_^m_.*F_[v_]^n_.*G_[w_]^p_.,x_Symbol] :=
  Int[ExpandToSum[u,x]^m*F[ExpandToSum[v,x]]^n*G[ExpandToSum[v,x]]^p,x] /;
FreeQ[{m,n,p},x] && HyperbolicQ[F] && HyperbolicQ[G] && EqQ[v,w] && LinearQ[{u,v,w},x] && Not[LinearMatchQ[{u,v,w},x]]

2:  ∫(((e+f x))^m)Cosh[c+d x](((a+b Sinh[c+d x]))^n)dx  when  m∈(SuperPlus[ℤ])∧ n≠-1

Derivation: Integration by parts

Basis: Cosh[c+d x](((a+b Sinh[c+d x]))^n)==(∂_x)((((a+b Sinh[c+d x]))^(n+1))/(b d(n+1)))

Rule: If  m∈(SuperPlus[ℤ])∧ n≠-1, then

∫(((e+f x))^m)Cosh[c+d x](((a+b Sinh[c+d x]))^n)dx  ⟶  (((((e+f x))^m)(((a+b Sinh[c+d x]))^(n+1)))/(b d (n+1)))-((f m)/(b d (n+1)))∫(((e+f x))^(m-1))(((a+b Sinh[c+d x]))^(n+1))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Cosh[c_.+d_.*x_]*(a_+b_.*Sinh[c_.+d_.*x_])^n_.,x_Symbol] :=
  (e+f*x)^m*(a+b*Sinh[c+d*x])^(n+1)/(b*d*(n+1)) - 
  f*m/(b*d*(n+1))*Int[(e+f*x)^(m-1)*(a+b*Sinh[c+d*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,n},x] && IGtQ[m,0] && NeQ[n,-1]

Int[(e_.+f_.*x_)^m_.*Sinh[c_.+d_.*x_]*(a_+b_.*Cosh[c_.+d_.*x_])^n_.,x_Symbol] :=
  (e+f*x)^m*(a+b*Cosh[c+d*x])^(n+1)/(b*d*(n+1)) - 
  f*m/(b*d*(n+1))*Int[(e+f*x)^(m-1)*(a+b*Cosh[c+d*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,n},x] && IGtQ[m,0] && NeQ[n,-1]

3:  ∫(((e+f x))^m)((Sech[c+d x])^2)(((a+b Tanh[c+d x]))^n)dx  when  m∈(SuperPlus[ℤ])∧ n≠-1

Derivation: Integration by parts

Basis: ((Sech[c+d x])^2)(((a+b Tanh[c+d x]))^n)==(∂_x)((((a+b Tanh[c+d x]))^(n+1))/(b d(n+1)))

Rule: If  m∈(SuperPlus[ℤ])∧ n≠-1, then

∫(((e+f x))^m)((Sech[c+d x])^2)(((a+b Tanh[c+d x]))^n)dx  ⟶  (((((e+f x))^m)(((a+b Tanh[c+d x]))^(n+1)))/(b d (n+1)))-((f m)/(b d (n+1)))∫(((e+f x))^(m-1))(((a+b Tanh[c+d x]))^(n+1))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sech[c_.+d_.*x_]^2*(a_+b_.*Tanh[c_.+d_.*x_])^n_.,x_Symbol] :=
  (e+f*x)^m*(a+b*Tanh[c+d*x])^(n+1)/(b*d*(n+1)) - 
  f*m/(b*d*(n+1))*Int[(e+f*x)^(m-1)*(a+b*Tanh[c+d*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,n},x] && IGtQ[m,0] && NeQ[n,-1]

Int[(e_.+f_.*x_)^m_.*Csch[c_.+d_.*x_]^2*(a_+b_.*Coth[c_.+d_.*x_])^n_.,x_Symbol] :=
  -(e+f*x)^m*(a+b*Coth[c+d*x])^(n+1)/(b*d*(n+1)) + 
  f*m/(b*d*(n+1))*Int[(e+f*x)^(m-1)*(a+b*Coth[c+d*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,n},x] && IGtQ[m,0] && NeQ[n,-1]

4:  ∫(((e+f x))^m)Sech[c+d x]Tanh[c+d x](((a+b Sech[c+d x]))^n)dx  when  m∈(SuperPlus[ℤ])∧ n≠-1

Derivation: Integration by parts

Basis: Sech[c+d x]Tanh[c+d x](((a+b Sech[c+d x]))^n)==-(∂_x)((((a+b Sech[c+d x]))^(n+1))/(b d(n+1)))

Rule: If  m∈(SuperPlus[ℤ])∧ n≠-1, then

∫(((e+f x))^m)Sech[c+d x]Tanh[c+d x](((a+b Sech[c+d x]))^n)dx  ⟶  -(((((e+f x))^m)(((a+b Sech[c+d x]))^(n+1)))/(b d (n+1)))+((f m)/(b d (n+1)))∫(((e+f x))^(m-1))(((a+b Sech[c+d x]))^(n+1))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sech[c_.+d_.*x_]*Tanh[c_.+d_.*x_]*(a_+b_.*Sech[c_.+d_.*x_])^n_.,x_Symbol] :=
  -(e+f*x)^m*(a+b*Sech[c+d*x])^(n+1)/(b*d*(n+1)) + 
  f*m/(b*d*(n+1))*Int[(e+f*x)^(m-1)*(a+b*Sech[c+d*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,n},x] && IGtQ[m,0] && NeQ[n,-1]

Int[(e_.+f_.*x_)^m_.*Csch[c_.+d_.*x_]*Coth[c_.+d_.*x_]*(a_+b_.*Csch[c_.+d_.*x_])^n_.,x_Symbol] :=
  -(e+f*x)^m*(a+b*Csch[c+d*x])^(n+1)/(b*d*(n+1)) + 
  f*m/(b*d*(n+1))*Int[(e+f*x)^(m-1)*(a+b*Csch[c+d*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,n},x] && IGtQ[m,0] && NeQ[n,-1]

5:  ∫(((e+f x))^m)((Sinh[a+b x])^p) ((Sinh[c+d x])^q)dx  when p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Algebraic expansion

Rule: If p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])∧ m∈ℤ, then

∫(((e+f x))^m)((Sinh[a+b x])^p) ((Cosh[c+d x])^q)dx  ⟶  ∫(((e+f x))^m)TrigReduce[((Sinh[a+b x])^p) ((Cosh[c+d x])^q)]dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sinh[a_.+b_.*x_]^p_.*Sinh[c_.+d_.*x_]^q_.,x_Symbol] :=
  Int[ExpandTrigReduce[(e+f*x)^m,Sinh[a+b*x]^p*Sinh[c+d*x]^q,x],x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && IGtQ[q,0] && IntegerQ[m]

Int[(e_.+f_.*x_)^m_.*Cosh[a_.+b_.*x_]^p_.*Cosh[c_.+d_.*x_]^q_.,x_Symbol] :=
  Int[ExpandTrigReduce[(e+f*x)^m,Cosh[a+b*x]^p*Cosh[c+d*x]^q,x],x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && IGtQ[q,0] && IntegerQ[m]

6:  ∫(((e+f x))^m)((Sinh[a+b x])^p) ((Cosh[c+d x])^q)dx  when p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ]), then

∫(((e+f x))^m)((Sinh[a+b x])^p) ((Cosh[c+d x])^q)dx  ⟶  ∫(((e+f x))^m)TrigReduce[((Sinh[a+b x])^p) ((Cosh[c+d x])^q)]dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sinh[a_.+b_.*x_]^p_.*Cosh[c_.+d_.*x_]^q_.,x_Symbol] :=
  Int[ExpandTrigReduce[(e+f*x)^m,Sinh[a+b*x]^p*Cosh[c+d*x]^q,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[p,0] && IGtQ[q,0]

7:  ∫(((e+f x))^m)((Sinh[a+b x])^p) ((Sech[c+d x])^q)dx  when p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])∧ b c-a d==0 ∧ (b/d)-1∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])∧ b c-a d==0 ∧ (b/d)-1∈(SuperPlus[ℤ]), then

∫(((e+f x))^m)((Sinh[a+b x])^p) ((Sech[c+d x])^q)dx  ⟶  ∫(((e+f x))^m)TrigExpand[((Sinh[a+b x])^p) ((Cosh[c+d x])^q)]dx

Program code:

Int[(e_.+f_.*x_)^m_.*F_[a_.+b_.*x_]^p_.*G_[c_.+d_.*x_]^q_.,x_Symbol] :=
  Int[ExpandTrigExpand[(e+f*x)^m*G[c+d*x]^q,F,c+d*x,p,b/d,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && MemberQ[{Sinh,Cosh},F] && MemberQ[{Sech,Csch},G] && IGtQ[p,0] && IGtQ[q,0] && EqQ[b*c-a*d,0] && IGtQ[b/d,1]