Rules for integrands involving polylogarithms

1.  ∫u PolyLog[n,a (((b (x^p)))^q)]dx

1.  ∫PolyLog[n,a (((b (x^p)))^q)]dx

1.  ∫PolyLog[n,a (((b (x^p)))^q)]dx  when  n>0

x:  ∫PolyLog[2,a (((b (x^p)))^q)]dx

Derivation:  Integration by parts

Note:  This rule not necessary for host systems, like Mathematica, that automatically simplify PolyLog[1,z] to -Log[1-z].

Rule:

∫PolyLog[2,a (((b (x^p)))^q)]dx  ⟶  x PolyLog[2,a (((b (x^p)))^q)]+p q∫Log[1-a (((b (x^p)))^q)]dx

Program code:

(* Int[PolyLog[2,a_.*(b_.*x_^p_.)^q_.],x_Symbol] :=
  x*PolyLog[2,a*(b*x^p)^q] + p*q*Int[Log[1-a*(b*x^p)^q],x] /;
FreeQ[{a,b,p,q},x] *)

2:  ∫PolyLog[n,a (((b (x^p)))^q)]dx  when  n>0

Derivation:  Integration by parts

Rule: If  n>0, then

∫PolyLog[n,a (((b (x^p)))^q)]dx  ⟶  x PolyLog[n,a (((b (x^p)))^q)]-p q∫PolyLog[n-1,a (((b (x^p)))^q)]dx

Program code:

Int[PolyLog[n_,a_.*(b_.*x_^p_.)^q_.],x_Symbol] :=
  x*PolyLog[n,a*(b*x^p)^q] - p*q*Int[PolyLog[n-1,a*(b*x^p)^q],x] /;
FreeQ[{a,b,p,q},x] && GtQ[n,0]

2:  ∫PolyLog[n,a (((b (x^p)))^q)]dx  when  n<-1

Derivation: Inverted integration by parts

Rule: If  n<-1, then

∫PolyLog[n,a (((b (x^p)))^q)]dx  ⟶  ((x PolyLog[n+1,a (((b (x^p)))^q)])/(p q))-(1/(p q))∫PolyLog[n+1,a (((b (x^p)))^q)]dx

Program code:

Int[PolyLog[n_,a_.*(b_.*x_^p_.)^q_.],x_Symbol] :=
  x*PolyLog[n+1,a*(b*x^p)^q]/(p*q) - 1/(p*q)*Int[PolyLog[n+1,a*(b*x^p)^q],x] /;
FreeQ[{a,b,p,q},x] && LtQ[n,-1]

U:  ∫PolyLog[n,a (((b (x^p)))^q)]dx

Rule:

∫PolyLog[n,a (((b (x^p)))^q)]dx  ⟶  ∫PolyLog[n,a (((b (x^p)))^q)]dx

Program code:

Int[PolyLog[n_,a_.*(b_.*x_^p_.)^q_.],x_Symbol] :=
  Unintegrable[PolyLog[n,a*(b*x^p)^q],x] /;
FreeQ[{a,b,n,p,q},x]

2.  ∫(((d x))^m)PolyLog[n,a (((b (x^p)))^q)]dx

1:  ∫((PolyLog[n,a (((b (x^p)))^q)])/x)dx

Derivation: Primitive rule

Basis: ((∂(PolyLog[n, z]))/(∂z))=((PolyLog[n-1, z])/z)

Rule:

∫((PolyLog[n,a (((b (x^p)))^q)])/x)dx  ⟶  ((PolyLog[n+1,a (((b (x^p)))^q)])/(p q))

Program code:

Int[PolyLog[n_,c_.*(a_.+b_.*x_)^p_.]/(d_.+e_.*x_),x_Symbol] :=
  PolyLog[n+1,c*(a+b*x)^p]/(e*p) /;
FreeQ[{a,b,c,d,e,n,p},x] && EqQ[b*d,a*e]

Int[PolyLog[n_,a_.*(b_.*x_^p_.)^q_.]/x_,x_Symbol] :=
  PolyLog[n+1,a*(b*x^p)^q]/(p*q) /;
FreeQ[{a,b,n,p,q},x]

