Rules for integrands of the formu ((Hyper[d (a+b Log[c (x^n)])])^p)

1.  ∫u ((Sinh[d (a+b Log[c (x^n)])])^p)dx

1.  ∫((Sinh[d (a+b Log[c (x^n)])])^p)dx

1:  ∫((Sinh[b Log[c (x^n)]])^p)dx

Derivation: Algebraic simplification

Basis: Sinh[b Log[c (x^n)]]=(1/2) (((c (x^n)))^b)-(1/(2 (((c (x^n)))^b)))

Basis: Cosh[b Log[c (x^n)]]=(1/2) (((c (x^n)))^b)+(1/(2 (((c (x^n)))^b)))

Rule:

∫((Sinh[b Log[c (x^n)]])^p)dx  ⟶  ∫(((((((c (x^n)))^b)/2)-(1/(2 (((c (x^n)))^b)))))^p)dx

Program code:

Int[Sinh[b_.*Log[c_.*x_^n_.]]^p_.,x_Symbol] :=
  Int[((c*x^n)^b/2 - 1/(2*(c*x^n)^b))^p,x] /;
FreeQ[c,x] && RationalQ[b,n,p]

Int[Cosh[b_.*Log[c_.*x_^n_.]]^p_.,x_Symbol] :=
  Int[((c*x^n)^b/2 + 1/(2*(c*x^n)^b))^p,x] /;
FreeQ[c,x] && RationalQ[b,n,p]

1.  ∫((Sinh[d (a+b Log[c (x^n)])])^p)dx  when  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)-1≠0

1:  ∫Sinh[d (a+b Log[c (x^n)])]dx  when  (b^2) (d^2) (n^2)-1≠0

Rule: If  (b^2) (d^2) (n^2)-1≠0, then

∫Sinh[d (a+b Log[c (x^n)])]dx  ⟶  -((x Sinh[d (a+b Log[c (x^n)])])/((b^2) (d^2) (n^2)-1))+((b d n x Cosh[d (a+b Log[c (x^n)])])/((b^2) (d^2) (n^2)-1))

Program code:

Int[Sinh[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  -x*Sinh[d*(a+b*Log[c*x^n])]/(b^2*d^2*n^2-1) + 
  b*d*n*x*Cosh[d*(a+b*Log[c*x^n])]/(b^2*d^2*n^2-1) /;
FreeQ[{a,b,c,d,n},x] && NeQ[b^2*d^2*n^2-1,0]

Int[Cosh[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  -x*Cosh[d*(a+b*Log[c*x^n])]/(b^2*d^2*n^2-1) + 
  b*d*n*x*Sinh[d*(a+b*Log[c*x^n])]/(b^2*d^2*n^2-1) /;
FreeQ[{a,b,c,d,n},x] && NeQ[b^2*d^2*n^2-1,0]

2:  ∫((Sinh[d (a+b Log[c (x^n)])])^p)dx  when  p-1∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)-1≠0

Rule: If  p-1∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)-1≠0, then

∫((Sinh[d (a+b Log[c (x^n)])])^p)dx  ⟶  
-((x ((Sinh[d (a+b Log[c (x^n)])])^p))/((b^2) (d^2) (n^2) (p^2)-1))+((b d n p x Cosh[d (a+b Log[c (x^n)])] ((Sinh[d (a+b Log[c (x^n)])])^(p-1)))/((b^2) (d^2) (n^2) (p^2)-1))-(((b^2) (d^2) (n^2) p (p-1))/((b^2) (d^2) (n^2) (p^2)-1))∫((Sinh[d (a+b Log[c (x^n)])])^(p-2))dx

Program code:

Int[Sinh[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_,x_Symbol] :=
  -x*Sinh[d*(a+b*Log[c*x^n])]^p/(b^2*d^2*n^2*p^2-1) +
  b*d*n*p*x*Cosh[d*(a+b*Log[c*x^n])]*Sinh[d*(a+b*Log[c*x^n])]^(p-1)/(b^2*d^2*n^2*p^2-1) -
  b^2*d^2*n^2*p*(p-1)/(b^2*d^2*n^2*p^2-1)*Int[Sinh[d*(a+b*Log[c*x^n])]^(p-2),x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[p,1] && NeQ[b^2*d^2*n^2*p^2-1,0]

Int[Cosh[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_,x_Symbol] :=
  -x*Cosh[d*(a+b*Log[c*x^n])]^p/(b^2*d^2*n^2*p^2-1) +
  b*d*n*p*x*Cosh[d*(a+b*Log[c*x^n])]^(p-1)*Sinh[d*(a+b*Log[c*x^n])]/(b^2*d^2*n^2*p^2-1) +
  b^2*d^2*n^2*p*(p-1)/(b^2*d^2*n^2*p^2-1)*Int[Cosh[d*(a+b*Log[c*x^n])]^(p-2),x] /;
FreeQ[{a,b,c,d,n},x] && IGtQ[p,1] && NeQ[b^2*d^2*n^2*p^2-1,0]

2.  ∫((Sinh[d (a+b Log[x])])^p)dx

1:  ∫((Sinh[d (a+b Log[x])])^p)dx  when  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (p^2)-1==0

Derivation: Algebraic expansion

Basis: If  (b^2) (d^2) (p^2)-1==0 ∧ p∈ℤ, then ((Sinh[d (a+b Log[x])])^p)==(1/((2^p) (b^p) (d^p) (p^p))) (((-(e^(-a b (d^2) p)) (x^(-(1/p)))+(e^(a b (d^2) p)) (x^(1/p))))^p)

Basis: If  (b^2) (d^2) (p^2)-1==0 ∧ p∈ℤ, then ((Cosh[d (a+b Log[x])])^p)==(1/(2^p)) ((((e^(-a b (d^2) p)) (x^(-(1/p)))+(e^(a b (d^2) p)) (x^(1/p))))^p)

Note: The above identities need to be formally derived, and possibly the domain of p expanded.

Rule: If  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (p^2)-1==0, then

∫((Sinh[d (a+b Log[x])])^p)dx  ⟶  (1/((2^p) (b^p) (d^p) (p^p))) ∫ExpandIntegrand[(((-(e^(-a b (d^2) p)) (x^(-(1/p)))+(e^(a b (d^2) p)) (x^(1/p))))^p),x]dx

Program code:

Int[Sinh[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  1/(2^p*b^p*d^p*p^p)*Int[ExpandIntegrand[(-E^(-a*b*d^2*p)*x^(-1/p)+E^(a*b*d^2*p)*x^(1/p))^p,x],x] /;
FreeQ[{a,b,d},x] && IGtQ[p,0] && EqQ[b^2*d^2*p^2-1,0]

Int[Cosh[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  1/2^p*Int[ExpandIntegrand[(E^(-a*b*d^2*p)*x^(-1/p)+E^(a*b*d^2*p)*x^(1/p))^p,x],x] /;
FreeQ[{a,b,d},x] && IGtQ[p,0] && EqQ[b^2*d^2*p^2-1,0]

x:  ∫((Sinh[d (a+b Log[x])])^p)dx  when  p∈ℤ

Derivation: Algebraic expansion

Basis: Sinh[d (a+b Log[x])]==((e^(a d))/2) (x^(b d)) (1-(e^(-2 a d)) (x^(-2 b d)))

Basis: Cosh[d (a+b Log[x])]==((e^(a d))/2) (x^(b d)) (1+(e^(-2 a d)) (x^(-2 b d)))

Rule: If  p∈ℤ, then

∫((Sinh[d (a+b Log[x])])^p)dx  ⟶  ((e^(a d p))/(2^p)) ∫(x^(b d p)) (((1-(e^(-2 a d)) (x^(-2 b d))))^p)dx

Program code:

(* Int[Sinh[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  E^(a*d*p)/2^p*Int[x^(b*d*p)*(1-1/(E^(2*a*d)*x^(2*b*d)))^p,x] /;
FreeQ[{a,b,d},x] && IntegerQ[p] *)

(* Int[Cosh[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  E^(a*d*p)/2^p*Int[x^(b*d*p)*(1+1/(E^(2*a*d)*x^(2*b*d)))^p,x] /;
FreeQ[{a,b,d},x] && IntegerQ[p] *)

2:  ∫((Sinh[d (a+b Log[x])])^p)dx  when  p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sinh[d (a+b Log[x])])^p)/((x^(b d p)) (((1-(e^(-2 a d)) (x^(-2 b d))))^p)))==0

Basis: (∂_x)(((Cosh[d (a+b Log[x])])^p)/((x^(b d p)) (((1+(e^(-2 a d)) (x^(-2 b d))))^p)))==0

Rule: If  p∉ℤ, then

∫((Sinh[d (a+b Log[x])])^p)dx  ⟶  (((Sinh[d (a+b Log[x])])^p)/((x^(b d p)) (((1-(e^(-2 a d)) (x^(-2 b d))))^p))) ∫(x^(b d p)) (((1-(e^(-2 a d)) (x^(-2 b d))))^p)dx

Program code:

Int[Sinh[d_.*(a_.+b_.*Log[x_])]^p_,x_Symbol] :=
  Sinh[d*(a+b*Log[x])]^p/(x^(b*d*p)*(1-1/(E^(2*a*d)*x^(2*b*d)))^p)*
    Int[x^(b*d*p)*(1-1/(E^(2*a*d)*x^(2*b*d)))^p,x] /;
FreeQ[{a,b,d,p},x] && Not[IntegerQ[p]]

Int[Cosh[d_.*(a_.+b_.*Log[x_])]^p_,x_Symbol] :=
  Cosh[d*(a+b*Log[x])]^p/(x^(b*d*p)*(1+1/(E^(2*a*d)*x^(2*b*d)))^p)*
    Int[x^(b*d*p)*(1+1/(E^(2*a*d)*x^(2*b*d)))^p,x] /;
FreeQ[{a,b,d,p},x] && Not[IntegerQ[p]]

3:  ∫((Sinh[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫((Sinh[d (a+b Log[c (x^n)])])^p)dx  ⟶  (x/(((c (x^n)))^(1/n))) ∫(((((c (x^n)))^(1/n)) ((Sinh[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  (x/(n (((c (x^n)))^(1/n)))) Subst[∫(x^(1/n-1)) ((Sinh[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[Sinh[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Sinh[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[Cosh[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Cosh[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

2.  ∫(((e x))^m)((Sinh[d (a+b Log[c (x^n)])])^p)dx

1.  ∫(((e x))^m)((Sinh[d (a+b Log[c (x^n)])])^p)dx  when  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)-(((m+1))^2)≠0

1:  ∫(((e x))^m)Sinh[d (a+b Log[c (x^n)])]dx  when  (b^2) (d^2) (n^2)-(((m+1))^2)≠0

Rule: If  (b^2) (d^2) (n^2)-(((m+1))^2)≠0, then

∫(((e x))^m)Sinh[d (a+b Log[c (x^n)])]dx  ⟶  -(((m+1) (((e x))^(m+1)) Sinh[d (a+b Log[c (x^n)])])/((b^2) (d^2) e (n^2)-e (((m+1))^2)))+((b d n (((e x))^(m+1)) Cosh[d (a+b Log[c (x^n)])])/((b^2) (d^2) e (n^2)-e (((m+1))^2)))

Program code:

Int[(e_.*x_)^m_.*Sinh[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  -(m+1)*(e*x)^(m+1)*Sinh[d*(a+b*Log[c*x^n])]/(b^2*d^2*e*n^2-e*(m+1)^2) + 
  b*d*n*(e*x)^(m+1)*Cosh[d*(a+b*Log[c*x^n])]/(b^2*d^2*e*n^2-e*(m+1)^2) /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[b^2*d^2*n^2-(m+1)^2,0]

Int[(e_.*x_)^m_.*Cosh[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  -(m+1)*(e*x)^(m+1)*Cosh[d*(a+b*Log[c*x^n])]/(b^2*d^2*e*n^2-e*(m+1)^2) + 
  b*d*n*(e*x)^(m+1)*Sinh[d*(a+b*Log[c*x^n])]/(b^2*d^2*e*n^2-e*(m+1)^2) /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[b^2*d^2*n^2-(m+1)^2,0]

2:  ∫(((e x))^m)((Sinh[d (a+b Log[c (x^n)])])^p)dx  when  p-1∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)-(((m+1))^2)≠0

Rule: If  p-1∈(SuperPlus[ℤ])∧ (b^2) (d^2) (n^2) (p^2)-(((m+1))^2)≠0, then

∫(((e x))^m)((Sinh[d (a+b Log[c (x^n)])])^p)dx  ⟶  

-(((m+1) (((e x))^(m+1)) ((Sinh[d (a+b Log[c (x^n)])])^p))/((b^2) (d^2) e (n^2) (p^2)-e (((m+1))^2)))+((b d n p (((e x))^(m+1)) Cosh[d (a+b Log[c (x^n)])] ((Sinh[d (a+b Log[c (x^n)])])^(p-1)))/((b^2) (d^2) e (n^2) (p^2)-e (((m+1))^2)))-
(((b^2) (d^2) (n^2) p (p-1))/((b^2) (d^2) (n^2) (p^2)-(((m+1))^2)))∫(((e x))^m) ((Sinh[d (a+b Log[c (x^n)])])^(p-2))dx

Program code:

Int[(e_.*x_)^m_.*Sinh[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_,x_Symbol] :=
  -(m+1)*(e*x)^(m+1)*Sinh[d*(a+b*Log[c*x^n])]^p/(b^2*d^2*e*n^2*p^2-e*(m+1)^2) + 
  b*d*n*p*(e*x)^(m+1)*Cosh[d*(a+b*Log[c*x^n])]*Sinh[d*(a+b*Log[c*x^n])]^(p-1)/(b^2*d^2*e*n^2*p^2-e*(m+1)^2) - 
  b^2*d^2*n^2*p*(p-1)/(b^2*d^2*n^2*p^2-(m+1)^2)*Int[(e*x)^m*Sinh[d*(a+b*Log[c*x^n])]^(p-2),x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IGtQ[p,1] && NeQ[b^2*d^2*n^2*p^2-(m+1)^2,0]

Int[(e_.*x_)^m_.*Cosh[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_,x_Symbol] :=
  -(m+1)*(e*x)^(m+1)*Cosh[d*(a+b*Log[c*x^n])]^p/(b^2*d^2*e*n^2*p^2-e*(m+1)^2) + 
  b*d*n*p*(e*x)^(m+1)*Sinh[d*(a+b*Log[c*x^n])]*Cosh[d*(a+b*Log[c*x^n])]^(p-1)/(b^2*d^2*e*n^2*p^2-e*(m+1)^2) + 
  b^2*d^2*n^2*p*(p-1)/(b^2*d^2*n^2*p^2-(m+1)^2)*Int[(e*x)^m*Cosh[d*(a+b*Log[c*x^n])]^(p-2),x] /;
FreeQ[{a,b,c,d,e,m,n},x] && IGtQ[p,1] && NeQ[b^2*d^2*n^2*p^2-(m+1)^2,0]

2.  ∫(((e x))^m) ((Sinh[d (a+b Log[x])])^p)dx

1:  ∫(((e x))^m)((Sinh[d (a+b Log[x])])^p)dx  when  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (p^2)-(((m+1))^2)==0

Derivation: Algebraic expansion

Basis: If  (b^2) (d^2) (p^2)-(((m+1))^2)==0 ∧ p∈ℤ, then ((Sinh[d (a+b Log[x])])^p)==((((m+1))^p)/((2^p) (b^p) (d^p) (p^p)))(((-(e^(-((a b (d^2) p)/(m+1))))(x^(-((m+1)/p)))+(e^((a b (d^2) p)/(m+1)))(x^((m+1)/p))))^p)

Basis: If  (b^2) (d^2) (p^2)-(((m+1))^2)==0 ∧ p∈ℤ, then ((Cosh[d (a+b Log[x])])^p)==(1/(2^p))((((e^(-((a b (d^2) p)/(m+1))))(x^(-((m+1)/p)))+(e^((a b (d^2) p)/(m+1))) (x^((m+1)/p))))^p)

Note: The above identities need to be formally derived, and possibly the domain of p expanded.

Rule: If  p∈(SuperPlus[ℤ])∧ (b^2) (d^2) (p^2)-(((m+1))^2)==0, then

∫(((e x))^m)((Sinh[d (a+b Log[x])])^p)dx  ⟶  ((((m+1))^p)/((2^p) (b^p) (d^p) (p^p))) ∫ExpandIntegrand[(((e x))^m)(((-(e^(-((a b (d^2) p)/(m+1))))(x^(-((m+1)/p)))+(e^((a b (d^2) p)/(m+1)))(x^((m+1)/p))))^p),x]dx

Program code:

Int[(e_.*x_)^m_.*Sinh[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  (m+1)^p/(2^p*b^p*d^p*p^p)*
    Int[ExpandIntegrand[(e*x)^m*(-E^(-a*b*d^2*p/(m+1))*x^(-(m+1)/p)+E^(a*b*d^2*p/(m+1))*x^((m+1)/p))^p,x],x] /;
FreeQ[{a,b,d,e,m},x] && IGtQ[p,0] && EqQ[b^2*d^2*p^2-(m+1)^2,0]

Int[(e_.*x_)^m_.*Cosh[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  1/2^p*Int[ExpandIntegrand[(e*x)^m*(E^(-a*b*d^2*p/(m+1))*x^(-(m+1)/p)+E^(a*b*d^2*p/(m+1))*x^((m+1)/p))^p,x],x] /;
FreeQ[{a,b,d,e,m},x] && IGtQ[p,0] && EqQ[b^2*d^2*p^2-(m+1)^2,0]

x:  ∫(((e x))^m) ((Sinh[d (a+b Log[x])])^p)dx  when  p∈ℤ

Derivation: Algebraic expansion

Basis: Sinh[d (a+b Log[x])]==((e^(a d))/2) (x^(b d)) (1-(e^(-2 a d)) (x^(-2 b d)))

Basis: Cosh[d (a+b Log[x])]==((e^(a d))/2) (x^(b d)) (1+(e^(-2 a d)) (x^(-2 b d)))

Rule: If  p∈ℤ, then

∫(((e x))^m) ((Sinh[d (a+b Log[x])])^p)dx  ⟶  ((e^(a d p))/(2^p)) ∫(((e x))^m) (x^(b d p)) (((1-(e^(-2 a d)) (x^(-2 b d))))^p)dx

Program code:

(* Int[(e_.*x_)^m_.*Sinh[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  E^(a*d*p)/2^p*Int[(e*x)^m*x^(b*d*p)*(1-1/(E^(2*a*d)*x^(2*b*d)))^p,x] /;
FreeQ[{a,b,d,e,m},x] && IntegerQ[p] *)

(* Int[(e_.*x_)^m_.*Cosh[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  E^(a*d*p)/2^p*Int[(e*x)^m*x^(b*d*p)*(1+1/(E^(2*a*d)*x^(2*b*d)))^p,x] /;
FreeQ[{a,b,d,e,m},x] && IntegerQ[p] *)

2:  ∫(((e x))^m) ((Sinh[d (a+b Log[x])])^p)dx  when  p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sinh[d (a+b Log[x])])^p)/((x^(b d p)) (((1-(e^(-2 a d)) (x^(-2 b d))))^p)))==0

Basis: (∂_x)(((Cosh[d (a+b Log[x])])^p)/((x^(b d p)) (((1+(e^(-2 a d)) (x^(-2 b d))))^p)))==0

Rule: If  p∉ℤ, then

∫(((e x))^m) ((Sinh[d (a+b Log[x])])^p)dx  ⟶  (((Sinh[d (a+b Log[x])])^p)/((x^(b d p)) (((1-(e^(-2 a d)) (x^(-2 b d))))^p))) ∫(((e x))^m) (x^(b d p)) (((1-(e^(-2 a d)) (x^(-2 b d))))^p)dx

Program code:

Int[(e_.*x_)^m_.*Sinh[d_.*(a_.+b_.*Log[x_])]^p_,x_Symbol] :=
  Sinh[d*(a+b*Log[x])]^p/(x^(b*d*p)*(1-1/(E^(2*a*d)*x^(2*b*d)))^p)*
    Int[(e*x)^m*x^(b*d*p)*(1-1/(E^(2*a*d)*x^(2*b*d)))^p,x] /;
FreeQ[{a,b,d,e,m,p},x] && Not[IntegerQ[p]]

Int[(e_.*x_)^m_.*Cosh[d_.*(a_.+b_.*Log[x_])]^p_,x_Symbol] :=
  Cosh[d*(a+b*Log[x])]^p/(x^(b*d*p)*(1+1/(E^(2*a*d)*x^(2*b*d)))^p)*
    Int[(e*x)^m*x^(b*d*p)*(1+1/(E^(2*a*d)*x^(2*b*d)))^p,x] /;
FreeQ[{a,b,d,e,m,p},x] && Not[IntegerQ[p]]

3:  ∫(((e x))^m) ((Sinh[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫(((e x))^m) ((Sinh[d (a+b Log[c (x^n)])])^p)dx  ⟶  ((((e x))^(m+1))/(e (((c (x^n)))^((m+1)/n)))) ∫(((((c (x^n)))^((m+1)/n)) ((Sinh[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  ((((e x))^(m+1))/(e n (((c (x^n)))^((m+1)/n)))) Subst[∫(x^((m+1)/n-1)) ((Sinh[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[(e_.*x_)^m_.*Sinh[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Sinh[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[(e_.*x_)^m_.*Cosh[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Cosh[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

3:  ∫(((h (e+f Log[g (x^m)])))^q) Sinh[d (a+b Log[c (x^n)])]dx

Derivation: Algebraic expansion and piecewise constant extraction

Basis: Sinh[d (a+b Log[z])]==-(1/2) (e^(-a d)) (z^(-b d))+(1/2) (e^(a d)) (z^(b d))

Basis: Cosh[d (a+b Log[z])]==(1/2) (e^(-a d)) (z^(-b d))+(1/2) (e^(a d)) (z^(b d))

Rule:

∫(((h (e+f Log[g (x^m)])))^q) Sinh[d (a+b Log[c (x^n)])]dx  ⟶  
-(((e^(-a d)) (((c (x^n)))^(-b d)))/(2 (x^(-b d n)))) ∫(x^(-b d n)) (((h (e+f Log[g (x^m)])))^q)dx+(((e^(a d)) (((c (x^n)))^(b d)))/(2 (x^(b d n)))) ∫(x^(b d n)) (((h (e+f Log[g (x^m)])))^q)dx

Program code:

Int[(h_.*(e_.+f_.*Log[g_.*x_^m_.]))^q_.*Sinh[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  -E^(-a*d)*(c*x^n)^(-b*d)/(2*x^(-b*d*n))*Int[x^(-b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] + 
  E^(a*d)*(c*x^n)^(b*d)/(2*x^(b*d*n))*Int[x^(b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n,q},x]

Int[(h_.*(e_.+f_.*Log[g_.*x_^m_.]))^q_.*Cosh[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  E^(-a*d)*(c*x^n)^(-b*d)/(2*x^(-b*d*n))*Int[x^(-b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] + 
  E^(a*d)*(c*x^n)^(b*d)/(2*x^(b*d*n))*Int[x^(b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n,q},x]

4:  ∫(((i x))^r) (((h (e+f Log[g (x^m)])))^q) Sinh[d (a+b Log[c (x^n)])]dx

Derivation: Algebraic expansion and piecewise constant extraction

Basis: Sinh[d (a+b Log[z])]==-(1/2) (e^(-a d)) (z^(-b d))+(1/2) (e^(a d)) (z^(b d))

Basis: Cosh[d (a+b Log[z])]==(1/2) (e^(-a d)) (z^(-b d))+(1/2) (e^(a d)) (z^(b d))

Rule:

∫(((i x))^r) (((h (e+f Log[g (x^m)])))^q) Sinh[d (a+b Log[c (x^n)])]dx  ⟶  
-(((e^(-a d)) (((i x))^r) (((c (x^n)))^(-b d)))/(2 (x^(r-b d n)))) ∫(x^(r-b d n)) (((h (e+f Log[g (x^m)])))^q)dx+(((e^(a d)) (((i x))^r) (((c (x^n)))^(b d)))/(2 (x^(r+b d n)))) ∫(x^(r+b d n)) (((h (e+f Log[g (x^m)])))^q)dx

Program code:

Int[(i_.*x_)^r_.*(h_.*(e_.+f_.*Log[g_.*x_^m_.]))^q_.*Sinh[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  -E^(-a*d)*(i*x)^r*(c*x^n)^(-b*d)/(2*x^(r-b*d*n))*Int[x^(r-b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] + 
  E^(a*d)*(i*x)^r*(c*x^n)^(b*d)/(2*x^(r+b*d*n))*Int[x^(r+b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,m,n,q,r},x]

Int[(i_.*x_)^r_.*(h_.*(e_.+f_.*Log[g_.*x_^m_.]))^q_.*Cosh[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  E^(-a*d)*(i*x)^r*(c*x^n)^(-b*d)/(2*x^(r-b*d*n))*Int[x^(r-b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] + 
  E^(a*d)*(i*x)^r*(c*x^n)^(b*d)/(2*x^(r+b*d*n))*Int[x^(r+b*d*n)*(h*(e+f*Log[g*x^m]))^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,m,n,q,r},x]

2.  ∫u ((Tanh[d (a+b Log[c (x^n)])])^p)dx

1.  ∫((Tanh[d (a+b Log[c (x^n)])])^p)dx

1:  ∫((Tanh[d (a+b Log[x])])^p)dx

Derivation: Algebraic expansion

Basis: ((Tanh[z])^p)==((((-1+(e^(2 z))))^p)/(((1+(e^(2 z))))^p))

Basis: ((Coth[z])^p)==((((-1-(e^(2 z))))^p)/(((1-(e^(2 z))))^p))

Rule:

∫((Tanh[d (a+b Log[x])])^p)dx  ⟶  ∫((((-1+(e^(2 a d)) (x^(2 b d))))^p)/(((1+(e^(2 a d)) (x^(2 b d))))^p))dx

Program code:

Int[Tanh[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Int[(-1+E^(2*a*d)*x^(2*b*d))^p/(1+E^(2*a*d)*x^(2*b*d))^p,x] /;
FreeQ[{a,b,d,p},x]

Int[Coth[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Int[(-1-E^(2*a*d)*x^(2*b*d))^p/(1-E^(2*a*d)*x^(2*b*d))^p,x] /;
FreeQ[{a,b,d,p},x]

2:  ∫((Tanh[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫((Tanh[d (a+b Log[c (x^n)])])^p)dx  ⟶  (x/(((c (x^n)))^(1/n))) ∫(((((c (x^n)))^(1/n)) ((Tanh[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  (x/(n (((c (x^n)))^(1/n)))) Subst[∫(x^(1/n-1)) ((Tanh[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[Tanh[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Tanh[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[Coth[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Coth[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

2.  ∫(((e x))^m)((Tanh[d (a+b Log[c (x^n)])])^p)dx

1:  ∫(((e x))^m) ((Tanh[d (a+b Log[x])])^p)dx

Derivation: Algebraic expansion

Basis: ((Tanh[z])^p)==((((-1+(e^(2 z))))^p)/(((1+(e^(2 z))))^p))

Basis: ((Coth[z])^p)==((((-1-(e^(2 z))))^p)/(((1-(e^(2 z))))^p))

Rule:

∫(((e x))^m) ((Tanh[d (a+b Log[x])])^p)dx  ⟶  ∫(((e x))^m) ((((-1+(e^(2 a d)) (x^(2 b d))))^p)/(((1+(e^(2 a d)) (x^(2 b d))))^p))dx

Program code:

Int[(e_.*x_)^m_.*Tanh[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Int[(e*x)^m*(-1+E^(2*a*d)*x^(2*b*d))^p/(1+E^(2*a*d)*x^(2*b*d))^p,x] /;
FreeQ[{a,b,d,e,m,p},x]

Int[(e_.*x_)^m_.*Coth[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Int[(e*x)^m*(-1-E^(2*a*d)*x^(2*b*d))^p/(1-E^(2*a*d)*x^(2*b*d))^p,x] /;
FreeQ[{a,b,d,e,m,p},x]

2:  ∫(((e x))^m) ((Tanh[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫(((e x))^m) ((Tanh[d (a+b Log[c (x^n)])])^p)dx  ⟶  ((((e x))^(m+1))/(e (((c (x^n)))^((m+1)/n)))) ∫(((((c (x^n)))^((m+1)/n)) ((Tanh[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  ((((e x))^(m+1))/(e n (((c (x^n)))^((m+1)/n)))) Subst[∫(x^((m+1)/n-1)) ((Tanh[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[(e_.*x_)^m_.*Tanh[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Tanh[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[(e_.*x_)^m_.*Coth[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Coth[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

3.  ∫u ((Sech[d (a+b Log[c (x^n)])])^p)dx

1.  ∫((Sech[d (a+b Log[c (x^n)])])^p)dx

1.  ∫((Sech[d (a+b Log[x])])^p)dx

1:  ∫((Sech[d (a+b Log[x])])^p)dx  when  p∈ℤ

Derivation: Algebraic expansion

Basis: Sech[d (a+b Log[x])]==((2 (e^(-a d)) (x^(-b d)))/(1+(e^(-2 a d)) (x^(-2 b d))))

Basis: Csch[d (a+b Log[x])]==((2 (e^(-a d)) (x^(-b d)))/(1-(e^(-2 a d)) (x^(-2 b d))))

Rule: If  p∈ℤ, then

∫((Sech[d (a+b Log[x])])^p)dx  ⟶  (2^p) (e^(-a d p)) ∫((x^(-b d p))/(((1+(e^(-2 a d)) (x^(-2 b d))))^p))dx

Program code:

Int[Sech[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  2^p*E^(-a*d*p)*Int[x^(-b*d*p)/(1+E^(-2*a*d)*x^(-2*b*d))^p,x] /;
FreeQ[{a,b,d},x] && IntegerQ[p]

Int[Csch[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  2^p*E^(-a*d*p)*Int[x^(-b*d*p)/(1-E^(-2*a*d)*x^(-2*b*d))^p,x] /;
FreeQ[{a,b,d},x] && IntegerQ[p]

2:  ∫((Sech[d (a+b Log[x])])^p)dx  when  p∉ℤ

Derivation: Algebraic expansion and piecewise constant extraction

Basis: (∂_x)((((Sech[d (a+b Log[x])])^p) (((1+(e^(-2 a d)) (x^(-2 b d))))^p))/(x^(-b d p)))==0

Basis: (∂_x)((((Csch[d (a+b Log[x])])^p) (((1-(e^(-2 a d)) (x^(-2 b d))))^p))/(x^(-b d p)))==0

Rule: If  p∉ℤ, then

∫((Sech[d (a+b Log[x])])^p)dx  ⟶  ((((Sech[d (a+b Log[x])])^p) (((1+(e^(-2 a d)) (x^(-2 b d))))^p))/(x^(-b d p))) ∫((x^(-b d p))/(((1+(e^(-2 a d)) (x^(-2 b d))))^p))dx

Program code:

Int[Sech[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Sech[d*(a+b*Log[x])]^p*(1+E^(-2*a*d)*x^(-2*b*d))^p/x^(-b*d*p)*
    Int[x^(-b*d*p)/(1+E^(-2*a*d)*x^(-2*b*d))^p,x] /;
FreeQ[{a,b,d,p},x] && Not[IntegerQ[p]]

Int[Csch[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Csch[d*(a+b*Log[x])]^p*(1-E^(-2*a*d)*x^(-2*b*d))^p/x^(-b*d*p)*
    Int[x^(-b*d*p)/(1-E^(-2*a*d)*x^(-2*b*d))^p,x] /;
FreeQ[{a,b,d,p},x] && Not[IntegerQ[p]]

2:  ∫((Sech[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫((Sech[d (a+b Log[c (x^n)])])^p)dx  ⟶  (x/(((c (x^n)))^(1/n))) ∫(((((c (x^n)))^(1/n)) ((Sech[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  (x/(n (((c (x^n)))^(1/n)))) Subst[∫(x^(1/n-1)) ((Sech[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[Sech[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Sech[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[Csch[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  x/(n*(c*x^n)^(1/n))*Subst[Int[x^(1/n-1)*Csch[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,n,p},x] && (NeQ[c,1] || NeQ[n,1])

2.  ∫(((e x))^m) ((Sech[d (a+b Log[c (x^n)])])^p)dx

1.  ∫(((e x))^m) ((Sech[d (a+b Log[x])])^p)dx

1:  ∫(((e x))^m) ((Sech[d (a+b Log[x])])^p)dx  when  p∈ℤ

Derivation: Algebraic expansion

Basis: Sech[d (a+b Log[x])]==((2 (e^(-a d)) (x^(-b d)))/(1+(e^(-2 a d)) (x^(-2 b d))))

Basis: Csch[d (a+b Log[x])]==((2 (e^(-a d)) (x^(-b d)))/(1-(e^(-2 a d)) (x^(-2 b d))))

Rule: If  p∈ℤ, then

∫(((e x))^m) ((Sech[d (a+b Log[x])])^p)dx  ⟶  (2^p) (e^(-a d p)) ∫(((((e x))^m) (x^(-b d p)))/(((1+(e^(-2 a d)) (x^(-2 b d))))^p))dx

Program code:

Int[(e_.*x_)^m_.*Sech[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  2^p*E^(-a*d*p)*Int[(e*x)^m*x^(-b*d*p)/(1+E^(-2*a*d)*x^(-2*b*d))^p,x] /;
FreeQ[{a,b,d,e,m},x] && IntegerQ[p]

Int[(e_.*x_)^m_.*Csch[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  2^p*E^(-a*d*p)*Int[(e*x)^m*x^(-b*d*p)/(1-E^(-2*a*d)*x^(-2*b*d))^p,x] /;
FreeQ[{a,b,d,e,m},x] && IntegerQ[p]

2:  ∫(((e x))^m) ((Sech[d (a+b Log[x])])^p)dx  when  p∉ℤ

Derivation: Algebraic expansion and piecewise constant extraction

Basis: (∂_x)((((Sech[d (a+b Log[x])])^p) (((1+(e^(-2 a d)) (x^(-2 b d))))^p))/(x^(-b d p)))==0

Basis: (∂_x)((((Csch[d (a+b Log[x])])^p) (((1-(e^(-2 a d)) (x^(-2 b d))))^p))/(x^(-b d p)))==0

Rule: If  p∉ℤ, then

∫(((e x))^m) ((Sech[d (a+b Log[x])])^p)dx  ⟶  ((((Sech[d (a+b Log[x])])^p) (((1+(e^(-2 a d)) (x^(-2 b d))))^p))/(x^(-b d p))) ∫(((((e x))^m) (x^(-b d p)))/(((1+(e^(-2 a d)) (x^(-2 b d))))^p))dx

Program code:

Int[(e_.*x_)^m_.*Sech[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Sech[d*(a+b*Log[x])]^p*(1+E^(-2*a*d)*x^(-2*b*d))^p/x^(-b*d*p)*
    Int[(e*x)^m*x^(-b*d*p)/(1+E^(-2*a*d)*x^(-2*b*d))^p,x] /;
FreeQ[{a,b,d,e,m,p},x] && Not[IntegerQ[p]]

Int[(e_.*x_)^m_.*Csch[d_.*(a_.+b_.*Log[x_])]^p_.,x_Symbol] :=
  Csch[d*(a+b*Log[x])]^p*(1-E^(-2*a*d)*x^(-2*b*d))^p/x^(-b*d*p)*
    Int[(e*x)^m*x^(-b*d*p)/(1-E^(-2*a*d)*x^(-2*b*d))^p,x] /;
FreeQ[{a,b,d,e,m,p},x] && Not[IntegerQ[p]]

2:  ∫(((e x))^m) ((Sech[d (a+b Log[c (x^n)])])^p)dx

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(x/(((c (x^n)))^(1/n)))==0

Basis: ((F[c (x^n)])/x)==(1/n) Subst[((F[x])/x),x,c (x^n)] (∂_x)(c (x^n))

Rule:

∫(((e x))^m) ((Sech[d (a+b Log[c (x^n)])])^p)dx  ⟶  ((((e x))^(m+1))/(e (((c (x^n)))^((m+1)/n)))) ∫(((((c (x^n)))^((m+1)/n)) ((Sech[d (a+b Log[c (x^n)])])^p))/x)dx

  ⟶  ((((e x))^(m+1))/(e n (((c (x^n)))^((m+1)/n)))) Subst[∫(x^((m+1)/n-1)) ((Sech[d (a+b Log[x])])^p)dx,x,c (x^n)]

Int[(e_.*x_)^m_.*Sech[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Sech[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Int[(e_.*x_)^m_.*Csch[d_.*(a_.+b_.*Log[c_.*x_^n_.])]^p_.,x_Symbol] :=
  (e*x)^(m+1)/(e*n*(c*x^n)^((m+1)/n))*Subst[Int[x^((m+1)/n-1)*Csch[d*(a+b*Log[x])]^p,x],x,c*x^n] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && (NeQ[c,1] || NeQ[n,1])

Rules for integrands of the formu Hyper[a (x^n) Log[b x]] Log[b x]

1.  ∫u Sinh[a (x^n) Log[b x]] Log[b x]dx

1:  ∫Sinh[a x Log[b x]] Log[b x]dx

Rule:

∫Sinh[a x Log[b x]] Log[b x]dx  ⟶  ((Cosh[a x Log[b x]])/a)-∫Sinh[a x Log[b x]]dx

Program code:

Int[Sinh[a_.*x_*Log[b_.*x_]]*Log[b_.*x_],x_Symbol] :=
  Cosh[a*x*Log[b*x]]/a - Int[Sinh[a*x*Log[b*x]],x] /;
FreeQ[{a,b},x]

Int[Cosh[a_.*x_*Log[b_.*x_]]*Log[b_.*x_],x_Symbol] :=
  Sinh[a*x*Log[b*x]]/a - Int[Cosh[a*x*Log[b*x]],x] /;
FreeQ[{a,b},x]

2:  ∫(x^m)Sinh[a (x^n) Log[b x]] Log[b x]dx  when  m==n-1

Rule: If  m==n-1, then

∫(x^m)Sinh[a (x^n) Log[b x]] Log[b x]dx  ⟶  ((Cosh[a (x^n) Log[b x]])/(a n))-(1/n)∫(x^m) Sinh[a (x^n) Log[b x]]dx

Program code:

Int[x_^m_.*Sinh[a_.*x_^n_.*Log[b_.*x_]]*Log[b_.*x_],x_Symbol] :=
  Cosh[a*x^n*Log[b*x]]/(a*n) - 1/n*Int[x^m*Sinh[a*x^n*Log[b*x]],x] /;
FreeQ[{a,b,m,n},x] && EqQ[m,n-1]

Int[x_^m_.*Cosh[a_.*x_^n_.*Log[b_.*x_]]*Log[b_.*x_],x_Symbol] :=
  Sinh[a*x^n*Log[b*x]]/(a*n) - 1/n*Int[x^m*Cosh[a*x^n*Log[b*x]],x] /;
FreeQ[{a,b,m,n},x] && EqQ[m,n-1]