Rules for integrands involving hyperbolic integral functions

1.  ∫u SinhIntegral[a+b x]dx

1:  ∫SinhIntegral[a+b x]dx

Derivation: Integration by parts

Rule:

∫SinhIntegral[a+b x]dx  ⟶  (((a+b x) SinhIntegral[a+b x])/b)-((Cosh[a+b x])/b)

Program code:

Int[SinhIntegral[a_.+b_.*x_],x_Symbol] :=
  (a+b*x)*SinhIntegral[a+b*x]/b - Cosh[a+b*x]/b/;
FreeQ[{a,b},x]

Int[CoshIntegral[a_.+b_.*x_],x_Symbol] :=
  (a+b*x)*CoshIntegral[a+b*x]/b - Sinh[a+b*x]/b /;
FreeQ[{a,b},x]

2.  ∫(((c+d x))^m) SinhIntegral[a+b x]dx

1:  ∫((SinhIntegral[b x])/x)dx

Basis: SinhIntegral[z]==-(1/2) (ExpIntegralE[1,-z]-ExpIntegralE[1,z]+Log[-z]-Log[z])

Basis: CoshIntegral[z]==-(1/2) (ExpIntegralE[1,-z]+ExpIntegralE[1,z]+Log[-z]-Log[z])

Rule:

∫((SinhIntegral[b x])/x)dx  ⟶  
(1/2) b x HypergeometricPFQ[{1,1,1},{2,2,2},-b x]+(1/2) b x HypergeometricPFQ[{1,1,1},{2,2,2},b x]

Program code:

Int[SinhIntegral[b_.*x_]/x_,x_Symbol] :=
  1/2*b*x*HypergeometricPFQ[{1,1,1},{2,2,2},-b*x] + 
  1/2*b*x*HypergeometricPFQ[{1,1,1},{2,2,2},b*x] /;
FreeQ[b,x]

Int[CoshIntegral[b_.*x_]/x_,x_Symbol] :=
  -1/2*b*x*HypergeometricPFQ[{1,1,1},{2,2,2},-b*x] + 
  1/2*b*x*HypergeometricPFQ[{1,1,1},{2,2,2},b*x] + 
  EulerGamma*Log[x] + 
  1/2*Log[b*x]^2 /;
FreeQ[b,x]

2:  ∫(((c+d x))^m) SinhIntegral[a+b x]dx  when  m≠-1

Derivation: Integration by parts

Rule: If  m≠-1, then

∫(((c+d x))^m) SinhIntegral[a+b x]dx  ⟶  (((((c+d x))^(m+1)) SinhIntegral[a+b x])/(d (m+1)))-(b/(d (m+1)))∫(((((c+d x))^(m+1)) Sinh[a+b x])/(a+b x))dx

Program code:

Int[(c_.+d_.*x_)^m_.*SinhIntegral[a_.+b_.*x_],x_Symbol] :=
  (c+d*x)^(m+1)*SinhIntegral[a+b*x]/(d*(m+1)) - 
  b/(d*(m+1))*Int[(c+d*x)^(m+1)*Sinh[a+b*x]/(a+b*x),x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1]

Int[(c_.+d_.*x_)^m_.*CoshIntegral[a_.+b_.*x_],x_Symbol] :=
  (c+d*x)^(m+1)*CoshIntegral[a+b*x]/(d*(m+1)) - 
  b/(d*(m+1))*Int[(c+d*x)^(m+1)*Cosh[a+b*x]/(a+b*x),x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1]

2.  ∫u ((SinhIntegral[a+b x])^2)dx

1:  ∫((SinhIntegral[a+b x])^2)dx

Derivation: Integration by parts

Rule:

∫((SinhIntegral[a+b x])^2)dx  ⟶  (((a+b x) ((SinhIntegral[a+b x])^2))/b)-2∫Sinh[a+b x] SinhIntegral[a+b x]dx

Program code:

Int[SinhIntegral[a_.+b_.*x_]^2,x_Symbol] :=
  (a+b*x)*SinhIntegral[a+b*x]^2/b -
  2*Int[Sinh[a+b*x]*SinhIntegral[a+b*x],x] /;
FreeQ[{a,b},x]

Int[CoshIntegral[a_.+b_.*x_]^2,x_Symbol] :=
  (a+b*x)*CoshIntegral[a+b*x]^2/b -
  2*Int[Cosh[a+b*x]*CoshIntegral[a+b*x],x] /;
FreeQ[{a,b},x]

2.  ∫(((c+d x))^m) ((SinhIntegral[a+b x])^2)dx

1:  ∫(x^m) ((SinhIntegral[b x])^2)dx  when  m∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  m∈(SuperPlus[ℤ]), then

