Rules for integrands of the form(((d x))^m) (((a+b ArcTanh[c (x^n)]))^p)

1.  ∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])

1.  ∫((((a+b ArcTanh[c (x^n)]))^p)/x)dx  when  p∈(SuperPlus[ℤ])

1.  ∫((((a+b ArcTanh[c x]))^p)/x)dx  when  p∈(SuperPlus[ℤ])

1:  ∫((a+b ArcTanh[c x])/x)dx

Derivation: Algebraic expansion

Basis: ArcTanh[z]==(1/2) Log[1+z]-(1/2) Log[1-z]

Basis: ArcCoth[z]==(1/2) Log[1+(1/z)]-(1/2) Log[1-(1/z)]

Rule:

∫((a+b ArcTanh[c x])/x)dx  ⟶  a ∫(1/x)dx+(b/2)∫((Log[1+c x])/x)dx-(b/2)∫((Log[1-c x])/x)dx

  ⟶  a Log[x]-(b/2) PolyLog[2,-c x]+(b/2) PolyLog[2,c x]

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])/x_,x_Symbol] :=
  a*Log[x] - b/2*PolyLog[2,-c*x] + b/2*PolyLog[2,c*x] /;
FreeQ[{a,b,c},x]

Int[(a_.+b_.*ArcCoth[c_.*x_])/x_,x_Symbol] :=
  a*Log[x] + b/2*PolyLog[2,-1/(c*x)] - b/2*PolyLog[2,1/(c*x)] /;
FreeQ[{a,b,c},x]

2:  ∫((((a+b ArcTanh[c x]))^p)/x)dx  when  p-1∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (1/x)==2(∂_x)ArcTanh[1-(2/(1-c x))]

Rule: If  p-1∈(SuperPlus[ℤ]), then

∫((((a+b ArcTanh[c x]))^p)/x)dx  ⟶  
2 (((a+b ArcTanh[c x]))^p) ArcTanh[1-(2/(1-c x))]-2b c p∫(((((a+b ArcTanh[c x]))^(p-1)) ArcTanh[1-(2/(1-c x))])/(1-(c^2)(x^2)))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_/x_,x_Symbol] :=
  2*(a+b*ArcTanh[c*x])^p*ArcTanh[1-2/(1-c*x)] -
  2*b*c*p*Int[(a+b*ArcTanh[c*x])^(p-1)*ArcTanh[1-2/(1-c*x)]/(1-c^2*x^2),x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_/x_,x_Symbol] :=
  2*(a+b*ArcCoth[c*x])^p*ArcCoth[1-2/(1-c*x)] -
  2*b*c*p*Int[(a+b*ArcCoth[c*x])^(p-1)*ArcCoth[1-2/(1-c*x)]/(1-c^2*x^2),x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1]

2:  ∫((((a+b ArcTanh[c (x^n)]))^p)/x)dx  when  p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: ((F[(x^n)])/x)==(1/n) Subst[((F[x])/x),x,(x^n)] (∂_x)(x^n)

Rule: If  p∈(SuperPlus[ℤ]), then

∫((((a+b ArcTanh[c (x^n)]))^p)/x)dx  ⟶  (1/n) Subst[∫((((a+b ArcTanh[c x]))^p)/x)dx,x,(x^n)]

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_^n_])^p_./x_,x_Symbol] :=
  1/n*Subst[Int[(a+b*ArcTanh[c*x])^p/x,x],x,x^n] /;
FreeQ[{a,b,c,n},x] && IGtQ[p,0]

Int[(a_.+b_.*ArcCoth[c_.*x_^n_])^p_./x_,x_Symbol] :=
  1/n*Subst[Int[(a+b*ArcCoth[c*x])^p/x,x],x,x^n] /;
FreeQ[{a,b,c,n},x] && IGtQ[p,0]

2:  ∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])∧(p==1 ∨ n==1∧m∈ℤ)∧ m≠-1

Derivation: Integration by parts

Basis: (∂_x)(((a+b ArcTanh[c (x^n)]))^p)==b c n p (((x^(n-1)) (((a+b ArcTanh[c (x^n)]))^(p-1)))/(1-(c^2) (x^(2 n))))

Rule: If  p∈(SuperPlus[ℤ])∧(p==1 ∨ n==1∧m∈ℤ)∧ m≠-1, then

∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  (((x^(m+1))(((a+b ArcTanh[c (x^n)]))^p))/(m+1))-((b c n p)/(m+1))∫(((x^(m+n)) (((a+b ArcTanh[c (x^n)]))^(p-1)))/(1-(c^2) (x^(2 n))))dx

