Rules for integrands of the form (((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0

0:  ∫(((f x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  d2 e1+d1 e2==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  d2 e1+d1 e2==0, then (d1+e1 x) (d2+e2 x)==d1 d2+e1 e2 (x^2)

Rule: If  d2 e1+d1 e2==0 ∧ p∈ℤ, then

∫(((f x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  ∫(((f x))^m) (((d1 d2+e1 e2 (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx

Program code:

Int[(f_.*x_)^m_.*(d1_+e1_.*x_)^p_.*(d2_+e2_.*x_)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[(f*x)^m*(d1*d2+e1*e2*x^2)^p*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m,n},x] && EqQ[d2*e1+d1*e2,0] && IntegerQ[p]

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0

1.  ∫x (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0

1:  ∫((x (((a+b ArcCosh[c x]))^n))/(d+e (x^2)))dx  when  (c^2) d+e==0 ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0, then (x/(d+e (x^2)))==(1/e)Subst[Coth[x],x,ArcCosh[c x]](∂_x)ArcCosh[c x]

Basis: If  (c^2) d+e==0, then (x/(d+e (x^2)))==-(1/(b e)) Subst[Coth[(a/b)-(x/b)],x,a+b ArcCosh[c x]] (∂_x)(a+b ArcCosh[c x])

Note: If  n∈(SuperPlus[ℤ]), then (((a+b x))^n) Coth[x]is integrable in closed-form.

Rule: If  (c^2) d+e==0 ∧ n∈(SuperPlus[ℤ]), then

∫((x (((a+b ArcCosh[c x]))^n))/(d+e (x^2)))dx  ⟶  (1/e)Subst[∫(((a+b x))^n) Coth[x]dx,x,ArcCosh[c x]]

Program code:

Int[x_*(a_.+b_.*ArcCosh[c_.*x_])^n_./(d_+e_.*x_^2),x_Symbol] :=
  1/e*Subst[Int[(a+b*x)^n*Coth[x],x],x,ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[n,0]

2:  ∫x (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p≠-1

Derivation: Integration by parts and piecewise constant extraction

Basis: x (((d+e (x^2)))^p)==(∂_x)((((d+e (x^2)))^(p+1))/(2 e (p+1)))

Basis: If  e1==c d1 ∧ e2==-c d2 ∧ p≠-1, then x (((d1+e1 x))^p) (((d2+e2 x))^p)==(∂_x)(((((d1+e1 x))^(p+1)) (((d2+e2 x))^(p+1)))/(2 e1 e2 (p+1)))

Basis: (∂_x)(((a+b ArcCosh[c x]))^n)==((b c n (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[1+c x]) (Sqrt[-1+c x])))

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/((((1+c x))^p) (((-1+c x))^p)))==0

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ p≠-1, then

∫x (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx
  ⟶  (((((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n))/(2 e (p+1)))-((b c n)/(2 e (p+1)))∫(((((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx
  ⟶  (((((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n))/(2 e (p+1)))-((b n (((d+e (x^2)))^p))/(2c(p+1) (((1+c x))^p) (((-1+c x))^p)))∫(((1+c x))^(p+(1/2))) (((-1+c x))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

Int[x_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n/(2*e*(p+1)) - 
  b*n/(2*c*(p+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && NeQ[p,-1]

Int[x_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (d1+e1*x)^(p+1)*(d2+e2*x)^(p+1)*(a+b*ArcCosh[c*x])^n/(2*e1*e2*(p+1)) - 
  b*n/(2*c*(p+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,p},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && NeQ[p,-1]

2.  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ m+2 p+3==0

1:  ∫((((a+b ArcCosh[c x]))^n)/(x (d+e (x^2))))dx  when  (c^2) d+e==0 ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0, then (1/(x (d+e (x^2))))==-(1/d)Subst[(1/(Cosh[x] Sinh[x])),x,ArcCosh[c x]] (∂_x)ArcCosh[c x]

Basis: If  (c^2) d+e==0, then (1/(x (d+e (x^2))))==-(1/(b d))Subst[(1/(Cosh[-(a/b)+(x/b)] Sinh[-(a/b)+(x/b)])),x,a+b ArcCosh[c x]] (∂_x)(a+b ArcCosh[c x])

Rule: If  (c^2) d+e==0 ∧ n∈(SuperPlus[ℤ]), then

∫((((a+b ArcCosh[c x]))^n)/(x (d+e (x^2))))dx  ⟶  -(1/d)Subst[∫((((a+b x))^n)/(Cosh[x] Sinh[x]))dx,x,ArcCosh[c x]]

Program code:

Int[(a_.+b_.*ArcCosh[c_.*x_])^n_./(x_*(d_+e_.*x_^2)),x_Symbol] :=
  -1/d*Subst[Int[(a+b*x)^n/(Cosh[x]*Sinh[x]),x],x,ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[n,0]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ m+2 p+3==0 ∧ m≠-1

Derivation: Integration by parts and piecewise constant extraction

Basis: If  m+2 p+3==0, then (((f x))^m) (((d+e (x^2)))^p)==(∂_x)(((((f x))^(m+1)) (((d+e (x^2)))^(p+1)))/(d f (m+1)))

Basis: If  d2 e1+d1 e2==0 ∧ m+2 p+3==0, then (((f x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p)==(∂_x)(((((f x))^(m+1)) (((d1+e1 x))^(p+1)) (((d2+e2 x))^(p+1)))/(d1 d2 f (m+1)))

Basis: (∂_x)(((a+b ArcCosh[c x]))^n)==((b c n (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[1+c x]) (Sqrt[-1+c x])))

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/((((1+c x))^p) (((-1+c x))^p)))==0

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ m+2 p+3==0 ∧ m≠-1, then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  
(((((f x))^(m+1)) (((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n))/(d f(m+1)))+
((b c n (((d+e (x^2)))^p))/(f(m+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m+1)) (((1+c x))^(p+(1/2))) (((-1+c x))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n/(d*f*(m+1)) + 
  b*c*n/(f*(m+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m+1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && EqQ[m+2*p+3,0] && NeQ[m,-1]

Int[(f_.*x_)^m_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d1+e1*x)^(p+1)*(d2+e2*x)^(p+1)*(a+b*ArcCosh[c*x])^n/(d1*d2*f*(m+1)) + 
  b*c*n/(f*(m+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m+1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m,p},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && EqQ[m+2*p+3,0] && NeQ[p,-1]

3.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p>0

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  when  (c^2) d+e==0 ∧ p>0

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ ((m-1)/2)∈(SuperMinus[ℤ])

1:  ∫(((((d+e (x^2)))^p) (a+b ArcCosh[c x]))/x)dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])

Derivation: Inverted integration by parts

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ]), then

∫(((((d+e (x^2)))^p) (a+b ArcCosh[c x]))/x)dx  ⟶  
(((((d+e (x^2)))^p) (a+b ArcCosh[c x]))/(2 p))-((b c (((-d))^p))/(2 p))∫(((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2)))dx+d ∫ (((((d+e (x^2)))^(p-1)) (a+b ArcCosh[c x]))/x)dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])/x_,x_Symbol] :=
  (d+e*x^2)^p*(a+b*ArcCosh[c*x])/(2*p) - 
  b*c*(-d)^p/(2*p)*Int[(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2),x] + 
  d*Int[(d+e*x^2)^(p-1)*(a+b*ArcCosh[c*x])/x,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ ((m+1)/2)∈(SuperMinus[ℤ])

Derivation: Inverted integration by parts

Rule: If (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ ((m+1)/2)∈(SuperMinus[ℤ]), then

∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  ⟶  
(((((f x))^(m+1))(((d+e (x^2)))^p) (a+b ArcCosh[c x]))/(f(m+1)))-
((b c (((-d))^p))/(f(m+1)))∫(((f x))^(m+1)) (((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2)))dx-((2 e p)/((f^2)(m+1)))∫(((f x))^(m+2)) (((d+e (x^2)))^(p-1)) (a+b ArcCosh[c x])dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^p*(a+b*ArcCosh[c*x])/(f*(m+1)) - 
  b*c*(-d)^p/(f*(m+1))*Int[(f*x)^(m+1)*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2),x] - 
  2*e*p/(f^2*(m+1))*Int[(f*x)^(m+2)*(d+e*x^2)^(p-1)*(a+b*ArcCosh[c*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && ILtQ[(m+1)/2,0]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ]), let  u->∫(((f x))^m) (((d+e (x^2)))^p)dx, then

∫(((f x))^m) (((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  ⟶  u (a+b ArcCosh[c x])-b c∫(u/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^p,x]},  
  Dist[a+b*ArcCosh[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x],x]] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && IGtQ[p,0]

2:  ∫(x^m) (((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  when  (c^2) d+e==0 ∧ p-(1/2)∈ℤ ∧ p≠-(1/2) ∧ (((m+1)/2)∈(SuperPlus[ℤ])∨ ((m+2 p+3)/2)∈(SuperMinus[ℤ]))

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcCosh[c x])==((b c)/((Sqrt[1+c x]) (Sqrt[-1+c x])))

Basis: If  (c^2) d+e==0, then (∂_x)((Sqrt[d+e (x^2)])/((Sqrt[1+c x]) (Sqrt[-1+c x])))==0

Note: If  p-(1/2)∈ℤ ∧ (((m+1)/2)∈(SuperPlus[ℤ])∨ ((m+2 p+3)/2)∈(SuperMinus[ℤ])), then ∫(x^m)(((d+e (x^2)))^p)dx is an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If  (c^2) d+e==0 ∧ p-(1/2)∈ℤ ∧ p≠-(1/2) ∧ (((m+1)/2)∈(SuperPlus[ℤ])∨ ((m+2 p+3)/2)∈(SuperMinus[ℤ])), let u->∫(x^m) (((d+e (x^2)))^p)dx, then

∫(x^m) (((d+e (x^2)))^p) (a+b ArcCosh[c x])dx

  ⟶  u (a+b ArcCosh[c x])-b c ∫(u/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

  ⟶  u (a+b ArcCosh[c x])-((b c (Sqrt[d+e (x^2)]))/((Sqrt[1+c x]) (Sqrt[-1+c x]))) ∫(u/(Sqrt[d+e (x^2)]))dx

Program code:

Int[x_^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*x^2)^p,x]},  
  Dist[a+b*ArcCosh[c*x],u] - 
  b*c*Simp[Sqrt[d+e*x^2]/(Sqrt[1+c*x]*Sqrt[-1+c*x])]*Int[SimplifyIntegrand[u/Sqrt[d+e*x^2],x],x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2] && NeQ[p,-1/2] && (IGtQ[(m+1)/2,0] || ILtQ[(m+2*p+3)/2,0])

Int[x_^m_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(d1+e1*x)^p*(d2+e2*x)^p,x]},  
  Dist[a+b*ArcCosh[c*x],u] - 
  b*c*Simp[Sqrt[d1+e1*x]*Sqrt[d2+e2*x]/(Sqrt[1+c*x]*Sqrt[-1+c*x])]*Int[SimplifyIntegrand[u/(Sqrt[d1+e1*x]*Sqrt[d2+e2*x]),x],x]] /;
FreeQ[{a,b,c,d1,e1,d2,e2},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && IntegerQ[p-1/2] && NeQ[p,-1/2] && (IGtQ[(m+1)/2,0] || ILtQ[(m+2*p+3)/2,0])

2.  ∫(((f x))^m)(Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>1

1:  ∫(((f x))^m) (Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ m<-1

Derivation: Inverted integration by parts

Note: The piecewise constant factor in the second integral reduces the degree of  d in the resulting antiderivative.

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ m<-1, then

∫(((f x))^m) (Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n)dx  ⟶  

(((((f x))^(m+1)) (Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n))/(f (m+1)))-
((b c n (Sqrt[d+e (x^2)]))/(f (m+1) (Sqrt[1+c x]) (Sqrt[-1+c x])))∫(((f x))^(m+1))(((a+b ArcCosh[c x]))^(n-1))dx-(((c^2)(Sqrt[d+e (x^2)]))/((f^2)(m+1)(Sqrt[1+c x]) (Sqrt[-1+c x])))∫(((((f x))^(m+2)) (((a+b ArcCosh[c x]))^n))/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

Program code:

Int[(f_.*x_)^m_*Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcCosh[c*x])^n/(f*(m+1)) - 
  b*c*n/(f*(m+1))*Simp[Sqrt[d+e*x^2]/(Sqrt[1+c*x]*Sqrt[-1+c*x])]*
    Int[(f*x)^(m+1)*(a+b*ArcCosh[c*x])^(n-1),x] - 
  c^2/(f^2*(m+1))*Simp[Sqrt[d+e*x^2]/(Sqrt[1+c*x]*Sqrt[-1+c*x])]*
    Int[(f*x)^(m+2)*(a+b*ArcCosh[c*x])^n/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && LtQ[m,-1]

Int[(f_.*x_)^m_*Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d1+e1*x]*Sqrt[d2+e2*x]*(a+b*ArcCosh[c*x])^n/(f*(m+1)) - 
  b*c*n/(f*(m+1))*Simp[Sqrt[d1+e1*x]/Sqrt[1+c*x]]*Simp[Sqrt[d2+e2*x]/Sqrt[-1+c*x]]*
    Int[(f*x)^(m+1)*(a+b*ArcCosh[c*x])^(n-1),x] - 
  c^2/(f^2*(m+1))*Simp[Sqrt[d1+e1*x]/Sqrt[1+c*x]]*Simp[Sqrt[d2+e2*x]/Sqrt[-1+c*x]]*
    Int[((f*x)^(m+2)*(a+b*ArcCosh[c*x])^n)/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && LtQ[m,-1]

2:  ∫(((f x))^m) (Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n∈(SuperPlus[ℤ])∧ (m+2∈(SuperPlus[ℤ])∨ n==1)

Derivation: Inverted integration by parts

Note: The piecewise constant factor in the second integral reduces the degree of  d in the resulting antiderivative.

Rule: If  (c^2) d+e==0 ∧ n∈(SuperPlus[ℤ])∧ (m+2∈(SuperPlus[ℤ])∨ n==1), then

∫(((f x))^m)(Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n)dx  ⟶  

(((((f x))^(m+1)) (Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n))/(f(m+2)))-
((b c n(Sqrt[d+e (x^2)]))/(f(m+2)(Sqrt[1+c x]) (Sqrt[-1+c x])))∫(((f x))^(m+1)) (((a+b ArcCosh[c x]))^(n-1))dx-((Sqrt[d+e (x^2)])/((m+2)(Sqrt[1+c x]) (Sqrt[-1+c x])))∫ (((((f x))^m) (((a+b ArcCosh[c x]))^n))/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

Program code:

Int[(f_.*x_)^m_*Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcCosh[c*x])^n/(f*(m+2)) - 
  b*c*n/(f*(m+2))*Simp[Sqrt[d+e*x^2]/(Sqrt[1+c*x]*Sqrt[-1+c*x])]*
    Int[(f*x)^(m+1)*(a+b*ArcCosh[c*x])^(n-1),x] - 
  1/(m+2)*Simp[Sqrt[d+e*x^2]/(Sqrt[1+c*x]*Sqrt[-1+c*x])]*
    Int[(f*x)^m*(a+b*ArcCosh[c*x])^n/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && IGtQ[n,0] && (IGtQ[m,-2] || EqQ[n,1])

Int[(f_.*x_)^m_*Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d1+e1*x]*Sqrt[d2+e2*x]*(a+b*ArcCosh[c*x])^n/(f*(m+2)) - 
  b*c*n/(f*(m+2))*Simp[Sqrt[d1+e1*x]/Sqrt[1+c*x]]*Simp[Sqrt[d2+e2*x]/Sqrt[-1+c*x]]*
    Int[(f*x)^(m+1)*(a+b*ArcCosh[c*x])^(n-1),x] - 
  1/(m+2)*Simp[Sqrt[d1+e1*x]/Sqrt[1+c*x]]*Simp[Sqrt[d2+e2*x]/Sqrt[-1+c*x]]*
    Int[(f*x)^m*(a+b*ArcCosh[c*x])^n/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && IGtQ[n,0] && (IGtQ[m,-2] || EqQ[n,1])

3.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p>0

1:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p>0 ∧ m<-1

Derivation: Inverted integration by parts

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ p>0 ∧ m<-1, then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

(((((f x))^(m+1))(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n))/(f(m+1)))-
((2 e p)/((f^2)(m+1)))∫(((f x))^(m+2)) (((d+e (x^2)))^(p-1)) (((a+b ArcCosh[c x]))^n)dx-
((b c n (((d+e (x^2)))^p))/(f(m+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m+1)) (((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^p*(a+b*ArcCosh[c*x])^n/(f*(m+1)) - 
  2*e*p/(f^2*(m+1))*Int[(f*x)^(m+2)*(d+e*x^2)^(p-1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*c*n/(f*(m+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m+1)*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && GtQ[p,0] && LtQ[m,-1]

Int[(f_.*x_)^m_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^n/(f*(m+1)) - 
  2*e1*e2*p/(f^2*(m+1))*Int[(f*x)^(m+2)*(d1+e1*x)^(p-1)*(d2+e2*x)^(p-1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*c*n/(f*(m+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m+1)*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && GtQ[p,0] && LtQ[m,-1]

x:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ m>1 ∧ m+2 p+1≠0 ∧ m∈ℤ

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ m>1 ∧ m+2 p+1≠0 ∧ m∈ℤ, then

∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

((f(((f x))^(m-1)) (((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n))/(e(m+2 p+1)))+
(((f^2)(m-1))/((c^2) (m+2 p+1)))∫(((f x))^(m-2))(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx-
((b f n (((d+e (x^2)))^p))/(c(m+2 p+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m-1)) (((-1+(c^2) (x^2)))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

(* Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  f*(f*x)^(m-1)*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n/(e*(m+2*p+1)) + 
  f^2*(m-1)/(c^2*(m+2*p+1))*Int[(f*x)^(m-2)*(d+e*x^2)^p*(a+b*ArcCosh[c*x])^n,x] - 
  b*f*n/(c*(m+2*p+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m-1)*(-1+c^2*x^2)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,p},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && EqQ[n,1] && IGtQ[p+1/2,0] && IGtQ[(m-1)/2,0] *)

x:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p<-1 ∧ m>1

Derivation: Integration by parts

Basis: x (((d+e (x^2)))^p)==(∂_x)((((d+e (x^2)))^(p+1))/(2 e (p+1)))

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ p<-1 ∧ m>1, then

∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

((f(((f x))^(m-1))(((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n))/(2 e (p+1)))-
(((f^2)(m-1))/(2e(p+1) ))∫(((f x))^(m-2))(((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n)dx-
((b f n (((d+e (x^2)))^p))/(2c(p+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m-1)) (((1+c x))^(p+(1/2))) (((-1+c x))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

(* Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  f*(f*x)^(m-1)*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n/(2*e*(p+1)) - 
  f^2*(m-1)/(2*e*(p+1))*Int[(f*x)^(m-2)*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*f*n/(2*c*(p+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m-1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && EqQ[n,1] && ILtQ[p-1/2,0] && IGtQ[(m-1)/2,0] *)

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p>0 ∧ m≮-1

Derivation: Inverted integration by parts

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ p>0 ∧ m≮-1, then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

(((((f x))^(m+1)) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n))/(f(m+2 p+1)))+
((2d p)/(m+2 p+1)) ∫ (((f x))^m) (((d+e (x^2)))^(p-1)) (((a+b ArcCosh[c x]))^n)dx-
((b c n (((d+e (x^2)))^p))/(f (m+2 p+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m+1)) (((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^p*(a+b*ArcCosh[c*x])^n/(f*(m+2*p+1)) + 
  2*d*p/(m+2*p+1)*Int[(f*x)^m*(d+e*x^2)^(p-1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*c*n/(f*(m+2*p+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m+1)*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && GtQ[p,0] && Not[LtQ[m,-1]]

Int[(f_.*x_)^m_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^n/(f*(m+2*p+1)) + 
  2*d1*d2*p/(m+2*p+1)*Int[(f*x)^m*(d1+e1*x)^(p-1)*(d2+e2*x)^(p-1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*c*n/(f*(m+2*p+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m+1)*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && GtQ[p,0] && Not[LtQ[m,-1]]

4:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ m+1∈(SuperMinus[ℤ])

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ m+1∈(SuperMinus[ℤ]), then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

(((((f x))^(m+1)) (((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n))/(d f(m+1)))+
(((c^2)(m+2 p+3))/((f^2)(m+1)))∫(((f x))^(m+2)) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx+
((b c n (((d+e (x^2)))^p))/(f(m+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m+1)) (((1+c x))^(p+(1/2))) (((-1+c x))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Programcode:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n/(d*f*(m+1)) + 
  c^2*(m+2*p+3)/(f^2*(m+1))*Int[(f*x)^(m+2)*(d+e*x^2)^p*(a+b*ArcCosh[c*x])^n,x] + 
  b*c*n/(f*(m+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m+1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,p},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && ILtQ[m,-1]

Int[(f_.*x_)^m_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d1+e1*x)^(p+1)*(d2+e2*x)^(p+1)*(a+b*ArcCosh[c*x])^n/(d1*d2*f*(m+1)) + 
  c^2*(m+2*p+3)/(f^2*(m+1))*Int[(f*x)^(m+2)*(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^n,x] + 
  b*c*n/(f*(m+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m+1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,p},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && ILtQ[m,-1]

5.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p<-1 ∧ m∈ℤ

1:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p<-1 ∧ m-1∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: x (((d+e (x^2)))^p)==(∂_x)((((d+e (x^2)))^(p+1))/(2 e (p+1)))

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ p<-1 ∧ m-1∈(SuperPlus[ℤ]), then

∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

((f(((f x))^(m-1))(((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n))/(2 e (p+1)))-
(((f^2)(m-1))/(2e(p+1) ))∫(((f x))^(m-2))(((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n)dx-
((b f n (((d+e (x^2)))^p))/(2c(p+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m-1)) (((1+c x))^(p+(1/2))) (((-1+c x))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  f*(f*x)^(m-1)*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n/(2*e*(p+1)) - 
  f^2*(m-1)/(2*e*(p+1))*Int[(f*x)^(m-2)*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*f*n/(2*c*(p+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m-1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && LtQ[p,-1] && IGtQ[m,1]

Int[(f_.*x_)^m_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  f*(f*x)^(m-1)*(d1+e1*x)^(p+1)*(d2+e2*x)^(p+1)*(a+b*ArcCosh[c*x])^n/(2*e1*e2*(p+1)) - 
  f^2*(m-1)/(2*e1*e2*(p+1))*Int[(f*x)^(m-2)*(d1+e1*x)^(p+1)*(d2+e2*x)^(p+1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*f*n/(2*c*(p+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m-1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && LtQ[p,-1] && IGtQ[m,1]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p<-1 ∧ m∈(SuperMinus[ℤ])

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ p<-1 ∧ m∈(SuperMinus[ℤ]), then

∫ (((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

-(((((f x))^(m+1)) (((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n))/(2 d f (p+1)))+
((m+2 p+3)/(2 d (p+1)))∫(((f x))^m)(((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n)dx-
((b c n (((d+e (x^2)))^p))/(2 f (p+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m+1)) (((1+c x))^(p+(1/2))) (((-1+c x))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  -(f*x)^(m+1)*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n/(2*d*f*(p+1)) + 
  (m+2*p+3)/(2*d*(p+1))*Int[(f*x)^m*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*c*n/(2*f*(p+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m+1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && LtQ[p,-1] && Not[GtQ[m,1]] && (IntegerQ[m] || IntegerQ[p] || EqQ[n,1])

Int[(f_.*x_)^m_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  -(f*x)^(m+1)*(d1+e1*x)^(p+1)*(d2+e2*x)^(p+1)*(a+b*ArcCosh[c*x])^n/(2*d1*d2*f*(p+1)) + 
  (m+2*p+3)/(2*d1*d2*(p+1))*Int[(f*x)^m*(d1+e1*x)^(p+1)*(d2+e2*x)^(p+1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*c*n/(2*f*(p+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m+1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && LtQ[p,-1] && Not[GtQ[m,1]] && (IntegerQ[m] || EqQ[n,1])

6:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ m-1∈(SuperPlus[ℤ])∧ m+2 p+1≠0

Derivation: Inverted integration by parts

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ m-1∈(SuperPlus[ℤ])∧ m+2 p+1≠0, then

∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

((f(((f x))^(m-1)) (((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n))/(e(m+2 p+1)))+
(((f^2)(m-1))/((c^2) (m+2 p+1)))∫(((f x))^(m-2))(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx-
((b f n (((d+e (x^2)))^p))/(c(m+2 p+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m-1)) (((1+c x))^(p+(1/2))) (((-1+c x))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  f*(f*x)^(m-1)*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n/(e*(m+2*p+1)) + 
  f^2*(m-1)/(c^2*(m+2*p+1))*Int[(f*x)^(m-2)*(d+e*x^2)^p*(a+b*ArcCosh[c*x])^n,x] - 
  b*f*n/(c*(m+2*p+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m-1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,p},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && IGtQ[m,1] && NeQ[m+2*p+1,0]

Int[(f_.*x_)^m_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  f*(f*x)^(m-1)*(d1+e1*x)^(p+1)*(d2+e2*x)^(p+1)*(a+b*ArcCosh[c*x])^n/(e1*e2*(m+2*p+1)) + 
  f^2*(m-1)/(c^2*(m+2*p+1))*Int[(f*x)^(m-2)*(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^n,x] - 
  b*f*n/(c*(m+2*p+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m-1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,p},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && IGtQ[m,1] && NeQ[m+2*p+1,0]

2.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n<-1

1:  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n<-1 ∧ m+2 p+1==0

Derivation: Integration by parts and piecewise constant extraction

Basis: ((((a+b ArcCosh[c x]))^n)/((Sqrt[1+c x]) (Sqrt[-1+c x])))==(∂_x)((((a+b ArcCosh[c x]))^(n+1))/(b c(n+1)))

Basis: If  (c^2) d+e==0 ∧ m+2 p+1==0, then (∂_x)((((f x))^m) (Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p))==-((f m (((f x))^(m-1)) (((d+e (x^2)))^p))/((Sqrt[1+c x]) (Sqrt[-1+c x])))

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/((((1+c x))^p) (((-1+c x))^p)))==0

Rule: If  (c^2) d+e==0 ∧ n<-1 ∧ m+2 p+1==0, then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  
(((((f x))^m) (Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)))/(b c (n+1)))+
((f m (((d+e (x^2)))^p) )/(b c (n+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m-1))(((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2)))(((a+b ArcCosh[c x]))^(n+1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  (f*x)^m*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]*(d+e*x^2)^p]*(a+b*ArcCosh[c*x])^(n+1)/(b*c*(n+1)) + 
  f*m/(b*c*(n+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m-1)*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && EqQ[c^2*d+e,0] && LtQ[n,-1] && EqQ[m+2*p+1,0]

Int[(f_.*x_)^m_.*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  (f*x)^m*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]*(d1+e1*x)^p]*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^(n+1)/(b*c*(n+1)) + 
  f*m/(b*c*(n+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m-1)*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m,p},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && LtQ[n,-1] && EqQ[m+2*p+1,0]

2:  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n<-1 ∧ 2p∈(SuperPlus[ℤ])∧ m+2 p+1≠0

Derivation: Integration by parts and piecewise constant extraction

Basis: ((((a+b ArcCosh[c x]))^n)/((Sqrt[1+c x]) (Sqrt[-1+c x])))==(∂_x)((((a+b ArcCosh[c x]))^(n+1))/(b c(n+1)))

Basis: If  (c^2) d+e==0, then (∂_x)((((f x))^m) (Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p))==-((f m (((f x))^(m-1)) (((d+e (x^2)))^p))/((Sqrt[1+c x]) (Sqrt[-1+c x])))+(((c^2) (m+2 p+1) (((f x))^(m+1)) (((d+e (x^2)))^p))/(f (Sqrt[1+c x]) (Sqrt[-1+c x])))

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/((((1+c x))^p) (((-1+c x))^p)))==0

Basis: If  p+(1/2)∈ℤ, then (((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2)))==(((-1+(c^2) (x^2)))^(p-(1/2)))

Rule: If  (c^2) d+e==0 ∧ n<-1 ∧ 2p∈(SuperPlus[ℤ])∧ m+2 p+1≠0, then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

(((((f x))^m) (Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)))/(b c (n+1)))+
((f m)/(b c (n+1))) ∫(((((f x))^(m-1)) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)))/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx-
((c (m+2 p+1) )/(b f (n+1)))∫(((((f x))^(m+1)) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)) )/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx  ⟶  

(((((f x))^m) (Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)))/(b c (n+1)))+
((f m (((d+e (x^2)))^p) )/(b c (n+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m-1))(((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2)))(((a+b ArcCosh[c x]))^(n+1))dx-
((c (m+2 p+1) (((d+e (x^2)))^p) )/(b f (n+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m+1))(((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2)))(((a+b ArcCosh[c x]))^(n+1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  (f*x)^m*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]*(d+e*x^2)^p]*(a+b*ArcCosh[c*x])^(n+1)/(b*c*(n+1)) + 
  f*m/(b*c*(n+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m-1)*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n+1),x] - 
  c*(m+2*p+1)/(b*f*(n+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m+1)*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && EqQ[c^2*d+e,0] && LtQ[n,-1] && IGtQ[2*p,0] && NeQ[m+2*p+1,0] && IGtQ[m,-3]

Int[(f_.*x_)^m_.*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  (f*x)^m*Sqrt[1+c*x]*Sqrt[-1+c*x]*(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^(n+1)/(b*c*(n+1)) + 
  f*m/(b*c*(n+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m-1)*(-1+c^2*x^2)^(p-1/2)*(a+b*ArcCosh[c*x])^(n+1),x] - 
  c*(m+2*p+1)/(b*f*(n+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m+1)*(-1+c^2*x^2)^(p-1/2)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m,p},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && LtQ[n,-1] && IGtQ[p+1/2,0] && NeQ[m+2*p+1,0] && IGtQ[m,-3]

3:  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n<-1 ∧ p≯0 ∧ p≠-(1/2)

Derivation: Integration by parts and piecewise constant extraction

Basis: ((((a+b ArcCosh[c x]))^n)/((Sqrt[1+c x]) (Sqrt[-1+c x])))==(∂_x)((((a+b ArcCosh[c x]))^(n+1))/(b c(n+1)))

Basis: If  (c^2) d+e==0, then (∂_x)((((f x))^m) (Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p))==f m (((f x))^(m-1)) (Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p)+(((c^2) (2 p+1) (((f x))^(m+1)) (((d+e (x^2)))^p))/(f (Sqrt[1+c x]) (Sqrt[-1+c x])))

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/((((1+c x))^p) (((-1+c x))^p)))==0

Basis: If  p+(1/2)∈ℤ, then (((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2)))==(((-1+(c^2) (x^2)))^(p-(1/2)))

Rule: If  (c^2) d+e==0 ∧ n<-1 ∧ p≯0 ∧ p≠-(1/2), then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx

  ⟶  (((((f x))^m) (Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)))/(b c (n+1)))-
((f m)/(b c (n+1))) ∫(((f x))^(m-1))(Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1))dx-
((c (2 p+1) )/(b f (n+1)))∫(((((f x))^(m+1)) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)))/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

  ⟶  (((((f x))^m) (Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)))/(b c (n+1)))-
((f m (((d+e (x^2)))^p))/(b c (n+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m-1)) (((1+c x))^(p+(1/2))) (((-1+c x))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n+1))dx-
((c (2 p+1) (((d+e (x^2)))^p))/(b f(n+1) (((1+c x))^p) (((-1+c x))^p)))∫(((f x))^(m+1)) (((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2))) (((a+b ArcCosh[c x]))^(n+1))dx

Program code:

(* Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  (f*x)^m*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]*(d+e*x^2)^p]*(a+b*ArcCosh[c*x])^(n+1)/(b*c*(n+1)) - 
  f*m/(b*c*(n+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m-1)*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n+1),x] - 
  c*(2*p+1)/(b*f*(n+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[(f*x)^(m+1)*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && EqQ[c^2*d+e,0] && LtQ[n,-1] && NeQ[p,-1/2] && IntegerQ[2*p] && IGtQ[m,-3] *)

(* Int[(f_.*x_)^m_.*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  (f*x)^m*Sqrt[1+c*x]*Sqrt[-1+c*x]*(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^(n+1)/(b*c*(n+1)) - 
  f*m/(b*c*(n+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m-1)*(-1+c^2*x^2)^(p+1/2)*(a+b*ArcCosh[c*x])^(n+1),x] - 
  c*(2*p+1)/(b*f*(n+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[(f*x)^(m+1)*(-1+c^2*x^2)^(p-1/2)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m,p},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && LtQ[n,-1] && ILtQ[p+1/2,0] && IGtQ[m,-3] *)

3.  ∫(((((f x))^m) (((a+b ArcCosh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0

1.  ∫(((((f x))^m) (((a+b ArcCosh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ n>0

1:  ∫(((((f x))^m) (((a+b ArcCosh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ n>0 ∧ m-1∈(SuperPlus[ℤ])

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ m-1∈(SuperPlus[ℤ]), then

∫(((((f x))^m) (((a+b ArcCosh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  ⟶  
((f (((f x))^(m-1)) (Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n))/(e m))-
((b f n(Sqrt[1+c x]) (Sqrt[-1+c x]))/(c m(Sqrt[d+e (x^2)])))∫(((f x))^(m-1)) (((a+b ArcCosh[c x]))^(n-1))dx+(((f^2)(m-1))/((c^2) m))∫(((((f x))^(m-2)) (((a+b ArcCosh[c x]))^n))/(Sqrt[d+e (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcCosh[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  f*(f*x)^(m-1)*Sqrt[d+e*x^2]*(a+b*ArcCosh[c*x])^n/(e*m) - 
  b*f*n/(c*m)*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]/Sqrt[d+e*x^2]]*Int[(f*x)^(m-1)*(a+b*ArcCosh[c*x])^(n-1),x] + 
  f^2*(m-1)/(c^2*m)*Int[(f*x)^(m-2)*(a+b*ArcCosh[c*x])^n/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && IGtQ[m,1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCosh[c_.*x_])^n_./(Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]),x_Symbol] :=
  f*(f*x)^(m-1)*Sqrt[d1+e1*x]*Sqrt[d2+e2*x]*(a+b*ArcCosh[c*x])^n/(e1*e2*m) - 
  b*f*n/(c*m)*Simp[Sqrt[1+c*x]/Sqrt[d1+e1*x]]*Simp[Sqrt[-1+c*x]/Sqrt[d2+e2*x]]*
    Int[(f*x)^(m-1)*(a+b*ArcCosh[c*x])^(n-1),x] + 
  f^2*(m-1)/(c^2*m)*Int[(f*x)^(m-2)*(a+b*ArcCosh[c*x])^n/(Sqrt[d1+e1*x]*Sqrt[d2+e2*x]),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && IGtQ[m,1]

2:  ∫(((x^m) (((a+b ArcCosh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ n∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  (c^2) d+e==0, then (∂_x)(((Sqrt[1+c x]) (Sqrt[-1+c x]))/(Sqrt[d+e (x^2)]))==0

Basis: If  m∈ℤ, then ((x^m)/((Sqrt[1+c x]) (Sqrt[-1+c x])))==(1/(c^(m+1))) Subst[((Cosh[x])^m),x,ArcCosh[c x]](∂_x)ArcCosh[c x]

Note: If  n∈(SuperPlus[ℤ]), then (((a+b x))^n)Cosh[x] is integrable in closed-form.

Rule: If  (c^2) d+e==0 ∧ n∈(SuperPlus[ℤ])∧ m∈ℤ, then

∫(((x^m) (((a+b ArcCosh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  ⟶  (((Sqrt[1+c x]) (Sqrt[-1+c x]))/((c^(m+1)) (Sqrt[d+e (x^2)])))Subst[∫(((a+b x))^n) ((Cosh[x])^m)dx,x,ArcCosh[c x]]

Program code:

Int[x_^m_*(a_.+b_.*ArcCosh[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  1/c^(m+1)*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]/Sqrt[d+e*x^2]]*
    Subst[Int[(a+b*x)^n*Cosh[x]^m,x],x,ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[n,0] && IntegerQ[m]

Int[x_^m_*(a_.+b_.*ArcCosh[c_.*x_])^n_./(Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]),x_Symbol] :=
  1/c^(m+1)*Simp[Sqrt[1+c*x]/Sqrt[d1+e1*x]]*Simp[Sqrt[-1+c*x]/Sqrt[d2+e2*x]]*
    Subst[Int[(a+b*x)^n*Cosh[x]^m,x],x,ArcCosh[c*x]] /;
FreeQ[{a,b,c,d1,e1,d2,e2},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && IGtQ[n,0] && IntegerQ[m]

3:  ∫(((((f x))^m) (a+b ArcCosh[c x]))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ m∉ℤ

Rule: If  (c^2) d+e==0 ∧ m∉ℤ, then

∫(((((f x))^m) (a+b ArcCosh[c x]))/(Sqrt[d+e (x^2)]))dx  ⟶  
(((((f x))^(m+1)) (Sqrt[1-(c^2) (x^2)]) (a+b ArcCosh[c x]))/(f (m+1) (Sqrt[d+e (x^2)]))) Hypergeometric2F1[(1/2),((1+m)/2),((3+m)/2),(c^2) (x^2)]+
((b c (((f x))^(m+2)) (Sqrt[1+c x]) (Sqrt[-1+c x]))/((f^2) (m+1) (m+2) (Sqrt[d+e (x^2)])))  HypergeometricPFQ[{1,1+(m/2),1+(m/2)},{(3/2)+(m/2),2+(m/2)},(c^2) (x^2)]

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcCosh[c_.*x_])/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  (f*x)^(m+1)/(f*(m+1))*Simp[Sqrt[1-c^2*x^2]/Sqrt[d+e*x^2]]*
    (a+b*ArcCosh[c*x])*Hypergeometric2F1[1/2,(1+m)/2,(3+m)/2,c^2*x^2] + 
  b*c*(f*x)^(m+2)/(f^2*(m+1)*(m+2))*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]/Sqrt[d+e*x^2]]*
    HypergeometricPFQ[{1,1+m/2,1+m/2},{3/2+m/2,2+m/2},c^2*x^2] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && Not[IntegerQ[m]]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCosh[c_.*x_])/(Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]),x_Symbol] :=
  (f*x)^(m+1)/(f*(m+1))*Simp[Sqrt[1-c^2*x^2]/(Sqrt[d1+e1*x]*Sqrt[d2+e2*x])]*
    (a+b*ArcCosh[c*x])*Hypergeometric2F1[1/2,(1+m)/2,(3+m)/2,c^2*x^2] + 
  b*c*(f*x)^(m+2)/(f^2*(m+1)*(m+2))*Simp[Sqrt[1+c*x]/Sqrt[d1+e1*x]]*Simp[Sqrt[-1+c*x]/Sqrt[d2+e2*x]]*
    HypergeometricPFQ[{1,1+m/2,1+m/2},{3/2+m/2,2+m/2},c^2*x^2] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && Not[IntegerQ[m]]

2:  ∫(((((f x))^m) (((a+b ArcCosh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ n<-1

Derivation: Integration by parts and piecewise constant extraction

Basis: ((((a+b ArcCosh[c x]))^n)/((Sqrt[1+c x]) (Sqrt[-1+c x])))==(∂_x)((((a+b ArcCosh[c x]))^(n+1))/(b c (n+1)))

Basis: If  (c^2) d+e==0, then (∂_x)(((((f x))^m) (Sqrt[1+c x]) (Sqrt[-1+c x]))/(Sqrt[d+e (x^2)]))==((f m (((f x))^(m-1)) (Sqrt[1+c x]) (Sqrt[-1+c x]))/(Sqrt[d+e (x^2)]))

Basis: If  (c^2) d+e==0, then (∂_x)(((Sqrt[1+c x]) (Sqrt[-1+c x]) )/(Sqrt[d+e (x^2)]))==0

Rule: If  (c^2) d+e==0 ∧ n<-1, then

∫(((((f x))^m) (((a+b ArcCosh[c x]))^n))/(Sqrt[d+e (x^2)]))dx

  ⟶  (((((f x))^m) (((a+b ArcCosh[c x]))^(n+1)) (Sqrt[1+c x]) (Sqrt[-1+c x]))/(b c (n+1) (Sqrt[d+e (x^2)])))-((f m (Sqrt[1+c x]) (Sqrt[-1+c x]) )/(b c (n+1) (Sqrt[d+e (x^2)]))) ∫(((f x))^(m-1)) (((a+b ArcCosh[c x]))^(n+1))dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*ArcCosh[c_.*x_])^n_/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  (f*x)^m*(a+b*ArcCosh[c*x])^(n+1)/(b*c*(n+1))*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]/Sqrt[d+e*x^2]] - 
  f*m/(b*c*(n+1))*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]/Sqrt[d+e*x^2]]*Int[(f*x)^(m-1)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && LtQ[n,-1]

Int[(f_.*x_)^m_.*(a_.+b_.*ArcCosh[c_.*x_])^n_/(Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]),x_Symbol] :=
  (f*x)^m*(a+b*ArcCosh[c*x])^(n+1)/(b*c*(n+1))*Simp[Sqrt[1+c*x]/Sqrt[d1+e1*x]]*Simp[Sqrt[-1+c*x]/Sqrt[d2+e2*x]] - 
  f*m/(b*c*(n+1))*Simp[Sqrt[1+c*x]/Sqrt[d1+e1*x]]*Simp[Sqrt[-1+c*x]/Sqrt[d2+e2*x]]*
    Int[(f*x)^(m-1)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && LtQ[n,-1]

4:  ∫(x^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ 2 p+2∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/((((1+c x))^p) (((-1+c x))^p)))==0

Basis: If  2 p∈ℤ ∧ m∈ℤ, then (x^m) (((1+c x))^p) (((-1+c x))^p)==(1/(b (c^(m+1)))) Subst[((Cosh[-(a/b)+(x/b)])^m) ((Sinh[-(a/b)+(x/b)])^(2p+1)),x,a+b ArcCosh[c x]] (∂_x)(a+b ArcCosh[c x])

Note: If  2 p+2∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ]), then (x^n) ((Cosh[-(a/b)+(x/b)])^m) ((Sinh[-(a/b)+(x/b)])^(2p+1)) is integrable in closed-form.

Rule: If  (c^2) d+e==0 ∧ 2 p+2∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ]), then

∫(x^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx

  ⟶  ((((d+e (x^2)))^p)/((((1+c x))^p) (((-1+c x))^p))) ∫(x^m) (((1+c x))^p) (((-1+c x))^p) (((a+b ArcCosh[c x]))^n)dx

  ⟶  ((((d+e (x^2)))^p)/(b (c^(m+1)) (((1+c x))^p) (((-1+c x))^p))) Subst[∫(x^n) ((Cosh[-(a/b)+(x/b)])^m) ((Sinh[-(a/b)+(x/b)])^(2p+1))dx,x,a+b ArcCosh[c x]]

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  1/(b*c^(m+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Subst[Int[x^n*Cosh[-a/b+x/b]^m*Sinh[-a/b+x/b]^(2*p+1),x],x,a+b*ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[c^2*d+e,0] && IGtQ[2*p+2,0] && IGtQ[m,0]

Int[x_^m_.*(d1_+e1_.*x_)^p_.*(d2_+e2_.*x_)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  1/(b*c^(m+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Subst[Int[x^n*Cosh[-a/b+x/b]^m*Sinh[-a/b+x/b]^(2*p+1),x],x,a+b*ArcCosh[c*x]] /;
FreeQ[{a,b,c,d1,e1,d2,e2,n},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && IGtQ[p+3/2,0] && IGtQ[m,0]

5:  ∫(((f x))^m)(((d+e (x^2)))^p)(((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ p+(1/2)∈(SuperPlus[ℤ])∧ ((m+1)/2)∉(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  (c^2) d+e==0 ∧ p+(1/2)∈(SuperPlus[ℤ])∧ ((m+1)/2)∉(SuperPlus[ℤ]), then

∫(((f x))^m)(((d+e (x^2)))^p)(((a+b ArcCosh[c x]))^n)dx  ⟶  ∫((((a+b ArcCosh[c x]))^n)/(Sqrt[d+e (x^2)]))ExpandIntegrand[(((f x))^m) (((d+e (x^2)))^(p+(1/2))),x]dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCosh[c*x])^n/Sqrt[d+e*x^2],(f*x)^m*(d+e*x^2)^(p+1/2),x],x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && EqQ[c^2*d+e,0] && IGtQ[p+1/2,0] && Not[IGtQ[(m+1)/2,0]] && (EqQ[m,-1] || EqQ[m,-2])

Int[(f_.*x_)^m_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCosh[c*x])^n/(Sqrt[d1+e1*x]*Sqrt[d2+e2*x]),(f*x)^m*(d1+e1*x)^(p+1/2)*(d2+e2*x)^(p+1/2),x],x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m,n},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[d1,0] && LtQ[d2,0] && IGtQ[p+1/2,0] && Not[IGtQ[(m+1)/2,0]] && 
  (EqQ[m,-1] || EqQ[m,-2])

2.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e≠ 0

0:  ∫(((f x))^m) (d+e (x^2)) (a+b ArcCosh[c x])dx  when  (c^2) d+e≠0 ∧ m≠-1 ∧ m≠-3

Derivation: Integration by parts

Note: This rule can be removed when integrands of the form (((d+e x))^m) (((f+g x))^m) (((a+c (x^2)))^p) when e f+d g==0 are integrated without first resorting to piecewise constant extraction.

Rule: If  (c^2) d+e≠0 ∧ m≠-1 ∧ m≠-3, then

∫(((f x))^m) (d+e (x^2)) (a+b ArcCosh[c x])dx  ⟶  
((d (((f x))^(m+1)) (a+b ArcCosh[c x]))/(f (m+1)))+((e (((f x))^(m+3)) (a+b ArcCosh[c x]))/((f^3) (m+3)))-((b c)/(f (m+1) (m+3))) ∫(((((f x))^(m+1)) (d (m+3)+e (m+1) (x^2)))/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  d*(f*x)^(m+1)*(a+b*ArcCosh[c*x])/(f*(m+1)) + 
  e*(f*x)^(m+3)*(a+b*ArcCosh[c*x])/(f^3*(m+3)) - 
  b*c/(f*(m+1)*(m+3))*Int[(f*x)^(m+1)*(d*(m+3)+e*(m+1)*x^2)/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && NeQ[c^2*d+e,0] && NeQ[m,-1] && NeQ[m,-3]

1:  ∫x (((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  when  (c^2) d+e≠ 0 ∧ p≠-1

Derivation: Integration by parts

Basis:: If  p≠-1, then x (((d+e (x^2)))^p)==(∂_x)((((d+e (x^2)))^(p+1))/(2 e (p+1)))

Rule: If  (c^2) d+e≠ 0 ∧ p≠-1, then

∫x (((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  ⟶  (((((d+e (x^2)))^(p+1)) (a+b ArcCosh[c x]))/(2 e (p+1)))-((b c)/(2 e (p+1)))∫((((d+e (x^2)))^(p+1))/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

Program code:

Int[x_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  (d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])/(2*e*(p+1)) - b*c/(2*e*(p+1))*Int[(d+e*x^2)^(p+1)/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[c^2*d+e,0] && NeQ[p,-1]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  when  (c^2) d+e≠ 0 ∧ p∈ℤ ∧ (p>0 ∨ ((m-1)/2)∈(SuperPlus[ℤ])∧ m+p≤0)

Derivation: Integration by parts

Note: If  ((m-1)/2)∈(SuperPlus[ℤ])∧ p∈(SuperMinus[ℤ])∧ m+p≥0, then ∫(((f x))^m) (((d+e (x^2)))^p) is a rational function.

Rule: If  (c^2) d+e≠ 0 ∧ p∈ℤ ∧ (p>0 ∨ ((m-1)/2)∈(SuperPlus[ℤ])∧ m+p≤0), let  u->∫(((f x))^m) (((d+e (x^2)))^p)dx, then

∫(((f x))^m) (((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  ⟶  u (a+b ArcCosh[c x])-b c∫(u/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^p,x]},  
  Dist[a+b*ArcCosh[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x],x]] /;
FreeQ[{a,b,c,d,e,f,m},x] && NeQ[c^2*d+e,0] && IntegerQ[p] && (GtQ[p,0] || IGtQ[(m-1)/2,0] && LeQ[m+p,0])

x:  ∫(x^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  m∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[x]==(1/(b c)) Subst[F[((Cosh[-(a/b)+(x/b)])/c)] Sinh[-(a/b)+(x/b)],x,a+b ArcCosh[c x]] (∂_x)(a+b ArcCosh[c x])

Note: If  m∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ]), then (x^n) ((Cosh[-(a/b)+(x/b)])^m) ((((c^2) d+e ((Cosh[-(a/b)+(x/b)])^2)))^p) Sinh[(a/b)-(x/b)] is integrable in closed-form.

Rule: If  m∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ]), then

∫(x^m) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶ (1/(b (c^(m+2 p+1)))) Subst[∫(x^n) ((Cosh[-(a/b)+(x/b)])^m) ((((c^2) d+e ((Cosh[-(a/b)+(x/b)])^2)))^p) Sinh[-(a/b)+(x/b)]dx,x,a+b ArcCosh[c x]]

Program code:

(* Int[x_^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  1/(b*c^(m+2*p+1))*Subst[Int[x^n*Cosh[-a/b+x/b]^m*(c^2*d+e*Cosh[-a/b+x/b]^2)^p*Sinh[-a/b+x/b],x],x,a+b*ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[m,0] && IGtQ[p,0] *)

3:  ∫(((f x))^m)(((d+e (x^2)))^p)(((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e≠ 0 ∧ n∈(SuperPlus[ℤ])∧ p∈ℤ ∧ m∈ℤ

Derivation: Algebraic expansion

Rule: If  (c^2) d+e≠ 0 ∧ n∈(SuperPlus[ℤ])∧ p∈ℤ ∧ m∈ℤ, then

∫(((f x))^m)(((d+e (x^2)))^p)(((a+b ArcCosh[c x]))^n)dx  ⟶  ∫(((a+b ArcCosh[c x]))^n) ExpandIntegrand[(((f x))^m)(((d+e (x^2)))^p),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCosh[c*x])^n,(f*x)^m*(d+e*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[c^2*d+e,0] && IGtQ[n,0] && IntegerQ[p] && IntegerQ[m]

U:  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx

Rule:

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[(f*x)^m*(d+e*x^2)^p*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p},x]

Int[(f_.*x_)^m_.*(d1_+e1_.*x_)^p_.*(d2_+e2_.*x_)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[(f*x)^m*(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,m,n,p},x]