∫(x^m) ((SinhIntegral[b x])^2)dx  ⟶  (((x^(m+1)) ((SinhIntegral[b x])^2))/(m+1))-(2/(m+1))∫(x^m) Sinh[b x] SinhIntegral[b x]dx

Program code:

Int[x_^m_.*SinhIntegral[b_.*x_]^2,x_Symbol] :=
  x^(m+1)*SinhIntegral[b*x]^2/(m+1) -
  2/(m+1)*Int[x^m*Sinh[b*x]*SinhIntegral[b*x],x] /;
FreeQ[b,x] && IGtQ[m,0]

Int[x_^m_.*CoshIntegral[b_.*x_]^2,x_Symbol] :=
  x^(m+1)*CoshIntegral[b*x]^2/(m+1) -
  2/(m+1)*Int[x^m*Cosh[b*x]*CoshIntegral[b*x],x] /;
FreeQ[b,x] && IGtQ[m,0]

2:  ∫(((c+d x))^m) ((SinhIntegral[a+b x])^2)dx  when  m∈(SuperPlus[ℤ])

Derivation: Iterated integration by parts

Rule: If  m∈(SuperPlus[ℤ]), then

∫(((c+d x))^m) ((SinhIntegral[a+b x])^2)dx  ⟶  

(((a+b x) (((c+d x))^m) ((SinhIntegral[a+b x])^2))/(b (m+1)))-
(2/(m+1))∫(((c+d x))^m) Sinh[a+b x] SinhIntegral[a+b x]dx+(((b c-a d) m)/(b (m+1)))∫(((c+d x))^(m-1)) ((SinhIntegral[a+b x])^2)dx

Program code:

Int[(c_.+d_.*x_)^m_.*SinhIntegral[a_+b_.*x_]^2,x_Symbol] :=
  (a+b*x)*(c+d*x)^m*SinhIntegral[a+b*x]^2/(b*(m+1)) - 
  2/(m+1)*Int[(c+d*x)^m*Sinh[a+b*x]*SinhIntegral[a+b*x],x] + 
  (b*c-a*d)*m/(b*(m+1))*Int[(c+d*x)^(m-1)*SinhIntegral[a+b*x]^2,x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0]

Int[(c_.+d_.*x_)^m_.*CoshIntegral[a_+b_.*x_]^2,x_Symbol] :=
  (a+b*x)*(c+d*x)^m*CoshIntegral[a+b*x]^2/(b*(m+1)) - 
  2/(m+1)*Int[(c+d*x)^m*Cosh[a+b*x]*CoshIntegral[a+b*x],x] + 
  (b*c-a*d)*m/(b*(m+1))*Int[(c+d*x)^(m-1)*CoshIntegral[a+b*x]^2,x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0]

x:  ∫(x^m) ((SinhIntegral[a+b x])^2)dx  when  m+2∈(SuperMinus[ℤ])

Derivation: Inverted integration by parts

Rule: If  m+2∈(SuperMinus[ℤ]), then

∫(x^m) ((SinhIntegral[a+b x])^2)dx  ⟶  ((b (x^(m+2)) ((SinhIntegral[a+b x])^2))/(a (m+1)))+(((x^(m+1)) ((SinhIntegral[a+b x])^2))/(m+1))-    
   ((2 b)/(a (m+1)))∫(x^(m+1)) Sinh[a+b x] SinhIntegral[a+b x]dx-((b (m+2))/(a (m+1)))∫(x^(m+1)) ((SinhIntegral[a+b x])^2)dx

Program code:

(* Int[x_^m_.*SinhIntegral[a_+b_.*x_]^2,x_Symbol] :=
  b*x^(m+2)*SinhIntegral[a+b*x]^2/(a*(m+1)) +
  x^(m+1)*SinhIntegral[a+b*x]^2/(m+1) -
  2*b/(a*(m+1))*Int[x^(m+1)*Sinh[a+b*x]*SinhIntegral[a+b*x],x] -
  b*(m+2)/(a*(m+1))*Int[x^(m+1)*SinhIntegral[a+b*x]^2,x] /;
FreeQ[{a,b},x] && ILtQ[m,-2] *)

(* Int[x_^m_.*CoshIntegral[a_+b_.*x_]^2,x_Symbol] :=
  b*x^(m+2)*CoshIntegral[a+b*x]^2/(a*(m+1)) +
  x^(m+1)*CoshIntegral[a+b*x]^2/(m+1) -
  2*b/(a*(m+1))*Int[x^(m+1)*Cosh[a+b*x]*CoshIntegral[a+b*x],x] -
  b*(m+2)/(a*(m+1))*Int[x^(m+1)*CoshIntegral[a+b*x]^2,x] /;
FreeQ[{a,b},x] && ILtQ[m,-2] *)