2.  ∫(((d x))^m)PolyLog[n,a (((b (x^p)))^q)]dx  when  m≠-1

1:  ∫(((d x))^m) PolyLog[n,a (((b (x^p)))^q)]dx  when  m≠-1 ∧ n>0

Derivation: Integration by parts

Rule: If  m≠-1 ∧ n>0, then

∫(((d x))^m) PolyLog[n,a (((b (x^p)))^q)]dx  ⟶  (((((d x))^(m+1)) PolyLog[n,a (((b (x^p)))^q)])/(d (m+1)))-((p q)/(m+1))∫(((d x))^m) PolyLog[n-1,a (((b (x^p)))^q)]dx

Program code:

Int[(d_.*x_)^m_.*PolyLog[n_,a_.*(b_.*x_^p_.)^q_.],x_Symbol] :=
  (d*x)^(m+1)*PolyLog[n,a*(b*x^p)^q]/(d*(m+1)) - 
  p*q/(m+1)*Int[(d*x)^m*PolyLog[n-1,a*(b*x^p)^q],x] /;
FreeQ[{a,b,d,m,p,q},x] && NeQ[m,-1] && GtQ[n,0]

2:  ∫(((d x))^m) PolyLog[n,a (((b (x^p)))^q)]dx  when  m≠-1 ∧ n<-1

Derivation: Inverted integration by parts

Rule: If  m≠-1 ∧ n<-1, then

∫(((d x))^m) PolyLog[n,a (((b (x^p)))^q)]dx  ⟶  (((((d x))^(m+1)) PolyLog[n+1,a (((b (x^p)))^q)])/(d p q))-((m+1)/(p q))∫(((d x))^m) PolyLog[n+1,a (((b (x^p)))^q)]dx

Program code:

Int[(d_.*x_)^m_.*PolyLog[n_,a_.*(b_.*x_^p_.)^q_.],x_Symbol] :=
  (d*x)^(m+1)*PolyLog[n+1,a*(b*x^p)^q]/(d*p*q) - 
  (m+1)/(p*q)*Int[(d*x)^m*PolyLog[n+1,a*(b*x^p)^q],x] /;
FreeQ[{a,b,d,m,p,q},x] && NeQ[m,-1] && LtQ[n,-1]

U:  ∫(((d x))^m) PolyLog[n,a (((b (x^p)))^q)]dx

Rule:

∫(((d x))^m) PolyLog[n,a (((b (x^p)))^q)]dx  ⟶  ∫(((d x))^m) PolyLog[n,a (((b (x^p)))^q)]dx

Program code:

Int[(d_.*x_)^m_.*PolyLog[n_,a_.*(b_.*x_^p_.)^q_.],x_Symbol] :=
  Unintegrable[(d*x)^m*PolyLog[n,a*(b*x^p)^q],x] /;
FreeQ[{a,b,d,m,n,p,q},x]

3:  ∫((((Log[c (x^m)])^r) PolyLog[n,a (((b (x^p)))^q)])/x)dx  when  r>0

Derivation: Integration by parts

Rule: If  r>0, then

∫((((Log[c (x^m)])^r) PolyLog[n,a (((b (x^p)))^q)])/x)dx  ⟶  
((((Log[c (x^m)])^r) PolyLog[n+1,a (((b (x^p)))^q)])/(p q))-((m r)/(p q))∫((((Log[c (x^m)])^(r-1)) PolyLog[n+1,a (((b (x^p)))^q)])/x)dx

Program code:

Int[Log[c_.*x_^m_.]^r_.*PolyLog[n_,a_.*(b_.*x_^p_.)^q_.]/x_,x_Symbol] :=
  Log[c*x^m]^r*PolyLog[n+1,a*(b*x^p)^q]/(p*q) - 
  m*r/(p*q)*Int[Log[c*x^m]^(r-1)*PolyLog[n+1,a*(b*x^p)^q]/x,x] /;
FreeQ[{a,b,c,m,n,q,r},x] && GtQ[r,0]

2.  ∫u PolyLog[n,c (((a+b x))^p)]dx

1:  ∫PolyLog[n,c (((a+b x))^p)]dx  when  n>0

Derivation: Integration by parts and algebraic expansion

