Rules for integrands of the form(((a+b ArcTanh[c (x^n)]))^p)

1:  ∫(((a+b ArcTanh[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])∧ (n==1∨p==1)

Derivation: Integration by parts

Basis: (∂_x)(((a+b ArcTanh[c (x^n)]))^p)==b c n p (((x^(n-1)) (((a+b ArcTanh[c (x^n)]))^(p-1)))/(1-(c^2) (x^(2 n))))

Rule: If  p∈(SuperPlus[ℤ])∧ (n==1∨p==1), then

∫(((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  x (((a+b ArcTanh[c (x^n)]))^p)-b c n p ∫(((x^n) (((a+b ArcTanh[c (x^n)]))^(p-1)))/(1-(c^2) (x^(2 n))))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_^n_.])^p_.,x_Symbol] :=
  x*(a+b*ArcTanh[c*x^n])^p - 
  b*c*n*p*Int[x^n*(a+b*ArcTanh[c*x^n])^(p-1)/(1-c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,n},x] && IGtQ[p,0] && (EqQ[n,1] || EqQ[p,1])

Int[(a_.+b_.*ArcCoth[c_.*x_^n_.])^p_.,x_Symbol] :=
  x*(a+b*ArcCoth[c*x^n])^p - 
  b*c*n*p*Int[x^n*(a+b*ArcCoth[c*x^n])^(p-1)/(1-c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,n},x] && IGtQ[p,0] && (EqQ[n,1] || EqQ[p,1])

2.  ∫(((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈ℤ

1:  ∫(((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: ArcTanh[z]==((Log[1+z])/2)-((Log[1-z])/2)

Basis: ArcCoth[z]==((Log[1+(z^(-1))])/2)-((Log[1-(z^(-1))])/2)

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ]), then

∫(((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  ∫ExpandIntegrand[(((a+((b Log[1+c (x^n)])/2)-((b Log[1-c (x^n)])/2)))^p),x]dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*Log[1+c*x^n]/2-b*Log[1-c*x^n]/2)^p,x],x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && IGtQ[n,0]

Int[(a_.+b_.*ArcCoth[c_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*Log[1+x^(-n)/c]/2-b*Log[1-x^(-n)/c]/2)^p,x],x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && IGtQ[n,0]

2:  ∫(((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: ArcTanh[z]==ArcCoth[(1/z)]

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈(SuperMinus[ℤ]), then

∫(((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  ∫(((a+b ArcCoth[((x^(-n))/c)]))^p)dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_^n_])^p_,x_Symbol] :=
  Int[(a+b*ArcCoth[x^(-n)/c])^p,x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && ILtQ[n,0]

Int[(a_.+b_.*ArcCoth[c_.*x_^n_])^p_,x_Symbol] :=
  Int[(a+b*ArcTanh[x^(-n)/c])^p,x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && ILtQ[n,0]

3:  ∫(((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈𝔽

Derivation: Integration by substitution

Basis: If k∈(SuperPlus[ℤ]), then F[x]==k Subst[(x^(k-1)) F[(x^k)],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈𝔽, let k->Denominator[n], then

∫(((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  k Subst[∫(x^(k-1)) (((a+b ArcTanh[c (x^(k n))]))^p)dx,x,(x^(1/k))]

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_^n_])^p_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*ArcTanh[c*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && FractionQ[n]

Int[(a_.+b_.*ArcCoth[c_.*x_^n_])^p_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*ArcCoth[c*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && FractionQ[n]

U:  ∫(((a+b ArcTanh[c (x^n)]))^p)dx

Rule:

∫(((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  ∫(((a+b ArcTanh[c (x^n)]))^p)dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_^n_.])^p_,x_Symbol] :=
  Unintegrable[(a+b*ArcTanh[c*x^n])^p,x] /;
FreeQ[{a,b,c,n,p},x]

Int[(a_.+b_.*ArcCoth[c_.*x_^n_.])^p_,x_Symbol] :=
  Unintegrable[(a+b*ArcCoth[c*x^n])^p,x] /;
FreeQ[{a,b,c,n,p},x]