Rules for integrands of the form(((d+e x))^m) (((a+b ArcTanh[c (x^n)]))^p)

1.  ∫(((d+e x))^q) (((a+b ArcTanh[c x]))^p)dx  when  p∈(SuperPlus[ℤ])

1.  ∫((((a+b ArcTanh[c x]))^p)/(d+e x))dx  when  p∈(SuperPlus[ℤ])

1:  ∫((((a+b ArcTanh[c x]))^p)/(d+e x))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0

Derivation: Integration by parts

Basis: (1/(d+e x))==-(1/e) (∂_x)Log[(2/(1+((e x)/d)))]

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0, then

∫((((a+b ArcTanh[c x]))^p)/(d+e x))dx  ⟶  -(((((a+b ArcTanh[c x]))^p) Log[(2/(1+((e x)/d)))])/e)+((b c p)/e)∫(((((a+b ArcTanh[c x]))^(p-1)) Log[(2/(1+((e x)/d)))])/(1-(c^2)(x^2)))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_),x_Symbol] :=
  -(a+b*ArcTanh[c*x])^p*Log[2/(1+e*x/d)]/e + 
  b*c*p/e*Int[(a+b*ArcTanh[c*x])^(p-1)*Log[2/(1+e*x/d)]/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d^2-e^2,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_),x_Symbol] :=
  -(a+b*ArcCoth[c*x])^p*Log[2/(1+e*x/d)]/e + 
  b*c*p/e*Int[(a+b*ArcCoth[c*x])^(p-1)*Log[2/(1+e*x/d)]/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d^2-e^2,0]

2.  ∫((((a+b ArcTanh[c x]))^p)/(d+e x))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)≠0

1:  ∫((a+b ArcTanh[c x])/(d+e x))dx  when  (c^2) (d^2)-(e^2)≠0

Derivation: Algebraic expansion and integration by parts

Basis: (1/(d+e x))==(c/(e (1+c x)))-((c d-e)/(e (1+c x) (d+e x)))

Basis: (1/(1+c x))==-(1/c) (∂_x)Log[(2/(1+c x))]

Basis: (1/((1+c x) (d+e x)))==-(1/(c d-e)) (∂_x)Log[((2 c (d+e x))/((c d+e) (1+c x)))]

Basis: (∂_x)(a+b ArcTanh[c x])==((b c)/(1-(c^2) (x^2)))

Rule: If  (c^2) (d^2)-(e^2)≠0, then

∫((a+b ArcTanh[c x])/(d+e x))dx  ⟶  (c/e) ∫((a+b ArcTanh[c x])/(1+c x))dx-((c d-e)/e) ∫((a+b ArcTanh[c x])/((1+c x) (d+e x)))dx  ⟶  

-(((a+b ArcTanh[c x]) Log[(2/(1+c x))])/e)+((b c)/e) ∫((Log[(2/(1+c x))])/(1-(c^2) (x^2)))dx+(((a+b ArcTanh[c x]) Log[((2 c (d+e x))/((c d+e) (1+c x)))])/e)-((b c)/e) ∫((Log[((2 c (d+e x))/((c d+e) (1+c x)))])/(1-(c^2) (x^2)))dx  ⟶  

