Rules for integrands of the form  (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)

1.  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d

1.  ∫((((a+b ArcSinh[c x]))^n)/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d

x:  ∫((((a+b ArcSinh[c x]))^n)/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2) (x^2)])/(Sqrt[d+e (x^2)]))==0

Basis: ((F[ArcSinh[c x]])/(Sqrt[1+(c^2) (x^2)]))==(1/c) Subst[F[x],x,ArcSinh[c x]] (∂_x)ArcSinh[c x]

Note: When n==1, this rule would result in a slightly less compact antiderivative since ∫(((a+b x))^n)dx returns a sum.

Rule: If  e==(c^2) d, then

∫((((a+b ArcSinh[c x]))^n)/(Sqrt[d+e (x^2)]))dx  ⟶  ((Sqrt[1+(c^2) (x^2)])/(c (Sqrt[d+e (x^2)]))) Subst[∫(((a+b x))^n)dx,x,ArcSinh[c x]]

Program code:

(* Int[(a_.+b_.*ArcSinh[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  1/c*Simp[Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]]*Subst[Int[(a+b*x)^n,x],x,ArcSinh[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[e,c^2*d] *)

1:  ∫(1/((Sqrt[d+e (x^2)])(a+b ArcSinh[c x])))dx  when  e==(c^2) d

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2) (x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  e==(c^2) d, then

∫(1/((Sqrt[d+e (x^2)])(a+b ArcSinh[c x])))dx  ⟶  ((Sqrt[1+(c^2) (x^2)])/(b c (Sqrt[d+e (x^2)]))) Log[a+b ArcSinh[c x]]

Program code:

Int[1/(Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcSinh[c_.*x_])),x_Symbol] :=
  1/(b*c)*Simp[Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]]*Log[a+b*ArcSinh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d]

2:  ∫((((a+b ArcSinh[c x]))^n)/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ n≠-1

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2) (x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  e==(c^2) d ∧ n≠-1, then

∫((((a+b ArcSinh[c x]))^n)/(Sqrt[d+e (x^2)]))dx  ⟶  ((Sqrt[1+(c^2) (x^2)])/(b c (n+1) (Sqrt[d+e (x^2)]))) (((a+b ArcSinh[c x]))^(n+1))

Program code:

Int[(a_.+b_.*ArcSinh[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  1/(b*c*(n+1))*Simp[Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]]*(a+b*ArcSinh[c*x])^(n+1) /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[e,c^2*d] && NeQ[n,-1]

2.  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0

1:  ∫(((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ]), let  u=∫(((d+e (x^2)))^p)dx, then

∫(((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  ⟶  u(a+b ArcSinh[c x])-b c∫(u/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^p,x]},  
  Dist[a+b*ArcSinh[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/Sqrt[1+c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0]

2.  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p>0

1:  ∫(Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0

Derivation: Inverted integration by parts

Note: The piecewise constant factor in the second integral reduces the degree of  d in the resulting antiderivative.

Rule: If  e==(c^2) d ∧ n>0, then

∫(Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n)dx  ⟶  
((x (Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n))/2)-((b c n (Sqrt[d+e (x^2)]))/(2 (Sqrt[1+(c^2) (x^2)])))∫x (((a+b ArcSinh[c x]))^(n-1))dx+((Sqrt[d+e (x^2)])/(2 (Sqrt[1+(c^2) (x^2)])))∫((((a+b ArcSinh[c x]))^n)/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  x*Sqrt[d+e*x^2]*(a+b*ArcSinh[c*x])^n/2 - 
  b*c*n/2*Simp[Sqrt[d+e*x^2]/Sqrt[1+c^2*x^2]]*Int[x*(a+b*ArcSinh[c*x])^(n-1),x] + 
  1/2*Simp[Sqrt[d+e*x^2]/Sqrt[1+c^2*x^2]]*Int[(a+b*ArcSinh[c*x])^n/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[n,0]

2:  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p>0

Derivation: Inverted integration by parts and piecewise constant extraction

Basis: If  e==(c^2) d, then (∂_x)((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p))==0

Rule: If  e==(c^2) d ∧ n>0 ∧ p>0, then

∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
((x (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n))/(2p+1))+
((2 d p)/(2p+1))∫(((d+e (x^2)))^(p-1)) (((a+b ArcSinh[c x]))^n)dx-((b c n (((d+e (x^2)))^p))/((2p+1)(((1+(c^2) (x^2)))^p)))∫x (((1+(c^2) (x^2)))^(p-(1/2))) (((a+b ArcSinh[c x]))^(n-1))dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  x*(d+e*x^2)^p*(a+b*ArcSinh[c*x])^n/(2*p+1) + 
  2*d*p/(2*p+1)*Int[(d+e*x^2)^(p-1)*(a+b*ArcSinh[c*x])^n,x] - 
  b*c*n/(2*p+1)*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[x*(1+c^2*x^2)^(p-1/2)*(a+b*ArcSinh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[n,0] && GtQ[p,0]

3.  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p<-1

1:  ∫((((a+b ArcSinh[c x]))^n)/(((d+e (x^2)))^(3/2)))dx  when  e==(c^2) d ∧ n>0

Derivation: Integration by parts and piecewise constant extraction

Basis: (1/(((d+e (x^2)))^(3/2)))==(∂_x)(x/(d (Sqrt[d+e (x^2)])))

Basis: (∂_x)(((a+b ArcSinh[c x]))^n)==((b c n (((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2) (x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  e==(c^2) d ∧ n>0, then

∫((((a+b ArcSinh[c x]))^n)/(((d+e (x^2)))^(3/2)))dx  ⟶  ((x (((a+b ArcSinh[c x]))^n))/(d (Sqrt[d+e (x^2)])))-((b c n (Sqrt[1+(c^2) (x^2)]))/(d (Sqrt[d+e (x^2)])))∫((x (((a+b ArcSinh[c x]))^(n-1)))/(1+(c^2) (x^2)))dx

Program code:

Int[(a_.+b_.*ArcSinh[c_.*x_])^n_./(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  x*(a+b*ArcSinh[c*x])^n/(d*Sqrt[d+e*x^2]) - 
  b*c*n/d*Simp[Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]]*Int[x*(a+b*ArcSinh[c*x])^(n-1)/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[n,0]

2:  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p<-1 ∧ p≠-(3/2)

Rule: If  e==(c^2) d ∧ n>0 ∧ p<-1 ∧ p≠-(3/2), then

∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
-((x (((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n))/(2d (p+1)))+
((2 p+3)/(2 d (p+1)))∫(((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n)dx+((b c n (((d+e (x^2)))^p))/(2 (p+1)(((1+(c^2) (x^2)))^p)))∫x (((1+(c^2) (x^2)))^(p+(1/2))) (((a+b ArcSinh[c x]))^(n-1))dx

Program code:

Int[(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  -x*(d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])^n/(2*d*(p+1)) + 
  (2*p+3)/(2*d*(p+1))*Int[(d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])^n,x] + 
  b*c*n/(2*(p+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[x*(1+c^2*x^2)^(p+1/2)*(a+b*ArcSinh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[n,0] && LtQ[p,-1] && NeQ[p,-3/2]

4:  ∫((((a+b ArcSinh[c x]))^n)/(d+e (x^2)))dx  when  e==(c^2) d ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: If  e==(c^2) d, then (1/(d+e (x^2)))==(1/(c d)) Subst[Sech[x],x,ArcSinh[c x]] (∂_x)ArcSinh[c x]

Note: If  n∈(SuperPlus[ℤ]), then (((a+b x))^n) Sech[x] is integrable in closed-form.

Rule: If  e==(c^2) d ∧ n∈(SuperPlus[ℤ]), then

∫((((a+b ArcSinh[c x]))^n)/(d+e (x^2)))dx  ⟶  (1/(c d))Subst[∫(((a+b x))^n) Sech[x]dx,x,ArcSinh[c x]]

Program code:

Int[(a_.+b_.*ArcSinh[c_.*x_])^n_./(d_+e_.*x_^2),x_Symbol] :=
  1/(c*d)*Subst[Int[(a+b*x)^n*Sech[x],x],x,ArcSinh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[n,0]

3.  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n<-1

1:  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n<-1 ∧ (p∈ℤ ∨ d>0)

Derivation: Integration by parts

Basis: ((((a+b ArcSinh[c x]))^n)/(Sqrt[1+(c^2) (x^2)]))==(∂_x)((((a+b ArcSinh[c x]))^(n+1))/(b c (n+1)))

Rule: If  e==(c^2) d ∧ n<-1 ∧ (p∈ℤ ∨ d>0), then

∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
(((d^p)(((1+(c^2) (x^2)))^(p+(1/2)))(((a+b ArcSinh[c x]))^(n+1)))/(b c(n+1)))-((c (d^p)(2 p+1))/(b(n+1)))∫x(((1+(c^2) (x^2)))^(p-(1/2)))(((a+b ArcSinh[c x]))^(n+1))dx

Program code:

(* Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  d^p*(1+c^2*x^2)^(p+1/2)*(a+b*ArcSinh[c*x])^(n+1)/(b*c*(n+1)) - 
  c*d^p*(2*p+1)/(b*(n+1))*Int[x*(1+c^2*x^2)^(p-1/2)*(a+b*ArcSinh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && LtQ[n,-1] && (IntegerQ[p] || GtQ[d,0]) *)

2:  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n<-1

Derivation: Integration by parts and piecewise constant extraction

Basis: ((((a+b ArcSinh[c x]))^n)/(Sqrt[1+(c^2) (x^2)]))==(∂_x)((((a+b ArcSinh[c x]))^(n+1))/(b c (n+1)))

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p))==(((c^2) (2 p+1) x (((d+e (x^2)))^p))/(Sqrt[1+(c^2) (x^2)]))

Basis: If  e==(c^2) d, then (∂_x)((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p))==0

Rule: If  e==(c^2) d ∧ n<-1, then

∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
(((Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^(n+1)))/(b c(n+1)))+((c (2 p+1))/(b(n+1)))∫((x (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^(n+1)))/(Sqrt[1+(c^2) (x^2)]))dx  ⟶  
(((Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^(n+1)))/(b c(n+1)))-((c (2 p+1) (((d+e (x^2)))^p))/(b(n+1) (((1+(c^2) (x^2)))^p)))∫x(((1+(c^2) (x^2)))^(p-(1/2)))(((a+b ArcSinh[c x]))^(n+1))dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  Simp[Sqrt[1+c^2*x^2]*(d+e*x^2)^p]*(a+b*ArcSinh[c*x])^(n+1)/(b*c*(n+1)) - 
  c*(2*p+1)/(b*(n+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[x*(1+c^2*x^2)^(p-1/2)*(a+b*ArcSinh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && LtQ[n,-1]

4:  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ 2p∈(SuperPlus[ℤ])

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  e==(c^2) d, then (∂_x)((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p))==0

Basis: (((1+(c^2) (x^2)))^p)==(1/(b c)) Subst[((Cosh[-(a/b)+(x/b)])^(2p+1)),x,a+b ArcSinh[c x]] (∂_x)(a+b ArcSinh[c x])

Note: If  2 p∈(SuperPlus[ℤ]), then (x^n) ((Cosh[-(a/b)+(x/b)])^(2p+1)) is integrable in closed-form.

Rule: If  e==(c^2) d ∧ 2 p∈(SuperPlus[ℤ]), then

∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  ((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p)) ∫(((1+(c^2) (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx

  ⟶  ((((d+e (x^2)))^p)/(b c (((1+(c^2) (x^2)))^p))) Subst[∫(x^n) ((Cosh[-(a/b)+(x/b)])^(2p+1))dx,x,a+b ArcSinh[c x]]

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  1/(b*c)*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Subst[Int[x^n*Cosh[-a/b+x/b]^(2*p+1),x],x,a+b*ArcSinh[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[e,c^2*d] && IGtQ[2*p,0]

2.  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e≠(c^2) d

1:  ∫(((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  when  e≠(c^2) d ∧ (p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ]))

Derivation: Integration by parts

Note: If  p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ]), then ∫(((d+e (x^2)))^p)dx is a rational function.

Rule: If  e≠(c^2) d ∧ (p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ])), let  u=∫(((d+e (x^2)))^p)dx, then

∫(((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  ⟶  u(a+b ArcSinh[c x])-b c∫(u/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^p,x]},  
  Dist[a+b*ArcSinh[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/Sqrt[1+c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[e,c^2*d] && (IGtQ[p,0] || ILtQ[p+1/2,0])

2:  ∫(((d+e (x^2)))^p)(((a+b ArcSinh[c x]))^n)dx  when  e≠(c^2) d ∧ p∈ℤ ∧ (p>0 ∨ n∈(SuperPlus[ℤ]))

Derivation: Algebraic expansion

Rule: If  e≠(c^2) d ∧ p∈ℤ ∧ (p>0 ∨ n∈(SuperPlus[ℤ])), then

∫(((d+e (x^2)))^p)(((a+b ArcSinh[c x]))^n)dx  ⟶  ∫ (((a+b ArcSinh[c x]))^n) ExpandIntegrand[(((d+e (x^2)))^p),x]dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcSinh[c*x])^n,(d+e*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e,n},x] && NeQ[e,c^2*d] && IntegerQ[p] && (p>0 || IGtQ[n,0])

U:  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx

Rule:

∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  ∫(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[(d+e*x^2)^p*(a+b*ArcSinh[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,n,p},x]

Rules for integrands of the form (((d+e x))^p) (((f+g x))^q) (((a+b ArcSinh[c x]))^n)

1:  ∫(((d+e x))^p) (((f+g x))^q) (((a+b ArcSinh[c x]))^n)dx  when  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0 ∧ (p|q)∈ℤ+(1/2) ∧ p-q≥0 ∧ d>0 ∧ (g/e)<0

Derivation: Algebraic expansion

Basis: If  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0 ∧ d>0 ∧ (g/e)<0, then (((d+e x))^p) (((f+g x))^q)==(((-(((d^2) g)/e)))^q) (((d+e x))^(p-q)) (((1+(c^2) (x^2)))^q)

Rule: If  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0 ∧ (p|q)∈ℤ+(1/2) ∧ p-q≥0 ∧ d>0 ∧ (g/e)<0, then

∫(((d+e x))^p) (((f+g x))^q) (((a+b ArcSinh[c x]))^n)dx  ⟶  (((-(((d^2) g)/e)))^q) ∫(((d+e x))^(p-q))(((1+(c^2) (x^2)))^q) (((a+b ArcSinh[c x]))^n)dx

Program code:

Int[(d_+e_.*x_)^p_*(f_+g_.*x_)^q_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (-d^2*g/e)^q*Int[(d+e*x)^(p-q)*(1+c^2*x^2)^q*(a+b*ArcSinh[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[e*f+d*g,0] && EqQ[c^2*d^2+e^2,0] && HalfIntegerQ[p,q] && GeQ[p-q,0] && GtQ[d,0] && LtQ[g/e,0]

2:  ∫(((d+e x))^p) (((f+g x))^q) (((a+b ArcSinh[c x]))^n)dx  when  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0 ∧ (p|q)∈ℤ+(1/2) ∧ p-q≥0 ∧ ¬(d>0 ∧ (g/e)<0)

Derivation: Piecewise constant extraction

Basis: If  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0, then (∂_x)(((((d+e x))^q) (((f+g x))^q))/(((1+(c^2) (x^2)))^q))==0

Rule: If  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0 ∧ (p|q)∈ℤ+(1/2) ∧ p-q≥0 ∧ ¬(d>0 ∧ (g/e)<0), then

∫(((d+e x))^p) (((f+g x))^q) (((a+b ArcSinh[c x]))^n)dx  ⟶  (((((d+e x))^q) (((f+g x))^q))/(((1+(c^2) (x^2)))^q)) ∫(((d+e x))^(p-q))(((1+(c^2) (x^2)))^q) (((a+b ArcSinh[c x]))^n)dx

Program code:

Int[(d_+e_.*x_)^p_*(f_+g_.*x_)^q_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (d+e*x)^q*(f+g*x)^q/(1+c^2*x^2)^q*Int[(d+e*x)^(p-q)*(1+c^2*x^2)^q*(a+b*ArcSinh[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[e*f+d*g,0] && EqQ[c^2*d^2+e^2,0] && HalfIntegerQ[p,q] && GeQ[p-q,0]