Program code:

Int[x_^m_.*(a_.+b_.*ArcTanh[c_.*x_^n_.])^p_.,x_Symbol] :=
  x^(m+1)*(a+b*ArcTanh[c*x^n])^p/(m+1) - 
  b*c*n*p/(m+1)*Int[x^(m+n)*(a+b*ArcTanh[c*x^n])^(p-1)/(1-c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,m,n},x] && IGtQ[p,0] && (EqQ[p,1] || EqQ[n,1] && IntegerQ[m])  && NeQ[m,-1]

Int[x_^m_.*(a_.+b_.*ArcCoth[c_.*x_^n_.])^p_.,x_Symbol] :=
  x^(m+1)*(a+b*ArcCoth[c*x^n])^p/(m+1) - 
  b*c*n*p/(m+1)*Int[x^(m+n)*(a+b*ArcCoth[c*x^n])^(p-1)/(1-c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,m,n},x] && IGtQ[p,0] && (EqQ[p,1] || EqQ[n,1] && IntegerQ[m])  && NeQ[m,-1]

3:  ∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ ((m+1)/n)∈ℤ

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m)F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Rule: If  p-1∈(SuperPlus[ℤ])∧ ((m+1)/n)∈ℤ, then

∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((a+b ArcTanh[c x]))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(a_.+b_.*ArcTanh[c_.*x_^n_])^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a+b*ArcTanh[c*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,m,n},x] && IGtQ[p,1] && IntegerQ[Simplify[(m+1)/n]]

Int[x_^m_.*(a_.+b_.*ArcCoth[c_.*x_^n_])^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a+b*ArcCoth[c*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,m,n},x] && IGtQ[p,1] && IntegerQ[Simplify[(m+1)/n]]

4.  ∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈ℤ

1.  ∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])

1:  ∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Algebraic expansion

Basis: ArcTanh[z]==((Log[1+z])/2)-((Log[1-z])/2)

Basis: ArcCoth[z]==((Log[1+(z^(-1))])/2)-((Log[1-(z^(-1))])/2)

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])∧ m∈ℤ, then

∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  ∫ExpandIntegrand[(x^m) (((a+((b Log[1+c (x^n)])/2)-((b Log[1-c (x^n)])/2)))^p),x]dx

Program code:

Int[x_^m_.*(a_.+b_.*ArcTanh[c_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandIntegrand[x^m*(a+b*Log[1+c*x^n]/2-b*Log[1-c*x^n]/2)^p,x],x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && IGtQ[n,0] && IntegerQ[m]

Int[x_^m_.*(a_.+b_.*ArcCoth[c_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandIntegrand[x^m*(a+b*Log[1+x^(-n)/c]/2-b*Log[1-x^(-n)/c]/2)^p,x],x] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && IGtQ[n,0] && IntegerQ[m]

2:  ∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If k∈(SuperPlus[ℤ]), then F[x]==k Subst[(x^(k-1)) F[(x^k)],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])∧ m∈𝔽, let k->Denominator[m], then

∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  k Subst[∫(x^(k (m+1)-1)) (((a+b ArcTanh[c (x^(k n))]))^p)dx,x,(x^(1/k))]

Program code:

Int[x_^m_.*(a_.+b_.*ArcTanh[c_.*x_^n_])^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  k*Subst[Int[x^(k*(m+1)-1)*(a+b*ArcTanh[c*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && IGtQ[n,0] && FractionQ[m]

Int[x_^m_.*(a_.+b_.*ArcCoth[c_.*x_^n_])^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  k*Subst[Int[x^(k*(m+1)-1)*(a+b*ArcCoth[c*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c},x] && IGtQ[p,1] && IGtQ[n,0] && FractionQ[m]

2:  ∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: ArcTanh[(z^(-1))]==ArcCoth[z]

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈(SuperMinus[ℤ]), then

∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  ∫(x^m) (((a+b ArcCoth[((x^(-n))/c)]))^p)dx

Program code:

Int[x_^m_.*(a_.+b_.*ArcTanh[c_.*x_^n_])^p_,x_Symbol] :=
  Int[x^m*(a+b*ArcCoth[x^(-n)/c])^p,x] /;
FreeQ[{a,b,c,m},x] && IGtQ[p,1] && ILtQ[n,0]

Int[x_^m_.*(a_.+b_.*ArcCoth[c_.*x_^n_])^p_,x_Symbol] :=
  Int[x^m*(a+b*ArcTanh[x^(-n)/c])^p,x] /;
FreeQ[{a,b,c,m},x] && IGtQ[p,1] && ILtQ[n,0]

5:  ∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ n∈𝔽

Derivation: Integration by substitution

Basis: If k∈(SuperPlus[ℤ]), then F[x]==k Subst[(x^(k-1)) F[(x^k)],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  p-1∈(SuperPlus[ℤ])∧ n∈𝔽 ∧ m∈ℤ, let k->Denominator[n], then

∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  k Subst[∫(x^(k (m+1)-1)) (((a+b ArcTanh[c (x^(k n))]))^p)dx,x,(x^(1/k))]

Program code:

Int[x_^m_.*(a_.+b_.*ArcTanh[c_.*x_^n_])^p_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k*(m+1)-1)*(a+b*ArcTanh[c*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,m},x] && IGtQ[p,1] && FractionQ[n]

Int[x_^m_.*(a_.+b_.*ArcCoth[c_.*x_^n_])^p_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k*(m+1)-1)*(a+b*ArcCoth[c*x^(k*n)])^p,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,m},x] && IGtQ[p,1] && FractionQ[n]

2:  ∫(((d x))^m) (a+b ArcTanh[c (x^n)])dx  when  n∈ℤ ∧ m≠-1

Derivation: Integration by parts

Basis: If  n∈ℤ, then (∂_x)(a+b ArcTanh[c (x^n)])==((b c n (((d x))^(n-1)))/((d^(n-1)) (1-(c^2) (x^(2 n)))))

Rule: If  n∈ℤ ∧ m≠-1, then

∫(((d x))^m) (a+b ArcTanh[c (x^n)])dx  ⟶  (((((d x))^(m+1))(a+b ArcTanh[c (x^n)]))/(d (m+1)))-((b c n)/((d^n)(m+1)))∫((((d x))^(m+n))/(1-(c^2) (x^(2 n))))dx

Program code:

Int[(d_*x_)^m_*(a_.+b_.*ArcTanh[c_.*x_^n_.]),x_Symbol] :=
  (d*x)^(m+1)*(a+b*ArcTanh[c*x^n])/(d*(m+1)) - 
  b*c*n/(d^n*(m+1))*Int[(d*x)^(m+n)/(1-c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,d,m,n},x] && IntegerQ[n] && NeQ[m,-1]

Int[(d_*x_)^m_*(a_.+b_.*ArcCoth[c_.*x_^n_.]),x_Symbol] :=
  (d*x)^(m+1)*(a+b*ArcCoth[c*x^n])/(d*(m+1)) - 
  b*c*n/(d^n*(m+1))*Int[(d*x)^(m+n)/(1-c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,d,m,n},x] && IntegerQ[n] && NeQ[m,-1]

3:  ∫(((d x))^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])∧(p==1 ∨ m∈ℝ∧n∈ℝ)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((d x))^m)/(x^m))==0

Rule: If  p∈(SuperPlus[ℤ])∧(p==1 ∨ m∈𝔽∧n∈𝔽), then

∫(((d x))^m) (((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  (((d^(IntPart[m]))(((d x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((a+b ArcTanh[c (x^n)]))^p)dx

Program code:

Int[(d_*x_)^m_*(a_.+b_.*ArcTanh[c_.*x_^n_.])^p_.,x_Symbol] :=
  d^IntPart[m]*(d*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*ArcTanh[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,m,n},x] && IGtQ[p,0] && (EqQ[p,1] || RationalQ[m,n])

Int[(d_*x_)^m_*(a_.+b_.*ArcCoth[c_.*x_^n_.])^p_.,x_Symbol] :=
  d^IntPart[m]*(d*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*ArcCoth[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,m,n},x] && IGtQ[p,0] && (EqQ[p,1] || RationalQ[m,n])

U:  ∫(((d x))^m)(((a+b ArcTanh[c (x^n)]))^p)dx

Rule:

∫(((d x))^m)(((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  ∫(((d x))^m)(((a+b ArcTanh[c (x^n)]))^p)dx

Program code:

Int[(d_.*x_)^m_.*(a_.+b_.*ArcTanh[c_.*x_^n_.])^p_.,x_Symbol] :=
  Unintegrable[(d*x)^m*(a+b*ArcTanh[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,m,n,p},x]

Int[(d_.*x_)^m_.*(a_.+b_.*ArcCoth[c_.*x_^n_.])^p_.,x_Symbol] :=
  Unintegrable[(d*x)^m*(a+b*ArcCoth[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,m,n,p},x]