-(((a+b ArcTanh[c x]) Log[(2/(1+c x))])/e)+((b PolyLog[2,1-(2/(1+c x))])/(2 e))+(((a+b ArcTanh[c x]) Log[((2 c (d+e x))/((c d+e) (1+c x)))])/e)-((b PolyLog[2,1-((2 c (d+e x))/((c d+e) (1+c x)))])/(2 e))

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])/(d_+e_.*x_),x_Symbol] :=
  -(a+b*ArcTanh[c*x])*Log[2/(1+c*x)]/e + 
  b*c/e*Int[Log[2/(1+c*x)]/(1-c^2*x^2),x] + 
  (a+b*ArcTanh[c*x])*Log[2*c*(d+e*x)/((c*d+e)*(1+c*x))]/e - 
  b*c/e*Int[Log[2*c*(d+e*x)/((c*d+e)*(1+c*x))]/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[c^2*d^2-e^2,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])/(d_+e_.*x_),x_Symbol] :=
  -(a+b*ArcCoth[c*x])*Log[2/(1+c*x)]/e + 
  b*c/e*Int[Log[2/(1+c*x)]/(1-c^2*x^2),x] + 
  (a+b*ArcCoth[c*x])*Log[2*c*(d+e*x)/((c*d+e)*(1+c*x))]/e - 
  b*c/e*Int[Log[2*c*(d+e*x)/((c*d+e)*(1+c*x))]/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[c^2*d^2-e^2,0]

2:  ∫((((a+b ArcTanh[c x]))^2)/(d+e x))dx  when  (c^2) (d^2)-(e^2)≠0

Derivation: Algebraic expansion and integration by parts

Basis: (1/(d+e x))==(c/(e (1+c x)))-((c d-e)/(e (1+c x) (d+e x)))

Basis: (1/(1+c x))==-(1/c) (∂_x)Log[(2/(1+c x))]

Basis: (1/((1+c x) (d+e x)))==-(1/(c d-e)) (∂_x)Log[((2 c (d+e x))/((c d+e) (1+c x)))]

Basis: (∂_x)(((a+b ArcTanh[c x]))^2)==((2 b c (a+b ArcTanh[c x]))/(1-(c^2) (x^2)))

Rule: If  (c^2) (d^2)-(e^2)≠0, then

∫((((a+b ArcTanh[c x]))^2)/(d+e x))dx  ⟶  (c/e) ∫((((a+b ArcTanh[c x]))^2)/(1+c x))dx-((c d-e)/e) ∫((((a+b ArcTanh[c x]))^2)/((1+c x) (d+e x)))dx  ⟶  

-(((((a+b ArcTanh[c x]))^2) Log[(2/(1+c x))])/e)+((2 b c)/e) ∫(((a+b ArcTanh[c x]) Log[(2/(1+c x))])/(1-(c^2) (x^2)))dx+
(((((a+b ArcTanh[c x]))^2) Log[((2 c (d+e x))/((c d+e) (1+c x)))])/e)-((2 b c)/e) ∫(((a+b ArcTanh[c x]) Log[((2 c (d+e x))/((c d+e) (1+c x)))])/(1-(c^2) (x^2)))dx  ⟶  

-(((((a+b ArcTanh[c x]))^2) Log[(2/(1+c x))])/e)+((b (a+b ArcTanh[c x]) PolyLog[2,1-(2/(1+c x))])/e)+(((b^2) PolyLog[3,1-(2/(1+c x))])/(2 e))+
(((((a+b ArcTanh[c x]))^2) Log[((2 c (d+e x))/((c d+e) (1+c x)))])/e)-((b (a+b ArcTanh[c x]) PolyLog[2,1-((2 c (d+e x))/((c d+e) (1+c x)))])/e)-(((b^2) PolyLog[3,1-((2 c (d+e x))/((c d+e) (1+c x)))])/(2 e))

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^2/(d_+e_.*x_),x_Symbol] :=
  -(a+b*ArcTanh[c*x])^2*Log[2/(1+c*x)]/e + 
  b*(a+b*ArcTanh[c*x])*PolyLog[2,1-2/(1+c*x)]/e + 
  b^2*PolyLog[3,1-2/(1+c*x)]/(2*e) + 
  (a+b*ArcTanh[c*x])^2*Log[2*c*(d+e*x)/((c*d+e)*(1+c*x))]/e - 
  b*(a+b*ArcTanh[c*x])*PolyLog[2,1-2*c*(d+e*x)/((c*d+e)*(1+c*x))]/e - 
  b^2*PolyLog[3,1-2*c*(d+e*x)/((c*d+e)*(1+c*x))]/(2*e) /;
FreeQ[{a,b,c,d,e},x] && NeQ[c^2*d^2-e^2,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^2/(d_+e_.*x_),x_Symbol] :=
  -(a+b*ArcCoth[c*x])^2*Log[2/(1+c*x)]/e + 
  b*(a+b*ArcCoth[c*x])*PolyLog[2,1-2/(1+c*x)]/e + 
  b^2*PolyLog[3,1-2/(1+c*x)]/(2*e) + 
  (a+b*ArcCoth[c*x])^2*Log[2*c*(d+e*x)/((c*d+e)*(1+c*x))]/e - 
  b*(a+b*ArcCoth[c*x])*PolyLog[2,1-2*c*(d+e*x)/((c*d+e)*(1+c*x))]/e - 
  b^2*PolyLog[3,1-2*c*(d+e*x)/((c*d+e)*(1+c*x))]/(2*e) /;