3.  ∫u Sinh[a+b x] SinhIntegral[c+d x]dx

1:  ∫Sinh[a+b x] SinhIntegral[c+d x]dx

Derivation: Integration by parts

Rule:

∫Sinh[a+b x] SinhIntegral[c+d x]dx  ⟶  ((Cosh[a+b x] SinhIntegral[c+d x])/b)-(d/b)∫((Cosh[a+b x] Sinh[c+d x])/(c+d x))dx

Program code:

Int[Sinh[a_.+b_.*x_]*SinhIntegral[c_.+d_.*x_],x_Symbol] :=
  Cosh[a+b*x]*SinhIntegral[c+d*x]/b -
  d/b*Int[Cosh[a+b*x]*Sinh[c+d*x]/(c+d*x),x] /;
FreeQ[{a,b,c,d},x]

Int[Cosh[a_.+b_.*x_]*CoshIntegral[c_.+d_.*x_],x_Symbol] :=
  Sinh[a+b*x]*CoshIntegral[c+d*x]/b -
  d/b*Int[Sinh[a+b*x]*Cosh[c+d*x]/(c+d*x),x] /;
FreeQ[{a,b,c,d},x]

2.  ∫(((e+f x))^m) Sinh[a+b x] SinhIntegral[c+d x]dx

1:  ∫(((e+f x))^m) Sinh[a+b x] SinhIntegral[c+d x]dx  when  m∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  m∈(SuperPlus[ℤ]), then

∫(((e+f x))^m) Sinh[a+b x] SinhIntegral[c+d x]dx  ⟶  

