Rules for integrands involving inverse hyperbolic cosines

1.  ∫u(((a+b ArcCosh[c+d x]))^n)dx

1:  ∫(((a+b ArcCosh[c+d x]))^n)dx

Derivation: Integration by substitution

Rule:

∫(((a+b ArcCosh[c+d x]))^n)dx  ⟶  (1/d) Subst[∫(((a+b ArcCosh[x]))^n)dx,x,c+d x]

Program code:

Int[(a_.+b_.*ArcCosh[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[(a+b*ArcCosh[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,n},x]

2:  ∫(((e+f x))^m)(((a+b ArcCosh[c+d x]))^n)dx

Derivation: Integration by substitution

Rule:

∫(((e+f x))^m)(((a+b ArcCosh[c+d x]))^n)dx  ⟶  (1/d)Subst[∫(((((d e-c f)/d)+((f x)/d)))^m)(((a+b ArcCosh[x]))^n)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcCosh[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(a+b*ArcCosh[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m,n},x]

3:  ∫(((A+B x+C (x^2)))^p)(((a+b ArcCosh[c+d x]))^n)dx  when  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0

Derivation: Integration by substitution

Basis: If  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0, then A+B x+C (x^2)==-(C/(d^2))+(C/(d^2))(((c+d x))^2)

Rule: If  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0, then

∫(((A+B x+C (x^2)))^p)(((a+b ArcCosh[c+d x]))^n)dx  ⟶  (1/d)Subst[∫(((-(C/(d^2))+((C (x^2))/(d^2))))^p)(((a+b ArcCosh[x]))^n)dx,x,c+d x]

Program code:

Int[(A_.+B_.*x_+C_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[(-C/d^2+C/d^2*x^2)^p*(a+b*ArcCosh[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,A,B,C,n,p},x] && EqQ[B*(1-c^2)+2*A*c*d,0] && EqQ[2*c*C-B*d,0]

4:  ∫(((e+f x))^m)(((A+B x+C (x^2)))^p)(((a+b ArcCosh[c+d x]))^n)dx  when  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0

Derivation: Integration by substitution

Basis: If  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0, then A+B x+C (x^2)==-(C/(d^2))+(C/(d^2))(((c+d x))^2)

Rule: If  B (1-(c^2))+2 A c d==0 ∧ 2 c C-B d==0, then

∫(((e+f x))^m)(((A+B x+C (x^2)))^p)(((a+b ArcCosh[c+d x]))^n)dx  ⟶  (1/d)Subst[∫(((((d e-c f)/d)+((f x)/d)))^m)(((-(C/(d^2))+((C (x^2))/(d^2))))^p)(((a+b ArcCosh[x]))^n)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*(A_.+B_.*x_+C_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(-C/d^2+C/d^2*x^2)^p*(a+b*ArcCosh[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,A,B,C,m,n,p},x] && EqQ[B*(1-c^2)+2*A*c*d,0] && EqQ[2*c*C-B*d,0]

2.  ∫(((a+b ArcCosh[c+d (x^2)]))^n)dx  when  (c^2)==1

1.  ∫(((a+b ArcCosh[c+d (x^2)]))^n)dx  when  (c^2)==1 ∧ n>0

1.  ∫(Sqrt[a+b ArcCosh[c+d (x^2)]])dx  when  (c^2)==1

1:  ∫(Sqrt[a+b ArcCosh[1+d (x^2)]])dx

Rule:

∫(Sqrt[a+b ArcCosh[1+d (x^2)]])dx  ⟶  
((2 (Sqrt[a+b ArcCosh[1+d (x^2)]]) ((Sinh[(1/2) ArcCosh[1+d (x^2)]])^2))/(d x)) -
(((Sqrt[b]) (Sqrt[(π/2)]) (Cosh[(a/(2 b))]-Sinh[(a/(2 b))]) Sinh[(1/2) ArcCosh[1+d (x^2)]] Erfi[(1/(Sqrt[2 b]))(Sqrt[a+b ArcCosh[1+d (x^2)]])])/(d x))+
(((Sqrt[b]) (Sqrt[(π/2)]) (Cosh[(a/(2 b))]+Sinh[(a/(2 b))]) Sinh[(1/2) ArcCosh[1+d (x^2)]]Erf[(1/(Sqrt[2 b]))(Sqrt[a+b ArcCosh[1+d (x^2)]])])/(d x))

Program code:

Int[Sqrt[a_.+b_.*ArcCosh[1+d_.*x_^2]],x_Symbol] :=
  2*Sqrt[a+b*ArcCosh[1+d*x^2]]*Sinh[(1/2)*ArcCosh[1+d*x^2]]^2/(d*x) - 
  Sqrt[b]*Sqrt[Pi/2]*(Cosh[a/(2*b)]-Sinh[a/(2*b)])*Sinh[(1/2)*ArcCosh[1+d*x^2]]*
    Erfi[(1/Sqrt[2*b])*Sqrt[a+b*ArcCosh[1+d*x^2]]]/(d*x) + 
  Sqrt[b]*Sqrt[Pi/2]*(Cosh[a/(2*b)]+Sinh[a/(2*b)])*Sinh[(1/2)*ArcCosh[1+d*x^2]]*
    Erf[(1/Sqrt[2*b])*Sqrt[a+b*ArcCosh[1+d*x^2]]]/(d*x) /;
FreeQ[{a,b,d},x]

2:  ∫(Sqrt[a+b ArcCosh[-1+d (x^2)]])dx

Rule:

∫(Sqrt[a+b ArcCosh[-1+d (x^2)]])dx  ⟶  
((2 (Sqrt[a+b ArcCosh[-1+d (x^2)]]) ((Cosh[(1/2) ArcCosh[-1+d (x^2)]])^2))/(d x))-
(((Sqrt[b]) (Sqrt[(π/2)]) (Cosh[(a/(2 b))]-Sinh[(a/(2 b))]) Cosh[(1/2) ArcCosh[-1+d (x^2)]] Erfi[(1/(Sqrt[2 b]))(Sqrt[a+b ArcCosh[-1+d (x^2)]])])/(d x))-
(((Sqrt[b]) (Sqrt[(π/2)]) (Cosh[(a/(2 b))]+Sinh[(a/(2 b))]) Cosh[(1/2) ArcCosh[-1+d (x^2)]] Erf[(1/(Sqrt[2 b]))(Sqrt[a+b ArcCosh[-1+d (x^2)]])])/(d x))

Program code:

Int[Sqrt[a_.+b_.*ArcCosh[-1+d_.*x_^2]],x_Symbol] :=
  2*Sqrt[a+b*ArcCosh[-1+d*x^2]]*Cosh[(1/2)*ArcCosh[-1+d*x^2]]^2/(d*x) - 
  Sqrt[b]*Sqrt[Pi/2]*(Cosh[a/(2*b)]-Sinh[a/(2*b)])*Cosh[(1/2)*ArcCosh[-1+d*x^2]]*
    Erfi[(1/Sqrt[2*b])*Sqrt[a+b*ArcCosh[-1+d*x^2]]]/(d*x) - 
  Sqrt[b]*Sqrt[Pi/2]*(Cosh[a/(2*b)]+Sinh[a/(2*b)])*Cosh[(1/2)*ArcCosh[-1+d*x^2]]*
    Erf[(1/Sqrt[2*b])*Sqrt[a+b*ArcCosh[-1+d*x^2]]]/(d*x) /;
FreeQ[{a,b,d},x]

2:  ∫(((a+b ArcCosh[c+d (x^2)]))^n)dx  when  (c^2)==1 ∧ n>1

Derivation: Integration by parts and piecewise constant extraction both twice!

Basis: (∂_x)(((a+b ArcCosh[c+d (x^2)]))^n)==((2 b d n x (((a+b ArcCosh[c+d (x^2)]))^(n-1)))/((Sqrt[-1+c+d (x^2)]) (Sqrt[1+c+d (x^2)])))

Basis: If  (c^2)==1, then (∂_x)((Sqrt[2 c d (x^2)+(d^2) (x^4)])/((Sqrt[-1+c+d (x^2)]) (Sqrt[1+c+d (x^2)])))==0

Basis: ((x^2)/(Sqrt[2 c d (x^2)+(d^2) (x^4)]))==(∂_x)((Sqrt[2 c d (x^2)+(d^2) (x^4)])/((d^2) x))

Rule: If  (c^2)==1 ∧ n>1, then

∫(((a+b ArcCosh[c+d (x^2)]))^n)dx  ⟶  x (((a+b ArcCosh[c+d (x^2)]))^n)-2 b d n∫(((x^2) (((a+b ArcCosh[c+d (x^2)]))^(n-1)))/((Sqrt[-1+c+d (x^2)]) (Sqrt[1+c+d (x^2)])))dx

  ⟶  x (((a+b ArcCosh[c+d (x^2)]))^n)-((2 b d n (Sqrt[2 c d (x^2)+(d^2) (x^4)]))/((Sqrt[-1+c+d (x^2)]) (Sqrt[1+c+d (x^2)])))∫(((x^2) (((a+b ArcCosh[c+d (x^2)]))^(n-1)))/(Sqrt[2 c d (x^2)+(d^2) (x^4)]))dx

  ⟶  x (((a+b ArcCosh[c+d (x^2)]))^n)-((2 b n (2 c d (x^2)+(d^2) (x^4)) (((a+b ArcCosh[c+d (x^2)]))^(n-1)))/(d x (Sqrt[-1+c+d (x^2)]) (Sqrt[1+c+d (x^2)])))+4 (b^2) n(n-1)∫(((a+b ArcCosh[c+d (x^2)]))^(n-2))dx

Program code:

Int[(a_.+b_.*ArcCosh[c_+d_.*x_^2])^n_,x_Symbol] :=
  x*(a+b*ArcCosh[c+d*x^2])^n - 
  2*b*n*(2*c*d*x^2+d^2*x^4)*(a+b*ArcCosh[c+d*x^2])^(n-1)/(d*x*Sqrt[-1+c+d*x^2]*Sqrt[1+c+d*x^2]) + 
  4*b^2*n*(n-1)*Int[(a+b*ArcCosh[c+d*x^2])^(n-2),x] /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1] && GtQ[n,1]

2.  ∫(((a+b ArcCosh[c+d (x^2)]))^n)dx  when  (c^2)==1 ∧ n<0

1.  ∫(1/(a+b ArcCosh[c+d (x^2)]))dx  when  (c^2)==1

1:  ∫(1/(a+b ArcCosh[1+d (x^2)]))dx

Rule:

∫(1/(a+b ArcCosh[1+d (x^2)]))dx  ⟶  
((x Cosh[(a/(2 b))] CoshIntegral[(1/(2 b))(a+b ArcCosh[1+d (x^2)])])/((Sqrt[2]) b (Sqrt[d (x^2)])))-((x Sinh[(a/(2 b))] SinhIntegral[(1/(2 b))(a+b ArcCosh[1+d (x^2)])])/((Sqrt[2]) b (Sqrt[d (x^2)])))

Program code:

Int[1/(a_.+b_.*ArcCosh[1+d_.*x_^2]),x_Symbol] :=
  x*Cosh[a/(2*b)]*CoshIntegral[(a+b*ArcCosh[1+d*x^2])/(2*b)]/(Sqrt[2]*b*Sqrt[d*x^2]) - 
  x*Sinh[a/(2*b)]*SinhIntegral[(a+b*ArcCosh[1+d*x^2])/(2*b)]/(Sqrt[2]*b*Sqrt[d*x^2]) /;
FreeQ[{a,b,d},x]

2:  ∫(1/(a+b ArcCosh[-1+d (x^2)]))dx

Rule:

∫(1/(a+b ArcCosh[-1+d (x^2)]))dx  ⟶  
-((x Sinh[(a/(2 b))]CoshIntegral[(1/(2 b))(a+b ArcCosh[-1+d (x^2)])])/((Sqrt[2]) b (Sqrt[d (x^2)])))+((x Cosh[(a/(2 b))] SinhIntegral[(1/(2 b))(a+b ArcCosh[-1+d (x^2)])])/((Sqrt[2]) b (Sqrt[d (x^2)])))

Program code:

Int[1/(a_.+b_.*ArcCosh[-1+d_.*x_^2]),x_Symbol] :=
  -x*Sinh[a/(2*b)]*CoshIntegral[(a+b*ArcCosh[-1+d*x^2])/(2*b)]/(Sqrt[2]*b*Sqrt[d*x^2]) + 
  x*Cosh[a/(2*b)]*SinhIntegral[(a+b*ArcCosh[-1+d*x^2])/(2*b)]/(Sqrt[2]*b*Sqrt[d*x^2]) /;
FreeQ[{a,b,d},x]

2.  ∫(1/(Sqrt[a+b ArcCosh[c+d (x^2)]]))dx  when  (c^2)==1

1:  ∫(1/(Sqrt[a+b ArcCosh[1+d (x^2)]]))dx

Rule:

∫(1/(Sqrt[a+b ArcCosh[1+d (x^2)]]))dx  ⟶  
(((Sqrt[(π/2)]) (Cosh[(a/(2 b))]-Sinh[(a/(2 b))]) Sinh[(1/2) ArcCosh[1+d (x^2)]] Erfi[(1/(Sqrt[2 b]))(Sqrt[a+b ArcCosh[1+d (x^2)]])])/((Sqrt[b]) d x))+
(((Sqrt[(π/2)]) (Cosh[(a/(2 b))]+Sinh[(a/(2 b))]) Sinh[(1/2) ArcCosh[1+d (x^2)]] Erf[(1/(Sqrt[2 b]))(Sqrt[a+b ArcCosh[1+d (x^2)]])])/((Sqrt[b]) d x))

Program code:

Int[1/Sqrt[a_.+b_.*ArcCosh[1+d_.*x_^2]],x_Symbol] :=
  Sqrt[Pi/2]*(Cosh[a/(2*b)]-Sinh[a/(2*b)])*Sinh[ArcCosh[1+d*x^2]/2]*Erfi[Sqrt[a+b*ArcCosh[1+d*x^2]]/Sqrt[2*b]]/(Sqrt[b]*d*x) + 
  Sqrt[Pi/2]*(Cosh[a/(2*b)]+Sinh[a/(2*b)])*Sinh[ArcCosh[1+d*x^2]/2]*Erf[Sqrt[a+b*ArcCosh[1+d*x^2]]/Sqrt[2*b]]/(Sqrt[b]*d*x) /;
FreeQ[{a,b,d},x]

2:  ∫(1/(Sqrt[a+b ArcCosh[-1+d (x^2)]]))dx

Rule:

∫(1/(Sqrt[a+b ArcCosh[-1+d (x^2)]]))dx  ⟶  
(((Sqrt[(π/2)]) (Cosh[(a/(2 b))]-Sinh[(a/(2 b))]) Cosh[(1/2) ArcCosh[-1+d (x^2)]] Erfi[(1/(Sqrt[2 b]))(Sqrt[a+b ArcCosh[-1+d (x^2)]])])/((Sqrt[b]) d x))-
(((Sqrt[(π/2)]) (Cosh[(a/(2 b))]+Sinh[(a/(2 b))]) Cosh[(1/2) ArcCosh[-1+d (x^2)]] Erf[(1/(Sqrt[2 b]))(Sqrt[a+b ArcCosh[-1+d (x^2)]])])/((Sqrt[b]) d x))

Program code:

Int[1/Sqrt[a_.+b_.*ArcCosh[-1+d_.*x_^2]],x_Symbol] :=
  Sqrt[Pi/2]*(Cosh[a/(2*b)]-Sinh[a/(2*b)])*Cosh[ArcCosh[-1+d*x^2]/2]*Erfi[Sqrt[a+b*ArcCosh[-1+d*x^2]]/Sqrt[2*b]]/(Sqrt[b]*d*x) - 
  Sqrt[Pi/2]*(Cosh[a/(2*b)]+Sinh[a/(2*b)])*Cosh[ArcCosh[-1+d*x^2]/2]*Erf[Sqrt[a+b*ArcCosh[-1+d*x^2]]/Sqrt[2*b]]/(Sqrt[b]*d*x) /;
FreeQ[{a,b,d},x]

3.  ∫(((a+b ArcCosh[c+d (x^2)]))^n)dx  when  (c^2)==1 ∧ n<-1

1.  ∫(1/(((a+b ArcCosh[c+d (x^2)]))^(3/2)))dx  when  (c^2)==1

1:  ∫(1/(((a+b ArcCosh[1+d (x^2)]))^(3/2)))dx

Derivation: Integration by parts

Basis: -((b d x)/((Sqrt[d (x^2)]) (Sqrt[2+d (x^2)]) (((a+b ArcCosh[1+d (x^2)]))^(3/2))))==(∂_x)(1/(Sqrt[a+b ArcCosh[1+d (x^2)]]))

Rule:

∫(1/(((a+b ArcCosh[1+d (x^2)]))^(3/2)))dx  ⟶  -(((Sqrt[d (x^2)]) (Sqrt[2+d (x^2)]))/(b d x (Sqrt[a+b ArcCosh[1+d (x^2)]])))+(d/b)∫((x^2)/((Sqrt[d (x^2)]) (Sqrt[2+d (x^2)]) (Sqrt[a+b ArcCosh[1+d (x^2)]])))dx

  ⟶  -(((Sqrt[d (x^2)]) (Sqrt[2+d (x^2)]))/(b d x (Sqrt[a+b ArcCosh[1+d (x^2)]])))+
(((Sqrt[(π/2)]) (Cosh[(a/(2 b))]-Sinh[(a/(2 b))]) Sinh[(1/2) ArcCosh[1+d (x^2)]] Erfi[(1/(Sqrt[2b]))(Sqrt[a+b ArcCosh[1+d (x^2)]])])/((b^(3/2)) d x))-
(((Sqrt[(π/2)]) (Cosh[(a/(2 b))]+Sinh[(a/(2 b))]) Sinh[(1/2) ArcCosh[1+d (x^2)]] Erf[(1/(Sqrt[2b]))(Sqrt[a+b ArcCosh[1+d (x^2)]])])/((b^(3/2)) d x))

Program code:

Int[1/(a_.+b_.*ArcCosh[1+d_.*x_^2])^(3/2),x_Symbol] :=
  -Sqrt[d*x^2]*Sqrt[2+d*x^2]/(b*d*x*Sqrt[a+b*ArcCosh[1+d*x^2]]) + 
  Sqrt[Pi/2]*(Cosh[a/(2*b)]-Sinh[a/(2*b)])*Sinh[ArcCosh[1+d*x^2]/2]*Erfi[Sqrt[a+b*ArcCosh[1+d*x^2]]/Sqrt[2*b]]/(b^(3/2)*d*x)- 
  Sqrt[Pi/2]*(Cosh[a/(2*b)]+Sinh[a/(2*b)])*Sinh[ArcCosh[1+d*x^2]/2]*Erf[Sqrt[a+b*ArcCosh[1+d*x^2]]/Sqrt[2*b]]/(b^(3/2)*d*x) /;
FreeQ[{a,b,d},x]

2:  ∫(1/(((a+b ArcCosh[-1+d (x^2)]))^(3/2)))dx

Derivation: Integration by parts

Basis: -((b d x)/((Sqrt[d (x^2)]) (Sqrt[-2+d (x^2)]) (((a+b ArcCosh[-1+d (x^2)]))^(3/2))))==(∂_x)(1/(Sqrt[a+b ArcCosh[-1+d (x^2)]]))

Rule:

∫(1/(((a+b ArcCosh[-1+d (x^2)]))^(3/2)))dx  ⟶  -(((Sqrt[d (x^2)]) (Sqrt[-2+d (x^2)]))/(b d x (Sqrt[a+b ArcCosh[-1+d (x^2)]])))+(d/b)∫((x^2)/((Sqrt[d (x^2)]) (Sqrt[-2+d (x^2)]) (Sqrt[a+b ArcCosh[-1+d (x^2)]])))dx

  ⟶  -(((Sqrt[d (x^2)]) (Sqrt[-2+d (x^2)]))/(b d x (Sqrt[a+b ArcCosh[-1+d (x^2)]])))+
(((Sqrt[(π/2)]) (Cosh[(a/(2 b))]-Sinh[(a/(2 b))]) Cosh[(1/2) ArcCosh[-1+d (x^2)]] Erfi[(1/(Sqrt[2b]))(Sqrt[a+b ArcCosh[-1+d (x^2)]])])/((b^(3/2)) d x))+
(((Sqrt[(π/2)]) (Cosh[(a/(2 b))]+Sinh[(a/(2 b))]) Cosh[(1/2) ArcCosh[-1+d (x^2)]] Erf[(1/(Sqrt[2b]))(Sqrt[a+b ArcCosh[-1+d (x^2)]])])/((b^(3/2)) d x))

Program code:

Int[1/(a_.+b_.*ArcCosh[-1+d_.*x_^2])^(3/2),x_Symbol] :=
  -Sqrt[d*x^2]*Sqrt[-2+d*x^2]/(b*d*x*Sqrt[a+b*ArcCosh[-1+d*x^2]]) + 
  Sqrt[Pi/2]*(Cosh[a/(2*b)]-Sinh[a/(2*b)])*Cosh[ArcCosh[-1+d*x^2]/2]*Erfi[Sqrt[a+b*ArcCosh[-1+d*x^2]]/Sqrt[2*b]]/(b^(3/2)*d*x) + 
  Sqrt[Pi/2]*(Cosh[a/(2*b)]+Sinh[a/(2*b)])*Cosh[ArcCosh[-1+d*x^2]/2]*Erf[Sqrt[a+b*ArcCosh[-1+d*x^2]]/Sqrt[2*b]]/(b^(3/2)*d*x) /;
FreeQ[{a,b,d},x]

2.  ∫(1/(((a+b ArcCosh[c+d (x^2)]))^2))dx  when  (c^2)==1

1:  ∫(1/(((a+b ArcCosh[1+d (x^2)]))^2))dx

Rule:

∫(1/(((a+b ArcCosh[1+d (x^2)]))^2))dx  ⟶  
-(((Sqrt[d (x^2)]) (Sqrt[2+d (x^2)]))/(2 b d x (a+b ArcCosh[1+d (x^2)])))-((x Sinh[(a/(2 b))] CoshIntegral[(1/(2 b))(a+b ArcCosh[1+d (x^2)])])/(2(Sqrt[2]) (b^2) (Sqrt[d (x^2)])))+((x Cosh[(a/(2 b))] SinhIntegral[(1/(2 b))(a+b ArcCosh[1+d (x^2)])])/(2(Sqrt[2]) (b^2) (Sqrt[d (x^2)])))

Program code:

Int[1/(a_.+b_.*ArcCosh[1+d_.*x_^2])^2,x_Symbol] :=
  -Sqrt[d*x^2]*Sqrt[2+d*x^2]/(2*b*d*x*(a+b*ArcCosh[1+d*x^2])) - 
  x*Sinh[a/(2*b)]*CoshIntegral[(a+b*ArcCosh[1+d*x^2])/(2*b)]/(2*Sqrt[2]*b^2*Sqrt[d*x^2]) + 
  x*Cosh[a/(2*b)]*SinhIntegral[(a+b*ArcCosh[1+d*x^2])/(2*b)]/(2*Sqrt[2]*b^2*Sqrt[d*x^2]) /;
FreeQ[{a,b,d},x]

2:  ∫(1/(((a+b ArcCosh[-1+d (x^2)]))^2))dx

Rule:

∫(1/(((a+b ArcCosh[-1+d (x^2)]))^2))dx  ⟶  
-(((Sqrt[d (x^2)]) (Sqrt[-2+d (x^2)]))/(2 b d x (a+b ArcCosh[-1+d (x^2)])))+((x Cosh[(a/(2 b))] CoshIntegral[(1/(2 b))(a+b ArcCosh[-1+d (x^2)])])/(2(Sqrt[2]) (b^2) (Sqrt[d (x^2)])))-((x Sinh[(a/(2 b))] SinhIntegral[(1/(2 b))(a+b ArcCosh[-1+d (x^2)])])/(2(Sqrt[2]) (b^2) (Sqrt[d (x^2)])))

Program code:

Int[1/(a_.+b_.*ArcCosh[-1+d_.*x_^2])^2,x_Symbol] :=
  -Sqrt[d*x^2]*Sqrt[-2+d*x^2]/(2*b*d*x*(a+b*ArcCosh[-1+d*x^2])) + 
  x*Cosh[a/(2*b)]*CoshIntegral[(a+b*ArcCosh[-1+d*x^2])/(2*b)]/(2*Sqrt[2]*b^2*Sqrt[d*x^2]) - 
  x*Sinh[a/(2*b)]*SinhIntegral[(a+b*ArcCosh[-1+d*x^2])/(2*b)]/(2*Sqrt[2]*b^2*Sqrt[d*x^2]) /;
FreeQ[{a,b,d},x]

3:  ∫(((a+b ArcCosh[c+d (x^2)]))^n)dx  when  (c^2)==1 ∧ n<-1 ∧ n≠-2

Derivation: Inverted integration by parts and piecewise constant extraction both twice!

Rule: If  (c^2)==1 ∧ n<-1 ∧ n≠-2, then

∫(((a+b ArcCosh[c+d (x^2)]))^n)dx  ⟶  
-((x (((a+b ArcCosh[c+d (x^2)]))^(n+2)))/(4 (b^2) (n+1) (n+2)))+(((2 c (x^2)+d (x^4)) (((a+b ArcCosh[c+d (x^2)]))^(n+1)))/(2 b (n+1) x (Sqrt[-1+c+d (x^2)]) (Sqrt[1+c+d (x^2)])))+(1/(4 (b^2) (n+1) (n+2)))∫(((a+b ArcCosh[c+d (x^2)]))^(n+2))dx

Program code:

Int[(a_.+b_.*ArcCosh[c_+d_.*x_^2])^n_,x_Symbol] :=
  -x*(a+b*ArcCosh[c+d*x^2])^(n+2)/(4*b^2*(n+1)*(n+2)) + 
  (2*c*x^2 +d*x^4)*(a+b*ArcCosh[c+d*x^2])^(n+1)/(2*b*(n+1)*x*Sqrt[-1+c+d*x^2]*Sqrt[1+c+d*x^2]) + 
  1/(4*b^2*(n+1)*(n+2))*Int[(a+b*ArcCosh[c+d*x^2])^(n+2),x] /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,1] && LtQ[n,-1] && NeQ[n,-2]

3:  ∫(((ArcCosh[a (x^p)])^n)/x)dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: (((ArcCosh[a (x^p)])^n)/x)==(1/p) Subst[(x^n) Tanh[x],x,ArcCosh[a (x^p)]] (∂_x)ArcCosh[a (x^p)]

Rule: If  n∈(SuperPlus[ℤ]), then

∫(((ArcCosh[a (x^p)])^n)/x)dx  ⟶  (1/p) Subst[∫(x^n) Tanh[x]dx,x,ArcCosh[a (x^p)]]

Program code:

Int[ArcCosh[a_.*x_^p_]^n_./x_,x_Symbol] :=
  1/p*Subst[Int[x^n*Tanh[x],x],x,ArcCosh[a*x^p]] /;
FreeQ[{a,p},x] && IGtQ[n,0]

4:  ∫u ((ArcCosh[(c/(a+b (x^n)))])^m)dx

Derivation:  Algebraic simplification

Basis: ArcCosh[z]==ArcSech[(1/z)]

Rule:

∫u ((ArcCosh[(c/(a+b (x^n)))])^m)dx  ⟶  ∫u ((ArcSech[(a/c)+((b (x^n))/c)])^m)dx

Program code:

Int[u_.*ArcCosh[c_./(a_.+b_.*x_^n_.)]^m_.,x_Symbol] :=
  Int[u*ArcSech[a/c+b*x^n/c]^m,x] /;
FreeQ[{a,b,c,n,m},x]

5:  ∫(((ArcCosh[(Sqrt[1+b (x^2)])])^n)/(Sqrt[1+b (x^2)]))dx

Derivation:  Piecewise constant extraction and integration by substitution

Basis: (∂_x)(((Sqrt[-1+(Sqrt[1+b (x^2)])]) (Sqrt[1+(Sqrt[1+b (x^2)])]))/x)==0

Basis: ((x ((ArcCosh[(Sqrt[1+b (x^2)])])^n))/((Sqrt[-1+(Sqrt[1+b (x^2)])]) (Sqrt[1+(Sqrt[1+b (x^2)])]) (Sqrt[1+b (x^2)])))==(1/b)Subst[(((ArcCosh[x])^n)/((Sqrt[-1+x]) (Sqrt[1+x]))),x,(Sqrt[1+b (x^2)])] (∂_x)(Sqrt[1+b (x^2)])

Rule:

∫(((ArcCosh[(Sqrt[1+b (x^2)])])^n)/(Sqrt[1+b (x^2)]))dx  ⟶  (((Sqrt[-1+(Sqrt[1+b (x^2)])]) (Sqrt[1+(Sqrt[1+b (x^2)])]))/x) ∫((x ((ArcCosh[(Sqrt[1+b (x^2)])])^n))/((Sqrt[-1+(Sqrt[1+b (x^2)])]) (Sqrt[1+(Sqrt[1+b (x^2)])]) (Sqrt[1+b (x^2)])))dx
  ⟶  (((Sqrt[-1+(Sqrt[1+b (x^2)])]) (Sqrt[1+(Sqrt[1+b (x^2)])]))/(b x)) Subst[∫(((ArcCosh[x])^n)/((Sqrt[-1+x]) (Sqrt[1+x])))dx,x,(Sqrt[1+b (x^2)])]

Program code:

Int[ArcCosh[Sqrt[1+b_.*x_^2]]^n_./Sqrt[1+b_.*x_^2],x_Symbol] :=
  Sqrt[-1+Sqrt[1+b*x^2]]*Sqrt[1+Sqrt[1+b*x^2]]/(b*x)*Subst[Int[ArcCosh[x]^n/(Sqrt[-1+x]*Sqrt[1+x]),x],x,Sqrt[1+b*x^2]] /;
FreeQ[{b,n},x]

6.  ∫u (f^(c ((ArcCosh[a+b x])^n)))dx  when  n∈(SuperPlus[ℤ])

1:  ∫(f^(c ((ArcCosh[a+b x])^n)))dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[ArcCosh[a+b x]]==(1/b)Subst[F[x] Sinh[x],x,ArcCosh[a+b x]] (∂_x)ArcCosh[a+b x]

Rule: If  n∈(SuperPlus[ℤ]), then

∫(f^(c ((ArcCosh[a+b x])^n)))dx  ⟶  (1/b)Subst[∫(f^(c (x^n)))Sinh[x]dx,x,ArcCosh[a+b x]]

Program code:

Int[f_^(c_.*ArcCosh[a_.+b_.*x_]^n_.),x_Symbol] :=
  1/b*Subst[Int[f^(c*x^n)*Sinh[x],x],x,ArcCosh[a+b*x]] /;
FreeQ[{a,b,c,f},x] && IGtQ[n,0]

2:  ∫(x^m) (f^(c ((ArcCosh[a+b x])^n)))dx  when  (m|n)∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[x,ArcCosh[a+b x]]==(1/b)Subst[F[-(a/b)+((Cosh[x])/b),x] Sinh[x],x,ArcCosh[a+b x]] (∂_x)ArcCosh[a+b x]

Rule: If  (m|n)∈(SuperPlus[ℤ]), then

∫(x^m) (f^(c ((ArcCosh[a+b x])^n)))dx  ⟶  (1/b)Subst[∫(((-(a/b)+((Cosh[x])/b)))^m) (f^(c (x^n)))Sinh[x]dx,x,ArcCosh[a+b x]]

Program code:

Int[x_^m_.*f_^(c_.*ArcCosh[a_.+b_.*x_]^n_.),x_Symbol] :=
  1/b*Subst[Int[(-a/b+Cosh[x]/b)^m*f^(c*x^n)*Sinh[x],x],x,ArcCosh[a+b*x]] /;
FreeQ[{a,b,c,f},x] && IGtQ[m,0] && IGtQ[n,0]

7.  ∫v (a+b ArcCosh[u])dx  when  u is free of inverse functions

1:  ∫ArcCosh[u]dx  when  u is free of inverse functions

Derivation: Integration by parts

Basis: (∂_x)ArcCosh[f[x]]==(((∂_x)f[x])/((Sqrt[-1+f[x]]) (Sqrt[1+f[x]])))

Rule: If u is free of inverse functions, then

∫ArcCosh[u]dx  ⟶  x ArcCosh[u]-∫((x (∂_x)u)/((Sqrt[-1+u])(Sqrt[1+u])))dx

Program code:

Int[ArcCosh[u_],x_Symbol] :=
  x*ArcCosh[u] - 
  Int[SimplifyIntegrand[x*D[u,x]/(Sqrt[-1+u]*Sqrt[1+u]),x],x] /;
InverseFunctionFreeQ[u,x] && Not[FunctionOfExponentialQ[u,x]]

2:  ∫(((c+d x))^m)(a+b ArcCosh[u])dx  when  m≠-1 ∧ u is free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)ArcCosh[f[x]]==(((∂_x)f[x])/((Sqrt[-1+f[x]]) (Sqrt[1+f[x]])))

Rule: If  m≠-1 ∧ u is free of inverse functions, then

∫(((c+d x))^m)(a+b ArcCosh[u])dx  ⟶  (((((c+d x))^(m+1)) (a+b ArcCosh[u]))/(d(m+1)))-(b/(d(m+1)))∫(((((c+d x))^(m+1)) (∂_x)u)/((Sqrt[-1+u])(Sqrt[1+u])))dx

Program code:

Int[(c_.+d_.*x_)^m_.*(a_.+b_.*ArcCosh[u_]),x_Symbol] :=
  (c+d*x)^(m+1)*(a+b*ArcCosh[u])/(d*(m+1)) -
  b/(d*(m+1))*Int[SimplifyIntegrand[(c+d*x)^(m+1)*D[u,x]/(Sqrt[-1+u]*Sqrt[1+u]),x],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1] && InverseFunctionFreeQ[u,x] && Not[FunctionOfQ[(c+d*x)^(m+1),u,x]] && Not[FunctionOfExponentialQ[u,x]]

3:  ∫v(a+b ArcCosh[u])dx  when  u and ∫vdx  are free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)ArcCosh[f[x]]==(((∂_x)f[x])/((Sqrt[-1+f[x]]) (Sqrt[1+f[x]])))

Rule: If u is free of inverse functions, let  w==∫vdx, if w is free of inverse functions, then

∫v(a+b ArcCosh[u])dx  ⟶  w (a+b ArcCosh[u])-b∫((w (∂_x)u)/((Sqrt[-1+u])(Sqrt[1+u])))dx

Program code:

Int[v_*(a_.+b_.*ArcCosh[u_]),x_Symbol] :=
  With[{w=IntHide[v,x]},  
  Dist[(a+b*ArcCosh[u]),w,x] - b*Int[SimplifyIntegrand[w*D[u,x]/(Sqrt[-1+u]*Sqrt[1+u]),x],x] /;
 InverseFunctionFreeQ[w,x]] /;
FreeQ[{a,b},x] && InverseFunctionFreeQ[u,x] && Not[MatchQ[v, (c_.+d_.*x)^m_. /; FreeQ[{c,d,m},x]]]

8.  ∫u (e^(n ArcCosh[(Subscript[P, x])]))dx

1:  ∫(e^(n ArcCosh[(Subscript[P, x])]))dx  when  n∈ℤ

Derivation: Algebraic simplification

Basis: (e^(n ArcCosh[z]))==(((z+(Sqrt[-1+z]) (Sqrt[1+z])))^n)

Basis: If n∈ℤ,  (e^(n ArcCosh[z]))==(((z+(Sqrt[((-1+z)/(1+z))])+z (Sqrt[((-1+z)/(1+z))])))^n)

Rule: If  n∈ℤ, then

∫(e^(n ArcCosh[(Subscript[P, x])]))dx  ⟶  ∫((((Subscript[P, x])+(Sqrt[-1+(Subscript[P, x])]) (Sqrt[1+(Subscript[P, x])])))^n)dx

Program code:

Int[E^(n_.*ArcCosh[u_]), x_Symbol] :=
  Int[(u+Sqrt[-1+u]*Sqrt[1+u])^n,x] /;
IntegerQ[n] && PolyQ[u,x]

2:  ∫(x^m)(e^(n ArcCosh[(Subscript[P, x])]))dx  when  n∈ℤ

Derivation: Algebraic simplification

Basis: (e^(n ArcCosh[z]))==(((z+(Sqrt[-1+z]) (Sqrt[1+z])))^n)

Rule: If  n∈ℤ, then

∫(x^m)(e^(n ArcCosh[(Subscript[P, x])]))dx  ⟶  ∫(x^m)((((Subscript[P, x])+(Sqrt[-1+(Subscript[P, x])]) (Sqrt[1+(Subscript[P, x])])))^n)dx

Program code:

Int[x_^m_.*E^(n_.*ArcCosh[u_]), x_Symbol] :=
  Int[x^m*(u+Sqrt[-1+u]*Sqrt[1+u])^n,x] /;
RationalQ[m] && IntegerQ[n] && PolyQ[u,x]