Rules for integrands involving zeta functions

1.  ∫Zeta[s,a+b x]dx

1:  ∫Zeta[2,a+b x]dx

Derivation: Algebraic simplification

Basis: (Zeta2[2, z])=(PolyGamma2[1, z])

Rule:

∫Zeta[2,a+b x]dx  ⟶  ∫PolyGamma[1,a+b x]dx

Program code:

Int[Zeta[2,a_.+b_.*x_],x_Symbol] :=
  Int[PolyGamma[1,a+b*x],x] /;
FreeQ[{a,b},x]

2:  ∫Zeta[s,a+b x]dx  when  s≠1 ∧ s≠2

Derivation: Primitive rule

Basis: ((∂(Zeta2[s, z]))/(∂z))=-s (Zeta2[s+1, z])

Rule: If  s≠1 ∧ s≠2, then

∫Zeta[s,a+b x]dx  ⟶  -((Zeta[s-1,a+b x])/(b (s-1)))

Program code:

Int[Zeta[s_,a_.+b_.*x_],x_Symbol] :=
  -Zeta[s-1,a+b*x]/(b*(s-1)) /;
FreeQ[{a,b,s},x] && NeQ[s,1] && NeQ[s,2]

2.  ∫(((c+d x))^m)Zeta[s,a+b x]dx

1:  ∫(((c+d x))^m) Zeta[2,a+b x]dx  when  m∈ℚ

Derivation: Algebraic simplification

Basis: (Zeta2[2, z])=(PolyGamma2[1, z])

Rule: If  m∈ℚ, then

∫(((c+d x))^m) Zeta[2,a+b x]dx  ⟶  ∫(((c+d x))^m) PolyGamma[1,a+b x]dx

Program code:

Int[(c_.+d_.*x_)^m_.*Zeta[2,a_.+b_.*x_],x_Symbol] :=
  Int[(c+d*x)^m*PolyGamma[1,a+b*x],x] /;
FreeQ[{a,b,c,d},x] && RationalQ[m]

2.  ∫(((c+d x))^m)Zeta[s,a+b x]dx  when  s≠1 ∧ s≠2

1:  ∫(((c+d x))^m) Zeta[s,a+b x]dx  when  s≠1 ∧ s≠2 ∧ m>0

Derivation: Integration by parts

Rule: If  s≠1 ∧ s≠2 ∧ m>0, then

∫(((c+d x))^m) Zeta[s,a+b x]dx  ⟶  -(((((c+d x))^m) Zeta[s-1,a+b x])/(b (s-1)))+((d m)/(b (s-1)))∫(((c+d x))^(m-1)) Zeta[s-1,a+b x]dx

Program code:

Int[(c_.+d_.*x_)^m_.*Zeta[s_,a_.+b_.*x_],x_Symbol] :=
  -(c+d*x)^m*Zeta[s-1,a+b*x]/(b*(s-1)) +
  d*m/(b*(s-1))*Int[(c+d*x)^(m-1)*Zeta[s-1,a+b*x],x] /;
FreeQ[{a,b,c,d,s},x] && NeQ[s,1] && NeQ[s,2] && GtQ[m,0]

2:  ∫(((c+d x))^m) Zeta[s,a+b x]dx  when  s≠1 ∧ s≠2 ∧ m<-1

Derivation: Inverted integration by parts

Rule: If  s≠1 ∧ s≠2 ∧ m<-1, then

∫(((c+d x))^m) Zeta[s,a+b x]dx  ⟶  (((((c+d x))^(m+1)) Zeta[s,a+b x])/(d (m+1)))+((b s)/(d (m+1)))∫(((c+d x))^(m+1)) Zeta[s+1,a+b x]dx

Program code:

Int[(c_.+d_.*x_)^m_.*Zeta[s_,a_.+b_.*x_],x_Symbol] :=
  (c+d*x)^(m+1)*Zeta[s,a+b*x]/(d*(m+1)) +
  b*s/(d*(m+1))*Int[(c+d*x)^(m+1)*Zeta[s+1,a+b*x],x] /;
FreeQ[{a,b,c,d,s},x] && NeQ[s,1] && NeQ[s,2] && LtQ[m,-1]