Rules for integrands of the form(F^(c(a+b x)))((Hyper[d+e x])^n)

1.  ∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx

1.  ∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  when  (e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)≠0 ∧ n>0

1:  ∫(F^(c(a+b x))) Sinh[d+e x]dx  when  (e^2)-(b^2) (c^2) ((Log[F])^2)≠0

Reference: CRC 533h

Reference: CRC 538h

Rule: If  (e^2)-(b^2) (c^2) ((Log[F])^2)≠0, then

∫(F^(c(a+b x))) Sinh[d+e x]dx  ⟶  -((b c Log[F](F^(c(a+b x)))Sinh[d+e x])/((e^2)-(b^2) (c^2) ((Log[F])^2)))+((e (F^(c(a+b x))) Cosh[d+e x])/((e^2)-(b^2) (c^2) ((Log[F])^2)))

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_],x_Symbol] :=
  -b*c*Log[F]*F^(c*(a+b*x))*Sinh[d+e*x]/(e^2-b^2*c^2*Log[F]^2) + 
  e*F^(c*(a+b*x))*Cosh[d+e*x]/(e^2-b^2*c^2*Log[F]^2) /;
FreeQ[{F,a,b,c,d,e},x] && NeQ[e^2-b^2*c^2*Log[F]^2,0]

Int[F_^(c_.*(a_.+b_.*x_))*Cosh[d_.+e_.*x_],x_Symbol] :=
  -b*c*Log[F]*F^(c*(a+b*x))*Cosh[d+e*x]/(e^2-b^2*c^2*Log[F]^2) + 
  e*F^(c*(a+b*x))*Sinh[d+e*x]/(e^2-b^2*c^2*Log[F]^2) /;
FreeQ[{F,a,b,c,d,e},x] && NeQ[e^2-b^2*c^2*Log[F]^2,0]

2:  ∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  when  (e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)≠0 ∧ n>1

Reference: CRC 542h

Reference: CRC 543h

Rule: If  (e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)≠0 ∧ n>1, then

∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  ⟶  
-((b c Log[F](F^(c(a+b x)))((Sinh[d+e x])^n))/((e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)))+((e n (F^(c(a+b x))) Cosh[d+e x] ((Sinh[d+e x])^(n-1)))/((e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)))-((n (n-1) (e^2))/((e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)))∫(F^(c(a+b x))) ((Sinh[d+e x])^(n-2))dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_]^n_,x_Symbol] :=
  -b*c*Log[F]*F^(c*(a+b*x))*Sinh[d+e*x]^n/(e^2*n^2-b^2*c^2*Log[F]^2) + 
  e*n*F^(c*(a+b*x))*Cosh[d+e*x]*Sinh[d+e*x]^(n-1)/(e^2*n^2-b^2*c^2*Log[F]^2) - 
  n*(n-1)*e^2/(e^2*n^2-b^2*c^2*Log[F]^2)*Int[F^(c*(a+b*x))*Sinh[d+e*x]^(n-2),x] /;
FreeQ[{F,a,b,c,d,e},x] && NeQ[e^2*n^2-b^2*c^2*Log[F]^2,0] && GtQ[n,1]

Int[F_^(c_.*(a_.+b_.*x_))*Cosh[d_.+e_.*x_]^n_,x_Symbol] :=
  -b*c*Log[F]*F^(c*(a+b*x))*Cosh[d+e*x]^n/(e^2*n^2-b^2*c^2*Log[F]^2) + 
  e*n*F^(c*(a+b*x))*Sinh[d+e*x]*Cosh[d+e*x]^(n-1)/(e^2*n^2-b^2*c^2*Log[F]^2) + 
  n*(n-1)*e^2/(e^2*n^2-b^2*c^2*Log[F]^2)*Int[F^(c*(a+b*x))*Cosh[d+e*x]^(n-2),x] /;
FreeQ[{F,a,b,c,d,e},x] && NeQ[e^2*n^2-b^2*c^2*Log[F]^2,0] && GtQ[n,1]

2:  ∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  when  (e^2) (((n+2))^2)-(b^2)(c^2)((Log[F])^2)==0 ∧ n≠-1 ∧ n≠-2

Reference: CRC 551h when (e^2)(((n+2))^2)-(b^2)(c^2)((Log[F])^2)==0

Reference: CRC 552h when (e^2)(((n+2))^2)-(b^2)(c^2)((Log[F])^2)==0

Rule: If  (e^2) (((n+2))^2)-(b^2)(c^2)((Log[F])^2)==0 ∧ n≠-1 ∧ n≠-2, then

∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  ⟶  -((b c Log[F](F^(c(a+b x))) ((Sinh[d+e x])^(n+2)))/((e^2)(n+1) (n+2)))+(((F^(c(a+b x)))Cosh[d+e x]((Sinh[d+e x])^(n+1)))/(e (n+1)))

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_]^n_,x_Symbol] :=
  -b*c*Log[F]*F^(c*(a+b*x))*Sinh[d+e*x]^(n+2)/(e^2*(n+1)*(n+2)) + 
  F^(c*(a+b*x))*Cosh[d+e*x]*Sinh[d+e*x]^(n+1)/(e*(n+1)) /;
FreeQ[{F,a,b,c,d,e,n},x] && EqQ[e^2*(n+2)^2-b^2*c^2*Log[F]^2,0] && NeQ[n,-1] && NeQ[n,-2]

