Rules for integrands involving Fresnel integral functions

1.  ∫((FresnelS[a+b x])^n)dx

1:  ∫FresnelS[a+b x]dx

Derivation: Integration by parts

Basis: (∂_x)FresnelS[a+b x]==b Sin[(π/2)(((a+b x))^2)]

Rule:

∫FresnelS[a+b x]dx  ⟶  (((a+b x) FresnelS[a+b x])/b)-∫(a+b x) Sin[(π/2)(((a+b x))^2)]dx  ⟶  (((a+b x) FresnelS[a+b x])/b)+((Cos[(π/2)(((a+b x))^2)])/(b π))

Program code:

Int[FresnelS[a_.+b_.*x_],x_Symbol] :=
  (a+b*x)*FresnelS[a+b*x]/b + Cos[Pi/2*(a+b*x)^2]/(b*Pi) /;
FreeQ[{a,b},x]

Int[FresnelC[a_.+b_.*x_],x_Symbol] :=
  (a+b*x)*FresnelC[a+b*x]/b - Sin[Pi/2*(a+b*x)^2]/(b*Pi) /;
FreeQ[{a,b},x]

2:  ∫((FresnelS[a+b x])^2)dx

Derivation: Integration by parts

Basis: (∂_x)((FresnelS[a+b x])^2)==2 b Sin[(π/2)(((a+b x))^2)] FresnelS[a+b x]

Rule:

∫((FresnelS[a+b x])^2)dx  ⟶  (((a+b x) ((FresnelS[a+b x])^2))/b)-2∫(a+b x) Sin[(π/2)(((a+b x))^2)] FresnelS[a+b x]dx

Program code:

Int[FresnelS[a_.+b_.*x_]^2,x_Symbol] :=
  (a+b*x)*FresnelS[a+b*x]^2/b -
  2*Int[(a+b*x)*Sin[Pi/2*(a+b*x)^2]*FresnelS[a+b*x],x] /;
FreeQ[{a,b},x]

Int[FresnelC[a_.+b_.*x_]^2,x_Symbol] :=
  (a+b*x)*FresnelC[a+b*x]^2/b -
  2*Int[(a+b*x)*Cos[Pi/2*(a+b*x)^2]*FresnelC[a+b*x],x] /;
FreeQ[{a,b},x]

X:  ∫((FresnelS[a+b x])^n)dx  when  n≠1 ∧ n≠2

Rule: If  n≠1 ∧ n≠2, then

∫((FresnelS[a+b x])^n)dx  ⟶  ∫((FresnelS[a+b x])^n)dx

Program code:

Int[FresnelS[a_.+b_.*x_]^n_,x_Symbol] :=
  Unintegrable[FresnelS[a+b*x]^n,x] /;
FreeQ[{a,b,n},x] && NeQ[n,1] && NeQ[n,2]

Int[FresnelC[a_.+b_.*x_]^n_,x_Symbol] :=
  Unintegrable[FresnelC[a+b*x]^n,x] /;
FreeQ[{a,b,n},x] && NeQ[n,1] && NeQ[n,2]

2.  ∫(((c+d x))^m) ((FresnelS[a+b x])^n)dx

1.  ∫(((c+d x))^m) FresnelS[a+b x]dx

1.  ∫(((d x))^m) FresnelS[b x]dx

1:  ∫((FresnelS[b x])/x)dx

Derivation: Algebraic expansion

Basis: FresnelS[b x]==((1+i)/4) Erf[((Sqrt[π])/2) (1+i) b x]+((1-i)/4) Erf[((Sqrt[π])/2) (1-i) b x]

Basis: FresnelC[b x]==((1-i)/4) Erf[((Sqrt[π])/2) (1+i) b x]+((1+i)/4) Erf[((Sqrt[π])/2) (1-i) b x]

Rule:

∫((FresnelS[b x])/x)dx  ⟶  ((1+i)/4) ∫((Erf[((Sqrt[π])/2) (1+i) b x])/x)dx+((1-i)/4) ∫((Erf[((Sqrt[π])/2) (1-i) b x])/x)dx

Program code:

Int[FresnelS[b_.*x_]/x_,x_Symbol] :=
  (1+I)/4*Int[Erf[Sqrt[Pi]/2*(1+I)*b*x]/x,x] + (1-I)/4*Int[Erf[Sqrt[Pi]/2*(1-I)*b*x]/x,x] /;
FreeQ[b,x]

Int[FresnelC[b_.*x_]/x_,x_Symbol] :=
  (1-I)/4*Int[Erf[Sqrt[Pi]/2*(1+I)*b*x]/x,x] + (1+I)/4*Int[Erf[Sqrt[Pi]/2*(1-I)*b*x]/x,x] /;
FreeQ[b,x]

2:  ∫(((d x))^m)FresnelS[b x]dx  when  m≠-1