Basis: (∂_x)PolyLog[n,c (((a+b x))^p)]==((b p PolyLog[n-1,c (((a+b x))^p)])/(a+b x))

Basis: (x/(a+b x))==(1/b)-(a/(b (a+b x)))

Rule: If  n>0, then

∫PolyLog[n,c (((a+b x))^p)]dx  ⟶
  x PolyLog[n,c (((a+b x))^p)]-b p ∫((x PolyLog[n-1,c (((a+b x))^p)])/(a+b x))dx  ⟶  
x PolyLog[n,c (((a+b x))^p)]-p ∫PolyLog[n-1,c (((a+b x))^p)]dx+a p ∫((PolyLog[n-1,c (((a+b x))^p)])/(a+b x))dx

Program code:

Int[PolyLog[n_,c_.*(a_.+b_.*x_)^p_.],x_Symbol] :=
  x*PolyLog[n,c*(a+b*x)^p] -
  p*Int[PolyLog[n-1,c*(a+b*x)^p],x] +
  a*p*Int[PolyLog[n-1,c*(a+b*x)^p]/(a+b*x),x] /;
FreeQ[{a,b,c,p},x] && GtQ[n,0]

2.  ∫(((d+e x))^m) PolyLog[n,c (((a+b x))^p)]dx

1.  ∫(((d+e x))^m) PolyLog[2,c (a+b x)]dx

1.  ∫((PolyLog[2,c (a+b x)])/(d+e x))dx

1:  ∫((PolyLog[2,c (a+b x)])/(d+e x))dx  when  c (b d-a e)+e==0

Derivation: Integration by parts

Basis: If  c (b d-a e)+e==0, then (1/(d+e x))==(∂_x)((Log[1-a c-b c x])/e)

Basis: (∂_x)PolyLog[2,c (a+b x)]==-((b Log[1-a c-b c x])/(a+b x))

Rule: If  c (b d-a e)+e==0, then

∫((PolyLog[2,c (a+b x)])/(d+e x)) dx  ⟶  ((Log[1-a c-b c x] PolyLog[2,c (a+b x)])/e)+(b/e) ∫(((Log[1-a c-b c x])^2)/(a+b x))dx

Program code:

Int[PolyLog[2,c_.*(a_.+b_.*x_)]/(d_.+e_.*x_),x_Symbol] :=
  Log[1-a*c-b*c*x]*PolyLog[2,c*(a+b*x)]/e + b/e*Int[Log[1-a*c-b*c*x]^2/(a+b*x),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c*(b*d-a*e)+e,0]

2:  ∫((PolyLog[2,c (a+b x)])/(d+e x))dx  when  c (b d-a e)+e≠0

Derivation: Integration by parts

Basis: (∂_x)PolyLog[2,c (a+b x)]==-((b Log[1-a c-b c x])/(a+b x))

Rule: If  c (b d-a e)+e≠0, then

∫((PolyLog[2,c (a+b x)])/(d+e x)) dx  ⟶  ((Log[d+e x] PolyLog[2,c (a+b x)])/e)+(b/e) ∫((Log[d+e x] Log[1-a c-b c x])/(a+b x))dx

Program code:

Int[PolyLog[2,c_.*(a_.+b_.*x_)]/(d_.+e_.*x_),x_Symbol] :=
  Log[d+e*x]*PolyLog[2,c*(a+b*x)]/e + b/e*Int[Log[d+e*x]*Log[1-a*c-b*c*x]/(a+b*x),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[c*(b*d-a*e)+e,0]

2:  ∫(((d+e x))^m) PolyLog[2,c (a+b x)]dx  when  m≠-1

Derivation: Integration by parts

Rule: If  m≠-1, then

∫(((d+e x))^m) PolyLog[2,c (a+b x)] dx  ⟶  (((((d+e x))^(m+1)) PolyLog[2,c (a+b x)])/(e (m+1)))+(b/(e (m+1))) ∫(((((d+e x))^(m+1)) Log[1-a c-b c x])/(a+b x))dx

Program code:

Int[(d_.+e_.*x_)^m_.*PolyLog[2,c_.*(a_.+b_.*x_)],x_Symbol] :=
  (d+e*x)^(m+1)*PolyLog[2,c*(a+b*x)]/(e*(m+1)) + b/(e*(m+1))*Int[(d+e*x)^(m+1)*Log[1-a*c-b*c*x]/(a+b*x),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[m,-1]

x:  ∫(((d+e x))^m) PolyLog[n,c (((a+b x))^p)]dx  when  n>0 ∧ m∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  n>0 ∧ m∈(SuperPlus[ℤ]), then

∫(((d+e x))^m) PolyLog[n,c (((a+b x))^p)]dx  ⟶  (((((d+e x))^(m+1)) PolyLog[n,c (((a+b x))^p)])/(e (m+1)))-((b p)/(e (m+1)))∫(((((d+e x))^(m+1)) PolyLog[n-1,c (((a+b x))^p)])/(a+b x))dx

Program code:

(* Int[(d_.+e_.*x_)^m_.*PolyLog[n_,c_.*(a_.+b_.*x_)^p_.],x_Symbol] :=
  (d+e*x)^(m+1)*PolyLog[n,c*(a+b*x)^p]/(e*(m+1)) -
  b*p/(e*(m+1))*Int[(d+e*x)^(m+1)*PolyLog[n-1,c*(a+b*x)^p]/(a+b*x),x] /;
FreeQ[{a,b,c,d,e,m,p},x] && GtQ[n,0] && IGtQ[m,0] *)

2:  ∫(x^m) PolyLog[n,c (((a+b x))^p)]dx  when  n>0 ∧ m∈ℤ ∧ m≠-1

Derivation: Integration by parts

Rule: If  n>0 ∧ m∈ℤ ∧ m≠-1, then

∫(x^m) PolyLog[n,c (((a+b x))^p)]dx  ⟶  
-((((a^(m+1))-(b^(m+1)) (x^(m+1))) PolyLog[n,c (((a+b x))^p)])/((m+1) (b^(m+1))))+(p/((m+1) (b^m))) ∫PolyLog[n-1,c (((a+b x))^p)] ExpandIntegrand[(((a^(m+1))-(b^(m+1)) (x^(m+1)))/(a+b x)),x] dx

Program code:

Int[x_^m_.*PolyLog[n_,c_.*(a_.+b_.*x_)^p_.],x_Symbol] :=
  -(a^(m+1)-b^(m+1)*x^(m+1))*PolyLog[n,c*(a+b*x)^p]/((m+1)*b^(m+1)) +
  p/((m+1)*b^m)*Int[ExpandIntegrand[PolyLog[n-1,c*(a+b*x)^p],(a^(m+1)-b^(m+1)*x^(m+1))/(a+b*x),x],x] /;
FreeQ[{a,b,c,p},x] && GtQ[n,0] && IntegerQ[m] && NeQ[m,-1]

3.  ∫u (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx

1:  ∫(g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx

Derivation: Integration by parts and algebraic expansion

Basis: (∂_x)((g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)])==-((b (g+h Log[f (((d+e x))^n)]) Log[1-c (a+b x)])/(a+b x))+((e h n PolyLog[2,c (a+b x)])/(d+e x))

Rule:

∫(g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx  ⟶  

x (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]+
b∫(g+ h Log[f (((d+e x))^n)]) Log[1-a c-b c x] ExpandIntegrand[(x/(a+b x)),x]dx-e h n ∫PolyLog[2,c (a+b x)] ExpandIntegrand[(x/(d+e x)),x]dx

Program code:

Int[(g_.+h_.*Log[f_.*(d_.+e_.*x_)^n_.])*PolyLog[2,c_.*(a_.+b_.*x_)],x_Symbol] :=
  x*(g+h*Log[f*(d+e*x)^n])*PolyLog[2,c*(a+b*x)] + 
  b*Int[(g+h*Log[f*(d+e*x)^n])*Log[1-a*c-b*c*x]*ExpandIntegrand[x/(a+b*x),x],x] - 
  e*h*n*Int[PolyLog[2,c*(a+b*x)]*ExpandIntegrand[x/(d+e*x),x],x] /;
FreeQ[{a,b,c,d,e,f,g,h,n},x]

2.  ∫(x^m) (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx  when  m∈ℤ

1.  ∫(((g+h Log[1+e x]) PolyLog[2,c x])/x)dx  when  c+e==0

1:  ∫((Log[1+e x] PolyLog[2,c x])/x)dx  when  c+e==0

Derivation: Integration by substitution

Basis: If  e+c==0, then ((Log[1+e x])/x)==-(∂_x)PolyLog[2,c x]

Rule: If  c+e==0, then

∫((Log[1+e x] PolyLog[2,c x])/x)dx  ⟶  -(((PolyLog[2,c x])^2)/2)

Program code:

Int[Log[1+e_.*x_]*PolyLog[2,c_.*x_]/x_,x_Symbol] :=
  -PolyLog[2,c*x]^2/2 /;
FreeQ[{c,e},x] && EqQ[c+e,0]

2:  ∫(((g+h Log[1+e x]) PolyLog[2,c x])/x)dx  when  c+e==0

Derivation: Algebraic expansion

Rule: If  c+e==0, then

∫(((g+h Log[1+e x]) PolyLog[2,c x])/x)dx  ⟶  g ∫((PolyLog[2,c x])/x)dx+h ∫((Log[1+e x] PolyLog[2,c x])/x)dx

Program code:

Int[(g_+h_.*Log[1+e_.*x_])*PolyLog[2,c_.*x_]/x_,x_Symbol] :=
  g*Int[PolyLog[2,c*x]/x,x] + h*Int[(Log[1+e*x]*PolyLog[2,c*x])/x,x] /;
FreeQ[{c,e,g,h},x] && EqQ[c+e,0]

2:  ∫(x^m) (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx  when  m∈ℤ ∧ m≠-1

Derivation: Integration by parts and algebraic expansion

Basis: (∂_x)((g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)])==-((b (g+h Log[f (((d+e x))^n)]) Log[1-a c-b c x])/(a+b x))+((e h n PolyLog[2,c (a+b x)])/(d+e x))

Rule: If  m∈ℤ ∧ m≠-1, then

∫(x^m) (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx  ⟶  

(((x^(m+1)) (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)])/(m+1))+(b/(m+1))∫(g+ h Log[f (((d+e x))^n)]) Log[1-a c-b c x] ExpandIntegrand[((x^(m+1))/(a+b x)),x]dx-((e h n)/(m+1))∫PolyLog[2,c (a+b x)] ExpandIntegrand[((x^(m+1))/(d+e x)),x]dx

Program code:

Int[x_^m_.*(g_.+h_.*Log[f_.*(d_.+e_.*x_)^n_.])*PolyLog[2,c_.*(a_.+b_.*x_)],x_Symbol] :=
  x^(m+1)*(g+h*Log[f*(d+e*x)^n])*PolyLog[2,c*(a+b*x)]/(m+1) + 
  b/(m+1)*Int[ExpandIntegrand[(g+h*Log[f*(d+e*x)^n])*Log[1-a*c-b*c*x],x^(m+1)/(a+b*x),x],x] - 
  e*h*n/(m+1)*Int[ExpandIntegrand[PolyLog[2,c*(a+b*x)],x^(m+1)/(d+e*x),x],x] /;
FreeQ[{a,b,c,d,e,f,g,h,n},x] && IntegerQ[m] && NeQ[m,-1]

3:  ∫P[x] (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx

Derivation: Integration by parts and algebraic expansion

Basis: (∂_x)((g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)])==-((b (g+h Log[f (((d+e x))^n)]) Log[1-a c-b c x])/(a+b x))+((e h n PolyLog[2,c (a+b x)])/(d+e x))

Rule: Let u->∫P[x]dx, then

∫P[x] (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx  ⟶  

u (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]+
b∫(g+ h Log[f (((d+e x))^n)]) Log[1-a c-b c x] ExpandIntegrand[(u/(a+b x)),x]dx-e h n∫PolyLog[2,c (a+b x)] ExpandIntegrand[(u/(d+e x)),x]dx

Program code:

Int[Px_*(g_.+h_.*Log[f_.*(d_.+e_.*x_)^n_.])*PolyLog[2,c_.*(a_.+b_.*x_)],x_Symbol] :=
  With[{u=IntHide[Px,x]},
  u*(g+h*Log[f*(d+e*x)^n])*PolyLog[2,c*(a+b*x)] + 
  b*Int[ExpandIntegrand[(g+h*Log[f*(d+e*x)^n])*Log[1-a*c-b*c*x],u/(a+b*x),x],x] - 
  e*h*n*Int[ExpandIntegrand[PolyLog[2,c*(a+b*x)],u/(d+e*x),x],x]] /;
FreeQ[{a,b,c,d,e,f,g,h,n},x] && PolyQ[Px,x]

4.  ∫(x^m) P[x] (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx  when  m∈ℤ

1:  ∫(x^m) P[x] (g+h Log[1+e x]) PolyLog[2,c x]dx  when  m∈(SuperMinus[ℤ])∧ c+e==0 ∧ P[x,-m-1]≠0

Derivation: Algebraic expansion

Note: Separates out the term in the integrand of the form ((P[x,-m-1] (g+h Log[1+e x]) PolyLog[2,c x])/x).

Rule: If  m∈(SuperMinus[ℤ])∧ c+e==0 ∧ P[x,-m-1]≠0, then

∫(x^m) P[x] (g+h Log[1+e x]) PolyLog[2,c x]dx  ⟶  
P[x,-m-1] ∫(((g+h Log[1+e x]) PolyLog[2,c x])/x)dx+∫(x^m) (P[x]-P[x,-m-1] (x^(-m-1))) (g+h Log[1+e x]) PolyLog[2,c x]dx

Program code:

Int[x_^m_*Px_*(g_.+h_.*Log[1+e_.*x_])*PolyLog[2,c_.*x_],x_Symbol] :=
  Coeff[Px,x,-m-1]*Int[(g+h*Log[1+e*x])*PolyLog[2,c*x]/x,x] + 
  Int[x^m*(Px-Coeff[Px,x,-m-1]*x^(-m-1))*(g+h*Log[1+e*x])*PolyLog[2,c*x],x] /;
FreeQ[{c,e,g,h},x] && PolyQ[Px,x] && ILtQ[m,0] && EqQ[c+e,0] && NeQ[Coeff[Px,x,-m-1],0]

2:  ∫(x^m) P[x] (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx  when  m∈ℤ

Derivation: Integration by parts and algebraic expansion

Basis: (∂_x)((g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)])==-((b (g+h Log[f (((d+e x))^n)]) Log[1-a c-b c x])/(a+b x))+((e h n PolyLog[2,c (a+b x)])/(d+e x))

Rule: If  m∈ℤ, let u->∫(x^m) P[x]dx, then

∫(x^m) P[x] (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx  ⟶  

u (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]+
b∫(g+ h Log[f (((d+e x))^n)]) Log[1-a c-b c x] ExpandIntegrand[(u/(a+b x)),x]dx-e h n∫PolyLog[2,c (a+b x)] ExpandIntegrand[(u/(d+e x)),x]dx

Program code:

Int[x_^m_.*Px_*(g_.+h_.*Log[f_.*(d_.+e_.*x_)^n_.])*PolyLog[2,c_.*(a_.+b_.*x_)],x_Symbol] :=
  With[{u=IntHide[x^m*Px,x]},
  u*(g+h*Log[f*(d+e*x)^n])*PolyLog[2,c*(a+b*x)] + 
  b*Int[ExpandIntegrand[(g+h*Log[f*(d+e*x)^n])*Log[1-a*c-b*c*x],u/(a+b*x),x],x] - 
  e*h*n*Int[ExpandIntegrand[PolyLog[2,c*(a+b*x)],u/(d+e*x),x],x]] /;
FreeQ[{a,b,c,d,e,f,g,h,n},x] && PolyQ[Px,x] && IntegerQ[m]

U:  ∫(x^m) P[x] (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx

Rule:

∫(x^m) P[x] (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx  ⟶  ∫(x^m) P[x] (g+ h Log[f (((d+e x))^n)]) PolyLog[2,c (a+b x)]dx

Program code:

Int[x_^m_*Px_.*(g_.+h_.*Log[f_.*(d_.+e_.*x_)^n_.])*PolyLog[2,c_.*(a_.+b_.*x_)],x_Symbol] :=
  Unintegrable[x^m*Px*(g+h*Log[f*(d+e*x)^n])*PolyLog[2,c*(a+b*x)],x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n},x] && PolyQ[Px,x]

4.  ∫u PolyLog[n,d((((F^(c(a+b x)))))^p)]dx

1:  ∫PolyLog[n,d((((F^(c(a+b x)))))^p)]dx

Derivation: Primitive rule

Basis: (∂_z)PolyLog[n,z]==((PolyLog[n-1,z])/z)

Rule:

∫PolyLog[n,d((((F^(c(a+b x)))))^p)]dx  ⟶  ((PolyLog[n+1,d((((F^(c(a+b x)))))^p)])/(b c p Log[F]))

Program code:

Int[PolyLog[n_,d_.*(F_^(c_.*(a_.+b_.*x_)))^p_.],x_Symbol] :=
  PolyLog[n+1,d*(F^(c*(a+b*x)))^p]/(b*c*p*Log[F]) /;
FreeQ[{F,a,b,c,d,n,p},x]

2:  ∫(((e+f x))^m) PolyLog[n,d((((F^(c(a+b x)))))^p)]dx  when  m>0

Derivation: Integration by parts

Basis: PolyLog[n,d ((((F^(c (a+b x)))))^p)]==(∂_x)((PolyLog[n+1,d ((((F^(c (a+b x)))))^p)])/(b c p Log[F]))

Rule: If  m>0, then

∫(((e+f x))^m) PolyLog[n,d((((F^(c(a+b x)))))^p)]dx  ⟶  
(((((e+f x))^m) PolyLog[n+1,d((((F^(c(a+b x)))))^p)])/(b c p Log[F]))-((f m)/(b c p Log[F]))∫(((e+f x))^(m-1)) PolyLog[n+1,d((((F^(c(a+b x)))))^p)]dx

Program code:

Int[(e_.+f_.*x_)^m_.*PolyLog[n_,d_.*(F_^(c_.*(a_.+b_.*x_)))^p_.],x_Symbol] :=
  (e+f*x)^m*PolyLog[n+1,d*(F^(c*(a+b*x)))^p]/(b*c*p*Log[F]) - 
  f*m/(b*c*p*Log[F])*Int[(e+f*x)^(m-1)*PolyLog[n+1,d*(F^(c*(a+b*x)))^p],x] /;
FreeQ[{F,a,b,c,d,e,f,n,p},x] && GtQ[m,0]

5.  ∫u ((PolyLog[n,F[x]]F'[x])/(F[x]))dx

1:  ∫((PolyLog[n,F[x]]F'[x])/(F[x]))dx

Basis:  (∂_x)PolyLog[n+1,x]==((PolyLog[n,x])/x)

Rule:

∫((PolyLog[n,F[x]]F'[x])/(F[x]))dx  ⟶  PolyLog[n+1,F[x]]

Program code:

Int[u_*PolyLog[n_,v_],x_Symbol] :=
  With[{w=DerivativeDivides[v,u*v,x]},
  w*PolyLog[n+1,v] /;
 Not[FalseQ[w]]] /;
FreeQ[n,x]

2:  ∫((Log[G[x]]PolyLog[n,F[x]]F'[x])/(F[x]))dx

Derivation: Integration by parts

Basis:  ((PolyLog[n,x])/x)==(∂_x)PolyLog[n+1,x]

Rule:

∫((Log[G[x]]PolyLog[n,F[x]]F'[x])/(F[x]))dx  ⟶  Log[G[x]]PolyLog[n+1,F[x]]-∫((G'[x]PolyLog[n+1,F[x]])/(G[x]))dx

Program code:

Int[u_*Log[w_]*PolyLog[n_,v_],x_Symbol] :=
  With[{z=DerivativeDivides[v,u*v,x]},
  z*Log[w]*PolyLog[n+1,v] - 
  Int[SimplifyIntegrand[z*D[w,x]*PolyLog[n+1,v]/w,x],x] /;
 Not[FalseQ[z]]] /;
FreeQ[n,x] && InverseFunctionFreeQ[w,x]