Int[F_^(c_.*(a_.+b_.*x_))*Cosh[d_.+e_.*x_]^n_,x_Symbol] :=
  b*c*Log[F]*F^(c*(a+b*x))*Cosh[d+e*x]^(n+2)/(e^2*(n+1)*(n+2)) - 
  F^(c*(a+b*x))*Sinh[d+e*x]*Cosh[d+e*x]^(n+1)/(e*(n+1)) /;
FreeQ[{F,a,b,c,d,e,n},x] && EqQ[e^2*(n+2)^2-b^2*c^2*Log[F]^2,0] && NeQ[n,-1] && NeQ[n,-2]

3:  ∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  when  (e^2) (((n+2))^2)-(b^2)(c^2)((Log[F])^2)≠0 ∧ n<-1 ∧ n≠-2

Reference: CRC 551h, CRC 542h inverted

Reference: CRC 552h, CRC 543h inverted

Rule: If  (e^2) (((n+2))^2)-(b^2)(c^2)((Log[F])^2)≠0 ∧ n<-1 ∧ n≠-2, then

∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  ⟶  
-((b c Log[F](F^(c(a+b x))) ((Sinh[d+e x])^(n+2)))/((e^2)(n+1) (n+2)))+(((F^(c(a+b x)))Cosh[d+e x]((Sinh[d+e x])^(n+1)))/(e (n+1)))-(((e^2)(((n+2))^2)-(b^2)(c^2)((Log[F])^2))/((e^2)(n+1) (n+2)))∫(F^(c(a+b x))) ((Sinh[d+e x])^(n+2))dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_]^n_,x_Symbol] :=
  -b*c*Log[F]*F^(c*(a+b*x))*Sinh[d+e*x]^(n+2)/(e^2*(n+1)*(n+2)) + 
  F^(c*(a+b*x))*Cosh[d+e*x]*Sinh[d+e*x]^(n+1)/(e*(n+1)) - 
  (e^2*(n+2)^2-b^2*c^2*Log[F]^2)/(e^2*(n+1)*(n+2))*Int[F^(c*(a+b*x))*Sinh[d+e*x]^(n+2),x] /;
FreeQ[{F,a,b,c,d,e},x] && NeQ[e^2*(n+2)^2-b^2*c^2*Log[F]^2,0] && LtQ[n,-1] && NeQ[n,-2]

Int[F_^(c_.*(a_.+b_.*x_))*Cosh[d_.+e_.*x_]^n_,x_Symbol] :=
  b*c*Log[F]*F^(c*(a+b*x))*Cosh[d+e*x]^(n+2)/(e^2*(n+1)*(n+2)) - 
  F^(c*(a+b*x))*Sinh[d+e*x]*Cosh[d+e*x]^(n+1)/(e*(n+1)) + 
  (e^2*(n+2)^2-b^2*c^2*Log[F]^2)/(e^2*(n+1)*(n+2))*Int[F^(c*(a+b*x))*Cosh[d+e*x]^(n+2),x] /;
FreeQ[{F,a,b,c,d,e},x] && NeQ[e^2*(n+2)^2-b^2*c^2*Log[F]^2,0] && LtQ[n,-1] && NeQ[n,-2]

4:  ∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  when  n∉ℤ

Derivation: Piecewise constant extraction

Basis: Sinh[z]==(1/2) (e^(-z)) (-1+(e^(2 z)))

Basis: (∂_x)(((e^(n (d+e x))) ((Sinh[d+e x])^n))/(((-1+(e^(2 (d+e x)))))^n))==0

Rule: If  n∉ℤ, then

∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  ⟶  (((e^(n (d+e x))) ((Sinh[d+e x])^n))/(((-1+(e^(2 (d+e x)))))^n))∫(F^(c(a+b x))) ((((-1+(e^(2 (d+e x)))))^n)/(e^(n (d+e x))))dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_]^n_,x_Symbol] :=
  E^(n*(d+e*x))*Sinh[d+e*x]^n/(-1+E^(2*(d+e*x)))^n*Int[F^(c*(a+b*x))*(-1+E^(2*(d+e*x)))^n/E^(n*(d+e*x)),x] /;
FreeQ[{F,a,b,c,d,e,n},x] && Not[IntegerQ[n]]

Int[F_^(c_.*(a_.+b_.*x_))*Cosh[d_.+e_.*x_]^n_,x_Symbol] :=
  E^(n*(d+e*x))*Cosh[d+e*x]^n/(1+E^(2*(d+e*x)))^n*Int[F^(c*(a+b*x))*(1+E^(2*(d+e*x)))^n/E^(n*(d+e*x)),x] /;
FreeQ[{F,a,b,c,d,e,n},x] && Not[IntegerQ[n]]

2:  ∫(F^(c(a+b x))) ((Tanh[d+e x])^n)dx  when  n∈ℤ

Derivation: Algebraic expansion

Basis: Tanh[z]==((-1+(e^(2 z)))/(1+(e^(2 z))))

Rule: If  n∈ℤ, then

∫(F^(c(a+b x))) ((Tanh[d+e x])^n)dx  ⟶  ∫(F^(c(a+b x)))((((-1+(e^(2 (d+e x)))))^n)/(((1+(e^(2 (d+e x)))))^n))dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Tanh[d_.+e_.*x_]^n_.,x_Symbol] :=
  Int[ExpandIntegrand[F^(c*(a+b*x))*(-1+E^(2*(d+e*x)))^n/(1+E^(2*(d+e*x)))^n,x],x] /;