FreeQ[{a,b,c,d,e},x] && NeQ[c^2*d^2-e^2,0]

3:  ∫((((a+b ArcTanh[c x]))^3)/(d+e x))dx  when  (c^2) (d^2)-(e^2)≠0

Derivation: Algebraic expansion and integration by parts

Basis: (1/(d+e x))==(c/(e (1+c x)))-((c d-e)/(e (1+c x) (d+e x)))

Basis: (1/(1+c x))==-(1/c) (∂_x)Log[(2/(1+c x))]

Basis: (1/((1+c x) (d+e x)))==-(1/(c d-e)) (∂_x)Log[((2 c (d+e x))/((c d+e) (1+c x)))]

Basis: (∂_x)(((a+b ArcTanh[c x]))^3)==((3 b c (((a+b ArcTanh[c x]))^2))/(1-(c^2) (x^2)))

Rule: If  (c^2) (d^2)-(e^2)≠0, then

∫((((a+b ArcTanh[c x]))^3)/(d+e x))dx  ⟶  (c/e) ∫((((a+b ArcTanh[c x]))^3)/(1+c x))dx-((c d-e)/e) ∫((((a+b ArcTanh[c x]))^3)/((1+c x) (d+e x)))dx  ⟶  

-(((((a+b ArcTanh[c x]))^3) Log[(2/(1+c x))])/e)+((3 b c)/e) ∫(((((a+b ArcTanh[c x]))^2) Log[(2/(1+c x))])/(1-(c^2) (x^2)))dx+
(((((a+b ArcTanh[c x]))^3) Log[((2 c (d+e x))/((c d+e) (1+c x)))])/e)-((3 b c)/e) ∫(((((a+b ArcTanh[c x]))^2) Log[((2 c (d+e x))/((c d+e) (1+c x)))])/(1-(c^2) (x^2)))dx  ⟶  

-(((((a+b ArcTanh[c x]))^3) Log[(2/(1+c x))])/e)+((3 b (((a+b ArcTanh[c x]))^2) PolyLog[2,1-(2/(1+c x))])/(2 e))+
((3 (b^2) (a+b ArcTanh[c x]) PolyLog[3,1-(2/(1+c x))])/(2 e))+((3 (b^3) PolyLog[4,1-(2/(1+c x))])/(4 e))+
(((((a+b ArcTanh[c x]))^3) Log[((2 c (d+e x))/((c d+e) (1+c x)))])/e)-((3 b (((a+b ArcTanh[c x]))^2) PolyLog[2,1-((2 c (d+e x))/((c d+e) (1+c x)))])/(2 e))-
((3 (b^2) (a+b ArcTanh[c x]) PolyLog[3,1-((2 c (d+e x))/((c d+e) (1+c x)))])/(2 e))-((3 (b^3) PolyLog[4,1-((2 c (d+e x))/((c d+e) (1+c x)))])/(4 e))

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^3/(d_+e_.*x_),x_Symbol] :=
  -(a+b*ArcTanh[c*x])^3*Log[2/(1+c*x)]/e + 
  3*b*(a+b*ArcTanh[c*x])^2*PolyLog[2,1-2/(1+c*x)]/(2*e) + 
  3*b^2*(a+b*ArcTanh[c*x])*PolyLog[3,1-2/(1+c*x)]/(2*e) + 
  3*b^3*PolyLog[4,1-2/(1+c*x)]/(4*e) + 
  (a+b*ArcTanh[c*x])^3*Log[2*c*(d+e*x)/((c*d+e)*(1+c*x))]/e - 
  3*b*(a+b*ArcTanh[c*x])^2*PolyLog[2,1-2*c*(d+e*x)/((c*d+e)*(1+c*x))]/(2*e) - 
  3*b^2*(a+b*ArcTanh[c*x])*PolyLog[3,1-2*c*(d+e*x)/((c*d+e)*(1+c*x))]/(2*e) - 
  3*b^3*PolyLog[4,1-2*c*(d+e*x)/((c*d+e)*(1+c*x))]/(4*e) /;
