Rules for integrands involving (((a+b ArcTanh[c x]))^p)

4.  ∫(((f x))^m) (((d+e x))^q) (((a+b ArcTanh[c x]))^p)dx  when  p∈(SuperPlus[ℤ])

1.  ∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(d+e x))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0

1:  ∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(d+e x))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0 ∧ m>0

Derivation: Algebraic expansion

Basis: (x/(d+e x))==(1/e)-(d/(e (d+e x)))

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0 ∧ m>0, then

∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(d+e x))dx  ⟶  (f/e)∫(((f x))^(m-1)) (((a+b ArcTanh[c x]))^p)dx-((d f)/e)∫(((((f x))^(m-1)) (((a+b ArcTanh[c x]))^p))/(d+e x))dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_),x_Symbol] :=
  f/e*Int[(f*x)^(m-1)*(a+b*ArcTanh[c*x])^p,x] - 
  d*f/e*Int[(f*x)^(m-1)*(a+b*ArcTanh[c*x])^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && EqQ[c^2*d^2-e^2,0] && GtQ[m,0]

Int[(f_.*x_)^m_.*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_),x_Symbol] :=
  f/e*Int[(f*x)^(m-1)*(a+b*ArcCoth[c*x])^p,x] - 
  d*f/e*Int[(f*x)^(m-1)*(a+b*ArcCoth[c*x])^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && EqQ[c^2*d^2-e^2,0] && GtQ[m,0]

2.  ∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(d+e x))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0 ∧ m<0

1:  ∫((((a+b ArcTanh[c x]))^p)/(x(d+e x)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0

Derivation: Integration by parts

Basis: (1/(x (d+e x)))==(1/d) (∂_x)Log[2-(2/(1+((e x)/d)))]

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0, then

∫((((a+b ArcTanh[c x]))^p)/(x(d+e x)))dx  ⟶  (((((a+b ArcTanh[c x]))^p) Log[2-(2/(1+((e x)/d)))])/d)-((b c p)/d)∫(((((a+b ArcTanh[c x]))^(p-1)) Log[2-(2/(1+((e x)/d)))])/(1-(c^2)(x^2)))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_./(x_*(d_+e_.*x_)),x_Symbol] :=
  (a+b*ArcTanh[c*x])^p*Log[2-2/(1+e*x/d)]/d - 
  b*c*p/d*Int[(a+b*ArcTanh[c*x])^(p-1)*Log[2-2/(1+e*x/d)]/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d^2-e^2,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_./(x_*(d_+e_.*x_)),x_Symbol] :=
  (a+b*ArcCoth[c*x])^p*Log[2-2/(1+e*x/d)]/d - 
  b*c*p/d*Int[(a+b*ArcCoth[c*x])^(p-1)*Log[2-2/(1+e*x/d)]/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d^2-e^2,0]

2:  ∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(d+e x))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0 ∧ m<-1

Derivation: Algebraic expansion

Basis: (1/(d+e x))==(1/d)-((e x)/(d (d+e x)))

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0 ∧ m<-1, then

∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(d+e x))dx  ⟶  (1/d)∫(((f x))^m) (((a+b ArcTanh[c x]))^p)dx-(e/(d f))∫(((((f x))^(m+1)) (((a+b ArcTanh[c x]))^p))/(d+e x))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_),x_Symbol] :=
  1/d*Int[(f*x)^m*(a+b*ArcTanh[c*x])^p,x] - 
  e/(d*f)*Int[(f*x)^(m+1)*(a+b*ArcTanh[c*x])^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && EqQ[c^2*d^2-e^2,0] && LtQ[m,-1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_),x_Symbol] :=
  1/d*Int[(f*x)^m*(a+b*ArcCoth[c*x])^p,x] - 
  e/(d*f)*Int[(f*x)^(m+1)*(a+b*ArcCoth[c*x])^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && EqQ[c^2*d^2-e^2,0] && LtQ[m,-1]

2:  ∫(((f x))^m) (((d+e x))^q)(a+b ArcTanh[c x])dx  when  q≠-1 ∧ 2 m∈ℤ ∧ ((m|q)∈(SuperPlus[ℤ]) ∨ m+q+1∈(SuperMinus[ℤ])∧ m q<0)

Derivation: Integration by parts

Rule: If  q≠-1 ∧ 2 m∈ℤ ∧ ((m|q)∈(SuperPlus[ℤ]) ∨ m+q+1∈(SuperMinus[ℤ])∧ m q<0), let u->∫(((f x))^m) (((d+e x))^q)dx, then

∫(((f x))^m) (((d+e x))^q) (a+b ArcTanh[c x])dx  ⟶  u(a+b ArcTanh[c x])-b c∫(u/(1-(c^2)(x^2)))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_)^q_.*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x)^q,x]},
  Dist[(a+b*ArcTanh[c*x]),u] - b*c*Int[SimplifyIntegrand[u/(1-c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,q},x] && NeQ[q,-1] && IntegerQ[2*m] && (IGtQ[m,0] && IGtQ[q,0] || ILtQ[m+q+1,0] && LtQ[m*q,0])

Int[(f_.*x_)^m_.*(d_.+e_.*x_)^q_.*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x)^q,x]},
  Dist[(a+b*ArcCoth[c*x]),u] - b*c*Int[SimplifyIntegrand[u/(1-c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,q},x] && NeQ[q,-1] && IntegerQ[2*m] && (IGtQ[m,0] && IGtQ[q,0] || ILtQ[m+q+1,0] && LtQ[m*q,0])

3:  ∫(((f x))^m) (((d+e x))^q)(((a+b ArcTanh[c x]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0 ∧ (m|q)∈ℤ ∧ q≠-1

Derivation: Integration by parts

Rule: If  p-1∈(SuperPlus[ℤ])∧ (c^2) (d^2)-(e^2)==0 ∧ (m|q)∈ℤ ∧ q≠-1, let u->∫(((f x))^m) (((d+e x))^q)dx, then

∫(((f x))^m) (((d+e x))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  
u(((a+b ArcTanh[c x]))^p)-b c p∫(((a+b ArcTanh[c x]))^(p-1)) ExpandIntegrand[(u/(1-(c^2)(x^2))),x] dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_,x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x)^q,x]},
  Dist[(a+b*ArcTanh[c*x])^p,u] - b*c*p*Int[ExpandIntegrand[(a+b*ArcTanh[c*x])^(p-1),u/(1-c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,q},x] && IGtQ[p,1] && EqQ[c^2*d^2-e^2,0] && IntegersQ[m,q] && NeQ[m,-1] && NeQ[q,-1] && ILtQ[m+q+1,0] && LtQ[m*q,0]

Int[(f_.*x_)^m_.*(d_.+e_.*x_)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_,x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x)^q,x]},
  Dist[(a+b*ArcCoth[c*x])^p,u] - b*c*p*Int[ExpandIntegrand[(a+b*ArcCoth[c*x])^(p-1),u/(1-c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,q},x] && IGtQ[p,1] && EqQ[c^2*d^2-e^2,0] && IntegersQ[m,q] && NeQ[m,-1] && NeQ[q,-1] && ILtQ[m+q+1,0] && LtQ[m*q,0]

4:  ∫(((f x))^m) (((d+e x))^q) (((a+b ArcTanh[c x]))^p)dx  when  p∈(SuperPlus[ℤ])∧ q∈ℤ ∧ (q>0 ∨ a≠0 ∨ m∈ℤ)

Rule: If  p∈(SuperPlus[ℤ])∧ q∈ℤ ∧ (q>0 ∨ a≠0 ∨ m∈ℤ), then

∫(((f x))^m) (((d+e x))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  ∫(((a+b ArcTanh[c x]))^p) ExpandIntegrand[(((f x))^m)(((d+e x))^q),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_)^q_.*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcTanh[c*x])^p,(f*x)^m*(d+e*x)^q,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[p,0] && IntegerQ[q] && (GtQ[q,0] || NeQ[a,0] || IntegerQ[m])

Int[(f_.*x_)^m_.*(d_+e_.*x_)^q_.*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCoth[c*x])^p,(f*x)^m*(d+e*x)^q,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[p,0] && IntegerQ[q] && (GtQ[q,0] || NeQ[a,0] || IntegerQ[m])

5.  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx

1.  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0

1.  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q>0

1:  ∫(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  when  (c^2) d+e==0 ∧ q>0

Rule: If  (c^2) d+e==0 ∧ q>0, then

∫(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  ⟶  
((b(((d+e (x^2)))^q))/(2 c q(2q+1)))+((x (((d+e (x^2)))^q) (a+b ArcTanh[c x]))/(2q+1))+((2 d q)/(2 q+1))∫(((d+e (x^2)))^(q-1)) (a+b ArcTanh[c x])dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  b*(d+e*x^2)^q/(2*c*q*(2*q+1)) + 
  x*(d+e*x^2)^q*(a+b*ArcTanh[c*x])/(2*q+1) + 
  2*d*q/(2*q+1)*Int[(d+e*x^2)^(q-1)*(a+b*ArcTanh[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[q,0]

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  b*(d+e*x^2)^q/(2*c*q*(2*q+1)) + 
  x*(d+e*x^2)^q*(a+b*ArcCoth[c*x])/(2*q+1) + 
  2*d*q/(2*q+1)*Int[(d+e*x^2)^(q-1)*(a+b*ArcCoth[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[q,0]

2:  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q>0 ∧ p>1

Rule: If  (c^2) d+e==0 ∧ q>0 ∧ p>1, then

∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  
((b p(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^(p-1)))/(2 c q(2q+1)))+(( x (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p))/(2q+1))+
((2d q)/(2q+1)) ∫(((d+e (x^2)))^(q-1)) (((a+b ArcTanh[c x]))^p)dx-(((b^2)d p(p-1))/(2q(2q+1))) ∫(((d+e (x^2)))^(q-1)) (((a+b ArcTanh[c x]))^(p-2))dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_])^p_,x_Symbol] :=
  b*p*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^(p-1)/(2*c*q*(2*q+1)) + 
  x*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^p/(2*q+1) + 
  2*d*q/(2*q+1)*Int[(d+e*x^2)^(q-1)*(a+b*ArcTanh[c*x])^p,x] - 
  b^2*d*p*(p-1)/(2*q*(2*q+1))*Int[(d+e*x^2)^(q-1)*(a+b*ArcTanh[c*x])^(p-2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[q,0] && GtQ[p,1]

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_])^p_,x_Symbol] :=
  b*p*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^(p-1)/(2*c*q*(2*q+1)) + 
  x*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^p/(2*q+1) + 
  2*d*q/(2*q+1)*Int[(d+e*x^2)^(q-1)*(a+b*ArcCoth[c*x])^p,x] - 
  b^2*d*p*(p-1)/(2*q*(2*q+1))*Int[(d+e*x^2)^(q-1)*(a+b*ArcCoth[c*x])^(p-2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[q,0] && GtQ[p,1]

2.  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q<0

1.  ∫((((a+b ArcTanh[c x]))^p)/(d+e (x^2)))dx  when  (c^2) d+e==0

x:  ∫((((a+b ArcTanh[c x]))^p)/(d+e (x^2)))dx  when  (c^2) d+e==0

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0, then ((F[ArcTanh[c x]])/(d+e (x^2)))==(1/(c d)) Subst[F[x],x,ArcTanh[c x]] (∂_x)ArcTanh[c x]

Rule: If  (c^2) d+e==0, then

∫((((a+b ArcTanh[c x]))^p)/(d+e (x^2)))dx  ⟶  (1/(c d)) Subst[∫(((a+b x))^p)dx,x,ArcTanh[c x]]

Program code:

(* Int[(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/(c*d)*Subst[Int[(a+b*x)^p,x],x,ArcTanh[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] *)

(* Int[(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/(c*d)*Subst[Int[(a+b*x)^p,x],x,ArcCoth[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] *)

1:  ∫(1/((d+e (x^2))(a+b ArcTanh[c x])))dx  when  (c^2) d+e==0

Derivation: Integration by substitution

Rule: If  (c^2) d+e==0, then

∫(1/((d+e (x^2))(a+b ArcTanh[c x])))dx  ⟶  ((Log[a+b ArcTanh[c x]])/(b c d))

Program code:

Int[1/((d_+e_.*x_^2)*(a_.+b_.*ArcTanh[c_.*x_])),x_Symbol] :=
  Log[RemoveContent[a+b*ArcTanh[c*x],x]]/(b*c*d) /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0]

Int[1/((d_+e_.*x_^2)*(a_.+b_.*ArcCoth[c_.*x_])),x_Symbol] :=
  Log[RemoveContent[a+b*ArcCoth[c*x],x]]/(b*c*d) /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0]

2:  ∫((((a+b ArcTanh[c x]))^p)/(d+e (x^2)))dx  when  (c^2) d+e==0 ∧ p≠-1

Derivation: Integration by substitution

Rule: If  (c^2) d+e==0 ∧ p≠-1, then

∫((((a+b ArcTanh[c x]))^p)/(d+e (x^2)))dx  ⟶  ((((a+b ArcTanh[c x]))^(p+1))/(b c d(p+1)))

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcTanh[c*x])^(p+1)/(b*c*d*(p+1)) /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && NeQ[p,-1]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcCoth[c*x])^(p+1)/(b*c*d*(p+1)) /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && NeQ[p,-1]

2.  ∫((((a+b ArcTanh[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])

1.  ∫((((a+b ArcTanh[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0

1:  ∫(((a+b ArcTanh[c x]))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ d>0

Derivation: Integration by substitution and algebraic simplification

Note: Although not essential, these rules returns antiderivatives free of complex exponentials of the form  (e^(ArcTanh[c x])) and  (e^(ArcCoth[c x])).

Basis: If  (c^2) d+e==0 ∧ d>0, then (1/(Sqrt[d+e (x^2)]))==(1/(c(Sqrt[d]))) Sech[ArcTanh[c x]] (∂_x)ArcTanh[c x]

Basis: If  (c^2) d+e==0 ∧ d>0, then (1/(Sqrt[d+e (x^2)]))==-(1/(c(Sqrt[d])))(((Csch[ArcCoth[c x]])^2)/(Sqrt[-((Csch[ArcCoth[c x]])^2)])) (∂_x)ArcCoth[c x]

Rule: If  (c^2) d+e==0 ∧ d>0, then

∫((a+b ArcTanh[c x])/(Sqrt[d+e (x^2)]))dx  ⟶  (1/(c(Sqrt[d])))Subst[(a+b x)Sech[x],x,ArcTanh[c x]]
  ⟶  -((2(a+b ArcTanh[c x]) ArcTan[((Sqrt[1-c x])/(Sqrt[1+c x]))])/(c (Sqrt[d])))-((i b PolyLog[2,-((i(Sqrt[1-c x]))/(Sqrt[1+c x]))])/(c (Sqrt[d])))+((i b PolyLog[2,((i(Sqrt[1-c x]))/(Sqrt[1+c x]))])/(c (Sqrt[d])))

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -2*(a+b*ArcTanh[c*x])*ArcTan[Sqrt[1-c*x]/Sqrt[1+c*x]]/(c*Sqrt[d]) - 
  I*b*PolyLog[2,-I*Sqrt[1-c*x]/Sqrt[1+c*x]]/(c*Sqrt[d]) + 
  I*b*PolyLog[2,I*Sqrt[1-c*x]/Sqrt[1+c*x]]/(c*Sqrt[d]) /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[d,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -2*(a+b*ArcCoth[c*x])*ArcTan[Sqrt[1-c*x]/Sqrt[1+c*x]]/(c*Sqrt[d]) - 
  I*b*PolyLog[2,-I*Sqrt[1-c*x]/Sqrt[1+c*x]]/(c*Sqrt[d]) + 
  I*b*PolyLog[2,I*Sqrt[1-c*x]/Sqrt[1+c*x]]/(c*Sqrt[d]) /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[d,0]

2.  ∫((((a+b ArcTanh[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0

1:  ∫((((a+b ArcTanh[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0 ∧ d>0, then (1/(Sqrt[d+e (x^2)]))==(1/(c(Sqrt[d]))) Sech[ArcTanh[c x]] (∂_x)ArcTanh[c x]

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0, then

∫((((a+b ArcTanh[c x]))^p)/(Sqrt[d+e (x^2)]))dx  ⟶  (1/(c(Sqrt[d]))) Subst[∫(((a+b x))^p)Sech[x]dx,x,ArcTanh[c x]]

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  1/(c*Sqrt[d])*Subst[Int[(a+b*x)^p*Sech[x],x],x,ArcTanh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && GtQ[d,0]

2:  ∫((((a+b ArcCoth[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0

Derivation: Integration by substitution and piecewise constant extraction

Basis: If  (c^2) d+e==0 ∧ d>0, then (1/(Sqrt[d+e (x^2)]))==-(1/(c(Sqrt[d])))(((Csch[ArcCoth[c x]])^2)/(Sqrt[-((Csch[ArcCoth[c x]])^2)])) (∂_x)ArcCoth[c x]

Basis: (∂_x)((Csch[x])/(Sqrt[-((Csch[x])^2)]))==0

Basis: ((Csch[ArcCoth[c x]])/(Sqrt[-((Csch[ArcCoth[c x]])^2)]))==((c x(Sqrt[1-(1/((c^2) (x^2)))]))/(Sqrt[1-(c^2)(x^2)]))

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0, then

∫((((a+b ArcCoth[c x]))^p)/(Sqrt[d+e (x^2)]))dx  ⟶ - (1/(c(Sqrt[d]))) Subst[∫(((((a+b x))^p)((Csch[x])^2))/(Sqrt[-((Csch[x])^2)]))dx,x,ArcCoth[c x]]                                        
                        ⟶ - ((x(Sqrt[1-(1/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)]))Subst[∫(((a+b x))^p)Csch[x]dx,x,ArcCoth[c x]]

Program code:

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -x*Sqrt[1-1/(c^2*x^2)]/Sqrt[d+e*x^2]*Subst[Int[(a+b*x)^p*Csch[x],x],x,ArcCoth[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && GtQ[d,0]

2:  ∫((((a+b ArcTanh[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d≯0

Derivation: Piecewise constant extraction

Basis: If  (c^2) d+e==0, then (∂_x)((Sqrt[1-(c^2)(x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d≯0, then

∫((((a+b ArcTanh[c x]))^p)/(Sqrt[d+e (x^2)]))dx  ⟶  ((Sqrt[1-(c^2)(x^2)])/(Sqrt[d+e (x^2)]))∫((((a+b ArcTanh[c x]))^p)/(Sqrt[1-(c^2)(x^2)]))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  Sqrt[1-c^2*x^2]/Sqrt[d+e*x^2]*Int[(a+b*ArcTanh[c*x])^p/Sqrt[1-c^2*x^2],x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && Not[GtQ[d,0]]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  Sqrt[1-c^2*x^2]/Sqrt[d+e*x^2]*Int[(a+b*ArcCoth[c*x])^p/Sqrt[1-c^2*x^2],x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && Not[GtQ[d,0]]

3.  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q<-1

1:  ∫((((a+b ArcTanh[c x]))^p)/(((d+e (x^2)))^2))dx  when  (c^2) d+e==0 ∧ p>0

Rule: If  (c^2) d+e==0 ∧ p>0, then

∫((((a+b ArcTanh[c x]))^p)/(((d+e (x^2)))^2))dx  ⟶  ((x (((a+b ArcTanh[c x]))^p))/(2 d (d+e (x^2))))+((((a+b ArcTanh[c x]))^(p+1))/(2b c (d^2)(p+1)))-((b c p)/2)∫((x (((a+b ArcTanh[c x]))^(p-1)))/(((d+e (x^2)))^2))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  x*(a+b*ArcTanh[c*x])^p/(2*d*(d+e*x^2)) + 
  (a+b*ArcTanh[c*x])^(p+1)/(2*b*c*d^2*(p+1)) - 
  b*c*p/2*Int[x*(a+b*ArcTanh[c*x])^(p-1)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[p,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  x*(a+b*ArcCoth[c*x])^p/(2*d*(d+e*x^2)) + 
  (a+b*ArcCoth[c*x])^(p+1)/(2*b*c*d^2*(p+1)) - 
  b*c*p/2*Int[x*(a+b*ArcCoth[c*x])^(p-1)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[p,0]

2.  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q<-1 ∧ p≥1

1.  ∫(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  when  (c^2) d+e==0 ∧ q<-1

1:  ∫((a+b ArcTanh[c x])/(((d+e (x^2)))^(3/2)))dx  when  (c^2) d+e==0

Rule: If  (c^2) d+e==0, then

∫((a+b ArcTanh[c x])/(((d+e (x^2)))^(3/2)))dx  ⟶  -(b/(c d(Sqrt[d+e (x^2)])))+((x (a+b ArcTanh[c x]))/(d(Sqrt[d+e (x^2)])))

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])/(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  -b/(c*d*Sqrt[d+e*x^2]) +
  x*(a+b*ArcTanh[c*x])/(d*Sqrt[d+e*x^2]) /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])/(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  -b/(c*d*Sqrt[d+e*x^2]) +
  x*(a+b*ArcCoth[c*x])/(d*Sqrt[d+e*x^2]) /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0]

2:  ∫(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  when  (c^2) d+e==0 ∧ q<-1 ∧ q≠-(3/2)

Rule: If  (c^2) d+e==0 ∧ q<-1 ∧ q≠-(3/2), then

∫(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  ⟶  -((b(((d+e (x^2)))^(q+1)))/(4 c d (((q+1))^2)))-((x (((d+e (x^2)))^(q+1)) (a+b ArcTanh[c x]))/(2d(q+1)))+((2q+3)/(2 d(q+1)))∫(((d+e (x^2)))^(q+1)) (a+b ArcTanh[c x])dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  -b*(d+e*x^2)^(q+1)/(4*c*d*(q+1)^2) -
  x*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])/(2*d*(q+1)) +
  (2*q+3)/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && LtQ[q,-1] && NeQ[q,-3/2]

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  -b*(d+e*x^2)^(q+1)/(4*c*d*(q+1)^2) -
  x*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])/(2*d*(q+1)) +
  (2*q+3)/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && LtQ[q,-1] && NeQ[q,-3/2]

2.  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q<-1 ∧ p>1

1:  ∫((((a+b ArcTanh[c x]))^p)/(((d+e (x^2)))^(3/2)))dx  when  (c^2) d+e==0 ∧ p>1

Rule: If  (c^2) d+e==0 ∧ p>1, then

∫((((a+b ArcTanh[c x]))^p)/(((d+e (x^2)))^(3/2)))dx  ⟶  -((b p (((a+b ArcTanh[c x]))^(p-1)))/(c d(Sqrt[d+e (x^2)])))+((x (((a+b ArcTanh[c x]))^p))/(d(Sqrt[d+e (x^2)])))+(b^2)p(p-1)∫((((a+b ArcTanh[c x]))^(p-2))/(((d+e (x^2)))^(3/2)))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_/(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  -b*p*(a+b*ArcTanh[c*x])^(p-1)/(c*d*Sqrt[d+e*x^2]) +
  x*(a+b*ArcTanh[c*x])^p/(d*Sqrt[d+e*x^2]) +
  b^2*p*(p-1)*Int[(a+b*ArcTanh[c*x])^(p-2)/(d+e*x^2)^(3/2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[p,1]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_/(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  -b*p*(a+b*ArcCoth[c*x])^(p-1)/(c*d*Sqrt[d+e*x^2]) +
  x*(a+b*ArcCoth[c*x])^p/(d*Sqrt[d+e*x^2]) +
  b^2*p*(p-1)*Int[(a+b*ArcCoth[c*x])^(p-2)/(d+e*x^2)^(3/2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[p,1]

2:  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q<-1 ∧ p>1 ∧ q≠-(3/2)

Rule: If  (c^2) d+e==0 ∧ q<-1 ∧ p>1 ∧ q≠-(3/2), then

∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  
-((b p (((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^(p-1)))/(4 c d(((q+1))^2)))-((x (((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^p))/(2 d(q+1)))+
((2 q+3)/(2 d(q+1)))∫(((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^p)dx+(((b^2)p(p-1))/(4(((q+1))^2)))∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^(p-2))dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_,x_Symbol] :=
  -b*p*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^(p-1)/(4*c*d*(q+1)^2) -
  x*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^p/(2*d*(q+1)) +
  (2*q+3)/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^p,x] +
  b^2*p*(p-1)/(4*(q+1)^2)*Int[(d+e*x^2)^q*(a+b*ArcTanh[c*x])^(p-2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && LtQ[q,-1] && GtQ[p,1] && NeQ[q,-3/2]

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_,x_Symbol] :=
  -b*p*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^(p-1)/(4*c*d*(q+1)^2) -
  x*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^p/(2*d*(q+1)) +
  (2*q+3)/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^p,x] +
  b^2*p*(p-1)/(4*(q+1)^2)*Int[(d+e*x^2)^q*(a+b*ArcCoth[c*x])^(p-2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && LtQ[q,-1] && GtQ[p,1] && NeQ[q,-3/2]

3:  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q<-1 ∧ p<-1

Derivation: Integration by parts

Basis: If  (c^2) d+e==0, then ((((a+b ArcTanh[c x]))^p)/(d+e (x^2)))==(∂_x)((((a+b ArcTanh[c x]))^(p+1))/(b c d(p+1)))

Rule: If  (c^2) d+e==0 ∧ q<-1 ∧ p<-1, then

∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  (((((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^(p+1)))/(b c d(p+1)))+((2 c (q+1))/(b(p+1)))  ∫x (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^(p+1))dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_,x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^(p+1)/(b*c*d*(p+1)) + 
  2*c*(q+1)/(b*(p+1))*Int[x*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && LtQ[q,-1] && LtQ[p,-1]

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_,x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^(p+1)/(b*c*d*(p+1)) + 
  2*c*(q+1)/(b*(p+1))*Int[x*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && LtQ[q,-1] && LtQ[p,-1]

4.  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])

1.  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])

1:  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ (q∈ℤ ∨ d>0)

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0 ∧ 2 (q+1)∈ℤ ∧ (q∈ℤ ∨ d>0), then (((d+e (x^2)))^q)==((d^q)/(c ((Cosh[ArcTanh[c x]])^(2 (q+1)))))(∂_x)ArcTanh[c x]

Rule: If  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ (q∈ℤ ∨ d>0), then

∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  ((d^q)/c) Subst[∫((((a+b x))^p)/((Cosh[x])^(2 (q+1))))dx,x,ArcTanh[c x]]

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  d^q/c*Subst[Int[(a+b*x)^p/Cosh[x]^(2*(q+1)),x],x,ArcTanh[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && ILtQ[2*(q+1),0] && (IntegerQ[q] || GtQ[d,0])

2:  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ ¬(q∈ℤ ∨ d>0)

Derivation: Piecewise contant extraction

Basis: If  (c^2) d+e==0, then (∂_x)((Sqrt[1-(c^2)(x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ ¬(q∈ℤ ∨ d>0), then

∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  (((d^(q+(1/2)))(Sqrt[1-(c^2)(x^2)]))/(Sqrt[d+e (x^2)])) ∫(((1-(c^2)(x^2)))^q)(((a+b ArcTanh[c x]))^p)dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  d^(q+1/2)*Sqrt[1-c^2*x^2]/Sqrt[d+e*x^2]*Int[(1-c^2*x^2)^q*(a+b*ArcTanh[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && ILtQ[2*(q+1),0] && Not[IntegerQ[q] || GtQ[d,0]]

2.  ∫(((d+e (x^2)))^q) (((a+b ArcCoth[c x]))^p)dx  when  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])

1:  ∫(((d+e (x^2)))^q) (((a+b ArcCoth[c x]))^p)dx  when  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ q∈ℤ

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0 ∧ q∈ℤ, then (((d+e (x^2)))^q)==-((((-d))^q)/(c ((Sinh[ArcCoth[c x]])^(2 (q+1)))))(∂_x)ArcCoth[c x]

Rule: If  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ q∈ℤ, then

∫(((d+e (x^2)))^q) (((a+b ArcCoth[c x]))^p)dx  ⟶  -((((-d))^q)/c) Subst[∫((((a+b x))^p)/((Sinh[x])^(2 (q+1))))dx,x,ArcCoth[c x]]

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  -(-d)^q/c*Subst[Int[(a+b*x)^p/Sinh[x]^(2*(q+1)),x],x,ArcCoth[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && ILtQ[2*(q+1),0] && IntegerQ[q]

2:  ∫(((d+e (x^2)))^q)(((a+b ArcCoth[c x]))^p)dx  when  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ q∉ℤ

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  (c^2) d+e==0, then (∂_x)((x (Sqrt[(((c^2)(x^2)-1)/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)]))==0

Basis: If  2 (q+1)∈ℤ ∧ q∉ℤ, then x(Sqrt[1-(1/((c^2) (x^2)))])(((-1+(c^2)(x^2)))^(q-(1/2)))==-(1/((c^2)((Sinh[ArcCoth[c x]])^(2(q+1)))))(∂_x)ArcCoth[c x]

Rule: If  (c^2) d+e==0 ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ q∉ℤ, then

∫(((d+e (x^2)))^q)(((a+b ArcCoth[c x]))^p)dx  ⟶  (((c^2)(((-d))^(q+(1/2)))x (Sqrt[(((c^2)(x^2)-1)/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)])) ∫x(Sqrt[1-(1/((c^2) (x^2)))])(((-1+(c^2)(x^2)))^(q-(1/2)))(((a+b ArcCoth[c x]))^p)dx
  ⟶  -(((((-d))^(q+(1/2)))x (Sqrt[(((c^2)(x^2)-1)/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)])) Subst[∫((((a+b x))^p)/((Sinh[x])^(2 (q+1))))dx,x,ArcCoth[c x]]

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  -(-d)^(q+1/2)*x*Sqrt[(c^2*x^2-1)/(c^2*x^2)]/Sqrt[d+e*x^2]*Subst[Int[(a+b*x)^p/Sinh[x]^(2*(q+1)),x],x,ArcCoth[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && ILtQ[2*(q+1),0] && Not[IntegerQ[q]]

2.  ∫((a+b ArcTanh[c x])/(d+e (x^2)))dx

1:  ∫((ArcTanh[c x])/(d+e (x^2)))dx

Derivation: Algebraic expansion

Basis: ArcTanh[z]==(1/2) Log[1+z]-(1/2) Log[1-z]

Basis: ArcCoth[z]==(1/2) Log[1+(1/z)]-(1/2) Log[1-(1/z)]

Rule:

∫((ArcTanh[c x])/(d+e (x^2)))dx  ⟶  (1/2)∫((Log[1+c x])/(d+e (x^2)))dx-(1/2)∫((Log[1-c x])/(d+e (x^2)))dx

Program code:

Int[ArcTanh[c_.*x_]/(d_.+e_.*x_^2),x_Symbol] :=
  1/2*Int[Log[1+c*x]/(d+e*x^2),x] - 1/2*Int[Log[1-c*x]/(d+e*x^2),x] /;
FreeQ[{c,d,e},x]

Int[ArcCoth[c_.*x_]/(d_.+e_.*x_^2),x_Symbol] :=
  1/2*Int[Log[1+1/(c*x)]/(d+e*x^2),x] - 1/2*Int[Log[1-1/(c*x)]/(d+e*x^2),x] /;
FreeQ[{c,d,e},x]

2:  ∫((a+b ArcTanh[c x])/(d+e (x^2)))dx

Derivation: Algebraic expansion

Rule:

∫((a+b ArcTanh[c x])/(d+e (x^2)))dx  ⟶  a∫(1/(d+e (x^2)))dx+b∫((ArcTanh[c x])/(d+e (x^2)))dx

Program code:

Int[(a_+b_.*ArcTanh[c_.*x_])/(d_.+e_.*x_^2),x_Symbol] :=
  a*Int[1/(d+e*x^2),x] + b*Int[ArcTanh[c*x]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x]

Int[(a_+b_.*ArcCoth[c_.*x_])/(d_.+e_.*x_^2),x_Symbol] :=
  a*Int[1/(d+e*x^2),x] + b*Int[ArcCoth[c*x]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x]

3:  ∫(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  when  q∈ℤ ∨ q+(1/2)∈(SuperMinus[ℤ])

Derivation: Integration by parts

Note: If  q∈(SuperPlus[ℤ])∨ q+(1/2)∈(SuperMinus[ℤ]), then ∫(((d+e (x^2)))^q)dx is expressible as an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If  q∈ℤ ∨ q+(1/2)∈(SuperMinus[ℤ]), let u=∫(((d+e (x^2)))^q)dx, then

∫(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  ⟶  u (a+b ArcTanh[c x])-b c∫(u/(1-(c^2) (x^2)))dx

Program code:

Int[(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^q,x]},  
  Dist[a+b*ArcTanh[c*x],u,x] - b*c*Int[u/(1-c^2*x^2),x]] /;
FreeQ[{a,b,c,d,e},x] && (IntegerQ[q] || ILtQ[q+1/2,0])

Int[(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^q,x]},  
  Dist[a+b*ArcCoth[c*x],u,x] - b*c*Int[u/(1-c^2*x^2),x]] /;
FreeQ[{a,b,c,d,e},x] && (IntegerQ[q] || ILtQ[q+1/2,0])

4:  ∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  q∈ℤ ∧ p∈(SuperPlus[ℤ])

Rule: If  q∈ℤ ∧ p∈(SuperPlus[ℤ]), then

∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  ∫(((a+b ArcTanh[c x]))^p) ExpandIntegrand[(((d+e (x^2)))^q),x]dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcTanh[c*x])^p,(d+e*x^2)^q,x],x] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[q] && IGtQ[p,0]

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCoth[c*x])^p,(d+e*x^2)^q,x],x] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[q] && IGtQ[p,0]

6.  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx

1.  ∫(((((f x))^m)(((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx

1:  ∫(((((f x))^m)(((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  p>0 ∧ m>1

Derivation: Algebraic expansion

Basis: ((x^2)/(d+e (x^2)))==(1/e)-(d/(e (d+e (x^2))))

Rule: If  p>0 ∧ m>1, then

∫(((((f x))^m)(((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  ⟶  ((f^2)/e)∫(((f x))^(m-2))(((a+b ArcTanh[c x]))^p)dx-((d (f^2))/e)∫(((((f x))^(m-2))(((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  f^2/e*Int[(f*x)^(m-2)*(a+b*ArcTanh[c*x])^p,x] -
  d*f^2/e*Int[(f*x)^(m-2)*(a+b*ArcTanh[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && GtQ[p,0] && GtQ[m,1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  f^2/e*Int[(f*x)^(m-2)*(a+b*ArcCoth[c*x])^p,x] -
  d*f^2/e*Int[(f*x)^(m-2)*(a+b*ArcCoth[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && GtQ[p,0] && GtQ[m,1]

2:  ∫(((((f x))^m)(((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  p>0 ∧ m<-1

Derivation: Algebraic expansion

Basis: (1/(d+e (x^2)))==(1/d)-((e (x^2))/(d (d+e (x^2))))

Rule: If  p>0 ∧ m<-1, then

∫(((((f x))^m)(((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  ⟶  (1/d)∫(((f x))^m)(((a+b ArcTanh[c x]))^p)dx-(e/(d (f^2)))∫(((((f x))^(m+2))(((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/d*Int[(f*x)^m*(a+b*ArcTanh[c*x])^p,x] -
  e/(d*f^2)*Int[(f*x)^(m+2)*(a+b*ArcTanh[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && GtQ[p,0] && LtQ[m,-1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/d*Int[(f*x)^m*(a+b*ArcCoth[c*x])^p,x] -
  e/(d*f^2)*Int[(f*x)^(m+2)*(a+b*ArcCoth[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && GtQ[p,0] && LtQ[m,-1]

3.  ∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  (c^2) d+e==0

1.  ∫((x (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  (c^2) d+e==0

1:  ∫((x (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion and power rule for integration

Basis: If  (c^2) d+e==0, then (x/(d+e (x^2)))==(c/(e (1-(c^2)(x^2))))+(1/(c d(1- c x)))

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ]), then

∫((x (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  ⟶  ((((a+b ArcTanh[c x]))^(p+1))/(b e(p+1)))+(1/(c d))∫((((a+b ArcTanh[c x]))^p)/(1- c x))dx

Program code:

Int[x_*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcTanh[c*x])^(p+1)/(b*e*(p+1)) + 
  1/(c*d)*Int[(a+b*ArcTanh[c*x])^p/(1-c*x),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0]

Int[x_*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcCoth[c*x])^(p+1)/(b*e*(p+1)) + 
  1/(c*d)*Int[(a+b*ArcCoth[c*x])^p/(1-c*x),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0]

2:  ∫((x (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  (c^2) d+e==0 ∧ p∉(SuperPlus[ℤ])∧ p≠-1

Derivation: Integration by parts

Basis: If  (c^2) d+e==0, then ((((a+b ArcTanh[c x]))^p)/(d+e (x^2)))==(∂_x)((((a+b ArcTanh[c x]))^(p+1))/(b c d(p+1)))

Rule: If  (c^2) d+e==0 ∧ p∉(SuperPlus[ℤ])∧ p≠-1, then

∫((x (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  ⟶  ((x (((a+b ArcTanh[c x]))^(p+1)))/(b c d(p+1)))-(1/(b c d(p+1)))∫(((a+b ArcTanh[c x]))^(p+1))dx

Program code:

Int[x_*(a_.+b_.*ArcTanh[c_.*x_])^p_/(d_+e_.*x_^2),x_Symbol] :=
  x*(a+b*ArcTanh[c*x])^(p+1)/(b*c*d*(p+1)) - 
  1/(b*c*d*(p+1))*Int[(a+b*ArcTanh[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && Not[IGtQ[p,0]] && NeQ[p,-1]

Int[x_*(a_.+b_.*ArcCoth[c_.*x_])^p_/(d_+e_.*x_^2),x_Symbol] :=
  -x*(a+b*ArcCoth[c*x])^(p+1)/(b*c*d*(p+1)) - 
  1/(b*c*d*(p+1))*Int[(a+b*ArcCoth[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && Not[IGtQ[p,0]] && NeQ[p,-1]

2:  ∫((((a+b ArcTanh[c x]))^p)/(x(d+e (x^2))))dx  when  (c^2) d+e==0 ∧ p>0

Derivation: Algebraic expansion

Basis: If  (c^2) d+e==0, then (1/(x(d+e (x^2))))==(c/(d+e (x^2)))+(1/(d x(1+c x)))

Rule: If  (c^2) d+e==0 ∧ p>0, then

∫((((a+b ArcTanh[c x]))^p)/(x(d+e (x^2))))dx  ⟶  ((((a+b ArcTanh[c x]))^(p+1))/(b d(p+1)))+(1/d)∫((((a+b ArcTanh[c x]))^p)/(x(1+c x)))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_./(x_*(d_+e_.*x_^2)),x_Symbol] :=
  (a+b*ArcTanh[c*x])^(p+1)/(b*d*(p+1)) +
  1/d*Int[(a+b*ArcTanh[c*x])^p/(x*(1+c*x)),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[p,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_./(x_*(d_+e_.*x_^2)),x_Symbol] :=
  (a+b*ArcCoth[c*x])^(p+1)/(b*d*(p+1)) +
  1/d*Int[(a+b*ArcCoth[c*x])^p/(x*(1+c*x)),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[p,0]

3:  ∫(((((f x))^m)(((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  (c^2) d+e==0 ∧ p<-1

Derivation: Integration by parts

Basis: If  (c^2) d+e==0, then ((((a+b ArcTanh[c x]))^p)/(d+e (x^2)))==(∂_x)((((a+b ArcTanh[c x]))^(p+1))/(b c d (p+1)))

Rule: If  (c^2) d+e==0 ∧ p<-1, then

∫(((((f x))^m)(((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  ⟶  (((((f x))^m)(((a+b ArcTanh[c x]))^(p+1)))/(b c d(p+1)))-((f m)/(b c d(p+1)))∫(((f x))^(m-1))(((a+b ArcTanh[c x]))^(p+1))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTanh[c_.*x_])^p_/(d_+e_.*x_^2),x_Symbol] :=
  (f*x)^m*(a+b*ArcTanh[c*x])^(p+1)/(b*c*d*(p+1)) - 
  f*m/(b*c*d*(p+1))*Int[(f*x)^(m-1)*(a+b*ArcTanh[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && LtQ[p,-1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCoth[c_.*x_])^p_/(d_+e_.*x_^2),x_Symbol] :=
  (f*x)^m*(a+b*ArcCoth[c*x])^(p+1)/(b*c*d*(p+1)) - 
  f*m/(b*c*d*(p+1))*Int[(f*x)^(m-1)*(a+b*ArcCoth[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && LtQ[p,-1]

4:  ∫(((x^m)(a+b ArcTanh[c x]))/(d+e (x^2)))dx  when  m∈ℤ ∧ ¬(m==1 ∧ a≠0)

Derivation: Algebraic expansion

Rule: If  m∈ℤ ∧ ¬(m==1 ∧ a≠0), then

∫(((x^m)(a+b ArcTanh[c x]))/(d+e (x^2)))dx  ⟶  ∫(a+b ArcTanh[c x])ExpandIntegrand[((x^m)/(d+e (x^2))),x]dx

Program code:

Int[x_^m_.*(a_.+b_.*ArcTanh[c_.*x_])/(d_+e_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcTanh[c*x]),x^m/(d+e*x^2),x],x] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[m] && Not[EqQ[m,1] && NeQ[a,0]]

Int[x_^m_.*(a_.+b_.*ArcCoth[c_.*x_])/(d_+e_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCoth[c*x]),x^m/(d+e*x^2),x],x] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[m] && Not[EqQ[m,1] && NeQ[a,0]]

2.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0

1.  ∫x(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0

1:  ∫x (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ p>0 ∧ q≠-1

Derivation: Integration by parts

Rule: If  (c^2) d+e==0 ∧ p>0 ∧ q≠-1, then

∫x (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  (((((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^p))/(2 e(q+1)))+((b p)/(2 c(q+1)))∫(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^(p-1))dx

Program code:

Int[x_*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^p/(2*e*(q+1)) + 
  b*p/(2*c*(q+1))*Int[(d+e*x^2)^q*(a+b*ArcTanh[c*x])^(p-1),x] /;
FreeQ[{a,b,c,d,e,q},x] && EqQ[c^2*d+e,0] && GtQ[p,0] && NeQ[q,-1]

Int[x_*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^p/(2*e*(q+1)) +
  b*p/(2*c*(q+1))*Int[(d+e*x^2)^q*(a+b*ArcCoth[c*x])^(p-1),x] /;
FreeQ[{a,b,c,d,e,q},x] && EqQ[c^2*d+e,0] && GtQ[p,0] && NeQ[q,-1]

2:  ∫((x (((a+b ArcTanh[c x]))^p))/(((d+e (x^2)))^2))dx  when  (c^2) d+e==0 ∧ p<-1 ∧ p≠-2

Rule: If  (c^2) d+e==0 ∧ p<-1 ∧ p≠-2, then

∫((x (((a+b ArcTanh[c x]))^p))/(((d+e (x^2)))^2))dx  ⟶  ((x (((a+b ArcTanh[c x]))^(p+1)))/(b c d (p+1) (d+e (x^2))))+(((1+(c^2)(x^2)) (((a+b ArcTanh[c x]))^(p+2)))/((b^2)e (p+1) (p+2) (d+e (x^2))))+(4/((b^2)(p+1)(p+2)))∫((x (((a+b ArcTanh[c x]))^(p+2)))/(((d+e (x^2)))^2))dx

Program code:

Int[x_*(a_.+b_.*ArcTanh[c_.*x_])^p_/(d_+e_.*x_^2)^2,x_Symbol] :=
  x*(a+b*ArcTanh[c*x])^(p+1)/(b*c*d*(p+1)*(d+e*x^2)) +
  (1+c^2*x^2)*(a+b*ArcTanh[c*x])^(p+2)/(b^2*e*(p+1)*(p+2)*(d+e*x^2)) +
  4/(b^2*(p+1)*(p+2))*Int[x*(a+b*ArcTanh[c*x])^(p+2)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && LtQ[p,-1] && NeQ[p,-2]

Int[x_*(a_.+b_.*ArcCoth[c_.*x_])^p_/(d_+e_.*x_^2)^2,x_Symbol] :=
  x*(a+b*ArcCoth[c*x])^(p+1)/(b*c*d*(p+1)*(d+e*x^2)) +
  (1+c^2*x^2)*(a+b*ArcCoth[c*x])^(p+2)/(b^2*e*(p+1)*(p+2)*(d+e*x^2)) +
  4/(b^2*(p+1)*(p+2))*Int[x*(a+b*ArcCoth[c*x])^(p+2)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && LtQ[p,-1] && NeQ[p,-2]

2.  ∫(x^2)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0

1:  ∫(x^2)(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  when  (c^2) d+e==0 ∧ q<-1

Rule: If  q==-(5/2), then better to use rule for when m+2q+3==0.

Rule: If  (c^2) d+e==0 ∧ q<-1, then

∫(x^2)(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  ⟶  -((b(((d+e (x^2)))^(q+1)))/(4 (c^3) d(((q+1))^2)))-((x(((d+e (x^2)))^(q+1)) (a+b ArcTanh[c x]))/(2 (c^2) d(q+1)))+(1/(2 (c^2) d (q+1)))∫(((d+e (x^2)))^(q+1)) (a+b ArcTanh[c x])dx

Program code:

Int[x_^2*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  -b*(d+e*x^2)^(q+1)/(4*c^3*d*(q+1)^2) - 
  x*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])/(2*c^2*d*(q+1)) + 
  1/(2*c^2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && LtQ[q,-1] && NeQ[q,-5/2]

Int[x_^2*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  -b*(d+e*x^2)^(q+1)/(4*c^3*d*(q+1)^2) - 
  x*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])/(2*c^2*d*(q+1)) + 
  1/(2*c^2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && LtQ[q,-1] && NeQ[q,-5/2]

2:  ∫(((x^2) (((a+b ArcTanh[c x]))^p))/(((d+e (x^2)))^2))dx  when  (c^2) d+e==0 ∧ p>0

Rule: If  (c^2) d+e==0 ∧ p>0, then

∫(((x^2) (((a+b ArcTanh[c x]))^p))/(((d+e (x^2)))^2))dx  ⟶  -((((a+b ArcTanh[c x]))^(p+1))/(2b (c^3) (d^2)(p+1)))+((x (((a+b ArcTanh[c x]))^p))/(2 (c^2) d (d+e (x^2))))-((b p)/(2c))∫((x (((a+b ArcTanh[c x]))^(p-1)))/(((d+e (x^2)))^2))dx

Program code:

Int[x_^2*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  -(a+b*ArcTanh[c*x])^(p+1)/(2*b*c^3*d^2*(p+1)) + 
  x*(a+b*ArcTanh[c*x])^p/(2*c^2*d*(d+e*x^2)) - 
  b*p/(2*c)*Int[x*(a+b*ArcTanh[c*x])^(p-1)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[p,0]

Int[x_^2*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  -(a+b*ArcCoth[c*x])^(p+1)/(2*b*c^3*d^2*(p+1)) + 
  x*(a+b*ArcCoth[c*x])^p/(2*c^2*d*(d+e*x^2)) - 
  b*p/(2*c)*Int[x*(a+b*ArcCoth[c*x])^(p-1)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[p,0]

3.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ m+2q+2==0

1.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ m+2q+2==0 ∧ q<-1 ∧ p≥1

1:  ∫(((f x))^m) (((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  when  (c^2) d+e==0 ∧ m+2q+2==0 ∧ q<-1

Rule: If  (c^2) d+e==0 ∧ m+2q+2==0 ∧ q<-1, then

∫(((f x))^m) (((d+e (x^2)))^q) (a+b ArcTanh[c x])dx ⟶  
-((b (((f x))^m) (((d+e (x^2)))^(q+1)))/(c d (m^2)))+((f (((f x))^(m-1)) (((d+e (x^2)))^(q+1)) (a+b ArcTanh[c x]))/((c^2) d m))-(((f^2) (m-1))/((c^2) d m))∫(((f x))^(m-2)) (((d+e (x^2)))^(q+1)) (a+b ArcTanh[c x])dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  -b*(f*x)^m*(d+e*x^2)^(q+1)/(c*d*m^2) + 
  f*(f*x)^(m-1)*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])/(c^2*d*m) - 
  f^2*(m-1)/(c^2*d*m)*Int[(f*x)^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && EqQ[m+2*q+2,0] && LtQ[q,-1]

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  -b*(f*x)^m*(d+e*x^2)^(q+1)/(c*d*m^2) + 
  f*(f*x)^(m-1)*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])/(c^2*d*m) - 
  f^2*(m-1)/(c^2*d*m)*Int[(f*x)^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && EqQ[m+2*q+2,0] && LtQ[q,-1]

2:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ m+2q+2==0 ∧ q<-1 ∧ p>1

Rule: If  (c^2) d+e==0 ∧ m+2q+2==0 ∧ q<-1 ∧ p>1, then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx ⟶  

-((b p (((f x))^m) (((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^(p-1)))/(c d (m^2)))+((f (((f x))^(m-1)) (((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^p))/((c^2) d m))+
(((b^2)p(p-1))/(m^2))∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^(p-2))dx-(((f^2) (m-1))/((c^2) d m))∫(((f x))^(m-2)) (((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^p)dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_,x_Symbol] :=
  -b*p*(f*x)^m*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^(p-1)/(c*d*m^2) + 
  f*(f*x)^(m-1)*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^p/(c^2*d*m) + 
  b^2*p*(p-1)/m^2*Int[(f*x)^m*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^(p-2),x] - 
  f^2*(m-1)/(c^2*d*m)*Int[(f*x)^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && EqQ[m+2*q+2,0] && LtQ[q,-1] && GtQ[p,1]

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_,x_Symbol] :=
  -b*p*(f*x)^m*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^(p-1)/(c*d*m^2) + 
  f*(f*x)^(m-1)*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^p/(c^2*d*m) + 
  b^2*p*(p-1)/m^2*Int[(f*x)^m*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^(p-2),x] - 
  f^2*(m-1)/(c^2*d*m)*Int[(f*x)^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && EqQ[m+2*q+2,0] && LtQ[q,-1] && GtQ[p,1]

2:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ m+2q+2==0 ∧ p<-1

Derivation: Integration by parts

Basis: If  (c^2) d+e==0, then ((((a+b ArcTanh[c x]))^p)/(d+e (x^2)))==(∂_x)((((a+b ArcTanh[c x]))^(p+1))/(b c d (p+1)))

Basis: If  m+2q+2==0, then (∂_x)((x^m) (((d+e (x^2)))^(q+1)))==c m (x^(m-1)) (((d+e (x^2)))^q)

Rule: If  (c^2) d+e==0 ∧ m+2q+2==0 ∧ p<-1, then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx ⟶  (((((f x))^m) (((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^(p+1)))/(b c d(p+1)))-((f m)/(b c (p+1)))∫(((f x))^(m-1)) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^(p+1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_])^p_,x_Symbol] :=
  (f*x)^m*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^(p+1)/(b*c*d*(p+1)) - 
  f*m/(b*c*(p+1))*Int[(f*x)^(m-1)*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[c^2*d+e,0] && EqQ[m+2*q+2,0] && LtQ[p,-1]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_])^p_,x_Symbol] :=
  (f*x)^m*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^(p+1)/(b*c*d*(p+1)) - 
  f*m/(b*c*(p+1))*Int[(f*x)^(m-1)*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[c^2*d+e,0] && EqQ[m+2*q+2,0] && LtQ[p,-1]

4:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ m+2q+3==0 ∧ p>0 ∧ m≠-1

Derivation: Integration by parts

Basis: If  m+2q+3==0, then (x^m) (((d+e (x^2)))^q)==(∂_x)(((x^(m+1)) (((d+e (x^2)))^(q+1)))/(d (m+1)))

Rule: If  (c^2) d+e==0 ∧ m+2q+3==0 ∧ p>0 ∧ m≠-1, then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx ⟶  (((((f x))^(m+1)) (((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^p))/(d f(m+1)))-((b c p)/(f (m+1)))∫(((f x))^(m+1)) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^(p-1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^p/(d*(m+1)) - 
  b*c*p/(m+1)*Int[(f*x)^(m+1)*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[c^2*d+e,0] && EqQ[m+2*q+3,0] && GtQ[p,0] && NeQ[m,-1]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^p/(d*f*(m+1)) - 
  b*c*p/(f*(m+1))*Int[(f*x)^(m+1)*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[c^2*d+e,0] && EqQ[m+2*q+3,0] && GtQ[p,0] && NeQ[m,-1]

5.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q>0

1:  ∫(((f x))^m) (Sqrt[d+e (x^2)]) (a+b ArcTanh[c x])dx  when  (c^2) d+e==0 ∧ m≠-2

Rule: If  (c^2) d+e==0 ∧ m≠-2, then

∫(((f x))^m) (Sqrt[d+e (x^2)]) (a+b ArcTanh[c x])dx  ⟶  (((((f x))^(m+1)) (Sqrt[d+e (x^2)]) (a+b ArcTanh[c x]))/(f (m+2)))-((b c d)/(f (m+2)))∫((((f x))^(m+1))/(Sqrt[d+e (x^2)]))dx+(d/(m+2))∫(((((f x))^m) (a+b ArcTanh[c x]))/(Sqrt[d+e (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcTanh[c*x])/(f*(m+2)) - 
  b*c*d/(f*(m+2))*Int[(f*x)^(m+1)/Sqrt[d+e*x^2],x] + 
  d/(m+2)*Int[(f*x)^m*(a+b*ArcTanh[c*x])/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && NeQ[m,-2]

Int[(f_.*x_)^m_*Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcCoth[c*x])/(f*(m+2)) - 
  b*c*d/(f*(m+2))*Int[(f*x)^(m+1)/Sqrt[d+e*x^2],x] + 
  d/(m+2)*Int[(f*x)^m*(a+b*ArcCoth[c*x])/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && NeQ[m,-2]

2:  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ q∈ℤ ∧ q>1

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ q∈ℤ ∧ q>1, then

∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  ∫ExpandIntegrand[(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p),x]dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^p,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && IGtQ[q,1]

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^p,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && IGtQ[q,1]

3:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q>0 ∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: If  (c^2) d+e==0, then (((d+e (x^2)))^q)==d(((d+e (x^2)))^(q-1))-(c^2) d (x^2) (((d+e (x^2)))^(q-1))

Rule: If  (c^2) d+e==0 ∧ q>0 ∧ p∈(SuperPlus[ℤ]), then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  d∫(((f x))^m) (((d+e (x^2)))^(q-1)) (((a+b ArcTanh[c x]))^p)dx-(((c^2) d)/(f^2)) ∫(((f x))^(m+2)) (((d+e (x^2)))^(q-1)) (((a+b ArcTanh[c x]))^p)dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  d*Int[(f*x)^m*(d+e*x^2)^(q-1)*(a+b*ArcTanh[c*x])^p,x] - 
  c^2*d/f^2*Int[(f*x)^(m+2)*(d+e*x^2)^(q-1)*(a+b*ArcTanh[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && GtQ[q,0] && IGtQ[p,0] && (RationalQ[m] || EqQ[p,1] && IntegerQ[q])

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  d*Int[(f*x)^m*(d+e*x^2)^(q-1)*(a+b*ArcCoth[c*x])^p,x] - 
  c^2*d/f^2*Int[(f*x)^(m+2)*(d+e*x^2)^(q-1)*(a+b*ArcCoth[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[c^2*d+e,0] && GtQ[q,0] && IGtQ[p,0] && (RationalQ[m] || EqQ[p,1] && IntegerQ[q])

6.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q<0

1.  ∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0

1:  ∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ p>0 ∧ m>1

Rule: If  (c^2) d+e==0 ∧ p>0 ∧ m>1, then

∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(Sqrt[d+e (x^2)]))dx  ⟶  
-((f (((f x))^(m-1)) (Sqrt[d+e (x^2)]) (((a+b ArcTanh[c x]))^p))/((c^2)d m))+((b f p)/(c m))∫ (((((f x))^(m-1))(((a+b ArcTanh[c x]))^(p-1)))/(Sqrt[d+e (x^2)]))dx+(((f^2) (m-1))/((c^2) m))∫(((((f x))^(m-2)) (((a+b ArcTanh[c x]))^p))/(Sqrt[d+e (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTanh[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -f*(f*x)^(m-1)*Sqrt[d+e*x^2]*(a+b*ArcTanh[c*x])^p/(c^2*d*m) + 
  b*f*p/(c*m)*Int[(f*x)^(m-1)*(a+b*ArcTanh[c*x])^(p-1)/Sqrt[d+e*x^2],x] + 
  f^2*(m-1)/(c^2*m)*Int[(f*x)^(m-2)*(a+b*ArcTanh[c*x])^p/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && GtQ[p,0] && GtQ[m,1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCoth[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -f*(f*x)^(m-1)*Sqrt[d+e*x^2]*(a+b*ArcCoth[c*x])^p/(c^2*d*m) + 
  b*f*p/(c*m)*Int[(f*x)^(m-1)*(a+b*ArcCoth[c*x])^(p-1)/Sqrt[d+e*x^2],x] + 
  f^2*(m-1)/(c^2*m)*Int[(f*x)^(m-2)*(a+b*ArcCoth[c*x])^p/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && GtQ[p,0] && GtQ[m,1]

2.  ∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ p>0 ∧ m≤-1

1.  ∫((((a+b ArcTanh[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])

1.  ∫((((a+b ArcTanh[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0

1:  ∫(((a+b ArcTanh[c x]))/(x(Sqrt[d+e (x^2)])))dx  when  (c^2) d+e==0 ∧ d>0

Derivation: Integration by substitution, piecewise constant extraction and algebraic simplification!

Note: Although not essential, these rules return antiderivatives free of complex exponentials of the form  (e^(ArcTanh[c x])) and  (e^(ArcCoth[c x])).

Basis: If  (c^2) d+e==0 ∧ d>0, then (1/(x(Sqrt[d+e (x^2)])))==(1/(Sqrt[d])) Csch[ArcTanh[c x]] (∂_x)ArcTanh[c x]

Basis: If  (c^2) d+e==0 ∧ d>0, then (1/(x(Sqrt[d+e (x^2)])))==-(1/(Sqrt[d]))((Csch[ArcCoth[c x]] Sech[ArcCoth[c x]])/(Sqrt[-((Csch[ArcCoth[c x]])^2)])) (∂_x)ArcCoth[c x]

Rule: If  (c^2) d+e==0 ∧ d>0, then

∫(((a+b ArcTanh[c x]))/(x(Sqrt[d+e (x^2)])))dx  ⟶  (1/(Sqrt[d]))Subst[∫(a+b x)Csch[x]dx,x,ArcTanh[c x]]
  ⟶  -(2/(Sqrt[d])) (a+b ArcTanh[c x]) ArcTanh[((Sqrt[1-c x])/(Sqrt[1+c x]))]+(b/(Sqrt[d]))PolyLog[2,-((Sqrt[1-c x])/(Sqrt[1+c x]))]-(b/(Sqrt[d])) PolyLog[2,((Sqrt[1-c x])/(Sqrt[1+c x]))]

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])/(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  -2/Sqrt[d]*(a+b*ArcTanh[c*x])*ArcTanh[Sqrt[1-c*x]/Sqrt[1+c*x]] + 
  b/Sqrt[d]*PolyLog[2,-Sqrt[1-c*x]/Sqrt[1+c*x]] - 
  b/Sqrt[d]*PolyLog[2,Sqrt[1-c*x]/Sqrt[1+c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[d,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])/(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  -2/Sqrt[d]*(a+b*ArcCoth[c*x])*ArcTanh[Sqrt[1-c*x]/Sqrt[1+c*x]] + 
  b/Sqrt[d]*PolyLog[2,-Sqrt[1-c*x]/Sqrt[1+c*x]] - 
  b/Sqrt[d]*PolyLog[2,Sqrt[1-c*x]/Sqrt[1+c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[d,0]

2.  ∫((((a+b ArcTanh[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0

1:  ∫((((a+b ArcTanh[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0 ∧ d>0, then (1/(x(Sqrt[d+e (x^2)])))==(1/(Sqrt[d])) Csch[ArcTanh[c x]] (∂_x)ArcTanh[c x]

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0, then

∫((((a+b ArcTanh[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  ⟶  (1/(Sqrt[d]))Subst[∫(((a+b x))^p) Csch[x]dx,x,ArcTanh[c x]]

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_/(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  1/Sqrt[d]*Subst[Int[(a+b*x)^p*Csch[x],x],x,ArcTanh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && GtQ[d,0]

2:  ∫((((a+b ArcCoth[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0

Derivation: Integration by substitution and piecewise constant extraction

Basis: If  (c^2) d+e==0 ∧ d>0, then (1/(x(Sqrt[d+e (x^2)])))==-(1/(Sqrt[d]))((Csch[ArcCoth[c x]] Sech[ArcCoth[c x]])/(Sqrt[-((Csch[ArcCoth[c x]])^2)])) (∂_x)ArcCoth[c x]

Basis: (∂_x)((Csch[x])/(Sqrt[-((Csch[x])^2)]))==0

Basis: ((Csch[ArcCoth[c x]])/(Sqrt[-((Csch[ArcCoth[c x]])^2)]))==((c x(Sqrt[1-(1/((c^2) (x^2)))]))/(Sqrt[1-(c^2)(x^2)]))

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d>0, then

∫((((a+b ArcCoth[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  ⟶  -(1/(Sqrt[d]))Subst[∫(((((a+b x))^p)Csch[x] Sech[x])/(Sqrt[-((Csch[x])^2)]))dx,x,ArcCoth[c x]]                                   
                         ⟶  -((c x(Sqrt[1-(1/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)]))Subst[∫(((a+b x))^p)Sech[x]dx,x,ArcCoth[c x]]

Program code:

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_/(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  -c*x*Sqrt[1-1/(c^2*x^2)]/Sqrt[d+e*x^2]*Subst[Int[(a+b*x)^p*Sech[x],x],x,ArcCoth[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && GtQ[d,0]

2:  ∫((((a+b ArcTanh[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d≯0

Derivation: Piecewise constant extraction

Basis: If  (c^2) d+e==0, then (∂_x)((Sqrt[1-(c^2)(x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])∧ d≯0, then

∫((((a+b ArcTanh[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  ⟶  ((Sqrt[1-(c^2)(x^2)])/(Sqrt[d+e (x^2)]))∫((((a+b ArcTanh[c x]))^p)/(x(Sqrt[1-(c^2)(x^2)])))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_./(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  Sqrt[1-c^2*x^2]/Sqrt[d+e*x^2]*Int[(a+b*ArcTanh[c*x])^p/(x*Sqrt[1-c^2*x^2]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && Not[GtQ[d,0]]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_./(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  Sqrt[1-c^2*x^2]/Sqrt[d+e*x^2]*Int[(a+b*ArcCoth[c*x])^p/(x*Sqrt[1-c^2*x^2]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && Not[GtQ[d,0]]

2.  ∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ p>0 ∧ m<-1

1:  ∫((((a+b ArcTanh[c x]))^p)/((x^2)(Sqrt[d+e (x^2)])))dx  when  (c^2) d+e==0 ∧ p>0

Derivation: Integration by parts

Basis: (1/((x^2) (Sqrt[d+e (x^2)])))==-(∂_x)((Sqrt[d+e (x^2)])/(d x))

Rule: If  (c^2) d+e==0 ∧ p>0, then

∫((((a+b ArcTanh[c x]))^p)/((x^2)(Sqrt[d+e (x^2)])))dx  ⟶  -(((Sqrt[d+e (x^2)]) (((a+b ArcTanh[c x]))^p))/(d x))+b c p∫ ((((a+b ArcTanh[c x]))^(p-1))/(x(Sqrt[d+e (x^2)])))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_./(x_^2*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  -Sqrt[d+e*x^2]*(a+b*ArcTanh[c*x])^p/(d*x) + 
  b*c*p*Int[(a+b*ArcTanh[c*x])^(p-1)/(x*Sqrt[d+e*x^2]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[p,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_./(x_^2*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  -Sqrt[d+e*x^2]*(a+b*ArcCoth[c*x])^p/(d*x) + 
  b*c*p*Int[(a+b*ArcCoth[c*x])^(p-1)/(x*Sqrt[d+e*x^2]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[p,0]

2:  ∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ p>0 ∧ m<-1 ∧ m≠-2

Rule: If  (c^2) d+e==0 ∧ p>0 ∧ m<-1 ∧ m≠-2, then

∫(((((f x))^m) (((a+b ArcTanh[c x]))^p))/(Sqrt[d+e (x^2)]))dx  ⟶  
(((((f x))^(m+1)) (Sqrt[d+e (x^2)]) (((a+b ArcTanh[c x]))^p))/(d f (m+1)))-((b c p)/(f (m+1)))∫ (((((f x))^(m+1))(((a+b ArcTanh[c x]))^(p-1)))/(Sqrt[d+e (x^2)]))dx+(((c^2) (m+2))/( (f^2) (m+1)))∫(((((f x))^(m+2))(((a+b ArcTanh[c x]))^p))/(Sqrt[d+e (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTanh[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcTanh[c*x])^p/(d*f*(m+1)) - 
  b*c*p/(f*(m+1))*Int[(f*x)^(m+1)*(a+b*ArcTanh[c*x])^(p-1)/Sqrt[d+e*x^2],x] + 
  c^2*(m+2)/(f^2*(m+1))*Int[(f*x)^(m+2)*(a+b*ArcTanh[c*x])^p/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && GtQ[p,0] && LtQ[m,-1] && NeQ[m,-2]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCoth[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcCoth[c*x])^p/(d*f*(m+1)) - 
  b*c*p/(f*(m+1))*Int[(f*x)^(m+1)*(a+b*ArcCoth[c*x])^(p-1)/Sqrt[d+e*x^2],x] + 
  c^2*(m+2)/(f^2*(m+1))*Int[(f*x)^(m+2)*(a+b*ArcCoth[c*x])^p/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[c^2*d+e,0] && GtQ[p,0] && LtQ[m,-1] && NeQ[m,-2]

2.  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ q<-1

1:  ∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ (m|p|2q)∈ℤ ∧ q<-1 ∧ m>1 ∧ p≠-1

Derivation: Algebraic expansion

Basis: ((x^2)/(d+e (x^2)))==(1/e)-(d/(e (d+e (x^2))))

Rule: If  (c^2) d+e==0 ∧ (m|p|2q)∈ℤ ∧ q<-1 ∧ m>1 ∧ p≠-1, then

∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  (1/e)∫(x^(m-2)) (((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^p)dx-(d/e)∫(x^(m-2)) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx

Program code:

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  1/e*Int[x^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^p,x] -
  d/e*Int[x^(m-2)*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^p,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IntegersQ[p,2*q] && LtQ[q,-1] && IGtQ[m,1] && NeQ[p,-1]

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  1/e*Int[x^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^p,x] -
  d/e*Int[x^(m-2)*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^p,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IntegersQ[p,2*q] && LtQ[q,-1] && IGtQ[m,1] && NeQ[p,-1]

2:  ∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ (m|p|2q)∈ℤ ∧ q<-1 ∧ m<0 ∧ p≠-1

Derivation: Algebraic expansion

Basis: (1/(d+e (x^2)))==(1/d)-((e (x^2))/(d (d+e (x^2))))

Rule: If  (c^2) d+e==0 ∧ (m|p|2q)∈ℤ ∧ q<-1 ∧ m<0 ∧ p≠-1, then

∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  (1/d)∫(x^m) (((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^p)dx-(e/d)∫(x^(m+2)) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx

Program code:

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  1/d*Int[x^m*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^p,x] -
  e/d*Int[x^(m+2)*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^p,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IntegersQ[p,2*q] && LtQ[q,-1] && ILtQ[m,0] && NeQ[p,-1]

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  1/d*Int[x^m*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^p,x] -
  e/d*Int[x^(m+2)*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^p,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IntegersQ[p,2*q] && LtQ[q,-1] && ILtQ[m,0] && NeQ[p,-1]

3:  ∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ m∈ℤ ∧ q<-1 ∧ p<-1 ∧ m+2q+2≠0

Derivation: Integration by parts

Rule: If  (c^2) d+e==0 ∧ m∈ℤ ∧ q<-1 ∧ p<-1 ∧ m+2q+2≠0, then

∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx ⟶  
(((x^m) (((d+e (x^2)))^(q+1)) (((a+b ArcTanh[c x]))^(p+1)))/(b c d(p+1)))-(m/(b c (p+1)))∫(x^(m-1)) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^(p+1))dx+((c (m+2q+2))/(b (p+1)))∫(x^(m+1)) (((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^(p+1))dx

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  x^m*(d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])^(p+1)/(b*c*d*(p+1)) - 
  m/(b*c*(p+1))*Int[x^(m-1)*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^(p+1),x] + 
  c*(m+2*q+2)/(b*(p+1))*Int[x^(m+1)*(d+e*x^2)^q*(a+b*ArcTanh[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IntegerQ[m] && LtQ[q,-1] && LtQ[p,-1] && NeQ[m+2*q+2,0]

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  x^m*(d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])^(p+1)/(b*c*d*(p+1)) - 
  m/(b*c*(p+1))*Int[x^(m-1)*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^(p+1),x] + 
  c*(m+2*q+2)/(b*(p+1))*Int[x^(m+1)*(d+e*x^2)^q*(a+b*ArcCoth[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IntegerQ[m] && LtQ[q,-1] && LtQ[p,-1] && NeQ[m+2*q+2,0]

4.  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])

1.  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])

1:  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ (q∈ℤ ∨ d>0)

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0 ∧ m∈ℤ ∧ m+2 q+1∈ℤ ∧ (q∈ℤ ∨ d>0), then (x^m)(((d+e (x^2)))^q)==(((d^q)((Sinh[ArcTanh[c x]])^m))/((c^(m+1))((Cosh[ArcTanh[c x]])^(m+2 (q+1)))))(∂_x)ArcTanh[c x]

Rule: If  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ (q∈ℤ ∨ d>0), then

∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  ((d^q)/(c^(m+1))) Subst[∫(((((a+b x))^p)((Sinh[x])^m))/((Cosh[x])^(m+2 (q+1))))dx,x,ArcTanh[c x]]

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  d^q/c^(m+1)*Subst[Int[(a+b*x)^p*Sinh[x]^m/Cosh[x]^(m+2*(q+1)),x],x,ArcTanh[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && IGtQ[m,0] && ILtQ[m+2*q+1,0] && (IntegerQ[q] || GtQ[d,0])

2:  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ]) ∧ m+2 q+1∈(SuperMinus[ℤ])∧ ¬(q∈ℤ ∨ d>0)

Derivation: Piecewise constant extraction

Basis: If  (c^2) d+e==0, then (∂_x)((Sqrt[1-(c^2)(x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ]) ∧ m+2 q+1∈(SuperMinus[ℤ])∧ ¬(q∈ℤ ∨ d>0), then

∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  (((d^(q+(1/2)))(Sqrt[1-(c^2)(x^2)]))/(Sqrt[d+e (x^2)])) ∫(x^m)(((1-(c^2)(x^2)))^q)(((a+b ArcTanh[c x]))^p)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  d^(q+1/2)*Sqrt[1-c^2*x^2]/Sqrt[d+e*x^2]*Int[x^m*(1-c^2*x^2)^q*(a+b*ArcTanh[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && IGtQ[m,0] && ILtQ[m+2*q+1,0] && Not[IntegerQ[q] || GtQ[d,0]]

2.  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcCoth[c x]))^p)dx  when  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])

1:  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcCoth[c x]))^p)dx  when  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ q∈ℤ

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0 ∧ m∈ℤ ∧ q∈ℤ, then (x^m)(((d+e (x^2)))^q)==-(((((-d))^q)((Cosh[ArcCoth[c x]])^m))/((c^(m+1))((Sinh[ArcCoth[c x]])^(m+2(q+1)))))(∂_x)ArcCoth[c x]

Rule: If  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ q∈ℤ, then

∫(x^m)(((d+e (x^2)))^q) (((a+b ArcCoth[c x]))^p)dx  ⟶  -((((-d))^q)/(c^(m+1))) Subst[∫(((((a+b x))^p)((Cosh[x])^m))/((Sinh[x])^(m+2 (q+1))))dx,x,ArcCoth[c x]]

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  -(-d)^q/c^(m+1)*Subst[Int[(a+b*x)^p*Cosh[x]^m/Sinh[x]^(m+2*(q+1)),x],x,ArcCoth[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && IGtQ[m,0] && ILtQ[m+2*q+1,0] && IntegerQ[q]

2:  ∫(x^m)(((d+e (x^2)))^q)(((a+b ArcCoth[c x]))^p)dx  when  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ q∉ℤ

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  (c^2) d+e==0, then (∂_x)((x (Sqrt[(((c^2)(x^2)-1)/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)]))==0

Basis: If  m∈ℤ ∧ m+2 q+1∈ℤ ∧ q∉ℤ, then (x^(m+1))(Sqrt[1-(1/((c^2) (x^2)))])(((-1+(c^2)(x^2)))^(q-(1/2)))==-(((Cosh[ArcCoth[c x]])^m)/((c^(m+2))((Sinh[ArcCoth[c x]])^(m+2(q+1)))))(∂_x)ArcCoth[c x]

Rule: If  (c^2) d+e==0 ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ q∉ℤ, then

∫(x^m)(((d+e (x^2)))^q)(((a+b ArcCoth[c x]))^p)dx  ⟶  (((c^2)(((-d))^(q+(1/2)))x (Sqrt[(((c^2)(x^2)-1)/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)])) ∫(x^(m+1))(Sqrt[1-(1/((c^2) (x^2)))])(((-1+(c^2)(x^2)))^(q-(1/2)))(((a+b ArcCoth[c x]))^p)dx
  ⟶  -(((((-d))^(q+(1/2)))x (Sqrt[(((c^2)(x^2)-1)/((c^2) (x^2)))]))/((c^m)(Sqrt[d+e (x^2)]))) Subst[∫(((((a+b x))^p)((Cosh[x])^m))/((Sinh[x])^(m+2 (q+1))))dx,x,ArcCoth[c x]]

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  -(-d)^(q+1/2)*x*Sqrt[(c^2*x^2-1)/(c^2*x^2)]/(c^m*Sqrt[d+e*x^2])*Subst[Int[(a+b*x)^p*Cosh[x]^m/Sinh[x]^(m+2*(q+1)),x],x,ArcCoth[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && IGtQ[m,0] && ILtQ[m+2*q+1,0] && Not[IntegerQ[q]]

3.  ∫(((f x))^m)(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  when  (q∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(q∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+2q+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ]))

1:  ∫x(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  when  q≠-1

Derivation: Integration by parts

Basis: x(((d+e (x^2)))^q)==(∂_x)((((d+e (x^2)))^(q+1))/(2 e (q+1)))

Rule: If  q≠-1, then

∫x(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  ⟶  (((((d+e (x^2)))^(q+1))(a+b ArcTanh[c x]))/(2 e (q+1)))-((b c)/(2 e (q+1)))∫((((d+e (x^2)))^(q+1))/(1-(c^2) (x^2)))dx

Program code:

Int[x_*(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcTanh[c*x])/(2*e*(q+1)) - 
  b*c/(2*e*(q+1))*Int[(d+e*x^2)^(q+1)/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[q,-1]

Int[x_*(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcCoth[c*x])/(2*e*(q+1)) - 
  b*c/(2*e*(q+1))*Int[(d+e*x^2)^(q+1)/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[q,-1]

2:  ∫(((f x))^m)(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  when  (q∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(q∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+2q+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ]))

Derivation: Integration by parts

Note: If (q∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(q∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+2q+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ])),
	then ∫(((f x))^m)(((d+e (x^2)))^q)dx is expressible as an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If  (q∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(q∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+2q+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ])), let u=∫(((f x))^m)(((d+e (x^2)))^q)dx, then

∫(((f x))^m)(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  ⟶  u (a+b ArcTanh[c x])-b c∫(u/(1-(c^2) (x^2)))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^q,x]},  
  Dist[a+b*ArcTanh[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/(1-c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && (
  IGtQ[q,0] && Not[ILtQ[(m-1)/2,0] && GtQ[m+2*q+3,0]] || 
  IGtQ[(m+1)/2,0] && Not[ILtQ[q,0] && GtQ[m+2*q+3,0]] || 
  ILtQ[(m+2*q+1)/2,0] && Not[ILtQ[(m-1)/2,0]] )

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^q,x]},  
  Dist[a+b*ArcCoth[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/(1-c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && (
  IGtQ[q,0] && Not[ILtQ[(m-1)/2,0] && GtQ[m+2*q+3,0]] || 
  IGtQ[(m+1)/2,0] && Not[ILtQ[q,0] && GtQ[m+2*q+3,0]] || 
  ILtQ[(m+2*q+1)/2,0] && Not[ILtQ[(m-1)/2,0]] )

4:  ∫((x (((a+b ArcTanh[c x]))^p))/(((d+e (x^2)))^2))dx  when  p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (x/(((d+e (x^2)))^2))==(1/(4 (d^2) (Sqrt[-(e/d)]) (((1-(Sqrt[-(e/d)]) x))^2)))-(1/(4 (d^2) (Sqrt[-(e/d)]) (((1+(Sqrt[-(e/d)]) x))^2)))

Rule: If  p∈(SuperPlus[ℤ]), then

∫((x (((a+b ArcTanh[c x]))^p))/(((d+e (x^2)))^2))dx  ⟶  (1/(4 (d^2) (Sqrt[-(e/d)]))) ∫((((a+b ArcTanh[c x]))^p)/(((1-(Sqrt[-(e/d)]) x))^2))dx-(1/(4 (d^2) (Sqrt[-(e/d)]))) ∫((((a+b ArcTanh[c x]))^p)/(((1+(Sqrt[-(e/d)]) x))^2))dx

Program code:

Int[x_*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  1/(4*d^2*Rt[-e/d,2])*Int[(a+b*ArcTanh[c*x])^p/(1-Rt[-e/d,2]*x)^2,x] - 
  1/(4*d^2*Rt[-e/d,2])*Int[(a+b*ArcTanh[c*x])^p/(1+Rt[-e/d,2]*x)^2,x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0]

Int[x_*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  1/(4*d^2*Rt[-e/d,2])*Int[(a+b*ArcCoth[c*x])^p/(1-Rt[-e/d,2]*x)^2,x] - 
  1/(4*d^2*Rt[-e/d,2])*Int[(a+b*ArcCoth[c*x])^p/(1+Rt[-e/d,2]*x)^2,x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0]

5:  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  when  q∈ℤ ∧ p∈(SuperPlus[ℤ])∧ (q>0 ∨ m∈ℤ)

Derivation: Algebraic expansion

Rule: If  q∈ℤ ∧ p∈(SuperPlus[ℤ])∧ (q>0 ∨ m∈ℤ), then

∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTanh[c x]))^p)dx  ⟶  ∫(((a+b ArcTanh[c x]))^p)ExpandIntegrand[(((f x))^m)(((d+e (x^2)))^q),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*ArcTanh[c*x])^p,(f*x)^m*(d+e*x^2)^q,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,m},x] && IntegerQ[q] && IGtQ[p,0] && (GtQ[q,0] || IntegerQ[m])

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*ArcCoth[c*x])^p,(f*x)^m*(d+e*x^2)^q,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,m},x] && IntegerQ[q] && IGtQ[p,0] && (GtQ[q,0] || IntegerQ[m])

6:  ∫(((f x))^m)(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx

Derivation: Algebraic expansion

Rule:

∫(((f x))^m)(((d+e (x^2)))^q) (a+b ArcTanh[c x])dx  ⟶  a∫(((f x))^m)(((d+e (x^2)))^q)dx+b∫(((f x))^m)(((d+e (x^2)))^q) ArcTanh[c x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  a*Int[(f*x)^m*(d+e*x^2)^q,x] + b*Int[(f*x)^m*(d+e*x^2)^q*ArcTanh[c*x],x] /;
FreeQ[{a,b,c,d,e,f,m,q},x]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  a*Int[(f*x)^m*(d+e*x^2)^q,x] + b*Int[(f*x)^m*(d+e*x^2)^q*ArcCoth[c*x],x] /;
FreeQ[{a,b,c,d,e,f,m,q},x]

7.  ∫((u (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  (c^2) d+e==0

1:  ∫(((((f+g x))^m) (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧  m∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧  m∈(SuperPlus[ℤ]), then

∫(((((f+g x))^m) (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  ⟶  ∫((((a+b ArcTanh[c x]))^p)/(d+e (x^2))) ExpandIntegrand[(((f+g x))^m),x]dx

Program code:

Int[(f_+g_.*x_)^m_.*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcTanh[c*x])^p/(d+e*x^2),(f+g*x)^m,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && IGtQ[m,0]

Int[(f_+g_.*x_)^m_.*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCoth[c*x])^p/(d+e*x^2),(f+g*x)^m,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && IGtQ[m,0]

2.  ∫((ArcTanh[u](((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0

1:  ∫((ArcTanh[u](((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (u^2)==(((1-(2/(1+c x))))^2)

Derivation: Algebraic expansion

Basis: ArcTanh[z]==(1/2) Log[1+z]-(1/2) Log[1-z]

Basis: ArcCoth[z]==(1/2) Log[1+(1/z)]-(1/2) Log[1-(1/z)]

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (u^2)==(((1-(2/(1+c x))))^2), then

∫((ArcTanh[u](((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  ⟶  (1/2) ∫((Log[1+u](((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx-(1/2) ∫((Log[1-u](((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx

Program code:

Int[ArcTanh[u_]*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/2*Int[Log[1+u]*(a+b*ArcTanh[c*x])^p/(d+e*x^2),x] -
  1/2*Int[Log[1-u]*(a+b*ArcTanh[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[u^2-(1-2/(1+c*x))^2,0]

Int[ArcCoth[u_]*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/2*Int[Log[SimplifyIntegrand[1+1/u,x]]*(a+b*ArcCoth[c*x])^p/(d+e*x^2),x] -
  1/2*Int[Log[SimplifyIntegrand[1-1/u,x]]*(a+b*ArcCoth[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[u^2-(1-2/(1+c*x))^2,0]

2:  ∫((ArcTanh[u](((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (u^2)==(((1-(2/(1-c x))))^2)

Derivation: Algebraic expansion

Basis: ArcTanh[z]==(1/2) Log[1+z]-(1/2) Log[1-z]

Basis: ArcCoth[z]==(1/2) Log[1+(1/z)]-(1/2) Log[1-(1/z)]

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (u^2)==(((1-(2/(1-c x))))^2), then

∫((ArcTanh[u](((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  ⟶  (1/2) ∫((Log[1+u](((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx-(1/2) ∫((Log[1-u](((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx

Program code:

Int[ArcTanh[u_]*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/2*Int[Log[1+u]*(a+b*ArcTanh[c*x])^p/(d+e*x^2),x] -
  1/2*Int[Log[1-u]*(a+b*ArcTanh[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[u^2-(1-2/(1-c*x))^2,0]

Int[ArcCoth[u_]*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/2*Int[Log[SimplifyIntegrand[1+1/u,x]]*(a+b*ArcCoth[c*x])^p/(d+e*x^2),x] -
  1/2*Int[Log[SimplifyIntegrand[1-1/u,x]]*(a+b*ArcCoth[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[u^2-(1-2/(1-c*x))^2,0]

3.  ∫(((((a+b ArcTanh[c x]))^p) Log[u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0

1:  ∫(((((a+b ArcTanh[c x]))^p) Log[f+g x])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (c^2) (f^2)-(g^2)==0

Derivation: Integration by parts

Basis: If  (c^2) d+e==0, then ((((a+b ArcTanh[c x]))^p)/(d+e (x^2)))==(∂_x)((((a+b ArcTanh[c x]))^(p+1))/(b c d (p+1)))

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (c^2) (f^2)-(g^2)==0, then

∫(((((a+b ArcTanh[c x]))^p) Log[f+g x])/(d+e (x^2)))dx  ⟶  (( (((a+b ArcTanh[c x]))^(p+1)) Log[f+g x])/(b c d (p+1)))-(g/(b c d (p+1)))∫((((a+b ArcTanh[c x]))^(p+1))/(f+g x))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_.*Log[f_+g_.*x_]/(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcTanh[c*x])^(p+1)*Log[f+g*x]/(b*c*d*(p+1)) - 
  g/(b*c*d*(p+1))*Int[(a+b*ArcTanh[c*x])^(p+1)/(f+g*x),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[c^2*f^2-g^2,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_.*Log[f_+g_.*x_]/(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcCoth[c*x])^(p+1)*Log[f+g*x]/(b*c*d*(p+1)) - 
  g/(b*c*d*(p+1))*Int[(a+b*ArcCoth[c*x])^(p+1)/(f+g*x),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[c^2*f^2-g^2,0]

2:  ∫(((((a+b ArcTanh[c x]))^p) Log[u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (((1-u))^2)==(((1-(2/(1+c x))))^2)

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (((1-u))^2)==(((1-(2/(1+c x))))^2), then

∫(((((a+b ArcTanh[c x]))^p) Log[u])/(d+e (x^2)))dx  ⟶  (( (((a+b ArcTanh[c x]))^p) PolyLog[2,1-u])/(2c d))-((b p)/2)∫(((((a+b ArcTanh[c x]))^(p-1)) PolyLog[2,1-u])/(d+e (x^2)))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_.*Log[u_]/(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcTanh[c*x])^p*PolyLog[2,1-u]/(2*c*d) - 
  b*p/2*Int[(a+b*ArcTanh[c*x])^(p-1)*PolyLog[2,1-u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[(1-u)^2-(1-2/(1+c*x))^2,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_.*Log[u_]/(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcCoth[c*x])^p*PolyLog[2,1-u]/(2*c*d) - 
  b*p/2*Int[(a+b*ArcCoth[c*x])^(p-1)*PolyLog[2,1-u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[(1-u)^2-(1-2/(1+c*x))^2,0]

3:  ∫(((((a+b ArcTanh[c x]))^p) Log[u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (((1-u))^2)==(((1-(2/(1-c x))))^2)

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (((1-u))^2)==(((1-(2/(1-c x))))^2), then

∫(((((a+b ArcTanh[c x]))^p) Log[u])/(d+e (x^2)))dx  ⟶  -(((((a+b ArcTanh[c x]))^p) PolyLog[2,1-u])/(2c d))+((b p)/2) ∫(((((a+b ArcTanh[c x]))^(p-1)) PolyLog[2,1-u])/(d+e (x^2)))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_.*Log[u_]/(d_+e_.*x_^2),x_Symbol] :=
  -(a+b*ArcTanh[c*x])^p*PolyLog[2,1-u]/(2*c*d) + 
  b*p/2*Int[(a+b*ArcTanh[c*x])^(p-1)*PolyLog[2,1-u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[(1-u)^2-(1-2/(1-c*x))^2,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_.*Log[u_]/(d_+e_.*x_^2),x_Symbol] :=
  -(a+b*ArcCoth[c*x])^p*PolyLog[2,1-u]/(2*c*d) + 
  b*p/2*Int[(a+b*ArcCoth[c*x])^(p-1)*PolyLog[2,1-u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[(1-u)^2-(1-2/(1-c*x))^2,0]

4.  ∫(((((a+b ArcTanh[c x]))^p) PolyLog[k,u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0

1:  ∫(((((a+b ArcTanh[c x]))^p) PolyLog[k,u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (u^2)==(((1-(2/(1+c x))))^2)

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (u^2)==(((1-(2/(1+c x))))^2), then

∫(((((a+b ArcTanh[c x]))^p) PolyLog[k,u])/(d+e (x^2)))dx  ⟶   -(((((a+b ArcTanh[c x]))^p) PolyLog[k+1,u])/(2c d))+((b p)/2) ∫(((((a+b ArcTanh[c x]))^(p-1)) PolyLog[k+1,u])/(d+e (x^2)))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_.*PolyLog[k_,u_]/(d_+e_.*x_^2),x_Symbol] :=
  -(a+b*ArcTanh[c*x])^p*PolyLog[k+1,u]/(2*c*d) +
  b*p/2*Int[(a+b*ArcTanh[c*x])^(p-1)*PolyLog[k+1,u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,k},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[u^2-(1-2/(1+c*x))^2,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_.*PolyLog[k_,u_]/(d_+e_.*x_^2),x_Symbol] :=
  -(a+b*ArcCoth[c*x])^p*PolyLog[k+1,u]/(2*c*d) +
  b*p/2*Int[(a+b*ArcCoth[c*x])^(p-1)*PolyLog[k+1,u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,k},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[u^2-(1-2/(1+c*x))^2,0]

2:  ∫(((((a+b ArcTanh[c x]))^p) PolyLog[k,u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (u^2)==(((1-(2/(1-c x))))^2)

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ (u^2)==(((1-(2/(1-c x))))^2), then

∫(((((a+b ArcTanh[c x]))^p) PolyLog[k,u])/(d+e (x^2)))dx  ⟶  (((((a+b ArcTanh[c x]))^p) PolyLog[k+1,u])/(2c d))-((b p)/2) ∫(((((a+b ArcTanh[c x]))^(p-1)) PolyLog[k+1,u])/(d+e (x^2)))dx

Program code:

Int[(a_.+b_.*ArcTanh[c_.*x_])^p_.*PolyLog[k_,u_]/(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcTanh[c*x])^p*PolyLog[k+1,u]/(2*c*d) -
  b*p/2*Int[(a+b*ArcTanh[c*x])^(p-1)*PolyLog[k+1,u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,k},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[u^2-(1-2/(1-c*x))^2,0]

Int[(a_.+b_.*ArcCoth[c_.*x_])^p_.*PolyLog[k_,u_]/(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcCoth[c*x])^p*PolyLog[k+1,u]/(2*c*d) -
  b*p/2*Int[(a+b*ArcCoth[c*x])^(p-1)*PolyLog[k+1,u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,k},x] && IGtQ[p,0] && EqQ[c^2*d+e,0] && EqQ[u^2-(1-2/(1-c*x))^2,0]

5.  ∫(((((a+b ArcCoth[c x]))^m) (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  (c^2) d+e==0

1:  ∫(1/((d+e (x^2)) (a+b ArcCoth[c x]) (a+b ArcTanh[c x])))dx  when  (c^2) d+e==0

Rule: If  (c^2) d+e==0, then

∫(1/((d+e (x^2)) (a+b ArcCoth[c x]) (a+b ArcTanh[c x])))dx  ⟶  ((-Log[a+b ArcCoth[c x]]+Log[a+b ArcTanh[c x]])/((b^2) c d (ArcCoth[c x]-ArcTanh[c x])))

Program code:

Int[1/((d_+e_.*x_^2)*(a_.+b_.*ArcCoth[c_.*x_])*(a_.+b_.*ArcTanh[c_.*x_])),x_Symbol] :=
  (-Log[a+b*ArcCoth[c*x]]+Log[a+b*ArcTanh[c*x]])/(b^2*c*d*(ArcCoth[c*x]-ArcTanh[c*x])) /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0]

2:  ∫(((((a+b ArcCoth[c x]))^m) (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  when  (c^2) d+e==0 ∧ (m|p)∈ℤ ∧ 0<p≤m

Derivation: Integration by parts

Rule: If  (c^2) d+e==0 ∧ (m|p)∈ℤ ∧ 0<p≤m, then

∫(((((a+b ArcCoth[c x]))^m) (((a+b ArcTanh[c x]))^p))/(d+e (x^2)))dx  ⟶  (((((a+b ArcCoth[c x]))^(m+1)) (((a+b ArcTanh[c x]))^p))/(b c d(m+1)))-(p/(m+1))∫(((((a+b ArcCoth[c x]))^(m+1)) (((a+b ArcTanh[c x]))^(p-1)))/(d+e (x^2)))dx

Program code:

Int[(a_.+b_.*ArcCoth[c_.*x_])^m_.*(a_.+b_.*ArcTanh[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcCoth[c*x])^(m+1)*(a+b*ArcTanh[c*x])^p/(b*c*d*(m+1)) -
  p/(m+1)*Int[(a+b*ArcCoth[c*x])^(m+1)*(a+b*ArcTanh[c*x])^(p-1)/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && IGeQ[m,p]

Int[(a_.+b_.*ArcTanh[c_.*x_])^m_.*(a_.+b_.*ArcCoth[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcTanh[c*x])^(m+1)*(a+b*ArcCoth[c*x])^p/(b*c*d*(m+1)) -
  p/(m+1)*Int[(a+b*ArcTanh[c*x])^(m+1)*(a+b*ArcCoth[c*x])^(p-1)/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0] && IGtQ[m,p]

8:  ∫((ArcTanh[a x])/(c+d (x^n)))dx  when  n∈ℤ ∧ ¬(n==2∧(a^2) c+d==0)

Derivation: Algebraic expansion

Basis: ArcTanh[z]==(1/2) Log[1+z]-(1/2) Log[1-z]

Basis: ArcCoth[z]==(1/2) Log[1+(1/z)]-(1/2) Log[1-(1/z)]

Rule: If  n∈ℤ ∧ ¬(n==2∧(a^2) c+d==0), then

∫((ArcTanh[a x])/(c+d (x^n)))dx  ⟶  (1/2)∫((Log[1+a x])/(c+d (x^n)))dx-(1/2)∫((Log[1-a x])/(c+d (x^n)))dx

Program code:

Int[ArcTanh[a_.*x_]/(c_+d_.*x_^n_.),x_Symbol] :=
  1/2*Int[Log[1+a*x]/(c+d*x^n),x] -
  1/2*Int[Log[1-a*x]/(c+d*x^n),x] /;
FreeQ[{a,c,d},x] && IntegerQ[n] && Not[EqQ[n,2] && EqQ[a^2*c+d,0]]

Int[ArcCoth[a_.*x_]/(c_+d_.*x_^n_.),x_Symbol] :=
  1/2*Int[Log[1+1/(a*x)]/(c+d*x^n),x] -
  1/2*Int[Log[1-1/(a*x)]/(c+d*x^n),x] /;
FreeQ[{a,c,d},x] && IntegerQ[n] && Not[EqQ[n,2] && EqQ[a^2*c+d,0]]

9.  ∫((Log[d (x^m)] (a+b ArcTanh[c (x^n)]))/x)dx

1:  ∫((Log[d (x^m)] ArcTanh[c (x^n)])/x)dx

Derivation: Algebraic expansion

Basis: ArcTanh[c (x^n)]==(1/2) Log[1+c (x^n)]-(1/2) Log[1-c (x^n)]

Rule:

∫((Log[d (x^m)] ArcTanh[c (x^n)])/x)dx  ⟶  (1/2) ∫((Log[d (x^m)] Log[1+c (x^n)])/x)dx-(1/2) ∫((Log[d (x^m)] Log[1-c (x^n)])/x)dx

Program code:

Int[Log[d_.*x_^m_.]*ArcTanh[c_.*x_^n_.]/x_,x_Symbol] :=
  1/2*Int[Log[d*x^m]*Log[1+c*x^n]/x,x] - 1/2*Int[Log[d*x^m]*Log[1-c*x^n]/x,x] /;
FreeQ[{c,d,m,n},x]

Int[Log[d_.*x_^m_.]*ArcCoth[c_.*x_^n_.]/x_,x_Symbol] :=
  1/2*Int[Log[d*x^m]*Log[1+1/(c*x^n)]/x,x] - 1/2*Int[Log[d*x^m]*Log[1-1/(c*x^n)]/x,x] /;
FreeQ[{c,d,m,n},x]

2:  ∫((Log[d (x^m)] (a+b ArcTanh[c (x^n)]))/x)dx

Derivation: Algebraic expansion

Rule:

∫((Log[d (x^m)] (a+b ArcTanh[c (x^n)]))/x)dx  ⟶  a ∫((Log[d (x^m)])/x)dx+b ∫((Log[d (x^m)] ArcTanh[c (x^n)])/x)dx

Program code:

Int[Log[d_.*x_^m_.]*(a_+b_.*ArcTanh[c_.*x_^n_.])/x_,x_Symbol] :=
  a*Int[Log[d*x^m]/x,x] + b*Int[(Log[d*x^m]*ArcTanh[c*x^n])/x,x] /;
FreeQ[{a,b,c,d,m,n},x]

Int[Log[d_.*x_^m_.]*(a_+b_.*ArcCoth[c_.*x_^n_.])/x_,x_Symbol] :=
  a*Int[Log[d*x^m]/x,x] + b*Int[(Log[d*x^m]*ArcCoth[c*x^n])/x,x] /;
FreeQ[{a,b,c,d,m,n},x]

10.  ∫u(d+e Log[f+g (x^2)])(((a+b ArcTanh[c x]))^p)dx

1:  ∫(d+e Log[f+g (x^2)]) (a+b ArcTanh[c x])dx

Derivation: Integration by parts

Rule:

∫(d+e Log[f+g (x^2)])(a+b ArcTanh[c x])dx  ⟶  x(d+e Log[f+g (x^2)])(a+b ArcTanh[c x])-2e g∫(((x^2)(a+b ArcTanh[c x]))/(f+g (x^2)))dx-b c∫((x(d+e Log[f+g (x^2)]))/(1-(c^2) (x^2)))dx

Program code:

Int[(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  x*(d+e*Log[f+g*x^2])*(a+b*ArcTanh[c*x]) - 
  2*e*g*Int[x^2*(a+b*ArcTanh[c*x])/(f+g*x^2),x] - 
  b*c*Int[x*(d+e*Log[f+g*x^2])/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x]

Int[(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  x*(d+e*Log[f+g*x^2])*(a+b*ArcCoth[c*x]) - 
  2*e*g*Int[x^2*(a+b*ArcCoth[c*x])/(f+g*x^2),x] - 
  b*c*Int[x*(d+e*Log[f+g*x^2])/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x]

2.  ∫(x^m)(d+e Log[f+g (x^2)]) (a+b ArcTanh[c x])dx

1.  ∫(((d+e Log[f+g (x^2)]) (a+b ArcTanh[c x]))/x)dx

1.  ∫((Log[f+g (x^2)] (a+b ArcTanh[c x]))/x)dx

1.  ∫((Log[f+g (x^2)] ArcTanh[c x])/x)dx  when  (c^2)f+g==0

1:  ∫((Log[f+g (x^2)] ArcTanh[c x])/x)dx  when  (c^2)f+g==0

Derivation: Piecewise constant extraction and algebraic simplification

Basis: If  (c^2)f+g==0, then (∂_x)(Log[f+g (x^2)]-Log[1-c x]-Log[1+c x])==0

Basis: (Log[1-c x]+Log[1+c x]) ArcTanh[c x]==-(1/2) ((Log[1-c x])^2)+(1/2) ((Log[1+c x])^2)

Rule: If  (c^2)f+g==0, then

∫((Log[f+g (x^2)] ArcTanh[c x])/x)dx  ⟶  

(Log[f+g (x^2)]-Log[1-c x]-Log[1+c x])∫((ArcTanh[c x])/x)dx+∫(((Log[1-c x]+Log[1+c x]) ArcTanh[c x])/x)dx  ⟶  

(Log[f+g (x^2)]-Log[1-c x]-Log[1+c x]) ∫((ArcTanh[c x])/x)dx-(1/2) ∫(((Log[1-c x])^2)/x)dx+(1/2) ∫(((Log[1+c x])^2)/x)dx

Program code:

Int[Log[f_.+g_.*x_^2]*ArcTanh[c_.*x_]/x_,x_Symbol] :=
  (Log[f+g*x^2]-Log[1-c*x]-Log[1+c*x])*Int[ArcTanh[c*x]/x,x] - 1/2*Int[Log[1-c*x]^2/x,x] + 1/2*Int[Log[1+c*x]^2/x,x] /;
FreeQ[{c,f,g},x] && EqQ[c^2*f+g,0]

2:  ∫((Log[f+g (x^2)] ArcCoth[c x])/x)dx  when  (c^2)f+g==0

Derivation: Piecewise constant extraction and algebraic simplification

Basis: If  (c^2)f+g==0, then (∂_x)(Log[f+g (x^2)]-Log[-(c^2) (x^2)]-Log[1-(1/(c x))]-Log[1+(1/(c x))])==0

Basis: (Log[-(c^2) (x^2)]+Log[1-(1/(c x))]+Log[1+(1/(c x))]) ArcCoth[c x]==Log[-(c^2) (x^2)] ArcCoth[c x]-(1/2) ((Log[1-(1/(c x))])^2)+(1/2) ((Log[1+(1/(c x))])^2)

Rule: If  (c^2)f+g==0, then

∫((Log[f+g (x^2)] ArcCoth[c x])/x)dx  ⟶  

(Log[f+g (x^2)]-Log[-(c^2) (x^2)]-Log[1-(1/(c x))]-Log[1+(1/(c x))])∫((ArcCoth[c x])/x)dx+∫(((Log[-(c^2) (x^2)]+ Log[1-(1/(c x))]+ Log[1+(1/(c x))]) ArcCoth[c x])/x)dx  ⟶  

(Log[f+g (x^2)]-Log[-(c^2) (x^2)]-Log[1-(1/(c x))]-Log[1+(1/(c x))]) ∫((ArcCoth[c x])/x)dx+∫((Log[-(c^2) (x^2)] ArcCoth[c x])/x)dx-(1/2) ∫(((Log[1-(1/(c x))])^2)/x)dx+(1/2) ∫(((Log[1+(1/(c x))])^2)/x)dx

Program code:

Int[Log[f_.+g_.*x_^2]*ArcCoth[c_.*x_]/x_,x_Symbol] :=
  (Log[f+g*x^2]-Log[-c^2*x^2]-Log[1-1/(c*x)]-Log[1+1/(c*x)])*Int[ArcCoth[c*x]/x,x] + 
  Int[Log[-c^2*x^2]*ArcCoth[c*x]/x,x] - 
  1/2*Int[Log[1-1/(c*x)]^2/x,x] + 
  1/2*Int[Log[1+1/(c*x)]^2/x,x] /;
FreeQ[{c,f,g},x] && EqQ[c^2*f+g,0]

2:  ∫((Log[f+g (x^2)] (a+b ArcTanh[c x]))/x)dx

Derivation: Algebraic expansion

Rule:

∫((Log[f+g (x^2)] (a+b ArcTanh[c x]))/x)dx  ⟶  a ∫((Log[f+g (x^2)])/x)dx+b ∫((Log[f+g (x^2)] ArcTanh[c x])/x)dx

Program code:

Int[Log[f_.+g_.*x_^2]*(a_+b_.*ArcTanh[c_.*x_])/x_,x_Symbol] :=
  a*Int[Log[f+g*x^2]/x,x] + b*Int[Log[f+g*x^2]*ArcTanh[c*x]/x,x] /;
FreeQ[{a,b,c,f,g},x]

Int[Log[f_.+g_.*x_^2]*(a_+b_.*ArcCoth[c_.*x_])/x_,x_Symbol] :=
  a*Int[Log[f+g*x^2]/x,x] + b*Int[Log[f+g*x^2]*ArcCoth[c*x]/x,x] /;
FreeQ[{a,b,c,f,g},x]

2:  ∫(((d+e Log[f+g (x^2)]) (a+b ArcTanh[c x]))/x)dx

Derivation: Algebraic expansion

Rule:

∫(((d+e Log[f+g (x^2)]) (a+b ArcTanh[c x]))/x)dx  ⟶  d ∫((a+b ArcTanh[c x])/x)dx+e ∫((Log[f+g (x^2)] (a+b ArcTanh[c x]))/x)dx

Program code:

Int[(d_+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcTanh[c_.*x_])/x_,x_Symbol] :=
  d*Int[(a+b*ArcTanh[c*x])/x,x] + e*Int[Log[f+g*x^2]*(a+b*ArcTanh[c*x])/x,x] /;
FreeQ[{a,b,c,d,e,f,g},x]

Int[(d_+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcCoth[c_.*x_])/x_,x_Symbol] :=
  d*Int[(a+b*ArcCoth[c*x])/x,x] + e*Int[Log[f+g*x^2]*(a+b*ArcCoth[c*x])/x,x] /;
FreeQ[{a,b,c,d,e,f,g},x]

2:  ∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTanh[c x])dx  when  (m/2)∈(SuperMinus[ℤ])

Derivation: Integration by parts

Rule: If (m/2)∈ℤ, then

∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTanh[c x])dx  ⟶  (((x^(m+1))(d+e Log[f+g (x^2)])(a+b ArcTanh[c x]))/(m+1))-((2e g)/(m+1))∫(((x^(m+2))(a+b ArcTanh[c x]))/(f+g (x^2)))dx-((b c)/(m+1))∫(((x^(m+1))(d+e Log[f+g (x^2)]))/(1-(c^2) (x^2)))dx

Program code:

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  x^(m+1)*(d+e*Log[f+g*x^2])*(a+b*ArcTanh[c*x])/(m+1) - 
  2*e*g/(m+1)*Int[x^(m+2)*(a+b*ArcTanh[c*x])/(f+g*x^2),x] - 
  b*c/(m+1)*Int[x^(m+1)*(d+e*Log[f+g*x^2])/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && ILtQ[m/2,0]

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  x^(m+1)*(d+e*Log[f+g*x^2])*(a+b*ArcCoth[c*x])/(m+1) - 
  2*e*g/(m+1)*Int[x^(m+2)*(a+b*ArcCoth[c*x])/(f+g*x^2),x] - 
  b*c/(m+1)*Int[x^(m+1)*(d+e*Log[f+g*x^2])/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && ILtQ[m/2,0]

3:  ∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTanh[c x])dx  when  ((m+1)/2)∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If ((m+1)/2)∈(SuperPlus[ℤ]), let u=∫(x^m)(d+e Log[f+g (x^2)])dx, then

∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTanh[c x])dx  ⟶  u (a+b ArcTanh[c x])-b c∫(u/(1-(c^2) (x^2)))dx

Program code:

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*Log[f+g*x^2]),x]},  
  Dist[a+b*ArcTanh[c*x],u,x] - b*c*Int[ExpandIntegrand[u/(1-c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[(m+1)/2,0]

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*Log[f+g*x^2]),x]},  
  Dist[a+b*ArcCoth[c*x],u,x] - b*c*Int[ExpandIntegrand[u/(1-c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[(m+1)/2,0]

4:  ∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTanh[c x])dx  when  m∈ℤ

Derivation: Integration by parts

Rule: If  m∈ℤ, let u=∫(x^m)(a+b ArcTanh[c x])dx, then

∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTanh[c x])dx  ⟶  u (d+e Log[f+g (x^2)])-2 e g∫((x u)/(f+g (x^2)))dx

Program code:

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcTanh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(a+b*ArcTanh[c*x]),x]},  
  Dist[d+e*Log[f+g*x^2],u,x] - 2*e*g*Int[ExpandIntegrand[x*u/(f+g*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IntegerQ[m] && NeQ[m,-1]

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcCoth[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(a+b*ArcCoth[c*x]),x]},  
  Dist[d+e*Log[f+g*x^2],u,x] - 2*e*g*Int[ExpandIntegrand[x*u/(f+g*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IntegerQ[m] && NeQ[m,-1]

3:  ∫x (d+e Log[f+g (x^2)]) (((a+b ArcTanh[c x]))^2)dx  when  (c^2)f+g==0

Derivation: Integration by parts

Basis: x (d+e Log[f+g (x^2)])==(∂_x)((((f+g (x^2)) (d+e Log[f+g (x^2)]))/(2 g))-((e (x^2))/2))

Rule: If  (c^2)f+g==0, then

∫x (d+e Log[f+g (x^2)]) (((a+b ArcTanh[c x]))^2)dx  ⟶  
(((f+g (x^2)) (d+e Log[f+g (x^2)])(((a+b ArcTanh[c x]))^2))/(2 g))-((e (x^2)(((a+b ArcTanh[c x]))^2))/2)+(b/c)∫(d+e Log[f+g (x^2)])(a+b ArcTanh[c x]) dx+b c e∫(((x^2)(a+b ArcTanh[c x]))/(1-(c^2) (x^2)))dx

Program code:

Int[x_*(d_.+e_.*Log[f_+g_.*x_^2])*(a_.+b_.*ArcTanh[c_.*x_])^2,x_Symbol] :=
  (f+g*x^2)*(d+e*Log[f+g*x^2])*(a+b*ArcTanh[c*x])^2/(2*g) - 
  e*x^2*(a+b*ArcTanh[c*x])^2/2 + 
  b/c*Int[(d+e*Log[f+g*x^2])*(a+b*ArcTanh[c*x]),x] + 
  b*c*e*Int[x^2*(a+b*ArcTanh[c*x])/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*f+g,0]

Int[x_*(d_.+e_.*Log[f_+g_.*x_^2])*(a_.+b_.*ArcCoth[c_.*x_])^2,x_Symbol] :=
  (f+g*x^2)*(d+e*Log[f+g*x^2])*(a+b*ArcCoth[c*x])^2/(2*g) - 
  e*x^2*(a+b*ArcCoth[c*x])^2/2 + 
  b/c*Int[(d+e*Log[f+g*x^2])*(a+b*ArcCoth[c*x]),x] + 
  b*c*e*Int[x^2*(a+b*ArcCoth[c*x])/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[c^2*f+g,0]

U:  ∫u(((a+b ArcTanh[c x]))^p)dx

Rule:

∫u(((a+b ArcTanh[c x]))^p)dx  ⟶  ∫u(((a+b ArcTanh[c x]))^p)dx

Program code:

Int[u_.*(a_.+b_.*ArcTanh[c_.*x_])^p_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcTanh[c*x])^p,x] /;
FreeQ[{a,b,c,p},x] && (EqQ[u,1] || 
  MatchQ[u,(d_.+e_.*x)^q_./; FreeQ[{d,e,q},x]] || 
  MatchQ[u,(f_.*x)^m_.*(d_.+e_.*x)^q_./; FreeQ[{d,e,f,m,q},x]] || 
  MatchQ[u,(d_.+e_.*x^2)^q_./; FreeQ[{d,e,q},x]] || 
  MatchQ[u,(f_.*x)^m_.*(d_.+e_.*x^2)^q_./; FreeQ[{d,e,f,m,q},x]])

Int[u_.*(a_.+b_.*ArcCoth[c_.*x_])^p_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcCoth[c*x])^p,x] /;
FreeQ[{a,b,c,p},x] && (EqQ[u,1] || 
  MatchQ[u,(d_.+e_.*x)^q_./; FreeQ[{d,e,q},x]] || 
  MatchQ[u,(f_.*x)^m_.*(d_.+e_.*x)^q_./; FreeQ[{d,e,f,m,q},x]] || 
  MatchQ[u,(d_.+e_.*x^2)^q_./; FreeQ[{d,e,q},x]] || 
  MatchQ[u,(f_.*x)^m_.*(d_.+e_.*x^2)^q_./; FreeQ[{d,e,f,m,q},x]])