FreeQ[{F,a,b,c,d,e},x] && IntegerQ[n]

Int[F_^(c_.*(a_.+b_.*x_))*Coth[d_.+e_.*x_]^n_.,x_Symbol] :=
  Int[ExpandIntegrand[F^(c*(a+b*x))*(1+E^(2*(d+e*x)))^n/(-1+E^(2*(d+e*x)))^n,x],x] /;
FreeQ[{F,a,b,c,d,e},x] && IntegerQ[n]

3.  ∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx

1:  ∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  when  (e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)≠0 ∧ n<-1

Reference: CRC 552h inverted

Reference: CRC 551h inverted

Rule: If  (e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)≠0 ∧ n<-1, then

∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  ⟶  
-((b c Log[F](F^(c(a+b x))) ((Sech[d+e x])^n))/((e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)))-((e n (F^(c(a+b x))) ((Sech[d+e x])^(n+1)) Sinh[d+e x])/((e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)))+(((e^2) n(n+1))/((e^2) (n^2)-(b^2) (c^2) ((Log[F])^2)))∫(F^(c(a+b x))) ((Sech[d+e x])^(n+2))dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sech[d_.+e_.*x_]^n_,x_Symbol] :=
  -b*c*Log[F]*F^(c*(a+b*x))*(Sech[d+e*x]^n/(e^2*n^2-b^2*c^2*Log[F]^2)) - 
  e*n*F^(c*(a+b*x))*Sech[d+e*x]^(n+1)*(Sinh[d+e*x]/(e^2*n^2-b^2*c^2*Log[F]^2)) + 
  e^2*n*((n+1)/(e^2*n^2-b^2*c^2*Log[F]^2))*Int[F^(c*(a+b*x))*Sech[d+e*x]^(n+2),x] /;
FreeQ[{F,a,b,c,d,e},x] && NeQ[e^2*n^2+b^2*c^2*Log[F]^2,0] && LtQ[n,-1]

Int[F_^(c_.*(a_.+b_.*x_))*Csch[d_.+e_.*x_]^n_,x_Symbol] :=
  -b*c*Log[F]*F^(c*(a+b*x))*(Csch[d+e*x]^n/(e^2*n^2-b^2*c^2*Log[F]^2)) - 
  e*n*F^(c*(a+b*x))*Csch[d+e*x]^(n+1)*(Cosh[d+e*x]/(e^2*n^2-b^2*c^2*Log[F]^2)) - 
  e^2*n*((n+1)/(e^2*n^2-b^2*c^2*Log[F]^2))*Int[F^(c*(a+b*x))*Csch[d+e*x]^(n+2),x] /;
FreeQ[{F,a,b,c,d,e},x] && NeQ[e^2*n^2+b^2*c^2*Log[F]^2,0] && LtQ[n,-1]

2:  ∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  when  (e^2) (((n-2))^2)-(b^2)(c^2)((Log[F])^2)==0 ∧ n≠1 ∧ n≠2

Reference: CRC 552h with  (e^2) (((n-2))^2)-(b^2)(c^2)((Log[F])^2)==0

Reference: CRC 551h with  (e^2) (((n-2))^2)-(b^2)(c^2)((Log[F])^2)==0

Rule: If  (e^2) (((n-2))^2)-(b^2)(c^2)((Log[F])^2)==0 ∧ n≠1 ∧ n≠2, then

∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  ⟶  ((b c Log[F](F^(c(a+b x))) ((Sech[d+e x])^(n-2)))/((e^2) (n-1) (n-2)))+(((F^(c(a+b x))) ((Sech[d+e x])^(n-1)) Sinh[d+e x])/(e (n-1)))

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sech[d_.+e_.*x_]^n_,x_Symbol] :=
  b*c*Log[F]*F^(c*(a+b*x))*Sech[d+e*x]^(n-2)/(e^2*(n-1)*(n-2)) + 
  F^(c*(a+b*x))*Sech[d+e*x]^(n-1)*Sinh[d+e*x]/(e*(n-1)) /;
FreeQ[{F,a,b,c,d,e,n},x] && EqQ[e^2*(n-2)^2-b^2*c^2*Log[F]^2,0] && NeQ[n,1] && NeQ[n,2]

Int[F_^(c_.*(a_.+b_.*x_))*Csch[d_.+e_.*x_]^n_,x_Symbol] :=
  -b*c*Log[F]*F^(c*(a+b*x))*Csch[d+e*x]^(n-2)/(e^2*(n-1)*(n-2)) - 
  F^(c*(a+b*x))*Csch[d+e*x]^(n-1)*Cosh[d+e*x]/(e*(n-1)) /;
FreeQ[{F,a,b,c,d,e,n},x] && EqQ[e^2*(n-2)^2-b^2*c^2*Log[F]^2,0] && NeQ[n,1] && NeQ[n,2]

3:  ∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  when  (e^2) (((n-2))^2)-(b^2)(c^2)((Log[F])^2)≠0 ∧ n>1 ∧ n≠2

Reference: CRC 552h

Reference: CRC 551h

Rule: If  (e^2) (((n-2))^2)-(b^2)(c^2)((Log[F])^2)≠0 ∧ n>1 ∧ n≠2, then

∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  ⟶  
((b c Log[F](F^(c(a+b x))) ((Sech[d+e x])^(n-2)))/((e^2) (n-1) (n-2)))+(((F^(c(a+b x))) ((Sech[d+e x])^(n-1)) Sinh[d+e x])/(e (n-1)))+(((e^2) (((n-2))^2)-(b^2)(c^2)((Log[F])^2))/((e^2) (n-1) (n-2)))∫(F^(c(a+b x))) ((Sech[d+e x])^(n-2))dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sech[d_.+e_.*x_]^n_,x_Symbol] :=
  b*c*Log[F]*F^(c*(a+b*x))*Sech[d+e*x]^(n-2)/(e^2*(n-1)*(n-2)) + 
  F^(c*(a+b*x))*Sech[d+e*x]^(n-1)*Sinh[d+e*x]/(e*(n-1)) +
  (e^2*(n-2)^2-b^2*c^2*Log[F]^2)/(e^2*(n-1)*(n-2))*Int[F^(c*(a+b*x))*Sech[d+e*x]^(n-2),x] /;
FreeQ[{F,a,b,c,d,e},x] && NeQ[e^2*(n-2)^2-b^2*c^2*Log[F]^2,0] && GtQ[n,1] && NeQ[n,2]

Int[F_^(c_.*(a_.+b_.*x_))*Csch[d_.+e_.*x_]^n_,x_Symbol] :=
  -b*c*Log[F]*F^(c*(a+b*x))*Csch[d+e*x]^(n-2)/(e^2*(n-1)*(n-2)) - 
  F^(c*(a+b*x))*Csch[d+e*x]^(n-1)*Cosh[d+e*x]/(e*(n-1)) -
  (e^2*(n-2)^2-b^2*c^2*Log[F]^2)/(e^2*(n-1)*(n-2))*Int[F^(c*(a+b*x))*Csch[d+e*x]^(n-2),x] /;
FreeQ[{F,a,b,c,d,e},x] && NeQ[e^2*(n-2)^2-b^2*c^2*Log[F]^2,0] && GtQ[n,1] && NeQ[n,2]

x:  ∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  when  n∈ℤ

Derivation: Algebraic expansion

Basis: Sech[z]==((2 (e^z))/(1+(e^(2z))))

Basis: Csch[z]==((2 (e^(-z)))/(1-(e^(-2z))))

Rule: If  n∈ℤ, then

∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  ⟶  (2^n)∫(F^(c(a+b x)))((e^(n(d+e x)))/(((1+(e^(2(d+e x)))))^n))dx

Program code:

(* Int[F_^(c_.*(a_.+b_.*x_))*Sech[d_.+e_.*x_]^n_.,x_Symbol] :=
  2^n*Int[SimplifyIntegrand[F^(c*(a+b*x))*E^(n*(d+e*x))/(1+E^(2*(d+e*x)))^n,x],x] /;
FreeQ[{F,a,b,c,d,e},x] && IntegerQ[n] *)

(* Int[F_^(c_.*(a_.+b_.*x_))*Csch[d_.+e_.*x_]^n_.,x_Symbol] :=
  2^n*Int[SimplifyIntegrand[F^(c*(a+b*x))*E^(-n*(d+e*x))/(1-E^(-2*(d+e*x)))^n,x],x] /;
FreeQ[{F,a,b,c,d,e},x] && IntegerQ[n] *)

4:  ∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  when  n∈ℤ

Rule: If  n∈ℤ, then

∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  ⟶  (((2^n) (e^(n (d+e x))) (F^(c (a+b x))))/(e n+b c Log[F]))Hypergeometric2F1[n,(n/2)+((b c Log[F])/(2 e)),1+(n/2)+((b c Log[F])/(2 e)),-(e^(2 (d+e x)))]

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sech[d_.+e_.*x_]^n_.,x_Symbol] :=
  2^n*E^(n*(d+e*x))*F^(c*(a+b*x))/(e*n+b*c*Log[F])*Hypergeometric2F1[n,n/2+b*c*Log[F]/(2*e),1+n/2+b*c*Log[F]/(2*e),-E^(2*(d+e*x))] /;
FreeQ[{F,a,b,c,d,e},x] && IntegerQ[n]

Int[F_^(c_.*(a_.+b_.*x_))*Csch[d_.+e_.*x_]^n_.,x_Symbol] :=
  (-2)^n*E^(n*(d+e*x))*F^(c*(a+b*x))/(e*n+b*c*Log[F])*Hypergeometric2F1[n,n/2+b*c*Log[F]/(2*e),1+n/2+b*c*Log[F]/(2*e),E^(2*(d+e*x))] /;
FreeQ[{F,a,b,c,d,e},x] && IntegerQ[n]

5:  ∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  when  n∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((((1+(e^(2 (d+e x)))))^n) ((Sech[d+e x])^n))/(e^(n (d+e x))))==0

Rule: If  n∉ℤ, then

∫(F^(c(a+b x))) ((Sech[d+e x])^n)dx  ⟶  (((((1+(e^(2 (d+e x)))))^n) ((Sech[d+e x])^n))/(e^(n (d+e x))))∫(F^(c(a+b x)))((e^(n(d+e x)))/(((1+(e^(2(d+e x)))))^n))dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sech[d_.+e_.*x_]^n_.,x_Symbol] :=
  (1+E^(2*(d+e*x)))^n*Sech[d+e*x]^n/E^(n*(d+e*x))*Int[SimplifyIntegrand[F^(c*(a+b*x))*E^(n*(d+e*x))/(1+E^(2*(d+e*x)))^n,x],x] /;