FreeQ[{a,b,c,d,e},x] && NeQ[c^2*d^2-e^2,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^3/(d_+e_.*x_),x_Symbol] :=
  -(a+b*ArcCoth[c*x])^3*Log[2/(1+c*x)]/e + 
  3*b*(a+b*ArcCoth[c*x])^2*PolyLog[2,1-2/(1+c*x)]/(2*e) + 
  3*b^2*(a+b*ArcCoth[c*x])*PolyLog[3,1-2/(1+c*x)]/(2*e) + 
  3*b^3*PolyLog[4,1-2/(1+c*x)]/(4*e) + 
  (a+b*ArcCoth[c*x])^3*Log[2*c*(d+e*x)/((c*d+e)*(1+c*x))]/e - 
  3*b*(a+b*ArcCoth[c*x])^2*PolyLog[2,1-2*c*(d+e*x)/((c*d+e)*(1+c*x))]/(2*e) - 
  3*b^2*(a+b*ArcCoth[c*x])*PolyLog[3,1-2*c*(d+e*x)/((c*d+e)*(1+c*x))]/(2*e) - 
  3*b^3*PolyLog[4,1-2*c*(d+e*x)/((c*d+e)*(1+c*x))]/(4*e) /;
FreeQ[{a,b,c,d,e},x] && NeQ[c^2*d^2-e^2,0]

2:  ∫(((d+e x))^q)(a+b ArcTanh[c x])dx  when  q≠-1

Derivation: Integration by parts

Rule: If  q≠-1, then

∫(((d+e x))^q) (a+b ArcTanh[c x])dx  ⟶  (((((d+e x))^(q+1))(a+b ArcTanh[c x]))/(e(q+1)))-((b c)/(e(q+1)))∫((((d+e x))^(q+1))/(1-(c^2)(x^2)))dx

Program code:

Int[(d_+e_.*x_)^q_.*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  (d+e*x)^(q+1)*(a+b*ArcTanh[c*x])/(e*(q+1)) - 
  b*c/(e*(q+1))*Int[(d+e*x)^(q+1)/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[q,-1]

Int[(d_+e_.*x_)^q_.*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  (d+e*x)^(q+1)*(a+b*ArcCoth[c*x])/(e*(q+1)) - 
  b*c/(e*(q+1))*Int[(d+e*x)^(q+1)/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[q,-1]

3:  ∫(((d+e x))^q)(((a+b ArcTanh[c x]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ q∈ℤ ∧ q≠-1

Derivation: Integration by parts

Rule: If  p-1∈(SuperPlus[ℤ])∧ q∈ℤ ∧ q≠-1, then

∫(((d+e x))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  
(((((d+e x))^(q+1))(((a+b ArcTanh[c x]))^p))/(e(q+1)))-((b c p)/(e(q+1)))∫(((a+b ArcTanh[c x]))^(p-1)) ExpandIntegrand[((((d+e x))^(q+1))/(1-(c^2)(x^2))),x] dx

Program code:

Int[(d_+e_.*x_)^q_.*(a_.+b_.*ArcTanh[c_.*x_])^p_,x_Symbol] :=
  (d+e*x)^(q+1)*(a+b*ArcTanh[c*x])^p/(e*(q+1)) - 
  b*c*p/(e*(q+1))*Int[ExpandIntegrand[(a+b*ArcTanh[c*x])^(p-1),(d+e*x)^(q+1)/(1-c^2*x^2),x],x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,1] && IntegerQ[q] && NeQ[q,-1]

Int[(d_+e_.*x_)^q_.*(a_.+b_.*ArcCoth[c_.*x_])^p_,x_Symbol] :=
  (d+e*x)^(q+1)*(a+b*ArcCoth[c*x])^p/(e*(q+1)) - 
  b*c*p/(e*(q+1))*Int[ExpandIntegrand[(a+b*ArcCoth[c*x])^(p-1),(d+e*x)^(q+1)/(1-c^2*x^2),x],x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,1] && IntegerQ[q] && NeQ[q,-1]

2.  ∫(((d+e x))^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])

1.  ∫(((d+e x))^m) (a+b ArcTanh[c (x^n)])dx

1.  ∫((a+b ArcTanh[c (x^n)])/(d+e x))dx

1:  ∫((a+b ArcTanh[c (x^n)])/(d+e x))dx  when  n∈ℤ

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcTanh[c (x^n)])==b c n ((x^(n-1))/(1-(c^2) (x^(2 n))))

Rule: If  n∈ℤ, then

∫((a+b ArcTanh[c (x^n)])/(d+e x))dx  ⟶  ((Log[d+e x] (a+b ArcTanh[c (x^n)]))/e)-((b c n)/e)∫(((x^(n-1)) Log[d+e x])/(1-(c^2) (x^(2 n))))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_^n_])/(d_.+e_.*x_),x_Symbol] :=
  Log[d+e*x]*(a+b*ArcTanh[c*x^n])/e - 
  b*c*n/e*Int[x^(n-1)*Log[d+e*x]/(1-c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,n},x] && IntegerQ[n]

Int[(a_.+b_.*ArcCoth[c_.*x_^n_])/(d_.+e_.*x_),x_Symbol] :=
  Log[d+e*x]*(a+b*ArcCoth[c*x^n])/e - 
  b*c*n/e*Int[x^(n-1)*Log[d+e*x]/(1-c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,n},x] && IntegerQ[n]

2:  ∫((a+b ArcTanh[c (x^n)])/(d+e x))dx  when  n∈𝔽

Derivation: Integration by substitution

Basis: If k∈(SuperPlus[ℤ]), then F[x]==k Subst[(x^(k-1)) F[(x^k)],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  n∈𝔽, let k->Denominator[n], then

∫((a+b ArcTanh[c (x^n)])/(d+e x))dx  ⟶  k Subst[∫(((x^(k-1)) (a+b ArcTanh[c (x^(k n))]))/(d+e (x^k)))dx,x,(x^(1/k))]

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_^n_])/(d_+e_.*x_),x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*ArcTanh[c*x^(k*n)])/(d+e*x^k),x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d,e},x] && FractionQ[n]