Derivation: Integration by parts

Rule: If  m≠-1, then

∫(((d x))^m)FresnelS[b x]dx  ⟶  (((((d x))^(m+1)) FresnelS[b x])/(d (m+1)))-(b/(d (m+1)))∫(((d x))^(m+1)) Sin[(π/2) (b^2) (x^2)]dx

Program code:

Int[(d_.*x_)^m_.*FresnelS[b_.*x_],x_Symbol] :=
  (d*x)^(m+1)*FresnelS[b*x]/(d*(m+1)) - b/(d*(m+1))*Int[(d*x)^(m+1)*Sin[Pi/2*b^2*x^2],x] /;
FreeQ[{b,d,m},x] && NeQ[m,-1]

Int[(d_.*x_)^m_.*FresnelC[b_.*x_],x_Symbol] :=
  (d*x)^(m+1)*FresnelC[b*x]/(d*(m+1)) - b/(d*(m+1))*Int[(d*x)^(m+1)*Cos[Pi/2*b^2*x^2],x] /;
FreeQ[{b,d,m},x] && NeQ[m,-1]

2:  ∫(((c+d x))^m)FresnelS[a+b x]dx  when  m∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (∂_x)FresnelS[a+b x]==b Sin[(π/2)(((a+b x))^2)]

Rule: If  m∈(SuperPlus[ℤ]), then

∫(((c+d x))^m)FresnelS[a+b x]dx  ⟶  (((((c+d x))^(m+1)) FresnelS[a+b x])/(d (m+1)))-(b/(d (m+1)))∫(((c+d x))^(m+1)) Sin[(π/2)(((a+b x))^2)]dx

Program code:

Int[(c_.+d_.*x_)^m_.*FresnelS[a_.+b_.*x_],x_Symbol] :=
  (c+d*x)^(m+1)*FresnelS[a+b*x]/(d*(m+1)) - 
  b/(d*(m+1))*Int[(c+d*x)^(m+1)*Sin[Pi/2*(a+b*x)^2],x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0]

Int[(c_.+d_.*x_)^m_.*FresnelC[a_.+b_.*x_],x_Symbol] :=
  (c+d*x)^(m+1)*FresnelC[a+b*x]/(d*(m+1)) - 
  b/(d*(m+1))*Int[(c+d*x)^(m+1)*Cos[Pi/2*(a+b*x)^2],x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0]

2.  ∫(((c+d x))^m) ((FresnelS[a+b x])^2)dx

1:  ∫(x^m) ((FresnelS[b x])^2)dx  when  m∈ℤ ∧ m≠-1

Derivation: Integration by parts

Basis: (∂_x)((FresnelS[b x])^2)==2 b Sin[(π/2)(b^2) (x^2)] FresnelS[b x]

Rule: If  m∈ℤ ∧ m≠-1, then

∫(x^m) ((FresnelS[b x])^2)dx  ⟶  (((x^(m+1)) ((FresnelS[b x])^2))/(m+1))-((2 b)/(m+1))∫(x^(m+1)) Sin[(π/2)(b^2) (x^2)] FresnelS[b x]dx

Program code:

Int[x_^m_.*FresnelS[b_.*x_]^2,x_Symbol] :=
  x^(m+1)*FresnelS[b*x]^2/(m+1) -
  2*b/(m+1)*Int[x^(m+1)*Sin[Pi/2*b^2*x^2]*FresnelS[b*x],x] /;
FreeQ[b,x] && IntegerQ[m] && NeQ[m,-1]

Int[x_^m_.*FresnelC[b_.*x_]^2,x_Symbol] :=
  x^(m+1)*FresnelC[b*x]^2/(m+1) -
  2*b/(m+1)*Int[x^(m+1)*Cos[Pi/2*b^2*x^2]*FresnelC[b*x],x] /;
FreeQ[b,x] && IntegerQ[m] && NeQ[m,-1]

2:  ∫(((c+d x))^m) ((FresnelS[a+b x])^2)dx  when  m∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Rule: If  m∈(SuperPlus[ℤ]), then

∫(((c+d x))^m) ((FresnelS[a+b x])^2)dx  ⟶  (1/(b^(m+1))) Subst[∫((FresnelS[x])^2) ExpandIntegrand[(((b c-a d+d x))^m),x]dx,x,a+b x]

Program code:

Int[(c_.+d_.*x_)^m_.*FresnelS[a_+b_.*x_]^2,x_Symbol] :=
  1/b^(m+1)*Subst[Int[ExpandIntegrand[FresnelS[x]^2,(b*c-a*d+d*x)^m,x],x],x,a+b*x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0]

Int[(c_.+d_.*x_)^m_.*FresnelC[a_+b_.*x_]^2,x_Symbol] :=
  1/b^(m+1)*Subst[Int[ExpandIntegrand[FresnelC[x]^2,(b*c-a*d+d*x)^m,x],x],x,a+b*x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0]