(((((e+f x))^m) Cosh[a+b x] SinhIntegral[c+d x])/b)-
(d/b)∫(((((e+f x))^m) Cosh[a+b x] Sinh[c+d x])/(c+d x))dx-((f m)/b)∫(((e+f x))^(m-1)) Cosh[a+b x] SinhIntegral[c+d x]dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sinh[a_.+b_.*x_]*SinhIntegral[c_.+d_.*x_],x_Symbol] :=
  (e+f*x)^m*Cosh[a+b*x]*SinhIntegral[c+d*x]/b - 
  d/b*Int[(e+f*x)^m*Cosh[a+b*x]*Sinh[c+d*x]/(c+d*x),x] - 
  f*m/b*Int[(e+f*x)^(m-1)*Cosh[a+b*x]*SinhIntegral[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0]

Int[(e_.+f_.*x_)^m_.*Cosh[a_.+b_.*x_]*CoshIntegral[c_.+d_.*x_],x_Symbol] :=
  (e+f*x)^m*Sinh[a+b*x]*CoshIntegral[c+d*x]/b - 
  d/b*Int[(e+f*x)^m*Sinh[a+b*x]*Cosh[c+d*x]/(c+d*x),x] - 
  f*m/b*Int[(e+f*x)^(m-1)*Sinh[a+b*x]*CoshIntegral[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0]

2:  ∫(((e+f x))^m) Sinh[a+b x] SinhIntegral[c+d x]dx  when  m+1∈(SuperMinus[ℤ])

Derivation: Inverted integration by parts

Rule: If  m+1∈(SuperMinus[ℤ]), then

∫(((e+f x))^m) Sinh[a+b x] SinhIntegral[c+d x]dx  ⟶  

(((((e+f x))^(m+1)) Sinh[a+b x] SinhIntegral[c+d x])/(f (m+1)))-
(d/(f (m+1)))∫(((((e+f x))^(m+1)) Sinh[a+b x] Sinh[c+d x])/(c+d x))dx-(b/(f (m+1)))∫(((e+f x))^(m+1)) Cosh[a+b x] SinhIntegral[c+d x]dx

Program code:

Int[(e_.+f_.*x_)^m_*Sinh[a_.+b_.*x_]*SinhIntegral[c_.+d_.*x_],x_Symbol] :=
  (e+f*x)^(m+1)*Sinh[a+b*x]*SinhIntegral[c+d*x]/(f*(m+1)) - 
  d/(f*(m+1))*Int[(e+f*x)^(m+1)*Sinh[a+b*x]*Sinh[c+d*x]/(c+d*x),x] - 
  b/(f*(m+1))*Int[(e+f*x)^(m+1)*Cosh[a+b*x]*SinhIntegral[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f},x] && ILtQ[m,-1]

Int[(e_.+f_.*x_)^m_.*Cosh[a_.+b_.*x_]*CoshIntegral[c_.+d_.*x_],x_Symbol] :=
  (e+f*x)^(m+1)*Cosh[a+b*x]*CoshIntegral[c+d*x]/(f*(m+1)) - 
  d/(f*(m+1))*Int[(e+f*x)^(m+1)*Cosh[a+b*x]*Cosh[c+d*x]/(c+d*x),x] - 
  b/(f*(m+1))*Int[(e+f*x)^(m+1)*Sinh[a+b*x]*CoshIntegral[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f},x] && ILtQ[m,-1]

4.  ∫u Cosh[a+b x] SinhIntegral[c+d x]dx

1:  ∫Cosh[a+b x] SinhIntegral[c+d x]dx

Derivation: Integration by parts

Rule:

∫Cosh[a+b x] SinhIntegral[c+d x]dx  ⟶  ((Sinh[a+b x] SinhIntegral[c+d x])/b)-(d/b)∫((Sinh[a+b x] Sinh[c+d x])/(c+d x))dx

Program code:

Int[Cosh[a_.+b_.*x_]*SinhIntegral[c_.+d_.*x_],x_Symbol] :=
  Sinh[a+b*x]*SinhIntegral[c+d*x]/b -
  d/b*Int[Sinh[a+b*x]*Sinh[c+d*x]/(c+d*x),x] /;
FreeQ[{a,b,c,d},x]

Int[Sinh[a_.+b_.*x_]*CoshIntegral[c_.+d_.*x_],x_Symbol] :=
  Cosh[a+b*x]*CoshIntegral[c+d*x]/b -
  d/b*Int[Cosh[a+b*x]*Cosh[c+d*x]/(c+d*x),x] /;
FreeQ[{a,b,c,d},x]

2.  ∫(((e+f x))^m) Cosh[a+b x] SinhIntegral[c+d x]dx

1:  ∫(((e+f x))^m) Cosh[a+b x] SinhIntegral[c+d x]dx  when  m∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  m∈(SuperPlus[ℤ]), then

∫(((e+f x))^m) Cosh[a+b x] SinhIntegral[c+d x]dx  ⟶  

(((((e+f x))^m) Sinh[a+b x] SinhIntegral[c+d x])/b)-
(d/b)∫(((((e+f x))^m) Sinh[a+b x] Sinh[c+d x])/(c+d x))dx-((f m)/b)∫(((e+f x))^(m-1)) Sinh[a+b x] SinhIntegral[c+d x]dx

Program code:

Int[(e_.+f_.*x_)^m_.*Cosh[a_.+b_.*x_]*SinhIntegral[c_.+d_.*x_],x_Symbol] :=
  (e+f*x)^m*Sinh[a+b*x]*SinhIntegral[c+d*x]/b -
  d/b*Int[(e+f*x)^m*Sinh[a+b*x]*Sinh[c+d*x]/(c+d*x),x] -
  f*m/b*Int[(e+f*x)^(m-1)*Sinh[a+b*x]*SinhIntegral[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0]

Int[(e_.+f_.*x_)^m_.*Sinh[a_.+b_.*x_]*CoshIntegral[c_.+d_.*x_],x_Symbol] :=
  (e+f*x)^m*Cosh[a+b*x]*CoshIntegral[c+d*x]/b -
  d/b*Int[(e+f*x)^m*Cosh[a+b*x]*Cosh[c+d*x]/(c+d*x),x] -
  f*m/b*Int[(e+f*x)^(m-1)*Cosh[a+b*x]*CoshIntegral[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0]

2:  ∫(((e+f x))^m) Cosh[a+b x] SinhIntegral[c+d x]dx  when  m+1∈(SuperMinus[ℤ])

Derivation: Inverted integration by parts

Rule: If  m+1∈(SuperMinus[ℤ]), then

∫(((e+f x))^m) Cosh[a+b x] SinhIntegral[c+d x]dx  ⟶  

(((((e+f x))^(m+1)) Cosh[a+b x] SinhIntegral[c+d x])/(f (m+1)))-
(d/(f (m+1)))∫(((((e+f x))^(m+1)) Cosh[a+b x] Sinh[c+d x])/(c+d x))dx-(b/(f (m+1)))∫(((e+f x))^(m+1)) Sinh[a+b x] SinhIntegral[c+d x]dx

Program code:

Int[(e_.+f_.*x_)^m_.*Cosh[a_.+b_.*x_]*SinhIntegral[c_.+d_.*x_],x_Symbol] :=
  (e+f*x)^(m+1)*Cosh[a+b*x]*SinhIntegral[c+d*x]/(f*(m+1)) -
  d/(f*(m+1))*Int[(e+f*x)^(m+1)*Cosh[a+b*x]*Sinh[c+d*x]/(c+d*x),x] -
  b/(f*(m+1))*Int[(e+f*x)^(m+1)*Sinh[a+b*x]*SinhIntegral[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f},x] && ILtQ[m,-1]

Int[(e_.+f_.*x_)^m_*Sinh[a_.+b_.*x_]*CoshIntegral[c_.+d_.*x_],x_Symbol] :=
  (e+f*x)^(m+1)*Sinh[a+b*x]*CoshIntegral[c+d*x]/(f*(m+1)) -
  d/(f*(m+1))*Int[(e+f*x)^(m+1)*Sinh[a+b*x]*Cosh[c+d*x]/(c+d*x),x] -
  b/(f*(m+1))*Int[(e+f*x)^(m+1)*Cosh[a+b*x]*CoshIntegral[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f},x] && ILtQ[m,-1]

5.  ∫u SinhIntegral[d (a+b Log[c (x^n)])]dx

1:  ∫SinhIntegral[d (a+b Log[c (x^n)])]dx

Derivation: Integration by parts

Basis: (∂_x)SinhIntegral[d (a+b Log[c (x^n)])]==((b d n Sinh[d (a+b Log[c (x^n)])])/(x (d (a+b Log[c (x^n)]))))

Rule: If  m≠-1, then

∫SinhIntegral[d (a+b Log[c (x^n)])]dx  ⟶  x SinhIntegral[d (a+b Log[c (x^n)])]-b d n ∫((Sinh[d (a+b Log[c (x^n)])])/(d (a+b Log[c (x^n)])))dx

Program code:

Int[SinhIntegral[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  x*SinhIntegral[d*(a+b*Log[c*x^n])] - b*d*n*Int[Sinh[d*(a+b*Log[c*x^n])]/(d*(a+b*Log[c*x^n])),x] /;
FreeQ[{a,b,c,d,n},x]

Int[CoshIntegral[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  x*CoshIntegral[d*(a+b*Log[c*x^n])] - b*d*n*Int[Cosh[d*(a+b*Log[c*x^n])]/(d*(a+b*Log[c*x^n])),x] /;
FreeQ[{a,b,c,d,n},x]

2:  ∫((SinhIntegral[d (a+b Log[c (x^n)])])/x)dx

Derivation: Integration by substitution

Basis: ((F[Log[c (x^n)]])/x)==(1/n) Subst[F[x],x,Log[c (x^n)]] (∂_x)Log[c (x^n)]

Rule:

∫((SinhIntegral[d (a+b Log[c (x^n)])])/x)dx  ⟶  (1/n) Subst[SinhIntegral[d (a+b x)],x,Log[c (x^n)]]

Program code:

Int[F_[d_.*(a_.+b_.*Log[c_.*x_^n_.])]/x_,x_Symbol] :=
  1/n*Subst[F[d*(a+b*x)],x,Log[c*x^n]] /;
FreeQ[{a,b,c,d,n},x] && MemberQ[{SinhIntegral,CoshIntegral},x]

3:  ∫(((e x))^m) SinhIntegral[d (a+b Log[c (x^n)])]dx  when  m≠-1

Derivation: Integration by parts

Basis: (∂_x)SinhIntegral[d (a+b Log[c (x^n)])]==((b d n Sinh[d (a+b Log[c (x^n)])])/(x (d (a+b Log[c (x^n)]))))

Rule: If  m≠-1, then

∫(((e x))^m) SinhIntegral[d (a+b Log[c (x^n)])]dx  ⟶  (((((e x))^(m+1)) SinhIntegral[d (a+b Log[c (x^n)])])/(e (m+1)))-((b d n)/(m+1)) ∫(((((e x))^m) Sinh[d (a+b Log[c (x^n)])])/(d (a+b Log[c (x^n)])))dx

Program code:

Int[(e_.*x_)^m_.*SinhIntegral[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  (e*x)^(m+1)*SinhIntegral[d*(a+b*Log[c*x^n])]/(e*(m+1)) - 
  b*d*n/(m+1)*Int[(e*x)^m*Sinh[d*(a+b*Log[c*x^n])]/(d*(a+b*Log[c*x^n])),x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[m,-1]

Int[(e_.*x_)^m_.*CoshIntegral[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  (e*x)^(m+1)*CoshIntegral[d*(a+b*Log[c*x^n])]/(e*(m+1)) - 
  b*d*n/(m+1)*Int[(e*x)^m*Cosh[d*(a+b*Log[c*x^n])]/(d*(a+b*Log[c*x^n])),x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[m,-1]