FreeQ[{F,a,b,c,d,e},x] && Not[IntegerQ[n]]

Int[F_^(c_.*(a_.+b_.*x_))*Csch[d_.+e_.*x_]^n_.,x_Symbol] :=
  (1-E^(-2*(d+e*x)))^n*Csch[d+e*x]^n/E^(-n*(d+e*x))*Int[SimplifyIntegrand[F^(c*(a+b*x))*E^(-n*(d+e*x))/(1-E^(-2*(d+e*x)))^n,x],x] /;
FreeQ[{F,a,b,c,d,e},x] && Not[IntegerQ[n]]

4.  ∫u (F^(c(a+b x))) (((f+g Sinh[d+e x]))^n)dx  when  (f^2)+(g^2)==0

1.  ∫(F^(c(a+b x))) (((f+g Sinh[d+e x]))^n)dx  when  (f^2)+(g^2)==0

1:  ∫(F^(c(a+b x)))(((f+g Sinh[d+e x]))^n)dx  when  (f^2)+(g^2)==0 ∧ n∈ℤ

Derivation: Algebraic simplification

Basis: If  (f^2)+(g^2)==0, then f+g Sinh[z]==2 f ((Cosh[(z/2)-((f π)/(4 g))])^2)

Basis: If  f-g==0, then f+g Cosh[z]==2 g ((Cosh[(z/2)])^2)

Basis: If  f+g==0, then f+g Cosh[z]==2 g ((Sinh[(z/2)])^2)

Rule: If  (f^2)+(g^2)==0 ∧ n∈ℤ, then

∫(F^(c(a+b x)))(((f+g Sinh[d+e x]))^n)dx  ⟶  (2^n)(f^n)∫(F^(c(a+b x))) ((Cosh[(d/2)-((f π)/(4 g))+((e x)/2)])^(2n))dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*(f_+g_.*Sinh[d_.+e_.*x_])^n_.,x_Symbol] :=
  2^n*f^n*Int[F^(c*(a+b*x))*Cosh[d/2-f*Pi/(4*g)+e*x/2]^(2*n),x] /;
FreeQ[{F,a,b,c,d,e,f,g},x] && EqQ[f^2+g^2,0] && ILtQ[n,0]

Int[F_^(c_.*(a_.+b_.*x_))*(f_+g_.*Cosh[d_.+e_.*x_])^n_.,x_Symbol] :=
  2^n*g^n*Int[F^(c*(a+b*x))*Cosh[d/2+e*x/2]^(2*n),x] /;
FreeQ[{F,a,b,c,d,e,f,g},x] && EqQ[f-g,0] && ILtQ[n,0]

Int[F_^(c_.*(a_.+b_.*x_))*(f_+g_.*Cosh[d_.+e_.*x_])^n_.,x_Symbol] :=
  2^n*g^n*Int[F^(c*(a+b*x))*Sinh[d/2+e*x/2]^(2*n),x] /;
FreeQ[{F,a,b,c,d,e,f,g},x] && EqQ[f+g,0] && ILtQ[n,0]

2:  ∫(F^(c(a+b x)))(((f+g Sinh[d+e x]))^n)dx  when  (f^2)+(g^2)==0 ∧ n∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (f^2)+(g^2)==0, then (∂_x)((((f+g Sinh[d+e x]))^n)/((Cosh[(d/2)-((f π)/(4 g))+((e x)/2)])^(2 n)))==0

Basis: If  f-g==0, then (∂_x)((((f+g Cosh[d+e x]))^n)/((Cosh[(d/2)+((e x)/2)])^(2 n)))==0

Basis: If  f+g==0, then (∂_x)((((f+g Cosh[d+e x]))^n)/((Sinh[(d/2)+((e x)/2)])^(2 n)))==0

Rule: If  (f^2)+(g^2)==0 ∧ n∉ℤ, then

∫(F^(c(a+b x)))(((f+g Sinh[d+e x]))^n)dx  ⟶  ((((f+g Sinh[d+e x]))^n)/((Cosh[(d/2)-((f π)/(4 g))+((e x)/2)])^(2 n))) ∫(F^(c(a+b x))) ((Cosh[(d/2)-((f π)/(4 g))+((e x)/2)])^(2n))dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*(f_+g_.*Sinh[d_.+e_.*x_])^n_.,x_Symbol] :=
  (f+g*Sinh[d+e*x])^n/Cosh[d/2-f*Pi/(4*g)+e*x/2]^(2*n)*Int[F^(c*(a+b*x))*Cosh[d/2-f*Pi/(4*g)+e*x/2]^(2*n),x] /;
FreeQ[{F,a,b,c,d,e,f,g,n},x] && EqQ[f^2+g^2,0] && Not[IntegerQ[n]]

Int[F_^(c_.*(a_.+b_.*x_))*(f_+g_.*Cosh[d_.+e_.*x_])^n_.,x_Symbol] :=
  (f+g*Cosh[d+e*x])^n/Cosh[d/2+e*x/2]^(2*n)*Int[F^(c*(a+b*x))*Cosh[d/2+e*x/2]^(2*n),x] /;
FreeQ[{F,a,b,c,d,e,f,g,n},x] && EqQ[f-g,0] && Not[IntegerQ[n]]

