Rules for integrands of the form  u (((a+b ArcSech[c+d x]))^p)

1.  ∫(((a+b ArcSech[c+d x]))^p)dx

1.  ∫ArcSech[c+d x]dx

1:  ∫ArcSech[c+d x]dx

Reference: CRC 591, A&S 4.6.47

Derivation: Integration by parts

Basis: (∂_x)ArcSech[c+d x]==-((d (Sqrt[((1-c-d x)/(1+c+d x))]))/((c+d x) (1-c-d x)))

Rule:

∫ArcSech[c+d x]dx  ⟶  (((c+d x) ArcSech[c+d x])/d)+∫((Sqrt[((1-c-d x)/(1+c+d x))])/(1-c-d x))dx

Program code:

Int[ArcSech[c_+d_.*x_],x_Symbol] :=
  (c+d*x)*ArcSech[c+d*x]/d + 
  Int[Sqrt[(1-c-d*x)/(1+c+d*x)]/(1-c-d*x),x] /;
FreeQ[{c,d},x]

2:  ∫ArcCsch[c+d x]dx

Reference: CRC 594, A&S 4.6.46

Derivation: Integration by parts

Basis: (∂_x)ArcCsch[c+d x]==-(d/((((c+d x))^2) (Sqrt[1+(1/(((c+d x))^2))])))

Rule:

∫ArcCsch[c+d x]dx  ⟶  (((c+d x) ArcCsch[c+d x])/d)+∫(1/((c+d x) (Sqrt[1+(1/(((c+d x))^2))])))dx

Program code:

Int[ArcCsch[c_+d_.*x_],x_Symbol] :=
  (c+d*x)*ArcCsch[c+d*x]/d + 
  Int[1/((c+d*x)*Sqrt[1+1/(c+d*x)^2]),x] /;
FreeQ[{c,d},x]

2:  ∫(((a+b ArcSech[c+d x]))^p)dx  when  p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Rule: If  p∈(SuperPlus[ℤ]), then

∫(((a+b ArcSech[c+d x]))^p)dx  ⟶  (1/d) Subst[∫(((a+b ArcSech[x]))^p)dx,x,c+d x]

Program code:

Int[(a_.+b_.*ArcSech[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[(a+b*ArcSech[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d},x] && IGtQ[p,0]

Int[(a_.+b_.*ArcCsch[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[(a+b*ArcCsch[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d},x] && IGtQ[p,0]

U:  ∫(((a+b ArcSech[c+d x]))^p)dx  when  p∉(SuperPlus[ℤ])

Rule: If  p∉(SuperPlus[ℤ]), then

∫(((a+b ArcSech[c+d x]))^p)dx  ⟶  ∫(((a+b ArcSech[c+d x]))^p)dx

Program code:

Int[(a_.+b_.*ArcSech[c_+d_.*x_])^p_,x_Symbol] :=
  Unintegrable[(a+b*ArcSech[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,p},x] && Not[IGtQ[p,0]]

Int[(a_.+b_.*ArcCsch[c_+d_.*x_])^p_,x_Symbol] :=
  Unintegrable[(a+b*ArcCsch[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,p},x] && Not[IGtQ[p,0]]

2.  ∫(((e+f x))^m) (((a+b ArcSech[c+d x]))^p)dx

1:  ∫(((e+f x))^m) (((a+b ArcSech[c+d x]))^p)dx  when  d e-c f==0 ∧ p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Rule: If  d e-c f==0 ∧ p∈(SuperPlus[ℤ]), then

∫(((e+f x))^m) (((a+b ArcSech[c+d x]))^p)dx  ⟶  (1/d) Subst[∫(((((f x)/d)))^m) (((a+b ArcSech[x]))^p)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcSech[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[(f*x/d)^m*(a+b*ArcSech[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[d*e-c*f,0] && IGtQ[p,0]

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcCsch[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[(f*x/d)^m*(a+b*ArcCsch[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[d*e-c*f,0] && IGtQ[p,0]

x.  ∫(x^m) ArcSech[a+b x]dx  when  m∈ℤ               ????

1:  ∫(x^m) ArcSech[a+b x]dx  when  m∈ℤ ∧ m≠-1

Derivation: Integration by parts and substitution

Basis: (x^m)==-(∂_x)(((((-a))^(m+1))-(b^(m+1)) (x^(m+1)))/((b^(m+1))(m+1)))

Basis: If  m∈ℤ, then ((((-a))^(m+1))-(b^(m+1)) (x^(m+1)))F[(1/(a+b x))]==-(1/b)Subst[(((((-a x))^(m+1))-(((1-a x))^(m+1)))/(x^(m+3)))F[x],x,(1/(a+b x))](∂_x)(1/(a+b x))

Rule: If  m∈ℤ ∧ m≠-1, then

∫(x^m) ArcSech[a+b x]dx  ⟶  -((((((-a))^(m+1))-(b^(m+1)) (x^(m+1))) ArcSech[a+b x])/((b^(m+1))(m+1)))-(1/((b^m)(m+1)))∫((((((-a))^(m+1))-(b^(m+1)) (x^(m+1)))(Sqrt[((1-a-b x)/(1+a+b x))]))/((1-a-b x) (a+b x)))dx
  ⟶  -((((((-a))^(m+1))-(b^(m+1)) (x^(m+1))) ArcSech[a+b x])/((b^(m+1))(m+1)))+(1/((b^(m+1))(m+1)))Subst[∫((((((-a x))^(m+1))-(((1-a x))^(m+1))))/((x^(m+1)) (Sqrt[-1+x]) (Sqrt[1+x])))dx,x,(1/(a+b x))]

Program code:

(* Int[x_^m_.*ArcSech[a_+b_.*x_],x_Symbol] :=
  -((-a)^(m+1)-b^(m+1)*x^(m+1))*ArcSech[a+b*x]/(b^(m+1)*(m+1)) + 
  1/(b^(m+1)*(m+1))*Subst[Int[((-a*x)^(m+1)-(1-a*x)^(m+1))/(x^(m+1)*Sqrt[-1+x]*Sqrt[1+x]),x],x,1/(a+b*x)] /;
FreeQ[{a,b},x] && IntegerQ[m] && NeQ[m,-1] *)

2:  ∫(x^m) ArcCsch[a+b x]dx  when  m∈ℤ ∧ m≠-1

Derivation: Integration by parts and substitution

Basis: If  m∈ℤ, then ((((((-a))^(m+1))-(b^(m+1)) (x^(m+1))))/(((a+b x))^2))F[(1/(a+b x))]==-(1/b)Subst[(((((-a x))^(m+1))-(((1-a x))^(m+1)))/(x^(m+1)))F[x],x,(1/(a+b x))](∂_x)(1/(a+b x))

Rule: If  m∈ℤ ∧ m≠-1, then

∫(x^m) ArcCsch[a+b x]dx  ⟶  -((((((-a))^(m+1))-(b^(m+1)) (x^(m+1))) ArcCsch[a+b x])/((b^(m+1))(m+1)))-(1/((b^m)(m+1)))∫((((((-a))^(m+1))-(b^(m+1)) (x^(m+1))))/((((a+b x))^2) (Sqrt[1+(1/(((a+b x))^2))])))dx
  ⟶  -((((((-a))^(m+1))-(b^(m+1)) (x^(m+1))) ArcCsch[a+b x])/((b^(m+1))(m+1)))+(1/((b^(m+1))(m+1)))Subst[∫(((((-a x))^(m+1))-(((1-a x))^(m+1)))/((x^(m+1)) (Sqrt[1+(x^2)])))dx,x,(1/(a+b x))]

Program code:

(* Int[x_^m_.*ArcCsch[a_+b_.*x_],x_Symbol] :=
  -((-a)^(m+1)-b^(m+1)*x^(m+1))*ArcCsch[a+b*x]/(b^(m+1)*(m+1)) + 
  1/(b^(m+1)*(m+1))*Subst[Int[((-a*x)^(m+1)-(1-a*x)^(m+1))/(x^(m+1)*Sqrt[1+x^2]),x],x,1/(a+b*x)] /;
FreeQ[{a,b},x] && IntegerQ[m] && NeQ[m,-1] *)

2:  ∫(((e+f x))^m) (((a+b ArcSech[c+d x]))^p)dx  when  p∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Integration by substitution

Basis: If  m∈ℤ, then (((e+f x))^m) F[ArcSech[c+d x]]==-(1/(d^(m+1))) Subst[F[x] Sech[x] Tanh[x] (((d e-c f+f Sech[x]))^m),x,ArcSech[c+d x]] (∂_x)ArcSech[c+d x]

Rule: If  p∈(SuperPlus[ℤ])∧ m∈ℤ, then

∫(((e+f x))^m) (((a+b ArcSech[c+d x]))^p)dx  ⟶  -(1/(d^(m+1))) Subst[∫(((a+b x))^p) Sech[x]Tanh[x] (((d e-c f+f Sech[x]))^m)dx,x,ArcSech[c+d x]]

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcSech[c_+d_.*x_])^p_.,x_Symbol] :=
  -1/d^(m+1)*Subst[Int[(a+b*x)^p*Sech[x]*Tanh[x]*(d*e-c*f+f*Sech[x])^m,x],x,ArcSech[c+d*x]] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && IntegerQ[m]

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcCsch[c_+d_.*x_])^p_.,x_Symbol] :=
  -1/d^(m+1)*Subst[Int[(a+b*x)^p*Csch[x]*Coth[x]*(d*e-c*f+f*Csch[x])^m,x],x,ArcCsch[c+d*x]] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && IntegerQ[m]

3:  ∫(((e+f x))^m)(((a+b ArcSech[c+d x]))^p)dx  when  p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Rule: If  p∈(SuperPlus[ℤ]), then

∫(((e+f x))^m)(((a+b ArcSech[c+d x]))^p)dx  ⟶  (1/d)Subst[∫(((((d e-c f)/d)+((f x)/d)))^m)(((a+b ArcSech[x]))^p)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcSech[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(a+b*ArcSech[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[p,0]

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcCsch[c_+d_.*x_])^p_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(a+b*ArcCsch[x])^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[p,0]

U:  ∫(((e+f x))^m)(((a+b ArcSech[c+d x]))^p)dx  when  p∉(SuperPlus[ℤ])

Rule: If  p∉(SuperPlus[ℤ]), then

∫(((e+f x))^m)(((a+b ArcSech[c+d x]))^p)dx  ⟶  ∫(((e+f x))^m)(((a+b ArcSech[c+d x]))^p)dx

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcSech[c_+d_.*x_])^p_,x_Symbol] :=
  Unintegrable[(e+f*x)^m*(a+b*ArcSech[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && Not[IGtQ[p,0]]

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcCsch[c_+d_.*x_])^p_,x_Symbol] :=
  Unintegrable[(e+f*x)^m*(a+b*ArcCsch[c+d*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && Not[IGtQ[p,0]]

Rules for integrands involving inverse hyperbolic secants and cosecants

1:  ∫u ((ArcSech[(c/(a+b (x^n)))])^m)dx

Derivation:  Algebraic simplification

Basis: ArcSech[z]==ArcCosh[(1/z)]

Rule:

∫u ((ArcSech[(c/(a+b (x^n)))])^m)dx  ⟶  ∫u ((ArcCosh[(a/c)+((b (x^n))/c)])^m)dx

Program code:

Int[u_.*ArcSech[c_./(a_.+b_.*x_^n_.)]^m_.,x_Symbol] :=
  Int[u*ArcCosh[a/c+b*x^n/c]^m,x] /;
FreeQ[{a,b,c,n,m},x]

Int[u_.*ArcCsch[c_./(a_.+b_.*x_^n_.)]^m_.,x_Symbol] :=
  Int[u*ArcSinh[a/c+b*x^n/c]^m,x] /;
FreeQ[{a,b,c,n,m},x]

2.  ∫v (e^(ArcSech[u]))dx

1.  ∫(e^(n ArcSech[u]))dx

1.  ∫(e^(ArcSech[a (x^p)]))dx

1.  ∫(e^(ArcSech[a (x^p)]))dx

1:  ∫(e^(ArcSech[a x]))dx

Derivation: Integration by parts

Basis: (∂_x)(e^(ArcSech[a x]))==-(1/(a (x^2)))-(1/(a (x^2) (1-a x)))(Sqrt[((1-a x)/(1+a x))])

Rule:

∫(e^(ArcSech[a x]))dx  ⟶  x (e^(ArcSech[a x])) + ((Log[x])/a) + (1/a)∫(1/(x(1-a x)))(Sqrt[((1-a x)/(1+a x))])dx

Program code:

Int[E^ArcSech[a_.*x_], x_Symbol] :=
  x*E^ArcSech[a*x] + Log[x]/a + 1/a*Int[1/(x*(1-a*x))*Sqrt[(1-a*x)/(1+a*x)],x] /;
FreeQ[a,x]

2:  ∫(e^(ArcSech[a (x^p)]))dx

Derivation: Integration by parts, piecewise constant extraction and algebraic simplification

Basis: (∂_x)(e^(ArcSech[a (x^p)]))==-(p/(a (x^(p+1))))-(p/(a (x^(p+1)) (1-a (x^p))))(Sqrt[((1-a (x^p))/(1+a (x^p)))])

Basis: (∂_x)((Sqrt[((1-a (x^p))/(1+a (x^p)))])/((Sqrt[1-a (x^p)])/(Sqrt[1+a (x^p)])))==0

Basis: (Sqrt[((1-a (x^p))/(1+a (x^p)))])/((Sqrt[1-a (x^p)])/(Sqrt[1+a (x^p)]))== (Sqrt[1+a (x^p)])(Sqrt[(1/(1+a (x^p)))])

Rule:

∫(e^(ArcSech[a (x^p)]))dx  ⟶  x (e^(ArcSech[a (x^p)])) + (p/a)∫(1/(x^p))dx + (( p(Sqrt[1+a (x^p)]))/a)(Sqrt[(1/(1+a (x^p)))])∫(1/((x^p)(Sqrt[1+a (x^p)])(Sqrt[1-a (x^p)])))dx

Program code:

Int[E^ArcSech[a_.*x_^p_], x_Symbol] :=
  x*E^ArcSech[a*x^p] + 
  p/a*Int[1/x^p,x] + 
  p*Sqrt[1+a*x^p]/a*Sqrt[1/(1+a*x^p)]*Int[1/(x^p*Sqrt[1+a*x^p]*Sqrt[1-a*x^p]),x] /;
FreeQ[{a,p},x]

2:  ∫(e^(ArcCsch[a (x^p)]))dx

Derivation: Algebraic simplification

Basis: (e^(ArcCsch[z]))==(1/z)+(Sqrt[1+(1/(z^2))])

Rule:

∫(e^(ArcCsch[a (x^p)]))dx  ⟶  (1/a)∫(1/(x^p))dx+∫(Sqrt[1+(1/((a^2)(x^(2 p))))])dx

Program code:

Int[E^ArcCsch[a_.*x_^p_.], x_Symbol] :=
  1/a*Int[1/x^p,x] + Int[Sqrt[1+1/(a^2*x^(2*p))],x] /;
FreeQ[{a,p},x]

2.  ∫(e^(n ArcSech[u]))dx  when  n∈ℤ

1:  ∫(e^(n ArcSech[u]))dx  when  n∈ℤ

Derivation: Algebraic simplification

Basis: (e^(ArcSech[z]))==(1/z)+(( 1+z)/z)(Sqrt[((1-z)/(1+z))])==(1/z)+(Sqrt[((1-z)/(1+z))])+(1/z)(Sqrt[((1-z)/(1+z))])

Basis: (e^(n ArcSech[z]))==((((1/z)+(Sqrt[-1+(1/z)]) (Sqrt[1+(1/z)])))^n)

Basis: If  n∈ℤ, then (e^(n z))==((((e^z)))^n)

Rule: If  n∈ℤ, then

∫(e^(n ArcSech[u]))dx  ⟶  ∫((((1/u) + (Sqrt[((1-u)/(1+u))]) + (1/u)(Sqrt[((1-u)/(1+u))])))^n)dx

Program code:

Int[E^(n_.*ArcSech[u_]), x_Symbol] :=
  Int[(1/u + Sqrt[(1-u)/(1+u)] + 1/u*Sqrt[(1-u)/(1+u)])^n,x] /;
IntegerQ[n]

2:  ∫(e^(n ArcCsch[u]))dx  when  n∈ℤ

Derivation: Algebraic simplification

Basis: (e^(n ArcCsch[z]))==((((1/z)+(Sqrt[1+(1/(z^2))])))^n)

Rule: If  n∈ℤ, then

∫(e^(n ArcCsch[u]))dx  ⟶  ∫((((1/u)+(Sqrt[1+(1/(u^2))])))^n)dx

Program code:

Int[E^(n_.*ArcCsch[u_]), x_Symbol] :=
  Int[(1/u + Sqrt[1+1/u^2])^n,x] /;
IntegerQ[n]

2.  ∫(x^m)(e^(n ArcSech[u]))dx

1.  ∫(x^m)(e^(ArcSech[a (x^p)]))dx

1.  ∫(x^m)(e^(ArcSech[a (x^p)]))dx

1:  ∫((e^(ArcSech[a (x^p)]))/x)dx

Derivation: Algebraic simplification, piecewise constant extraction and algebraic simplification

Basis: (e^(ArcSech[z]))==(1/z)+(( 1+z)/z)(Sqrt[((1-z)/(1+z))])==(1/z)+(Sqrt[((1-z)/(1+z))])+(1/z)(Sqrt[((1-z)/(1+z))])

Basis: (∂_x)((Sqrt[((1-a (x^p))/(1+a (x^p)))])/((Sqrt[1-a (x^p)])/(Sqrt[1+a (x^p)])))==0

Basis: (Sqrt[((1-a (x^p))/(1+a (x^p)))])/((Sqrt[1-a (x^p)])/(Sqrt[1+a (x^p)]))== (Sqrt[1+a (x^p)])(Sqrt[(1/(1+a (x^p)))])

Rule:

∫((e^(ArcSech[a (x^p)]))/x)dx  ⟶  -(1/(a p (x^p))) + ((Sqrt[1+a (x^p)])/a)(Sqrt[(1/(1+a (x^p)))])∫(((Sqrt[1+a (x^p)])(Sqrt[1-a (x^p)]))/(x^(p+1)))dx

Program code:

Int[E^ArcSech[a_.*x_^p_.]/x_, x_Symbol] :=
  -1/(a*p*x^p) + 
  Sqrt[1+a*x^p]/a*Sqrt[1/(1+a*x^p)]*Int[Sqrt[1+a*x^p]*Sqrt[1-a*x^p]/x^(p+1),x] /;
FreeQ[{a,p},x]

2:  ∫(x^m)(e^(ArcSech[a (x^p)]))dx  when  m≠-1

Derivation: Integration by parts, piecewise constant extraction and algebraic simplification

Basis: (∂_x)(e^(ArcSech[a (x^p)]))==-(p/(a (x^(p+1))))-(p/(a (x^(p+1)) (1-a (x^p))))(Sqrt[((1-a (x^p))/(1+a (x^p)))])

Basis: (∂_x)((Sqrt[((1-a (x^p))/(1+a (x^p)))])/((Sqrt[1-a (x^p)])/(Sqrt[1+a (x^p)])))==0

Basis: (Sqrt[((1-a (x^p))/(1+a (x^p)))])/((Sqrt[1-a (x^p)])/(Sqrt[1+a (x^p)]))== (Sqrt[1+a (x^p)])(Sqrt[(1/(1+a (x^p)))])

Rule: If  m≠-1, then

∫(x^m)(e^(ArcSech[a (x^p)]))dx  ⟶  (((x^(m+1)) (e^(ArcSech[a (x^p)])))/(m+1)) + (p/(a(m+1)))∫(x^(m-p))dx + (( p(Sqrt[1+a (x^p)]))/(a(m+1)))(Sqrt[(1/(1+a (x^p)))])∫((x^(m-p))/((Sqrt[1+a (x^p)])(Sqrt[1-a (x^p)])))dx

Program code:

Int[x_^m_.*E^ArcSech[a_.*x_^p_.], x_Symbol] :=
  x^(m+1)*E^ArcSech[a*x^p]/(m+1) + 
  p/(a*(m+1))*Int[x^(m-p),x] + 
  p*Sqrt[1+a*x^p]/(a*(m+1))*Sqrt[1/(1+a*x^p)]*Int[x^(m-p)/(Sqrt[1+a*x^p]*Sqrt[1-a*x^p]),x] /;
FreeQ[{a,m,p},x] && NeQ[m,-1]

2:  ∫(x^m)(e^(ArcCsch[a (x^p)]))dx

Derivation: Algebraic simplification

Basis: (e^(ArcCsch[z]))==(1/z)+(Sqrt[1+(1/(z^2))])

Rule:

∫(x^m)(e^(ArcCsch[a (x^p)]))dx  ⟶  (1/a)∫(x^(m-p))dx+∫(x^m)(Sqrt[1+(1/((a^2)(x^(2 p))))])dx

Program code:

Int[x_^m_.*E^ArcCsch[a_.*x_^p_.], x_Symbol] :=
  1/a*Int[x^(m-p),x] + Int[x^m*Sqrt[1+1/(a^2*x^(2*p))],x] /;
FreeQ[{a,m,p},x]

2.  ∫(x^m)(e^(n ArcSech[u]))dx

1:  ∫(x^m)(e^(n ArcSech[u]))dx  when  n∈ℤ

Derivation: Algebraic simplification

Basis: (e^(ArcSech[z]))==(1/z)+(( 1+z)/z)(Sqrt[((1-z)/(1+z))])==(1/z)+(Sqrt[((1-z)/(1+z))])+(1/z)(Sqrt[((1-z)/(1+z))])

Basis: (e^(n ArcSech[z]))==((((1/z)+(Sqrt[-1+(1/z)]) (Sqrt[1+(1/z)])))^n)

Rule: If  n∈ℤ, then

∫(x^m)(e^(n ArcSech[u]))dx  ⟶  ∫(x^m) ((((1/u) + (Sqrt[((1-u)/(1+u))]) + (1/u)(Sqrt[((1-u)/(1+u))])))^n)dx

Program code:

Int[x_^m_.*E^(n_.*ArcSech[u_]), x_Symbol] :=
  Int[x^m*(1/u + Sqrt[(1-u)/(1+u)] + 1/u*Sqrt[(1-u)/(1+u)])^n,x] /;
FreeQ[m,x] && IntegerQ[n]

2:  ∫(x^m)(e^(n ArcCsch[u]))dx  when  n∈ℤ

Derivation: Algebraic simplification

Basis: (e^(n ArcCsch[z]))==((((1/z)+(Sqrt[1+(1/(z^2))])))^n)

Rule: If  n∈ℤ, then

∫(x^m)(e^(n ArcCsch[u]))dx  ⟶  ∫(x^m)((((1/u)+(Sqrt[1+(1/(u^2))])))^n)dx

Program code:

Int[x_^m_.*E^(n_.*ArcCsch[u_]), x_Symbol] :=
  Int[x^m*(1/u + Sqrt[1+1/u^2])^n,x] /;
FreeQ[m,x] && IntegerQ[n]

3:  ∫((e^(ArcSech[c x]))/(a+b (x^2)))dx  when  b+a (c^2)==0

Derivation: Algebraic expansion

Basis: ((e^(ArcSech[x]))/(1-(x^2)))==((Sqrt[(1/(1+x))])/(x (Sqrt[1-x])))+(1/(x (1-(x^2))))

Basis: If  b+a (c^2)==0 , then ((e^(ArcSech[c x]))/(a+b (x^2)))==((Sqrt[(1/(1+c x))])/(a c x (Sqrt[1-c x])))+(1/(c x (a+b (x^2))))

Rule: If  b+a (c^2)==0 , then

∫((e^(ArcSech[c x]))/(a+b (x^2)))dx  ⟶  (1/(a c)) ∫((Sqrt[(1/(1+c x))])/(x (Sqrt[1-c x])))dx+(1/c) ∫(1/(x (a+b (x^2))))dx

Basis: ((e^(ArcCsch[x]))/(1+(x^2)))==(1/((x^2) (Sqrt[1+(1/(x^2))])))+(1/(x (1+(x^2))))

Basis: If  b-a (c^2)==0 , then ((e^(ArcCsch[c x]))/(a+b (x^2)))==(1/(a (c^2) (x^2) (Sqrt[1+(1/((c^2) (x^2)))])))+(1/(c x (a+b (x^2))))

Rule: If  b-a (c^2)==0 , then

∫((e^(ArcCsch[c x]))/(a+b (x^2)))dx  ⟶  (1/(a (c^2))) ∫(1/((x^2) (Sqrt[1+(1/((c^2) (x^2)))])))dx+(1/c) ∫(1/(x (a+b (x^2))))dx

Program code:

Int[E^(ArcSech[c_.*x_])/(a_+b_.*x_^2), x_Symbol] :=
  1/(a*c)*Int[Sqrt[1/(1+c*x)]/(x*Sqrt[1-c*x]),x] + 1/c*Int[1/(x*(a+b*x^2)),x] /;
FreeQ[{a,b,c},x] && EqQ[b+a*c^2,0]

Int[E^(ArcCsch[c_.*x_])/(a_+b_.*x_^2), x_Symbol] :=
  1/(a*c^2)*Int[1/(x^2*Sqrt[1+1/(c^2*x^2)]),x] + 1/c*Int[1/(x*(a+b*x^2)),x] /;
FreeQ[{a,b,c},x] && EqQ[b-a*c^2,0]

4:  ∫(((((d x))^m) (e^(ArcSech[c x])))/(a+b (x^2)))dx  when  b+a (c^2)==0

Derivation: Algebraic expansion

Basis: ((e^(ArcSech[x]))/(1-(x^2)))==((Sqrt[(1/(1+x))])/(x (Sqrt[1-x])))+(1/(x (1-(x^2))))

Basis: If  b+a (c^2)==0 , then (((((d x))^m) (e^(ArcSech[c x])))/(a+b (x^2)))==((d (((d x))^(m-1)) (Sqrt[(1/(1+c x))]))/(a c (Sqrt[1-c x])))+((d (((d x))^(m-1)))/(c (a+b (x^2))))

Rule: If  b+a (c^2)==0 , then

∫(((((d x))^m) (e^(ArcSech[c x])))/(a+b (x^2)))dx  ⟶  (d/(a c)) ∫(((((d x))^(m-1)) (Sqrt[(1/(1+c x))]))/(Sqrt[1-c x]))dx+(d/c) ∫((((d x))^(m-1))/(a+b (x^2)))dx

Basis: ((e^(ArcCsch[x]))/(1+(x^2)))==(1/((x^2) (Sqrt[1+(1/(x^2))])))+(1/(x (1+(x^2))))

Basis: If  b-a (c^2)==0 , then (((((d x))^m) (e^(ArcCsch[c x])))/(a+b (x^2)))==(((d^2) (((d x))^(m-2)))/(a (c^2) (Sqrt[1+(1/((c^2) (x^2)))])))+((d (((d x))^(m-1)))/(c (a+b (x^2))))

Rule: If  b-a (c^2)==0 , then

∫(((((d x))^m) (e^(ArcCsch[c x])))/(a+b (x^2)))dx  ⟶  ((d^2)/(a (c^2))) ∫((((d x))^(m-2))/(Sqrt[1+(1/((c^2) (x^2)))]))dx+(d/c) ∫((((d x))^(m-1))/(a+b (x^2)))dx

Program code:

Int[(d_.*x_)^m_.*E^(ArcSech[c_.*x_])/(a_+b_.*x_^2), x_Symbol] :=
  d/(a*c)*Int[(d*x)^(m-1)*Sqrt[1/(1+c*x)]/Sqrt[1-c*x],x] + d/c*Int[(d*x)^(m-1)/(a+b*x^2),x] /;
FreeQ[{a,b,c,d,m},x] && EqQ[b+a*c^2,0]

Int[(d_.*x_)^m_.*E^(ArcCsch[c_.*x_])/(a_+b_.*x_^2), x_Symbol] :=
  d^2/(a*c^2)*Int[(d*x)^(m-2)/Sqrt[1+1/(c^2*x^2)],x] + d/c*Int[(d*x)^(m-1)/(a+b*x^2),x] /;
FreeQ[{a,b,c,d,m},x] && EqQ[b-a*c^2,0]

3.  ∫v (a+b ArcSech[u])dx  when  u is free of inverse functions

1.  ∫ArcSech[u]dx  when  u is free of inverse functions

1:  ∫ArcSech[u]dx  whenu is free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)ArcSech[f[x]]==-(((∂_x)f[x])/(((f[x])^2)(Sqrt[-1+(1/(f[x]))])(Sqrt[1+(1/(f[x]))])))

Basis: (∂_x)((Sqrt[1-((f[x])^2)])/(f[x](Sqrt[-1+(1/(f[x]))]) (Sqrt[1+(1/(f[x]))])))==0

Rule: If u is free of inverse functions, then

∫ArcSech[u]dx  ⟶  x ArcSech[u]+∫((x (∂_x)u)/((u^2) (Sqrt[-1+(1/u)]) (Sqrt[1+(1/u)])))dx  ⟶  x ArcSech[u]+((Sqrt[1-(u^2)])/(u(Sqrt[-1+(1/u)]) (Sqrt[1+(1/u)])))∫((x (∂_x)u)/(u (Sqrt[1-(u^2)])))dx

Program code:

Int[ArcSech[u_],x_Symbol] :=
  x*ArcSech[u] +
  Sqrt[1-u^2]/(u*Sqrt[-1+1/u]*Sqrt[1+1/u])*Int[SimplifyIntegrand[x*D[u,x]/(u*Sqrt[1-u^2]),x],x] /;
InverseFunctionFreeQ[u,x] && Not[FunctionOfExponentialQ[u,x]]

2:  ∫ArcCsch[u]dx  whenu is free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)ArcCsch[f[x]]==-(((∂_x)f[x])/(((f[x])^2)(Sqrt[1+(1/((f[x])^2))])))==(((∂_x)f[x])/((Sqrt[-((f[x])^2)])(Sqrt[-1-((f[x])^2)])))

Basis: (∂_x)((f[x])/(Sqrt[-((f[x])^2)]))==0

Rule: If u is free of inverse functions, then

∫ArcCsch[u]dx  ⟶  x ArcCsch[u]-∫((x (∂_x)u)/((Sqrt[-(u^2)])(Sqrt[-1-(u^2)])))dx  ⟶  x ArcCsch[u]-(u/(Sqrt[-(u^2)]))∫((x (∂_x)u)/(u(Sqrt[-1-(u^2)])))dx

Program code:

Int[ArcCsch[u_],x_Symbol] :=
  x*ArcCsch[u] -
  u/Sqrt[-u^2]*Int[SimplifyIntegrand[x*D[u,x]/(u*Sqrt[-1-u^2]),x],x] /;
InverseFunctionFreeQ[u,x] && Not[FunctionOfExponentialQ[u,x]]

2.  ∫(((c+d x))^m) (a+b ArcSech[u])dx  when  m≠-1 ∧ u is free of inverse functions

1:  ∫(((c+d x))^m)(a+b ArcSech[u])dx  when  m≠-1 ∧ u is free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)ArcSech[f[x]]==-(((∂_x)f[x])/(((f[x])^2)(Sqrt[-1+(1/(f[x]))])(Sqrt[1+(1/(f[x]))])))

Basis: (∂_x)((Sqrt[1-((f[x])^2)])/(f[x](Sqrt[-1+(1/(f[x]))]) (Sqrt[1+(1/(f[x]))])))==0

Rule: If  m≠-1 ∧ if u is free of inverse functions, then

∫(((c+d x))^m)(a+b ArcSech[u])dx  ⟶  (((((c+d x))^(m+1)) (a+b ArcSech[u]))/(d(m+1)))+(b/(d(m+1)))∫(((((c+d x))^(m+1)) (∂_x)u)/((u^2) (Sqrt[-1+(1/u)]) (Sqrt[1+(1/u)])))dx
  ⟶  (((((c+d x))^(m+1)) (a+b ArcSech[u]))/(d(m+1)))+((b(Sqrt[1-(u^2)]))/(d(m+1)u(Sqrt[-1+(1/u)]) (Sqrt[1+(1/u)])))∫(((((c+d x))^(m+1)) (∂_x)u)/(u (Sqrt[1-(u^2)])))dx

Program code:

Int[(c_.+d_.*x_)^m_.*(a_.+b_.*ArcSech[u_]),x_Symbol] :=
  (c+d*x)^(m+1)*(a+b*ArcSech[u])/(d*(m+1)) + 
  b*Sqrt[1-u^2]/(d*(m+1)*u*Sqrt[-1+1/u]*Sqrt[1+1/u])*Int[SimplifyIntegrand[(c+d*x)^(m+1)*D[u,x]/(u*Sqrt[1-u^2]),x],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1] && InverseFunctionFreeQ[u,x] && Not[FunctionOfQ[(c+d*x)^(m+1),u,x]] && Not[FunctionOfExponentialQ[u,x]]

2:  ∫(((c+d x))^m)(a+b ArcCsch[u])dx  when  m≠-1 ∧ u is free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcCsch[f[x]])==-((b (∂_x)f[x])/(((f[x])^2)(Sqrt[1+(1/((f[x])^2))])))==((b (∂_x)f[x])/((Sqrt[-((f[x])^2)])(Sqrt[-1-((f[x])^2)])))

Basis: (∂_x)((f[x])/(Sqrt[-((f[x])^2)]))==0

Rule: If  m≠-1 ∧ u is free of inverse functions, then

∫(((c+d x))^m)(a+b ArcCsch[u])dx  ⟶  (((((c+d x))^(m+1)) (a+b ArcCsch[u]))/(d(m+1)))-(b/(d(m+1)))∫(((((c+d x))^(m+1)) (∂_x)u)/((Sqrt[-(u^2)])(Sqrt[-1-(u^2)])))dx
  ⟶  (((((c+d x))^(m+1)) (a+b ArcCsch[u]))/(d(m+1)))-((b u)/(d(m+1)(Sqrt[-(u^2)])))∫(((((c+d x))^(m+1)) (∂_x)u)/(u(Sqrt[-1-(u^2)])))dx

Program code:

Int[(c_.+d_.*x_)^m_.*(a_.+b_.*ArcCsch[u_]),x_Symbol] :=
  (c+d*x)^(m+1)*(a+b*ArcCsch[u])/(d*(m+1)) - 
  b*u/(d*(m+1)*Sqrt[-u^2])*Int[SimplifyIntegrand[(c+d*x)^(m+1)*D[u,x]/(u*Sqrt[-1-u^2]),x],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1] && InverseFunctionFreeQ[u,x] && Not[FunctionOfQ[(c+d*x)^(m+1),u,x]] && Not[FunctionOfExponentialQ[u,x]]

3.  ∫v (a+b ArcSech[u])dx  when  u and ∫vdx  are free of inverse functions

1:  ∫v (a+b ArcSech[u])dx  when  u and ∫vdx  are free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)ArcSech[f[x]]==-(((∂_x)f[x])/(((f[x])^2)(Sqrt[-1+(1/(f[x]))])(Sqrt[1+(1/(f[x]))])))

Basis: (∂_x)((Sqrt[1-((f[x])^2)])/(f[x](Sqrt[-1+(1/(f[x]))]) (Sqrt[1+(1/(f[x]))])))==0

Rule: If u is free of inverse functions, let  w==∫vdx, if w is free of inverse functions, then

∫v (a+b ArcSech[u])dx  ⟶  w (a+b ArcSech[u])+b∫((w (∂_x)u)/((u^2) (Sqrt[-1+(1/u)]) (Sqrt[1+(1/u)])))dx  ⟶  w (a+b ArcSech[u])+((b(Sqrt[1-(u^2)]))/(u(Sqrt[-1+(1/u)]) (Sqrt[1+(1/u)])))∫((w (∂_x)u)/(u(Sqrt[1-(u^2)])))dx

Program code:

Int[v_*(a_.+b_.*ArcSech[u_]),x_Symbol] :=
  With[{w=IntHide[v,x]},  
  Dist[(a+b*ArcSech[u]),w,x] + b*Sqrt[1-u^2]/(u*Sqrt[-1+1/u]*Sqrt[1+1/u])*Int[SimplifyIntegrand[w*D[u,x]/(u*Sqrt[1-u^2]),x],x] /;
 InverseFunctionFreeQ[w,x]] /;
FreeQ[{a,b},x] && InverseFunctionFreeQ[u,x] && Not[MatchQ[v, (c_.+d_.*x)^m_. /; FreeQ[{c,d,m},x]]]

2:  ∫v (a+b ArcCsch[u])dx  when  u and ∫vdx  are free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcCsch[f[x]])==-((b (∂_x)f[x])/(((f[x])^2)(Sqrt[1+(1/((f[x])^2))])))==((b (∂_x)f[x])/((Sqrt[-((f[x])^2)])(Sqrt[-1-((f[x])^2)])))

Basis: (∂_x)((f[x])/(Sqrt[-((f[x])^2)]))==0

Rule: If u is free of inverse functions, let  w==∫vdx, if w is free of inverse functions, then

∫v (a+b ArcCsch[u])dx  ⟶  w (a+b ArcCsch[u])-b∫((w (∂_x)u)/((Sqrt[-(u^2)])(Sqrt[-1-(u^2)])))dx  ⟶  w (a+b ArcCsch[u])-((b u)/(Sqrt[-(u^2)]))∫((w (∂_x)u)/(u(Sqrt[-1-(u^2)])))dx

Program code:

Int[v_*(a_.+b_.*ArcCsch[u_]),x_Symbol] :=
  With[{w=IntHide[v,x]},  
  Dist[(a+b*ArcCsch[u]),w,x] - b*u/Sqrt[-u^2]*Int[SimplifyIntegrand[w*D[u,x]/(u*Sqrt[-1-u^2]),x],x] /;
 InverseFunctionFreeQ[w,x]] /;
FreeQ[{a,b},x] && InverseFunctionFreeQ[u,x] && Not[MatchQ[v, (c_.+d_.*x)^m_. /; FreeQ[{c,d,m},x]]]