Rules for integrands of the form  (((a+b ArcSinh[c x]))^n)

1:  ∫(((a+b ArcSinh[c x]))^n)dx  when  n>0

Derivation: Integration by parts

Basis: (∂_x)(((a+b ArcSinh[c x]))^n)==((b c n (((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))

Rule: If  n>0, then

∫(((a+b ArcSinh[c x]))^n)dx  ⟶  x (((a+b ArcSinh[c x]))^n)-b c n∫((x (((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  x*(a+b*ArcSinh[c*x])^n - 
  b*c*n*Int[x*(a+b*ArcSinh[c*x])^(n-1)/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c},x] && GtQ[n,0]

2:  ∫(((a+b ArcSinh[c x]))^n)dx  when  n<-1

Derivation: Integration by parts

Basis: ((((a+b ArcSinh[c x]))^n)/(Sqrt[1+(c^2) (x^2)]))==(∂_x)((((a+b ArcSinh[c x]))^(n+1))/(b c (n+1)))

Rule: If  n<-1, then

∫(((a+b ArcSinh[c x]))^n)dx  ⟶  (((Sqrt[1+(c^2) (x^2)]) (((a+b ArcSinh[c x]))^(n+1)))/(b c(n+1)))-(c/(b (n+1)))∫((x (((a+b ArcSinh[c x]))^(n+1)))/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  Sqrt[1+c^2*x^2]*(a+b*ArcSinh[c*x])^(n+1)/(b*c*(n+1)) - 
  c/(b*(n+1))*Int[x*(a+b*ArcSinh[c*x])^(n+1)/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c},x] && LtQ[n,-1]

3:  ∫(((a+b ArcSinh[c x]))^n)dx

Derivation: Integration by substitution

Basis: (((a+b ArcSinh[c x]))^n)==(1/(b c)) Subst[(x^n)Cosh[-(a/b)+(x/b)],x,(a+b ArcSinh[c x])] (∂_x)(a+b ArcSinh[c x])

Rule:

∫(((a+b ArcSinh[c x]))^n)dx  ⟶  (1/(b c)) Subst[∫(x^n) Cosh[-(a/b)+(x/b)]dx,x,a+b ArcSinh[c x]]

Program code:

Int[(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  1/(b*c)*Subst[Int[x^n*Cosh[-a/b+x/b],x],x,a+b*ArcSinh[c*x]] /;
FreeQ[{a,b,c,n},x]