Int[F_^(c_.*(a_.+b_.*x_))*(f_+g_.*Cosh[d_.+e_.*x_])^n_.,x_Symbol] :=
  (f+g*Cosh[d+e*x])^n/Sinh[d/2+e*x/2]^(2*n)*Int[F^(c*(a+b*x))*Sinh[d/2+e*x/2]^(2*n),x] /;
FreeQ[{F,a,b,c,d,e,f,g,n},x] && EqQ[f+g,0] && Not[IntegerQ[n]]

2:  ∫(F^(c(a+b x))) ((Cosh[d+e x])^m)(((f+g Sinh[d+e x]))^n)dx  when  (f^2)+(g^2)==0 ∧ (m|n)∈ℤ ∧ m+n==0

Derivation: Algebraic simplification

Basis: If  (f^2)+(g^2)==0, then ((Cosh[z])/(f+g Sinh[z]))==(1/g)Tanh[(z/2)-((f π)/(4 g))]

Basis: If  f-g==0, then ((Sinh[z])/(f+g Cosh[z]))==(1/g)Tanh[(z/2)]

Basis: If  f+g==0, then ((Sinh[z])/(f+g Cosh[z]))==(1/g)Coth[(z/2)]

Rule: If  (f^2)+(g^2)==0 ∧ (m|n)∈ℤ ∧ m+n==0, then

∫(F^(c(a+b x))) ((Cosh[d+e x])^m)(((f+g Sinh[d+e x]))^n)dx  ⟶  (g^n)∫(F^(c(a+b x))) ((Tanh[(d/2)+((e x)/2)-((f π)/(4 g))])^m)dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Cosh[d_.+e_.*x_]^m_.*(f_+g_.*Sinh[d_.+e_.*x_])^n_.,x_Symbol] :=
  g^n*Int[F^(c*(a+b*x))*Tanh[d/2+e*x/2-f*Pi/(4*g)]^m,x] /;
FreeQ[{F,a,b,c,d,e,f,g},x] && EqQ[f^2+g^2,0] && IntegersQ[m,n] && EqQ[m+n,0]

Int[F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_]^m_.*(f_+g_.*Cosh[d_.+e_.*x_])^n_.,x_Symbol] :=
  g^n*Int[F^(c*(a+b*x))*Tanh[d/2+e*x/2]^m,x] /;
FreeQ[{F,a,b,c,d,e,f,g},x] && EqQ[f-g,0] && IntegersQ[m,n] && EqQ[m+n,0]

Int[F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_]^m_.*(f_+g_.*Cosh[d_.+e_.*x_])^n_.,x_Symbol] :=
  g^n*Int[F^(c*(a+b*x))*Coth[d/2+e*x/2]^m,x] /;
FreeQ[{F,a,b,c,d,e,f,g},x] && EqQ[f+g,0] && IntegersQ[m,n] && EqQ[m+n,0]

3:  ∫(F^(c(a+b x))) ((h+i Cosh[d+e x])/(f+g Sinh[d+e x]))dx  when  (f^2)+(g^2)==0 ∧ (h^2)-(i^2)==0 ∧ g h+f i==0

Derivation: Algebraic simplification

Basis: ((h+i Cos[z])/(f+g Sin[z]))==((2i Cos[z])/(f+g Sin[z]))+((h-i Cos[z])/(f+g Sin[z]))

Rule: If  (f^2)+(g^2)==0 ∧ (h^2)-(i^2)==0 ∧ g h+f i==0, then

∫(F^(c(a+b x))) ((h+i Cosh[d+e x])/(f+g Sinh[d+e x]))dx  ⟶  2 i∫(F^(c(a+b x))) ((Cosh[d+e x])/(f+g Sinh[d+e x]))dx+∫(F^(c(a+b x))) ((h-i Cosh[d+e x])/(f+g Sinh[d+e x]))dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*(h_+i_.*Cosh[d_.+e_.*x_])/(f_+g_.*Sinh[d_.+e_.*x_]),x_Symbol] :=
  2*i*Int[F^(c*(a+b*x))*(Cosh[d+e*x]/(f+g*Sinh[d+e*x])),x] + 
  Int[F^(c*(a+b*x))*((h-i*Cosh[d+e*x])/(f+g*Sinh[d+e*x])),x] /;
FreeQ[{F,a,b,c,d,e,f,g,h,i},x] && EqQ[f^2+g^2,0] && EqQ[h^2-i^2,0] && EqQ[g*h-f*i,0]

Int[F_^(c_.*(a_.+b_.*x_))*(h_+i_.*Sinh[d_.+e_.*x_])/(f_+g_.*Cosh[d_.+e_.*x_]),x_Symbol] :=
  2*i*Int[F^(c*(a+b*x))*(Sinh[d+e*x]/(f+g*Cosh[d+e*x])),x] + 
  Int[F^(c*(a+b*x))*((h-i*Sinh[d+e*x])/(f+g*Cosh[d+e*x])),x] /;
FreeQ[{F,a,b,c,d,e,f,g,h,i},x] && EqQ[f^2-g^2,0] && EqQ[h^2+i^2,0] && EqQ[g*h+f*i,0]

5:  ∫(F^(c u))((Hyper[v])^n)dx  when  u==a+b x ∧ v==d+e x

Derivation: Algebraic normalization