X:  ∫(((c+d x))^m) ((FresnelS[a+b x])^n)dx

Rule:

∫(((c+d x))^m) ((FresnelS[a+b x])^n)dx  ⟶  ∫(((c+d x))^m) ((FresnelS[a+b x])^n)dx

Program code:

Int[(c_.+d_.*x_)^m_.*FresnelS[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(c+d*x)^m*FresnelS[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,m,n},x]

Int[(c_.+d_.*x_)^m_.*FresnelC[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(c+d*x)^m*FresnelC[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,m,n},x]

3.  ∫(e^(c+d (x^2))) ((FresnelS[a+b x])^n)dx

1:  ∫(e^(c+d (x^2))) FresnelS[b x]dx  when  (d^2)==-((π^2)/4) (b^4)

Derivation: Algebraic expansion

Basis: FresnelS[b x]==((1+i)/4) Erf[((Sqrt[π])/2) (1+i) b x]+((1-i)/4) Erf[((Sqrt[π])/2) (1-i) b x]

Basis: FresnelC[b x]==((1-i)/4) Erf[((Sqrt[π])/2) (1+i) b x]+((1+i)/4) Erf[((Sqrt[π])/2) (1-i) b x]

Note: If  (d^2)==-((π^2)/4) (b^4), then resulting integrands are integrable.

Rule:

∫(e^(c+d (x^2))) FresnelS[b x]dx  ⟶  ((1+i)/4) ∫(e^(c+d (x^2))) Erf[((Sqrt[π])/2) (1+i) b x]dx+((1-i)/4) ∫(e^(c+d (x^2))) Erf[((Sqrt[π])/2) (1-i) b x]dx

Program code:

Int[E^(c_.+d_.*x_^2)*FresnelS[b_.*x_],x_Symbol] :=
  (1+I)/4*Int[E^(c+d*x^2)*Erf[Sqrt[Pi]/2*(1+I)*b*x],x] + (1-I)/4*Int[E^(c+d*x^2)*Erf[Sqrt[Pi]/2*(1-I)*b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,-Pi^2/4*b^4]

Int[E^(c_.+d_.*x_^2)*FresnelC[b_.*x_],x_Symbol] :=
  (1-I)/4*Int[E^(c+d*x^2)*Erf[Sqrt[Pi]/2*(1+I)*b*x],x] + (1+I)/4*Int[E^(c+d*x^2)*Erf[Sqrt[Pi]/2*(1-I)*b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,-Pi^2/4*b^4]

X:  ∫(e^(c+d (x^2))) ((FresnelS[a+b x])^n)dx

Rule:

∫(e^(c+d (x^2))) ((FresnelS[a+b x])^n)dx  ⟶  ∫(e^(c+d (x^2))) ((FresnelS[a+b x])^n)dx

Program code:

Int[E^(c_.+d_.*x_^2)*FresnelS[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[E^(c+d*x^2)*FresnelS[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x]

Int[E^(c_.+d_.*x_^2)*FresnelC[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[E^(c+d*x^2)*FresnelC[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x]

4.  ∫Sin[c+d (x^2)] ((FresnelS[a+b x])^n)dx

1:  ∫Sin[d (x^2)] ((FresnelS[b x])^n)dx  when  (d^2)==((π^2)/4) (b^4)

Derivation: Integration by substitution

Basis: If  (d^2)==((π^2)/4) (b^4), then Sin[d (x^2)] F[FresnelS[b x]]==((π b)/(2 d)) Subst[F[x],x,FresnelS[b x]] (∂_x)FresnelS[b x]

Rule: If  (d^2)==((π^2)/4) (b^4), then

∫Sin[d (x^2)] ((FresnelS[b x])^n)dx  ⟶  ((π b)/(2 d)) Subst[∫(x^n)dx,x,FresnelS[b x]]

Program code:

Int[Sin[d_.*x_^2]*FresnelS[b_.*x_]^n_.,x_Symbol] :=
  Pi*b/(2*d)*Subst[Int[x^n,x],x,FresnelS[b*x]] /;
FreeQ[{b,d,n},x] && EqQ[d^2,Pi^2/4*b^4]

Int[Cos[d_.*x_^2]*FresnelC[b_.*x_]^n_.,x_Symbol] :=
  Pi*b/(2*d)*Subst[Int[x^n,x],x,FresnelC[b*x]] /;
FreeQ[{b,d,n},x] && EqQ[d^2,Pi^2/4*b^4]

2:  ∫Sin[c+d (x^2)] FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4)

Derivation: Algebraic expansion

Basis: Sin[c+d (x^2)]==Sin[c] Cos[d (x^2)]+Cos[c] Sin[d (x^2)]

Rule: If  (d^2)==((π^2)/4) (b^4), then

∫Sin[c+d (x^2)] FresnelS[b x]dx  ⟶  Sin[c] ∫Cos[d (x^2)] FresnelS[b x]dx+Cos[c] ∫Sin[d (x^2)] FresnelS[b x]dx

Program code:

Int[Sin[c_+d_.*x_^2]*FresnelS[b_.*x_],x_Symbol] :=
  Sin[c]*Int[Cos[d*x^2]*FresnelS[b*x],x] + Cos[c]*Int[Sin[d*x^2]*FresnelS[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,Pi^2/4*b^4]

Int[Cos[c_+d_.*x_^2]*FresnelC[b_.*x_],x_Symbol] :=
  Cos[c]*Int[Cos[d*x^2]*FresnelC[b*x],x] - Sin[c]*Int[Sin[d*x^2]*FresnelC[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,Pi^2/4*b^4]

X:  ∫Sin[c+d (x^2)] ((FresnelS[a+b x])^n)dx

Rule:

∫Sin[c+d (x^2)] ((FresnelS[a+b x])^n)dx  ⟶  ∫Sin[c+d (x^2)] ((FresnelS[a+b x])^n)dx

Program code:

Int[Sin[c_.+d_.*x_^2]*FresnelS[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[Sin[c+d*x^2]*FresnelS[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x]

Int[Cos[c_.+d_.*x_^2]*FresnelC[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[Cos[c+d*x^2]*FresnelC[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x]

5.  ∫Cos[c+d (x^2)] ((FresnelS[a+b x])^n)dx

1:  ∫Cos[d (x^2)] FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4)

Derivation: Algebraic expansion

Rule: If  (d^2)==((π^2)/4) (b^4), then

∫Cos[d (x^2)] FresnelS[b x]dx  ⟶  
((FresnelC[b x] FresnelS[b x])/(2 b))-(1/8) i b (x^2) HypergeometricPFQ[{1,1},{(3/2),2},-(1/2) i (b^2) π (x^2)]+(1/8) i b (x^2) HypergeometricPFQ[{1,1},{(3/2),2},(1/2) i (b^2) π (x^2)]

Program code:

Int[Cos[d_.*x_^2]*FresnelS[b_.*x_],x_Symbol] :=
  FresnelC[b*x]*FresnelS[b*x]/(2*b) - 
  1/8*I*b*x^2*HypergeometricPFQ[{1,1},{3/2,2},-1/2*I*b^2*Pi*x^2] + 
  1/8*I*b*x^2*HypergeometricPFQ[{1,1},{3/2,2},1/2*I*b^2*Pi*x^2] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4]

Int[Sin[d_.*x_^2]*FresnelC[b_.*x_],x_Symbol] :=
  b*Pi*FresnelC[b*x]*FresnelS[b*x]/(4*d) + 
  1/8*I*b*x^2*HypergeometricPFQ[{1,1},{3/2,2},-I*d*x^2] - 
  1/8*I*b*x^2*HypergeometricPFQ[{1,1},{3/2,2},I*d*x^2] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4]

2:  ∫Cos[c+d (x^2)] FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4)

Derivation: Algebraic expansion

Basis: Cos[c+d (x^2)]==Cos[c] Cos[d (x^2)]-Sin[c] Sin[d (x^2)]

Rule: If  (d^2)==((π^2)/4) (b^4), then

∫Cos[c+d (x^2)] FresnelS[b x]dx  ⟶  Cos[c] ∫Cos[d (x^2)] FresnelS[b x]dx-Sin[c] ∫Sin[d (x^2)] FresnelS[b x]dx

Program code:

Int[Cos[c_+d_.*x_^2]*FresnelS[b_.*x_],x_Symbol] :=
  Cos[c]*Int[Cos[d*x^2]*FresnelS[b*x],x] - Sin[c]*Int[Sin[d*x^2]*FresnelS[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,Pi^2/4*b^4]

Int[Sin[c_+d_.*x_^2]*FresnelC[b_.*x_],x_Symbol] :=
  Sin[c]*Int[Cos[d*x^2]*FresnelC[b*x],x] + Cos[c]*Int[Sin[d*x^2]*FresnelC[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,Pi^2/4*b^4]

X:  ∫Cos[c+d (x^2)] ((FresnelS[a+b x])^n)dx

Rule:

∫Cos[c+d (x^2)] ((FresnelS[a+b x])^n)dx  ⟶  ∫Cos[c+d (x^2)] ((FresnelS[a+b x])^n)dx

Program code:

Int[Cos[c_.+d_.*x_^2]*FresnelS[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[Cos[c+d*x^2]*FresnelS[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x]

Int[Sin[c_.+d_.*x_^2]*FresnelC[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[Sin[c+d*x^2]*FresnelC[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x]

6.  ∫(((e x))^m) Sin[c+d (x^2)]((FresnelS[a+b x])^n)dx

1.  ∫(x^m) Sin[d (x^2)]FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4) ∧ m∈ℤ

1.  ∫(x^m) Sin[d (x^2)]FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4) ∧ m∈(SuperPlus[ℤ])

1:  ∫x Sin[d (x^2)]FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4)

Derivation: Integration by parts and algebraic simplification

Basis: -(∂_x)((Cos[d (x^2)])/(2 d))==x Sin[d (x^2)]

Basis: If  (d^2)==((π^2)/4) (b^4), then Cos[d (x^2)] Sin[(1/2) (b^2) π (x^2)]==(d/((b^2) π)) Sin[2 d (x^2)]

Rule: If  (d^2)==((π^2)/4) (b^4), then

∫x Sin[d (x^2)]FresnelS[b x]dx  ⟶  -((Cos[d (x^2)]FresnelS[b x])/(2 d))+(1/(2 b Pi))∫Sin[2 d (x^2)]dx

Basis: (∂_x)((Sin[d (x^2)])/(2 d))==x Cos[d (x^2)]

Basis: If  (d^2)==((π^2)/4) (b^4), then Sin[d (x^2)] Cos[(1/2) (b^2) π (x^2)]==(1/2) Sin[2 d (x^2)]

Rule: If  (d^2)==((π^2)/4) (b^4), then

∫x Cos[d (x^2)]FresnelC[b x]dx  ⟶  ((Sin[d (x^2)]FresnelC[b x])/(2 d))-(b/(4 d))∫Sin[2 d (x^2)]dx

Program code:

Int[x_*Sin[d_.*x_^2]*FresnelS[b_.*x_],x_Symbol] :=
  -Cos[d*x^2]*FresnelS[b*x]/(2*d) + 1/(2*b*Pi)*Int[Sin[2*d*x^2],x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4]

Int[x_*Cos[d_.*x_^2]*FresnelC[b_.*x_],x_Symbol] :=
  Sin[d*x^2]*FresnelC[b*x]/(2*d) - b/(4*d)*Int[Sin[2*d*x^2],x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4]

2:  ∫(x^m) Sin[d (x^2)]FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4) ∧ m-1∈(SuperPlus[ℤ])

Derivation: Integration by parts and algebraic simplification

Basis: -(∂_x)((Cos[d (x^2)])/(2 d))==x Sin[d (x^2)]

Basis: If  (d^2)==((π^2)/4) (b^4), then Cos[d (x^2)] Sin[(1/2) (b^2) π (x^2)]==(d/((b^2) π)) Sin[2 d (x^2)]

Rule: If  (d^2)==((π^2)/4) (b^4) ∧ m-1∈(SuperPlus[ℤ]), then

∫(x^m) Sin[d (x^2)]FresnelS[b x]dx  ⟶  
-(((x^(m-1)) Cos[d (x^2)]FresnelS[b x])/(2 d))+(1/(2 b Pi))∫(x^(m-1))Sin[2 d (x^2)]dx+((m-1)/(2 d))∫(x^(m-2)) Cos[d (x^2)]FresnelS[b x]dx

Basis: (∂_x)((Sin[d (x^2)])/(2 d))==x Cos[d (x^2)]

Basis: If  (d^2)==((π^2)/4) (b^4), then Sin[d (x^2)] Cos[(1/2) (b^2) π (x^2)]==(1/2) Sin[2 d (x^2)]

Rule: If  (d^2)==((π^2)/4) (b^4) ∧ m-1∈(SuperPlus[ℤ]), then

∫(x^m) Cos[d (x^2)]FresnelC[b x]dx  ⟶  
(((x^(m-1)) Sin[d (x^2)]FresnelC[b x])/(2 d))-(b/(4 d))∫(x^(m-1)) Sin[2 d (x^2)]dx-((m-1)/(2 d))∫(x^(m-2)) Sin[d (x^2)]FresnelC[b x]dx

Program code:

Int[x_^m_*Sin[d_.*x_^2]*FresnelS[b_.*x_],x_Symbol] :=
  -x^(m-1)*Cos[d*x^2]*FresnelS[b*x]/(2*d) + 
  1/(2*b*Pi)*Int[x^(m-1)*Sin[2*d*x^2],x] + 
  (m-1)/(2*d)*Int[x^(m-2)*Cos[d*x^2]*FresnelS[b*x],x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4] && IGtQ[m,1]

Int[x_^m_*Cos[d_.*x_^2]*FresnelC[b_.*x_],x_Symbol] :=
  x^(m-1)*Sin[d*x^2]*FresnelC[b*x]/(2*d) - 
  b/(4*d)*Int[x^(m-1)*Sin[2*d*x^2],x] - 
  (m-1)/(2*d)*Int[x^(m-2)*Sin[d*x^2]*FresnelC[b*x],x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4] && IGtQ[m,1]

2:  ∫(x^m) Sin[d (x^2)]FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4) ∧ m+2∈(SuperMinus[ℤ])

Derivation: Inverted integration by parts

Rule: If  (d^2)==((π^2)/4) (b^4) ∧ m+2∈(SuperMinus[ℤ]), then

∫(x^m) Sin[d (x^2)]FresnelS[b x]dx  ⟶  
(((x^(m+1)) Sin[d (x^2)]FresnelS[b x])/(m+1))-((d (x^(m+2)))/(π b (m+1) (m+2)))+(d/(π b (m+1)))∫(x^(m+1))Cos[2 d (x^2)]dx-((2 d)/(m+1))∫(x^(m+2)) Cos[d (x^2)]FresnelS[b x]dx

∫(x^m) Cos[d (x^2)]FresnelC[b x]dx  ⟶  
(((x^(m+1)) Cos[d (x^2)]FresnelC[b x])/(m+1))-((b (x^(m+2)))/(2 (m+1) (m+2)))-(b/(2 (m+1)))∫(x^(m+1))Cos[2 d (x^2)]dx+((2 d)/(m+1))∫(x^(m+2)) Sin[d (x^2)]FresnelC[b x]dx

Program code:

Int[x_^m_*Sin[d_.*x_^2]*FresnelS[b_.*x_],x_Symbol] :=
  x^(m+1)*Sin[d*x^2]*FresnelS[b*x]/(m+1) - 
  d*x^(m+2)/(Pi*b*(m+1)*(m+2)) + 
  d/(Pi*b*(m+1))*Int[x^(m+1)*Cos[2*d*x^2],x] - 
  2*d/(m+1)*Int[x^(m+2)*Cos[d*x^2]*FresnelS[b*x],x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4] && ILtQ[m,-2]

Int[x_^m_*Cos[d_.*x_^2]*FresnelC[b_.*x_],x_Symbol] :=
  x^(m+1)*Cos[d*x^2]*FresnelC[b*x]/(m+1) - 
  b*x^(m+2)/(2*(m+1)*(m+2)) - 
  b/(2*(m+1))*Int[x^(m+1)*Cos[2*d*x^2],x] + 
  2*d/(m+1)*Int[x^(m+2)*Sin[d*x^2]*FresnelC[b*x],x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4] && ILtQ[m,-2]

X:  ∫(((e x))^m) Sin[c+d (x^2)] ((FresnelS[a+b x])^n)dx

Rule:

∫(((e x))^m) Sin[c+d (x^2)] ((FresnelS[a+b x])^n)dx  ⟶  ∫(((e x))^m) Sin[c+d (x^2)] ((FresnelS[a+b x])^n)dx

Program code:

Int[(e_.*x_)^m_.*Sin[c_.+d_.*x_^2]*FresnelS[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(e*x)^m*Sin[c+d*x^2]*FresnelS[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,e,m,n},x]

Int[(e_.*x_)^m_.*Cos[c_.+d_.*x_^2]*FresnelC[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(e*x)^m*Cos[c+d*x^2]*FresnelC[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,e,m,n},x]

7.  ∫(((e x))^m) Cos[c+d (x^2)]((FresnelS[a+b x])^n)dx

1.  ∫(x^m) Cos[d (x^2)]FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4) ∧ m∈ℤ

1.  ∫(x^m) Cos[d (x^2)]FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4) ∧ m∈(SuperPlus[ℤ])

1:  ∫x Cos[d (x^2)]FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4)

Derivation: Integration by parts and algebraic simplification

Basis: (∂_x)((Sin[d (x^2)])/(2 d))==x Cos[d (x^2)]

Basis: If  (d^2)==((π^2)/4) (b^4), then Sin[d (x^2)] Sin[(1/2) (b^2) π (x^2)]==((2 d)/(π (b^2))) ((Sin[d (x^2)])^2)

Rule: If  (d^2)==((π^2)/4) (b^4), then

∫x Cos[d (x^2)]FresnelS[b x]dx  ⟶  ((Sin[d (x^2)]FresnelS[b x])/(2 d))-(1/(π b))∫((Sin[d (x^2)])^2)dx

Basis: -(∂_x)((Cos[d (x^2)])/(2 d))==x Sin[d (x^2)]

Basis: If  (d^2)==((π^2)/4) (b^4), then Cos[d (x^2)] Cos[(1/2) (b^2) π (x^2)]==((Cos[d (x^2)])^2)

Rule: If  (d^2)==((π^2)/4) (b^4), then

∫x Sin[d (x^2)]FresnelC[b x]dx  ⟶  -((Cos[d (x^2)]FresnelC[b x])/(2 d))+(b/(2 d))∫((Cos[d (x^2)])^2)dx

Program code:

Int[x_*Cos[d_.*x_^2]*FresnelS[b_.*x_],x_Symbol] :=
  Sin[d*x^2]*FresnelS[b*x]/(2*d) - 1/(Pi*b)*Int[Sin[d*x^2]^2,x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4]

Int[x_*Sin[d_.*x_^2]*FresnelC[b_.*x_],x_Symbol] :=
  -Cos[d*x^2]*FresnelC[b*x]/(2*d) + b/(2*d)*Int[Cos[d*x^2]^2,x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4]

2:  ∫(x^m) Cos[d (x^2)]FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4) ∧ m-1∈(SuperPlus[ℤ])

Derivation: Integration by parts and algebraic simplification

Basis: (∂_x)((Sin[d (x^2)])/(2 d))==x Cos[d (x^2)]

Basis: If  (d^2)==((π^2)/4) (b^4), then Sin[d (x^2)] Sin[(1/2) (b^2) π (x^2)]==((2 d)/(π (b^2))) ((Sin[d (x^2)])^2)

Rule: If  (d^2)==((π^2)/4) (b^4) ∧ m-1∈(SuperPlus[ℤ]), then

∫(x^m) Cos[d (x^2)]FresnelS[b x]dx  ⟶  
(((x^(m-1)) Sin[d (x^2)]FresnelS[b x])/(2 d))-(1/(π b))∫(x^(m-1))((Sin[d (x^2)])^2)dx-((m-1)/(2 d))∫(x^(m-2)) Sin[d (x^2)]FresnelS[b x]dx

Basis: -(∂_x)((Cos[d (x^2)])/(2 d))==x Sin[d (x^2)]

Basis: If  (d^2)==((π^2)/4) (b^4), then Cos[d (x^2)] Cos[(1/2) (b^2) π (x^2)]==((Cos[d (x^2)])^2)

Rule: If  (d^2)==((π^2)/4) (b^4), then

∫(x^m) Sin[d (x^2)]FresnelC[b x]dx  ⟶  
-(((x^(m-1)) Cos[d (x^2)]FresnelC[b x])/(2 d))+(b/(2 d))∫(x^(m-1)) ((Cos[d (x^2)])^2)dx+((m-1)/(2 d))∫(x^(m-2)) Cos[d (x^2)]FresnelC[b x]dx

Program code:

Int[x_^m_*Cos[d_.*x_^2]*FresnelS[b_.*x_],x_Symbol] :=
  x^(m-1)*Sin[d*x^2]*FresnelS[b*x]/(2*d) - 
  1/(Pi*b)*Int[x^(m-1)*Sin[d*x^2]^2,x] - 
  (m-1)/(2*d)*Int[x^(m-2)*Sin[d*x^2]*FresnelS[b*x],x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4] && IGtQ[m,1]

Int[x_^m_*Sin[d_.*x_^2]*FresnelC[b_.*x_],x_Symbol] :=
  -x^(m-1)*Cos[d*x^2]*FresnelC[b*x]/(2*d) + 
  b/(2*d)*Int[x^(m-1)*Cos[d*x^2]^2,x] + 
  (m-1)/(2*d)*Int[x^(m-2)*Cos[d*x^2]*FresnelC[b*x],x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4] && IGtQ[m,1]

2:  ∫(x^m) Cos[d (x^2)]FresnelS[b x]dx  when  (d^2)==((π^2)/4) (b^4) ∧ m+1∈(SuperMinus[ℤ])

Derivation: Inverted integration by parts

Rule: If  (d^2)==((π^2)/4) (b^4) ∧ m+1∈(SuperMinus[ℤ]), then

∫(x^m) Cos[d (x^2)]FresnelS[b x]dx  ⟶  
(((x^(m+1)) Cos[d (x^2)]FresnelS[b x])/(m+1))-(( d)/(π b (m+1)))∫(x^(m+1))Sin[2 d (x^2)]dx+((2 d)/(m+1))∫(x^(m+2)) Sin[d (x^2)]FresnelS[b x]dx

∫(x^m) Sin[d (x^2)]FresnelC[b x]dx  ⟶  
(((x^(m+1)) Sin[d (x^2)]FresnelC[b x])/(m+1))-(( b)/(2 (m+1)))∫(x^(m+1))Sin[2 d (x^2)]dx-((2 d)/(m+1))∫(x^(m+2)) Cos[d (x^2)]FresnelC[b x]dx

Program code:

Int[x_^m_*Cos[d_.*x_^2]*FresnelS[b_.*x_],x_Symbol] :=
  x^(m+1)*Cos[d*x^2]*FresnelS[b*x]/(m+1) - 
  d/(Pi*b*(m+1))*Int[x^(m+1)*Sin[2*d*x^2],x] + 
  2*d/(m+1)*Int[x^(m+2)*Sin[d*x^2]*FresnelS[b*x],x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4] && ILtQ[m,-1]

Int[x_^m_*Sin[d_.*x_^2]*FresnelC[b_.*x_],x_Symbol] :=
  x^(m+1)*Sin[d*x^2]*FresnelC[b*x]/(m+1) - 
  b/(2*(m+1))*Int[x^(m+1)*Sin[2*d*x^2],x] - 
  2*d/(m+1)*Int[x^(m+2)*Cos[d*x^2]*FresnelC[b*x],x] /;
FreeQ[{b,d},x] && EqQ[d^2,Pi^2/4*b^4] && ILtQ[m,-1]

X:  ∫(((e x))^m) Cos[c+d (x^2)] ((FresnelS[a+b x])^n)dx

Rule:

∫(((e x))^m) Cos[c+d (x^2)] ((FresnelS[a+b x])^n)dx  ⟶  ∫(((e x))^m) Cos[c+d (x^2)] ((FresnelS[a+b x])^n)dx

Program code:

Int[(e_.*x_)^m_.*Cos[c_.+d_.*x_^2]*FresnelS[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(e*x)^m*Cos[c+d*x^2]*FresnelS[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,e,m,n},x]

Int[(e_.*x_)^m_.*Sin[c_.+d_.*x_^2]*FresnelC[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(e*x)^m*Sin[c+d*x^2]*FresnelC[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,e,m,n},x]

8.  ∫u FresnelS[d (a+b Log[c (x^n)])]dx

1:  ∫FresnelS[d (a+b Log[c (x^n)])]dx

Derivation: Integration by parts

Basis: (∂_x)FresnelS[d (a+b Log[c (x^n)])]==((b d n Sin[(π/2) (((d (a+b Log[c (x^n)])))^2)])/x)

Rule:

∫FresnelS[d (a+b Log[c (x^n)])]dx  ⟶  x FresnelS[d (a+b Log[c (x^n)])]-b d n ∫Sin[(π/2) (((d (a+b Log[c (x^n)])))^2)]dx

Program code:

Int[FresnelS[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  x*FresnelS[d*(a+b*Log[c*x^n])] - b*d*n*Int[Sin[Pi/2*(d*(a+b*Log[c*x^n]))^2],x] /;
FreeQ[{a,b,c,d,n},x]

Int[FresnelC[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  x*FresnelC[d*(a+b*Log[c*x^n])] - b*d*n*Int[Cos[Pi/2*(d*(a+b*Log[c*x^n]))^2],x] /;
FreeQ[{a,b,c,d,n},x]

2:  ∫((FresnelS[d (a+b Log[c (x^n)])])/x)dx

Derivation: Integration by substitution

Basis: ((F[Log[c (x^n)]])/x)==(1/n) Subst[F[x],x,Log[c (x^n)]] (∂_x)Log[c (x^n)]

Rule:

∫((FresnelS[d (a+b Log[c (x^n)])])/x)dx  ⟶  (1/n) Subst[FresnelS[d (a+b x)],x,Log[c (x^n)]]

Program code:

Int[F_[d_.*(a_.+b_.*Log[c_.*x_^n_.])]/x_,x_Symbol] :=
  1/n*Subst[F[d*(a+b*x)],x,Log[c*x^n]] /;
FreeQ[{a,b,c,d,n},x] && MemberQ[{FresnelS,FresnelC},F]

3:  ∫(((e x))^m) FresnelS[d (a+b Log[c (x^n)])]dx  when  m≠-1

Derivation: Integration by parts

Basis: (∂_x)FresnelS[d (a+b Log[c (x^n)])]==((b d n Sin[(π/2) (((d (a+b Log[c (x^n)])))^2)])/x)

Rule: If  m≠-1, then

∫(((e x))^m) FresnelS[d (a+b Log[c (x^n)])]dx  ⟶  (((((e x))^(m+1)) FresnelS[d (a+b Log[c (x^n)])])/(e (m+1)))-((b d n)/(m+1)) ∫(((e x))^m) Sin[(π/2) (((d (a+b Log[c (x^n)])))^2)]dx

Program code:

Int[(e_.*x_)^m_.*FresnelS[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  (e*x)^(m+1)*FresnelS[d*(a+b*Log[c*x^n])]/(e*(m+1)) - 
  b*d*n/(m+1)*Int[(e*x)^m*Sin[Pi/2*(d*(a+b*Log[c*x^n]))^2],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[m,-1]

Int[(e_.*x_)^m_.*FresnelC[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  (e*x)^(m+1)*FresnelC[d*(a+b*Log[c*x^n])]/(e*(m+1)) - 
  b*d*n/(m+1)*Int[(e*x)^m*Cos[Pi/2*(d*(a+b*Log[c*x^n]))^2],x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[m,-1]