Int[(a_.+b_.*ArcCoth[c_.*x_^n_])/(d_+e_.*x_),x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*ArcCoth[c*x^(k*n)])/(d+e*x^k),x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d,e},x] && FractionQ[n]

2:  ∫(((d+e x))^m) (a+b ArcTanh[c (x^n)])dx  when  m≠-1

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcTanh[c (x^n)])==b c n ((x^(n-1))/(1-(c^2) (x^(2 n))))

Rule: If  m≠-1, then

∫(((d+e x))^m) (a+b ArcTanh[c (x^n)])dx  ⟶  (((((d+e x))^(m+1))(a+b ArcTanh[c (x^n)]))/(e (m+1)))-((b c n)/(e (m+1)))∫(((x^(n-1)) (((d+e x))^(m+1)))/(1-(c^2) (x^(2 n))))dx

Program code:

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcTanh[c_.*x_^n_]),x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*ArcTanh[c*x^n])/(e*(m+1)) - 
  b*c*n/(e*(m+1))*Int[x^(n-1)*(d+e*x)^(m+1)/(1-c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[m,-1]

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcCoth[c_.*x_^n_]),x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*ArcCoth[c*x^n])/(e*(m+1)) - 
  b*c*n/(e*(m+1))*Int[x^(n-1)*(d+e*x)^(m+1)/(1-c^2*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[m,-1]

2:  ∫(((d+e x))^m) (((a+b ArcTanh[c (x^n)]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p-1∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ]), then

∫(((d+e x))^m) (((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  ∫(((a+b ArcTanh[c (x^n)]))^p) ExpandIntegrand[(((d+e x))^m),x]dx

Program code:

Int[(d_+e_.*x_)^m_.*(a_.+b_.*ArcTanh[c_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcTanh[c*x^n])^p,(d+e*x)^m,x],x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[p,1] && IGtQ[m,0]

Int[(d_+e_.*x_)^m_.*(a_.+b_.*ArcCoth[c_.*x_^n_])^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCoth[c*x^n])^p,(d+e*x)^m,x],x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[p,1] && IGtQ[m,0]

U:  ∫(((d+e x))^m)(((a+b ArcTanh[c (x^n)]))^p)dx

Rule:

∫(((d+e x))^m)(((a+b ArcTanh[c (x^n)]))^p)dx  ⟶  ∫(((d+e x))^m)(((a+b ArcTanh[c (x^n)]))^p)dx

Program code:

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcTanh[c_.*x_^n_])^p_.,x_Symbol] :=
  Unintegrable[(d+e*x)^m*(a+b*ArcTanh[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x]

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcCoth[c_.*x_^n_])^p_.,x_Symbol] :=
  Unintegrable[(d+e*x)^m*(a+b*ArcCoth[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x]