Rule: If  u==a+b x ∧ v==d+e x, then

∫(F^(c u))((Hyper[v])^n)dx  ⟶  ∫(F^(c(a+b x))) ((Hyper[d+e x])^n)dx

Program code:

Int[F_^(c_.*u_)*G_[v_]^n_.,x_Symbol] :=
  Int[F^(c*ExpandToSum[u,x])*G[ExpandToSum[v,x]]^n,x] /;
FreeQ[{F,c,n},x] && HyperbolicQ[G] && LinearQ[{u,v},x] && Not[LinearMatchQ[{u,v},x]]

6.  ∫(((f x))^m)(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫(((f x))^m)(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  when  n∈(SuperPlus[ℤ])∧ m>0

Derivation: Integration by parts

Note: Each term of the resulting integrand will be similar in form to the original integrand, but the degree of the monomial will be smaller by one.

Rule: If  n∈(SuperPlus[ℤ])∧ m>0, let  u=∫(F^(c(a+b x))) ((Sinh[d+e x])^n)dx, then

∫(((f x))^m)(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  ⟶  (((f x))^m)u-f m ∫(((f x))^(m-1)) udx

Program code:

Int[(f_.*x_)^m_.*F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_]^n_.,x_Symbol] :=
  Module[{u=IntHide[F^(c*(a+b*x))*Sinh[d+e*x]^n,x]},
  Dist[(f*x)^m,u,x] - f*m*Int[(f*x)^(m-1)*u,x]] /;
FreeQ[{F,a,b,c,d,e,f},x] && IGtQ[n,0] && GtQ[m,0]

Int[(f_.*x_)^m_.*F_^(c_.*(a_.+b_.*x_))*Cosh[d_.+e_.*x_]^n_.,x_Symbol] :=
  Module[{u=IntHide[F^(c*(a+b*x))*Cosh[d+e*x]^n,x]},
  Dist[(f*x)^m,u,x] - f*m*Int[(f*x)^(m-1)*u,x]] /;
FreeQ[{F,a,b,c,d,e,f},x] && IGtQ[n,0] && GtQ[m,0]

2:  ∫(((f x))^m)(F^(c(a+b x))) Sinh[d+e x]dx  when  m<-1

Derivation: Integration by parts

Basis: (((f x))^m)==(∂_x)((((f x))^(m+1))/(f (m+1)))

Basis: (∂_x)((F^(c (a+b x))) Sinh[d+e x])==e (F^(c (a+b x))) Cosh[d+e x]+b c Log[F] (F^(c (a+b x))) Sinh[d+e x]

Rule: If  m<-1, then

∫(((f x))^m)(F^(c(a+b x))) Sinh[d+e x]dx  ⟶  
((((f x))^(m+1))/(f (m+1)))(F^(c(a+b x))) Sinh[d+e x]-(e/(f (m+1))) ∫(((f x))^(m+1))  (F^(c (a+b x))) Cosh[d+e x]dx-((b c Log[F])/(f (m+1))) ∫(((f x))^(m+1))  (F^(c (a+b x))) Sinh[d+e x]dx

Program code:

Int[(f_.*x_)^m_*F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_],x_Symbol] :=
  (f*x)^(m+1)/(f*(m+1))*F^(c*(a+b*x))*Sinh[d+e*x] - 
  e/(f*(m+1))*Int[(f*x)^(m+1)*F^(c*(a+b*x))*Cosh[d+e*x],x] - 
  b*c*Log[F]/(f*(m+1))*Int[(f*x)^(m+1)*F^(c*(a+b*x))*Sinh[d+e*x],x] /;
FreeQ[{F,a,b,c,d,e,f,m},x] && (LtQ[m,-1] || SumSimplerQ[m,1])

Int[(f_.*x_)^m_*F_^(c_.*(a_.+b_.*x_))*Cosh[d_.+e_.*x_],x_Symbol] :=
  (f*x)^(m+1)/(f*(m+1))*F^(c*(a+b*x))*Cosh[d+e*x] - 
  e/(f*(m+1))*Int[(f*x)^(m+1)*F^(c*(a+b*x))*Sinh[d+e*x],x] - 
  b*c*Log[F]/(f*(m+1))*Int[(f*x)^(m+1)*F^(c*(a+b*x))*Cosh[d+e*x],x] /;
FreeQ[{F,a,b,c,d,e,f,m},x] && (LtQ[m,-1] || SumSimplerQ[m,1])

x:  ∫(((f x))^m)(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  when  n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: Sinh[z]==-(1/2) ((e^(-z))-(e^z))

Basis: Cosh[z]==(1/2) ((e^(-z))+(e^z))

Rule: If  n∈(SuperPlus[ℤ]), then

∫(((f x))^m)(F^(c(a+b x))) ((Sinh[d+e x])^n)dx  ⟶  ((((-1))^n)/(2^n)) ∫(((f x))^m)(F^(c(a+b x))) ExpandIntegrand[((((e^(-(d+e x)))-(e^(d+e x))))^n),x]dx

Program code:

(* Int[(f_.*x_)^m_.*F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_]^n_.,x_Symbol] :=
  (-1)^n/2^n*Int[ExpandIntegrand[(f*x)^m*F^(c*(a+b*x)),(E^(-(d+e*x))-E^(d+e*x))^n,x],x] /;
FreeQ[{F,a,b,c,d,e,f},x] && IGtQ[n,0] *)

(* Int[(f_.*x_)^m_.*F_^(c_.*(a_.+b_.*x_))*Cosh[d_.+e_.*x_]^n_.,x_Symbol] :=
  1/2^n*Int[ExpandIntegrand[(f*x)^m*F^(c*(a+b*x)),(E^(-(d+e*x))+E^(d+e*x))^n,x],x] /;
FreeQ[{F,a,b,c,d,e,f},x] && IGtQ[n,0] *)

7.  ∫u (F^(c(a+b x)))((Sinh[d+e x])^m)((Cosh[f+g x])^n)dx

1:  ∫(F^(c(a+b x)))((Sinh[d+e x])^m)((Cosh[f+g x])^n)dx  when m∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  m∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ]), then

∫(F^(c(a+b x)))((Sinh[d+e x])^m)((Cosh[f+g x])^n)dx  ⟶  ∫(F^(c(a+b x)))TrigReduce[((Sinh[d+e x])^m)((Cosh[f+g x])^n)]dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_]^m_.*Cosh[f_.+g_.*x_]^n_.,x_Symbol] :=
  Int[ExpandTrigReduce[F^(c*(a+b*x)),Sinh[d+e*x]^m*Cosh[f+g*x]^n,x],x] /;
FreeQ[{F,a,b,c,d,e,f,g},x] && IGtQ[m,0] && IGtQ[n,0]

2:  ∫(x^p)(F^(c(a+b x)))((Sinh[d+e x])^m)((Cosh[f+g x])^n)dx  when m∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If m∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ]), then

∫(x^p)(F^(c(a+b x)))((Sinh[d+e x])^m)((Cosh[f+g x])^n)dx  ⟶  ∫(x^p)(F^(c(a+b x)))TrigReduce[((Sinh[d+e x])^m)((Cosh[f+g x])^n)]dx

Program code:

Int[x_^p_.*F_^(c_.*(a_.+b_.*x_))*Sinh[d_.+e_.*x_]^m_.*Cosh[f_.+g_.*x_]^n_.,x_Symbol] :=
  Int[ExpandTrigReduce[x^p*F^(c*(a+b*x)),Sinh[d+e*x]^m*Cosh[f+g*x]^n,x],x] /;
FreeQ[{F,a,b,c,d,e,f,g},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

8:  ∫(F^(c(a+b x))) ((Hyper[d+e x])^m)((Hyper[d+e x])^n)dx  when  m∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If m∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ]), then

∫(F^(c(a+b x))) ((Hyper[d+e x])^m)((Hyper[d+e x])^n)dx  ⟶  ∫(F^(c(a+b x))) TrigToExp[((Hyper[d+e x])^m)((Hyper[d+e x])^n),x]dx

Program code:

Int[F_^(c_.*(a_.+b_.*x_))*G_[d_.+e_.*x_]^m_.*H_[d_.+e_.*x_]^n_.,x_Symbol] :=
  Int[ExpandTrigToExp[F^(c*(a+b*x)),G[d+e*x]^m*H[d+e*x]^n,x],x] /;
FreeQ[{F,a,b,c,d,e},x] && IGtQ[m,0] && IGtQ[n,0] && HyperbolicQ[G] && HyperbolicQ[H]

9:  ∫(F^(a+b x+c (x^2))) ((Sinh[d+e x+f (x^2)])^n)dx  when n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ]), then

∫(F^(a+b x+c (x^2))) ((Sinh[d+e x+f (x^2)])^n)dx  ⟶  ∫(F^(a+b x+c (x^2)))TrigToExp[((Sinh[d+e x+f (x^2)])^n)]dx

Program code:

Int[F_^u_*Sinh[v_]^n_.,x_Symbol] :=
  Int[ExpandTrigToExp[F^u,Sinh[v]^n,x],x] /;
FreeQ[F,x] && (LinearQ[u,x] || PolyQ[u,x,2]) && (LinearQ[v,x] || PolyQ[v,x,2]) && IGtQ[n,0]

Int[F_^u_*Cosh[v_]^n_.,x_Symbol] :=
  Int[ExpandTrigToExp[F^u,Cosh[v]^n,x],x] /;
FreeQ[F,x] && (LinearQ[u,x] || PolyQ[u,x,2]) && (LinearQ[v,x] || PolyQ[v,x,2]) && IGtQ[n,0]

10:  ∫(F^(a+b x+c (x^2))) ((Sinh[d+e x+f (x^2)])^m)((Cosh[d+e x+f (x^2)])^n)dx  when (m|n)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If (m|n)∈(SuperPlus[ℤ]), then

∫(F^(a+b x+c (x^2))) ((Sinh[d+e x+f (x^2)])^m)((Cosh[d+e x+f (x^2)])^n)dx  ⟶  ∫(F^(a+b x+c (x^2)))TrigToExp[((Sinh[d+e x+f (x^2)])^m)((Cosh[d+e x+f (x^2)])^n)]dx

Program code:

Int[F_^u_*Sinh[v_]^m_.*Cosh[v_]^n_.,x_Symbol] :=
  Int[ExpandTrigToExp[F^u,Sinh[v]^m*Cosh[v]^n,x],x] /;
FreeQ[F,x] && (LinearQ[u,x] || PolyQ[u,x,2]) && (LinearQ[v,x] || PolyQ[v,x,2]) && IGtQ[m,0] && IGtQ[n,0]